         TITLE 'IEFSD598     MFT II ENQ PURGE ROUTINE'                  00100015
IEFSD598 CSECT                                                     MFT2 00200015
*480000,483000                                                   A24268 00700019
*                                                                A22926 01200018
         EJECT                                                          03100015
*        GENERAL REGISTER EQUATES                                       03200015
         SPACE 1                                                        03300015
GMREG    EQU   0                        FOR REGISTER GETMAIN            03400015
WORKREG0 EQU   0                        GENERAL WORK REGISTER           03500015
FMREG    EQU   1                        FOR REGISTER FREEMAIN           03600015
INPUTREG EQU   1                        POINTER TO INPUT LIST           03700015
SUMREG   EQU   1                        FOR REGMAIN CALCULATIONS        03800015
GMRETREG EQU   1                        RETURN REGISTER FROM GETMAIN    03900015
ABENDREG EQU   1                        WHEN ABENDING CURRENT REQUESTOR 04000015
MCTCBRG  EQU   1                        THE ADDR OF THE MC TASK         04100015
BASEREG  EQU   2                        BASE REGISTER                   04200015
WORKREG3 EQU   3                        GENERAL WORK REGISTER           04300015
CURTCB   EQU   4                        CURRENT TCB ADDRESS             04400015
CURRB    EQU   5                        CURRENT RB ADDRESS              04500015
WORKREG4 EQU   6                        GENERAL WORK REGISTER           04600015
TOPPARM  EQU   6                        ADDRESS OF 1ST LIST ELEMENT     04700015
CURMIN   EQU   7                        CURRENT MINOR QCB ADDRESS       04800015
CURMAJ   EQU   8                        CURRENT MAJOR QCB ADDRESS       04900015
CURQEL   EQU   9                        CURRENT QEL ADDRESS             05000015
TASKTCB  EQU   10                       TCB ADDR FOR TASK SWITCH        05100015
CURPARM  EQU   10                       CURRENT LIST ELEMENT            05200015
WORKREG1 EQU   11                       GENERAL WORK REGISTER           05300015
WKRG1    EQU   11                       GENERAL WORK REGISTER           05400015
TCBREG   EQU   11                       FOR RIPPLING DOWN TCB QUEUE     05500015
JSTCBRG  EQU   12                       ADDRESS OF JOB STEP TCB         05600015
WORKREG2 EQU   12                       GENERAL WORK REGISTER           05700015
WKRG2    EQU   12                       GENERAL WORK REGISTER           05800015
LINKREG  EQU   14                      INTERNAL LINK REGISTER           05900015
RETREG   EQU   14                       RETURN REGISTER                 06000015
GENREG   EQU   15                       SELECTED USE                    06100015
MASKREG  EQU   15                       DISPATCHABILITY MODIFIER        06200015
         EJECT                                                          06300015
*        TCB EQUATES                                                    06400015
         SPACE 1                                                        06500015
TCBPKF   EQU   28                       TCB PROTECT KEY FIELD           06600015
TCBFLG   EQU   29                       *                               06700015
TCBFLG1  EQU   30                       * TCB FLAGS                     06800015
TCBFLG2  EQU   31                       *                               06900015
TCBDISP  EQU   33                       TCB DISPATCHABILITY FLAGS       07000015
TCBGRS0  EQU   48                       OFFSET TO TCB REGISTER SAVE     07100015
TCBCT    EQU   34                      ENQ COUNT FIELD IN TCB           07200015
TCBTCB   EQU   116                      NEXT LOWER TCB ON READY QUEUE   07300015
JSPTR    EQU   124                      ADDR OF JOB STEP TCB IN TCB     07400015
TCBNTC   EQU   128                      ADDRESS OF SISTER TCB           07500015
TCBOTC   EQU   132                      ADDRESS OF MOTHER TCB           07600015
TCBLTC   EQU   136                      ADDRESS OF DAUGHTER TCB         07700015
         SPACE 1                                                        07800015
ABTERM   EQU   X'80'                    ABTERM BIT IN TCB               07900015
TCBFJMC  EQU   X'08'                    TO SET TCB MUST COMPLETE        08000015
TCBRJMC  EQU   X'F7'                    TO RESET STEP MUST COMPLETE     08100015
TCBFSMC  EQU   X'10'                    TO SET TCB SYS MUST COMPLETE    08200015
TCBRSMC  EQU   X'EF'                    TO RESET SYS MUST COMPLETE      08300015
TCBFXS   EQU   X'01'                    SET TO DEFER ASYNC EXITS        08400015
TCBFXR   EQU   X'FE'                    RESET ASYNC EXIT FLAG           08500015
PKEY0    EQU   X'F0'                    PROTECT KEY PORTION OF TCBPKF   08600015
         SPACE 3                                                        08700015
*        RB EQUATES                                                     08800015
         SPACE 1                                                        08900015
PSWADR   EQU   16                       RESUME PSW IN RB                09000015
RBWCF    EQU   28                       WAIT COUNT FIELD IN RB          09100015
SVCOPSW  EQU   33                       SECOND BYTE OF SVC OLD PSW      09200015
XSAV     EQU   96                       EXTENDED SAVE AREA              09300015
         SPACE 3                                                        09400015
*        GENERALIZED EQUATES                                            09500015
         SPACE 1                                                        09600015
ONE      EQU   1                        VALUE OF ONE                    09700015
LPSW     EQU   8                        LENGTH OF PSW                   09800015
PREVIOUS EQU   5                        DISPLACEMENT TO PREVIOUS FIELD  09900015
         SPACE 1                                                        10000015
WAITIND  EQU   X'00'                    FOR TESTING                     10100015
ANYON    EQU   X'FF'                    BYTE VALUES                     10200015
         EJECT                                                          10300015
*        PARAMETER LIST ELEMENT                                         10400015
         SPACE 3                                                        10500015
*******************************************                             10600015
* 0       * 1        * 2       * 3        *                             10700015
* LISTEND *  LMINOR  * PARMCDS *  RETURN  *                             10800015
*         *          *         *          *                             10900015
*******************************************                             11000015
* 4                                       *                             11100015
*    ADDRESS OF MAJOR RESOURCE NAME       *                             11200015
*                                         *                             11300015
*******************************************                             11400015
* 8                                       *                             11500015
*    ADDRESS OF MINOR RESOURCE NAME       *                             11600015
*                                         *                             11700015
*******************************************                             11800015
         SPACE 3                                                        11900015
*        WHERE:                                                         12000015
         SPACE 1                                                        12100015
LISTEND  EQU   0                        OFFSET TO LIST END INDICATOR    12200015
LMINOR   EQU   1                        OFFSET TO LENGTH OF MINOR NAME  12300015
PARMCDS  EQU   2                        OFFSET TO PARAMETER CODES       12400015
RETURN   EQU   3                        OFFSET TO RETURN CODE FIELD     12500015
PTRMAJ   EQU   4                        OFFSET TO ADDR OF MAJOR NAME    12600015
PTRMIN   EQU   8                        OFFSET TO ADDR OF MINOR NAME    12700015
         SPACE 1                                                        12800015
ENDIND   EQU   X'FF'                    INDICATOR FOR END OF LIST       12900015
PLMI     EQU   X'80'                    PLUS OR MINUS INDICATOR         13000015
SHARE    EQU   X'40'                    SHARED RESOURCE INDICATOR       13100015
SMC      EQU   X'30'                    SET MUST COMPLETE INDICATORS    13200015
SMCSYS   EQU   X'20'                    SYSTEM MUST COMPLETE            13300015
SMCSTP   EQU   X'10'                    STEP MUST COMPLETE              13400015
HAVE     EQU   X'01'                    TO TEST 'HAVE' MASK             13500015
USE      EQU   X'03'                    TO TEST 'USE' MASK              13600015
TEST     EQU   X'07'                    TO TEST 'TEST' MASK             13700015
AVAIL    EQU   X'00'                    RETURN CODE OF ZERO             13800015
INUSE    EQU   X'04'                    RETURN CODE OF FOUR             13900015
HAS      EQU   X'08'                    RETURN CODE OF EIGHT            14000015
         SPACE 1                                                        14100015
PARMSIZE EQU   12                       LENGTH OF ELEMENT               14200015
LPARM    EQU   12                       LENGTH OF ELEMENT               14300015
         EJECT                                                          14400015
*****    CONTROL BLOCK FORMATS    *****                                 14500015
         SPACE 3                                                        14600015
*        MAJOR QUEUE CONTROL BLOCK                                      14700015
         SPACE 1                                                        14800015
*******************************************                             14900015
* 0                                       *                             15000015
*        ADDRESS OF NEXT MAJOR QCB        *                             15100015
*                                         *                             15200015
*******************************************                             15300015
* 4                                       *                             15400015
*       ADDRESS OF PREVIOUS MAJOR QCB     *                             15500015
*                                         *                             15600015
*******************************************                             15700015
* 8                                       *                             15800015
*        ADDRESS OF FIRST MINOR QCB       *                             15900015
*                                         *                             16000015
*******************************************                             16100015
* 12                                      *                             16200015
*             MAJOR QCB NAME              *                             16300015
*                                         *                             16400015
*******************************************                             16500015
* 16                                      *                             16600015
*             MAJOR QCB NAME              *                             16700015
*                                         *                             16800015
*******************************************                             16900015
         SPACE 2                                                        17000015
NXMAJ    EQU   0                        POINTER TO NEXT MAJOR QCB       17100015
PREVMAJ  EQU   4                        POINTER TO PREVIOUS MAJOR QCB   17200015
FSTMIN   EQU   8                        POINTER TO FIRST MINOR QCB      17300015
LMAJ     EQU   8                        LENGTH OF MAJOR NAME            17400015
MAJNAME  EQU   12                       MAJOR QCB NAME                  17500015
MAJSIZE  EQU   24                       SIZE OF MAJOR TO A DBL WORD     17600015
MAJCLR   EQU   4                        PORTION TO CLEAR IN MINOR QCB   17700015
         EJECT                                                          17800015
*        MINOR QUEUE CONTROL BLOCK                                      17900015
         SPACE 1                                                        18000015
*******************************************                             18100015
* 0                                       *                             18200015
*          ADDRESS OF FIRST QEL           *                             18300015
*                                         *                             18400015
*******************************************                             18500015
* 4                                       *                             18600015
*      ADDRESS OF PREVIOUS MINOR QCB      *                             18700015
*                                         *                             18800015
*******************************************                             18900015
* 8                                       *                             19000015
*        ADDRESS OF NEXT MINOR QCB        *                             19100015
*                                         *                             19200015
*******************************************                             19300015
* 12      * 13       * 14                 *                             19400015
* LENGTH  *  QCBPKF  *   MINOR QCB NAME   *                             19500015
*         *          *                    *                             19600015
*******************************************                             19700015
* 16                                      *                             19800015
*           MINOR QCB NAME                *                             19900015
*         (VARIABLE LENGTH)               *                             20000015
*******************************************                             20100015
         SPACE 3                                                        20200015
FSTQEL   EQU   0                        ADDRESS OF FIRST QEL            20300015
PREVMIN  EQU   4                        ADDRESS OF PREVIOUS MINOR QCB   20400015
NXMIN    EQU   8                        ADDRES OF NEXT MINOR QCB        20500015
ELEVEN   EQU   11                       DISPLACEMENT TO LENGTH -1       20600015
LMINAME  EQU   12                       LENGTH OF MINOR NAME            20700015
QCBPKF   EQU   13                       TCB PROTECT KEY FIELD IN QCB    20800015
MINAME   EQU   14                       MINOR NAME                      20900015
TWELVE   EQU   12                                                       20950019
         SPACE 1                                                        21000015
NOKEY    EQU   X'FF'                    INDICATES A SHARED RESOURCE     21100015
         SPACE 1                                                        21200015
MINCLR   EQU   4                        PORTION TO CLEAR IN MINOR QCB   21300015
FULLSIZE EQU   21                       ALLOW ROUNDING TO A DBL WORD    21400015
         EJECT                                                          21500015
*              QUEUE ELEMENT              *                             21600015
         SPACE 1                                                        21700015
*******************************************                             21800015
* 0       * 1                             *                             21900015
*   SMC   *    ADDRESS OF NEXT QEL        *                             22000015
*         *                               *                             22100015
*******************************************                             22200015
* 4       * 5                             *                             22300015
*  CODE   *   ADDRESS OF PREVIOUS QEL     *                             22400015
*         *                               *                             22500015
*******************************************                             22600015
* 8                                       *                             22700015
*      ADDRESS OF ENQUEUEING TCB          *                             22800015
*                                         *                             22900015
*******************************************                             23000015
* 12                                      *                             23100015
*      ADDRESS OF SVRB FOR ENQ            *                             23200015
*                                         *                             23300015
*******************************************                             23400015
         SPACE 2                                                        23500015
NXQEL    EQU   0                        POINTER TO NEXT QEL             23600015
QELSMC   EQU   0                        SMC INDICATOR IN QEL            23700015
PREVQEL  EQU   4                        POINTER TO PREVIOUS QEL         23800015
QELCDS   EQU   4                        QEL CODE BYTE                   23900015
QELCLR   EQU   4                        PORTION TO BE CLEARED IN QEL    24000015
QELTCB   EQU   8                        POINTER TO TCB                  24100015
SVRBPTR  EQU   12                       POINTER TO SVRB OF ENQ          24200015
QELSIZE  EQU   16                       LENGTH OF QEL                   24300015
NEGCODE  EQU   X'80'                    INDICATES MINUS QEL REQUEST     24400015
         EJECT                                                          24500015
         SAVE  (0,12),T                                                 24550015
IEAOEQ01 BALR  BASEREG,0                                                24600015
         USING *,BASEREG                                           MFT2 24700015
         SSM   DISABLE                                                  24750015
         LA    CURTCB,0(CURTCB)         CLEAR HI BYTE                   24770015
         SPACE 1                                                        24800015
         SR    WORKREG0,WORKREG0        INITIALIZE COMPERAND            24900015
         L     CURMAJ,16                                                24950015
         L     CURMAJ,52(CURMAJ)                                        25000015
         L     CURMAJ,12(CURMAJ)                                        25050015
         SPACE 1                                                        25100015
LOADMAJ  CL    WORKREG0,NXMAJ(CURMAJ)   Q. IS MAJOR PRESENT             25200015
         BC    8,EXIT                   BR TO GET NEXT LOAD        MFT2 25300015
         SPACE 1                                                        25400015
REPTEMAJ L     CURMAJ,NXMAJ(CURMAJ)     GET ADDRESS OF MAJOR QCB        25500015
*                                                                       25507015
* FOR DATA SET INTEGRITY, R4 PLUS=STEPTERM ENTRY, R4 MINUS=JOBTERM ENTY 25514015
* TEST IS AGAINST REGISTER 4 IN REGISTER SAVE AREA                      25521015
*                                                                       25528015
         TM    36(13),X'80'             Q. IS JOBTERM INDICATED         25535015
         BO    CMPMINOR                 YES, PURGE ALL RESRCES FOR JOB  25542015
         CLC   MAJNAME(LMAJ,CURMAJ),DSN Q. IS MAJOR FOR DATA SET INTGRY 25549015
         BE    LOADMAJ                  YES, BYPASS SINCE STEPTERM      25556015
         B     CMPMINOR                 NO, CONTINUE PURGE              25563015
*                                                                       25570015
DSN      DC    C'SYSDSN  '                                              25577015
*                                                                       25584015
CMPMINOR DS    0F                                                       25591015
         CL    WORKREG0,FSTMIN(CURMAJ)  Q. IS THERE A MINOR             25600015
         BC    8,FREMAJ                 NO MINOR, DEQUEUE MAJOR         25700015
         SPACE 1                                                        25800015
*    THE SITUATION TESTED FOR ABOVE, A MAJOR QCB WITHOUT A              25900015
*    MINOR QCB, CAN ARISE IF THE TASK WAS ABENDED FROM ENQ.             26000015
*    IF WE FALL THROUGH TO HERE, THERE IS A MINOR QCB.                  26100015
*    NOTE THAT THERE CANNOT BE A MINOR QCB WITHOUT A QEL.               26200015
*    UNLESS ENQ FAILED IN ATTEMPT TO GETMAIN FOR QEL, THEN WE WILL    * 26230018
*    DEQUEUE A MINOR WITHOUT A QEL(22926).                            * 26260018
         SPACE 1                                                        26300015
         LA    WORKREG3,TESTMIN         SET EXIT ADDRESS                26400015
         L     CURMIN,FSTMIN(CURMAJ)    GET THE ADDRESS OF THE MINOR    26500015
REPTEMIN SR    WORKREG1,WORKREG1        INITIALIZE INDICATOR            26600015
         CL    WORKREG1,FSTQEL(CURMIN) IS THERE A QEL?           A22926 26630018
         BC    8,DQMINOR               NO QEL,DEQUEUE MINOR      A22926 26660018
         L     CURQEL,FSTQEL(CURMIN)    GET FIRST QEL                   26700015
         CL    CURTCB,QELTCB(CURQEL)    Q. SHOULD IT BE DEQUEUED        26800015
         LR    WORKREG0,CURQEL          YES, SAVE ADDRESS OF QEL        26900015
         BC    8,TSTNXT                 YES, TAKE BRANCH                27000015
TSTSHR   TM    QELCDS(CURQEL),NEGCODE   Q. IS IT SHARED                 27100015
         BC    7,SKIP1                  YES                             27200015
         BALR  WORKREG1,0               NO, SET INDICATOR               27300015
SKIP1    BAL   LINKREG,ISNXT            GO GET NEXT                     27400015
         BCR   15,WORKREG3              EXIT, NO MORE QEL'S             27500015
         BCR   0,0                      PAD FOR VECTOR RETURN           27600015
         LR    CURQEL,WORKREG2          XFR QEL ADDRESS                 27700015
         CL    CURTCB,QELTCB(CURQEL)    Q. SHOULD IT BE DEQUEUED        27800015
         BC    7,TSTSHR                 NO, TEST CODE AND GET NEXT      27900015
         LR    WORKREG0,CURQEL          YES, SAVE ADDRESS OF QEL        28000015
         LTR   WORKREG1,WORKREG1        Q. IS INDICATOR ON              28100015
         BC    7,REMVE                  YES, GO DIRECTLY TO DEQUEUE IT  28200015
         BAL   LINKREG,ISNXT            GO GET NEXT                     28300015
         BC    15,REMVE                 NO MORE QELS, REMOVE LAST       28400015
         LTR   GENREG,GENREG            Q. IS NEXT QEL SHARED           28500015
         BC    7,REMVE                  NO, GO DIRECTLY TO REMOVE       28600015
         LTR   WORKREG1,WORKREG1        Q. IS INDICATOR ON              28700015
         BC    7,LOOP1                  YES, RIPPLE DOWN AND ADJUST     28800015
         TM    QELCDS(CURQEL),NEGCODE   Q. IS THIS QEL SHARED           28900015
         BC    1,REMVE                  YES, GO REMOVE IT               29000015
LOOP1    BAL   LINKREG,ISNXT            GO GET NEXT                     29100015
         BC    15,REMVE                 NO MORE QELS, DEQUEUE CURRENT   29200015
         LTR   GENREG,GENREG            Q. IS NEXT QEL SHARED           29300015
         BC    7,REMVE                  NO, RIPPLE DONE, DQ CURRENT     29400015
         LR    CURQEL,WORKREG2          XFR QEL ADDR FOR INTERFACE      29500015
         L     GENREG,SVRBPTR(WORKREG2) GET SVRB ADDRESS                29600015
         LA    LINKREG,LOOP1            SET RETURN REGISTER             29700015
REDUCE   CLI   RBWCF(GENREG),WAITIND    Q. IS WAIT COUNT ZERO           29800015
         BCR   8,LINKREG                YES, DON'T DECREMENT            29900015
         IC    TASKTCB,RBWCF(GENREG)    GET WAIT COUNT                  30000015
         BCTR  TASKTCB,0                DECREMENT IT                    30100015
         STC   TASKTCB,RBWCF(GENREG)    PUT IT BACK                     30200015
         CLI   RBWCF(GENREG),WAITIND    Q. IS IT STILL WAITING          30300015
         BCR   7,LINKREG                YES, CONTINUE LOOP              30400015
         L     TASKTCB,QELTCB(WORKREG2) GET TCB ADDRESS                 30500015
TASKSW   EQU   *                                                        30520015
         CLC   TCBDSP(LDSP,CURTCB),TCBDSP(TASKTCB) IS NEXT QEL HIER PRI 30540015
         BCR   10,LINKREG                          NO, CONTINUE         30560015
         L     WORKREG4,16                         YES, CVT ADDRESS     30580015
         L     WORKREG4,0(WORKREG4)                NEW/OLD ADDRESS      30600015
         ST    TASKTCB,0(WORKREG4)                 NEXT QELS TCB IN NEW 30620015
         BCR   15,LINKREG                                               30640015
TSTNXT   TM    QELCDS(CURQEL),NEGCODE   Q. IS THE QEL SHARED            30700015
         BC    1,TSTNXT1                YES, TAKE BRANCH                30800015
         BAL   LINKREG,ISNXT            GO GET NEXT                     30900015
         BC    15,REMVE                 NO MORE, REMOVE CURRENT         31000015
         LTR   GENREG,GENREG            Q. IS NEXT QEL SHARED           31100015
         BC    8,LOOP1                  YES, GO RIPPLE DOWN             31200015
DECR1    L     GENREG,SVRBPTR(WORKREG2) GET SVRB ADDRESS                31300015
         LA    LINKREG,REMVE            LOAD RETURN ADDRESS             31400015
         BC    15,REDUCE                GO ADJUST WAIT COUNT AND        31500015
*                                       INVOKE TASK SWITCH              31600015
TSTNXT1  BAL   LINKREG,ISNXT            GO GET NEXT                     31700015
         BC    15,REMVE                 NO MORE, DEQUEUE THIS QEL       31800015
         LTR   GENREG,GENREG            Q. IS NEXT QEL SHARED           31900015
         BC    8,REMVE                  YES, GO TO DEQUEUE              32000015
         BC    15,DECR1                 NO, DECR THEN DEQUEUE           32100015
ISNXT    SR    GENREG,GENREG            INITIALIZE TO SHARED            32200015
         L     WORKREG2,NXQEL(CURQEL)   GET NEXT QEL                    32300015
         LA    WORKREG2,0(WORKREG2)     CLEAR HIGH ORDER BYTE           32400015
         LTR   WORKREG2,WORKREG2        Q. IS THERE A QEL               32500015
         BCR   8,LINKREG                NO, RETURN TO NEXT IN LINE      32600015
         TM    QELCDS(WORKREG2),NEGCODE YES, NOW TEST FOR SHARED        32700015
         BC    1,4(LINKREG)             REQUEST IS SHARED, RETURN       32800015
         BALR  GENREG,0                 SET INDICATOR EXCLUSIVE         32900015
         BC    15,4(LINKREG)            AND RETURN                      33000015
         SPACE 1                                                        33100015
***  GO DEQUEUE THE QEL                                                 33200015
REMVE    LR    CURQEL,WORKREG0          RESTORE QEL REGISTER            33300015
         LR    WORKREG1,CURQEL          SET FOR INTERFACE               33400015
         BAL   LINKREG,DQELEMNT         AND GO DEQUEUE IT               33500015
***  FREE THE SPACE FOR THE QEL                                         33600015
         LA    WORKREG0,QELSIZE         OBTAIN QEL SIZE                 33700015
         LR    FMREG,CURQEL             LOAD ADDRESS FOR FREEMAIN       33800015
         BAL   LINKREG,FREEUP           GO TO FREEMAIN INTERFACE        33900015
         BAL   LINKREG,DECTCB           DECREMENT TCB COUNT             34000015
         BCR   15,WORKREG3              EXIT                            34100015
         SPACE 1                                                        34200015
***  SEE IF THE MINOR QCB CAN BE FREED                                  34300015
         SPACE 1                                                        34400015
TESTMIN  SR    WORKREG0,WORKREG0        CLEAR FOR TEST                  34500015
         CL    WORKREG0,FSTQEL(CURMIN)  Q. IS THERE A QEL               34600015
         BC    7,LOADMIN                YES, MINOR CAN'T BE FREED       34700015
         LA    CURPARM,ELEVEN(CURMIN)   GET MINOR ADDRESS PLUS 11       34800015
         BAL   LINKREG,ADDMINOR         GET MINOR SIZE                  34900015
         BAL   LINKREG,DQMINOR          AND GO DEQUEUE IT               35000015
         LR    WORKREG0,SUMREG          XFR SIZE OF MINOR               35100015
         LR    FMREG,CURMIN             LOAD ADDRESS FOR FREEMAIN       35200015
         BAL   LINKREG,FREEUP           GO TO FREEMAIN INTERFACE        35300015
         SPACE 3                                                        35400015
***  SEE IF THERE ARE MORE MINORS TO SEARCH                             35500015
         SPACE 1                                                        35600015
LOADMIN  L     CURMIN,NXMIN(CURMIN)     GET NEXT MINOR                  35700015
         CLR   WORKREG0,CURMIN          Q. IS NEXT MINOR PRESENT        35800015
         BC    7,REPTEMIN               YES, TRY TO FIND A QEL          35900015
         SPACE 3                                                        36000015
***  SEE IF THE MAJOR CAN BE FREED                                      36100015
         SPACE 1                                                        36200015
         CL    WORKREG0,FSTMIN(CURMAJ)  Q. DOES MAJOR POINT TO MINOR    36300015
         BC    7,LOADMAJ                YES, GET THE NEXT ONE           36400015
FREMAJ   LR    WORKREG1,CURMAJ          GET ADDRESS FOR DEQUEUEING      36500015
         BAL   LINKREG,DQELEMNT         AND GO TO DEQUEUE               36600015
         SPACE 1                                                        36700015
         LA    WORKREG0,MAJSIZE         GET SIZE OF MAJOR               36800015
         LR    FMREG,CURMAJ             GET ADDRESS FOR FREEMAIN        36900015
*    THE NEXT INSTRUCTION PREVENTS PICKING UP AN INVALID LINK FIELD.    37000015
         L     CURMAJ,PREVMAJ(CURMAJ)   GET PREVIOUS MAJOR QCB          37100015
         LA    LINKREG,LOADMAJ          LOAD RETURN ADDRESS             37200015
         BC    15,FREEUP                GO TO FREEMAIN INTERFACE        37300015
EXIT     EQU   *                                                        37400015
         SSM   ENABLE                                                   38400015
         RETURN  (14,12),T                                              39400015
         EJECT                                                          41400015
***  DEQUEUE SUBROUTINE                                                 41500015
*    THIS ROUTINE WILL DEQUEUE THE MAJOR QCB'S AND QEL'S                41600015
*    INPUT-    WORKREG1-ADDRESS OF ELEMENT TO BE DEQUEUED               41700015
*    USES--    WORKREG1,GENREG                                          41800015
         SPACE 1                                                        41900015
DQELEMNT L     GENREG,0(WORKREG1)       GET ADDRESS OF NEXT ELEMENT     42000015
         LA    GENREG,0(GENREG)         CLEAR HIGH ORDER BYTE           42100015
         LTR   GENREG,GENREG            Q. IS NEXT ELEMENT PRESENT      42200015
         BC    8,ONLYONE                NO, SKIP NEXT INST              42300015
         MVC   PREVIOUS(3,GENREG),PREVIOUS(WORKREG1)                    42400015
ONLYONE  L     GENREG,4(WORKREG1)       GET PREVIOUS FIELD              42500015
         MVC   ONE(3,GENREG),ONE(WORKREG1) MOVE IN NEXT FIELD           42600015
         BCR   15,LINKREG               RETURN                          42700015
         SPACE 3                                                        42800015
***  DEQUEUE SUBROUTINE                                                 42900015
*    THIS ROUTINE WILL DEQUEUE MINOR QCB'S                              43000015
*    INPUT-    CURMIN-ADDRESS OF MINOR TO BE DEQUEUED                   43100015
*    USES--    CURMIN,GENREG                                            43200015
         SPACE 1                                                        43300015
DQMINOR  L     GENREG,NXMIN(CURMIN)     GET ADDRESS OF NEXT MINOR       43400015
         LTR   GENREG,GENREG            Q. IS NEXT MINOR PRESENT        43500015
         BC    8,SINGLE                 NO TAKE BRANCH                  43600015
         MVC   PREVMIN(4,GENREG),PREVMIN(CURMIN)    UPDATE PREV. FIELD  43700015
SINGLE   L     GENREG,PREVMIN(CURMIN)   LOAD PREVIOUS MINOR             43800015
         MVC   NXMIN(4,GENREG),NXMIN(CURMIN)  UPDATE NEXT FIELD         43900015
         BCR   15,LINKREG               RETURN TO MAIN LINE             44000015
         SPACE 3                                                        44100015
***  DECREMENT ENQUEUE COUNT FIELD IN TCB.                              44200015
*    INPUT-    CURTCB-ADDRESS OF CURRENT TCB                            44300015
*    USES--    GENREG                                                   44400015
         SPACE 1                                                        44500015
DECTCB   IC    GENREG,TCBCT(CURTCB)     GET TCB COUNT                   44600015
         BCTR  GENREG,0                 DECREMENT IT                    44700015
         STC   GENREG,TCBCT(CURTCB)     PUT IT BACK                     44800015
         BCR   15,LINKREG               RETURN                          44900015
         EJECT                                                          45000015
*    FREEUP ROUTINE                                                     45100015
*                                                                       45200015
*   THIS ROUTINE FREES CORE FOR MAJOR AND MINOR QCBS, AND QELS.         45300015
*  THIS ROUTINE ENVOKES THE FREEMAIN SVC ROUTINE. IT FURTHER            45400015
*  EXPECTS THAT REGISTER 0 HAS BEEN INITIALIZED WITH THE NUMBER         45500015
*  OF BYTES TO BE FREED.  REGISTER 1 MUST ALSO CONTAIN THE ADDRESS      45600015
*  OF THE BLOCK TO BE FREED.                                            45700015
FREEUP   O     WORKREG0,SP255          INDICATE SUBPOOL                 45800015
         FREEMAIN R,LV=(0),A=(1)                                        45900015
         SR    WORKREG0,WORKREG0       INITIALIZE REG TO 0              46000015
         BCR   15,LINKREG              RETURN                           46100015
         SPACE 3                                                        46200015
         EJECT                                                          47200015
***  DETERMINE LENGTH OF MINOR QCB, INCLUDING NAME, AND                 47300015
*    ROUND UP TO A FULL WORD BOUNDRY.  NOTE SUMREG=GMRETREG=1           47400015
         SPACE 1                                                        47500015
ADDMINOR SR    SUMREG,SUMREG            CLEAR ACCUMULATOR               47600015
         IC    SUMREG,LMINOR(CURPARM)   GET LENGTH OF MINOR             47700015
         LTR   SUMREG,SUMREG            Q. IS IT ZERO                   47800015
         BC    7,NMLTH                  NO, USE IT AS THE LENTH         47900015
         LA    SUMREG,TWELVE             THIS CONDITION SHOULD   A24268 48000019
*                                      NEVER OCCUR,THEREFORE FREE AT  * 48100019
*                                      LEAST 1 DOUBLE WORD INCLUDING  * 48200019
*                                      FIRST 2 BYTES OF MIN NAME 24268* 48300019
NMLTH    LA    SUMREG,FULLSIZE(SUMREG)  ROUND UP                        48400015
         N     SUMREG,MASKFULL          TO DOUBLE WORD                  48500015
         BCR   15,LINKREG               RETURN                          48600015
         EJECT                                                          48700015
         SPACE 3                                                        48800015
ERRX2    LA    ABENDREG,X'238'          INVALID NAME LENGTH ON ENQ      48900015
         BC    15,ABEND2                                                49000015
ABEND2   SLL   ABENDREG,12             SHIFT ERROR CODE FOR             49100015
*                                      INTERFACE WITH ABEND.            49200015
         ABEND (1),DUMP                                                 49300015
         EJECT                                                          49400015
DISABLE  DC    X'00'                                                    49500015
ENABLE   DC    X'FF'                                                    49600015
         SPACE 3                                                        49700015
         DS    0F                                                       49750015
SP255    DC    X'FF000000'              GM/FM FOR SUBPOOL 255           49800015
MASKFULL DC    X'FFFFFFF8'              FOR ROUNDING TO A DBL WORD      49900015
         SPACE 3                                                        50000015
TCBDSP   EQU   35                                                       51000015
LDSP     EQU   1                                                        52000015
         END                                                            54500015
