         TITLE 'IEFRPREP-TERMINATION RESTART PREPARATION'               00200017
IEFRPREP CSECT                                                          00400017
* A-259100,A-670200,A-670220                                      M0115 00450021
* 215500,222560,707000-710000                                     M0092 00500018
* 228300,256500,667900                                            M3678 00550019
*                                                                       00600017
*                                                                P17035 00700018
*********************************************************************** 00800017
* NAME        .IEFRPREP                                                 01000017
*                                                                       01200017
* FUNCTION    .TO DETERMINE IF A JOBSTEP TASK WHICH HAS ABENDED CAN BE  01400017
*              RESTARTED    AND                                         01600017
*            .TO PREPARE FOR RESTART                                    01800017
*                                                                       02000017
* INPUT       .LOT (LIFE-OF-TASK) BLOCK) POINTED TO IN REG 12           02200017
*                                                                       02400017
* ENTRY       .FROM STEP TERMINATE DRIVER -IEFYNIMP                     02600017
*                                                                       02800017
* OUTPUT      .A RETURN CODE IN THE 'LCTERROR' FIELD OF THE LCT         02900017
*                  X'00' - NO RESTART                                   03000017
*                  X'08' - RESTART IS TO OCCUR                          03100017
*             .INDICATORS SET IN THE JCT FOR RESTART OR NO RESTART AND  03200017
*              IF RESTART - FOR STEP OR CHECKPOINT RESTART              03300017
*                                                                       03800017
* BASIC FLOW                                                            03860017
*             .TEST FOR DSDRP STEP ABENDING                             03920017
*             .TEST FOR RESTART REQUEST                                 03980017
*             .TEST FOR CHECKPOINTS TAKEN                               04040017
*             .IF NOT PCP - TEST FOR MSGLEVEL=1                         04100017
*             .VERIFY  ABEND CODE ELIGIBLE                              04200017
*             .REQUEST OPERATOR AUTHORIZATION                           04400017
*             .SAVE RESTART INDICATORS                                  04600017
*             .SAVE DISPOSITION INDICATORS BASED ON RESTART TYPE        04800017
*             .IF STEP RESTART - SCAN PDQ ENTRIES FOR RESTART ACTION    05000017
*            .RETURN TO IEFYNIMP                                        05200017
*                                                                       05400017
* ATTRIBUTES  .REENTRANT                                                05600017
*             .CHARACTER DEPENDENCE-TYPE C                              05800017
*                                                                       06000017
*********************************************************************** 06200017
*                                                                       06400017
         EJECT                                                          06600017
R0       EQU   0                                                        06800017
R1       EQU   1                                                        07000017
R2       EQU   2         WORK REGS                                      07200017
R3       EQU   3           *                                            07400017
R4       EQU   4           *                                            07600017
R5       EQU   5           *                                            07800017
R6       EQU   6           *                                            08000017
R7       EQU   7           *                                            08200017
R8       EQU   8           *                                            08400017
R9       EQU   9         PROGRAM BASE                                   08600017
RA       EQU   10        JCT BASE                                       08800017
RB       EQU   11        SCT BASE                                       09000017
RC       EQU   12        LCT BASE                                       09200017
RD       EQU   13                                                       09400017
RE       EQU   14                                                       09600017
RF       EQU   15                                                       09800017
*                                                                       10000017
*                                                                       10200017
         SAVE  (14,12)                                                  10400017
         BALR  R9,R0              ESTABLISH                             10500018
         USING *,R9                    ADDRESSABILITY                   10600018
         B     RP050              AND BRANCH AROUND DUMP IDENTIFIER     10700018
*                                                                       10800018
         DC    X'1111'            THIS IS                               10900018
         DC    C'28JUNE68'           TO RECOGNIZE                       11000018
         DC    C'IEFRPREP'                 RPREP IN                     11100018
         DC    X'1111'                      A DUMP                      11200018
*********************************************************************** 11800017
*                                                                       12000017
*             INITIALIZATION  AND RESTART VERIFICATION                  12200017
*              VERIFICATION INCLUDES-                                   12400017
*               -TESTING RESTART STATUS AS REQUESTED VIA THE JOB AND/OR 12600017
*                EXEC STATEMENT                                         12800017
*               -DETERMINING IF ABEND CODE IS ELIGIBLE FOR RESTART-THAT 13000017
*                IS,CONTAINED IN A SYSGEN TABLE OF RESTARTABLE ABEND    13200017
*                CODES                                                  13400017
*               -REQUESTING AUTHORIZATION FROM THE SYSTEM OPERATOR FOR  13600017
*                RESTART                                                13800017
*                                                                       14000017
*                                                                       14200017
*********************************************************************** 14400017
RP050    DS    0H                                                       14600018
         USING LCT,RC         LCT  BASE                                 14800017
         L     RA,LCTJCTAD    SETUP JCT BASE REGISTER                   15000017
         MVI   LCTERROR,ZERO      ZERO RET CODE IN LCT FOR NO RSTRT     15100018
         USING JCT,RA                                                   15200017
         L     RB,LCTSCTAD                                              15500017
         USING     SCT,RB                                               15800017
         CLC   SCTSNAME,IEFDSDRP  IS IT THE DSDRP STEP BEING STARTED    15830018
         BE    CABEND1            YES - THEN NO RESTART WILL OCCUR      15860017
         TM    JCTRSW2,JCTNORST    IS JOB TO BE RESTARTED               15900017
         BO   RP950                     BCH NO TO EXIT ... W/O SAVE     16000017
         TM    JCTRSW2,JCTRESTT   IS BIT ON FOR RSTRT TO OCCUR          16060017
         USING CVT,R5                                                   16090017
         BO    RP070              YES - BR AROUND CHECKPT CHECK         16130017
         TM    JCTRSW1,JCTCKFT    NO - WERE CHKPTS TAKEN                16170017
         BZ    CABEND1            NO - SET BITS FOR NORST AND EXIT      16210017
*                                                                       16250017
RP070    DS    0H                 IF NOT PCP, MSGLEVEL MUST EQ 1        16290017
         L     R5,CVTPTR          PICK UP CVT ADDRESS                   16330018
         CLI   CVTDCB,PCPSYS      IS THIS PCP                           16370018
         BE    RP075              YES - SKIP MSGLEVEL TEST              16410017
         TM    JCTJMGLV,INCMMGL1  DOES MSGLEVEL=1                       16450017
         BZ    CABEND1            NO - BR TO SET NORST FLAGS            16490017
*                                                                       16530017
* * *    CHECK TO SEE IF ABEND CODE IS PERMITTED TO RESTART             16610017
*                                           *                           16620017
RP075    DS    0H                                                       16622017
         L     R4,LCTTCBAD             GET TCB ADDR FROM LCT            16625017
*                                                                       16630018
         USING TCB,R4                                                   16635018
         L     R4,TCBCMP          PICK UP ABEND CODE                    16640018
         DROP  R4                                                       16645018
*                                                                       16650018
         LA    R4,ZERO(R4)        CLEAR HI ORDER BYTE                   16655018
         SRDL  R4,TWLVE           SHIFT USER CODE TO REG5 - IF ANY      16660018
*                                                                       16669017
         L     R2,VCONDS           ESTABLISH POINTER TO BEGIN OF        16671017
         LR    R1,R2              VALID RESTART CODES - SYSTEM - AND    16671617
         AH    R1,ZERO(R2)        TO END OF VALID SYSTEM RESTART CODES  16672218
         LTR   R4,R4              IS IT A SYSTEM ABEND CODE             16672817
         BNE   CABEND0            YES - BRANCH TO PROCESS IT            16673417
         SLDL  R4,TWLVE           NO - SHIFT USER CODE BACK INTO R4     16674018
         LR    R2,R1              LOAD END SYSTEM RESTART CODE TABLE    16674617
         AH    R1,ZERO(R2)        ADD LENGTH USER CODE TABLE - TO       16675218
*                                 POINT TO THE END OF THE TABLE         16675817
CABEND0  DS    0H                                                       16676818
         LA    R2,TWO(R2)         POINT TO NEXT VALID ABEND CODE        16677818
         CR    R2,R1              END OF TABLE                          16679017
         BE    CABEND1              YES      NO RESTART                 16681017
*                                   NO                                  16683017
         CH    R4,ZERO(R2)         VALID ABEND CODE FOR RESTART         16685018
         BNE   CABEND0              NO       CONTINUE SEARCH            16687017
         B     RP100              YES    RESTARTABLE                    16689017
CABEND1  DS    0H                                                       16691017
         OI    JCTRSW2,JCTNORST   SET NO RESTART SWITCH                 16741018
* NEED TO TURN OFF THESE BITS IN SWITCH 1 AS THIS IS A COMMON EXIT PATH 16791018
         NI    JCTRSW1,OFFSW1                                           16841018
         B     RP950              GO TO EXIT                            16900017
*********************************************************************** 17200017
*             REQUEST OPERATOR AUTHORIZATION OF JOB RESTART             17400017
*             ALL REGISTERS ARE FREE FOR USE                            17600017
*             .CREATE INTERFACE FOR GENERATE-WTO MSG MODULE             17800017
*             .WAIT ON REPLY                                            18000017
*********************************************************************** 18200017
*                                                                       18400017
RP100    EQU   *                                                        18600017
         GETMAIN R,LV=200         GET CORE FOR MSG + PDQ PROCESSING     18700017
         LR    R8,R1               ADDRESS MSG AREA                     18800017
*********************************************************************** 18810017
*        R1 MUST BE SAVED THROUGHOUT FORMATTING THE MESSAGE.            18820017
*        IT POINTS TO THE GOTTEN CORE.                                  18830017
*        R8 IS THE REG USED TO POSITION THE DATA IN THE MESSAGE.        18840017
*********************************************************************** 18850017
         USING MSG,R8                                                   18900017
         SR    R2,R2              SUBTRACT OUT INDEX REG                18950018
         MVC   MSGWTOR(MSGLN),MESS1 MOVE LIST DATA TO GOTTEN CORE       19150018
         MVC   MSGJOB,JCTJNAME    INSERT JOBNAME INTO MESSAGE           19250018
         MVC   MSGSTEP,SCTSNAME   INSERT STEPNAME                       19350018
         CLI   SCTSCLPC,BLANK     Q. IS THERE A CALLING STEPNAME        19450018
         BE    RP110                BR NO                               19800017
         MVI   MSGPT2,PERIOD      MOVE DELIMITER TO MSG                 19840018
         MVC   MSGSTEP,SCTSCLPC   INSERT CALLING STEPNAME IN MSG        19880018
         MVC   MSGPROC,SCTSNAME    RE INSERT STEPNAME                   19920018
         B     RP115              B TO CHECK RESTART CODE               19970017
RP110    DS    0H                                                       20040017
         LA    R7,NINE            LOAD 9 AND SUBTRACT IT FROM           20080018
         LA    R2,NINE(R2)        ADD IN INDEX                          20120018
         SR    R8,R7                 FROM MSG BASE REGISTER             20180017
RP115    DS    0H                                                       20250017
         TM    JCTRSW1,JCTCKFT  WAS CHECKPT TAKEN FOR THIS STEP         20320017
         BZ    RP117              NO - GO TO FLAG STEP RSTRT            20390017
         OI    JCTRSW1,JCTCKPTR   INTRA-STEP RESTART FLAG               20460017
         MVC   MSGCHKID,JCTCKIDT  MOVE CHECKID TO MSG                   20530018
         B     RP119              BR TO PUT IN REST OF MESSAGE          20600018
RP117    OI    JCTRSW1,JCTSTEPR   SET THE STEP RESTART BIT ON IN JCT    20670017
         LA    R7,CON17           LOAD 17 TO SUBTRACT FROM MSG BASE     20710018
         LA    R2,CON17(R2)       ADD IN INDEX TO GET TO SECOND PART    20750018
         SR    R8,R7              TO POSITION SECOND PART OF MSG        20810017
RP119    DS    0H                                                       20880017
         LA    R7,MSGMSG1(R2)     POINT TO SECOND PART OF MSG           21080018
         MVC   MSGMSG1(TWLVE),ZERO(R7) MOVE SECOND PART OF MSG          21280018
         LA    R5,MSGMCS           THIS POINTS TO END OF MSG.     M0092 21480018
*        R1 CONTAINS ORIGINAL POINTER TO GOTTEN CORE.                   21850017
         LR    R8,R1              RESET BASE REG TO ORIG ADDRESS        22240017
         LA    R1,MSGHDR                                                22246017
         SR    R5,R1              SUBTRACT BEG OF MSG FROM END          22252017
         STH   R5,MSGHDR          STORE MSG LENGTH                      22260017
         LA    R2,MSGREPLY         LOAD REPLY ADDRESS                   22300017
         ST    R2,MSGREPL          SAVE IN PARM LIST                    22400017
         MVI   MSGREPL,REPLEN4    INSERT MAX REPLY LENGTH               22500018
         LA    R2,MSGECB           LOAD ECB ADDRESS                     22600017
         ST    R2,MSGECBAD         SAVE IN PARM LIST                    22700017
RP130    EQU   *                                                        22800017
         LA    R1,MSGREPL          POINT TO MSG BUFFER                  22860017
         MVI   MSGREPLY,BLANK     BLANK OUR REPLY AREA                  22890018
         MVC   MSGREPLY+ONE(L3),MSGREPLY  REPLY AREA IN CASE OF REISSUE 22920018
         XC    MSGECB,MSGECB      CLEAR THE ECB                         22950018
         WTO   MF=(E,(1))          WRITE MESSAGE TO CONSOLE             23000017
*                                                                       25200017
         WAIT  ECB=(2)                                                  25400017
*                                                                       25600017
         LR    R7,R8              SAVE POINTER TO GOTTEN CORE           25700017
*********************************************************************** 25740017
*        R7 MUST BE SAVED THROUGH ALL FURTHER PROCESSING.               25780017
*        IT CONTAINS THE ADDRESS OF THE GOTTEN CORE.                    25820017
*********************************************************************** 25860017
         OC    MSGREPLY(FOUR),BLANKS  FOLD REPLY TO CAPS          M0115 25910021
         CLC   MSGREPLY,NO        NO - MEANING CANCEL                   25960018
         BE    RP150              TAKE NO RESTART PATH                  26160018
         CLC   MSGREPLY,YES       YES - MEANING IMMEDIATE RESTART/      26360018
         BE    RP160              TAKE RESTART TO OCCUR PATH            26560018
         CLC   MSGREPLY,HOLD      HOLD - MEANING PUT IN HOLD QUEUE      26760018
         BE    RP155              TAKE HOLD PATH WITH CHECK FOR PCP     26960018
         B     RP130               BAD REPLY - GO RETRY MESSAGE         27200017
*                                                                       27400017
*             NO MEANS CANCEL WHICH SETS THE NO RESTART INDICATOR FOR   27600017
*              THIS JOBSTEP                                             27800017
*                                                                       28000017
RP150    EQU   *                                                        28200017
         NI    JCTRSW1,OFFSW1                                           28300018
         OI    JCTRSW2,JCTNORST                                         28400017
         B     RP899              TO FREE MSG BUFFER AND EXIT           28600017
*                                                                       28800017
*             HOLD MEANS OPERATOR DEFERRED RESTART-GO THRU THE MOTIONS  29000017
*              OF RESTART THEN ENQ JOB ON THE HOLD QUEUE                29200017
*                                                                       29400017
RP155    EQU   *                                                        29600017
         L     R5,CVTPTR          PICK UP CVT POINTER                   29650018
         CLI   CVTDCB,PCPSYS      ENVIRONMENT TEST HOLD IN PCP          29700018
         BE    RP150                   MEANS CANCEL                     29750017
         MVI   JCTQIDNT,HOLDQ     INDICATE HOLD QUEUE IN JCT            29850018
         B     RP200              GO TO NORMAL PROCESSING               29950018
*                                                                       30200017
*             YES MEANS RESTART - ENQ JOB ON THE INPUT QUEUE            30400017
*                                                                       30600017
RP160    EQU   *                                                        30800017
         MVI   JCTQIDNT,JOBQ                                            31000017
*                                                                       31200017
         DROP  R8                                                       31700017
*                                                                       32000017
RP200    EQU   *                                                        32200017
*********************************************************************** 32800017
*             RESTART IS TO OCCUR                                       33000017
*             .SAVE TTR OF STEP-TO-START                                33200017
*             .TEST RESTART TYPE -IF CHKPT MACRO ISSUED-INTRASTEP       33400017
*                                 NO CHKPT MACRO ISSUED-STEP            33600017
*             .PDQ PROCESSING DONE ONLY FOR STEP RESTART                33800017
*********************************************************************** 34000017
*                                                                       34200017
         MVC   JCTSSTR,SCTDISKA   RESTART THIS STEP                     34400018
         TM    JCTRSW1,JCTCKFT    WAS CHKPT TAKEN FOR THIS STEP         34600017
*                                                                       35000017
*             INTRA STEP RESTART                                        35200017
*                                                                       35400017
         BO    RP850              BR TO EXIT RTN TO SET RSTRT CODE      35800017
*                                                                       36200017
*********************************************************************** 36400017
*             STEP RESTART-                                             36600017
*             .SCAN ANY PDQ ENTRIES FOR THOSE CREATED BY CURRENT STEP-  37000017
*              DECREMENT STEP NUMBER AND SET PASS BIT TO PASS TO RESTRT 37200017
*********************************************************************** 37400017
*                                                                       38400017
         CLC   JCTPDQDA(L3),FZERO IS THERE A PDQ TO PROCESS             38600018
         BE    RP850              BR IF NO PDQ TO PROCESS               38800017
         L     R8,JCTPDQDA        SAVE PDQ DIRECTORY TTR                39000017
         DROP  RB                                                       39400017
*                                                                       39600017
*********************************************************************** 40000017
*                                                                       40200017
*             PDQ DIRECTORY BLOCK PROCESSING                            40400017
*              A DIRECTORY CONTAINS FROM 1 TO 3 DATASET NAMES-EACH      40600017
*              CORRESPONDING TO A PDQ ENTRY.1-3 PDQ ENTRIES ARE PACKED  40800017
*              INTO AN ENTRY BLOCK. THE NO. OF ENTRIES IN THE BLOCK     41000017
*              IS CONTAINED IN THE DIRECTORY.                           41200017
*             PDQ ENTRY BLOCK                                           41400017
*              ONE PDQ ENTRY BLOCK EXISTS FOR EACH PDQ DIRECTORY BLOCK. 41600017
*              ONE PDQ ENTRY BLOCK CONTAINS 3 PDQ ENTRIES-EACH 56 BYTES 41800017
*              LONG.                                                    42000017
*             REGISTERS USED                                            42200017
*        R1-R3 + R5-R6  WORK REGS                                       42300017
*        R4    QUEUE MANAGER PARM AREA BASE                             42400017
*        R7 POINTS TO GOTTEN CORE                                       42500017
*              R8  PDQ DIRECTORY AND ENTRY BASE                         42600017
*               R9  PROGRAM BASE                                        42800017
*        RA JCT BASE                                                    43000017
*              RB  ADDR OF GOTTEN CORE                                  43200017
*              RC  LCT BASE                                             43400017
*********************************************************************** 43600017
*                                                                       43800017
*                                                                       44000017
         IEFSAVER                                                       44100017
         L     R4,LCTCMCBA        LOCATE QUEUE PARAM AREA               44200017
         LA    R4,LCTQMPAM(R4)                                          44300017
         USING IOPARAMS,R4                                              44400017
         LR    RB,R7              POINTER TO GOTTEN CORE                44600017
         ST    R7,QMPCL                                                 44800017
         USING RPCORE,RB                                                45200017
*                                                                       45400017
*             QUEUE MANAGER INITIALIZATION                              45600017
*              READ IN BUFFER                                           45800017
*                                                                       46000017
         LA    R5,READIN                                                46400017
         ST    R5,QMRWL     INITIALIZE ADDR WITH CORE READIN BUFFER     46600017
         ST    R8,QMRWT      TTR OF FIRST PDQ DIRECTORY SAVED FROM JCT  46800017
         MVI   QMPNC,ONE     READ 1 RECORD                              47000018
         MVI   QMPOP,QMREAD  READ OP CODE                               47200017
         LA    R6,RP400      SET LINK REG                               47400017
*                                                                       47600017
*             QUEUE MANAGER READ ROUTINE                                47800017
*                                                                       48000017
RP350    EQU   *                                                        48200017
         LR    R1,R4              PARM LIST PASSED IN REG 1             48400017
         L     RF,RP999  VCON OF IEFQMRAW                               48600017
         BALR  RE,RF              GO TO QMGR TO READ PDQ                48700018
         LTR   RF,RF              RET CODE = ZERO FROM QMGR             48840017
         BCR   ZEROES,R6          YES - LINK REGISTER RETURN            48880018
         OI    JCTRSW2,JCTNORST   NO - I/O ERROR - NO RESTART           48920017
         USING ERRMSG,R7                                                48960018
         XC    ERRHDR,ERRHDR      CLEAR FIRST WORD FOR LENGTH           49000018
         MVC   ERRHDR(ERRMSGLN),ERRMSG1  MOVE ERRWTO TO BUFFER          49040018
         MVC   ERRJNAME,JCTJNAME   MOVE IN JOBNAME FOR WTO              49080018
         MVC   ERRMSGP2,ERRMSG2   MOVE IN MESSAGE TEST                  49120018
         MVI   ERRLEN,ERRMSGLN    PUT LENGTH IN HEADER                  49160018
         LR    R1,R7                                                    49200017
         WTO   MF=(E,(1))         WTO I/O ERROR - NO RESTART            49240017
         B     RP600              GO TO FREE REG SAVE AREA              49280017
*                                                                       49400017
*                                                                       49600017
*             PDQ DIRECTORY PROCESSING                                  49800017
*              SAVE TTR OF NEXT DIRECTORY                               50000017
*              SAVE COUNT OF PDQ ENTRIES FOR THIS DIRECTORY             50200017
*                                                                       50400017
RP400    EQU   *                                                        50600017
         LA    R8,READIN   SETUP DIRECTORY BASE                         50800017
         USING PDQ,R8                                                   51000017
         MVC   TTRSAVE,PDQBLKDA     TTR OF NEXT DIRECTORY FOR SAFE KEEP 51200018
         CLI   PDQCOUNT,ZERO      ARE THERE ANY ENTRIES THIS DIRECTORY  51400018
         BE    RP450              NO - GO READ IN NEXT DIRECTORY        51600018
         XR    R5,R5                                                    51800017
         IC    R5,PDQCOUNT    COUNT OF ENTRYS IN ENTRY BLOCK            52000017
         B     RP475              GO TO PROCESS ENTRIES                 52200018
*                                                                       52400017
*             READ NEXT DIRECTORY                                       52600017
*                                                                       52800017
RP450    EQU   *                                                        53000017
         CLC   TTRSAVE(L3),FZERO   IS TTR OF DIRECTORY BLOCK EQ ZERO    53200018
         BE    RP600              YES - PDQ PROCESSING COMPLETE - EXIT  53400018
         MVC   QMRWT(L3),TTRSAVE   TTR OF DIRECTORY BLOCK TO READ       53600018
         LA    R6,RP400            SET RETURN REG                       53800017
         B     RP350               GO TO QUEUE MANAGER READ RTN         54000017
*                                                                       54200017
*             READ PDQ ENTRY BLOCK                                      54400017
*                                                                       54600017
RP475    EQU   *                                                        54800017
         LA    R6,RP500       RETURN REG FROM READ RTN                  55000017
         MVC   QMRWT(L3),PDQENTDA TTR OF ENTRY BLOCK                    55300018
         B     RP350          GO TO QUEUE MANAG READ RTN                55600017
         DROP  R8                                                       55800017
*                                                                       56000017
*       PDQ ENTRY PROCESSING                                            56200017
*             -TEST FOR CURRENT STEP NO.                                56400017
*                 IF EQUAL-DECREMENT BY ONE AND SET PASS BIT            56600017
*                 IF UNEQUAL-GO ON TO NEXT ENTRY                        56800017
*             -WHEN ALL ENTRIES HAVE BEEN PROCESSED-REWRITE PDQ ENTRY   57000017
*              BLOCK-AND RETURN TO READ NEXT DIRECTORY BLOCK            57200017
*                                                                       57400017
RP500    EQU   *                                                        57600017
         USING PDQBLOCK,R8                                              57800017
         CLC   PDQSIOTA+THREE(L1),LCTSNUMB  ARE STEP NOS EQUAL          57900018
*                                              OR WAS THIS              58000018
         BE    RP525               ENTRY CREATED BY THIS STEP           58200017
RP505    BCT   R5,RP515       HAVE ALL ENTRIES BEEN TESTED              58400017
         MVI   QMPOP,QMWRTE   REWRITE PDQ ENTRY BLOCK                   58600017
         BAL   R6,RP350           USE QMGR INTERFACE ROUTINE            58800018
         MVI   QMPOP,QMREAD                                             59000017
         B     RP450      YES -GO READ NEXT PDQ DIRECTORY               59200017
*             THIS BIT OF CODE SUPPOSEDLY ADJUSTS THE BASE              59400017
*             REGISTER TO POINT TO NEXT ENTRY                           59600017
*             R4 CONTAINS RELATIVE ENTRY POSITION OF NEXT ENTRY         59800017
*             R5 CONTAINS COUNT OF ENTRIES OFF DIRECTORY                60000017
*             R8 IS THE BASE REGISTER                                   60200017
RP515    EQU   *                                                        60400017
         A     R8,PDQELG           ADJUST PTR TO NEXT ENTRY             60900017
         B     RP500              GO BACK TO PROCESS THIS ENTRY         61200018
*                                                                       61600017
*             THIS ENTRY WAS CREATED FOR THIS STEP-DECREMENT STEP NO.   61800017
*              SUCH THAT IT IS NO LONGER EQUAL TO THE CURRENT STEP NO.  62000017
*              AND SET THE PASS INDICATOR TO PASS THE DATA SET ON.      62200017
*                                                                       62400017
RP525    EQU   *                                                        62600017
         XR    R2,R2          WORK REG-                                 62800017
         IC    R2,PDQSIOTA+THREE  INSERT STEP NUMBER                    63000018
         BCTR  R2,R0           DECREMENT IT ONE                         63200018
         STC   R2,PDQSIOTA+THREE   RESTORE IN PDQ ENTRY                 63400018
         OI    PDQBTWKA,PDQPASIN  TURN ON PASS INDICATOR                63600017
         IC    R2,PDQBSTNO        INSERT STEP NO                        63630017
         LTR   R2,R2              ANY STEP NUMBER                       63660017
         BZ    RP505              NO - BRANCH                           63690017
         BCTR  R2,R0              DECREMENT STEP NO                     63720018
         STC   R2,PDQBSTNO        RESTORE IN PDQ                        63750017
         B     RP505              GO TO WRITE UPDATED ENTRY BACK OUT    63850018
*                                                                       64000017
*                                                                       64200017
RP600    EQU   *                                                        64400017
         IEFRELSE                                                       64500017
         TM    JCTRSW2,JCTNORST   HAS RSTRT BEEN CANCELED BY I/O ERROR  64600017
         BO    RP150              YES - GO TURN OFF RSTRT BITS AND EXIT 64700017
RP850    DS    0H                    ENTER. ** SET RET CODE **          64802017
         L     R4,LCTCMCBA         LOCATE QUEUE PARAM AREA       P17035 64810018
         LA    R4,LCTQMPAM(R4)                                   P17035 64818018
         USING IOPARAMS,R4                                       P17035 64826018
         OI    QMSTA,X'10'         TURN ON REINTERPRETATION SW   P17035 64834018
         MVI   LCTERROR,RSTRT     IMMED RESTART RETURN CODE             64842018
RP899    DS    0H                 ENTRY TO FREE MSG BUFFER              64885017
         LR    R1,R7              POINTER TO AREA TO R1                 64890017
         FREEMAIN R,LV=200,A=(1)   FREE WORK CORE                       64895017
RP950      DS    0H                                                     65400017
         RETURN (14,12),T                                               65600017
HOLDQ    EQU   X'01'                                                    66200017
JOBQ     EQU   X'02'                                                    66400017
MESS1    WTOR  'IEF225D SHOULD         .                               *66430018
                   RESTART',REPLYARE,4,ECBSELF,MF=L,ROUTCDE=(1),       $66460018
               DESC=(2)                                                 66490018
REPLYARE DS    CL4                 REPLY AREA FOR MCS WTOR              66520018
ECBSELF  DS    F                  ECB FOR MOVE TO GOTTEN CORE           66550018
MESS2    EQU   *                                                        66580018
MSGLN    EQU   MESS2-MESS1                                              66610018
ERRMSG1  WTO   'IEF228I          RESTART CANCELED - I/O ERROR SCHEDULER*66640018
                WORK AREA',MF=L,ROUTCDE=(2,11),DESC=(6)                 66670018
ERRMSG2  EQU   *                                                        66700018
ERRMSGLN  EQU  ERRMSG2-ERRMSG1                                          66730018
FZERO    DC    F'0'               WORD OF ZEROS FOR COMPARE             66760018
IEFSQCBS DC    C'SYSIEFSD'        MAJOR NAME                            66820018
IEFQ5QCB DC    C'Q5'              MINOR NAME                            66850018
RP999    DC    V(IEFQMSSS)        VCON FOR QMGR                         66870018
VCONDS   DC    V(IEFYRCDS)        VCON FOR TABLE OF ELIGIBLE CODES      66890018
PDQELG   DC    A(PDQENTRY)        LENGTH OF A PDQ ENTRY                 66910018
NO       DC    C'NO  '            CONSTANTS TO                          66930018
YES      DC    C'YES '            COMPARE AGAINST                       66950018
HOLD     DC    C'HOLD'            OPERATOR REPLIES                      66970018
IEFDSDRP DC    C'IEFDSDRP'        CONSTANT - DSDR STEP DOES NOT GET     66990018
*                                 RESTARTED UNDER ANY CIRCUMSTANCES     67010018
BLANKS   DC    C'    '            FOLDER FOR REPLY                M0115 67020021
FOUR     EQU   4                                                  M0115 67022021
ZERO     EQU   0                                                        67030018
ONE      EQU   1                                                        67050018
L1       EQU   1                                                        67070018
TWO      EQU   2                                                        67090018
THREE    EQU   3                                                        67110018
L3       EQU   3                                                        67150018
NINE     EQU   9                                                        67170018
RSTRT    EQU   8                                                        67190018
ZEROES   EQU   8                                                        67210018
TWLVE    EQU   12                                                       67230018
CON17    EQU   17                                                       67250018
L86      EQU   86                                                       67270018
BLANK    EQU   C' '                                                     67290018
PERIOD   EQU   C'.'                                                     67310018
REPLEN4  EQU   4                                                        67330018
OFFSW1   EQU   X'F3'              MASK TO TURN OFF RESTART BITS IN SW1  67350018
*                                                                       67600017
*                                                                       67800017
*                                                                       68000017
         EJECT                                                          68200017
         DS    0D                                                       68400017
MSG      DSECT                                                          68600017
MSGWTOR  DS    CL12               WTOR HEADER AREA                      68860018
         ORG   MSGWTOR            ORG BACK TO DIVIDE AREA               68920018
MSGREPL DS     1C                  REPLY LENGTH                         69000017
MSGREPAD DS    3C                  REPLY AREA ADDRESS                   69200017
MSGECBAD DS   F                    REPLY ECB ADDRESS                    69400017
MSGHDR   DS   F                    MESSAGE HEADER                       69600017
MSGBUF   DS   15C                  1ST OF MESSAGE 'IEF225A SHOULD'      69800017
MSGJOB   DS   CL8                  JOBNAME                              69900018
MSGPT1   DS    C                  SEPARATOR .                           70000018
MSGSTEP  DS   CL8                 STEPNAME                              70100018
MSGPT2   DS    C                  SEPARATOR .                           70200018
MSGPROC  DS   CL8                 PROCSTEP                              70300018
         DS    C                  SEPARATOR                             70400018
MSGCHKID DS    CL16               CHECKPOINT ID                         70500018
         DS    C                  SEPARATOR                             70600018
MSGMSG1  DS    CL7                 'RESTART'                      M0092 70700018
MSGMCS   DS    CL4                 MCS ROUTING AND DEXC CODES     M0092 70800018
MSGREPLY DS    F                   REPLY AREA                     M0092 70900018
MSGLGT   EQU   MSGREPLY-MSGBUF     MESSAGE LENGTH                       71200017
MSGECB   DS    F                   REPLY ECB                            71400017
         DS    0D                                                       71490018
ERRMSG   DSECT                                                          71580018
ERRHDR   DS    F                  MSG LEN + HALFWORD OF ZEROES          71670018
         ORG   ERRHDR             ORG BACK TO DIVIDE HEADER             71760018
         DS    C                  DISPLACEMENT TO LENGTH OF MSG         71850018
ERRLEN   DS    C                  LENGTH OF MESSAGE                     71940018
         DS    H                  MCSFLAG GO HERE                       72030018
ERRMSGID DS    CL8                'IEF228I '                            72120018
ERRJNAME DS    CL8                'JOBNAME '                            72210018
ERRMSGP2 DS    CL50               ' RESTART CANCELLED - IOERR...'       72300018
         DS    0D                                                       72400017
RPCORE   DSECT                                                          72600017
QMRWL    DS    F                  DSECT OF EXTERNAL                     72800018
QMRWT    DS    F                  PARAMETERS FOR                        73000018
TTRSAVE  DS    F                  QUEUE MANAGER                         73200018
READIN   EQU   *                                                        73400017
PDQ      DSECT                                                          73600017
         IEFPDQBK                                                       73800017
         EJECT                                                          74000017
LCT      DSECT                                                          74200017
         IEFALLCT                                                       74400017
         EJECT                                                          74600017
JCT      DSECT                                                          74800017
         IEFAJCTB                                                       75000017
         EJECT                                                          75200017
SCT      DSECT                                                          75400017
         IEFASCTB                                                       75600017
         EJECT                                                          75800017
         IEFQMPAM                                                       76000017
         EJECT                                                          76010017
TIOT     DSECT                                                          76020017
         IEFTIOT1                                                       76030017
         EJECT                                                          76040017
CVT      DSECT                                                          76050017
         CVT                                                            76060017
PCPSYS   EQU   X'40'                                                    76065018
         EJECT                                                          76070017
UCB      DSECT                                                          76080017
         IEFUCBOB                                                       76090017
         EJECT                                                          76100017
TCB      DSECT                                                          76110017
         DS    3F                 DISPLACEMENT IN TCB                   76130018
TCBTIO   DS    F                  TO PTR TO JOBS TIOT                   76150018
TCBCMP   DS    F                  TASK COMPLETION CODE                  76170018
         END                                                            76200017
