  TITLE  'IEFSD002'                                                     00020000
*  PURPOSE-    TO DETERMINE IF A RETURN TO INTERPRETER IS INDICATED AT  00040000
*              STEP TERM, AND IF SO, TO PERFORM APPROPRIATE INTERFACE.  00060000
         SPACE 2                                                        00080000
*  INPUT REQ-  PASSREG POINTS TO A GOTTEN CORE PARAMETER LIST WHICH     00100000
*              CONTAINS POINTERS TO THE INITIATOR'S                     00120000
*                            LINKAGE CONTROL TABLE,                     00140000
*                            THE JOB CONTROL TABLE, AND                 00160000
*                            THE STEP CONTROL TABLE                     00180000
*              RESPECTIVELY.  (EACH IN GOTTEN CORE.)                    00200000
         SPACE                                                          00220000
*  OUTPUT REQ- 1. IF MORE JOB STEPS ARE ENQUEUED, PASS THE LCT AND JCT  00240000
*                 ON TO THE INITIATOR.                                  00260000
*              2. IF NO MORE STEPS ARE ENQUEUED (INDICATING A DD* CARD  00280000
*                 WAS ENCOUNTERED BY INTERPRETER SINCE THIS IS STEP     00300000
*                 TERM CONDITION ONLY)-- PASS THE JCT BACK TO INTERPRTR 00320000
         SPACE 2                                                        00340000
*  METHOD-     A STEP CONTROL TABLE FLAG INDICATES WHETHER OR NOT MORE  00360000
*              STEPS ARE ENQUEUED.  THE LCT IS PRESERVED BY A ROUTINE   00380000
*              WHICH MANAGES THE PRE-EMPTIVE TRACK AREA ON THE JOB      00400000
*              QUEUE.  THIS PROGRAM IS REENTRANT.                       00420000
         SPACE 2                                                        00440000
*  PARAMETERS-                                                          00460000
*                     B I T  D E S C R I P T O R                        00480000
STEPSQED EQU   X'40'   SCT FLAG INDICATING MORE STEPS ENQUEUED WHEN OFF 00500000
*                     D I S P L A C E M E N T S                         00520000
LCTBACK  EQU   0 LCT PTR DISPLACEMENT IN RETURN PARAMETER LIST.         00540000
JCTBACK  EQU   4 JCT PTR DISPLACEMENT IN RETURN PARAMETER LIST.         00560000
*                        R E G I S T E R S                              00580000
R0       EQU   0                                                   AACA 00590017
PASSREG  EQU   1 PRIMARY PARAMETER PASSING                              00600000
R1       EQU   1                                                   AACA 00610017
SCTBASE EQU    2 STEP CONTROL TABLE BASE                                00620000
R2       EQU   2                                                   AACA 00630017
INPUT    EQU   3 INPUT PARAMETER LIST REFERENCE                         00640000
R3       EQU   3                                                   AACA 00650017
DUMPLIST EQU   4 PARAMETER LIST TO TABLE DUMP ROUTINE.                  00660000
R4       EQU   4                                                   AACA 00670017
SAVEREG  EQU   4 HOLDING AREA                                           00680000
EXIT     EQU   5 EXIT SELECTION REG                                     00700000
R5       EQU   5                                                   AACA 00710017
BASEREG EQU    6 INSTRUCTION BASE                                       00720000
R6       EQU   6                                                   AACA 00730017
JCTBASE  EQU   7                                                        00740000
R7       EQU   7                                                   AACA 00742017
R8       EQU   8                                                   AACA 00744017
R9       EQU   9                                                   AACA 00746017
RA       EQU   10                                                  AACA 00748017
RB       EQU   11                                                  AACA 00750017
RC       EQU   12                                                  AACA 00752017
SAVEAREA EQU   13 STANDARD LINKAGE SAVE AREA                            00760000
RD       EQU   13                                                  AACA 00770017
LINKREG EQU    14 LINKING RETURN POINT                                  00780000
RE       EQU   14                                                  AACA 00790017
ENTRY    EQU   15 LINKING ENTRY POINT                                   00800000
RF       EQU   15                                                  AACA 00810017
         EJECT                                                          00820000
INLIST   DSECT                                                          00840000
         SPACE                                                          00860000
LCT      DS    A LCT PTR                **************************      00880000
JCT      DS    A JCT PTR                ** INPUT PARAMETER LIST **      00900000
SCT      DS    A SCT PTR                **************************      00920000
         SPACE 5                                                        00940000
DMPLIST  DSECT                                                          00960000
         SPACE                                                          00980000
OPERATOR DS    F READ OR WRITE          ******************************* 01000000
FBA      DS    A TABLE TO DUMP          ** TABLE DUMP PARAMETER LIST ** 01020000
RECNBR   DS    F LOGICAL POSITION       ******************************* 01040000
         SPACE 3                                                        01060000
********** LAYOUT OF PREEMPTIVE AREA OF JOB QUEUE ************          01080000
         SPACE                                                          01100000
         IEFSD005                                                       01120000
         EJECT                                                          01140000
SCTDSECT DSECT                         DESCRIBE THE SCT                 01160000
         IEFASCTB                                                       01180000
JCTDSECT DSECT                                                          01200000
         IEFAJCTB                                                       01220000
         IEFQMNGR                                                  AACA 01230017
         SPACE 10                                                       01240000
IEFSD002 CSECT                                                          01260000
*2347015800-019200,020800                                          AACA 01270017
         SPACE                                                          01280000
         USING INLIST,INPUT            INPUT PARAMETER LIST             01300000
         USING SCTDSECT,SCTBASE        STEP CONTROL TABLE               01320000
         USING JCTDSECT,JCTBASE                                         01340000
         USING DMPLIST,DUMPLIST        TABLE SAVE ARGUMENT LIST         01360000
         USING IEFSD002+2,BASEREG      INSTRUCTION BASE                 01380000
         SPACE                                                          01400000
         BALR  BASEREG,0                                                01420000
         B     SD002                                               AACA 01423017
         DC    4X'11'              LOCATOR                         AACA 01426017
         DC    X'2068'             DATE 7/24/68                    AACA 01429017
         DC    C'IEFSD002'                                         AACA 01432017
SD002    DS    0H                                                  AACA 01435017
         EJECT                                                          01440000
         LR    INPUT,PASSREG           ESTABLISH PARAMETER LIST.        01460000
         L     SCTBASE,SCT             RETRIEVE SCT ADDRESS FROM LIST.  01480000
         L     JCTBASE,JCT             RETRIEVE JCT ADDRESS             01500000
         TM    SCTSSTAT,INCMSSTS       IS STEP CANCELLED SW ON          01520000
         BZ    CONT                    BRANCH IF NOT ON                 01540000
         OI    JCTJSTAT,JCTJSTPC       SET CONDITION CODE SW IN JCT ON  01560000
CONT     EQU   *                                                   AACA 01580017
         GETMAIN R,LV=296          GET WORKAREA                    AACA 01600017
         TM    JCTRSW1,JCTCKPTR+JCTSTEPR Q. C/R FLAGES ON          AACA 01620017
         BNZ   CONTA                      BR - YES                 AACA 01640017
         TM    SCTSTYPE,STEPSQED   Q. MORE STEPS QUEUED            AACA 01660017
         BZ    RETURN               YES, RETURN TO INITIATOR       AACA 01680017
CONTA    EQU   *                                                   AACA 01700017
         LA    RD,16(R1)           LOCATE SAVE AREA                AACA 01720017
         LR    DUMPLIST,PASSREG    LOCATE ARGUMENTS                AACA 01740017
         MVC   OPERATOR(4),OPCODE  SET UP ARGUMENT LIST SUFFICIENT AACA 01760017
         MVC   FBA(4),LCT          TO DUMP LCT TO PREEMPTIVE       AACA 01780017
         LA    PASSREG,SDLCT       TRACK STACK.                    AACA 01800017
         ST    PASSREG,RECNBR      ***                             AACA 01820017
         LR    PASSREG,DUMPLIST    SAVE LCT                        AACA 01840017
         L     ENTRY,SNAPOUT       ***                             AACA 01860017
         BALR  LINKREG,ENTRY       ***                             AACA 01880017
         FREEMAIN R,LV=296,A=(DUMPLIST) FREE WORKAREA              AACA 01900017
         SPACE                                                          01940000
         GETMAIN R,LV=8                GET INTERPRETER PASS AREA.       01960000
         XC    0(8,1),0(1)                                              01970014
         SPACE                                                          01980000
         MVC   0(4,1),JCT              CREATE PARAMETER TO PASS.        02000000
         LA    EXIT,INTRPRTR            RETURN VIA INT. INTERFACE.      02020000
         B     FREESCT                 GO TO FREE CORE FOR SCT.         02040000
         SPACE 2                                                        02060000
RETURN   EQU   *                                                   AACA 02061017
         LR    R8,RD               SAVE REG SAVE AREA ADDR.        AACA 02062017
         LR    RD,R1               SET UP SAVE AREA                AACA 02063017
         LA    R1,SDLCT            CONVERT LCT                     AACA 02064017
         L     RF,SD006             RECORD NO. TO                  AACA 02065017
         BALR  RE,RF                A TTR                          AACA 02066017
         LR    R0,R1               SAVE TTR                        AACA 02067017
         LR    R1,RD               RESTORE GOTTEN AREA ADDR.       AACA 02068017
         LA    R1,72(R1)           UPDATE TO QMPA AREA             AACA 02069017
         USING IOPARAMS,R1                                         AACA 02070017
         XC    0(36,R1),0(R1)      CLEAR QMPA AREA                 AACA 02071017
         LA    RF,36(R1)           UPDATE TO EXTERN PARM AREA AND  AACA 02072017
         ST    RF,QMPCL            SAVE IN QMPA                    AACA 02073017
         MVI   QMPOP,QMWRTE        OPERATION IS TO WRITE           AACA 02074017
         MVI   QMPNC,1             SET NO. OF RECORDS TO WRITE     AACA 02075017
         LA    RE,120(RD)          LOAD ADDR. OF NEW LCT AREA      AACA 02076017
         ST    RE,0(RF)            STORE AS OUTPUT AREA            AACA 02077017
         L     R8,0(R3)            LOAD LCT ADDR.                  AACA 02078017
         L     R9,0(R8)            LOAD LCT LENGTH                 AACA 02079017
         BCTR  R9,0                REDUCE BY 1                     AACA 02080017
         EX    R9,MOVE             MOVE LCT TO NEW AREA TO WRITE   AACA 02081017
         ST    R0,4(RF)             FOR Q-MAN                      AACA 02082017
         L     RF,QMAN             EXIT TO                         AACA 02083017
         BALR  RE,RF                Q-MAN                          AACA 02084017
         LR    R1,RD               SET UP TO FREE                  AACA 02085017
         LA    R1,8(R1)            UPDATE AREA POINTER TO FREE     AACA 02086017
*                                   ALL BUT 8 BYTES OF GOTTEN CORE AACA 02087017
*                                   THESE 8 BYTES WILL BE USED FOR AACA 02088017
*                                   THE PARAMETER LIST PASSED.     AACA 02089017
         LA    R0,288              LENGTH TO FREE                  AACA 02090017
         FREEMAIN R,LV=(0),A=(1)   FREE UP AREA                    AACA 02091017
         LR    R1,RD               ADDR. OF PARM AREA TO PARM REG  AACA 02092017
         LR    RD,R8               RESTORE REG SAVE AREA           AACA 02093017
         SPACE                                                          02100000
         MVC   LCTBACK(4,1),LCT        USE TWO MOVES INTO PARAM LIST    02120000
         MVC   JCTBACK(4,1),JCT         FOR SYSFLEX.                    02140000
         LA    EXIT,INITIATR            RETURN VIA INIT. INTERFACE.     02160000
         EJECT                                                          02180000
FREESCT  LR    SAVEREG,1                SAVE OUTPUT LIST POINTER        02200000
         FREEMAIN R,LV=176,A=(SCTBASE) FREE THE SCT.......              02220000
         DROP  SCTBASE                                                  02240000
         SPACE                                                          02260000
         FREEMAIN R,LV=16,A=(INPUT)    FREE THE INPUT PARAMETER LIST.   02280000
         DROP  INPUT                                                    02300000
         SPACE                                                          02320000
         LR    PASSREG,SAVEREG          GET POINTER TO PASS.            02340000
         BR    EXIT                     GO TO INIT OR INT AS SELECTED.  02360000
         SPACE 5                                                        02380000
INTRPRTR L     15,RDRINTPR                                              02400000
         BR    15                      GO TO RDR INT INTERFACE          02420000
         SPACE 2                                                        02440000
INITIATR L     ENTRY,OUT                GET SUFFIX ENTRY POINT          02460000
         BR    ENTRY                    GO TO SUFFIX                    02480000
MOVE     MVC   0(1,RE),0(R8)                                       AACA 02490017
         SPACE 2                                                        02500000
SNAPOUT  DC    V(IEFSD007)              TABLE SAVE ROUTINE              02520000
RDRINTPR DC    V(IEFSD008)             INTERPRETER INTERFACE            02540000
OUT      DC    V(IEFSD009)              SUFFIX ROUTINE (TO INITIATOR)   02560000
QMAN     DC    V(IEFQMSSS)         Q-MANAGER RTN                   AACA 02566017
SD006    DC    V(IEFSD006)         CONVERT REC. NO. TO TTR RTN     AACA 02572017
OPCODE   DC    F'3'    WRITE (STORE) INDICATOR FOR TABLE SAVE ROUTINE.  02580000
         END IEFSD002                                                   02600000
