IEFSD079 CSECT                                                          00020000
*                                                                       00021000
*          RELEASE 22 DELETIONS/CHANGES                                 00022000
*          RELEASE 21 DELETIONS/CHANGES                                 00023000
*          RELEASE 20 DELETIONS/CHANGES                                 00024000
* 021423-023600                                                  MAPMAC 00025000
*                                                                       00026000
*0833000300,0176000,021200,0214000                                 SM0I 00030018
         TITLE 'IEFSD079 - VMS SYSOUT WTR  LINK-TO-QMNGR-DELETE'        00040000
**********************************************************************  00060000
*                                                                    *  00080000
*TITLE-- IEFSD079 - SYSOUT WRITER LINK-TO-QMGR-DELETE                *  00100000
*                                                                    *  00120000
*STATUS -- CHANGE LEVEL 000                                          *  00140000
*                                                                    *  00160000
*FUNCTION--UPON COMPLETION OF A SYSOUT JOB, THIS MODULE IS ENTERED.  *  00180000
*   IT LINKS TO  IEFQDELE (QUEUE MANAGER 'DELETE' FUNCTION) IN       *  00200000
*   ORDER TO DELETE ALL CONTROL RECORDS, SYSTEM MESSAGE BLOCKS       *  00220000
*   (SMB'S), AND DATA SET BLOCKS (DSB'S) ASSOCIATED WITH THAT        *  00240000
*   SYSOUT JOB.  THE SYSOUT WRITER MAIN CONTROL PROCESSING ROUTINE   *  00260000
*   IS THEN EXITED TO.  HOWEVER, IF THE ERROR INDICATOR BYTE IN THE  *  00280000
*   UPPER BYTE OF PARLIST SLOT  PARWORK2  IS NOT ZERO, THE DELETE    *  00300000
*   ROUTINE IS NOT LINKED TO AND DIRECT EXIT TO IEFSD082 OCCURS.     *  00320000
*                                                                    *  00340000
*ENTRY POINT--                                                       *  00360000
*        IEFSD079 - VIA XCTL FROM IEFSD078 (BY WAY OF XCTL MODULE    *  00380000
*   IEF079SD).                                                       *  00400000
*                                                                    *  00420000
*INPUT--ADDRESS, IN REGISTER 1, OF SYSOUT PARAMETER LIST PROPAGATED  *  00440000
*   THROUGHOUT THE WRITER, THE SIX WORDS CONTAINING THE FOLLOWING    *  00460000
*                             CSCB PTR,                              *  00480000
*                             PTR TO OUTPUT DCB,                     *  00500000
*                             WD OF BLANKS (OR FORMS NO.)            *  00520000
*                             PTR TO ECB LIST,                       *  00540000
*                             PTR TO QMGR PARAMETER AREA,            *  00560000
*                             PTR TO SMB/DSB AREA.                   *  00580000
*                                                                    *  00600000
*OUTPUT--SAME AS INPUT, PLUS 'COMING FROM IEFSD079' INDICATION IN    *  00620000
*   REGISTER 8.                                                      *  00640000
*                                                                    *  00660000
*EXTERNAL ROUTINES--                                                 *  00680000
*        IEFQDELE - QUEUE MANAGER 'DELETE' MODULE                    *  00700000
*                                                                    *  00720000
*EXIT--DIRECTLY TO                                                   *  00740000
*        IEFSD082 - SYSOUT WRITER MAIN CONTROL PROCESSING            *  00760000
*                                                                    *  00780000
*ATTRIBUTES--REENTRANT                                               *  00800000
*                                                                    *  00820000
**********************************************************************  00840000
***                                                                ***  00860000
*        ESSENTIAL EQUATES                                           *  00880000
***                                                                ***  00900000
*                                                                    *  00920000
R0       EQU   0                                                        00940000
R1       EQU   1                                                        00960000
R2       EQU   2                                                   SM0I 00965018
R3       EQU   3                                                   SM0I 00970018
R13      EQU   13                                                  SM0I 00975018
R4       EQU   4                                                        00980000
R6       EQU   6                                                        01000000
R8       EQU   8                                                        01020000
R9       EQU   9                                                        01040000
R10      EQU   10                                                  000F 01050015
R14      EQU   14                                                       01060000
R15      EQU   15                                                       01080000
*                                                                    *  01100000
IOERROR  EQU   X'0C'                    USED TO INDICATE QMGR I/O ERR   01120000
*                                                                    *  01140000
MFTWO    EQU   X'74'                                               000F 01146015
MFTBT    EQU   X'20'                                               000F 01152015
**********************************************************************  01160000
         BALR  R9,0                                                     01180000
         USING *,R9                                                     01200000
***                                                                ***  01220000
*        GO TO QUEUE MANAGER  TO DELETE EXTERNAL SPACE               *  01240000
*        ASSOCIATED WITH THE JOB WHICH HAS JUST BEEN FINISHED        *  01260000
***                                                                ***  01280000
         LR    R6,R1                    LOAD ADDR OF PARLIST            01300000
         USING PARLIST,R6               ADDRESSABILITY FOR PARLIST      01320000
         CLI   PARWORK2,X'00'           IS ERROR INDICATOR ZERO         01340000
         BNE   SD79RETN                 NO,DO NOT DELETE,LEAVE          01360000
         L     R1,PARQMPAR              LOAD PTR TO QMNGR PARAM AREA    01380000
         USING IOPARAMS,R1              ADDRESSABILITY FOR LATTER       01400000
         MVI   QMPOP,QMDELE             SET CODE FOR 'DELETE'           01420000
         L     R15,SD79QDEL             LOAD ADDR OF QMGR DELETE RTN    01440000
         BALR  R14,R15                  LINK TO IT                      01460000
         LTR   R15,R15                  CHECK RETURN CODE FROM QMGR     01480000
         BC    8,SD79SETN               0 MEANS NORMAL DELETION    000F 01500015
         MVI   PARWORK2,IOERROR         NON-0  MEANS ERROR IN QMGR      01520000
*                                        DELETE FUNCTION.  INDICATE     01540000
SD79SETN L     R1,CVTPTR                TEST FOR MFT IF SO         000F 01560015
         TM    MFTWO(R1),MFTBT    BRANCH TO POST THE READER ECBS   000F 01580015
         BO    SD79POST           TO INDICATE SPACE IS AVAILABLE   000F 01600015
*                                                                    *  01640000
***                                                                ***  01660000
***                                                                ***  01680000
*        ON RETURN, INDICATE TO  IEFSD082  THAT ENTRY TO IT          *  01700000
*        IS FROM THIS ROUTINE,  AND EXIT TO  IEFSD082                *  01720000
***                                                                ***  01740000
SD79RETN LA    R15,IEFSMFWR         GET ADDRESS OF SMF WRITER      SM0I 01748018
         BALR  R14,R15             BRANCH TO SMF WRITER            SM0I 01756018
FINISH   L     R8,SD79TO82         LOAD INDICATION INTO REGISTER   SM0I 01764018
         L     R2,PARQMPAR         QMGR PARAM AREA ADDRESS         SM0I 01772018
         L     R15,SD79OUT              LOAD EXIT ADDRESS               01780000
         LR    R1,R6                    RESTORE INPUT REGISTER          01800000
         BALR  R14,R15             *****     EXIT     *****             01820000
*                                                                    *  01840000
**********************************************************************  01860000
*                                                                    *  01880000
SD79POST EQU   *                                                   000F 01880915
         DROP  R1                                                  000F 01881815
         L     R4,CVTPTR                SETUP CVT BASE REG         000F 01882715
         USING CVT,R4                                              000F 01883615
         L     R8,CVTMSER               SETUP 'BASE' BASE REG      000F 01884515
         USING BASE,R8                                             000F 01885415
         L     R1,BATECBP               LOAD ECB ADDR IN R1        000F 01886315
         LTR   R1,R1              CHECK FOR ANY ECB'S PRESENT      000F 01887215
         BZ    SD79RETN                 BRANCH IF NONE FOUND       000F 01888115
         LR    R10,R1                   SAVE R1                    000F 01889015
         ENQ   MF=(E,HRCPO)                                        000F 01889915
         LR    R1,R10                   RESTORE R1                 000F 01890815
SDAGAIN  EQU   *                                                   000F 01891715
         POST  (1)                      POST THE ECB               000F 01892615
         L     R1,4(R1)                 PICK UP ADDR NEXT ECB      000F 01893515
         LTR   R1,R1              CHECK FOR MORE ECB'S PRESENT     000F 01894415
         BNZ   SDAGAIN                  BRANCH IF MORE FOUND       000F 01895315
         DEQ   MF=(E,HRCPO)                                        000F 01896215
         DROP  R4,R8                                               000F 01897115
         B     SD79RETN                 BRANCH TO EXIT RTN         000F 01898015
**********************************************************************  01900000
*                                                                    *  01920000
***                                                                ***  01940000
*        CONSTANTS AND DSECTS                                        *  01960000
***                                                                ***  01980000
*                                                                    *  02000000
         DS    0F                                                       02020000
SD79TO82 DC    CL4'SD79'                                                02040000
SD79OUT  DC    V(IEFSD082)              EXIT ADDRESS                    02060000
SD79QDEL DC    V(IEFQDELE)              ADDR OF QMGR DELETE RTN         02080000
*                                                                    *  02100000
HRCPO    ENQ   (HRSYSIEF,HRCPOWT,E,7,SYSTEM),MF=L                  000F 02105015
HRSYSIEF DC    C'SYSIEFSD'                                         000F 02110015
HRCPOWT  DC    C'CPOWAIT'                                          000F 02115015
**********************************************************************  02115718
*                                                                    *  02116418
R5       EQU   5                                                   SM0I 02117118
R7       EQU   7                                                   SM0I 02117818
R11      EQU   11                                                  SM0I 02118518
TCBTCT   EQU   X'94'                                               SM0I 02119218
IEFSMFWR CLI   PARSMF+3,X'FF'      CHECK FOR SMF PROCESSING        SM0I 02119918
         BE    SMFFINE2            IF NONE SKIP PROCESSING         SM0I 02120618
         L     R10,PARSMF          GET ADDRESS OF SMF WORK AREA    SM0I 02121318
         LTR   R10,R10             CHECK FOR ONE SMB IN JOB        SM0I 02122018
         BZ    SMFFINE2              IF SO SKIP SMF PROCESSING     SM0I 02122718
         USING  SMFREC,R10                                         SM0I 02123418
         CLI   PARWORK2,X'00'      CHECK FOR NO ERRORS             SM0I 02124118
         BE    PROCESS             IF NONE OUTPUT FORM AND JOB REC SM0I 02124818
         CLI   PARWORK2,X'08'      CHECK FOR OUTPUT ERROR          SM0I 02125518
         BE    OPERROR             IF SO-GO SET OUTPUT ERROR SWITCHSM0I 02126218
         CLI   PARWORK2,X'0C'      CHECK FOR INPUT ERROR           SM0I 02126918
         BE    IPERROR             IF SO-GO SET INPUT ERROR SWITCH SM0I 02127618
         B     PROCESS             IF OTHER GO AND PROCESS         SM0I 02128318
IPERROR  OI    SMFERIN,X'01'       SET INPUT ERROR SWITCH ON       SM0I 02129018
         B     PROCESS                                             SM0I 02129718
OPERROR  OI    SMFERIN,X'02'       SET OUTPUT ERROR SWITCH         SM0I 02130418
PROCESS  L     R2,SMFFRMLL         GET LENGTH OF FORM RECORD       SM0I 02131118
         SLL   R2,16               LEFT ADJUST                     SM0I 02131818
         ST    R2,SMFLLBB          STORE IN LLBB                   SM0I 02132518
         TIME  BIN                                                 SM0I 02133218
         STM   R0,R1,SMFWORKA      SAVE STOP TIME AND DATE         SM0I 02133918
         MVC   SMFSPTM(8),SMFWORKA PUT DATE AND TIME INTO SMF      SM0I 02134618
         MVC   SMFFORM(4),PARFORM  MOVE IN FORM NUMBER             SM0I 02135318
         OC    SMFERIN(1),SMFERINJ   OR IN JOB ERROR INDICATOR     SM0I 02136018
SMFSVCWT LA    R1,SMFLLBB          LOAD REG1 WITH RECORD ADDRESS   SM0I 02136718
         SVC   83                                                  SM0I 02137418
         L     R0,SMFWKLL          SET UP TO FREE SMF WORK AREA    SM0I 02138118
         LA    R1,SMFLLBB          GET ADDRESS AND LENGTH          SM0I 02138818
         FREEMAIN    R,LV=(0),A=(1)                                SM0I 02139518
SMFFINE2 XC    PARSMF(4),PARSMF    ZERO OUT SMFREC POINTER         SM0I 02140218
         B     FINISH              RETURN TO DELETE ROUTINE        SM0I 02140918
SMFFRMLL DC    A(SMFENDFM-SMFLLBB)     FORM RECORD LENGTH          SM0I 02141618
         IEFSDSMF                                                MAPMAC 02221600
         IEFSDPAR                                                MAPMAC 02301600
         EJECT                                                          02400000
**********************************************************************  02420000
         IEFQMNGR                                                       02440000
**********************************************************************  02460000
CVT      DSECT                                                     000F 02462015
*              CVT                                                 000F 02464015
         CVT                                                            02466015
*******************************************************************000F 02468015
*        IEEBASEB                                                  000F 02470015
         IEEBASEB                                                       02472015
*******************************************************************000F 02474015
         END                                                            02480000
