         TITLE 'IEFRAPCP - RESTART ACTIVATION FOR PCP.'                 12400017
IEFRAPCP CSECT                                                          12420018
*2866002000-122000,214000,218000,250000,276000,302000,308000            12440018
*    312000-322000,340000-342000,354000-362000,366000,388000,392000     12460018
*    398000,402000,410000,420000,430000-432000,438000,448000-454000     12480018
*    458000,463200,464000,472000,476000,494000-496000,510000,518000     12500018
*    522000,526000-528000,536000,542000-546000,554000-556000            12520018
*    570000,576000,580000,584000-586000,590000-592000,596000-598000     12540018
*    602000-604000,612000,634000,644000,652000,664000,674000,698000     12560018
*    704000,714000,720000-722000,734000-736000,752000-754000,760000     12580018
*********************************************************************** 12600017
*                                                                     * 12800017
* FUNCTION - ACTIVATE A RESTART IN PCP BY -                           * 13000017
*                                                                     * 13200017
*               1. INSURING PRESENCE OF JOB IN READER.                * 13400017
*               2. ENQUEUING A PSEUDO-STEP FOR INTRA-STEP RESTART.    * 13600017
*               3. PREPARING JCT FOR RESTART.                         * 13800017
*               4. PROVIDING FOR A SECOND Q.                          * 14000017
*                                                                     * 14200017
* ENTRY - IEFRAPCP FROM IEFK3.                                        * 14400017
*                                                                     * 14600017
* INPUT - Q FOR ABENDING JOB.                                         * 14800017
*                                                                     * 15000017
* OUTPUT - JCT, R/I PARAMETERS.                                       * 15200017
*                                                                     * 15400017
* EXTERNAL ROUTINES - IEFQMSSS -- QUEUE MANAGER.                      * 15600017
*                     IEFSD006 -- TTR CONVERTER.                      * 15800017
*                                                                     * 16000017
* EXIT - RETURN.                                                      * 16200017
*                                                                     * 16400017
* TABLES - JCT,SCT,MRC,SIOT,JFCB,UCB,UCB VECTOR TABLE,CVT,QMPA,IEFJOB,* 16600017
*              IEFSD005.                                              * 16800017
*                                                                     * 17000017
* ATTRIBUTES - RE-ENTRANT.                                            * 17200017
*                                                                     * 17400017
* NOTES - ISSUES WTO FOR URE READER.                                  * 17600017
*                                                                     * 17800017
*********************************************************************** 18000017
R0       EQU   0                   USED FOR FOMING ADDRESSES TO BE STRD 18200017
R1       EQU   1                   USED FOR Q MANAGER PARM AREA POINTER 18400017
R2       EQU   2                   USED FOR UCB ADDR TABLE AND MSLT     18600017
R3       EQU   3                   USED FOR UCB                         18800017
R4       EQU   4                   USED FOR CVT                         19000017
R5       EQU   5                                                        19200017
R6       EQU   6                   USED FOR IEFJOB                      19400017
R7       EQU   7                                                        19600017
R8       EQU   8                                                        19800017
R9       EQU   9                                                        20000017
RA       EQU   10                  USED FOR RESTART WORK AREA           20200017
RB       EQU   11                                                       20400017
RC       EQU   12                  USED FOR BASE REGISTER               20600017
RD       EQU   13                  USED FOR REGISTER SAVE AREA          20800017
RE       EQU   14                  RETURN REGISTER                      21000017
RF       EQU   15                  USED FOR ADDRESS OF Q MANAGER        21200017
         SAVE  (14,12)             SAVE REGISTERS                       21600017
         BALR  RC,ZERO             SET BASE REGISTER                    21800018
         USING *,RC                                                     22000017
         LR    R2,R1               SAVE PARM REG                        22200017
       IEFSAVER                                                         22400017
         LR    R1,R2               RELOAD PARM REG                      22600017
         SPACE 1                                                        22650018
*  THE FOLLOWING CODE SEARCHES THE UCB'S FOR THE SYSIN DEVICE.          22700018
  SPACE 1                                                               22750018
         L     R4,CVTPTR           LOAD CVT ADDR                        22800017
         USING CVT,R4                                                   23000017
         L     R2,CVTILK2          LOAD ADDRESS OF UCB VEC TABLE        23200017
         USING UCBVECT,R2                                               23400017
RA0002   LH    R3,UCBVEC           GET UCB ADDR                         23600017
         N     R3,MASK             MASK HI- ORDER BITS OFF              23800017
         BZ    RA0005              LOOP IF ZERO                         24000017
         USING UCBOB,R3                                                 24200017
         TM    UCBWGT,SRTSYSIN     Q. SYSIN UCB                         24400017
         BO    RA0010              BR- YES                              24600017
RA0005   LA    R2,L'UCBVEC(R2)     INC TO NEXT UCB ADDR                 24800017
         B     RA0002              CONTINUE SEARCH FOR SYSIN UCB        24900018
   SPACE 1                                                              25000018
RA0010   EQU   *                                                        25200017
         DROP  R2                                                       25400017
         LA    R0,LRESTWA                                               25600017
         GETMAIN R,LV=(0)          GET MAIN STORAGE SPACE FOR REST WA   25800017
         LR    RA,R1                                                    26000017
         USING RESTWA,RA                                                26200017
*        SET UP Q MANAGER INTERFACES                                    26400017
         LA    R0,JCTR             MOVE ADDRESS OF JCT TO Q MGR EXT PRM 26600017
         ST    R0,QMADDR           STORE ADDRESS OF JCT                 26800017
         LA    R0,QMEXTPAR         SET ADDR OF Q MGR EXTERNAL PARMS     27000017
         USING IOPARAMS+RESTWA-QMPAR,RA                                 27200017
         ST    R0,QMPCM                                                 27400017
         MVI   QMPNC,ONE           INDICATE 1 RECORD                    27600018
*        READ IN JCT                                                    27800017
         MVI   QMPOP,QMREAD        DENOTE READ TO BE DONE               28000017
         LA    R1,SDJCT                                                 28200017
         L     RF,IEFSD006         LOAD TTR CONVERT RTN ADDR.           28400017
         USING RESTWA,RA                                                28600017
         BALR  RE,RF               CALL TTR CONVERT ROUTINE             28800017
         ST    R1,QMTTR                                                 29000017
         ST    R1,SAVJCTDA         SAVE JCT TTR FOR PARM FIELD          29200017
         L     RF,IEFQMSSS         LOAD Q-MAN ADDR.                     29400017
         LA    R1,QMPAR            LOAD ADDRESS OF Q MGR PARM AREA      29600017
         BALR  RE,RF               CALL QUEUE MANAGER                   29800017
         USING JCTD+RESTWA-JCTR,RA  USE REG AT RESTWA FOR JCT           30000017
   MVC RJOBNAME-RESTWA(L'JCTJNAME,RA),JCTJNAME  MOVE IN JOB NAME        30200018
         TM    UCBTBYT3,UCB3TAPE   Q. SYSIN ON TAPE                     30400017
         BO    RA0030              BR - YES                             30600017
   SPACE 1                                                              30650018
*  THE FOLLOWING CODE BUILDS A WTO MESSAGE, THE MESSAGE INFORMS THE     30700018
* OPERATOR TO REPOSITION THE JOB TO BE RESTARTED IN THE SYSIN           30750018
*  DEVICE, SO THAT THE JOB MAY BE RE-READ FOR THE RESTART.              30800018
   SPACE 1                                                              30850018
   LA R0,L'RAMSG1+L'RAMSG2+L'JCTJNAME+L'UCBNAME+FOUR  LOAD LENGTH       30900018
         GETMAIN R,LV=(0)          GET SPACE FOR WTO FOR RESTART        31000017
   MVC FOUR(L'RAMSG1,R1),RAMSG1  MOVE MESSAGE TO GOTTEN STORAGE         31100018
   MVC FOUR+L'RAMSG1(L'JCTJNAME,R1),JCTJNAME  MOVE JOBNAME              31200018
   MVC FOUR+L'RAMSG1+L'JCTJNAME(L'RAMSG2,R1),RAMSG2  2ND PART (MSG)     31300018
   MVC FOUR+L'RAMSG1+L'JCTJNAME+L'RAMSG2(L'UCBNAME,R1),UCBNAME          31400018
*                                  INSERT DEVICE NAME                   31500018
         STH   R0,ZERO(R1)         STORE LENGTH OV MESSAGE              31600018
         XC    TWO(TWO,R1),TWO(R1)  ZERO TWO BYTES FOR WTO              31700018
         LR    R2,R1               SAVE GOTTEN CORE ADDR                32400017
         LR    R5,R0               SAVE LENGTH VALUE                    32600017
         WTO   ,MF=(E,(1))         WRITE MESSAGE                        32800017
         LR    R1,R2               RESET GOTTEN CORE ADDR               33000017
         LR    R0,R5               RESET LENGTH OF GOTTEN CORE          33200017
         FREEMAIN R,LV=(0),A=(1)   FREE AREA OF MESSAGE                 33400017
RA0030   EQU   *                   TEST FOR STEP OR INTRA-STEP RESTART  33600017
*        SAVE SCT TTR FROM JCTSSTR AT RSTEPNAM                          33800017
         MVC   RSTEPNAM-RESTWA(FOUR,RA),JCTSSTR  SAVE ABENDED SCT'S     33860018
*                                  TTR FOR RESTART RECHAINING           33920018
         SPACE 1                                                        33980018
*  THIS AREA IS CLEARED DURING THE TABLE MERGING FOR A RESTART OF       34040018
*  THIS JOB (IEFW21SD). IF THE R/I REACHES EOF FOR THE SYSIN D.S.       34100018
*  THE LOCATION TESTED WILL NOT HAVE BEEN CLEARED, SECOND ENTRY TO      34160018
*  THIS MODULE FOR THE SAME RESTART.                                    34220018
         SPACE 1                                                        34280018
         CLI   CVTCRTTR+TWO,ZERO   TEST FOR PREVIOUS PROCESSING.        34340018
         BNE   RA0300               BR - YES THIS RESTART IS PROCESAACA 34400017
         TM    CVTSTUSA,CVTSTEPR   Q. STEP RESTART                      34600017
         BO    RA0200               BR - YES                       AACA 34800017
*        PREPARE FOR INTRA-STEP RESTART                                 35000017
         USING RESTWA,RA                                                35200017
         XC    SCTR(L'SCTR),SCTR             ZERO                       35400018
         XC    SIOTR(L'SIOTR),SIOTR           ALL                       35600018
         XC    JFCBR(L'JFCBR),JFCBR           TABLES                    35800018
         XC    VOLTR(L'VOLTR),VOLTR           EXCEPT                    36000018
         XC    RJFCBEXT(L'RJFCBEXT),RJFCBEXT  JCT                       36200018
         USING JCTD+RESTWA-JCTR,RA                                      36400017
         MVC  QMTTR-RESTWA(FOUR,RA),JCTCKTTR  TTR-READ CKPT JFCB        36600018
         USING RESTWA,RA                                                36800017
         LA    R0,JFCBR            AREA OF WORKAREA TO READ             37000017
         ST    R0,QMADDR            CHKPT JFCB INTO                     37200017
         L     RF,IEFQMSSS         LOAD Q-MAN ADDR                      37400017
         LA    R1,QMPAR            LOAD QMPA ADDR                       37600017
         BALR  RE,RF               CALL Q-MAN                           37800017
*        GET NEEDED TTR'S                                               38000017
         USING IOPARAMS+RESTWA-QMPAR,RA                                 38200017
         LA    R0,RESTTTRS-RESTWA(RA) SET ADDR OF AREA FOR 4 TTR'S      38400017
         ST    R0,QMPCM                                                 38600017
         MVI   QMPNC,SIXT*(RESTTTRL/4)  TTR'S TO ASSIGN                 38800018
         MVI   QMPOP,QMASGN        DENOTE ASSIGN FUNCTION               39000017
         LA    R1,QMPAR-RESTWA(RA) LOAD ADDRESS OF Q-MGR PARM AREA      39200018
         L     RF,IEFQMSSS                                              39400017
         BALR  RE,RF               CALL QUEUE MANAGER                   39600017
         LA    R0,QMEXTPAR-RESTWA(RA)  RESTART XTRN PARM AREA PTR       39800018
         ST    R0,QMPCM                                                 40000017
         MVI   QMPNC,ONE           RESTORE NUMBER OF RECORDS (=1)       40040018
         SPACE 1                                                        40080018
*  THE FOLLOWING CODE BUILDS IEFDSDRP'S SCT, SIOT, JFCB AND VOLT.       40120018
*  THIS IS THE CREATED STEP FOR AN AUTOMATIC CHECKPOINT RESTART.        40160018
*  IEFDSDRP'S STEP IS CHAINED INTO THE JCT AS THE FIRST STEP TO         40200018
*  BE EXECUTED WHEN THE JOB IS INITIATED AGAIN, THE FOLLOWING STEP      40240018
*  WILL BE THE ABENDED STEP'S SCT.                                      40280018
         SPACE 1                                                        40320018
         USING JCTD+RESTWA-JCTR,RA  USE REG AT RESTWA FOR JCT           40400017
         MVC   JCTSSTR,RSCTTTR-RESTWA(RA) MOVE IN TTR OF DSDR           40600017
         USING SCTD+RESTWA-SCTR,RA USE REG AT RESTWA FOR SCT            40800017
         MVI   SCTSEXEC+ONE,TRI    SET LENGTH OF PARM FIELD             41000018
         MVI   SCTSSTAT,SCTKEY0    SET BIT TO GIVE KEY 0 TO DSDR P      41200017
         MVC   SCTXBTTR,RSCTXTTR-RESTWA(RA) SET TTR OF BLOCK W/ PARM    41400017
         MVC   SCTANSCT,RSTEPNAM-RESTWA(RA) MOVE IN TTTR OF FAILED STEP 41600017
         MVC   SCTVOLTB,RVOLTTTR-RESTWA(RA) SAVE VOLT TTR IN SCT        41800017
         MVI   SCTVOLTL+ONE,SIX    SET VOLT LENGTH TO 6                 42000018
         MVC   SCTDISKA,RSCTTTR-RESTWA(RA) SET SCT DISK ADDRESS         42200017
         MVI   SCTTBLID,SCTID      SET SCT ID                           42400017
         MVC   SCTFSIOT,RSIOTTTR-RESTWA(RA) SET TTR OF SIOT             42600017
         MVC   SCTSNAME,IEFDSDRP   SET STEP NAME                        42800017
         MVI   SCTNSIOT,ONE        SET NUMBER OF SIOTS TO ONE           43000018
         MVI   SCTLALOC+ONE,ONE    SET NUMBER OF GOOD DD'S TO ONE       43200018
         MVC   SCTPGMNM,IEFDSDRP   SET PROGRAM NAME                     43400017
         USING SIOT+RESTWA-SIOTR,RA USE REG AT RESTWA FOR SIOT          43600017
         MVI   SIOTDCBR,BLK        BLANK DCB REFERENCE IN SIOT          43800018
         MVC   SCTDDNAM,SYSCHK     SET DD NAME                          44000017
         MVC   SIOTDSKA,RSIOTTTR-RESTWA(RA) SET TTR OF SIOT             44200017
         MVI   SIOTTYPE,SIOTID     SET ID                               44400017
         MVC   SCTPJFCB,RJFCBTTR-RESTWA(RA) SET TTR OF JFCB             44600017
         OI    SCTDDINO,ONE        SET NUMBER OF DD'S                   44700018
         OI    SCTNMBUT,ONE         AND UNITS TO ONE IN SIOT            44800018
         OI    SCTSDISP,RETAIN+KEEP  DISPOSITION EQ. RETAIN & KEEP      44900018
   MVC SCTUTYPE(L'JCTDEVT),(JCTR-RESTWA)+(JCTDEVT-JCTD)(RA)  MOVE       45000018
*  DEVICE TYPE INFO FOR CKPT DATA SET FROM JCT TO THE SIOT              45100018
         USING JFCB+RESTWA-JFCBR,RA USE REG AT RESTWA FOR JFCB          45600017
         LA    R3,ONE              SET JFCB SEQ. NO. TO 1               45800018
         STH   R3,JFCBVLSQ         NO. FROM JCT TO JFCB                 46000017
         IC    R3,(JCTR-RESTWA)+(JCTVOLSQ-JCTD)(RA) VOLUME SEQ.         46200017
         LTR   R3,R3               Q. SEQ. COUNT EQ ZERO                46240017
         BNZ   RA0040               BRANCH NO                           46280017
         LA    R3,ONE              SET SEQ. COUNT EQ. ZERO              46320018
RA0040   EQU   *                                                        46360017
   CLI (JCTR-RESTWA)+(JCTVOLSQ-JCTD)(RA),FIVE  Q. SEQ LARGER THAN 5     46460018
         BNH   RA0075               BR - NO                             46600017
         USING IOPARAMS+RESTWA-QMPAR,RA                                 46800017
         MVI   QMPOP,QMREAD        SET READ OP CODE                     47000017
         MVI   QMPNC,ONE           DENOTE 1 RECORD TO RD/WRT            47200018
         USING JFCB+RESTWA-JFCBR,RA                                     47400017
         MVC   QMTTR-RESTWA(TRI,RA),JFCBEXAD  TTR TO READ JFCB          47600018
         LA    RF,RJFCBEXT-RESTWA(RA)     EXTENSION BLOCK               47800017
         ST    RF,QMADDR-RESTWA(RA)                                     48000017
         L     RF,IEFQMSSS         LOAD Q-MAN ADDR.                     48200017
         LA    R1,QMPAR-RESTWA(RA) LOAD QMPA ADDR                       48400017
         BALR  RE,RF               CALL Q-MAN - READ JFCB EXTENSION     48600017
         SPACE 1                                                        48800017
         SH    R3,CON5             REDUCE SEQ. NO. BY 5                 49000017
         SR    R5,R5               DETERMINE SHICH JFCB EXTENSION       49200017
         IC    R5,JFCBEXTL          BLOCK CONTAINS THE REQUIRED         49400018
         LA    R9,FIFT              VOLUME SERIAL NUMBER                49600018
         LA    R6,RJFCBEXT-RESTWA(RA)   LOAD MOVE AREA ADDR.            49800017
RA0050   EQU   *                                                        50000017
         CLR   R9,R5               Q. VOL. SER.NO. IN THIS EXTEN        50200017
         BNL   RA0100               BR - YES                            50400017
         SH    R3,CON15            ADJUST CONSTANTS TO REFLECT THE      50600017
         AH    R9,CON15             NEXT EXTENSION BLOCK                50800017
   MVC QMTTR-RESTWA(TRI,RA),RJFCBEXT-RESTWA(RA)  TTR OF NEXT EXTEN.     51000018
         LA    R1,QMPAR-RESTWA(RA) LOAD QMPA ADDR                       51200017
         L     RF,IEFQMSSS         LOAD Q-MAN ADDR                      51400017
         BALR  RE,RF               CALL Q-MAN - READ JFCB EXTENSION     51600017
         B     RA0050              CONTINUE PROCESSING JFCB EXTEN'S     51800018
RA0075   EQU   *                                                        52000017
         LA    R6,JFCBVOLS-FOUR    LOAD MOVE AREA ADDR.                 52200018
RA0100   EQU   *                                                        52400017
         BCTR  R3,ZERO             REDUCE VOL. SEQ. BY ONE              52600018
         LA    RE,SIX              COMPUTE POSITION OF                  52800018
         LR    RF,R3                VOLUME SERIAL NO. WITHIN THE        53000017
         MR    RE,RE                GROUP                               53200017
         AR    R6,RF               ADJUST DISPLACEMENT ADDR. TO         53400017
   MVC VOLTR+EIGHT-RESTWA(SIX,RA),FOUR(R6)  MOVE VOL SQ NO. TO VOLT     53600018
         LR    R5,RA                                                    53800017
         USING SIOT+RESTWA-SIOTR,R5                                     54000017
         MVC   SIOTVLCT(ONE),JFCBVLCT  UPDATE SPECIFIED VOL COUNT       54200018
         MVI   SCTVOLCT,ONE        SET SIOT VOL COUNT TO ONE            54400018
         MVI   SCTVLPTR+ONE,ONE    SET SIOT REL VOL PTR                 54600018
         OI    SCTSBYT3,OLD        SET SIOT DISP + OLD                  54800017
OLD      EQU   1                   DISP OF DATA SET = OLD               55000017
NOLABEL  EQU   1                                                        55030017
         TM    JFCBLTYP,NOLABEL    NON-LABELLED TAPE                    55060017
         BZ    RA0150               NO - BRANCH                         55090017
         OI    SCTSBYT2,SCTUNLBD   SET NO LABEL BIT IN SIOT             55120017
RA0150   EQU   *                                                        55150017
         DROP  R5                                                       55200017
   MVC VOLTR-RESTWA(TRI,RA),RVOLTTTR-RESTWA(RA)  INITIALIZE THE         55400018
         MVI   VOLTR+TRI-RESTWA(RA),SIX  VOLT RECORD - TTR AND ID       55600018
         SPACE 2                                                        55800017
         USING IOPARAMS+RESTWA-QMPAR,RA                                 56000017
         MVI   QMPOP,QMWRTE        DENOTE WRITE OF                      56200017
         SPACE 1                                                        56400017
         USING RESTWA,RA                                                56600017
         LM    R5,R6,JCTR          SAVE 2 WORDS OF JCT                  56800017
         MVC   JCTR+FOUR(TRI),SAVJCTDA  INSERT PARM OF JCT TTR          57000018
         MVC   JCTR(TRI),RSCTXTTR  PLACE SELF-TTR IN RECORD             57200018
         MVI   JCTR+TRI,SCTXID     INSERT ID (SCT EXTENSION)            57400018
         LA    RF,SCTR             SET UP QMPA EXTERNAL PARM AREA       57600018
         ST    RF,RJFCBEXT          TO WRITE THE SCT, SIOT, JFCB,       57800017
   MVC RJFCBEXT+FOUR(FOUR),RSCTTTR  SCT EXTENSION BLOCK AND VOLT        58000018
         LA    RF,SIOTR                                                 58200017
         ST    RF,RJFCBEXT+EIGHT   SIOT                                 58400018
         MVC   RJFCBEXT+TWEL(FOUR),RSIOTTTR                             58600018
         LA    RF,JFCBR                                                 58800017
         ST    RF,RJFCBEXT+SIXT                                         59000018
         MVC   RJFCBEXT+TWEN(FOUR),RJFCBTTR  JFCB                       59200018
         LA    RF,JCTR                                                  59400017
         ST    RF,RJFCBEXT+TWEN4                                        59600018
         MVC   RJFCBEXT+TWEN8(FOUR),RSCTXTTR  SCT EXTENSION             59800018
         LA    RF,VOLTR                                                 60000017
         ST    RF,RJFCBEXT+TRI2                                         60200018
         MVC   RJFCBEXT+TRI6(FOUR),RVOLTTTR  VOLT                       60400018
         LA    RF,RJFCBEXT         CHANGE QMPA EXTERNAL PARM            60600017
         USING IOPARAMS+RESTWA-QMPAR,RA                                 60800017
         ST    RF,QMPCL             AREA ADDR.                          61000017
         MVI   QMPNC,FIVE          FIVE RECORDS                         61200018
         USING RESTWA,RA                                                61400017
         L     RF,IEFQMSSS         LOAD Q-MAN ADDR                      61600017
         LA    R1,QMPAR            LOAD QMPA ADDR                       61800017
         BALR  RE,RF               CALL Q-MAN TO WRITE FIVE RECORDS     62000017
         STM   R5,R6,JCTR                                               62200017
         LA    RF,QMADDR           RESET QMPA EXTERNAL PARM             62400017
         USING IOPARAMS+RESTWA-QMPAR,RA                                 62600017
         ST    RF,QMPCL             AREA                                62800017
RA0200   EQU   *                   CODE COMMON FOR ALL RESTARTS         63000017
*        WRITE OT JCT                                                   63200017
         MVI   QMPNC,SIXT          DENOTE ONE ASSIGN                    63400018
         LA    R1,QMPAR-RESTWA(RA) LOAD ADDRESS OF Q MGR PARM AREA      63600017
         MVI   QMPOP,QMASGN        DENOTE ASSIGN FUNCTION               63800017
         L     RF,IEFQMSSS         LOAD Q-MAN ADDR.                     64000017
         BALR  RE,RF                   CALL QUEUE MANAGER               64200017
         MVI   QMPNC,ONE           DENOTE ONE RECORD                    64400018
         MVI   QMPOP,QMWRTE        DENOTE WRITE                         64600017
         USING RESTWA,RA                                                64800017
         MVC   QMTTR,QMADDR            MOVE TTR TO PARM AREA            65000017
         MVC   RSCTXTTR(TRI),QMADDR  SAVE ASSIGNED JCT TTR              65200018
         LA    R0,JCTR             STORE ADDRESS OF JCT                 65400017
         L     R6,CVTJOB           GET ADDR OF IEFJOB                   65600017
         USING IEFJOB,R6                                                65800017
         LR    R5,R0               GET ADDR OF JCT                      66000017
         USING JCTD,R5                                                  66200017
         MVC   JCTSTIOT(FOUR),SCATALLY  SAVE LAST ASSIGNED Q RECD       66400018
*                                   FOR RESTORING BY W21SD              66600017
         DROP  R5                                                       66800017
         ST    R0,QMADDR                                                67000017
         L     RF,IEFQMSSS         LOAD Q-MAN ADDR.                     67200017
         LA    R1,QMPAR-RESTWA(RA) LOAD ADDRESS OF Q-MAN PARM AREA      67400018
         BALR  RE,RF               CALL QUEUE MANAGER                   67600017
         LH    R5,QMTTR            GET LAST USED TT                     67800017
RA0300   EQU   *                                                        68000017
*        TTR OF SCT SAVED IN RSTEPNAM FROM JCTSSTR                      68200017
*        READ SCT FOR STEP TO BE RESTARTED INTO JCT AREA                68400017
         MVC   QMTTR,RSTEPNAM      SET UP TTR FOR Q MANAGER             68600017
         LA    R0,JCTR             SET UP ADDRESS OF SCT TO BE READ IN  68800017
         ST    R0,QMADDR                                                69000017
         USING IOPARAMS+RESTWA-QMPAR,RA                                 69200017
         MVI   QMPOP,QMREAD        DENOTE READ TO BE DONE               69400017
         L     RF,IEFQMSSS         LOAD Q-MAN ADDR.                     69600017
         LA    R1,QMPAR-RESTWA(RA) LOAD ADDRESS OF Q-MAN PARM AREA      69800018
         BALR  RE,RF               CALL QUEUE MANAGER                   70000017
*        SET TTR FOR START IN IEFJOB AND SAVE OLD ONE                   70200017
         CLI   CVTCRTTR+TWO,ZERO   Q. RESTART PROCESSED PREVIOUSLY      70400018
         BNE   RA0400               BR - YES                            70600017
         L     R6,CVTJOB           GET ADDR OF IEFJOB                   70800017
         USING IEFJOB,R6                                                71000017
         USING RESTWA,RA                                                71200017
         MVC   CVTCRTTR(TRI),RSCTXTTR  SAVE MODIFIED JCT TTR IN CVT     71400018
RA0400   EQU   *                                                        71600017
         USING SCTD+RESTWA-JCTR,RA                                      71800017
   MVC RSTEPNAM-RESTWA(L'SCTSNAME,RA),SCTSNAME  SET UP STEP NAME &      72000018
   MVC RSCLPCNM-RESTWA(L'SCTSCLPC,RA),SCTSCLPC  CALLING STEP NAME       72200018
         USING RESTWA,RA                                                72400017
         LA    R0,LRESTWA-(L'RENAMES*TRI)  LOAD LGTH OF AREA TO FREE    72600018
         LA    R1,RESTTTRS         LOAD ADDR OF AREA TO BE FREED        72800017
         FREEMAIN R,LV=(0),A=(1)   FREE AREA NO LONGER NEEDED           73000017
*        PASS RENAMES (RESTART NAMES)                                   73200017
         L     RF,FOUR(RD)         STORE PARM ADDR                      73400018
         ST    RA,TWEN4(RF)         OVER REGISTER ONE                   73600018
       IEFRELSE                                                         73800017
         SR    RF,RF               RETURN CODE =0                       74000017
        RETURN (14,12),T,RC=(15)   RETURN TO CALLER                     74200017
RAMSG1   DC    C'IEF226A LOAD JOB ' MESSAGE TO OPERATOR FOR RE-ENTERING 74400017
RAMSG2    DC    C' INTO DEVICE '   JOB THROUGH READER FOR RESTART       74600017
IEFSD006 DC    V(IEFSD006)         CONVERT TO TTR ROUTINE               74800017
IEFQMSSS DC    V(IEFQMSSS)         QUEUE MANAGER ADDR                   75000017
IEFDSDRP DC    C'IEFDSDRP'         STEP & PROGRAM NAME                  75200018
SYSCHK   DC    CL8'SYSCHK'         DD NAME                              75400018
CON5     DC    H'5'                CONSTANT                             75600017
CON15    DC    H'15'               CONSTANT                             75800017
MASK     DC    X'0000FFFF'         UCB ADDR. MASK                       75804018
         EJECT                                                          75808018
*  THE FOLLOWING EQUATES ARE FOR OFFSETS AND CONSTANTS USED             75812018
*  THROUGH-OUT THIS ASSEMBLY                                            75816018
         SPACE 1                                                        75820018
*******************************************************************     75824018
ZERO     EQU   0                                                        75828018
ONE      EQU   1                                                        75832018
TWO      EQU   2                                                        75836018
TRI      EQU   3                                                        75840018
FOUR     EQU   4                                                        75844018
FIVE     EQU   5                                                        75848018
SIX      EQU  6                                                         75852018
EIGHT    EQU   8                                                        75856018
KEEP     EQU   8                                                        75860018
TWEL     EQU   12                                                       75864018
FIFT     EQU   15                                                       75868018
SIXT     EQU   16                                                       75872018
TWEN     EQU   20                                                       75876018
TWEN4    EQU   24                                                       75880018
TWEN8    EQU   28                                                       75884018
TRI2     EQU   32                                                       75888018
TRI6     EQU   36                                                       75892018
BLK      EQU  64                                                        75896018
RETAIN   EQU  64                                                        75900018
*******************************************************************     75904018
         EJECT                                                          75908018
         IEFSD005                                                       75912018
         EJECT                                                          75916018
         IEFQMPAM                                                       75920018
QMPAEND  EQU   *                                                        75924018
QMPAL    EQU   QMPAEND-QMNAM                                            75928018
         EJECT                                                          75932018
RESTWA   DSECT                                                          75936018
         SPACE 1                                                        75940018
RENAMES  DS    0D                  R/I PARAMETER AREA                   75944018
RJOBNAME DS    D                   RESTARTING JOB NAME                  75948018
RSCLPCNM DS    D                   RESTARTING CALLING STEP NAME         75952018
RSTEPNAM DS    D                   RESTARTING STEP NAME                 75956018
         SPACE 1                                                        75960018
RESTTTRS DS    0F                  ASSIGNED TTRS                        75964018
RSCTTTR  DS    F                   SCT TTR                              75968018
RSIOTTTR DS    F                   SIOT TTR                             75972018
RJFCBTTR DS    F                   JFCB TTR                             75976018
RSCTXTTR DS    F                   SCT OF DSDRP TTR, ALSO USED          75980018
*                                  TO SAVE ASSIGNED TTR FOR JCT         75984018
RVOLTTTR DS    F                   VOLT TTR                             75988018
RESTTTRL EQU   *-RESTTTRS         LENGTH OF TTR AREA                    75992018
         SPACE 1                                                        75996018
QMPAR    DS    CL(QMPAL)           QMPA AREA                            76000018
SAVJCTDA EQU   QMPAR               JCT TTR SAVE AREA (UNUSED WORD)      76004018
         SPACE 1                                                        76008018
QMEXTPAR DS    0D                  Q-MAN EXTERNAL PARM LIST             76012018
QMADDR   DS    F                   AREA ADDR                            76016018
QMTTR    DS    F                   RECORD TTR                           76020018
         SPACE 1                                                        76024018
RESTTBLS DS    0C                  RESTARTING TABLES AREA               76028018
JCTR     DS    CL176               JCT RECORD AREA                      76032018
SCTR     DS    CL176               SCT RECORD AREA                      76036018
SIOTR    DS    CL176               SIOT RECORD AREA                     76040018
JFCBR    DS    CL176               JFCB RECORD AREA                     76044018
VOLTR    DS    CL176               VOLT RECORD AREA                     76048018
RJFCBEXT DS    CL176               JFCB EXTENSION BLOCK RECORD AREA     76052018
         SPACE 1                                                        76056018
LRESTWA  EQU   *-RESTWA            RESTART WORKAREA LENGTH              76060018
         EJECT                                                          76064018
UCBVECT  DSECT                     UCB ADDR LIST                        76068018
UCBVEC   DS    H                   LENGHT OF ADDR EQ. 2                 76072018
         DS    0F                  ALIGN TO FULL WORD BOUNDARY          76076018
         IEFUCBOB                  UCB MACRO                            76080018
         SPACE 1                                                        76084018
SRTSYSIN EQU   128                 BIT DENOTING SYSTEM INPUT DEVICE     76088018
         EJECT                                                          76092018
CVT      DSECT                                                          76096018
         CVT   SYS=MIN                                                  76100018
         EJECT                                                          76104018
JCTD     DSECT                                                          76108018
         IEFAJCTB                                                       76112018
         EJECT                                                          76116018
SCTD     DSECT                                                          76120018
         IEFASCTB                                                       76124018
SCTXID   EQU   12                  ID FOR SCT EXT. BLOCK (PARM FLD)     76128018
SCTKEY0  EQU   4                   SCT BIT FOR KEY ZERO                 76132018
         EJECT                                                          76136018
SIOT     DSECT                                                          76140018
         IEFASIOT                                                       76144018
         EJECT                                                          76148018
JFCB     DSECT                                                          76152018
         IEFJFCBN                                                       76156018
         EJECT                                                          76160018
IEFJOB   DSECT                                                          76164018
         DS    25F                 ALIGNMENT                            76168018
SCATALLY DS    F                   LAST ASSIGNED Q RECORD               76172018
SCASTRKS DS    H                   TT OF 1ST RECORD NON-PREEMPT         76176018
         SPACE 4                                                        76180018
IEEMSLT  IEEGMSLT  LABEL=MRC                                            76184018
 END                                                                    76200017
