IEFSD082 CSECT                                                          00020000
*                                                                       00020700
*          RELEASE 22 DELETIONS/CHANGES                                 00021400
*          RELEASE 21 DELETIONS/CHANGES                                 00022100
*          RELEASE 20 DELETIONS/CHANGES                                 00022800
* 049000-050680                                                  MAPMAC 00023500
*                                                                       00024200
* 023300-023500,050760-050840                                      I272 00025019
*1244043880-043900                                                 9723 00030017
*1244025000                                                        000H 00035017
         TITLE 'IEFSD082 - VMS SYSOUT WTR  CONTROL ROUTINE'             00040000
**********************************************************************  00060000
*                                                                    *  00080000
*TITLE--       IEFSD082 - SYSTEM OUTPUT WRITER MAIN LOGIC ROUTINE    *  00100000
*                                                                    *  00120000
*STATUS -- CHANGE LEVEL 000                                          *  00140000
*                                                                    *  00160000
*FUNCTION/OPERATION--THE ROUTINE HANDLES THE MAIN LOGIC OF THE       *  00180000
*   SYSOUT WRITER, WITH THE FOLLOWING FUNCTIONS--                    *  00200000
*   1. GETS MAIN STORAGE FOR QUEUE MANAGER PARAMETER AREAS, A SAVE   *  00220000
*      AREA, AND AN SMB/DSB AREA.                                    *  00240000
*      (THIS IS NOT DONE IF ENTRY IS FROM  IEFSD079)                 *  00260000
*   2. INITIALLY, AND AFTER EACH SYSOUT JOB, CHECKS FOR COMMAND      *  00280000
*      POSTING AND  XCTL'S  TO THE COMMAND PROCESSING ROUTINE        *  00300000
*      (IEFSD083) IF IT FINDS THE COMMAND ECB (IN THE  CSCB) POSTED. *  00320000
*   3. FOR EVERY CLASS-ASSOCIATED ECB, IT USES THE QUEUE MANAGER     *  00340000
*      TO DEQUEUE SYSOUT JOBS.                                       *  00360000
*   4. IF IT FINDS NO POSTED  ECB  OR NO WORK IN ALL OF ITS CLASSES, *  00380000
*      IT  XCTL'S  TO A WAIT ROUTINE (IEFSD084) TO WAIT ON ITS       *  00400000
*      LIST OF ECB'S ASSOCIATED WITH ITS SYSOYT CLASSES.             *  00420000
*      (STORAGE OBTAINED IN STEP 1 IS FREED BEFORE EXIT)             *  00440000
*   5. EXITS TO A RTN (IEFSD078) WHICH LINKS TO THE  DSB- OR SMB-RTN *  00460000
*      IF THERE IS WORK ON THE QUEUE OF THE CLASS WHOSE ECB WAS      *  00480000
*      POSTED INITIALLY OR BY THE QUEUE MANAGER                      *  00500000
*   6. EXITS TO THE COMMAND PROCESSING ROUTINE (IEFSD083) ON AN      *  00520000
*      I/O ERROR INDICATION FROM QUEUE MANAGER DEQUEUE ROUTINE       *  00540000
*      AND/OR OTHER SYSOUT ROUTINES.                                 *  00560000
*                                                                    *  00580000
*ENTRY POINT--                                                       *  00600000
*        IEFSD082 - DIRECTLY FROM CLASSNAME SET-UP RTN (IEFSD081),   *  00620000
*   FROM DELETE RTN (IEFSD079) WITH  'SD79'  INDIC. IN REG. 8,       *  00640000
*   OR FROM  WAIT  ROUTINE (IEFSD084).                               *  00660000
*                                                                    *  00680000
*INPUT--ADDRESS OF A 6-WORD PARAMETER LIST WHICH CONTAINS PTRS TO    *  00700000
*   A CSCB, A DCB, AND AN ECB-LIST (ONE ECB PER SYSOUT CLASS         *  00720000
*   ASSOCIATED WITH THIS WRITER).                                    *  00740000
*   THE 6 WORD LIST LOOKS AS FOLLOWS --                              *  00760000
*                             CSCB PTR,                              *  00780000
*                             PTR TO OUTPUT DCB,                     *  00800000
*                             WD OF BLANKS,                          *  00820000
*                             PTR TO ECB LIST,                       *  00840000
*                             NOTHING,                               *  00860000
*                             NOTHING.                               *  00880000
*                                                                    *  00900000
*OUTPUT--THIS ROUTINE ADDS TO THE PARAMETER LIST PTRS TO A QUEUE     *  00920000
*   MANAGER PARAMETER AREA AND AN SMB/DSB AREA, IN THE 5TH AND 6TH   *  00940000
*   WORD, RESP., OF THE LIST.                                        *  00960000
*                                                                    *  00980000
*EXTERNAL ROUTINES--                                                 *  01000000
*        IEFQMDQ2 - QUEUE MANAGER DEQUEUE ROUTINE,                   *  01020000
*        IEFQDELE - QUEUE MANAGER DELETE (OF EXTERNAL SPACE) RTN,    *  01040000
*        IEFSD085 - SYSOUT WRITER DSB ROUTINE                        *  01060000
*        IEFSD086 - SYSOUT WRITER SMB ROUTINE                        *  01080000
*                                                                    *  01100000
*EXIT--UNDER CONDITIONS EXPLAINED IN 'FUNCTION/OPERATION', TO        *  01120000
*        IEFSD083 - SYSOUT WRITER COMMAND PROCESSING ROUTINE,        *  01140000
*        IEFSD084 - SYSOUT WRITER WAIT ROUTINE,  OR                  *  01160000
*        IEFSD078 - SYSOUT WRITER LINK-TO-DSB/SMB RTN                *  01180000
*                                                                    *  01200000
*TABLES/WORKAREAS--NONE USED INTERNALLY, BUT MAIN STORAGE IS         *  01220000
*   OBTAINED FOR QUEUE MANAGER PARAMETER AREAS, A SAVE AREA, AND AN  *  01240000
*   SMB/DSB AREA.  THE ECB LIST IS CONTROLLED IN CONJUNCTION WITH    *  01260000
*   THE WAIT ROUTINE.                                                *  01280000
*   ON SUCCESSFUL SYSOUT DEQUEUE, THE SELF-ID TTR OF THE SMB/DSB (THE*  01300000
*   FIRST OF THIS SYSOUT JOB) IS STORED IN  ECBLIST-8  FOR POSSIBLE  *  01320000
*   REFERENCE BY OTHER SYSOUT ROUTINES.                              *  01340000
*                                                                    *  01360000
*ATTRIBUTES--REENTRANT                                               *  01380000
*                                                                    *  01400000
*NOTES--THE FOLLOWING SYSTEM MACROS ARE USED--                       *  01420000
*        GETMAIN, FREEMAIN, IEFQMNGR, LINK                           *  01440000
*                                                                    *  01460000
**********************************************************************  01480000
*                                                                    *  01500000
***                                                                ***  01520000
*        ESSENTIAL EQUATES                                           *  01540000
***                                                                ***  01560000
R0       EQU   0                                                        01580000
R1       EQU   1                                                        01600000
R2       EQU   2                                                        01620000
R3       EQU   3                                                        01640000
R4       EQU   4                                                        01660000
R5       EQU   5                                                        01680000
R6       EQU   6                                                        01700000
R7       EQU   7                                                        01720000
R8       EQU   8                                                        01740000
R9       EQU   9                                                        01760000
R10      EQU   10                                                       01780000
R11      EQU   11                                                       01800000
R12      EQU   12                                                       01820000
R13      EQU   13                                                       01840000
R14      EQU   14                                                       01860000
R15      EQU   15                                                       01880000
*                                                                    *  01900000
SD82QMPS EQU   44                       SIZE OF QMGR PAR AREA PLUS      01920000
*                                                   EXTERNAL PAR AREA   01940000
SD82SAVS EQU   72                            OF SAVE AREA               01960000
SD82SMBS EQU   180                           OF SMB/DSB + 4             01980000
SD82GETS EQU   SD82QMPS+SD82SAVS+SD82SMBS    OF STORAGE OBTAINED HERE   02000000
POSTED   EQU   X'40'                    MASK FOR POSTED ECB,UPPER BYTE  02020000
IOERROR  EQU   X'0C'                    USED TO INDICATE I/O ERROR      02040000
MFTWO    EQU   X'74'                                               000H 02043017
MFTBT    EQU   X'20'                                               000H 02046017
TCBPIB   EQU   X'7C'                                               000H 02049017
DEFINBIT EQU   X'0C'                                               000H 02052017
STOPWTR  EQU   X'50'                                               000H 02055017
**********************************************************************  02060000
         EJECT                                                          02080000
**********************************************************************  02100000
*        IEFSD082                       THE PROGRAM                  *  02120000
**********************************************************************  02140000
***                                                                ***  02160000
*        ESTABLISH BASE REGISTER, SAVE INPUT                         *  02180000
*        IF ENTRY IS FROM  IEFSD079  (LINK-TO-QMGR-DELETE),          *  02200000
*        SKIP NEXT SECTION OF CODING, GO TO CHECK COMMAND            *  02220000
***                                                                ***  02240000
         BALR  R9,0                                                     02260000
         USING *,R9                                                     02280000
         LR    R6,R1                    SAVE ADDRESS OF PARAM LIST      02300000
         USING PARLIST,R6               ADDRESSABILITY FOR PARAM LIST   02320000
         L     R3,PARCOMM              GET ADDR OF COMM AREA       I272 02328019
         USING COMMAD,R3                                           I272 02336019
         L     R3,COMMECB              GET ADDR OF COMMAND ECB     I272 02344019
***                                                             ***000H 02352017
*     IF MFT II AND THE DEFINE BIT IS ON, STOP THE WRITER         *000H 02354017
***                                                             ***000H 02356017
         L     R10,16              GET CVT ADDRESS                 000H 02358017
         TM    MFTWO(R10),MFTBT    CHECK IF MFT II                 000H 02360017
         BZ    CONTINUE            IF NOT AVOID CHECKING THE PIB   000H 02362017
         L     R10,0(R10)          GET ADDRESS OF TCB ADDRESSES    000H 02364017
         L     R10,4(R10)          GET ADDRESS OF CURRENT TCB      000H 02366017
         L     R10,TCBPIB(R10)     NOW GET ADDRESS OF PIB          000H 02368017
         TM    DEFINBIT(R10),X'04'   CHECK TO SEE IF DEFINE BIT ON 000H 02370017
         BZ    CONTINUE            IF NO, AVOID STOPPING THE WTR   000H 02372017
         OI    0(R3),STOPWTR       POST SPLECB WITH STOP WRITER    000H 02374017
***                                                                ***  02380000
*        LOOK FOR POSTED CONDITION IN  CSCB  TO DETERMINE            *  02400000
*        WHETHER A 'STOP' OR 'MODIFY' COMMAND HAS BEEN               *  02420000
*        ISSUED  AND LEAVE THE ROUTINE IF THE ECB  IN THE            *  02440000
*        CSCB HAS  INDEED BEEN POSTED.  IF NOT, CONTINUE.            *  02460000
***                                                                ***  02480000
CONTINUE TM    0(R3),POSTED        IS THE ECB POSTED               000H 02500017
         BZ    SD82DO                   NO, BRANCH                      02520000
         L     R10,SD82OUT1             IT IS POSTED, PREPARE FOR EXIT  02540000
         C     R8,SD82ENTR              IS ENTRY FROM IEFSD079          02560000
         BE    SD82FREE                 YES, MUST FREE CORE FIRST       02580000
         B     SD82EXIT                 LEAVE DIRECTLY                  02600000
SD82DO   C     R8,SD82ENTR              IS ENTRY FROM ISFSD079          02620000
         BNE   SD82CTNU                 NO, MUST GET CORE               02640000
         CLI   PARWORK2,X'00'           IS ERROR INDICATED              02660000
         BE    SD82STAY                 NO ERROR, CONTINUE              02680000
         L     R10,SD82OUT1             ERROR, LOAD EXIT ADDRESS        02700000
         B     SD82FREE                  AND GO TO EXIT                 02720000
***                                                                ***  02740000
*        GETMAIN FOR QMGR PARAM AREA, EXTERNAL PARAM AREA, SAVE AREA,*  02760000
*        AND SMB/DSB AREA.  INITIALIZE PARLIST FURTHER.              *  02780000
***                                                                ***  02800000
SD82CTNU LA    R0,SD82GETS              LOAD AMT OF CORE WANTED         02820000
         GETMAIN R,LV=(0)                                               02840000
         ST    R1,PARQMPAR              QMGR PARAM AREA ADDRESS         02860000
         LR    R2,R1                                                    02880000
         USING IOPARAMS,R2              QMGR PARAM AREA ADDRESSABILITY  02900000
         XC    QMCAN(44),QMCAN          CLEAR QMGR PARAM AREAS          02920000
         LA    R1,SD82QMPS(R1)          INCREMENT PAST QMGR PARAM AREAS 02940000
         ST    R13,4(R1)                STORE CONT. OF SAVE REGISTER    02960000
         LR    R13,R1                   LOAD THIS PROGRAM'S SAVE ADDR   02980000
         LA    R1,SD82SAVS(R1)          INCREMENT PAST SAVE ADDR        03000000
         ST    R1,PARSMB                STORE THIS AS SMB PTR           03020000
*                                        IN PARAM LIST                  03040000
         ST    R1,QMPCL+4               STORE SAME PTR IN QMGR          03060000
*                                        EXTERNAL PARAM AREA            03080000
         LA    R3,QMPCL+4               STORE ADDR OF THAT AREA         03100000
         ST    R3,QMPCL                   IN THE QMGR PARAM AREA        03120000
         XC    SD82SMBS-4(4,R1),SD82SMBS-4(R1)  CLEAR 4 BYTES PAST SMB  03140000
***                                                                ***  03160000
*        SCAN THE SYSOUT ECB LIST (ADDRESS OF LIST IS IN PARLIST)    *  03180000
*        FOR A POSTED ECB.  IF NONE IS FOUND POSTED, GO TO WAIT RTN  *  03200000
*        VIA PREVIOUS SECTION OF CODING (SD82FREE).  IF ONE IS       *  03220000
*        FOUND POSTED, GO TO ATTEMPT TO DEQUEUE A SYSOUT JOB         *  03240000
*        FROM THE SYSOUT CLASS QUEUE ASSOCIATED WITH THE POSTED ECB. *  03260000
***                                                                ***  03280000
SD82STAY L     R5,PARECBL               GET ECB LIST PTR FROM PARLIST   03300000
SD82EPTR LA    R5,4(R5)                 INCREMENT TO NEXT ECB PTR FLD   03320000
         L     R4,0(R5)                 LOAD CONTENTS OF PTR FIELD      03340000
         TM    0(R4),POSTED             IS ECB POINTED TO  POSTED       03360000
         BO    SD82GODQ                 YES, GO TO TRY TO DEQUEUE JOB   03380000
SD82LAST LTR   R4,R4                    NO, IS THIS LAST ECB PTR        03400000
         BC    11,SD82EPTR              NOT LAST (SIGN IS POSITIVE),    03420000
*                                        GO TO CHECK NEXT ECB           03440000
***                                                                ***  03460000
*        IF LAST ECB PTR (INDICATED BY NEG. BIT 0), GO TO WAIT RTN   *  03480000
***                                                                ***  03500000
         L     R10,SD82OUT2             LOAD WAIT RTN EXIT ADDR         03520000
SD82FREE L     R1,PARQMPAR              RESTORE ADDR OF GOT CORE        03540000
         L     R13,4(R13)               REESTABLISH SAVE AREA REGISTER  03560000
         LA    R0,SD82GETS              LOAD AMT OF CORE TO BE FREED    03580000
         FREEMAIN R,LV=(0),A=(1)         FREE CORE                      03600000
SD82EXIT LR    R1,R6                    RESTORE PARLIST PTR             03620000
         LR    R15,R10                  LOAD PROPER EXIT REGISTER       03640000
         BALR  R14,R15                  ***EXIT DIRECTLY TO WAIT RTN**  03660000
*                                       ***OR COMMAND RTN           **  03680000
*                                       ***(DEPD'G ON CONT. OF R15) **  03700000
*                                                                    *  03720000
***                                                                ***  03740000
*        SET UP ALL NECESSARY FIELDS IN QMGR PARAM AREAS,            *  03760000
*        LINK TO DEQUEUE A SYSOUT JOB                                *  03780000
***                                                                ***  03800000
SD82GODQ MVC   QMTPY(1),4(R4)      MOVE CLASSNAME                       03820016
         LA    R12,0(R4)                LOAD      R4'S 3 LOWER BYTES    03840000
         ST    R12,QMCAN                STORE ECB PTR IN QMGR AREA      03860000
         MVI   QMPOP,QMDTOP             INDICATE 'DEQUEUE' CODE         03880000
         LR    R1,R2                    LOAD ADDR OF QMGR PARAM AREA    03900000
         L     R15,SD82QDEQ             LOAD ADDR OF QMGR DEQUEUE RTN   03920000
         BALR  R14,R15                  LINK TO IT                      03940000
***                                                                ***  03960000
*        ON RETURN, CHECK RETURN CODE IN R15.  IF ZERO, THERE IS     *  03980000
*        WORK,  AND QMGR HAS RETURNED A RECORD IN SMB/DSB AREA       *  04000000
*        IF CODE IS  4, NO WORK WAS FOUND IN QUEUE.                  *  04020000
*        IF CODE IS 12, AN I/O ERROR HAS OCCURRED IN ACCESSING       *  04040000
*                       THE SYSOUT QUEUES BY QUEUE MNGR.  IN THIS    *  04060000
*                       CASE, EXIT IS TAKEN DIRECTLY TO IEFSD083     *  04080000
*                       IN ORDER TO STOP THE WRITER                  *  04100000
***                                                                ***  04120000
         LTR   R15,R15                                                  04140000
         BC    8,SD82TYPE               CODE IS 0, CHECK RECORD TYPE    04160000
         CH    R15,SD82FOUR             IS RETURN CODE = 4              04180000
         BE    SD82LAST                 YES, NO WORK IN THIS CLASS      04200000
SD82ERRO MVI   PARWORK2,IOERROR         PUT ERROR INDIC. INTO PARLIST   04220000
         L     R10,SD82OUT1             LOAD EXIT ADDRESS               04240000
         B     SD82FREE                 BRANCH TO FREE CORE             04260000
***                                                                ***  04280000
*        EXIT TO THE ROUTINE  (IEFSD078)  WHICH LINKS TO THE         *  04300000
*        DSB- OR SMB RTN  (DEPENDING ON THE TYPE OF RECORD           *  04320000
*        RETURNED BY THE QUEUE MANAGER  DEQUEUE ROUTINE)             *  04340000
***                                                                ***  04360000
* TO AVOID LEAVING ECBS ON THE NO WORK CHAIN IF THE WTR ABENDS   * 4870 04362016
* UNPOSTED ECBS ARE UNCHAINED PRIOR TO SERVICING THE REQUEST     * 4870 04364016
* FOR THE OUTPUT WRITER                                          * 4870 04366016
SD82TYPE L     R5,PARECBL              GET THE ECB PTR LIST        4870 04368016
SD82SCAN LA    R5,4(R5)                INDEX TO NEXT ECB           4870 04370016
         L     R1,0(R5)            LOAD CONTENTS OF PTR FIELD      4870 04372016
         CR    R1,R4                   DOES THIS ECB HAVE WORK     4870 04374016
         BE    SD82TEST                YES, SKIP OVER IT           4870 04376016
         LA    R1,0(R1)                CLEAR HI-ORDER BYTE         9723 04377017
         TM    0(R1),POSTED            IS THE ECB POSTED           4870 04378016
         BO    SD82TEST                YES, SKIP OVER IT           4870 04380016
         L     R15,SD82QMNQ            NO, CALL IEFQMUNQ           4870 04382016
         BALR  R14,R15                                             4870 04384016
         OI    0(R1),POSTED            THE ECB MUST BE POSTED      4870 04386016
SD82TEST TM    0(R5),X'80'             IS THIS THE LAST ECB        9723 04388017
         BZ    SD82SCAN                NO, GET ANOTHER ECB         9723 04390017
         LR    R1,R6               GET ADDRESS OF PARLIST          4870 04392016
         L     R4,PARECBL               LOAD ECB LIST PTR               04400000
         SH    R4,SD82EIGT              SUBTRACT EIGHT                  04420000
         L     R5,QMPCL                 LOAD PTR TO EXT. QMGR PAR AREA  04440000
         L     R5,0(R5)                 GET PTR TO IN-CORE SMB/DSB      04460000
         MVC   0(3,R4),0(R5)            MOVE SELF-ID TTR                04480000
*                                        OF SAME INTO  ECBLIST-8        04500000
         L     R15,SD82OUT3             LOAD EXIT ADDR TO IEFSD078      04520000
         BALR  R14,R15                  EXIT TO  IEFSD078               04540000
*                                                                    *  04560000
         EJECT                                                          04580000
**********************************************************************  04600000
***                                                                ***  04620000
*        CONSTANTS AND DSECTS                                        *  04640000
***                                                                ***  04660000
**********************************************************************  04680000
SD82OUT1 DC    V(IEFSD083)              EXIT ADDR TO COMND PROC. RTN    04700000
SD82OUT2 DC    V(IEFSD084)              EXIT ADDR OF WAIT RTN           04720000
SD82OUT3 DC    V(IEFSD078)              EXIT ADDR TO  IEFSD078          04740000
*                                        (OR  XCTL  MODULES TO THESE)   04760000
SD82QDEQ DC    V(IEFQMDQ2)              ADDR OF QMGR DEQUEUE RTN        04780000
SD82QMNQ DC    V(IEFQMUNC)             ADDR OF UNCHAIN RTN         4870 04790016
         DS    0F                                                       04800000
SD82ENTR DC    CL4'SD79'                                                04820000
SD82FOUR DC    H'4'                                                     04840000
SD82EIGT DC    H'8'                                                     04860000
**********************************************************************  04880000
         IEFSDPAR                                                MAPMAC 04970000
COMMAD   DSECT                         COMMUNICATIONS AREA IN CSCB I272 05076019
COMMECB  DS    A                       ADDR OF COMMAND ECB         I272 05084019
COMMCIB  DS    A                       ADDR OF COMMAND INPUT BUFFERI272 05092019
         EJECT                                                          05100000
**********************************************************************  05120000
         EJECT                                                          05180000
**********************************************************************  05200000
         IEFQMNGR                                                       05220000
**********************************************************************  05240000
         END                                                            05260000
