  TITLE  'IEFSD007'                                                     00020000
*********************************************************************** 00020714
*        THE IWA MACRO, IEFVMIWA, MUST BE FOLLOWED BY THE MACRO FOR   * 00021414
* THE NEL, IEFH1NEL.                                                  * 00022114
*********************************************************************** 00022814
         IEFVMIWA                                                       00023514
         IEFNEL                                                         00024218
NELEND   DS    0H                                                       00036814
* IEFVMEWA IS USED HERE BECAUSE IT IS THE LARGEST OF THE PRIVATE  15765 00037017
* MACROS -- IT WAS IEFVMDWA                                       15765 00037217
         IEFVMEWA                                                       00037717
ENDLAREA EQU   *                                                        00038214
*********************************************************************** 00040000
*                          ** THIS MODULE IS RE-ENTERABLE **          * 00060000
*                                                                     * 00080000
*                       READ/WRITE ROUTINE                            * 00100000
* FUNCTION: TO READ OR WRITE VARIABLE SIZE TABLES USED BY THE JOB     * 00120000
* SCHEDULER.                                                          * 00140000
* ENTRY POINTS: IEFSD007                                              * 00160000
* INPUT: A 3 WORD PARAMETER LIST WHOSE ADDRESS IS IN GENERAL REGISTER * 00180000
* 1 AND THE ADDRESS OF AN 18 WORD, USER SUPPLIED, REGISTER SAVE AREA  * 00200000
* IN GENERAL REGISTER 13.  THE PARAMETER LIST IS AS FOLLOWS:          * 00220000
* 1ST WORD IS THE OPERATION CODE, 2ND WORD IS THE CORE ADDRESS OF THE * 00240000
* RECORD, 3RD WORD IS THE RECORD NUMBER OF THE RECORD.  ALL VALUES ARE* 00260000
* RIGHT JUSTIFIED.  THE OPERATION CODES ARE 4 FOR A READ AND 3 FOR A  * 00280000
* WRITE.                                                              * 00300000
* OUTPUT: ON A READ, THE RECORD IN CORE AND THE ADDRESS OF THE RECORD * 00320000
* IN THE SECOND WORD OF THE PARAMETER LIST.  ON A WRITE, RECORD ON    * 00340000
* DISK AND THE CORE OCCUPIED BY THE RECORD FREED.                     * 00360000
* EXTERNAL REFERENCES: THE RECORD NUMBER TO TTR CONVERSION ROUTINE    * 00380000
* (IEFSD006) AND THE QUEUE MANAGER (IEFQMSSS)                         * 00400000
* EXITS: BRANCH ON GENERAL REGISTER 14.                               * 00420000
* NOTES: THE FIRST WORD OF THE RECORD MUST CONTAIN THE ENTIRE LENGTH  * 00440000
* (INCLUDING LENGTH FIELD) OF THE RECORD.  THE VALUE IN THIS WORD     * 00460000
* MUST BE RIGHT JUSTIFIED.                                            * 00480000
*                                                                     * 00500000
*              THE LENGTH OF THE INTERPRETER WORK AREA IS DEFINED IN  * 00520000
*              AN 'EQU' STATEMENT.  SHOULD THE LENGTH OF THIS AREA    * 00540000
*              CHANGE, THIS 'EQU' STATEMENT MUST BE CHANGED TO REFLECT* 00560000
*              THE NEW LENGTH.                                        * 00580000
*                                                                     * 00600000
* TABLES/WORK AREAS: THIS ROUTINE USES THE NUMBER OF RECORDS PER TRACK* 00620000
* ENTRY IN THE SCHEDULER COMMUNICATIONS AREA.                         * 00640000
*                                                                     * 00660000
*                                                                     * 00680000
*                                                                     * 00700000
*              THE OPERATION OF THIS CONTROL SECTION DEPENDS UPON AN    00720000
*              INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET    00740000
*              WHICH IS EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.    00760000
*              THE CODING HAS BEEN ARRANGED SO THAT REDEFINITION OF     00780000
*              'CHARACTER' CONSTANTS, BY REASSEMBLY, WILL RESULT IN A   00800000
*              CORRECT MODULE FOR THE NEW DEFINITIONS.                  00820000
*                                                                     * 00840000
*                                                                     * 00860000
*********************************************************************** 00880000
IEFSD007 CSECT                                                          00900000
*1160061406-062000                                                15951 00910017
         STM   R0,R15,0(R13)            STORE REGISTERS IN AN AREA      00920000
*                                       PROVIDED BY THE USING MODULE    00940000
*                                       AND POINTED TO BY REG.13        00960000
         BALR  R9,0                     SET UP THE PROGRAMS BASE REG.   00980000
         USING *,R9                                                     01000000
         CLI   10(R1),X'00'        IS THE PARAMETER A RECORD NUMBER     01020000
         BNE   NORECNUM            NO                                   01040000
         CLI   11(R1),SDIWA                                             01060000
         BE    IWARTN              YES                                  01080000
NORECNUM LM    R2,R4,0(R1)         LOAD PARAMETER LIST                  01100000
         LR    R6,R1                    SAVE ADDRESS OF USERS PARAMETER 01120000
*                                       LIST IN GENERAL REGISTER SIX    01140000
         USING IOPARAMS,R1              IOPARAMS IS A DSECT DEFINING    01160000
*                                       THE QMGR.PARAMETER AREA         01180000
         LA    R0,QKPOOLSZ              LOAD LENGTH OF CORE TO BE       01200000
*                                       GOTTEN. THIS AREA WILL CONTAIN  01220000
*                                       THE QMGR.PARA.AREA,A REGISTER   01240000
*                                       SAVE AREA AND A 176 BYTE BUFFER 01260000
         GETMAIN R,LV=(0)                                               01280000
         ST    R13,108(R1)              SAVE ADDR.OF USERS REGISTER     01300000
*                                       SAVE AREA                       01320000
         LR    R13,R1                   SET UP POINTER TO THIS MODULES  01340000
*                                       REG.SAVE AREA                   01360000
         CLI   10(R6),X'00'             DETERMINE IF THE THIRD PARA.    01380000
*                                       CONTAINS A RECORD NUMBER OR     01400000
*                                       A TTR                           01420000
         BC    7,QKTTR                  BRANCH IF IT IS A TTR           01440000
         LR    R1,R4                    LOAD RECORD NUMBER FOR RECORD   01460000
*                                       NUMBER TO TTR CONVERSION ROUT.  01480000
         L     R15,QKADDR1              LOAD ADDR. OF CONVERSION ROUT   01500000
         BALR  R14,R15                  BR.TO CONVERSION ROUT           01520000
         LR    R4,R1                    LOAD TTR                        01540000
         LR    R1,R13                   RESTORE R1                      01560000
QKTTR    LA    R0,100(R1)               CALCULATE ADDR.OF QMGR EXTERNAL 01580000
*                                       PARAMETERS                      01600000
         LA    R1,64(R1)                CALCULATE ADDR.OF QMGR.PARA     01620000
*                                       AREA                            01640000
         ST    R0,QMPCL                 STORE ADDR.OF EXTERNAL PARA IN  01660000
*                                       QMGR PARA AREA                  01680000
         MVI   QMPCL,QKNUMREC           STORE NUMBER OF RECORDS TO BE   01700000
*                                       READ OR WRITTEN                 01720000
         STC   R2,QMPOP                 STORE THE OPERATION CODE IN THE 01740000
*                                       QMGR.PARA AREA                  01760000
         ST    R4,0(R13)                STORE DISK ADDR.IN TEMP.HOLD    01780000
*                                       SO A LIMIT FIELD CAN BE         01800000
*                                       CONSTRUCTED                     01820000
         L     R8,COMMVEC               LOAD ADDR.OF COMM VECTOR TABLE  01840000
         L     R8,IEFJOB(R8)            LOAD ADDR. OF SCA               01860000
         MVC   2(1,R13),SCARECPT(R8)    MOVE NUMBER OF RECORDS PER      01880000
*                                       TRACK INTO LIMIT FIELD          01900000
         L     R2,0(R13)                LOAD LIMIT FIELD                01920000
         STM   R15,R1,288(R13)                                          01940014
*                                       SAVE                            01960000
         CLI   QMPOP,QKWTCODE           IS IT A WRITE OPERATION         01980000
         BC    8,QKWRITE                BRANCH YES                      02000000
QKREAD   LA    R0,112(R13)              LOAD ADDR.OF BUFFER AREA        02020000
         ST    R0,100(R13)              STORE CORE ADDR.IN EXTERN PARA  02040000
         ST    R4,104(R13)              STORE DISK ADDR.IN EXTERN PARA  02060000
         L     R15,QKADDR2              LOAD ADDR. OF QMGR.             02080000
         BALR  R14,R15                  GO TO QMGR.                     02100000
QKREADA  L     R5,112(R13)              LOAD LENGTH OF RECORD           02120000
         LR    R0,R5                    SET UP TO GET CORE FOR THE REC. 02140000
         GETMAIN R,LV=(0)                                               02160000
         LR    R3,R1                    MOVE ADDR.OF CORE TO GENERAL    02180000
         LR    R10,R1                   REGISTERS THREE AND TEN         02200000
         C     R5,QK176                 IS RECORD LENGTH LESS THAN OR   02220000
*                                       EQUAL TO 176 BYTES              02240000
         BH    QKREADB                  BRANCH NO                       02260000
         S     R5,QK1                   SUBTRACT ONE FROM LENGTH TO     02280000
*                                       SET UP FOR EXECUTE              02300000
         EX    R5,QKMOVEA               MOVE RECORD FROM BUFFER TO AREA 02320000
         LM    R15,R1,288(R13)                                          02340014
         BC    15,QKRET                 BRANCH TO EXIT                  02360000
QKREADB  MVC   0(176,R3),112(R13)       MOVE FIRST 176 BYTE PORTION TO  02380000
*                                       RECORD AREA                     02400000
QKLOOP   LM    R15,R1,288(R13)                                          02420014
*                                       RESTORE                         02440000
         A     R3,QK176                 UPDATE CORE ADDRESS TO NEXT 176 02460000
*                                       BYTE PORTION                    02480000
         S     R5,QK176                 SUBTRACT 176 BYTES JUST         02500000
*                                       OPERATED ON FROM TOTAL LENGTH   02520000
*                                       OF THE RECORD                   02540000
         BC    8,QKRET                  BRANCH YES TO EXIT              02560000
         C     R5,QK176                 IS THE REMAINING PORTION LESS   02580000
*                                       THAN 176 BYTES                  02600000
         BNL   QKLOOPA                  BRANCH NO                       02620000
         AR    R3,R5                    OBTAIN A POINTER TO THE END OF  02640000
*                                       THE RECORD                      02660000
         S     R3,QK176                 ADJUST CORE ADDR.SO LAST RECORD 02680000
*                                       WILL BE 176 BYTES               02700000
         L     R5,QK176                 ADJUST LENGTH FIELD TO REFLECT  02720000
*                                       THIS                            02740000
QKLOOPA  CR    R4,R2                    HAS THE LAST RECORD OF THE      02760000
*                                       TRACK BEEN READ OR WRITTEN      02780000
         BC    7,QKLOOPB                BRANCH NO                       02800000
         A     R4,QKTRKCON              UPDATE TTR TO NEXT TRACK        02820000
         N     R4,QKTMASK               ZERO RECORD PORTION OF TTR      02840000
         A     R2,QKTRKCON              UPDATE LIMIT FIELD TO NEXT TRK  02860000
QKLOOPB  A     R4,QKRECCON              UPDATE TTR TO NEXT RECORD       02880000
QKLOOPC  STM   R3,R4,100(R13)           STORE EXTERN PARAMETERS         02900000
         L     R15,QKADDR2              LOAD ADDR. OF QMGR.             02920000
         BALR  R14,R15                  GO TO QMGR.                     02940000
         B     QKLOOP              CONTINUE                             02960000
QKWRITE  LR    R10,R3                   SAVE BEGINNING ADDR.OF RECORD   02980000
         L     R5,0(R3)                 LOAD LENGTH OF RECORD           03000000
         C     R5,QK176                 IS THE LENGTH OF THE RECORD     03020000
*                                       LESS THAN 176 BYTES             03040000
         BNL   QKLOOPC                  BRANCH NO                       03060000
         S     R5,QK1                   SUBTRACT ONE FROM LENGTH TO     03080000
*                                       SET UP FOR EXECUTE              03100000
         EX    R5,QKMOVEB               MOVE RECORD TO BUFFER           03120000
         LA    R3,112(R13)              LOAD ADDR.OF BUFFER AREA        03140000
         L     R5,QK176                 SET RECORD LENGTH TO 176 BYTES  03160000
         BC    15,QKLOOPC               BRANCH TO WRITE RECORD          03180000
QKRET    L     R7,108(R13)              LOAD ADDR.OF USERS REGISTERS    03200000
*                                       SAVE AREA                       03220000
         CLI   QMPOP,QKRDCODE           WAS IT A READ OPERATION         03240000
         BC    8,QKRETA                 BRANCH YES                      03260000
         LR    R1,R10                   LOAD ADDR.OF CORE THAT WAS      03280000
*                                       OCCUPIED BY RECORD              03300000
         L     R0,0(R1)                 LOAD LENGTH OF CORE             03320000
         FREEMAIN R,LV=(0),A=(1)                                        03340000
         BC    15,QKRETB                                                03360000
QKRETA   ST    R10,4(R6)                STORE ADDR.OF RECORD JUST READ  03380000
QKRETB   LR    R1,R13                   LOAD ADDR.OF CORE FOR THIS      03400000
*                                       MODULE                          03420000
         LA    R0,QKPOOLSZ              LOAD LENGTH OF CORE             03440000
         FREEMAIN R,LV=(0),A=(1)                                        03460000
         CLI   10(R6),X'00'             DID USERS PASS A TTR            03480000
         BC    8,QKRETD                 BRANCH NO TTR                   03500000
         CR    R4,R2                    DOES GR4 CONTAIN A TTR OF THE   03520000
*                                       LAST RECORD OF A TRACK          03540000
         BC    7,QKRETC                 BRANCH NO                       03560000
         A     R4,QKTRKCON              UPDATE TTR TO NEXT TRACK        03580000
         N     R4,QKTMASK               ZERO RECORD PORTION OF TTR      03600000
QKRETC   A     R4,QKRECCON              UPDATE TTR TO NEXT RECORD       03620000
         L     R6,16               KGN  GET CVT ADDRESS                 03640000
         L     R6,160(0,R6)        KGN  GET HIGH PRIORITY TCB ADDRESS   03660000
         L     R6,116(0,R6)        KGN  IS THERE MORE THAN ONE TCB      03680000
         LTR   R6,R6               KGN                                  03700000
         BNE   SPSCODE             KGN  YES - USE SPS CODE              03720000
         ST    R4,BUMPTTR(R8)           STORE LAST TTR USED PLUS ONE    03740000
         B     QKRETD              KGN                                  03760000
BUMPTTRS EQU   120                 KGN                                  03780000
SPSCODE  ST    R4,BUMPTTRS(R8)     KGN  STORE LAST TTR USED PLUS ONE    03800000
QKRETD   LM    R0,R15,0(R7)             LOAD USERS REGISTERS            03820000
         RETURN                                                         03840000
         IEFSD005                                                       03860000
IECPCNVT EQU   28                                                       03880000
IWARTN   LR    R3,R1               SAVE POINTER TO PARAMETER LIST       03900000
         L     R7,IWALEN           GET LENGTH OF IWA                    03920000
         SR    R6,R6                                                    03940000
         D     R6,QK176            GET THE NUMBER OF 176 BYTE RECORDS   03960000
*                                  THAT ARE TO BE PROCESSED             03980000
         LR    R5,R7                                                    04000000
         LTR   R6,R6               IS THERE A REMAINDER                 04020000
         BZ    *+8                 NO                                   04040000
         LA    R5,1(R5)            YES, GET NUMBER OF DATA COMMANDS     04060000
*                                  NEEDED FOR CHANNEL PROGRAM           04080000
         CLI   3(R3),X'04'         IS THIS A READ                       04100000
         BNE   WRITAREA            NO, IT'S A WRITE                     04120000
         SLL   R5,3                CALCULATE AMOUNT OF CORE NEEDED FOR  04140000
         LA    R5,16(R5)           THE CHANNEL PROGRAM.                 04160000
GETMAIN  LA    R0,END1-WORKAREA(R5) GET SIZE OF AREA FOR GETMAIN        04180000
         GETMAIN R,LV=(0)                                               04200000
         LR    R4,R1               SAVE POINTER TO WORKAREA             04220000
         USING WORKAREA,R4                                              04240000
         ST    R13,SAVE13          SAVE ADDRESS OF PASSED SAVE AREA     04260000
         XC    SD7ECB(END1-SD7ECB),SD7ECB    CLEAR 'IOB' AND 'ECB'      04280000
         LA    R13,SAVEAREA        GET ADDRESS OF NEW SAVE AREA         04300000
         STM   R5,R7,LENCHANP                                           04320000
         L     R1,8(R3)            GET RECORD NUMBER                    04340000
         L     R15,QKADDR1         GET POINTER TO 'RECORD NUMBER TO     04360000
*                                  TTR' CONVERSION ROUTINE.             04380000
         BALR  R14,R15             LINK TO CONVERT ROUTINE              04400000
         LR    R10,R1              SAVE TTR                             04420000
         ST    R10,MAXREC                                               04440000
         L     R6,COMMVEC          GET POINTER TO CVT                   04460000
         L     R6,IEFJOB(R6)       GET POINTER TO SCHEDULER OPENED DCB  04480000
         LR    R11,R6              SAVE IT                              04500000
         USING QJOB,R11                                                 04520000
         MVC   MAXREC+2(1),SCARECPT(R6) GET NUMBER OF RECORDS PER TRACK 04540000
         STM   R9,R13,SAVE                                              04560000
         LA    R1,SDEB             GET POINTER TO DEB                   04580000
         LR    R0,R10              GET TTR                              04600000
         LA    R2,MBBCCHHR         GET ADDRESS  FOR MBBCCHHR            04620000
         L     R15,COMMVEC         GET POINTER TO CVT                   04640000
         L     R15,IECPCNVT(R15)   GET POINTER TO 'TTR TO MBBCCHHR'     04660000
*                                  CONVERSION ROUTINE.                  04680000
         ST    R15,CONVERT         SAVE IT                              04700000
         BALR  R14,R15             LINK TO CONVERT ROUTINE              04720000
         LM    R9,R13,SAVE                                              04740000
* THE FOLLOWING INSTRUCTIONS SET UP THE IOB                           * 04760000
         MVI   SD7IOB,X'42'        INDICATE COMMAND CHAINING          * 04780000
         LA    R2,SD7ECB                                              * 04800000
         ST    R2,ADECB            SET UP 'ECB' ADDRESS               * 04820000
         LA    R2,END1                                                * 04840000
         ST    R2,ADCP             SET UP 'CHANNEL PROGRAM' ADDRESS   * 04860000
         ST    R11,ADDCB           SET UP 'DCB' ADDRESS               * 04880000
         L     R7,LMAX             GET MAXIMUM LENGTH FOR 'XC' INSTR.   04900000
LOOP1    CR    R5,R7               DOES THE LENGTH OF THE AREA TO BE    04920000
*                                  CLEARED EXCEED THE MAXIMUM VALUE.    04940000
         BNH   LASTXC              NO                                   04960000
         EX    R7,CLEAR            CLEAR 255 BYTES                      04980000
         SR    R5,R7               REDUCE LENGTH BY 255                 05000000
         S     R5,QK1              COMPENSATE FOR 'XC' INSTRUCTION      05020000
         BZ    XC256               NO                                   05040000
         LA    R2,1(R2,R7)         GET ADDRESS OF NEXT BLOCK TO BE      05060000
*                                  CLEARED.                             05080000
         B     LOOP1               CONTINUE                             05100000
CLEAR    XC    0(1,R2),0(R2)       CLEAR 'CHANNEL PROGRAM' AREA         05120000
LASTXC   S     R5,QK1              DECREMENT FOR 'XC' INSTRUCTION       05140000
         EX    R5,CLEAR            CLEAR LAST BLOCK OF CORE             05160000
XC256    L     R1,QK176            GET NORMAL RECORD LENGTH             05180000
         LA    R2,END1             GET POINTER TO BEGINNING OF THE      05200000
*                                  CHANNEL PROGRAM.                     05220000
         LA    R5,MBBCCHHR+3       GET POINTER TO 'CCHHR'               05240000
         ST    R5,0(R2)            STORE IT INTO SEARCH COMMAND         05260000
         MVI   0(R2),X'31'         SET UP 'SEARCH' COMMAND CODE         05280000
         MVI   4(R2),X'40'         INDICATE COMMAND CHAINING            05300000
         MVI   7(R2),X'05'         SET UP COUNT FIELD                   05320000
         ST    R2,8(R2)            SET UP ADDRESS FIELD FOR 'TIC'       05340000
         MVI   8(R2),X'08'         SET UP 'TIC' COMMAND CODE            05360000
         LA    R2,16(R2)           GET POINTER TO NEXT AVAILABLE SLOT   05380000
*                                  IN THE CHANNEL PROGRAM.              05400000
         L     R8,RECORDS                                               05420000
         CLI   3(R3),X'04'         IS THIS A READ                       05440000
         BNE   WRITECP             NO, IT'S A WRITE                     05460000
         L     R0,IWALEN           GET LENGTH OF IWA                    05480000
         GETMAIN R,LV=(0)          GETMAIN FOR IWA                      05500000
         LR    R12,R1                                                   05520000
         ST    R12,4(R3)           PUT POINTER TO IWQ INTO PARAMETER    05540000
*                                  LIST.                                05560000
         L     R1,QK176            GET NORMAL RECORD LENGTH             05580000
         ST    R12,0(R2)           SET UP DATA ADDRESS                  05600000
         MVI   0(R2),X'06'         SET UP FIRST READ COMMAND            05620000
         B     FIRSTRD             CONTINUE                             05640000
LOOP2    ST    R12,0(R2)           SET UP DATA ADDRESS                  05660000
         MVI   0(R2),X'86'         SET UP 'READ' COMMAND CODE WITH      05680000
*                                  MULTIPLE TRACK BIT ON.               05700000
FIRSTRD  ST    R1,4(R2)            SET UP COUNT FIELD                   05720000
         MVI   4(R2),X'40'         INDICATE COMMAND CHAINING            05740000
         AR    R12,R1              GET POINTER TO NEXT SLOT IN THE      05760000
*                                  INPUT BUFFER.                        05780000
         LA    R2,8(R2)            GET POINTER TO NEXT AVAILABLE SLOT   05800000
*                                  IN THE CHANNEL PROGRAM               05820000
         BCT   R8,LOOP2                                                 05840000
         L     R8,REMAIN           GET LENGTH OF SHORT RECORD           05860000
         LTR   R8,R8               IS IT ZERO                           05880000
         BC    8,NOREMAIN          YES                                  05900000
         ST    R12,CORE            SAVE ADDRESS OF LAST RECORD IN IWA   05920000
         LA    R12,BUFFER          GET BUFFER ADDRESS FOR LAST READ CCW 05940000
         ST    R12,0(R2)           SET UP DATA ADDRESS                  05960000
         MVI   0(R2),X'86'         SET UP LAST 'READ' COMMAND CODE WITH 05980000
*                                  MULTIPLE TRACK BIT ON.               06000000
         ST    R1,4(R2)            SET UP RECORD LENGTH                 06020000
ISSUEIO  EXCP  SD7IOB                                                   06040000
         WAIT  ECB=SD7ECB                                               06060000
         CLI   SD7ECB,X'7F'        WAS THERE AN I/O ERROR               06080000
         BNE   ERROR               YES                                  06100000
         CLI   3(R3),X'04'         IS THIS A READ                       06120000
         BE    SHORTREC            YES                                  06140000
         L     R1,4(R3)            GET ADDRESS OF AREA FOR FREEMAIN     06160017
         L     R0,IWALEN           GET LENGTH OF IWA                    06180017
         FREEMAIN  R,LV=(0),A=(1)                                       06200017
CLEANUP  L     R7,SAVE13           GET POINTER TO SAVE AREA THAT WAS    06220000
*                                  INITIALLY PASSED TO IEFSD007.        06240000
         L     R6,LENCHANP         GET CHANNEL PROGRAM LENGTH           06260000
         LA    R0,END1-WORKAREA(R6) GET LENGTH OF WORK AREA             06280000
         LR    R1,R4               GET ADDRESS OF WORK AREA             06300000
         FREEMAIN R,LV=(0),A=(1)   FREE WORKAREA UP                     06320000
         LM    R0,R15,0(R7)        RESTORE REGS.                        06340000
         BR    R14                 RETURN TO CALLER                     06360000
SHORTREC L     R8,REMAIN           GET SHORT RECORD LENGTH              06380000
         LTR   R8,R8               IS IT ZERO                           06400000
         BZ    CLEANUP             YES                                  06420000
         S     R8,QK1              DECREMENT FOR MOVE INSTRUCTION       06440000
         L     R12,CORE            GET ADDRESS OF LAST RECORD IN IWA    06460000
         EX    R8,MOVERD           MOVE SHORT RECORD TO IWA             06480000
         B     CLEANUP             CONTINUE                             06500000
MOVERD   MVC   0(1,R12),BUFFER                                          06520000
NOREMAIN SH    R2,FOUR                                                  06540000
         MVI   0(R2),X'00'         RESET COMMAND CHAINING BIT           06560000
         B     ISSUEIO             CONTINUE                             06580000
ERROR    WTO   'IEF400W I/O ERROR IN SCHEDULER WORK AREA'               06600000
         L     R1,ABENDCD                                               06620000
         ABEND (1)                                                      06640000
ABENDCD  DS    0F                                                       06660000
         DC    X'00B0000'                                               06680000
WRITAREA LR    R4,R5                                                    06700000
         MH    R5,BYTES24          CALCULATE SIZE OF CHANNEL PROGRAM    06720000
         LR    R12,R5              SAVE IT                              06740000
         MH    R4,FIVE             CALCULATE SIZE OF 'CCHHR' LIST       06760000
         SH    R4,FIVE                                                  06780000
         AR    R5,R4               GET TOTAL LENGTH                     06800000
         B     GETMAIN             CONTINUE                             06820000
WRITECP  LA    R5,END1(R12)        GET POINTER TO 'CCHHR' LIST          06840000
         L     R12,4(R3)           GET POINTER TO IWA                   06860000
         ST    R12,0(R2)           SET UP DATA ADDRESS                  06880000
         MVI   0(R2),X'05'         SET UP 'WRITE COMMAND CODE           06900000
         STH   R1,6(R2)            SET UP COUNT FIELD                   06920000
         MVI   4(R2),X'40'         INDICATE COMMAND CHAINING            06940000
         AR    R12,R1              GET POINTER TO NEXT RECORD IN IWA    06960000
         LA    R2,8(R2)            GET POINTER TO NEXT AVAILABLE SLOT   06980000
*                                  IN THE CHANNEL PROGRAM               07000000
         S     R8,QK1                                                   07020000
         MVC   CCHHR+3(5),MBBCCHHR+3 INITIALIZE 'CCHHR'                 07040000
LOOP3    A     R10,QKRECCON        BUMP 'R' OF 'TTR'                    07060000
         C     R10,MAXREC          IS THE MAXIMUM RECORD NUMBER         07080000
*                                  EXCEEDED                             07100000
         BH    CONVRSON            YES                                  07120000
         L     R14,CCHHR+4         GET CURRENT 'CHHR'                   07140000
         A     R14,QK1             UPDATE IT                            07160000
         ST    R14,CCHHR+4         RETURN UPDATED 'CHHR'                07180000
LOOP4    MVC   0(5,R5),CCHHR+3     MOVE 'CCHHR' TO 'CCHHR' LIST         07200000
         ST    R5,0(R2)            SET UP 'SEARCH' ADDRESS              07220000
         MVI   0(R2),X'B1'         SET UP 'SEARCH' COMMAND CODE WITH    07240000
*                                  MULTIPLE TRACK BIT ON.               07260000
         MVI   7(R2),X'05'         SET UP COUNT FIELD                   07280000
         MVI   4(R2),X'40'         INDICATE COMMAND CHAINING            07300000
         ST    R2,8(R2)            SET UP 'TIC' ADDRESS                 07320000
         MVI   8(R2),X'08'         SET UP 'TIC' COMMAND CODE            07340000
         ST    R12,16(R2)          SET UP DATA ADERESS                  07360000
         MVI   16(R2),X'05'        SET UP 'WRITE' COMMAND CODE          07380000
         ST    R1,20(R2)           SET UP COUNT FIELD                   07400000
         MVI   20(R2),X'40'        INDICATE COMMAND CHAINING            07420000
         AR    R12,R1              GET POINTER TO NEXT 176 BYTE RECORD  07440000
*                                  IN THE IWA.                          07460000
         LA    R2,24(R2)           GET POINTER TO NEXT SLOT IN THE      07480000
*                                  CHANNEL PROGRAM.                     07500000
         LA    R5,5(R5)            GET POINTER TO NEXT SLOT IN 'CCHHR'  07520000
*                                  LIST.                                07540000
         BCT   R8,LOOP3            CONTINUE                             07560000
         L     R8,REMAIN           GET SHORT RECORD LENGTH              07580000
         LTR   R8,R8               IS IT ZERO                           07600000
         BZ    NOREMAIN            YES                                  07620000
         S     R8,QK1              DECREMENT FOR MOVE INSTRUCTION       07640000
         EX    R8,MOVEWT           MOVE SHORT RECORD TO A 176 BYTE      07660000
*                                  BUFFER.                              07680000
         LA    R12,BUFFER          GET DATA ADDRESS FOR LAST CCW        07700000
         SR    R8,R8               CLEAR REMAINDER FIELD                07720000
         ST    R8,REMAIN           *                                    07740000
         LA    R8,1                SET LOOP FOR 1 MORE TIME             07760000
         B     LOOP3               SET UP LAST COMMAND LIST             07780000
MOVEWT   MVC   BUFFER(1),0(R12)                                         07800000
CONVRSON L     R10,MAXREC          ***                                  07820000
         A     R10,QKTRKCON          *** UPDATE TT OF TTR               07840000
         ST    R10,MAXREC          ***                   MAX            07860000
         N     R10,QKTMASK         CALCULATE CURRENT TTR                07880000
         A     R10,QKRECCON        *                                    07900000
         STM   R9,R13,SAVE                                              07920000
         STM   R1,R2,SAVE+20                                            07940000
         LA    R1,SDEB             GET POINTER TO DEB                   07960000
         LR    R0,R10              GET 'TTR'                            07980000
         LA    R2,CCHHR            GET POINTER TO 'MBBCCHHR'            08000000
         L     R15,CONVERT         GET POINTER TO 'TTR TO MBBCCHHR'     08020000
*                                  CONVERT ROUTINE.                     08040000
         BALR  R14,R15             LINK TO CONVERT ROUTINE              08060000
         LM    R9,R13,SAVE                                              08080000
         LM    R1,R2,SAVE+20                                            08100000
         B     LOOP4               CONTINUE                             08120000
*********************************************************************** 08140000
*                           ** GENERAL REGISTERS **                   * 08160000
*********************************************************************** 08180000
R10      EQU   10                                                       08400000
R11      EQU   11                                                       08420000
R12      EQU   12                                                       08440000
R13      EQU   13                                                       08460000
R14      EQU   14                                                       08480000
R15      EQU   15                                                       08500000
*********************************************************************** 08520000
*                          ** CONSTANTS NEEDED BY PROGRAM **          * 08540000
*********************************************************************** 08560000
FOUR     DC    H'4'                                                     08580000
BYTES24  DC    H'24'                                                    08600000
FIVE     DC    H'5'                                                     08620000
IWALEN   DC    A(LENIWA)           IWA LENGTH                           08640000
LMAX     DC    F'255'                                                   08660000
QK176    DC    F'176'                                                   08680000
QK1      DC    F'1'                                                     08700000
*********************************************************************** 08720000
*                THE FOLLOWING VALUES ARE USED AS OFFSETS FROM AN     * 08740000
*              ABSOLUTE CORE ADDRESS OR FROM AN ADDRESS WHICH CAN  BE * 08760000
*              FOUND AT A KNOWN ADDRESS AT EXECUTION TIME.  IF ANY OF * 08780000
*              THE OFFSETS CHANGE THE PROGRAM MUST BE REASSEMBLED     * 08800000
*********************************************************************** 08820000
COMMVEC  EQU   16                       OFFSET FROM THE BEGINNING OF    08840000
*                                       CORE TO THE LOCATION CONTAINING 08860000
*                                       THE ADDRESS OF THE COMMUNICA-   08880000
*                                       TIONS VECTOR TABLE              08900000
IEFJOB   EQU   12                       OFFSET FROM THE BEGINNING OF    08920000
*                                       THE COMMUNICATIONS VECTOR       08940000
*                                       TABLE TO THE WORD CONTAINING    08960000
*                                       THE ADDRESS OF THE SCHEDULER    08980000
*                                       COMMUNICATIONS AREA             09000000
SCARECPT EQU   108                      THE OFFSET IN THE SCHEDULER     09020000
*                                       COMMUNICATIONS AREA TO THE      09040000
*                                       BYTE CONTAINING THE NUMBER      09060000
*                                       OF RECORDS PER TRACK            09080000
BUMPTTR  EQU   36                                                       09100000
*********************************************************************** 09120000
*                  ** EXTERNS TO ROUTINES NEEDED BY THIS ROUTINE **   * 09140000
*********************************************************************** 09160000
QKADDR1  DC    V(IEFSD006)              RECORD NUMBER TO TTR            09180000
QKADDR2  DC    V(IEFQMSSS)              QUEUE MANAGER ROUTINE           09200000
*********************************************************************** 09220000
*               ** CONSTANTS USED IN MANIPULATING THE DISK ADDR.  **  * 09240000
*********************************************************************** 09260000
QKTRKCON DC    X'00010000'              USED TO UPDATE TRACK            09280000
QKRECCON DC    X'00000100'              USED TO UPDATE RECORD           09300000
QKTMASK  DC    X'FFFF0000'              USED TO MASK OUT RECORD ADDRESS 09320000
*********************************************************************** 09340000
*                          ** INSTRUCTIONS TO BE EXECUTED **          * 09360000
*********************************************************************** 09380000
QKMOVEA  MVC   0(1,R3),112(R13)                                         09400000
QKMOVEB  MVC   112(1,R13),0(R3)                                         09420000
*********************************************************************** 09440000
*                          ** EQUATED VALUES **                       * 09460000
*********************************************************************** 09480000
QKPOOLSZ EQU   300                                                      09500014
QKNUMREC EQU   1                                                        09520000
QKRDCODE EQU   4                                                        09540000
QKWTCODE EQU   3                                                        09560000
*********************************************************************** 09580000
*                                                                     * 09600000
*        THIS IS THE LENGTH OF THE INTERPRETER WORK AREA AND THE NEL. * 09610014
* IF THERE IS A CHANGE IN THE LENGTH OF EITHER OF THESE TABLES, THIS  * 09620014
* EQUATE STATEMENT MUST BE CHANGED TO REFLECT THE NEW LENGTH.         * 09630014
* THE 16 EXTRA BYTES ARE FOR THE EXIT LIST WHICH IS NOT PART OF THE   * 09640014
* NEL MACRO.                                                          * 09650014
LENIWA   EQU   NELEND-IWA+16                                            09660014
*                                                                     * 09720000
*********************************************************************** 09740000
         IEFQMPAM                                                       09760000
WORKAREA DSECT                                                          09780000
SAVE13   DC    F'0'                                                     09800000
SAVE     DS    7F                                                       09820000
SAVEAREA DS    18F                                                      09840000
CONVERT  DS    F                   POINTER TO 'TTR TO MBBCCHHR' CONVERT 09860000
LENCHANP DS    F                   LENGTH OF CHANNEL PROGRAM            09880000
REMAIN   DS    F                   LENGTH OF RECORD LESS THAN 176 BYTES 09900000
RECORDS  DS    F                   NUMBER OF 176 BYTE RECORDS           09920000
MAXREC   DS    F                                                        09940000
CCHHR    DS    0D                                                       09960000
         DS    2F                                                       09980000
CORE     DS    1F                                                       10000000
BUFFER   DS    176X                                                     10020000
SD7ECB   DC    F'0'                ECB                                  10040000
* THE FOLLOWING CODE REPRESENTS THE IOB                               * 10060000
SD7IOB   DC    B'01000010'         INDICATE COMMAND CHAINING          * 10080000
         DC    3X'00'                                                 * 10100000
ADECB    DC    A(SD7ECB)           POINTER TO ECB                     * 10120000
         DC    8X'00'                                                 * 10140000
ADCP     DC    A(0)                POINTER TO CHANNEL PROGRAM         * 10160000
ADDCB    DC    A(0)                POINTER TO DCB                       10180000
         DC    4X'00'                                                   10200000
         DC    4X'00'                                                   10220000
MBBCCHHR DC    8X'00'              MBBCCHHR                           * 10240000
*                                                                     * 10260000
*                                                                     * 10280000
END1     DS    0D                                                       10300000
QJOB     DSECT                                                          10320000
SDCB     DS    13F                                                      10340000
SDEB     DS    12F                                                      10360000
         END                                                            10380000
