         TITLE '   MFT PURGE ROUTINE FOR SDASD  '                       00100016
IEFSD598 CSECT                                                     MFT2 00200016
* 453000,456000                                                  A24268 00220019
*                                                                A22926 00250018
         EJECT                                                          00300016
*        GENERAL REGISTER EQUATES                                       00400016
         SPACE 1                                                        00500016
GMREG    EQU   0                        FOR REGISTER GETMAIN            00600016
WORKREG0 EQU   0                        GENERAL WORK REGISTER           00700016
FMREG    EQU   1                        FOR REGISTER FREEMAIN           00800016
INPUTREG EQU   1                        POINTER TO INPUT LIST           00900016
SUMREG   EQU   1                        FOR REGMAIN CALCULATIONS        01000016
GMRETREG EQU   1                        RETURN REGISTER FROM GETMAIN    01100016
ABENDREG EQU   1                        WHEN ABENDING CURRENT REQUESTOR 01200016
MCTCBRG  EQU   1                        THE ADDR OF THE MC TASK         01300016
BASEREG  EQU   2                        BASE REGISTER                   01400016
WORKREG3 EQU   3                        GENERAL WORK REGISTER           01500016
CURTCB   EQU   4                        CURRENT TCB ADDRESS             01600016
CURRB    EQU   5                        CURRENT RB ADDRESS              01700016
WORKREG4 EQU   6                        GENERAL WORK REGISTER           01800016
TOPPARM  EQU   6                        ADDRESS OF 1ST LIST ELEMENT     01900016
CURMIN   EQU   7                        CURRENT MINOR QCB ADDRESS       02000016
CURMAJ   EQU   8                        CURRENT MAJOR QCB ADDRESS       02100016
CURQEL   EQU   9                        CURRENT QEL ADDRESS             02200016
TASKTCB  EQU   10                       TCB ADDR FOR TASK SWITCH        02300016
CURPARM  EQU   10                       CURRENT LIST ELEMENT            02400016
WORKREG1 EQU   11                       GENERAL WORK REGISTER           02500016
WKRG1    EQU   11                       GENERAL WORK REGISTER           02600016
TCBREG   EQU   11                       FOR RIPPLING DOWN TCB QUEUE     02700016
JSTCBRG  EQU   12                       ADDRESS OF JOB STEP TCB         02800016
WORKREG2 EQU   12                       GENERAL WORK REGISTER           02900016
WKRG2    EQU   12                       GENERAL WORK REGISTER           03000016
LINKREG  EQU   14                      INTERNAL LINK REGISTER           03100016
RETREG   EQU   14                       RETURN REGISTER                 03200016
GENREG   EQU   15                       SELECTED USE                    03300016
MASKREG  EQU   15                       DISPATCHABILITY MODIFIER        03400016
UCBREG   EQU   3                                                        03420016
ZENREG   EQU   3                                                        03440016
RELWK1   EQU   12                                                       03460016
         EJECT                                                          03500016
*        TCB EQUATES                                                    03600016
         SPACE 1                                                        03700016
TCBPKF   EQU   28                       TCB PROTECT KEY FIELD           03800016
TCBFLG   EQU   29                       *                               03900016
TCBFLG1  EQU   30                       * TCB FLAGS                     04000016
TCBFLG2  EQU   31                       *                               04100016
TCBDISP  EQU   33                       TCB DISPATCHABILITY FLAGS       04200016
TCBGRS0  EQU   48                       OFFSET TO TCB REGISTER SAVE     04300016
TCBCT    EQU   34                      ENQ COUNT FIELD IN TCB           04400016
TCBTCB   EQU   116                      NEXT LOWER TCB ON READY QUEUE   04500016
JSPTR    EQU   124                      ADDR OF JOB STEP TCB IN TCB     04600016
TCBNTC   EQU   128                      ADDRESS OF SISTER TCB           04700016
TCBOTC   EQU   132                      ADDRESS OF MOTHER TCB           04800016
TCBLTC   EQU   136                      ADDRESS OF DAUGHTER TCB         04900016
         SPACE 1                                                        05000016
ABTERM   EQU   X'80'                    ABTERM BIT IN TCB               05100016
TCBFJMC  EQU   X'08'                    TO SET TCB MUST COMPLETE        05200016
TCBRJMC  EQU   X'F7'                    TO RESET STEP MUST COMPLETE     05300016
TCBFSMC  EQU   X'10'                    TO SET TCB SYS MUST COMPLETE    05400016
TCBRSMC  EQU   X'EF'                    TO RESET SYS MUST COMPLETE      05500016
TCBFXS   EQU   X'01'                    SET TO DEFER ASYNC EXITS        05600016
TCBFXR   EQU   X'FE'                    RESET ASYNC EXIT FLAG           05700016
PKEY0    EQU   X'F0'                    PROTECT KEY PORTION OF TCBPKF   05800016
         SPACE 3                                                        05900016
*        RB EQUATES                                                     06000016
         SPACE 1                                                        06100016
PSWADR   EQU   16                       RESUME PSW IN RB                06200016
RBWCF    EQU   28                       WAIT COUNT FIELD IN RB          06300016
SVCOPSW  EQU   33                       SECOND BYTE OF SVC OLD PSW      06400016
XSAV     EQU   96                       EXTENDED SAVE AREA              06500016
         SPACE 3                                                        06600016
*        GENERALIZED EQUATES                                            06700016
         SPACE 1                                                        06800016
ONE      EQU   1                        VALUE OF ONE                    06900016
LPSW     EQU   8                        LENGTH OF PSW                   07000016
PREVIOUS EQU   5                        DISPLACEMENT TO PREVIOUS FIELD  07100016
         SPACE 1                                                        07200016
WAITIND  EQU   X'00'                    FOR TESTING                     07300016
ANYON    EQU   X'FF'                    BYTE VALUES                     07400016
RESERVED EQU   X'40'                                                    07410016
RESINDIC EQU   41            UCB RESERVE INDICATOR                      07415016
CURPRG   EQU   104           OFFSET TO XR8 IN TCB                       07420016
PTRUCB   EQU   12            OFFSET TO UCB IN PLIST                     07430016
QELUCB   EQU   12            OFFSET TO UCB IN QEL                       07440016
UCBRSCT  EQU   40            OFFSET TO RESERVE COUNT IN UCB             07450016
UCBSKA   EQU   48            OFFSET TO SEEK FIELD IN UCB                07460016
         EJECT                                                          07500016
*        PARAMETER LIST ELEMENT                                         07600016
         SPACE 3                                                        07700016
*******************************************                             07800016
* 0       * 1        * 2       * 3        *                             07900016
* LISTEND *  LMINOR  * PARMCDS *  RETURN  *                             08000016
*         *          *         *          *                             08100016
*******************************************                             08200016
* 4                                       *                             08300016
*    ADDRESS OF MAJOR RESOURCE NAME       *                             08400016
*                                         *                             08500016
*******************************************                             08600016
* 8                                       *                             08700016
*    ADDRESS OF MINOR RESOURCE NAME       *                             08800016
*                                         *                             08900016
*******************************************                             09000016
*12                                       *                             09003016
*  POINTER TO THE UCB ADDRESS             *                             09006016
*     FOR RESERVE REQUESTS                *                             09009016
*******************************************                             09012016
         SPACE 2                                                        09015016
*  DEFINITION OF FLAGS AT OFFSET 2                                      09018016
*  BIT 0 - IF SET TO ONE, INDICATES SHARED REQUEST                      09021016
*        - IF SET TO ZERO, INDICATES EXCLUSIVE REQUEST                  09024016
*  BIT 1 - SEE BELOW                                                    09027016
*  BIT 2 - IF SET TO ONE, INDICATES REQUEST FOR SYSTEM MUST COMPLETE    09030016
*  BIT 3 - IF SET TO ONE, INDICATES REQUEST FOR STEP MUST COMPLETE      09033016
* BIT 4 - SEE BELOW                                                     09036016
* BITS 5,6, AND 7                                                       09039016
*          001 - RET=HAVE                                               09042016
*          011 - RET=USE                                                09045016
*          111 - RET=TEST                                               09048016
*  BITS 1 AND 4 PERTAIN TOTHE SCOPE OF THE REQUEST AND HAVE THE FOLL    09051016
*          OWING MEANING                                                09054016
*        BIT 1     BIT 4     MEANING                                    09057016
*          0         0       STEP                                       09060016
*          0         1       RESERVE                                    09063016
*          1         0       SYSTEM                                     09066016
*          1         1       SYSTEMS                                    09069016
*  ON A RESERVE REQUEST, THE SCOPE IS AUTOMATICALLY CONVERTED TO        09072016
*  SYSTEMS.(KNOWN ACROSS SYSTEMS).                                      09075016
         SPACE 3                                                        09100016
*        WHERE:                                                         09200016
         SPACE 1                                                        09300016
LISTEND  EQU   0                        OFFSET TO LIST END INDICATOR    09400016
LMINOR   EQU   1                        OFFSET TO LENGTH OF MINOR NAME  09500016
PARMCDS  EQU   2                        OFFSET TO PARAMETER CODES       09600016
RETURN   EQU   3                        OFFSET TO RETURN CODE FIELD     09700016
PTRMAJ   EQU   4                        OFFSET TO ADDR OF MAJOR NAME    09800016
PTRMIN   EQU   8                        OFFSET TO ADDR OF MINOR NAME    09900016
         SPACE 1                                                        10000016
ENDIND   EQU   X'FF'                    INDICATOR FOR END OF LIST       10100016
PLMI     EQU   X'80'                    PLUS OR MINUS INDICATOR         10200016
SHARE    EQU   X'40'                    SHARED RESOURCE INDICATOR       10300016
SMC      EQU   X'30'                    SET MUST COMPLETE INDICATORS    10400016
SMCSYS   EQU   X'20'                    SYSTEM MUST COMPLETE            10500016
SMCSTP   EQU   X'10'                    STEP MUST COMPLETE              10600016
HAVE     EQU   X'01'                    TO TEST 'HAVE' MASK             10700016
USE      EQU   X'03'                    TO TEST 'USE' MASK              10800016
TEST     EQU   X'07'                    TO TEST 'TEST' MASK             10900016
AVAIL    EQU   X'00'                    RETURN CODE OF ZERO             11000016
INUSE    EQU   X'04'                    RETURN CODE OF FOUR             11100016
HAS      EQU   X'08'                    RETURN CODE OF EIGHT            11200016
         SPACE 1                                                        11300016
PARMSIZE EQU   12                       LENGTH OF ELEMENT               11400016
LPARM    EQU   12                       LENGTH OF ELEMENT               11500016
         EJECT                                                          11600016
*****    CONTROL BLOCK FORMATS    *****                                 11700016
         SPACE 3                                                        11800016
*        MAJOR QUEUE CONTROL BLOCK                                      11900016
         SPACE 1                                                        12000016
*******************************************                             12100016
* 0                                       *                             12200016
*        ADDRESS OF NEXT MAJOR QCB        *                             12300016
*                                         *                             12400016
*******************************************                             12500016
* 4                                       *                             12600016
*       ADDRESS OF PREVIOUS MAJOR QCB     *                             12700016
*                                         *                             12800016
*******************************************                             12900016
* 8                                       *                             13000016
*        ADDRESS OF FIRST MINOR QCB       *                             13100016
*                                         *                             13200016
*******************************************                             13300016
* 12                                      *                             13400016
*             MAJOR QCB NAME              *                             13500016
*                                         *                             13600016
*******************************************                             13700016
* 16                                      *                             13800016
*             MAJOR QCB NAME              *                             13900016
*                                         *                             14000016
*******************************************                             14100016
         SPACE 2                                                        14200016
NXMAJ    EQU   0                        POINTER TO NEXT MAJOR QCB       14300016
PREVMAJ  EQU   4                        POINTER TO PREVIOUS MAJOR QCB   14400016
FSTMIN   EQU   8                        POINTER TO FIRST MINOR QCB      14500016
LMAJ     EQU   8                        LENGTH OF MAJOR NAME            14600016
MAJNAME  EQU   12                       MAJOR QCB NAME                  14700016
MAJSIZE  EQU   24                       SIZE OF MAJOR TO A DBL WORD     14800016
MAJCLR   EQU   4                        PORTION TO CLEAR IN MINOR QCB   14900016
         EJECT                                                          15000016
*        MINOR QUEUE CONTROL BLOCK                                      15100016
         SPACE 1                                                        15200016
*******************************************                             15300016
* 0                                       *                             15400016
*          ADDRESS OF FIRST QEL           *                             15500016
*                                         *                             15600016
*******************************************                             15700016
* 4                                       *                             15800016
*      ADDRESS OF PREVIOUS MINOR QCB      *                             15900016
*                                         *                             16000016
*******************************************                             16100016
* 8                                       *                             16200016
*        ADDRESS OF NEXT MINOR QCB        *                             16300016
*                                         *                             16400016
*******************************************                             16500016
* 12      * 13       * 14                 *                             16600016
* LENGTH  *  QCBPKF  *   MINOR QCB NAME   *                             16700016
*         *          *                    *                             16800016
*******************************************                             16900016
* 16                                      *                             17000016
*           MINOR QCB NAME                *                             17100016
*         (VARIABLE LENGTH)               *                             17200016
*******************************************                             17300016
         SPACE 3                                                        17400016
FSTQEL   EQU   0                        ADDRESS OF FIRST QEL            17500016
PREVMIN  EQU   4                        ADDRESS OF PREVIOUS MINOR QCB   17600016
NXMIN    EQU   8                        ADDRES OF NEXT MINOR QCB        17700016
ELEVEN   EQU   11                       DISPLACEMENT TO LENGTH -1       17800016
LMINAME  EQU   12                       LENGTH OF MINOR NAME            17900016
QCBPKF   EQU   13                       TCB PROTECT KEY FIELD IN QCB    18000016
MINAME   EQU   14                       MINOR NAME                      18100016
TWELVE   EQU   12                                                       18110019
         SPACE 1                                                        18200016
NOKEY    EQU   X'FF'                    INDICATES A SHARED RESOURCE     18300016
         SPACE 1                                                        18400016
MINCLR   EQU   4                        PORTION TO CLEAR IN MINOR QCB   18500016
FULLSIZE EQU   21                       ALLOW ROUNDING TO A DBL WORD    18600016
         EJECT                                                          18700016
*              QUEUE ELEMENT              *                             18800016
         SPACE 1                                                        18900016
*******************************************                             19000016
* 0       * 1                             *                             19100016
*   SMC   *    ADDRESS OF NEXT QEL        *                             19200016
*         *                               *                             19300016
*******************************************                             19400016
* 4       * 5                             *                             19500016
*  CODE   *   ADDRESS OF PREVIOUS QEL     *                             19600016
*         *                               *                             19700016
*******************************************                             19800016
* 8                                       *                             19900016
*      ADDRESS OF ENQUEUEING TCB          *                             20000016
*                                         *                             20100016
*******************************************                             20200016
* 12                                      *                             20300016
*      ADDRESS OF SVRB FOR ENQ            *                             20400016
*                                         *                             20500016
*******************************************                             20600016
         SPACE 2                                                        20610016
*  IF THE QEL REPRESENTS A RESERVE REQUEST AND THE REQUESTOR WAS GIVEN  20620016
*  CONTROL OF THE RESOURCE, OFFSET 12 WILL CONTAIN THE UCB ADDRESS      20630016
*  OFFSET 4 FLAG DEFINITIONS                                            20640016
*  X'00' - INDICATES EXCLUSIVE REQUEST                                  20650016
*  X'40' - INDICATES RESERVE REQUEST                                    20660016
*  X'80' - INDICATES SHARED REQUEST                                     20670016
         SPACE 2                                                        20700016
NXQEL    EQU   0                        POINTER TO NEXT QEL             20800016
QELSMC   EQU   0                        SMC INDICATOR IN QEL            20900016
PREVQEL  EQU   4                        POINTER TO PREVIOUS QEL         21000016
QELCDS   EQU   4                        QEL CODE BYTE                   21100016
QELCLR   EQU   4                        PORTION TO BE CLEARED IN QEL    21200016
QELTCB   EQU   8                        POINTER TO TCB                  21300016
SVRBPTR  EQU   12                       POINTER TO SVRB OF ENQ          21400016
QELSIZE  EQU   16                       LENGTH OF QEL                   21500016
NEGCODE  EQU   X'80'                    INDICATES MINUS QEL REQUEST     21600016
         EJECT                                                          21700016
         SAVE  (0,12),T                                                 21800016
IEAOEQ01 BALR  BASEREG,0                                                21900016
         USING *,BASEREG                                           MFT2 22000016
         SSM   DISABLE                                                  22100016
         LA    CURTCB,0(CURTCB)   CLEAR HIGH ORDER BYTE                 22200016
         SR    WORKREG0,WORKREG0        INITIALIZE COMPERAND            22300016
         L     CURMAJ,16                                                22400016
         L     CURMAJ,52(CURMAJ)                                        22500016
         L     CURMAJ,12(CURMAJ)                                        22600016
         SPACE 1                                                        22700016
LOADMAJ  CL    WORKREG0,NXMAJ(CURMAJ)   Q. IS MAJOR PRESENT             22800016
         BC    8,EXIT                   BR TO GET NEXT LOAD        MFT2 22900016
         SPACE 1                                                        23000016
REPTEMAJ L     CURMAJ,NXMAJ(CURMAJ)     GET ADDRESS OF MAJOR QCB        23100016
*                                                                       23200016
* FOR DATA SET INTEGRITY, R4 PLUS = STEPTERM ENTRY, R4 MINUS =          23300016
* JOBTERM ENTRY                                                         23400016
* TEST IS AGAINST REGISTER 4 IN REGISTER SAVE AREA                      23500016
*                                                                       23600016
         TM    36(13),X'80'       IS JOBTERM INDICATED                  23700016
         BO    CMPMINOR           YES, PURGE ALL RESOURCES FOR JOB      23800016
         CLC   MAJNAME(LMAJ,CURMAJ),DSN  IS MAJOR FOR DATA SET INTEGRI  23900016
         BE    LOADMAJ            YES, BYPASSFOR STEPTERM               24000016
         B     CMPMINOR           NO, CONTINUE PURGE                    24100016
*                                                                       24200016
DSN      DC    C'SYSDSN  '                                              24300016
*                                                                       24400016
CMPMINOR DS    0F                                                       24500016
         CL    WORKREG0,FSTMIN(CURMAJ)  Q. IS THERE A MINOR             24600016
         BC    8,FREMAJ                 NO MINOR, DEQUEUE MAJOR         24700016
         SPACE 1                                                        24800016
*    THE SITUATION TESTED FOR ABOVE, A MAJOR QCB WITHOUT A              24900016
*    MINOR QCB, CAN ARISE IF THE TASK WAS ABENDED FROM ENQ.             25000016
*    IF WE FALL THROUGH TO HERE, THERE IS A MINOR QCB.                  25100016
*    NOTE THAT THERE CANNOT BE A MINOR QCB WITHOUT A QEL.               25200016
*    UNLESS ENQ FAILED IN ATTEMPT TO GETMAIN FOR QEL, THEN WE WILL    * 25230018
*    DEQUEUE A MINOR WITHOUT A QEL(22926).                            * 25260018
         SPACE 1                                                        25300016
         LA    WORKREG3,TESTMIN         SET EXIT ADDRESS                25400016
         L     CURMIN,FSTMIN(CURMAJ)    GET THE ADDRESS OF THE MINOR    25500016
REPTEMIN SR    WORKREG1,WORKREG1        INITIALIZE INDICATOR            25600016
         CL    WORKREG1,FSTQEL(CURMIN) IS THERE A QEL?           A22926 25630018
         BC    8,DQMINOR               NO QEL,DEQUEUE MINOR      A22926 25660018
         L     CURQEL,FSTQEL(CURMIN)    GET FIRST QEL                   25700016
         CL    CURTCB,QELTCB(CURQEL)    Q. SHOULD IT BE DEQUEUED        25800016
         LR    WORKREG0,CURQEL          YES, SAVE ADDRESS OF QEL        25900016
         BC    8,TSTNXT                 YES, TAKE BRANCH                26000016
TSTSHR   TM    QELCDS(CURQEL),NEGCODE   Q. IS IT SHARED                 26100016
         BC    7,SKIP1                  YES                             26200016
         BALR  WORKREG1,0               NO, SET INDICATOR               26300016
SKIP1    BAL   LINKREG,ISNXT            GO GET NEXT                     26400016
         BCR   15,WORKREG3              EXIT, NO MORE QEL'S             26500016
         BCR   0,0                      PAD FOR VECTOR RETURN           26600016
         LR    CURQEL,WORKREG2          XFR QEL ADDRESS                 26700016
         CL    CURTCB,QELTCB(CURQEL)    Q. SHOULD IT BE DEQUEUED        26800016
         BC    7,TSTSHR                 NO, TEST CODE AND GET NEXT      26900016
         LR    WORKREG0,CURQEL          YES, SAVE ADDRESS OF QEL        27000016
         LTR   WORKREG1,WORKREG1       Q. IS INDICATOR ON               27100016
         BC    7,REMVE                 YES REMOVE THE QEL               27200016
         TM    QELCDS(CURQEL),RESERVED  NO IS QEL A RESERVE             27300016
         BC    8,SKIP2                 NO TREAT NORMALLY                27400016
         NI    QELCDS(CURQEL),X'BF'  YES, SET NON RESERVE FOR RELEASE   27500016
         LR    GENREG,UCBREG      SAVE WORKREG3                         27600016
         L     UCBREG,QELUCB(CURQEL)  GET UCB POINTER                   27700016
         BAL   LINKREG,RLSETEST   DECREMENT UCB COUNT                   27720016
         LR    WORKREG0,CURQEL    RESTORE SAVED QEL POINTER             27740016
         LR    WORKREG3,GENREG    RESTORE WORKREG3                      27760016
         SR    WORKREG1,WORKREG1  RESTORE INDICATOR TO ZERO             27780016
SKIP2    BAL   LINKREG,ISNXT           GO GET NEXT                      27800016
         BC    15,REMVE                 NO MORE QELS, REMOVE LAST       27900016
         LTR   GENREG,GENREG            Q. IS NEXT QEL SHARED           28000016
         BC    7,REMVE                  NO, GO DIRECTLY TO REMOVE       28100016
         LTR   WORKREG1,WORKREG1        Q. IS INDICATOR ON              28200016
         BC    7,LOOP1                  YES, RIPPLE DOWN AND ADJUST     28300016
         TM    QELCDS(CURQEL),NEGCODE   Q. IS THIS QEL SHARED           28400016
         BC    1,REMVE                  YES, GO REMOVE IT               28500016
LOOP1    BAL   LINKREG,ISNXT            GO GET NEXT                     28600016
         BC    15,REMVE                 NO MORE QELS, DEQUEUE CURRENT   28700016
         LTR   GENREG,GENREG            Q. IS NEXT QEL SHARED           28800016
         BC    7,REMVE                  NO, RIPPLE DONE, DQ CURRENT     28900016
         LR    CURQEL,WORKREG2          XFR QEL ADDR FOR INTERFACE      29000016
         L     GENREG,SVRBPTR(WORKREG2) GET SVRB ADDRESS                29100016
         LA    LINKREG,LOOP1            SET RETURN REGISTER             29200016
REDUCE   CLI   RBWCF(GENREG),WAITIND    Q. IS WAIT COUNT ZERO           29300016
         BCR   8,LINKREG                YES, DON'T DECREMENT            29400016
         IC    TASKTCB,RBWCF(GENREG)    GET WAIT COUNT                  29500016
         BCTR  TASKTCB,0                DECREMENT IT                    29600016
         STC   TASKTCB,RBWCF(GENREG)    PUT IT BACK                     29700016
         TM    QELCDS(CURQEL),RESERVED  Q. IS THIS QEL RESERVE QEL      29800016
         BC    8,NORESV                NO DO NOT INCREMENT UCB COUNT    29900016
         L     TASKTCB,QELTCB(CURQEL)   YES GET TCB POINTER             30000016
         L     WORKREG2,CURPRG(TASKTCB) GET PARM POINTER                30100016
         ST    WORKREG2,QELUCB(CURQEL)  SET UCB POINTER IN QEL          30500016
         SR    WORKREG1,WORKREG1       CLEAR REG FOR IC                 30600016
         IC    WORKREG1,UCBRSCT(WORKREG2) GET UCB RESERVE COUNT         30700016
         LA    WORKREG1,1(WORKREG1)    BY ONE AND                       30800016
         STC   WORKREG1,UCBRSCT(WORKREG2) REPLACE NEW RESERVE COUNT     30900016
NORESV   CLI   RBWCF(GENREG),WAITIND    Q. IS IT STILL WAITING          31000016
         BCR   7,LINKREG                YES, CONTINUE LOOP              31100016
         L     TASKTCB,QELTCB(CURQEL)  GET TCB ADDR                     31200016
TASKSW   DS    0H                                                       31300016
         CLC   TCBDSP(LDSP,CURTCB),TCBDSP(TASKTCB)  IS NEXT QEL OF      31400016
*                                      HIGHER PRIORITY                  31500016
         BCR   10,LINKREG         NO, CONTINUE                          31600016
         L     WORKREG4,16        YES, GET CVT ADDRESS                  31700016
         L     WORKREG4,0(WORKREG4)  GET NEW/OLD ADDRESS                31800016
         ST    TASKTCB,0(WORKREG4)  PUT NEXT QELS TCB IN NEW            31900016
         BCR   15,LINKREG                                               32000016
TSTNXT   TM    QELCDS(CURQEL),RESERVED  Q. IS THIS QEL RESERVE QEL      32100016
         BC    8,TSTNXTBB         NO, TREAT NORMALLY                    32200016
         NI    QELCDS(CURQEL),X'BF'  YES, SET NON RESERVE FOR RELEASE   32300016
         LR    GENREG,UCBREG      SAVE WORKREG3                         32400016
         L     UCBREG,QELUCB(CURQEL)  GET UCB POINTER                   32500016
         BAL   LINKREG,RLSETEST   DECREMENT UCB COUNT                   32600016
         LR    WORKREG0,CURQEL    RESTORE SAVED QEL POINTER             32650016
         LR    WORKREG3,GENREG    RESTORE WORKREG3                      32700016
TSTNXTBB TM    QELCDS(CURQEL),NEGCODE   Q. IS THE QEL SHARED            32800016
         BC    1,TSTNXT1                YES, TAKE BRANCH                32900016
         BAL   LINKREG,ISNXT            GO GET NEXT                     33000016
         BC    15,REMVE                 NO MORE, REMOVE CURRENT         33100016
         LTR   GENREG,GENREG            Q. IS NEXT QEL SHARED           33200016
         BC    8,LOOP1                  YES, GO RIPPLE DOWN             33300016
DECR1    L     GENREG,SVRBPTR(WORKREG2) GET SVRB ADDRESS                33400016
         LA    LINKREG,REMVE            LOAD RETURN ADDRESS             33500016
         BC    15,REDUCE                GO ADJUST WAIT COUNT AND        33600016
*                                       INVOKE TASK SWITCH              33700016
TSTNXT1  BAL   LINKREG,ISNXT            GO GET NEXT                     33800016
         BC    15,REMVE                 NO MORE, DEQUEUE THIS QEL       33900016
         LTR   GENREG,GENREG            Q. IS NEXT QEL SHARED           34000016
         BC    8,REMVE                  YES, GO TO DEQUEUE              34100016
         BC    15,DECR1                 NO, DECR THEN DEQUEUE           34200016
ISNXT    SR    GENREG,GENREG            INITIALIZE TO SHARED            34300016
         L     WORKREG2,NXQEL(CURQEL)   GET NEXT QEL                    34400016
         LA    WORKREG2,0(WORKREG2)     CLEAR HIGH ORDER BYTE           34500016
         LTR   WORKREG2,WORKREG2        Q. IS THERE A QEL               34600016
         BCR   8,LINKREG                NO, RETURN TO NEXT IN LINE      34700016
         TM    QELCDS(WORKREG2),NEGCODE YES, NOW TEST FOR SHARED        34800016
         BC    1,4(LINKREG)             REQUEST IS SHARED, RETURN       34900016
         BALR  GENREG,0                 SET INDICATOR EXCLUSIVE         35000016
         BC    15,4(LINKREG)            AND RETURN                      35100016
         SPACE 1                                                        35200016
***  GO DEQUEUE THE QEL                                                 35300016
REMVE    LR    CURQEL,WORKREG0          RESTORE QEL REGISTER            35400016
         LR    WORKREG1,CURQEL          SET FOR INTERFACE               35500016
         BAL   LINKREG,DQELEMNT         AND GO DEQUEUE IT               35600016
***  FREE THE SPACE FOR THE QEL                                         35700016
         LA    WORKREG0,QELSIZE         OBTAIN QEL SIZE                 35800016
         LR    FMREG,CURQEL             LOAD ADDRESS FOR FREEMAIN       35900016
         BAL   LINKREG,FREEUP           GO TO FREEMAIN INTERFACE        36000016
         BAL   LINKREG,DECTCB           DECREMENT TCB COUNT             36100016
         BCR   15,WORKREG3              EXIT                            36200016
         SPACE 1                                                        36300016
***  SEE IF THE MINOR QCB CAN BE FREED                                  36400016
         SPACE 1                                                        36500016
TESTMIN  SR    WORKREG0,WORKREG0        CLEAR FOR TEST                  36600016
         CL    WORKREG0,FSTQEL(CURMIN)  Q. IS THERE A QEL               36700016
         BC    7,LOADMIN                YES, MINOR CAN'T BE FREED       36800016
         LA    CURPARM,ELEVEN(CURMIN)   GET MINOR ADDRESS PLUS 11       36900016
         BAL   LINKREG,ADDMINOR         GET MINOR SIZE                  37000016
         BAL   LINKREG,DQMINOR          AND GO DEQUEUE IT               37100016
         LR    WORKREG0,SUMREG          XFR SIZE OF MINOR               37200016
         LR    FMREG,CURMIN             LOAD ADDRESS FOR FREEMAIN       37300016
         BAL   LINKREG,FREEUP           GO TO FREEMAIN INTERFACE        37400016
         SPACE 3                                                        37500016
***  SEE IF THERE ARE MORE MINORS TO SEARCH                             37600016
         SPACE 1                                                        37700016
LOADMIN  L     CURMIN,NXMIN(CURMIN)     GET NEXT MINOR                  37800016
         CLR   WORKREG0,CURMIN          Q. IS NEXT MINOR PRESENT        37900016
         BC    7,REPTEMIN               YES, TRY TO FIND A QEL          38000016
         SPACE 3                                                        38100016
***  SEE IF THE MAJOR CAN BE FREED                                      38200016
         SPACE 1                                                        38300016
         CL    WORKREG0,FSTMIN(CURMAJ)  Q. DOES MAJOR POINT TO MINOR    38400016
         BC    7,LOADMAJ                YES, GET THE NEXT ONE           38500016
FREMAJ   LR    WORKREG1,CURMAJ          GET ADDRESS FOR DEQUEUEING      38600016
         BAL   LINKREG,DQELEMNT         AND GO TO DEQUEUE               38700016
         SPACE 1                                                        38800016
         LA    WORKREG0,MAJSIZE         GET SIZE OF MAJOR               38900016
         LR    FMREG,CURMAJ             GET ADDRESS FOR FREEMAIN        39000016
*    THE NEXT INSTRUCTION PREVENTS PICKING UP AN INVALID LINK FIELD.    39100016
         L     CURMAJ,PREVMAJ(CURMAJ)   GET PREVIOUS MAJOR QCB          39200016
         LA    LINKREG,LOADMAJ          LOAD RETURN ADDRESS             39300016
         BC    15,FREEUP                GO TO FREEMAIN INTERFACE        39400016
EXIT     EQU   *                                                        39500016
         SSM   ENABLE                                                   39600016
         RETURN  (14,12),T                                              39700016
         EJECT                                                          39800016
***  DEQUEUE SUBROUTINE                                                 39900016
*    THIS ROUTINE WILL DEQUEUE THE MAJOR QCB'S AND QEL'S                40000016
*    INPUT-    WORKREG1-ADDRESS OF ELEMENT TO BE DEQUEUED               40100016
*    USES--    WORKREG1,GENREG                                          40200016
         SPACE 1                                                        40300016
DQELEMNT L     GENREG,0(WORKREG1)       GET ADDRESS OF NEXT ELEMENT     40400016
         LA    GENREG,0(GENREG)         CLEAR HIGH ORDER BYTE           40500016
         LTR   GENREG,GENREG            Q. IS NEXT ELEMENT PRESENT      40600016
         BC    8,ONLYONE                NO, SKIP NEXT INST              40700016
         MVC   PREVIOUS(3,GENREG),PREVIOUS(WORKREG1)                    40800016
ONLYONE  L     GENREG,4(WORKREG1)       GET PREVIOUS FIELD              40900016
         MVC   ONE(3,GENREG),ONE(WORKREG1) MOVE IN NEXT FIELD           41000016
         BCR   15,LINKREG               RETURN                          41100016
         SPACE 3                                                        41200016
***  DEQUEUE SUBROUTINE                                                 41300016
*    THIS ROUTINE WILL DEQUEUE MINOR QCB'S                              41400016
*    INPUT-    CURMIN-ADDRESS OF MINOR TO BE DEQUEUED                   41500016
*    USES--    CURMIN,GENREG                                            41600016
         SPACE 1                                                        41700016
DQMINOR  L     GENREG,NXMIN(CURMIN)     GET ADDRESS OF NEXT MINOR       41800016
         LTR   GENREG,GENREG            Q. IS NEXT MINOR PRESENT        41900016
         BC    8,SINGLE                 NO TAKE BRANCH                  42000016
         MVC   PREVMIN(4,GENREG),PREVMIN(CURMIN)    UPDATE PREV. FIELD  42100016
SINGLE   L     GENREG,PREVMIN(CURMIN)   LOAD PREVIOUS MINOR             42200016
         MVC   NXMIN(4,GENREG),NXMIN(CURMIN)  UPDATE NEXT FIELD         42300016
         BCR   15,LINKREG               RETURN TO MAIN LINE             42400016
         SPACE 3                                                        42500016
***  DECREMENT ENQUEUE COUNT FIELD IN TCB.                              42600016
*    INPUT-    CURTCB-ADDRESS OF CURRENT TCB                            42700016
*    USES--    GENREG                                                   42800016
         SPACE 1                                                        42900016
DECTCB   IC    GENREG,TCBCT(CURTCB)     GET TCB COUNT                   43000016
         BCTR  GENREG,0                 DECREMENT IT                    43100016
         STC   GENREG,TCBCT(CURTCB)     PUT IT BACK                     43200016
         BCR   15,LINKREG               RETURN                          43300016
         EJECT                                                          43400016
*    FREEUP ROUTINE                                                     43500016
*                                                                       43600016
*   THIS ROUTINE FREES CORE FOR MAJOR AND MINOR QCBS, AND QELS.         43700016
*  THIS ROUTINE ENVOKES THE FREEMAIN SVC ROUTINE. IT FURTHER            43800016
*  EXPECTS THAT REGISTER 0 HAS BEEN INITIALIZED WITH THE NUMBER         43900016
*  OF BYTES TO BE FREED.  REGISTER 1 MUST ALSO CONTAIN THE ADDRESS      44000016
*  OF THE BLOCK TO BE FREED.                                            44100016
FREEUP   O     WORKREG0,SP255          INDICATE SUBPOOL                 44200016
         FREEMAIN R,LV=(0),A=(1)                                        44300016
         SR    WORKREG0,WORKREG0       INITIALIZE REG TO 0              44400016
         BCR   15,LINKREG              RETURN                           44500016
***  DETERMINE LENGTH OF MINOR QCB, INCLUDING NAME, AND                 44600016
*    ROUND UP TO A FULL WORD BOUNDRY.  NOTE SUMREG=GMRETREG=1           44700016
         SPACE 1                                                        44800016
ADDMINOR SR    SUMREG,SUMREG            CLEAR ACCUMULATOR               44900016
         IC    SUMREG,LMINOR(CURPARM)   GET LENGTH OF MINOR             45000016
         LTR   SUMREG,SUMREG            Q. IS IT ZERO                   45100016
         BC    7,NMLTH                  NO, USE IT AS THE LENTH         45200016
         LA    SUMREG,TWELVE     THIS CONDITION SHOULD        A24268    45300019
*                            NEVER OCCUR, THEREFORE FREE AT             45400019
*                            LEAST 2 DOUBLE WORDS INCLUDING             45500019
*                            FIRST 2 BYTES OF MIN NAME        A24268    45600019
NMLTH    LA    SUMREG,FULLSIZE(SUMREG)  ROUND UP                        45700016
         N     SUMREG,MASKFULL          TO DOUBLE WORD                  45800016
         BCR   15,LINKREG               RETURN                          45900016
         EJECT                                                          46000016
RLSETEST SR    WORKREG1,WORKREG1  CLEAR FOR IC                          46100016
         IC    WORKREG1,UCBRSCT(ZENREG)  GET UCB RESERVE COUNT          46200016
         BCTR  WORKREG1,0               COUNT IN THE UCB FOR WHICH      46300016
         STC   WORKREG1,UCBRSCT(ZENREG) REPLACE NEW RESERVE COUNT       46400016
         LTR   WORKREG1,WORKREG1  IS THE RESERVE COUNT ZERO             46450016
         BCR   7,LINKREG     NO.  DO NOT RELEASE DEVICE                 46500016
         CLI   RESINDIC(ZENREG),WAITIND  IS THE DEVICE RESERVED         46550016
         BCR   8,LINKREG     NO.  BYPASS RELEASE EXCP                   46600016
*  NOTE:  ANY CHANGE TO THE FOLLOWING RELEASE EXCP ROUTINE OR ITS       46650016
*  ASSOCIATED INTERFACE WILL REQUIRE THE SAME CHANGE IN THE             46700016
*  ENQ/DEQ GENERATOR MACRO, IEAENQ.                                     46750016
         EJECT                                                          46800016
*  FUNCTION                                                          *  46900016
*                                                                    *  47000016
*          1. GET 100 BYTES FROM SUBPOOL 0                           *  47100016
*                                                                    *  47200016
*          2. INITIALIZE A DEB, DCB, IOB, ECB, AND CHANNEL PROGRAM   *  47300016
*             IN SUBPOOL 0                                           *  47400016
*                                                                    *  47500016
*          3. ISSUE AN SVC 0 TO CAUSE A DEVICE RELEASE               *  47600016
*                                                                    *  47700016
*          4. WAIT FOR THE RELEASE TO COMPLETE                       *  47800016
*                                                                    *  47900016
*          5. FREE CORE FROM SUBPOOL 0                               *  48000016
*                                                                    *  48100016
*          6. RETURN TO THE DEQUEUE ROUTINE                          *  48200016
*                                                                    *  48300016
*  ENTRY                                                             *  48400016
*                                                                    *  48500016
*          FROM DEQUEUE VIA A BRANCH                                 *  48600016
*                                                                    *  48700016
*  EXIT                                                              *  48800016
*          BACK TO DEQUEUE                                           *  48900016
*                                                                    *  49000016
*  INPUT                                                             *  49100016
*                                                                    *  49200016
*          PTR TO CURRENT TCB IN REG TCBREG                          *  49300016
*          PTR TO UCB OF DEVICE REQUIRING A RELEASE IN REG UCBREG    *  49400016
*  OUTPUT                                                            *  49500016
*          NONE                                                      *  49600016
*                                                                    *  49700016
*  OPERATION                                                         *  49800016
*                                                                    *  49900016
*          SEE COMMENTS AND REMARKS ASSOCIATED WITH CODE             *  50000016
*                                                                    *  50100016
**********************************************************************  50200016
*                                                                    *  50300016
         SPACE 3                                                        50400016
*   OBTAIN THE CORE REQUIRED FOR THE DCB, ECB, IOB, CCW, AND DEB        50500016
         SPACE 1                                                        50600016
         LR    WORKREG1,GENREG    SAVE WORKREG3                         50650016
EXCPINFC GETMAIN  R,LV=100,SP=0         GET 100 BYTES OF SUBPOOL 0 CORE 50700016
         LR    GENREG,WORKREG1    RESTORE WORKREG3                      50800016
         LR    WORKREG1,GMRETREG        GET ADDRESS OF GOTTEN CORE      50900016
         USING RLDCB,WORKREG1           USE AS BASE FOR DSECT           51000016
*   INITIALIZE DEB                                                      51100016
         XC    0(100,WORKREG1),0(WORKREG1) CLEAR GOTTEN CORE            51200016
         ST    RELWK1,DEAPGV            STORE IN APPENDAGE VECTOR TABLE 51400016
         MVC   DEAPGV+4(16),DEAPGV      PROPAGATE THRU REMAINDER OF AVT 51500016
         MVI   DENEXT,X'02'             NUMBER OF EXTENTS               51600016
         ST    WORKREG1,DEDCBAD        POINT DEB TO DCB                 51900016
         MVI   DEPKID,X'0F'            SET DEB ID                       52000016
         MVZ   DEPKID,TCBPKF(TCBREG)    SET DEB PROTECT KEY             52100016
         L     RELWK1,CVTPTR      GET ADDR OF CVT                       52160016
         L     RELWK1,CVTXAPG-CVT(RELWK1)  GET ADDR OF IOS APP TABLE    52220016
         ST    RELWK1,DEAPPAD           STORE IN TBL POINTER SLOT       52300016
         MVI   DEEXTSCL,X'04'           SET SIZE OF EXTENTS             52400016
         ST    UCBREG,DEUCBAD-2         SET POINTER TO UCB              52500016
         MVI   DEFM,X'18'               SET FILE MASK                   52600016
         MVC   DEBB(2),UCBSKA+1(UCBREG) SET BIN NUMBER OF DEVICE        52700016
         XC    DESTART(4),DESTART       INIT START CCHH TO ZEROS        52800016
         MVI   DEEND,X'FF'              INIT END C TO 'FF'              52900016
         MVC   DEEND+1(3),DEEND         PROPAGATE 'FF' TO REMAINING CHH 53000016
         LA    RELWK1,X'01'             SET NO. ALLOCATED TRACKS TO 1   53100016
         STH   RELWK1,DETRKS            STORE IN DEB                    53200016
*   INITIALIZE IOB                                                      53300016
         MVI   IOBFL1,X'02'             SET IOB FLAGS                   53400016
         MVI   IOBFL2,X'00'                                             53500016
         ST    WORKREG1,IOBECBAD       SET ADDRESS OF ECB               53600016
         LA    RELWK1,RLCCW             GET ADDRESS OF CHANNEL PROGRAM  53700016
         ST    RELWK1,IOBSTART          POINT IOB TO CHANNEL PROGRAM    53800016
         ST    WORKREG1,IOBDCBAD       POINT IOB TODCB                  53900016
         XC    IOBMOD(8),IOBMOD         CLEAR FIELDS                    54000016
         MVC   IOBSK(4),UCBSKA+1(UCBREG) MOVE IN SEEK ADDRESS FROM UCB  54100016
*   INITIALIZE DCB                                                      54200016
         LA    RELWK1,DEAPGV            GET ADDRESS OF DEB              54300016
         ST    RELWK1,DCBDEBAD          POINT DCB TO DEB                54400016
*   INITIALIZE CHANNEL PROGRAM                                          54500016
         MVI   RLCCW,X'03'              NOP COMMAND CODE                54600016
         MVI   RLCCW+4,X'20'            SUPPRESS INCORRECT LENGTH IND.  54700016
         MVI   RLCCW+7,X'EE'            IDENTIFICATION, NORMALLY COUNT  54800016
         LR    WORKREG2,GENREG    PRESERVE WORKREG3                     54900016
         SSM   ENABLE                  ENABLE FOR I/O INTERRUPTS        55000016
         EXCP  RLIOB                   ISSUE RELEASE                    55100016
*                                                                       55200016
         WAIT  ECB=RLECB               WAIT FOR RELEASE                 55300016
         SSM   DISABLE                 DISABLE FOR I/O INTERRUPTS       55400016
         LR    GMRETREG,WORKREG1   SET UP ADDR FOR FREEMAIN             55450016
         FREEMAIN R,LV=100,A=(1)                                        55500016
*                                                                       55600016
         LR    GENREG,WORKREG2    RESTORE WORKREG3                      55700016
         BCR   15,LINKREG               RETURN TO CALLER                55800016
         SPACE 3                                                        55900016
ERRX2    LA    ABENDREG,X'238'          INVALID NAME LENGTH ON ENQ      56000016
ABEND2   SLL   ABENDREG,12             SHIFT ERROR CODE FOR             56100016
*                                      INTERFACE WITH ABEND.            56200016
         ABEND (1),DUMP                                                 56300016
         EJECT                                                          56400016
DISABLE  DC    X'00'                                                    56500016
ENABLE   DC    X'FF'                                                    56600016
         SPACE 3                                                        56700016
         DS    0F                                                       56800016
SP255    DC    X'FF000000'              GM/FM FOR SUBPOOL 255           56900016
MASKFULL DC    X'FFFFFFF8'              FOR ROUNDING TO A DBL WORD      57000016
         SPACE 3                                                        57100016
TCBDSP   EQU   35                                                       57200016
LDSP     EQU   1                                                        57300016
         EJECT                                                          57400016
RLDCB    DSECT          DCB,ECB, IOB, AND DEB USED FOR RELEASE EXCP     57500016
RLECB    DS    F                  ECB TO WAIT ON                        57600016
RLIOB    DS    0F                 START OF IOB                          57700016
IOBFL1   DS    X                  IOB FLAGS                             57800016
IOBFL2   DS    X                  IOB FLAGS                             57900016
         DS    H                  FILLER                                58000016
IOBECBAD DS    F                  ADR OF ECB TO BE POSTED               58100016
         DS    2F                 FILLER                                58200016
IOBSTART DS    F                  ADR OF CHANNEL PROGRAM                58300016
IOBDCBAD DS    F                  ADR OF ASSOCIATED DCB                 58400016
         DS    2F                 FILLER                                58500016
IOBMOD   DS    X                  MODIFIER - DEB EXTENT NUMBER          58600016
IOBSK    DS    CL4                BBCC TO SEEK TO                       58700016
         DS    CL3                FILLER                                58800016
DCBDEBAD DS    F                  I FLAGS AND SDR OF ASSOC. DEB         58900016
RLCCW    DS    X                  CCW OP CODE                           59000016
         DS    CL3                FILLER                                59100016
         DS    X                  CCW GLAGS                             59200016
         DS    CL2                FILLER                                59300016
         DS    X                  BYTE COUNT -END OF IOB INDICATOR      59400016
DEAPGV   DS    4F                 APPENDAGE VECTOR TABLE                59500016
DENEXT   DS    X                  NUMBER OF EXTENTS                     59600016
         DS    CL3                REMAINDER OF APG VECT TABLE           59700016
DEPRIOR  DS    X                  DEB PRIORITY                          59800016
         DS    X                  FILLER BYTE                           59900016
DEVRET   DS    H                  APG VECT TABLE RETURN                 60000016
DEPKID   DS    0X                 USERS PROT KEY AND DEB ID             60100016
DEDCBAD  DS    F                  ADR OF ASSOCIATED DCB                 60200016
DEEXTSCL DS    0X                 SIZE OF EXTENTS                       60300016
DEAPPAD  DS    F                  ADR OF APG VECT TABLE                 60400016
DEFM     DS    X                  FILE MASK                             60500016
         DS    X                  FILLER BYTE                           60600016
DEUCBAD  DS    H                  ADR OF UCB                            60700016
DEBB     DS    H                  BIN OF DEVICE                         60800016
DESTART  DS    2H                 START CCHH OF EXTENT                  60900016
DEEND    DS    2H                 END CCHH OF EXTENT                    61000016
DETRKS   DS    H                  NO OF TRACKS ALLOCATED                61100016
*     COMMUNICATIONS VECTOR TABLE                                       61120016
CVT      DSECT                                                          61140016
         CVT   SYS=MIN                                                  61160016
         END                                                            61200016
