         TITLE 'IEFSD572 MFT INTERPRETER/QMGR INTERLOCK MODULE'         00600015
IEFSD572 CSECT                                                          01200015
* C 850200                                                       A50447 01250021
*********************************************************************** 01800015
*        MODULE IEFSD572 - MFT INTERPRETER/QMGR INTERLOCK MODULE      * 02400015
*                                                                     * 03000015
*********************************************************************** 03600015
*                                                                     * 04200015
*STATUS - CHANGE LEVEL 000                                            * 04800015
*                                                                     * 05400015
*FUNCTION - TO DETERMINE IF A READER REQUIRING QUEUE SPACE IS         * 06000015
*  TRANSIENT,AND IF SO TO OFFER A WAIT OR CANCEL OPTION TO THE        * 06600015
*  OPERATOR AND TAKE APPROPRIATE ACTION.                              * 07200015
*                                                                     * 07800015
*ENTRY POINT - IEFSD572  FROM IEFQASGQ- Q MGR ASSIGN                  * 08400015
*                                                                     * 09000015
*INPUT - A QUEUE MANAGER PARAMETER AREA PT TO BY REGISTER 1.          * 09600015
*        SAVE AREA PT TO BY REG 13.                                   * 10200015
*OUTPUT - NONE                                                        * 10800015
*                                                                     * 11400015
*EXTERNAL REFERENCES - IEFQDELE - QUEUE MGR DELETE ROUTINE            * 12000015
*                      IEFSD573 - MESSAGE MODULE                      * 12600015
*EXITS - RETURN IF A WAIT FOR SPACE IS SELECTED OR THE READER         * 13200015
*        IS IN A READER PARTITION. ABEND IF CANCEL IS SELECTED        * 13800015
*                                                                     * 14400015
*ERROR CODES - NONE                                                   * 15000015
*TABLES/WORKAREAS  74 BYTES FOR A MESSAGE CONSTRUCTION AREA           * 15600015
*                                                                     * 16200015
*                  TCB                                                * 16800015
*                  QUEUE MANAGER PARAMETER AREA                       * 17400015
*ATTRIBUTES - READ ONLY, REENTRANT                                    * 18000015
*                                                                     * 18600015
*OPERATION -                                                          * 19200015
*            WHEN THE READER/INTERPRETER REQUESTS TRACK ASSIGNMENT FOR* 19800015
*        THE JOB IT IS PROCESSING, AND THERE IS NO SPACE TO ASSIGN,   * 20400015
*        THE ASSIGN ROUTINE (IEFQASGQ) PASSES CONTROL TO THIS INTER-  * 21000015
*        LOCK ROUTINE (IEFSD572) TO EXAMINE FOR A POSSIBLE INTERLOCK  * 21600015
*        CONDITION.  IF THE READER IS TRANSIENT, THE POSSIBILITY EX-  * 22200015
*        ISTS THAT SPACE NEEDED BY THE READER/INTERPRETER CAN ONLY BE * 22800015
*        PROVIDED BY THE TERMINATION ROUTINES, WHICH MUST OPERATE IN  * 23400015
*        THE PARTITION THAT THE READER OCCUPIES.  THE REQUESTED SPACE * 24000015
*        IS NOT AVAILABLE, THE ROUTINE ISSUES A MESSAGE TO THE OPERAT-* 24600015
*        OR REQUESTING A REPLY OF 'WAIT' OR 'CANCEL'.  IF THE REPLY IS* 25200015
*        WAIT, THIS ROUTINE RETURNS TO THE ASSIGN ROUTINE TO WAIT FOR * 25800015
*        AVAILABLE SPACE.  (IF THE READER REQUESTING SPACE IS A RES-  * 26400015
*        IDENT READER, NO MESSAGE IS ISSUED, AND A REPLY WAIT IS      * 27000015
*        ASSUMED.)                                                    * 27600015
*            IF THE REPLY IS CANCEL, CONTROL PASSES TO THE DELETE ROU-* 28200015
*        TINE (IEFQDELQ) TO DELETE ALL QUEUE SPACE ASSIGNED TO THE JOB* 28800015
*        BEING PROCESSED (IF ANY SPACE HAD ALREADY BEEN ASSIGNED).    * 29400015
*        WHEN CONTROL RETURNS, THE INTERLOCK ROUTINE ABNORMALLY TERM- * 30000015
*        INATES THE JOB WITH A JOB CANCELLED CODE OF 222.  NORMAL     * 30600015
*        INITIATOR OPERATION RECOVERS THE PARTITION FOR FURTHER USE.  * 31200015
*********************************************************************** 31800015
R0       EQU   0                                                        32400015
R1       EQU   1                                                        33000015
R2       EQU   2                   QMPA REG                             33600015
R3       EQU   3                   CVT BASE                             34200015
R4       EQU   4                   ECB PT & TCB PT                      34800015
R5       EQU   5                   MSG MOD & DSECT BASE                 35400015
R6       EQU   6                   BASE REG                             36000015
R7       EQU   7                                                        36200018
R8       EQU   8                                                        36400018
R12      EQU   12                                                       36600015
R13      EQU   13                  SAVE AREA PT                         37200015
R14      EQU   14                  RETURN REG                           37800015
R15      EQU   15                  ENTRY REG                            38400015
         USING CVTD,R3                                                  39000015
         USING BASE,R7                                                  39200018
         USING IEFCSCB,R8                                               39400018
         USING IOPARAMS,R2                                              39600015
         STM   R14,R12,12(13)      SAVE REGS                            40200015
         BALR  R6,0                SET ADDRESSABILITY                   40800015
         USING *,R6                                                     41400015
         LR    R2,R1               SAVE QMPA PT                         42000015
         L     R3,CVTPTR           ADDRESS CVT                          42600015
         L     R4,CVTTCBP          GET OLD/NEW                          43200015
         L     R4,4(R4)            GET CURRENT TCB PT.                  43800015
         TM    TCBPIB(R4),X'C0'    IS THIS A PROB PGM PARTITION?        44400015
TCBPIB   EQU   124                 PART INFO BLOCK DISPLACEMENT &ID     45000015
         BC    14,EXIT            BR NO                                 45600015
         L     R7,CVTMSER              SET UP ADDRESSABILITY FOR BASEB  45700018
         L     R8,BACHN                SET UP ADDRESSABILITY FOR CSCB   45800018
         IC    R0,CHUCMP               GET THE CONSOLE ID          MCS  45900018
         L     R5,VSD573           PT TO MSG MODULE                     46200015
         USING IEFSD573,R5                                              46800015
         LR    R1,R5               PT TO DISPLAY A MSG                  47400015
         WTO   MF=(E,(1))          WRITE BEFORE ENTERING TO SYSTEM      48000015
         LA    R1,CMDDA                POINT TO D A COMMAND         MCS 48400018
         SR    R0,R0                   ZERO R 0 FOR INTERNAL SVC 34     48900018
         SVC   34                  AUTOMATIC DISPLAY A                  49200015
         GETMAIN R,LV=MSGLG                                             49800015
         LR    R3,R1               SET AREA BASE                        50100015
TRYAGAIN MVC   0(MSGLG,R3),MSGRPLY FORMAT MSG AREA                      50400015
         USING MSGRPLY,R3                                               51600015
         MVC   MSGNAM(8),QMNAM     MOVE JOBNAME TO MESSAGE              52200015
         LA    R1,MSGHD            PT TO WTOR PARMS                     52800015
         LA    R4,MSGECB           PT TO REPLY ECB                      53400015
         IC    R0,CHUCMP               GET CONSOLE ID              MCS  53700018
         WTOR  ,(3),6,(4),MF=(E,(1))                                    54000015
         WAIT  ECB=(4)                                                  54600015
         CLC   MSGRPLY(5),WAIT     IS REPLY WAIT?                       55200015
         BNE   TRYCL              BR NO TO TRY CANCEL                   55800015
         LA    R4,1               SET WAIT INDICATOR                    56400015
         B     FREE               GO FREE AND EXIT                      57000015
TRYCL    CLC   MSGRPLY(6),CANCEL   IS IT CANCEL?                        57600015
         BNE   TRYAGAIN            BR NO TO REISSUE REPLY               58200015
         SR    R4,R4              ZERO REG4 AS CANCEL INDIC             58800015
FREE     EQU   *                                                        59400015
         LR    R1,R3                                                    60000015
         FREEMAIN R,LV=MSGLG,A=(1)                                      60600015
         LTR   R4,R4              TEST FOR WAIT OR CANCEL               61200015
         BP    EXIT               IF POSITIVE RETURN TO ASSIGN          61800015
         CLI   QMNOT,0             ANY LTRKS ASSIGNED?                  62400015
         BZ    ABEND                                                    63000015
         DEQ   MF=(E,IEFQASGA)     DEQUEUE OFF RESOURCE                 63600015
         LOAD  EP=IEFQDELE         LOAD Q MGR DELETE MODULE             64000015
         LR    R15,R0              SET ENTRY POINT FOR BRANCH           64400015
         LR    R1,R2               SET QMPA                             64800015
         MVI   QMPOP,QMDELE        INDICATE DELETE                      65400015
         BALR  R14,R15             GO DELETE LTRKS FROM JOB QUEUE       66000015
ABEND    L     R1,ABCODE           SET CANCELLED CODE                   66600015
         ABEND (1)                 ABEND READER                         67200015
EXIT     LM    R14,R12,12(R13)     RESTORE AND RETURN                   67800015
         BR    R14                                                      68400015
IEFQASGA ENQ   (IEFSQCBS,IEFQ2QCB,E,2,SYSTEM),MF=L                      69000015
         DS    0F                                                       69600015
ABCODE   DC    X'80222000'                                              70200015
VSD573   DC    V(IEFSD573)                                              71400015
IEFSQCBS DC    C'SYSIEFSD'                                              72000015
IEFQ2QCB DC    C'Q2'                                                    72600015
WAIT     DC    C'WAIT '                                                 73200015
CANCEL   DC    C'CANCEL'                                                73800015
         IEFQMNGR                                                       74400015
CVTD     DSECT                                                          75000015
         CVT                                                            75600015
         IEEBASEB                                                       75700018
IEFCSCB  DSECT                                                          75800018
         IEECHAIN                                                       75900018
IEFSD573 CSECT                                                          76200015
MSGDA    DC    AL2(MSGND-MSGDA)                                         76800015
         DC    B'0100000000000000'     MCSFLAGS                    MCS  77400018
         DC    C'IEF871I SYSTEM ISSUED DISPLAY A'                       78000018
MSGND    EQU   *                                                        78600015
         DC    X'4000'                 ROUTER CODE            MCS       78800018
         DC    X'1000'                 DESCRIPTER CODE             MCS  79000018
         DS    0F                                                       79200015
MSGRPLY  DC    CL6' '                                                   79800015
MSGX     DC    H'0'                                                     80400015
MSGECB   DC    F'0'                                                     81000015
MSGHD    DC    2F'0'                                                    81600015
MSGQF    DC    AL2(MSGQND-MSGQF)                                        82200015
         DC    B'1100000000000000'             MCSFLAGS            MCS  82800018
         DC    C'IEF865A Q FULL REPLY ''WAIT'' OR ''CANCEL''- '         83400015
MSGNAM   DC    CL8' '                                                   84000015
MSGQND   EQU   *                                                        84600015
         DC    B'1000000000000000'    ROUTE CODE                   MCS  84800018
         DC    B'0100000000000000'     DESC CODE                 MCS    85000018
         DS    0F         TO SET D A ON HALFWORD BNDRY           A50447 85020021
CMDDA    DC    AL2(CMDEND-CMDDA)       LENGTH OF COMMAND            MCS 85040018
         DC    AL2(0)                                                   85080018
         DC    C'D A '                 DISPLAY ACTIVE             M2126 85120018
CMDEND   EQU   *                                                        85160018
MSGLG    EQU   *-MSGRPLY                                                85200015
         END                                                            85800015
