  TITLE  'IEFSD010'                                                     00020000
*                       WRITING SYSOUT MESSAGES FOR SSS ROUTINE       * 00040000
* FUNCTION: TO WRITE THE SYSTEM MESSAGES FROM THE SMB'S ENQUEUED BY   * 00060000
* INTERPRETER AND INITIATOR.                                          * 00080000
* ENTRY POINTS: IEFS010                                               * 00100000
*         TAPE DENSITY IN REG. 1 IF SYSOUT IS ON TAPE.                  00120000
* INPUT: THE STRING OF SMBS TO BE PUT OUT.                            * 00140000
* OUTPUT: THE MESSAGES IN THE SMB'S                                   * 00160000
* EXTERNAL REFERENCES: IEFQMSSS, IEFSD006                             * 00180000
* EXITS: RETURN VIA REGISTER 14                                       * 00200000
* NOTES: MACROS USED: IEFSD005, OPEN, PRTOV, WRITE, CHECK, CLOSE      * 00220000
* TABLES/WORK AREAS: JCT, SCT, TIOT, QMPAM, GMSLT, GNRWT, DCB         * 00240000
*                                                                     * 00260000
*                                                                     * 00280000
*              THE OPERATION OF THIS CONTROL SECTION DEPENDS UPON AN    00300000
*              INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET    00320000
*              WHICH IS EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.    00340000
*              THE CODING HAS BEEN ARRANGED SO THAT REDEFINITION OF     00360000
*              'CHARACTER' CONSTANTS, BY REASSEMBLY, WILL RESULT IN A   00380000
*              CORRECT MODULE FOR THE NEW DEFINITIONS.                  00400000
*                                                                     * 00420000
*                                                                     * 00440000
*********************************************************************** 00460000
*                                                                     * 00480000
*        JCL STATEMENTS IN THE SMB'S ARE IN PACKED FORMAT. STARTING     00483000
*        WITH THE BYTE, SMBMSGLN, THE PACKED FORMAT IS AS FOLLOWS:      00486000
*                X'FE' - INDICATES PACKED FORMAT                        00489000
*                   1C  - TOTAL LENGTH OF STATEMENT                     00492000
*              A    1C  - LENGTH OF FIRST FIELD                         00495000
*              B    NC  - DATA FIELD                                    00498000
*              C    1C  - LENGTH OF BLANK FIELD FOLLOWING DATA FIELD    00501000
*                                                                       00504000
*              A,B,C ARE REPEATED FOR EACH DATA FIELD IN THE STATEMENT* 00507000
*        THE LAST DATA FIELD IS NOT FOLLOWED BY A FIELD WITH THE      * 00510000
*        NUMBER OF TRAILING BLANKS.                                   * 00513000
*        THE END OF THE SMB IS DENOTED BY '00'.                       * 00516000
*                                                                     * 00520000
*********************************************************************** 00540000
TCBCN    EQU   0                        COMMUN. VECTOR TO MAGIC         00560000
MAJCN    EQU   4                        MAGIC POINT TO TCB              00580000
JCTOF    EQU   4                        JCT OFFSET                      00600000
COMTB    EQU   16                                                       00620000
*DEFINE JOB CONTROL TABLE                                               00640000
JCTAR    DSECT                                                          00660000
         IEFAJCTB                                                       00680000
*DEFINE TIOT                                                            00700000
TIOTD    DSECT                                                          00720000
         IEFTIOT1                                                       00740000
*DEFINE QUEUE MANAGER PARAMETERS                                        00760000
         IEFQMPAM                                                       00780000
*DEFINE READER WRITER TABLE                                             00800000
RWRAR    DSECT                                                          00820000
         IEEGNRWT                                                       00840000
*DEFINE TCB                                                             00860000
TCBAR    DSECT                                                          00880000
         DS    2F                                                       00900000
TCBDEB   DS    1F                                                       00920000
TCBTIO   DS    1F                                                       00940000
*DEFINE WHOLE AREA TO MOVE                                              00960000
*DEFINE AREA TO BE ZERO                                                 00980000
SPWKA    DSECT                                                          01000000
SPBGG    DS    0F                       BEGINNING OF FIRST PART         01020000
*QUEUE MANAGER AREA                                                     01040000
QMPAR    DC    9F'0'                    QUEUE MANAGER PARAMETER         01060000
QMPCA    DC    AL4(BUFFR)               POINTER TO BUFFER               01080000
QMPEX    DC    X'00000000'              DISK ADDRESS                    01100000
SPBT0    EQU   128                                                      01120000
SPBT1    EQU   64                                                       01140000
SPBT2    EQU   32                                                       01160000
SPBT3    EQU   16                                                       01180000
SPBT4    EQU   8                                                        01200000
SPBT5    EQU   4                                                        01220000
SPBT6    EQU   2                                                        01240000
SPBT7    EQU   1                                                        01260000
SPBY0    DC    X'00'                                                    01280000
SPNFI    EQU   SPBT0                    NOT FIRST TIME IN BIT           01300000
SPAES    EQU   SPBT1                    END OF MESSAGE SWITCH           01320000
SPHND    DS    0F                       END OF FIRST PART               01340000
*                                                                       01360000
*INSERT NEW MATERIAL HERE ONLY. ZERO AREA DONE BY TWO XC INSTRUCTIONS   01380000
*                                                                       01400000
* DO NOT CHANGE THE  ORDER OF THESE CONSTANTS ************************  01420000
SAVELEN  DC    F'0'                                                     01440000
SAVEAREA DC    F'00'                                                    01460000
         DC    X'00'                                                    01480000
SWITCH   DC    X'00'                                                    01500000
**********************************************************************  01520000
* DO NOT CHANGE THE  ORDER OF THESE CONSTANTS ************************  01540000
SAVE1    DC    F'0'                                                     01560000
SAVE2    DC    F'0'                                                     01580000
SAVE4    DC    F'0'                                                     01600000
SAVE3    DC    F'0'                                                     01620000
SAVE5    DC    F'0'                                                     01640000
LINECNT  DC    F'50'               LINE COUNT                           01660000
MESSCNT  DC    F'0'                                                     01680000
MESSCNT2 DC    F'0'                                                     01700000
BUFFER   DC    F'12'                                                    01720000
**********************************************************************  01740000
SPINX    DS    1F                       SAVE AREA FOR REGISTER          01760000
SPSAR    DS    18F                      SAVE REGISTERS                  01780000
SVSMB    DC    X'00000000'              SAVE SMB POINTER                01800000
*TIO TABLE                                                              01820000
TIOTL    DC    C'IEFIBM01'                                              01840000
         DC    C'IEFIBM01'                                              01860000
         DC    2F'0'                                                    01880000
         DC    X'14000000'                                              01900000
         DC    C'IEFIBM01'                                              01920000
AREAF    DC    2F'0'                    AREA TO FIX                     01940000
         DC    1F'0'                                                    01960000
*OPEN AND CLOSE                                                         01980000
SPOPN    OPEN  (SPODC,OUTPUT),MF=L                                      02000000
SPCLO    CLOSE (SPODC),MF=L                                             02020000
*DCB                                                                    02040000
SPODC    DCB   DDNAME=IEFIBM01,                                        *02060000
               DSORG=PS,                                               *02080000
               NCP=16,                                                 *02100000
               MACRF=WC,                                               *02120000
               RECFM=VBA,                                              *02140000
               BLKSIZE=141,                                            *02160000
               DEVD=DA                                                  02180000
SPWAE    EQU   *                                                        02200000
SPWND    DS    0F                                                       02220000
OUTAREA  DSECT                                                          02240000
OUTAREAX DS    0F                                                       02260000
EXTEND   DS    16F                                                      02280000
BUFFR    DS    176C                                                     02300000
         DC    4X'00'                                                   02320000
BUFEND   DS    0F                                                       02340000
* THE FOLLOWING IS THE FORMAT OF A DECB                                 02360000
DECBS    DSECT                                                          02380000
SPDEW    DS    0F                                                       02400000
SPECW    DC    F'0'                                                     02420000
SPTYW    DC    X'0000'                                                  02440000
SPLNW    DC    X'0000'                                                  02460000
SPDCW    DC    AL4(SPODC)                                               02480000
SPARW    DC    AL4(BUFFR)                                               02500000
SPIOW    DC    4X'00'                                                   02520000
SPEND    DS    0F                                                       02540000
*REGISTERS                                                              02560000
XK       EQU   0                                                        02580000
XL       EQU   1                                                        02600000
XM       EQU   2                                                        02620000
XN       EQU   3                                                        02640000
XO       EQU   4                                                        02660000
XP       EQU   5                                                        02680000
XQ       EQU   6                                                        02700000
XR       EQU   7                                                        02720000
XS       EQU   8                                                        02740000
XT       EQU   9                                                        02760000
XU       EQU   10                                                       02780000
XV       EQU   11                                                       02800000
XW       EQU   12                                                       02820000
XX       EQU   13                                                       02840000
XY       EQU   14                                                       02860000
XZ       EQU   15                                                       02880000
*INITIALIZE                                                             02900000
IEFSD010 CSECT                                                          02920000
*                                                                A25967 02920400
*0544053384                                                       17641 02922016
*3058075400,081600,083000,084200                                   4064 02925016
*90810492,0511,0555,0602-0606,0634-0636,0759                            02930000
*2116051060,051120,057600,057800,058200,060400-063600             19829 02935017
         STM   XM,XY,0(XX)         SAVE REGISTERS                       02940000
         BALR  XM,0                     SETS UP THIS MODULE FOR RUNNING 02960000
         USING *,XM                                                     02980000
         LR    XS,XK                    SAVE ADDRESS OF NRWT            02990000
         L     XW,COMTB                 GET COMMUNICATION TABLE         03000000
         L     XW,TCBCN(0,XW)           GET POINTER TO MAGIC AREA       03020000
         L     XW,MAJCN(0,XW)           GET POINTER TO TCB              03040000
         USING TCBAR,XW                 SETS UP TCB                     03060000
         L     XV,JCTOF(0,XL)           SETS UP JCT                     03080000
         USING JCTAR,XV                                                 03100000
         LA    XK,SPWND-SPBGG+2*(BUFEND-OUTAREAX)+16*(SPEND-SPDEW)      03120000
*  CALCULATE SIZE OF AREA FOR GETMAIN                                   03140000
         GETMAIN R,LV=(0)               GET MAIN CORE                   03160000
         LR    XR,XL                    SAVE LOCATION OF GOT AREA       03180000
         USING SPBGG,XR                                                 03200000
         XC    SPBGG(TIOTL-SPBGG),SPBGG  ZERO OUT AREA TO BE SET UP     03220000
         MVC   TIOTL(SPWAE-TIOTL),TIOTM  TIOT AND DCB PUT IN GOT CORE   03240000
         ST    XX,SPINX                 SAVE RESTORE REGISTER           03260000
         USING OUTAREA,XU                                               03280000
         USING DECBS,XN                                                 03300000
         LA    XU,SPWND            GET ADDRESS OF BUFFER 1              03320000
         ST    XU,SAVE1                                                 03340000
         LA    XY,BUFEND           GET ADDRESS OF BUFFER 2              03360000
         ST    XY,SAVE2                                                 03380000
         LA    XY,2*(BUFEND-OUTAREAX) * GET ADDRESS OF DECB'S TO BE     03400000
         LA    XY,0(XU,XY)            * USED WITH BUFFER 1              03420000
         ST    XY,SAVE3                                                 03440000
         LR    XN,XY                                                    03460000
         LA    XT,2                                                     03480000
LOOP2A   ST    XN,SAVE4            GET ADDRESS OF DECB'S TO BE USED     03500000
*                                  WITH BUFFER 2                        03520000
         LA    XO,8                                                     03540000
LOOP1A   XC    SPDEW(SPEND-SPDEW),SPDEW CLEAR DECB'S TO ZERO            03560000
         LA    XQ,SPODC            SET UP DCB ADDR. IN DECB             03580000
         ST    XQ,SPDCW                                                 03600000
         LA    XN,20(0,XN)         GET ADDR. OF NEXT DECB               03620000
         BCT   XO,LOOP1A                                                03640000
         BCT   XT,LOOP2A                                                03660000
         LA    XQ,BUFFR                 FIX POINTER TO READ BUFFER      03680000
         ST    XQ,QMPCA                 IN QUEUE MANAGER AREA           03700000
         LA    XT,QMPAR                 SETS UP QUEUE MANAGER PARAMETER 03720000
         USING IOPARAMS,XT                                              03740000
         SR    XQ,XQ                    CLEAR OUT REGISTER              03760000
*SET UP QUEUE MANAGER PARAMETERS                                        03780000
         MVI   QMPOP,X'04'              INDICATE READ                   03800000
         LA    XO,QMPCA                                                 03820000
         ST    XO,QMPCL                 FIX POINTER TO QMPCA            03840000
         MVI   QMPNC,X'01'              INDICATE 1 RECORD TO BE READ    03860000
         USING RWRAR,XS                 SETS UP READER WRITER TABLE     04160000
         LA    XS,NRWTW                 OFFSET TO CLASS A ENTRY         04170000
         TM    NRWTF,NRWTFA             TEST FOR ACTIVE IF SO           04180000
         BO    HVADD                    BRANCH TO HAVE ADDRESS          04200000
         AH    XS,EIGHT            POINT AT SECOND ENTRY                04220000
HVADD    MVC   AREAF(8),NRWTR           PUTS IN JFCB INFORMATION        04240000
         MVI   AREAF+NRWTF-NRWTR,X'00'  CLEAR OUT STATUS C              04260000
         MVI   AREAF+NRWTCLS-NRWTR,X'00'     CLEAR OUT CLASSNAME        04266000
         NI    AREAF+NRWTB-NRWTR,X'80'                                  04272000
*SET TCB POINTER TO SYSOUT TIOT                                         04280000
         LA    XO,TIOTL                                                 04300000
         ST    XO,TCBTIO                                                04320000
*OPEN SYSOUT                                                            04340000
         LA    XO,SPODC                 GET ADDRESS OF DCB              04360000
         LA    XL,SPOPN                 GET ADDRESS OF OPEN             04380000
         OPEN  ((XO),OUTPUT),MF=(E,(1))                                 04400000
*SAVE NEXT SMB ADDRESS                                                  04420000
         MVC   SVSMB(3),JCTSMBAD        SAVE SMB ADDRESS                04440000
         LA    XQ,8                INITIALIZE 'BUFFER' TO INDICATE THAT 04460000
*                                  BUFFER 2 IS TO BE USED NEXT          04480000
         OI    SWITCH,X'60'        INITIALIZE SWITCHES                  04500000
         ST    XQ,BUFFER                                                04520000
         L     XQ,MAX                                                   04540000
         ST    XQ,LINECNT          INITIALIZE LINE COUNT TO 50          04560000
         GETMAIN R,LV=176              GET CORE FOR SMB                 04566000
         ST    1,SMBADDR               SAVE ADDR OF INPUT BUFFER        04572000
SVNSM    L     XN,SVSMB                 GET ADDRESS                     04580000
*READ IN SMB BY QUEUE MANAGER                                           04600000
         LTR   XN,XN               IS IT ZERO                           04620000
         BZ    CLEANUP             YES, CONTINUE                        04640000
RSMBQ    ST    XN,QMPEX                                                 04660000
         MVC   QMPCA(4),SMBADDR        PUT ADDR OF INPUT BUFFER IN      04680000
*                                      PARAMETER LIST                   04700000
         LA    XL,QMPAR                 INDICATE QM PARAMETERS          04720000
         LA    XX,SPSAR                 INDICATE SAVE AREA              04740000
         L     XZ,IEFQM3SS              FIX BRANCH                      04760000
         BALR  XY,XZ                    BRANCH TO READ IN SMB           04780000
*              ***  NO ERROR ROUTINE  ***                               04800000
*INITIALIZE POINTER TO FIRST MESSAGE IN BUFFER                          04820000
         L     XP,SMBADDR              GET ADDRESS OF INPUT BUFFER      04850000
         MVC   SVSMB(3),SMBNEXT-SMBDSKAD(XP) SAVE SMB ADDRESS           04880000
         LA    XP,SMBMSGLN-SMBDSKAD(XP) POINT TO MESSAGE LENGTH         04910000
         SR    SMBEND,SMBEND       INITIALIZE THE NUMBER OF CHARS.      04960000
*                                  PROCESSED TO ZERO                    04980000
BEGIN    DS    0H                                                       04990000
         SR    TTLCOUNT,TTLCOUNT       ZERO DISPLACEMENT IN BUFFER      05000000
         SR    MESSNUM1,MESSNUM1       ZERO NUMBER OF MESSAGES          05010000
         L     LNCOUNT,LINECNT     RESTORE LINE COUNT                   05020000
LOOP     DS    0H                                                       05024000
         SR    XQ,XQ                   LENGTH OF EXPANDED RECORD        05028000
         CLI   0(XP),X'FE'             IS THE JCL COMPRESSED            05032000
         BNE   LOOPA              NO                                    05036000
         OI    SWITCH,X'08'            INDICATE COMPRESSED JCL          05040000
         LA    XP,1(XP)                                                 05044000
LOOPA    DS    0H                                                       05048000
         IC    XQ,0(XP)                GET TOTAL MESSAGE LENGTH         05052000
         LTR   XQ,XQ               IS IT ZERO                           05060000
         BZ    LOOP2               YES, CONTINUE                        05080000
         L     XV,LENGTH               GET LENGTH OF BUFFER             05080600
         SR    XV,TTLCOUNT             GET LENGTH USED                  05081200
*                                      XV NOW CONTAINS THE NUMBER OF    05081800
*                                      AVAILABLE BYTES                  05082400
         TM    SWITCH,X'08'            COMPRESSED JCL                   05083000
         BZ    NONCOMP                 NO- MSG LENGTH ALREADY KNOWN     05083600
         SR    XZ,XZ                   ZERO LENGTH OF COMPRESSED MSG    05084200
         SR    XY,XY                   ZERO LENGTH BYTE REGISTER        05084800
         LR    XW,XP                   SAVE POINTER TO MSG LENGTH       05085400
         BCTR  XP,0                    POINT TO COMPRESSED INDICATOR    05086000
         LA    XO,0(XP,XQ)             POINT TO END OF MESSAGE          05086600
LOOPC    DS    0H                                                       05087200
         LA    XW,1(XW)                GET PTR TO LENGTH FIELD          05087800
         IC    XY,0(XW)                LENGTH OF FIELD                  05088400
         AR    XZ,XY                   ADD FIELD LENGTH TO TOTAL        05089000
         LA    XW,1(XY,XW)             POINT TO NEXT LENGTH BYTE        05089600
         CR    XW,XO                   END OF MESSAGE                   05090200
         BNL   TESTLEN                 NOW SEE IF MSG WILL FIT          05090800
         IC    XY,0(XW)                PICK UP NUMBER OF BLANKS         05091400
         AR    XZ,XY                   ADD BLANKS TO TOTAL              05092000
         B     LOOPC                                                    05092600
TESTLEN  DS    0H                                                       05093200
         CR    XZ,XV                   WILL MSG FIT IN BUFFER           05093800
         BH    SAVEREG5                NO - WRITE OUT THIS BUFFER       05094400
         CH    XV,DEC18      ARE THERE AT LEAST 18 BYTES LEFT?   A25967 05094500
         BL    SAVEREG5      NO-WRITE OUT BUFFER                 A25967 05096400
         CH    MESSNUM1,EIGHT      EIGHT MSGS IN BUFFER?          19829 05099100
         BE    SAVEREG5            YES-WRITE THIS ONE             19829 05101000
         LA    XP,1(XP)                POINT TO LNGTH OF COMPRESSED MSG 05102900
         B     LOOPD                   FORMAT THE MESSAGE               05104800
NONCOMP  DS    0H                                                       05106700
         CR    XQ,XV                   WILL MSG FIT IN BUFFER           05108600
         BH    SAVEREG                 NO- WRITE OUT THIS BUFFER        05110500
         CH    XV,DEC18      ARE THERE AT LEAST 18 BYTES LEFT?   A25967 05110900
         BL    SAVEREG       NO-WRITE OUT BUFFER                 A25967 05111300
         CH    MESSNUM1,EIGHT      EIGHT MSGS IN BUFFER?          19829 05112400
         BE    SAVEREG             YES-WRITE THIS ONE             19829 05114300
LOOPD    DS    0H                                                       05116200
         AH    MESSNUM1,ONE        BUMP NUMBER OF MESSAGES COUNTER      05118100
         LR    XZ,XQ               SAVE MESSAGE LENGTH                  05120000
         BCT   XZ,*+4                  GET LENGTH NOT YET HANDLED       05180000
         LA    XO,EXTEND(TTLCOUNT)  GET ADDRESS OF MESSAGE              05320000
         TM    SWITCH,X'08'            IS THE JCL COMPRESSED            05320800
         BZ    ERRMSG                  NO, MOVE FROM SMB TO BUFFER      05321600
         NI    SWITCH,X'F7'            TURN OFF COMPRESSED JCL SWITCH   05322400
         AR    SMBEND,XQ               INCREMENT CHARACTERS HANDLED     05322800
         SR    XY,XY                   FIELD LENGTH                     05323200
         SR    XQ,XQ                   LENGTH OF EXPANDED RECORD        05324000
MFRCM    DS    0H                                                       05324800
         LA    XP,1(XP)                POINTS TO FIELD LENGTH           05325600
         BCT   XZ,*+4                  KEEP COUNT OF HOW MUCH LEFT      05326400
         IC    XY,0(XP)                GET FIELD LENGTH                 05327200
         LTR   XY,XY                   IS THIS FIELD LENGTH ZERO        05327316
         BZ    MFRCM1                  YES - DON'T MOVE ANY BYTES       05327416
         BCTR  XY,0                    GET READY FOR EXECUTE 14 PTM/401 05327600
         MVC   9(1,XO),1(XP)           DUMMY                            05328000
         EX    XY,*-6                  MOVE CHARACTERS                  05328800
         LA    XY,1(XY)                INCREMENT FOR CORRECT 14 PTM/401 05329000
*                                      ADDITIONS TO POINTERS 14 PTM/401 05329200
MFRCM1   DS    0H                                                       05329416
         AR    XQ,XY                   ADJUST LENGTH EXPANDED           05329600
         AR    XO,XY                   ADJUST POINTER TO WHERE MOVE     05330400
         LA    XP,1(XY,XP)             POINT TO NUMBER OF BLANKS        05331200
*IS THE COMPRESSED MESSAGE COMPLETED                                    05332000
         BCT   XZ,*+4                  GET AMOUNT OF COMPRESSED RECORD  05332800
         SR    XZ,XY                   NOT YET DEALT WITH               05333600
         BZ    LOOP3                                                    05334400
*MOVE IN THE BLANKS FOR EXPANDED RECORD                                 05335200
         IC    XY,0(XP)                GET NUMBER OF BLANKS             05336000
         BCTR  XY,0          TO DECREMENT FOR MVC                 17641 05336416
         MVI   9(XO),C' '              MOVE IN A BLANK                  05336800
         MVC   10(1,XO),9(XO)          DUMMY                            05337600
         EX    XY,*-6         MOVE IN BLANKS (1 TOO MANY)         17641 05338116
         LA    XY,1(XY)       INCREMENT FOR CORRECT POINTER       17641 05338616
         AR    XQ,XY                   ADJUST LENGTH EXPANDED           05339200
         AR    XO,XY                   ADJUST POINTER TO WHERE MOVE     05340000
         B     MFRCM                   BRANCH TO MOVE IN NEXT FIELD     05340800
SAVEREG5 DS    0H                                                       05341600
         NI    SWITCH,X'F7'            TURN OFF COMPRESSED JCL SWITCH   05342400
SAVEREG  DS    0H                                                       05343200
         ST    SMBEND,SV3              SAVE NUMBER OF BYTES PROCESSED   05344000
         ST    XP,SV5                  SAVE POINTER TO NEXT MESSAGE     05344800
         OI    SWITCH,X'02'                          THE SMB            05345600
         B     LOOP2                                                    05346400
ERRMSG   DS    0H                                                       05347200
         EX    XQ,MOVE                                                  05348000
         LA    SMBEND,1(XQ,SMBEND)     INCREMENT CHARACTERS HANDLED     05348400
         LA    XP,1(XP,XQ)             GET POINTER TO NEXT MESSAGE      05348800
LOOP3    DS    0H                                                       05349600
         CH    XQ,DEC17      IS MSG LESS THAN 18 BYTES?          A25967 05350000
         BNL   LOOP3A        NO-DO NOT HAVE TO PAD FOR NOISE     A25967 05350100
         LA    XO,SPODC      ADDRESS DCB                         A25967 05350200
         USING IHADCB,XO                                         A25967 05350400
         CLI   DCBDEVT,X'81' IS SYSOUT TO TAPE?                  A25967 05350800
         BNE   LOOP3A        NO - DON'T HAVE TO PAD FOR NOISE    A25967 05350900
         DROP  XO                                                A25967 05351100
         LR    XK,XQ         ON TAPE - SAVE MSG LENGTH           A25967 05351800
         LA    XO,EXTEND(TTLCOUNT)  PTR IN BUFFER FOR PADDING    A25967 05352000
         AR    XO,XQ         UPDATE PTR FOR PADDING              A25967 05352100
         LA    XQ,DEC17      COMPUTE LENGTH TO PAD               A25967 05352400
         SR    XQ,XK                                             A25967 05352800
         EX    XQ,MOVEA      PAD BUFFER TO 18 BYTES WITH BLANKS  A25967 05353200
         LH    XQ,DEC18      SET MSG LENGTH TO 18                A25967 05353600
LOOP3A   EQU   *                                                 A25967 05354500
         SLL   XQ,16                                                    05354800
         A     XQ,FIVE                 GET LOGICAL RECORD LENGTH        05356900
         ST    XQ,SAVEAREA                                              05359000
         A     XQ,ZEROFOUR             GET BLOCK LENGTH                 05361100
         ST    XQ,SAVELEN                                               05363200
         C     LNCOUNT,MAX             IS THE PAGE FILLED               05365300
         BNL   PAGEFULL                YES, CONTINUE                    05367400
         MVI   SAVEAREA+4,C' '         INDICATE SPACE BEFORE PRINTING   05369500
LOOPB    DS    0H                                                       05371600
         AH    LNCOUNT,ONE             BUMP LINE COUNT                  05373700
         LA    XO,EXTEND(TTLCOUNT)     POINT TO BUFFER BEGINNING        05375800
         MVC   0(9,XO),SAVELEN     SET UP CONTROL CHARACTERS            05377900
*                                  OUTPUT BUFFER                        05380000
         SRL   XQ,16               READJUST LOGICAL RECORD LENGTH       05400000
         CH    SMBEND,ONE62        HAVE ALL MESSAGES BEEN PROCESSED     05440000
         BNL   LOOP2               YES, CONTINUE                        05460000
         LA    TTLCOUNT,0(TTLCOUNT,XQ) UPDATE OUTPUT BUFFER POINTER     05490000
         B     LOOP                CONTINUE                             05520000
PAGEFULL SR    LNCOUNT,LNCOUNT     INITIALIZE LINE COUNT TO ZERO        05540000
         MVI   SAVEAREA+4,C'1'     INDICATE SKIP TO CHANNEL 1           05560000
         B     LOOPB                                                    05580000
LOOP2    ST    LNCOUNT,LINECNT     SAVE LINE COUNT                      05600000
         ST    XP,HOLD1     SAVE ADDRESS OF NINTH MESSAGE          9317 05610000
         L     XQ,BUFFER           GET INDEXING FACTOR                  05620000
         ST    MESSNUM1,LINECNT(XQ) SAVE NUMBER OF MESSAGES             05640000
         LR    MESSNUM,MESSNUM1                                         05660000
         LA    XQ,EXTEND                                                05680000
         SR    MESSLEN,MESSLEN                                          05700000
RECYCLE1 L     XN,BUFFER           GET INDEXING FACTOR                  05720000
         L     XN,SAVE2(XN)        GET ADDR. OF DECB'S TO BE USED       05740000
RECYCLE  LTR   MESSNUM,MESSNUM     ARE THERE ANY MORE MESSAGES          05800000
         BZ    CONTINUE            NO-CONTINUE                    19829 05820017
         LA    XQ,0(MESSLEN,XQ)    GET MESSAGE ADDRESS                  05840000
         ST    XQ,SPARW            PUT IT IN THE DECB                   05860000
         MVC   SPLNW(2),0(XQ)      PUT MESSAGE LENGTH INTO DECB         05880000
         LH    MESSLEN,SPLNW       GET MESSAGE LENGTH                   05900000
         SH    MESSNUM,ONE                                              05920000
         LA    XX,SPSAR            LOAD SAVE AREA ADDRESS               05940000
         WRITE SPDEW,SF,MF=E                                            05960000
         LA    XN,20(0,XN)         GET ADDR. OF NEXT DECB               05980000
         B     RECYCLE             CONTINUE                             06000000
CONTINUE L     BUFNUM,BUFFER       GET INDEXING FACTOR                  06380000
HERE     B     HERE(BUFNUM)        GO TO BRANCH TABLE                   06400000
         B     USEBUF1             USE BUFFER 1 AGAIN                   06420000
USEBUF2  LA    BUFNUM,4            INDICATE BUFFER 1 TO BE USED NEXT    06440000
         L     XU,SAVE2            SET BASE RO REFLECT USE OF BUFFER 2  06460000
         TM    SWITCH,X'40'        IS THIS THE FIRST TIME               06480000
         BO    LOOP4               YES, CONTINUE                        06500000
         L     XO,MESSCNT          GET NUMBER OF MESSAGES IN BUFFER 1   06520000
         L     XN,SAVE4            GET ADDRESS OF ECB'S TO BE CHECKED   06540000
LOOP5    LTR   XO,XO               ARE THERE ANY MORE DECB'S TO BE      06560000
*                                  CHECKED                              06580000
         BC    8,LOOP4             NO, CONTINUE                         06600000
         LA    XX,SPSAR            GET SAVE AREA ADDRESS                06620000
         CHECK SPDEW               MAKE SURE THE I/O CONCERNED WITH     06640000
*                                  THIS BUFFER IS COMPLETED             06660000
         LA    XN,20(0,XN)         GET ADDR. OF NEXT DECB               06680000
         SH    XO,ONE              DECREMENT NUMBER OF MESSAGES TO BE   06700000
*                                  CHECKED                              06720000
         B     LOOP5               CONTINUE                             06740000
LOOP4    ST    BUFNUM,BUFFER                                            06760000
         NI    SWITCH,X'BF'        RESET FIRST TIME SWITCH              06780000
         XC    EXTEND(BUFEND-EXTEND),EXTEND CLEAR OUT BUFFER            06785000
         TM    SWITCH,X'02'            ARE THERE MORE MSGS IN SMB       06790000
         BO    RESTREG                 YES-RESTORE SPECIAL REGISTERS    06795000
         B     SVNSM               CONTINUE                             06800000
RESTREG  DS    0H                                                       06803000
         L     SMBEND,SV3              RESTORE NUMBER OF BYTES PROCESSD 06806000
         L     XP,SV5                  RESTORE POINTER TO NEXT MESSAGE  06809000
         NI    SWITCH,X'FD'                          THE SMB            06812000
         B     BEGIN                   START NEW BUFFER                 06815000
USEBUF1  LA    BUFNUM,8            INDICATE BUFFER 2 IS TO BE USED NEXT 06820000
         L     XU,SAVE1            SET BASE RO REFLECT USE OF BUFFER 1  06840000
         L     XN,SAVE3            GET ADDRESS OF ECB'S TO BE CHECKED   06860000
         L     XO,MESSCNT2         GET NUMBER OF MESSAGES IN BUFFER 2   06880000
         B     LOOP5               CONTINUE                             06900000
*CLOSE SYSOUT                                                           06920000
CLEANUP  TM    SWITCH,X'20'        HAVE ALL WRITES BEEN CHECKED         06940000
         BZ    FINISH              YES                                  06960000
         NI    SWITCH,X'DF'        RESET COMPLETION INDICATOR           06980000
         B     CONTINUE            NO, GO CHECK REMAINING WRITES        07000000
FINISH   L     XN,SAVE4           DECB ADDR                             07020000
         XC    SPDEW(20),SPDEW     CLEAR DECB                           07040000
         LA    XX,SPSAR            LOAD SAVE AREA ADDRESS               07060000
         WRITE SPDEW,SF,SPODC,SPACE,'S',MF=E   SPACE A LINE             07080000
         CHECK SPDEW                                                    07100000
         LA    XO,SPODC            GET ADDRESS OF DCB                   07120000
         USING IHADCB,XO                                                07140000
         SR    XV,XV                                                    07160000
         CLI   DCBDEVT,X'81'       IS THIS A TAPE                       07180000
         BNE   NOTAPE              NO                                   07200000
         IC    XV,DCBDEN           YES, GET DENSITY                     07220000
NOTAPE   EQU   *                                                        07240000
         LA    XL,SPCLO                 GET ADDRESS OF CLOSE            07260000
         CLOSE ((XO)),MF=(E,(1))                                        07280000
         L     1,SMBADDR               GET ADDR OF SMB BUFFER TO FREE   07286000
         FREEMAIN R,LV=176,A=(1)                                        07292000
*SAVE UCB POINTER                                                       07300000
         LH    XQ,AREAF+NRWTSRT-NRWTR   GET UCB POINTER                 07320000
         LA    XK,SPWND-SPBGG+2*(BUFEND-OUTAREAX)+16*(SPEND-SPDEW)      07340000
*  CALCULATE SIZE OF AREA FOR FREEMAIN                                  07360000
         LR    XL,XR                    GET LOCATION OF GOT AREA        07380000
         LA    XX,SPSAR                 GET SAVE AREA                   07400000
         L     XO,SPINX                 RESTORE RETURN REGISTER         07420000
         FREEMAIN R,LV=(0),A=(1)        FREE MAIN CORE                  07440000
         LR    XZ,XQ                    PUT UCB POINTER IN RIGHT REG    07460000
         N     XZ,SVLHF                 SAVE LOWER HALF ONLY            07480000
         LR    1,XV                                                     07500000
         LM    XM,XY,0(XO)         RESTORE REGISTERS                    07520000
ERREXIT  BR    XY                                                 14604 07540016
*CONSTANTS                                                              07560000
         DS    0F                                                       07580000
HOLD1    DS    1F     TO HOLD 9TH MESSAGE ADDRESS                  9317 07590000
SVLHF    DC    X'0000FFFF'              TO SAVE LOWER HALF ONLY         07600000
ZEROFOUR DC    X'00040000'                                              07620000
FIVE     DC    X'00050000'                                              07640000
ONE62    DC    H'162'                                                   07660000
MAX      DC    F'50'                                                    07680000
ONE      DC    H'1'                                                     07700000
MOVE     MVC   8(1,XO),0(XP)                                            07720000
MOVEA    MVC   9(1,XO),BLANK MVC TO PAD BUFFER WITH BLANKS       A25967 07730000
DEC17    DC    H'17'                                             A25967 07734000
DEC18    DC    H'18'                                             A25967 07736000
BLANK    DC    CL18' '                                           A25967 07738000
EIGHT    DC    H'8'                                                     07740000
SPACE    DC    X'0014'                                                  07760000
         DC    C'  '                                                    07780000
         DC    X'0010'                                                  07800000
         DC    C'  '                                                    07820000
         DC    C' '                                                     07840000
         DC    12C' '                                                   07860000
SMBADDR  DC    F'0'                    ADDRESS OF SMB BUFFER            07862000
*********************************************************************** 07864000
* THESE TWO WORDS ARE ONLY USED WHEN A BUFFER IS FULL BEFORE THE      * 07866000
* ENTIRE SMB HAS BEEN DECOMPRESSED AND FORMATTED.                     * 07868000
SV3      DC    F'0'                    CONTAINS NUMBER OF BYTES PRCESSD 07870000
SV5      DC    F'0'                    CONTAINS POINTER TO NEXT MESSAGE 07872000
*********************************************************************** 07874000
LENGTH   DC    A(BUFEND-OUTAREAX-9)    LENGTH OF OUTPUT BUFFER MINUS    07876000
*                                      9 BYTES FOR CONTROL CHARACTERS   07878000
SMBEND   EQU   3                                                        07880000
MESSLEN  EQU   XP                                                       07900000
LNCOUNT  EQU   13                                                       07920000
MESSNUM  EQU   4                                                        07940000
MESSNUM1 EQU   8                                                        07960000
TTLCOUNT EQU   1                                                        07980000
BUFNUM   EQU   5                                                        08000000
IEFSD6CN DC    V(IEFSD006)              ROUTINE TO FIND R/W TABLE       08020000
IEFQM3SS DC    V(IEFQMSSS)              QUEUE MANAGER ROUTINE           08040000
*TIO TABLE                                                              08060000
TIOTM    DC    C'IEFIBM01'                                              08080000
         DC    C'IEFIBM01'                                              08100000
         DC    2F'0'                                                    08120000
         DC    X'14000000'                                              08140000
         DC    C'SYSABEND'                                              08160016
         DC    2F'0'                                                    08180000
         DC    1F'0'                                                    08200000
*OPEN AND CLOSE                                                         08220000
         OPEN  (SPODD,OUTPUT),MF=L                                      08240000
         CLOSE (SPODD),MF=L                                             08260000
*DCB                                                                    08280000
SPODD    DCB   DDNAME=SYSABEND,                                        *08300016
               DSORG=PS,                                               *08320000
               MACRF=WC,                                               *08340000
               RECFM=VBA,                                              *08360000
               NCP=16,                                                 *08380000
               BLKSIZE=141,                                            *08400000
               DEVD=DA,SYNAD=ERREXIT                              14604 08420016
         DCBD  DSORG=PS,DEVD=TA                                         08440000
         END                                                            08460000
