         TITLE 'IEFQMNQQ - VMS Q MNGR ENQUEUE JOB ROUTINE'              00020000
IEFQMNQ2 CSECT                                                          00040000
*A 015900-015940                                                 S21774 00040421
*085000                                                          A39557 00042020
* 010200,013000,025800,026000,068400,069600,075200,083000        S20201 00050020
* 083700,083800                                                  S20201 00052020
*********************************************************************** 00060000
**                                                                   ** 00080000
**               MODULE IEFQMNQQ - VMS Q MNGR ENQUEUE JOB ROUTINE    ** 00100000
**                                                                   ** 00120000
*********************************************************************** 00140000
**  FUNCTION            - TO PUT A JOB ON A JOB QUEUE OR A SYSOUT    ** 00160000
**                        QUEUE AT THE PROPER PRIORITY               ** 00180000
**  INPUT               - THE ADDRESS OF A QUEUE MANAGER PARAMETER   ** 00200000
**                        AREA IN REGISTER ONE AND THE  ADDRESS OF A ** 00220000
**                        REGISTER SAVE AREA IN REGISTER THIRTEEN.   ** 00240000
**                        THE FIRST 20 BYTES OF THE PARAMETER AREA   ** 00260000
**                        SHOULD BE THE QUEUE ENTRY FOR THE JOB TO   ** 00280000
**                        BE PLACED ON THE QUEUE. THE PARAMETER AREA ** 00300000
**                        SHOULD ALSO CONTAIN THE ADDRESS OF AN      ** 00320000
**                        ECB/IOB AND THE ADDRESS OF AN EXTERNAL     ** 00340000
**                        PARAMETER AREA WHICH CONTAINS THE CORE     ** 00360000
**                        ADDRESS AND THE DISK ADDRESS OF THE JCT.   ** 00380000
**                       FOR TRACK STACKING THE QMPA ALSO            ** 00400015
**                        CONTAINS AN ADDR OF A WD WHICH CONTAINS IN ** 00420000
**                        (1) UPPER BYTE  -- NO. OF BUFFERS FOR      ** 00440000
**                             STACKING                              ** 00460000
**                        (2) NEXT 3 BYTES -- ADDR OF STACK. THIS IS ** 00480000
**                              ZERO IF NO STACK IS PRESENT.         ** 00500000
**  OUTPUT              - THE JOB WILL BE ON THE APPROPRIATE QUEUE   ** 00520000
**                        AND THE CORE FOR THE ECB/IOB WILL BE FREED ** 00540000
**  EXTERNAL REFERENCES - (1) ABSOLUTE LOCATION 16 TO OBTAIN THE     ** 00560000
**                        ADDRESS OF THE COMMUNICATIONS VECTOR TABLE ** 00580000
**                        (2) CVT+12 TO OBTAIN THE ADDRESS OF THE    ** 00600000
**                        QUEUE MANAGERS RESIDENT CORE               ** 00620000
**                        (3) CVT+28 TO OBTAIN THE ADDRESS OF THE    ** 00640000
**                        SUPERVISORS CONVERT ROUTINE                ** 00660000
**                       (4) WITH TRACK STACKING, THE RECORD ACCESSING  00680015
**                       PROGRAM IEFSD111 IS USED TO WRT OUT THE JCT IF 00700015
**                       A JOB IS BEING ENQUEUED ON ONE OF THE JOB(AS   00720015
**                       OPPOSED TO SYSOUT) QUEUES.                     00740015
**                       (5) ALSO IF TRACK STACKING IS SPECIFIED, AFTER 00760015
**                       WRITING THE JCT(IF NECESSARY) AND BEFORE DE-   00780015
**                       QUEUING FROM THE QUEUE MANAGER'S AREAS (QCRS)  00800015
**                       ON DISK, THE PURGE PROGRAM IEFSD112 IS CALLED  00820015
**                       AND THE STACK PURGED.                          00840015
**  EXITS               - RETURN IS MADE TO THE LINKOR VIA REGISTER  ** 00920000
**                        FOURTEEN                                   ** 00940000
**  ERROR CODES         - THE RETURN CODE IS CONTAINED IN REGISTER 15** 00960000
**                           (1) ZERO  NO ERROR (NORMAL RETURN)      ** 00980000
**                           (2) TWELVE = I/O ERROR                  ** 01000000
*  TABLES/WORK AREAS- 80 BYTES OF CORE IS GOTTEN FOR USE BY THIS S20201 01020020
**                        ROUTINE AND FREED BEFORE RETURNING TO THE  ** 01040000
**                        LINKOR.                                    ** 01060000
**                           *******************************         ** 01080000
**                           *                             *         ** 01100000
**                           *   36 BYTES FOR THE CONTROL  *         ** 01120000
**                           *       RECORD                *         ** 01140000
**                           *                             *         ** 01160000
**                           *******************************         ** 01180000
**                           *                             *         ** 01200000
**                           *  20 BYTES FOR A QUEUE ENTRY *         ** 01220000
**                           *                             *         ** 01240000
**                           *******************************         ** 01260000
**                           *                             *         ** 01280000
**                           *  24 BYTES FOR A SAVE AREA   *     S20201 01300020
**                           *                             *         ** 01320000
**                           *******************************         ** 01340000
**                        FOR TRACK STACKING, THIS PROGRAM USES THE  ** 01360000
**                        REGISTER IN WHICH THE SAVE REGISTER CON-   ** 01380000
**                        TENTS ARE SAVED TO INDICATE PRESENCE OF A  ** 01400000
**                        TRACK STACK AFTER THE INITIAL TEST FOR     ** 01420000
**                        TRACK STACKING IS MADE.                    ** 01440000
**  ATTRIBUTES          - THIS MODULE IS REENTERENT                  ** 01460000
*********************************************************************** 01480000
*047400-048000,098400                                            A23933 01490019
         SAVE  (14,12),T                SAVE USERS REGISTERS            01500000
         BALR  R8,0                     ESTABLISH ADDRESSABILITY FOR    01520000
*                                       THIS ROUTINE                    01540000
         USING *,R8                     DESIGNATE REGISTER 8 AS A BASE  01560000
*                                       REGISTER                        01580000
         B     QMENQ000                                          S21774 01590021
         DC    C'IEFQMNQQ'                                       S21774 01592021
QMENQ000 EQU   *                                                 S21774 01594021
         L     R3,QMENQE1               LOAD THE ADDRESS OF THE         01600000
*                                       COMMUNICATIONS VECTOR TABLE     01620000
         L     R3,QMENQE2(R3)           LOAD THE ADDRESS OF THE QUEUE   01640000
*                                       MANAGERS RESIDENT CORE          01660000
         LR    R4,R1                    SAVE THE ADDRESS OF THE QUEUE   01680000
*                                       MANAGERS PARAMETER AREA         01700000
         USING QMENQRES,R3              DESIGNATE REGISTER 3 AS THE     01720000
*                                       BASE REGISTER FOR QUEUE MANAGER 01740000
*                                       RESIDENT CORE (QMGR DCB,QMGR    01760000
*                                       DEB,AND THE MASTER HANDLE)      01780000
         USING IOPARAMS,R4              DESIGNATE REGISTER 4 AS THE     01800000
*                                       BASE REGISTER OF THE USERS      01820000
*                                       PARAMETER AREA                  01840000
         LA    R0,CORELG          LOAD LENGTH OF A QCR AND LTH   S20201 01844020
*                                 AND A 24 BYTE SAVE AREA        S20201 01848020
         GETMAIN R,LV=(0)              GET THE CORE              S20201 01852020
         LR    R9,R1                   SAVE ADDR OF CORE         S20201 01856020
         L     R2,QMEIA                 LOAD THE ADDRESS OF THE USERS   01860000
*                                       ECB/IOB                         01880000
         LR    R5,R13                   SAVE THE ADDRESS OF THE USERS   01900000
*                                       REGISTER SAVE AREA              01920000
         L     R6,QMCAP                 LOAD PTR TO STACK INFORMATION   01940000
         LTR   R6,R6                    IF IT IS 0, STACKING NOT RE-    01960000
         BC    8,QMENQ002                QUESTED.  BRANCH ARND          01980000
*                                                                       02000000
         L     R6,0(R6)                 LOAD ADDRESS OF STACK           02020000
         LA    R6,0(R6)                  (GET RID OF UPPER BYTE)        02040000
         LTR   R6,R6                    IF STACK PTR IS 0, NO STACK     02060000
         BC    8,QMENQ002                IS PRESENT.  PROCEED NORMALLY  02080000
*                                                                       02100000
         LCR   R5,R5                    INDICATE PRESENCE OF A STACK    02120000
*                                        BY TAKING COMPLMT OF SAVE REG  02140000
*                                                                       02160000
QMENQ002 L     R6,QMPCL                 LOAD THE ADDRESS OF THE USER'S  02180000
*                                       EXTERNAL PARAMETERS (CORE AND   02200000
*                                       DISK ADDRESSES OF THE JCT)      02220000
         LTR   R6,R6                    IS THERE A JCT TO BE WRITTEN    02240000
*                                       FOR THIS ENQUEUE                02260000
         BC    8,QMENQ010               BRANCH IF THERE IS NO JCT TO    02280000
*                                       BE WRITTEN                      02300000
         LTR   R5,R5                    IF CONT. OF SAVE REG IS POSIT., 02320000
         BP    QMENQ005                  NO STACKING.  BRANCH AROUND    02340000
*                                                                       02360000
         BAL   R7,QMENQ600              WITH PTR TO EXTERNAL PARAM AREA 02380000
*                                        IN REG 6, GO TO CALL REC ACC.  02400000
*                                        PGM TO WRITE JCT TO STACK      02420000
         B     QMENQ010                 BRANCH AROUND NORMAL WRITE      02440000
*                                                                     * 02460000
QMENQ005 L     R0,4(R6)                 LOAD THE TTR FOR THE JCT INTO   02480000
*                                       THE REGISTER USED BY THE        02500000
*                                       CONVERT ROUTINE                 02520000
         LR    R6,R9              SAVE ADDR OF GOTTEN CORE       S20201 02526020
         SR    R1,R1              MAKE SURE QCR REG IS 0         S20201 02532020
         BAL   R7,QMENQ070              LINK TO THE ROUTINE WHICH WILL  02540000
*                                       CONVERT THE TTR TO A MBBCCHHR   02560000
         L     R9,QMPCL           RESTORE EXTERNAL PARN ADDR     S20201 02580020
         L     R9,0(R9)           GET ADDR USER'S JCT OR SMB     S20201 02600020
         LA    R10,176                  LOAD THE LENGTH OF THE JCT      02620000
         BAL   R7,QMENQ100              LINK TO THE ROUTINE WHICH WILL  02640000
*                                       WRITE THE JCT ONTO DISK         02660000
         LR    R9,R6               RESTORE ADDR OF WORK AREA            02670020
QMENQ010 XR    R11,R11                  INITIALIZE THE REGISTER WILL    02680000
*                                       HOLD THE LOGICAL RECORD NUMBER  02700000
*                                       OF THE QUEUE CONTROL RECORD     02720000
         IC    R11,QMTPY                INSERT THE QUEUE TYPE FROM      02740000
*                                       WHICH THE JOB IS TO BE GOTTEN   02760000
         XR    R12,R12                  LOAD THE LOGICAL TRACK NUMBER   02780000
*                                       ON WHICH THE JOB QUEUE CONTROL  02800000
*                                       RECORDS START                   02820000
         LR    R6,R9                    SAVE ADDR OF GOTTEN CORE S20201 02830020
         LH    R9,QMHPT                 LOAD THE NUMBER OF JOB QUEUE    02840000
*                                       RECORDS PER PHYSICAL TRACK      02860000
         LR    R1,R9                    R1=NON-ZERO FOR QCR      S20201 02870020
         LA    R15,QMENQ070             LOAD REG TO CAUSE FURTHER CON-  02880000
*                                       VERSION AFTER TTR IS OBTAINED   02900000
         BAL   R7,QMENQ060              LINK TO THE ROUTINE WHICH WILL  02920000
*                                       CONVERT THE LOGICAL RECORD      02940000
*                                       NUMBER TO A MBBCCHHR            02960000
         LA    R10,QMENQE6              LOAD THE LENGTH OF THE QUEUE    03120000
*                                       CONTROL RECORD FOR THE READ     03140000
*                                       ROUTINE                         03160000
         ENQ   MF=(E,IEFQMNQA)               ENQUEUE ON RESOURCE        03180000
         LR    R9,R6              ADDR OF QCR AREA                      03200020
         BAL   R7,QMENQ110              LINK TO THE ROUTINE WHICH WILL  03220000
*                                       READ THE QUEUE CONTROL RECORD   03240000
         MVC   56(8,R6),36(R2)          SAVE THE MBBCCHHR FOR THE QUEUE 03260000
*                                       CONTROL RECORD                  03280000
         MVC   QCRSECT(C1,R6),SECT(R2)  SAVE SECTOR VALUE FOR    S20201 03286020
*                                       QUEUE CONTROL RECORD     S20201 03292020
         LA    R1,X'0F'                 LOAD THE MASK WHICH WILL BE     03300000
*                                       USED TO ZERO ALL BUT THE FOUR   03320000
*                                       PRIORITY BITS                   03340000
         IC    R13,QMPRI                PICK UP THE BYTE CONTAINING THE 03360000
*                                       PRIORITY FIELD                  03380000
         NR    R13,R1                   ZERO ALL BUT THE PRIORITY       03400000
         LCR   R12,R13                  COMPLEMENT THE PRIORITY (THIS   03420000
*                                       REGISTER WILL BE USED AS A      03440000
*                                       NEGATIVE OFFSET TO OBTAIN THE   03460000
*                                       PROPER SLOT IN THE JOB QUEUE    03480000
*                                       HANDLE FOR THIS PRIORITY)       03500000
         SLL   R12,1                    MULTIPLY BY TWO TO OBTAIN THE   03520000
*                                       PROPER NEGATIVE OFFSET          03540000
         LH    R14,QMTID                LOAD THE LOGICAL RECORD NUMBER  03560000
*                                       FOR THIS QUEUE ENTRY            03580000
         LH    R11,30(R9,R12)           LOAD THE LOGICAL RECORD NUMBER  03600000
*                                       OF THE QUEUE ENTRY FOR THE LAST 03620000
*                                       JOB IN THE CHAIN WITH THE SAME  03640000
*                                       PRIORITY AS THE PRESENT JOB     03660000
         STH   R14,30(R9,R12)           STORE THE LOGICAL RECORD NUMBER 03680000
*                                       OF THIS JOBS QUEUE ENTRY AS THE 03700000
*                                       LAST OF THE PRIORITY            03720000
         LTR   R11,R11                  IS THERE ANOTHER JOB WITH THE   03740000
*                                       PRESENT PRIORITY                03760000
         BC    7,QMENQ040               BRANCH IF THERE IS ANOTHER JOB  03780000
         IC    R1,32(R9)                PICK UP THE BYTE OF INFORMATION 03800000
*                                       FROM THE QUEUE CONTROL RECORD   03820000
*                                       WHICH INDICATES THE STATUS OF   03840000
*                                       THE QUEUE AND THE HIGHEST       03860000
*                                       PRIORITY JOB IN THE QUEUE       03880000
         LA    R7,X'F0'                 LOAD A MASK WHICH WILL PRESERVE 03900000
*                                       THE STATUS BITS AND ZERO THE    03920000
*                                       PRIORITY BITS                   03940000
         NR    R7,R1                    CREATE A FIELD WITH JUST THE    03960000
*                                       STATUS BITS                     03980000
         OR    R7,R13                   CREATE A BYTE OF INFORMATION    04000000
*                                       WITH THE STATUS BITS AND THIS   04020000
*                                       JOBS PRIORITY                   04040000
         CR    R1,R7                    DOES THIS JOB HAVE A PRIORITY   04060000
*                                       GREATER THAN THE TOP OF THE     04080000
*                                       QUEUE                           04100000
         BC    2,QMENQ020               BRANCH IF IT DOES NOT           04120000
         STC   R7,32(R9)                USE THE PRIORITY OF THIS JOB AS 04140000
*                                       THE HIGHEST PRIORITY IN THE     04160000
*                                       QUEUE                           04180000
         MVC   QMLNK(2),0(R9)           MOVE THE LOGICAL RECORD NUMBER  04200000
*                                       OF THE QUEUE ENTRY AT THE QUEUE 04220000
*                                       TO THE QUEUE ENTRY LINK FIELD   04240000
*                                       OF THE PRESENT JOB              04260000
         STH   R14,0(R9)                STORE THE LOGICAL RECORD NUMBER 04280000
*                                       OF THE PRESENT JOBS QUEUE ENTRY 04300000
*                                       INTO THE TOP OF THE QUEUE SLOT  04320000
         L     R7,32(R9)                LOAD THE LAST WORD OF THE       04340000
*                                       QUEUE CONTROL RECORD            04360000
         LTR   R7,R7                    IS THIS QUEUE BEING HELD        04380000
         BC    4,QMENQ050               BRANCH YES                      04400000
         XC    33(3,R9),33(R9)          ZERO THE POINTER TO THE NO WORK 04420000
*                                       QUEUE IF ANY                    04440000
QMENQ015 LA    R7,0(R7)                 CLEAR THE HIGH ORDER BYTE       04460000
         LTR   R7,R7                    ARE THERE ANY TASKS WAITING FOR 04480000
*                                       WORK                            04500000
         BC    8,QMENQ050               BRANCH NO                       04520000
         LR    R1,R7                    LOAD THE ADDRESS OF THE ECB     04540000
         POST  (1)                      POST THE TASK                   04560000
         L     R7,4(R7)                 LOAD THE ADDRESS OF THE NEXT    04580000
*                                       TASKS EIGHT BYTE CONTROL AREA   04600000
         BC    15,QMENQ015              BRANCH TO TEST IF THERE IS      04620000
*                                       ANOTHER TASK WAITING            04640000
QMENQ020 L     R14,QMENQK2              LOAD REGISTER 14 WITH THE       04660000
*                                       NEGATIVE INCREMENT BETWEEN      04680000
*                                       PRIORITY ENTRIES IN THE QUEUE   04700000
*                                       CONTROL RECORD                  04720000
QMENQ030 EQU   *                                                 A23933 04740019
         AR    R12,R14                 ADD NEG INCREMENT TO NEG  A23933 04760019
*                                      OFFSET FOR NEXT PRIORITY  A23933 04780019
         LH    R11,30(R9,R12)           LOAD THE LOGICAL RECORD NUMBER  04820000
*                                       FOR THE LAST QUEUE ENTRY IN     04840000
*                                       THE PRIORITY SLOT               04860000
         LTR   R11,R11                  IS THERE A JOB WITH THIS        04880000
*                                       PRIORITY                        04900000
         BC    8,QMENQ030               BRANCH NO TO PICK UP THE NEXT   04920000
*                                       PRIORITY                        04940000
QMENQ040 LA    R15,QMENQ070             LOAD REG FOR FULL CONVERT       04960000
         BAL   R7,QMENQ080              GO TO CONVERT THE QUEUE         04980000
*                                       ENTRY LOGICAL RECORD NUMBER     05000000
*                                       INTO A MBBCCHHR                 05020000
         LA    R9,36(R6)                LOAD THE ADDRESS OF THE CORE TO 05040000
*                                       BE USED FOR THE QUEUE ENTRY     05060000
         LA    R10,20                   LOAD THE LENGTH OF THE QUEUE    05080000
*                                       ENTRY                           05100000
         BAL   R7,QMENQ110              LINK TO THE ROUTINE WHICH WILL  05120000
*                                       READ IN THE QUEUE ENTRY         05140000
         MVC   QMLNK(2),QMLNK-QMCAN(R9)   MOVE THE LINK NN OF THE QUEUE 05160000
*                                       ENTRY JUST READ TO THE QUEUE    05180000
*                                       ENTRY OF THE PRESENT JOB        05200000
         MVC   QMLNK-QMCAN(2,R9),QMTID    MOVE THE NN OF THE NEW QUEUE  05220000
*                                       ENTRY INTO THE LINK FIELD OF    05240000
*                                       THE QUEUE ENTRY JUST READ       05260000
         XC    QMTLN(2),QMTLN           ZERO NEXT LTRK PNTR IN NEW      05280000
*                                            QUEUE ENTRY                05300000
         MVC   64(8,R6),36(R2)          SAVE THE MBBCCHHR FOR THE QUEUE 05320000
         MVC   LTHSECT(C1,R6),SECT(R2)  SAVE THE SECTOR VALUE    S20201 05326020
*                                       FOR THE LTH              S20201 05332020
*                                       ENTRY                           05340000
QMENQ050 LTR   R5,R5               CHECK FOR TRACK STACKING             05370015
         BP    QMENQS50            IF NOT , GO TO WRITE OUT NEW Q ENTRY 05400015
*********************************************************************** 05430015
** WHEN TRACK STACKING HAS BEEN SPECIFIED THE STACK MUST BE PURGED   ** 05460015
** BEFORE DEQ'ING OFF THE QCRS RESOURCE                              ** 05490015
*********************************************************************** 05520015
         L     R13,QMCAP           GET STACK INFO PTR                   05550015
         L     R13,0(R13)          GET STACK                            05580015
         LA    R13,0(R13)                    ADDRESS                    05610015
         LR    R1,R4               GET QMPA PTR IN PARAM REG            05640015
         L     R15,QMENQSTP        GET ADDR OF PURGE ROUTINE IEFSD112   05670015
         BALR  R14,R15             PURGE AND FREE STACK                 05700015
         LPR   R5,R5               ON RETURN INDICATE ABSENCE OF STACK  05730015
*                                  BY RE-COMPLEMENTING R5(SAVE REG)     05760015
         LR    R7,R15              SAVE RETURN CODE                     05790015
         LR    R1,R13              GET ADDR OF RETURNED SAVE AREA       05820015
         FREEMAIN R,LV=72,A=(1)    FREE SAVE AREA                       05850015
         LTR   R7,R7               CHECK RETURN CODE FROM PURGE RTN     05880015
         BC    8,QMENQS50          ON NORMAL RETURN(ZERO) GO TO WRITE   05910015
*                                  OUT NEW QUEUE ENTRY                  05940015
         ST    R7,16(R5)           STORE ABNORMAL RETURN CODE           05970015
         B     QMENQ054            EXIT                                 06000015
*                                                                       06030015
*                                                                       06060015
QMENQS50 LH    R11,QMTID           GET NN OF NEW QUEUE ENTRY            06090015
         CLI   QMDPI,0                  WILL DISPATCHING PRIORITY       06093017
*                                       DIFFER FROM SCHEDULING          06096017
         BE    QMENQS51                 NO - DONT CHANGE                06099017
         XI    QMDPI,X'80'              UNSET CHANGE INDICATOR          06102017
         MVC   QMPRI(1),QMDPI           INSERT DISPATCHING PRIORITY     06105017
         XC    QMDPI(1),QMDPI           ZERO PRIORITY CHANGE BYTE       06108017
QMENQS51 EQU   *                                                        06111017
         LA    R15,QMENQ070        LOAD REG TO EFFECT COMPLETE          06120015
*                                  CONVERSION TO MBBCCHHR               06150015
         BAL   R7,QMENQ080         LINK TO RTN WHICH WILL CONVERT NN    06180015
         OI    QMSTA,X'04'         SET INITIATOR BIT IN THE STATUS      06210015
*                                  BYTE OF THE NEW QUEUE ENTRY          06240015
         MVC   QMPOP,QMOSC         MOVE INTO QMPOP (A FIELD THAT IS     06243015
*                                    MEANINGLESS FOR AN ENQUEUED JOB)   06246015
*                                    THE ORIGINAL STEP CLASS NAME       06249015
*                                    OR, FOR A JOB TO BE PUT INTO THE   06252015
*                                    HOLD Q BECAUSE OF TYPRUN=HOLD,     06255015
*                                    THE NAME OF ITS JOB CLASS,         06258015
*                                    TO BE USED FOR THE RELEASE OF      06261015
*                                    THE JOB TO ITS PROPER CLASS.       06264015
         XC    QMTLN(2),QMTLN      ZERO NEXT LOG TRK PTR IN Q ENTRY     06270015
         LR    R9,R4               LOAD CORE ADDR OF NEW QUEUE ENTRY    06300015
         LA    R10,20              LOAD LENGTH OF QUEUE ENTRY           06330015
*                                                                       06360015
         BAL   R7,QMENQ100              LINK TO THE ROUTINE WHICH WILL  06400000
*                                       WRITE THE NEW QUEUE ENTRY       06420000
QMENQS57 CLC   QMTID(2),0(R6)           IS THERE ANOTHER QUEUE ENTRY    06440000
*                                       TO BE WRITTEN                   06460000
         BC    8,QMENQ052               BRANCH NO                       06480000
         MVC   36(8,R2),64(R6)          RESTORE THE MBBCCHHR FOR THE    06500000
*                                       QUEUE ENTRY                     06520000
         MVC   SECT(C1,R2),LTHSECT(R6)  RESTORE THE SECTOR VALUE S20201 06530020
         LA    R9,36(R6)                LOAD THE CORE ADDRESS OF THE    06540000
*                                       QUEUE ENTRY                     06560000
         BAL   R7,QMENQ100              LINK TO THE ROUTINE WHICH WILL  06580000
*                                       WRITE THE OLD QUEUE ENTRY       06600000
QMENQ052 MVC   36(8,R2),56(R6)          RESTORE THE MBBCCHHR FOR THE    06620000
*                                       QUEUE CONTROL RECORD            06640000
         MVC   SECT(C1,R2),QCRSECT(R6)  RESTORE THE SECTOR VALUE S20201 06650020
         LR    R9,R6                    LOAD THE CORE ADDRESS OF THE    06660000
*                                       QUEUE CONTROL RECORD            06680000
         LA    R10,36                   LOAD THE LENGTH OF THE QUEUE    06700000
*                                       CONTROL RECORD                  06720000
         BAL   R7,QMENQ100              LINK TO THE ROUTINE WHICH WILL  06740000
*                                       WRITE THE QUEUE CONTROL RECORD  06760000
         XC    16(4,R5),16(R5)          SET UP NORMAL RETURN CODE       06780000
QMENQ054 EQU   *                             IEFQMNQ2                   06800000
         DEQ   MF=(E,IEFQMNQA)               DEQUEUE OFF RESOURCE       06820000
QMENQ056 EQU   *                                                 S20201 06830020
         LA    R0,CORELG          LOAD THE LENGTH OF THE WORK    S20201 06840020
*                                       AREA                            06860000
*                                       FOR THE CONTROL RECORD AND THE  06880000
*                                       QUEUE ENTRY                     06900000
         LR    R1,R6                    LOAD THE ADDRESS OF THIS CORE   06920000
         FREEMAIN R,LV=(0),A=(1)        FREE THE CORE                   06940000
         LR    R1,R2              LOAD THE ADDR OF THE ECB/IOB   S20201 06960120
         A     R1,QMENQK4               DECREMENT ADDRESS TO THE ADDR.  06980000
*                                       OF THE LENGTH FIELD             07000000
         L     R0,0(R1)                 PICK UP THE LENGTH OF CORE TO   07020000
*                                       BE FREED                        07040000
         FREEMAIN R,LV=(0),A=(1)        FREE ECB/IOB                    07060000
         LPR   R13,R5                   RESTORE USER'S REGISTERS        07080000
         LM    R14,R12,12(R13)          LOAD THE USERS REGISTERS        07100000
         RETURN RC=(15)                 RETURN TO THE USER              07120000
QMENQ060 XR    R10,R10                  ZERO REGISTER TO BE USED IN THE 07140000
*                                       DIVIDE                          07160000
         DR    R10,R9                   DIVIDE THE LOGICAL RECORD NO.   07180000
*                                       BY THE NUMBER OF RECORDS PER    07200000
*                                       PHYSICAL TRACK (THE QUOTIENT    07220000
*                                       WILL BE THE THE LOGICAL TRACK   07240000
*                                       NUMBER-TT AND THE REMAINDER     07260000
*                                       IS THE NUMBER OF THE RECORD ON  07280000
*                                       THE TRACK MINUS ONE-R-1)        07300000
         AR    R11,R12                  ADJUST THE TT JUST CALCULATED   07320000
*                                       TO REFLECT A TRUE TT FROM THE   07340000
*                                       BEGINNING OF THE QUEUE MANAGERS 07360000
*                                       EXTENT                          07380000
         SLL   R11,8                    ADJUST THE POSITION OF THE TT   07400000
*                                       TO ENABLE A TTR TO BE FORMED    07420000
         LA    R0,1(R10,R11)            FORM A TTR BY ADDING ONE TO R-1 07440000
*                                       AND COMBINING THE TT AND THE R. 07460000
QMENQ065 SLL   R0,8                     LEFT JUSTIFY THE TTR            07480000
         BR    R15                      CONTINUE OR RETURN WITH TTR     07500000
QMENQ070 EQU   *                                                 S20201 07501020
         TM    QMRPS,RPSON              TEST FOR RPS DEVICE      S20201 07502020
         BNO   QMENQ075                 NO,NORMAL CONVERT        S20201 07503020
         ST    R0,TTRSAVE(R6)       SAVE TTR IN WORK AREA        S20201 07504020
         LTR   R1,R1                    TEST FOR QCR- IF 15,NO   S20201 07505020
         BNZ   QMENQ072                 NEED FOR VARIABLE RECORD S20201 07506020
*                                       LENGTH CONVERT ROUTINES  S20201 07507020
         L     R15,CVTPTR               GET CVT ADDRESS          S20201 07508020
         USING COMMVECT,R15             ADDRESS OF VARIABLE LENG S20201 07509020
         L     R15,CVT0SCR1             CONVERT RTN              S20201 07510020
         DROP  R15                      ADDR OF Q MNGR CONVERT   S20201 07511020
         L     R15,4(R15)               ROUTINE -  FOR # BYTES   S20201 07512020
         BALR  R14,R15                  GET # PRECEEDING BYTES   S20201 07513020
*                                       (RETURNED IN REG 0 )     S20201 07514020
QMENQ071 EQU   *                                                 S20201 07515020
         L     R15,CVTPTR               GET ADDR OF ROUTINE TO   S20201 07516020
         USING COMMVECT,R15             CONVERT # BYTES          S20201 07517020
         L     R15,CVT0SCR1             PRECEEDING RECORD TO A   S20201 07518020
         DROP  R15                      SECTOR VALUE             S20201 07519020
         L     R11,QMEIA                GET ECB/10B ADDRESS      S20201 07520120
         LA    R11,SECT(R11)            ADDR WHERE TO SAVE       S20201 07521020
         SLL   R11,8                    SECTOR, LEFT JUSTIFIED   S20201 07522020
         LH    R10,QMRPS                DEVICE TYPE CODE + ADDR  S20201 07523020
         SRDL  R10,8                    SECTOR SAVE  INTO PARM   S20201 07524020
         LR    R2,R11                   REGISTER(2)              S20201 07525020
         BALR  R14,R15                  GET SECTOR VALUE         S20201 07526020
         L     R2,QMEIA                 RESTORE  ECB/IOB         S20201 07527020
         L     R0,TTRSAVE(R6)           RESTORE TTR              S20201 07528020
         B     QMENQ075                 GO TO MBBCCHHR CONVERT   S20201 07529020
QMENQ072 EQU   *                                                 S20201 07530020
         SRDL  R0,16                    GET REC #  IN REG ONE    S20201 07531020
         LA    R0,QCRLH                 GET LENGTH OF QCR        S20201 07532020
         SLL   R0,8                     0-QCRLG-0  IN REG 0      S20201 07533020
         SRDL  R0,24                    R1 HAS QCRLG-0-R  FOR    S20201 07534020
         LR    R0,R1                    CONVERT.PUT INTO PARM REGS20201 07535020
         B     QMENQ071                                          S20201 07536020
QMENQ075 EQU   *                                                 S20201 07537020
         LA    R2,QMENQE3(R2)           ADJUST ADDR OF  THE ECB/ S20201 07538020
*                                       IOB TO OBTAIN THE ADDRESS OF    07540000
*                                       THE EIGHT BYTE AREA INTO WHICH  07560000
*                                       THE MBBCCHHR WILL BE PLACED     07580000
         LA    R1,QMENQE4(R3)           LOAD THE ADDRESS OF THE DATA    07600000
*                                       EXTENT BLOCK                    07620000
         L     R15,QMENQE1              LOAD THE ADDRESS OF THE         07640000
*                                       COMMUNICATIONS VECTOR TABLE     07660000
         L     R15,QMENQE5(R15)         LOAD THE ADDRESS OF THE         07680000
*                                       SUPERVISOR CONVERT ROUTINE      07700000
         BALR  R14,R15                  LINK TO THIS ROUTINE TO CONVERT 07720000
*                                       THE TTR TO A MBBCCHHR.          07740000
         S     R2,QMENQK1               RESTORE THE ADDRESS OF THE      07760000
*                                       ECB/IOB                         07780000
         BCR   15,R7                                                    07800000
QMENQ080 LH    R12,QMKTT                LOAD THE TT OF THE FIRST TRACK  07820000
*                                       CONTAINING ONLY JOB QUEUE       07840000
*                                       ENTRIES                         07860000
         SR    R1,R1                    ZERO QCR INDICATOR REG   S20201 07866020
*                                       FOR  LATER  TEST         S20201 07872020
         SH    R11,QMFQR                SUBTRACT THE NN OF THE FIRST    07880000
*                                       RECORD ON THE TRACK CONTAINING  07900000
*                                       ONLY JOB QUEUE ENTRIES          07920000
         BC    4,QMENQ090               BRANCH IF THE PRESENT NN IS     07940000
*                                       LESS (RECORD IS ON THE MIXED    07960000
*                                       TRACK)                          07980000
         LH    R9,QMRPT                 LOAD THE NUMBER OF JOB QUEUE    08000000
*                                       ENTRIES ON A PHYSICAL TRACK     08020000
         BC    15,QMENQ060              LINK TO THE ROUTINE WHICH WILL  08040000
*                                       CONVERT THE LOGICAL RECORD      08060000
*                                       NUMBER TO A MBBCCHHR            08080000
QMENQ090 AH    R11,QMFQR                RESTORE THE ORIGINAL NN         08100000
         AH    R11,QMNHM                ADD THE NUMBER OF QUEUE CONTROL 08120000
*                                       RECORDS ON THE MIXED TRACK      08140000
         BCTR  R12,0                    SUBTRACT ONE FROM TT TO GET THE 08160000
*                                       TT OF THE MIXED TRACK           08180000
         SLL   R12,8                    REPOSITION THE TT TO ALLOW THE  08200000
*                                       RECORD NUMBER TO BE ADDED       08220000
         LA    R0,0(R12,R11)            FORM THE TTR IN REGISTER ZERO   08240000
         BC    15,QMENQ065              LINK TO THE ROUTINE WHICH WILL  08260000
*                                       CONVERT THE TTR TO A MBBCCHHR   08280000
QMENQ100 EQU   *                                                 S20201 08290020
         LA    R11,SECT(R2)                                      S20201 08300120
         XDAP  (2),WI,(3),(9),(10),,,(11),MF=E                   S20201 08310020
         BC    15,QMENQ120              BRANCH TO AWAIT COMPLETION OF   08320000
*                                       THE OPERATION AND TEST FOR      08340000
*                                       ANY ERRORS                      08360000
QMENQ110 EQU   *                                                 S20201 08370020
         LA    R11,SECT(R2)                                      S20201 08380120
         XDAP  (2),RI,(3),(9),(10),,,(11),MF=E                   S20201 08390020
QMENQ120 LR    R1,R2                    LOAD THE ADDRESS OO THE ECB/IOB 08400000
         WAIT  1,ECB=(1)                WAIT FOR THE READ/WRITE         08420000
         CLI   0(R2),X'7F'              WAS AN ERROR ENCOUNTED IN THE   08440000
*                                       OPERATION                       08460000
         BCR   8,R7                     RETURN IF THERE WAS NO ERROR    08480000
         LA    R13,12                   SET UP AN ERROR RETURN CODE     08500000
         LPR   R5,R5                    CORRECT SA PTR, IF NEG   A39557 08510020
         ST    R13,16(R5)                                               08520000
         C     R10,QMENQK5              WAS THE ERROR ENCOUNTED WHOLE   08540000
*                                       WRITING THE JCT                 08560000
         BC    8,QMENQ056               BRANCH YES                      08580000
         BC     15,QMENQ054             BRANCH NO                       08600000
*                                                                       08620000
*********************************************************************** 08640000
** THE FOLLOWING SECTION IS USED FOR WRITING A JCT WITH TRACK STACK- ** 08660015
**ING. THE INTERFACE TO THE RECORD ACCESSING PROGRAM IEFSD111 IS AS  ** 08680015
**FOLLOWS -                                                          ** 08700015
**                                                                   ** 08720015
**             REGISTER 13 - ADDR OF STACK(COMMON SAVE AREA)         ** 08740015
**             REGISTER 1  - ADDR OF QUEUE MANAGER PARAMETER AREA    ** 08760015
**             WHICH CONTAINS THE FOLLOWING -                        ** 08780015
**                                                                   ** 08800015
**             (1) A WRT CODE OF X'02' AT DISP +8 (QMPOP)            ** 08820015
**             (2) AT DISP +24 A FULL WORD PTR TO A WORD WHICH CON-  ** 08840015
**             TAINS IN THE HIGH ORDER BYTE THE NO. OF BUFFERS IN THE** 08860015
**             STACK AND IN THE LOW ORDER 3 BYTES THE ADDR OF THE    ** 08880015
**             STACK                                                 ** 08900015
**             (3) AT DISP +28 A FULL WORD PTR TO AN ECB/IOB         ** 08920015
**             (4) AT DISP +33 A 3 BYTE PTR TO AN 8 BYTE ELEMENT, THE** 08940015
**             FIRST 4 BYTES OF WHICH CONTAIN  A PTR TO THE AREA FROM** 08960015
**             WHICH THE RECORD IS TO BE WRITTEN, THE NEXT 3 BYTES OF** 08980015
**             WHICH CONTAIN THE TTR OF THE RECORD, AND THE LAST BYTE** 09000015
**             OF WHICH IS 0,                                        ** 09020015
**                                                                   ** 09040015
**                                                                   ** 09060015
*********************************************************************** 09080015
*                                                                       09100015
*                                                                       09120015
*                                                                       09140015
QMENQ600 L     R13,QMCAP           GET TRACK STACKING INFO PTR          09160015
         L     R13,0(R13)          GET STACK                            09180015
         LA    R13,0(R13)                    ADDRESS                    09200015
         IC    R10,QMPOP           SAVE FUNCTION CODE                   09220015
         MVI   QMPOP,X'02'         PUT IN 'WRITE' CODE CALL OTHER PTRS  09240015
*                                  REQUIRED IN THE QMPA ARE PROVIDED BY 09260015
*                                  THE USER OF THE ENQUEUE ROUTINE      09280015
         LR    R1,R4               GET PTR TO QMPA IN PARAMETER REG     09300015
         L     R15,QMENQRAP        GET ADDR OF RECORD ACCESSING PROGRAM 09320015
*                                  IEFSD111                             09340015
         BALR  R14,R15             GO TO 'WRITE' JCT                    09360015
         STC   R10,QMPOP           RESTORE FUNCTION CODE                09380015
         LTR   R15,R15             CHECK RETURN CODE                    09400015
         BCR   8,R7                RETURN TO MAIN LINE ON NORMAL (0)    09420015
*                                  RETURN CODE                          09440015
         LPR   R5,R5               RESET R5 TO POSITIVE                 09460015
         ST    R15,16(R5)          STORE ERROR RETURN CODE              09480015
         LCR   R5,R5               RESET R5 TO NEG TO INDICATE PRESENCE 09500015
*                                  OF STACK                             09520015
         B     QMENQ056            GO TO FREE CORE FOR USER'S ECB/IOB   09540015
*                                  AND EXIT                             09560015
*                                                                       09660000
QMENQRAP DC    V(IEFSD111)              ADDR OF STACK REC ACC PGM       09680000
QMENQSTP DC    V(IEFSD112)              ADDR OF STACK PURGE PGM         09700000
QMENQ699 DC    X'80000000'              MASK TO INDICATE WR TO ACC PGM  09720000
********************************************************************    09736020
CORELG   EQU   80                  WORK AREA  LENGTH             S20201 09746020
QCRSECT  EQU   73                 WORKAREA OFFSET FOR QCR SECTOR S20201 09756020
LTHSECT  EQU   74                 WORKAREA OFFSET FOR LTH SECTOR S20201 09766020
TTRSAVE  EQU   76                 OFFSET IN WORKAREA FOR TTR     S20201 09776020
C1       EQU   1                   LENGTH FOR  SECTOR BYTE MOVE  S20201 09786020
RPSON    EQU   X'10'               RPS INDICATOR                 S20201 09796020
SECT     EQU   X'4C'              SECTOR VALUE AREA 10B OFFSET   S20201 09806020
QCRLH    EQU   36                 LENGTH OF QUEUE CONTROL RECORD S20201 09816020
QMENQE1  EQU   16                                                       09860000
QMENQE2  EQU   12                                                       09880000
QMENQE3  EQU   36                                                       09900000
QMENQE4  EQU   52                                                       09920000
QMENQE5  EQU   28                                                       09940000
QMENQE6  EQU   36                                                       09960000
QMENQK1  DC    F'36'                                                    09980000
QMENQK2  DC    F'-2'                                                    10000000
QMENQK3  DC    F'-30'                                                   10020000
QMENQK4  DC    F'-4'                                                    10040000
QMENQK5  DC    F'176'                                                   10060000
*********************************************************************** 10080000
*          ENQ/DEQ MACRO PARAMETER LIST                               * 10100000
*********************************************************************** 10120000
IEFQMNQA ENQ   (IEFSQCBS,IEFQ1QCB,E,2,SYSTEM),MF=L    ENQ/DEQ PARM LIST 10140000
IEFSQCBS DC    C'SYSIEFSD'              MAJOR NAME                      10160000
IEFQ1QCB DC    C'Q1'                    MINOR NAME ENQ/DEQ Q MNGR       10180000
*********************************************************************** 10200000
**               EQUATES FOR THE GENERAL REGISTERS                   ** 10220000
*********************************************************************** 10240000
R0       EQU   0                                                        10260000
R1       EQU   1                                                        10280000
R2       EQU   2                                                        10300000
R3       EQU   3                                                        10320000
R4       EQU   4                                                        10340000
R5       EQU   5                                                        10360000
R6       EQU   6                                                        10380000
R7       EQU   7                                                        10400000
R8       EQU   8                                                        10420000
R9       EQU   9                                                        10440000
R10      EQU   10                                                       10460000
R11      EQU   11                                                       10480000
R12      EQU   12                                                       10500000
R13      EQU   13                                                       10520000
R14      EQU   14                                                       10540000
R15      EQU   15                                                       10560000
         TITLE 'Q MNGR RESIDENT CORE AREA DEFINITIONS'                  10580000
QMENQRES DSECT                                                          10600000
         IEFQMRES                                                       10620000
         TITLE 'Q MNGR PARAMETER AREA DEFINITIONS'                      10640000
         IEFQMNGR                                                       10660000
QMCAP    EQU   IOPARAMS+24              PTR TO STACK AND Q BREAK INFO   10680000
QMOSC    EQU   QMTID+2                  1-BYTE FIELD FOR 'REMEMBERING'  10686015
*                                        OLD STEP CLASS OR JOB CLASS    10692015
QMDPI    EQU   QMTID+3                                                  10696017
COMMVECT DSECT                                                   S20201 10696520
         CVT                                                     S20201 10697020
         EJECT                                                          10700000
         END                                                            11000000
