  TITLE  'IEFSD006'                                                     00020000
*********************************************************************** 00040000
*                                                                     * 00060000
*                       RECORD NUMBER TO TTR CONVERSION ROUTINE       * 00080000
* FUNCTION: CONVERTS A RECORD NUMBER TO A TTR.  A RECORD NUMBER IS THE* 00100000
* NUMBER OF THE LOGICAL RECORD ON THE DISK.  RECORD NUMBERS BEGIN WITH* 00120000
* ZERO.                                                               * 00140000
* ENTRY POINTS: IEFSD006                                              * 00160000
* INPUT: THE RECORD NUMBER RIGHT JUSTIFIED IN GENERAL REGISTER 1 AND  * 00180000
* THE ADDRESS OF AN 18 WORD, USER SUPPLIED, REGISTER SAVE AREA IN     * 00200000
* GENERAL REGISTER 13.                                                * 00220000
* OUTPUT: A 3 BYTE TTR LEFT JUSTIFIED IN REGISTER 1.                  * 00240000
* EXITS: BRANCH ON GENERAL REGISTER 14.                               * 00260000
* TABLES/WORK AREAS: THIS ROUTINE USES THE NUMBER OF RECORDS PER TRACK* 00280000
* ENTRY IN THE SCHEDULER COMMUNICATIONS AREA.                         * 00300000
*                                                                     * 00320000
*********************************************************************** 00340000
IEFSD006 CSECT                                                          00360000
         STM   R13,R12,8(R13)           SAVE USERS REGISTERS IN AN AREA 00380000
*                                       PROVIDED BY THE USING MODULE    00400000
         BALR  R9,0                     LOAD PROGRAM BASE REGISTER      00420000
         USING *,R9                                                     00440000
         L     R10,COMMVEC              LOAD ADDR.OF COMMUNICATIONS     00460000
*                                       VECTOR TABLE                    00480000
         L     R10,IEFJOB(R10)          LOAD ADDR.OF SCHED.COM.AREA     00500000
         SR    R8,R8                    CLEAR REGISTER                  00520000
         IC    R8,SCARECPT(R10)         LOAD NUMBER OF RECORDS PER TRK  00540000
         SR    R6,R6                    CLEAR REGISTER FOR DIVIDE       00560000
         LR    R7,R1                    LOAD RECORD NUMBER              00580000
         DR    R6,R8                    DIVIDE NUMBER OF RECORDS PER    00600000
*                                       TRK INTO RECORD NUMBER          00620000
         A     R6,KONE                  ADJUST RECORD BY ONE            00640000
         SLL   R6,8                     SET RECORD TO BYTE 3            00660000
         SLL   R7,16                    SET TRACK TO BYTES 1 AND 2      00680000
         OR    R6,R7                    FORM TTR                        00700000
         ST    R6,24(R13)               STORE TTR IN RETURN REGISTER    00720000
         LM    R13,R12,8(R13)           RESTORE USERS REGISTERS         00740000
         RETURN                                                         00760000
*********************************************************************** 00780000
*                          ** GENERAL REGISTERS **                    * 00800000
*********************************************************************** 00820000
R0       EQU   0                                                        00840000
R1       EQU   1                                                        00860000
R2       EQU   2                                                        00880000
R3       EQU   3                                                        00900000
R4       EQU   4                                                        00920000
R5       EQU   5                                                        00940000
R6       EQU   6                                                        00960000
R7       EQU   7                                                        00980000
R8       EQU   8                                                        01000000
R9       EQU   9                                                        01020000
R10      EQU   10                                                       01040000
R11      EQU   11                                                       01060000
R12      EQU   12                                                       01080000
R13      EQU   13                                                       01100000
R14      EQU   14                                                       01120000
R15      EQU   15                                                       01140000
*********************************************************************** 01160000
*                          ** CONSTANTS FOR PROGRAM **                * 01180000
*********************************************************************** 01200000
KONE     DC    F'1'                                                     01220000
*********************************************************************** 01240000
*                THE FOLLOWING VALUES ARE USED AS OFFSETS FROM AN     * 01260000
*              ABSOLUTE CORE ADDRESS OR FROM AN ADDRESS WHICH CAN  BE * 01280000
*              FOUND AT A KNOWN ADDRESS AT EXECUTION TIME.  IF ANY OF * 01300000
*              THE OFFSETS CHANGE THE PROGRAM MUST BE REASSEMBLED     * 01320000
*********************************************************************** 01340000
COMMVEC  EQU   16                       OFFSET FROM THE BEGINNING OF    01360000
*                                       CORE TO THE LOCATION CONTAINING 01380000
*                                       THE ADDRESS OF THE COMMUNICA-   01400000
*                                       TIONS VECTOR TABLE              01420000
IEFJOB   EQU   12                       OFFSET FROM THE BEGINNING OF    01440000
*                                       THE COMMUNICATIONS VECTOR       01460000
*                                       TABLE TO THE WORD CONTAINING    01480000
*                                       THE ADDRESS OF THE SCHEDULER    01500000
*                                       COMMUNICATIONS AREA             01520000
SCARECPT EQU   108                      THE OFFSET IN THE SCHEDULER     01540000
*                                       COMMUNICATIONS AREA TO THE      01560000
*                                       BYTE CONTAINING THE NUMBER      01580000
*                                       OF RECORDS PER TRACK            01600000
*                                                                       01620000
 ENTRY IEFHAF4,IEFSD016,IEFSYSP,IEFW1FAK,IEFW2FAK,IEFYT     KGN - SPS   01640000
*                                                                       01660000
*THIS CODE EXISTS FOR THE SOLE PURPOSE OF PREVENTING UNRESOLVED         01680000
*SYMBOLS FROM APPEARING WHEN THE SCHEDULER IS LINK-EDITED. ADCONS ALLOW 01700000
*DIRECT BRANCHING TO THIS CODE UNTIL ROUTINES ARE ADDED TO PERFORM      01720000
*THE DEFERRED FUNCTIONS. THIS CODE IS LOADED IN EACH LOAD MODULE IF THE 01740000
*FOLLOWING ARE REFERENCED:                                              01760000
*                                                                       01780000
IEFHAF4  EQU   *                                                        01800000
IEFSYSP  EQU   *                                                        01820000
         DC    H'0'      NOT TO BE REFERENCED                           01840000
IEFSD016 EQU   *                                                        01860000
IEFYT    EQU   *                                                        01880000
         BCR   15,14     RETURN ON 14                                   01900000
*NON-SETUP PADDING MODULE. ENTERED FROM IEFWD000,EXITS TO INITIATOR.    01920000
IEFW1FAK EQU   *                                                        01940000
*PROJECTED MOUNT MODULE. ENTERED FROM IEFWD000, EXITS TO INITIATOR.     01960000
IEFW2FAK EQU   *                                                        01980000
         BCR   15,15     RETURN ON 15                                   02000000
*                                                                       02020000
         END                                                            02040000
