         TITLE 'IEFSD080 - VMS SYSOUT WTR  INITIALIZATION'              00010021
IEFSD080 CSECT                                                          00020000
*                                                                       00020120
*          RELEASE 22 DELETIONS/CHANGES                                 00020220
*          RELEASE 21 DELETIONS/CHANGES                                 00020320
* 022042                                NO EXCP IF 3211          SM0217 00020721
* 022042                                   EXCP IF 3211          A64002 00020821
* 022042                                N0 EXCP IF 3211          A59773 00021521
*          RELEASE 20 DELETIONS/CHANGES                                 00022021
* 041900-043300,044200-045000                                    MAPMAC 00022521
* 022030,022038,022100-023350                                    A32047 00023021
*                                                                       00023521
*                                                                 M3785 00024021
* 020800-021205                                                   M3070 00024521
* 044400-044500                                                    I272 00025019
*3245000260-000360                                                 SM0I 00030018
*025100                                                          A29072 00035019
*                                                                S20201 00037020
*                                                                A42459 00038021
         EJECT                                                          00040021
**********************************************************************  00060000
*                                                                    *  00080000
*TITLE-- IEFSD080 - SYSOUT WRITER INITIALIZATION ROUTINE             *  00100000
*                                                                    *  00120000
*0371                                                            A36842 00130021
*STATUS CHANGE LEVEL 007                                                00140021
*FUNCTION/OPERATION--                                                *  00160000
*   THIS ROUTINE SERVES TO INITIALIZE THE SYSOUT WRITER, PERFORMING  *  00180000
*   THE FOLLOWING STEPS                                              *  00200000
*   1. GETS CERTAIN BLOCKS OF STORAGE FOR THE SYSOUT WRITER, INCL.   *  00220000
*      A PARAMETER LIST COMMON TO ALL OF ITS ROUTINES                *  00240000
*   2. INITIALIZES PARTS OF THE PARAMETER LIST                       *  00260000
*   3. GETS DCB FOR PUT LOCATE. READS IN JFCB AND TESTS TO SEE IF  CC0H 00268017
*      CHAIN SCHEDULING IS TO BE DONE ON OUTPUT. IF SO THE DCB IS  CC0H 00276017
*      REPLACED BY A DCB FOR EXCP AND INFORMATION IS SAVED WHICH   CC0H 00284017
*      WILL BE NEEDED TO CONSTRUCT TABLES FOR EXCP.                CC0H 00292017
*   4. SCANS PARAMETER FIELD  PROVIDED IN EXEC PROC STATEMENT FOR THE * 00300000
*      JOB SEPARATOR PROGRAM NAME.IF FOUND,IT IS SAVED LEFT ADJUSTED  * 00320000
*      AND PADDED WITH BLANKS TO MAKE IT 8 CHARACTER FIELD,IF NOT     * 00340000
*      FOUND,THE ENTIRE 8 CHAR JOB SEPARATOR NAME FIELD IS MADE BLANKS* 00360000
*   5. EXITS TO IEFSD081,WITH THE ADDRESS OF THE PARAMETER LIST       * 00380000
*      IN THE STANDARD PARAMETER REGISTER                            *  00400000
*                                                                    *  00420000
*ENTRY POINT--                                                       *  00440000
*        IEFSD080 - BY WAY OF ATTACH BY MASTER SCHEDULER, IN         *  00460000
*   RESPONSE TO A  'START WTR'  COMMAND.                             *  00480000
*                                                                    *  00500000
*INPUT--                                                             *  00520000
*   EXPLICIT--  ADDRESS OF START PARAMETER LIST (SAL) IN REG. 1.   CC0H 00540017
*   IMPLICITLY--  TCB, JFCB, TIOT, UCB.                            CC0H 00560017
*                                                                    *  00600000
*OUTPUT--                                                            *  00620000
*   IN REGISTER 1, THE ADDRESS OF A 13-WORD PARAMETER LIST         CC0H 00650017
*   COMMON TO ALL SYSOUT WRITER ROUTINES.                          CC0H 00680017
*                                                                    *  00720000
*                                                                    *  00740000
*EXTERNAL ROUTINES--NONE                                             *  00760000
*                                                                    *  00780000
*EXIT--  AT END OF INITIALIZATION, CONTROL IS PASSED TO              *  00800000
*        IEFSD081, THE SYSOUT WRITER 'CLASSNAME SET-UP' ROUTINE      *  00820000
*                                                                    *  00840000
*TABLES/WORKAREAS--                                                  *  00860000
*   THIS ROUTINE OBTAINS MAIN STORAGE FOR A  DCB AND A PARAMETER     *  00880000
*   LIST. IT ALSO GETS CORE FOR THE JFCB WHICH IT SUBSEQUENTLY     CC0H 00900017
*   FREES.                                                         CC0H 00920017
*                                                                    *  00960000
*NOTES--                                                             *  00980000
*   THE FOLLOWING SYSTEM MACROS ARE USED--                           *  01000000
*        GETMAIN, FREEMAIN, DCB, DCBD, RDJFCB                      CC0H 01020017
*                                                                    *  01040000
*ATTRIBUTES--                                                        *  01060000
*   THIS ROUTINE IS REENTRANT AND REFRESHABLE.                     CC0H 01080017
*                                                                    *  01100000
**********************************************************************  01120000
***                                                                ***  01140000
*        ESSENTIAL EQUATES                                           *  01160000
***                                                                ***  01180000
R0       EQU   0                                                        01200000
R1       EQU   1                                                        01220000
R2       EQU   2                                                        01240000
R3       EQU   3                                                        01260000
R4       EQU   4                                                        01280000
R5       EQU   5                                                        01300000
R6       EQU   6                                                        01320000
R7       EQU   7                                                        01340000
R8       EQU   8                                                        01360000
R9       EQU   9                                                        01380000
R10      EQU   10                                                       01400000
R11      EQU   11                                                       01420000
R12      EQU   12                                                       01440000
R13      EQU   13                                                       01460000
R14      EQU   14                                                       01480000
R15      EQU   15                                                       01500000
MFTWO    EQU   X'74'                                               000H 01504017
MFTBT    EQU   X'20'                                               000H 01508017
TCBPIB   EQU   X'7C'                                               000H 01512017
PIBWTR   EQU   X'10'                                               000H 01516017
HIAR1    EQU   X'84'                    TEST JFCBHIAR FIELD      A36842 01516521
SET0     EQU   X'7F'                    SET PARUCS TO HIAR 0     A36842 01517021
SET1     EQU   X'80'                    SET PARUCS TO HIAR 1     A36842 01517521
WTRPART  EQU   X'02'              USED TO SET BIT 6 WTR IN PARTIT M3785 01518019
DEVLNGH  EQU   8                       AMOUNT OF CORE FOR DEVTPE A32047 01519020
*                                                                    *  01520000
**********************************************************************  01540000
         EJECT                                                          01560000
**********************************************************************  01580000
*        IEFSD080                       THE PROGRAM                  *  01600000
**********************************************************************  01620000
***                                                                ***  01640000
*        ESTABLISH BASE REGISTER AND SAVE INPUT REGISTERS            *  01660000
***                                                                ***  01680000
         SAVE  (14,12)                  SAVE REGISTERS                  01700000
         BALR  R9,0                     ESTABLISH                       01720000
         USING *,R9                       BASE REGISTER                 01740000
         LR    R7,R1                    SAVE PARAM REG                  01760014
***                                                                ***  01780000
*        GETMAIN AND ESTABLISH ADDRESSABILITY                        *  01800000
***                                                                ***  01820000
         LA    R0,CORELENG              LOAD LTH OF DCB+PARLIST+4  CC0H 01840017
         GETMAIN R,LV=(0)                                               01860000
         LA    R0,CORELENG              REESTABLISH SIZE           SM0I 01870018
         ST    R0,0(R1)                 STORE LENGTH IN FIRST 4 BYTES   01880000
         LA    R2,4(R1)                 INCREMENT ADDR PAST LENGTH      01900000
*                                        FIELD TO DCB ADDR              01920000
         LA    R3,PARDCBLN(R2)          LOAD ADDR OF PARAMETER LIST,    01940000
*                                        HENCEFORTH CALLED 'PARLIST'    01960000
         USING IHADCB,R2                ADDRESSABILITY FOR DCB          01980000
         USING PARLIST,R3               ADDRESSABILITY FOR PARLIST      02000000
         USING SPLAD,R7                 ADDRESSABILITY FOR SPL          02020014
***                                                                ***  02040000
*        INITIALIZE PARTS OF THE PARAMETER LIST                      *  02060000
***                                                           *** M3070 02065019
         ST    R2,PARDCB           STORE DCB ADDR IN PARLIST      M3070 02070019
         ST    R7,PARSPL           STORE SAVED SPL ADDR IN LIST   M3070 02075019
         LA    R0,COMMLENG         GET LENGTH OF EXTRACT PARAMETE M3070 02080019
         GETMAIN R,LV=(0)          GET CORE FOR EXTRACT           M3070 02085019
         MVC   0(COMMLENG,1),COMMLIST  MOVE LIST TO GOTTEN CORE   M3070 02090019
         LR    R10,R1              SAVE GETMAIN ADDRESS           M3070 02095019
         EXTRACT PARCOMM,MF=(E,(1))    EXECUTE EXTRACT SVC        M3070 02100019
         LA    R0,COMMLENG         GET LENGTH OF EXTRACT PARAMETE M3070 02105019
         LR    R1,R10              RESTORE GETMAIN ADDR           M3070 02110019
         FREEMAIN R,LV=(0),A=(1)       FREE CORE FOR EXTRACT       I272 02120619
***                                                             ***000H 02121017
         XC    PARSMF(4),PARSMF    ZERO OUT SMF ADDRESS            SM0I 02121518
*     IF MFT II, SET WTR PRESENT BIT ON IN THE PIB                *000H 02122017
***                                                             ***000H 02123017
         L     R6,16               GET CVT ADDRESS                 000H 02124017
         TM    MFTWO(R6),MFTBT     CHECK IF MFT II                 000H 02125017
         BZ    CONTINUE            IF NOT, AVOID SETTING BIT IN PIB000H 02126017
         L     R6,0(R6)            GET ADDRESS OF TCB ADDRESSES    000H 02127017
         L     R6,4(R6)            GET ADDRESS OF CURRENT TCB      000H 02128017
         OI    TCBPIB(R6),WTRPART      SET WTR IN PARTITION BIT   M3785 02128519
         L     R6,TCBPIB(R6)       NOW GET ADDRESS OF PIB          000H 02129017
         OI    PIBWTR(R6),X'08'    SET WTR PRESENT BIT ON          000H 02134017
***                                                                ***  02140000
*        PREPARE DCB FOR OUTPUT OPEN                                 *  02160000
***                                                                ***  02180000
CONTINUE MVC   0(PARDCBLN,R2),SD80DCB  MOVE OUTPUT DCB INTO GOTCORE000H 02190017
         XC    PAREXCP(4),PAREXCP CLEAR OUT EXCP POINTERS        A32047 02193020
         XC    PARWORK1(16),PARWORK1   CLEAR WRKAREA & SWITCHES  A32047 02196020
*GET CORE FOR JFCB AND DCB EXIT LIST AND MAKE UP EXIT LIST         CC0H 02201017
         L     R6,16                   GET TCB ADDRESS           A32047 02201220
         L     R6,0(R6)                                          A32047 02201420
         L     R6,4(R6)                NOW HAVE TCB ADDRESS      A32047 02201620
         USING TCBAR,R6                ADDRESSABILITY FOR TCB    A32047 02201820
         L     R6,TCBTIO               GET TIOT ADDRESS          A32047 02202020
         USING TIOTAR,R6               ADDRESSIBILITY FOR TIOT   A32047 02202220
         MVC   DCBDDNAM(8),TIOEDDNM    MOVE DDNAME TO DCB        A32047 02202420
         LA    R0,DEVLNGH              AMT OF CORE FOR DEVTYPE   A32047 02202620
         GETMAIN R,LV=(0)              GET CORE FOR DEVTYPE      A32047 02202820
         LR    R11,R1                  SAVE GETMAIN ADDRESS      A32047 02203020
         DEVTYPE DCBDDNAM,(R11)        EXECUTE DEVTYPE SVC       A32047 02203220
         CLC   PAREXCP(4),0(R11)       TEST FOR DUMMY DATA SET   A32047 02203420
         BE    SETDUMSW                YES- BRANCH TO SET SWITCH A32047 02203620
         TM    2(R11),X'08'            TEST FOR UNIT REC-IF NOT  A32047 02203820
         BZ    CLEAREXT                BRANCH TO QSAM DCB IS OK  A32047 02204020
         CLI   3(R11),X'09'            IS IT 3211 PRINTER        A59773 02204121
         BE    CLEAREXT (NOP TO USE EXCP) YES, QSAM REQUIRED     SM0217 02204221
         B     GETCORE                 CONTINUE CHECK FOR QSAM   A59773 02224221
SETDUMSW OI    PARSWCH,PARDUMMY        TURN ON DD DUMMY SWITCH   A32047 02234221
GETCORE  LA    R0,JFCBLGTH+4           GET AMOUNT OF CORE   CCOH A32047 02244221
         GETMAIN R,LV=(0)          GET CORE                 CCOH A32047 02254221
         LR    R4,R1                    SAVE ADDRESS WHERE JFCB PUTCC0H 02264221
         ST    R4,JFCBLGTH(R4)          PUT JFCB AREA ADD IN EXLST CC0H 02274221
         MVI   JFCBLGTH(R4),X'87'       INDICATE THIS IS ONLY ENTRYCC0H 02284221
         LA    R1,JFCBLGTH(R4)          GET EXIT LIST ADDRESS      CC0H 02294221
         ST    R1,DCBRECFM              PUT IT IN EXLST, 0 RECFM   CC0H 02304221
*GET JFCB AND FIND OUT IF EXCP IS TO BE USED                       CC0H 02342017
         LA    R1,PARFORM               LOAD ADDRESS OF WORD USED  CC0H 02349017
*                                        FOR JFCB LIST             CC0H 02356017
         MVC   PARFORM,SD80JFCB         MOVE JFCB LIST TO GOT CORE CC0H 02363017
         RDJFCB ((R2)),MF=(E,(1))       GET JFCB                   CC0H 02370017
         USING JFCAR,R4                 ADDRESSABILITY OF JFCB     CC0H 02377017
         CLI   JFCBUFNO,X'03'           TEST FOR MORE THAN 3 BUFFS CC0H 02384017
         BNH   SD80FREE                 IF NOT THE QSAM DCB IS OK  CC0H 02391017
         TM    JFCRECFM,X'02'           TEST FOR MACHINE OUTPUT    CC0H 02398017
         BZ    SD80FREE                 IF NOT THE QSAM DCB IS OK  CC0H 02405017
         TM    JFCOPTCD,X'20'           TEST FOR PCI SCHED.        CC0H 02412017
         BO    SD80FREE                 IF SO THE QSAM DCB IS OK   CC0H 02419017
*INDICATE EXCP DCB WILL BE USED                                    CC0H 02426017
         TM    JFCBFTEK,HIAR1           IS HIARCH 1 REQUESTED    A36842 02427021
         BO    SETH1                    YES, INDICATE SO         A36842 02428021
         NI    PARUCSID,SET0            NO, INDICATE HIARCH 0    A36842 02429021
         B     INDEXCP                  BRANCH AROUND IND HIAR1  A36842 02430021
SETH1    OI    PARUCSID,SET1            INDICATE HIARCHY 1       A36842 02431021
INDEXCP  EQU   *                                                 A36842 02432021
         LH    R0,JFCBLKSI              GET BLOCK SIZE             CC0H 02433017
         TM    JFCRECFM,VARSW           IF NOT VAR. TYPE THEN      CC0H 02440017
         BZ    FIXLN                    BRANCH TO GO ON            CC0H 02447017
         TM    JFCRECFM,FIXSW           IF FIXED TYPE THEN         CC0H 02454017
         BO    FIXLN                    BRANCH TO GO ON            CC0H 02461017
         LA    R1,4                     GET LENGTH FOR VAR. TYPE   CC0H 02468017
         SR    R0,R1                                               CC0H 02475017
FIXLN    STH   R0,PAREXCP+2             (BYTES 2-3 HAVE BUFF SIZE) CC0H 02482017
         MVC   PAREXCP(1),JFCBUFNO      (BYTE 0 HAS NUMBER)        CC0H 02489017
         MVC   PAREXCP+1(1),JFCRECFM    (BYTE 1 HAS RECORD FORMAT) CC0H 02496017
         MVC   IHADCB(DCBDDNAM-IHADCB),SD80EXC  PUT IN EXCP DCB    CC0H 02503017
         MVC   DCBOFLGS(DCBNCP-DCBOFLGS),SD80EXC+DCBOFLGS-IHADCB A29072 02510019
         NC    JFCLRECL(2),JFCLRECL     TEST FOR 0 LRECL IF SO     CC0H 02517017
         BZ    USEBL                    BRANCH TO BLKSI FOR LRECL  CC0H 02524017
         LH    R0,JFCLRECL              GET LRECL                  CC0H 02531017
USEBL    STH   R0,DCBLRECL              FIXED LRECL MADE BLKSIZE   CC0H 02538017
*FREE THE JFCB                                                     CC0H 02545017
SD80FREE LA    R0,JFCBLGTH+4            GET AMOUNT OF CORE TO FREE CC0H 02552017
         LR    R1,R4                    GET ADDRESS OF JFCB        CC0H 02559017
         FREEMAIN R,LV=(0),A=(1)                                   CC0H 02566017
CLEAREXT LA    R0,DEVLNGH              AMT OF CORE FOR DEVTYPE   A32047 02567020
         LR    R1,R11                  ADDR OF CORE FOR DEVTYPE  A32047 02568020
         FREEMAIN R,LV=(0),A=(1)       FREE CORE FOR DEVTYPE     A32047 02569020
         XC    DCBEXLST+1(3),DCBEXLST+1 CLEAR OUT EXIT LIST PTR.   CC0H 02573017
         LA    R4,PARJSNM                                          CC0H 02580017
         ST    R4,PARJBSEP              SET PTR TO JOB SEP NAME FIELD.  02620000
         MVI   0(R4),C' '               BLANK OUT NAME FIELD.           02640000
         MVC   1(7,R4),0(R4)                                            02660000
**********************************************************************  03160000
*        EXIT                                                        *  03180000
**********************************************************************  03200000
         LR    R1,R3                    LOAD ADDRESS OF PARLIST.        03280000
         L     R15,SD80EXIT             LOAD ADDR FOR EXIT              03300000
         BALR  R14,R15                  LEAVE                           03320000
**********************************************************************  03660000
*                                                                    *  03680000
*                                                                    *  03700000
*                                                                    *  03720000
**********************************************************************  03740000
*        CONSTANTS AND DSECTS                                        *  03760000
**********************************************************************  03780000
COMMLIST EXTRACT ,FIELDS=COMM,MF=L     EXTRACT LIST FORM           I272 03786019
COMMLENG EQU   *-COMMLIST              LENGTH OF EXTRACT PARAMETERSI272 03792019
SD80EXIT DC    V(IEFSD081)              EXIT ADDRESS (CLASSNAME         03800000
*                                        SET-UP RTN OR XCTL RTN)        03820000
SD80EREX EQU   0                        *** TEMP***                  *  03860000
VARSW    EQU   X'40'                    VARIABLE SWITCH            CC0H 03863017
FIXSW    EQU   X'80'                    FIXED SWITCH               CC0H 03866017
SD80JFCB RDJFCB (0),MF=L                READ JFCB LIST             CC0H 03869017
SD80EXC  DCB   DSORG=PS,                                           CC0HX03872017
               CENDA=C5,                                         A29072*03873019
               MACRF=E                                             CC0H 03875017
SD80DCB  DCB   DSORG=PS,                                               X03880000
               MACRF=PL,                                               X03900000
               BFTEK=S,                                                X03920000
               SYNAD=SD80EREX                                           03940000
*                                                                    *  03960000
*                                                                    *  03980000
*                                                                    *  04000000
*                                                                    *  04020000
*        N O T E      THAT IN THE FOLLOWING EXPANSION USED FOR       *  04040000
*        AN OPEN LIST   THE  DCB ADDRESS IS  OVERRIDDEN IN THE       *  04060000
*        ABOVE CODE BY THE ADDRESS OF THE  DCB  WHICH IS ACTUALLY    *  04080000
*        TO BE OPENED, NAMELY, THE ONE IN GOTTEN CORE                *  04100000
*                                                                    *  04120000
*                                                                    *  04160000
         DCBD  DSORG=PS                                                 04180000
         IEFSDPAR                                                MAPMAC 04250020
PARDCBLN EQU   DCBEOB+4-IHADCB                                   MAPMAC 04320020
CORELENG EQU   PARLENGT+PARDCBLN+4      4-EXTRA BYTES FOR CORE ADD CC0H 04400017
         EJECT                                                          04520000
**********************************************************************  04620000
JFCAR    DSECT                                                          04640000
         IEFJFCBN                                                       04660000
         EJECT                                                          04680000
**********************************************************************  04700000
TIOTAR   DSECT                                                          04720000
         IEFTIOT1                                                       04740000
**********************************************************************  04760000
TCBAR    DSECT                                                          04780000
         DS    2F                                                       04800000
TCBDEB   DS    1F                                                       04820000
TCBTIO   DS    1F                                                       04840000
**********************************************************************  04860000
DEBAR    DSECT                                                     CC0H 04862017
         DS    8F                                                  CC0H 04864017
DEBUCB   DS    1F                                                  CC0H 04866017
*******************************************************************CC0H 04868017
UCBAR    DSECT                                                     CC0H 04870017
         IEFUCBOB                                                       04872017
         END   IEFSD080                 ENTRY POINT FOR WRITER   A59773 04880021
