         TITLE 'IEFSDXYZ - FAKE PUT ROUTINE FOR CHAIN SCHEDULING'       00400017
*                                                                       00450020
*          RELEASE 22 DELETIONS/CHANGES                                 00500020
*          RELEASE 21 DELETIONS/CHANGES                                 00550020
* 697600-698000           CRG CTL/LAST PAGE                      YA4295 00551921
* 160000                  FIX CRG CTL FOR SEPARATOR              A69301 00552021
*1162697600-698500                                               M3018  00560021
*1162940430,940520                                               M3017  00570021
*          RELEASE 20 DELETIONS/CHANGES                                 00600020
*1058                                                            M6004  00620020
* 236008-400000                                                  MAPMAC 00650020
*1058449200,451000                                               A35780 00670020
*1058570000,584000,614000,620000-622000                          A35926 00680020
*516000-520000,636000-640000                                     A29072 00680121
*                                                                       00700020
**********************************************************************  00800017
*                                                                    *  01200017
*TITLE-- IEFSDXYZ - FAKE PUT ROUTINE FOR CHAIN SCHEDULING            *  01600017
*                                                                    *  02000017
*STATUS CHANGE LEVEL 002                                                02400020
*                                                                    *  02800017
*FUNCTION/OPERATION-- THIS ROUTINE SIMULATES PUT LOCATE AND TRUNC    *  03200017
*   AND USES CHAIN SCHEDULING IN ORDER TO REDUCE THE AMOUNT OF CPU   *  03600017
*   TIME USED BY THE SYSOUT WRITER.                                  *  04000017
*                                                                    *  04400017
*ENTRY POINT-- IEFSDXYZ - FROM THE 'PUT' IN IEFSD089 OR A USER       *  04800017
*   SYSOUT WRITER MODULE (IN WHICH CASE REG. 15 IS NOT EQUAL TO      *  05200017
*   ZERO). OR FROM IEFSD078, IEFSD086, OR IEFSD070 IN ORDER TO       *  05600017
*   TRUNCATE THE CHAIN OF BUFFERS (IN WHICH CASE REG. 15 IS ZERO).   *  06000017
*                                                                    *  06400017
*INPUT-- REGISTER 1 POINTS TO THE OUTPUT DCB                         *  06800017
*                                                                    *  07200017
*OUTPUT-- WHEN THIS ROUTINE IS ACTING AS A PUT LOCATE IT RETURNS     *  07600017
*   IN REGISTER 1 THE LOCATION INTO WHICH THE RECORD IS TO BE        *  08000017
*   MOVED. WHEN THIS ROUTINE IS ACTING AS A TRUNC REG. 1 WILL BE     *  08400017
*   ZERO ONLY WHEN THERE WAS AN OUTPUT ERROR.                        *  08800017
*                                                                    *  09200017
*EXTERNAL ROUTINES-- NONE                                            *  09600017
*                                                                    *  10000017
*EXIT-- RETURNS TO THE INSTRUCTION FOLLOWING THE ONE WHICH BRANCHED  *  10400017
*   TO THIS ROUTINE EXCEPT IN THE CASE THAT A PUT BRANCHED TO THIS   *  10800017
*   ROUTINE AND AN OUTPUT I/O ERROR OCCURED. IN THIS CASE IT         *  11200017
*   BRANCHES TO THE ERROR EXIT IN THE SYNAD FIELD OF THE DCB.        *  11600017
*                                                                    *  12000017
*TABLES/WORK AREAS-- THE I-O TABLE MADE UP OF CONTROL INFORMATION,   *  12400017
*   THE ECB, THE IOB, THE CCW'S, AND THE BUFFERS NEEDED BY THE       *  12800017
*   EXCP DCB.                                                        *  13200017
*                                                                    *  13600017
*ATTRIBUTES-- THIS ROUTINE IS REENTRANT AND REFRESHABLE.             *  14000017
*                                                                    *  14400017
*NOTES-- THE EXCP AND WAIT MACROS ARE USED.                          *  14800017
*                                                                    *  15200017
**********************************************************************  15600017
IEFSDXYZ CSECT                          ESSENTIAL EQUATES        A69301 16000021
R0       EQU   0                                                        16400017
R1       EQU   1                                                        16800017
R2       EQU   2                                                        17200017
R3       EQU   3                                                        17600017
R4       EQU   4                                                        18000017
R5       EQU   5                                                        18400017
R6       EQU   6                                                        18800017
R7       EQU   7                                                        19200017
R8       EQU   8                                                        19600017
R9       EQU   9                                                        20000017
R10      EQU   10                                                       20400017
R11      EQU   11                                                       20800017
R12      EQU   12                                                       21200017
R13      EQU   13                                                       21600017
R14      EQU   14                                                       22000017
R15      EQU   15                                                       22400017
*******************************************************************     22800017
*DEFINE DCB                                                             23200017
         DCBD  DSORG=PS                                                 23600017
DCBEND   EQU   *                                                 F40172 23600219
DCBLN    EQU   DCBEND-IHADCB       LENGTH OF OUTPUT DCB          F40172 23600419
         DS    0F                                                       23600619
EAJFCB   DSECT                                                   YA4295 23602621
         IEFJFCBN                                                YA4295 23610621
         IEFSDPAR                                                MAPMAC 25600620
         IEFSDWKT                                                MAPMAC 27600620
         IEFSDSDR                                                MAPMAC 29600620
         IEFSDWKX                                                MAPMAC 31600620
         IEFSDBAR                                                MAPMAC 33600620
*******************************************************************     40400017
*              THE FOLLOWING IS THE REPLACEMENT FOR PUT ROUTINE   *     40800017
*              WHEN EXCP IS BEING USED INSTEAD OF PUT. THE PUT    *     41200017
*              MACRO WILL GET THE ADDRESS 48 IN THE DCB AND THAT  *     41600017
*              WILL BRANCH TO HERE.                               *     42000017
*******************************************************************     42400017
IEFSDXYZ CSECT                                                          42800017
         SAVE  (2,12)                   SAVE REGISTERS                  43200017
         BALR  R9,0                     ESTABLISH                       43600017
         USING *,R9                      BASE REGISTER                  44000017
         LR    R5,R1                    GET DCB BASE                    44400017
         USING IHADCB,R5                SET BASE FOR DCB                44800017
         LA    R7,IHADCB+DCBLN     GET ADDRESS OF PARLIST        F40172 44850019
         USING PARLIST,R7          ESTABLISH ADDRESSIBILITY      F40172 44900019
         L     R3,PARWKSOR              GET ADDR OF WKSOR        A35780 44920020
         L     R7,PARWKLST         GET ADDRESSS OF WORKLIST      F40172 44950019
         USING WORKLST,R7                                          VS0H 45000017
         USING WKSOR,R3                                          A35780 45100020
         L     R11,DCBIOBAD             GET LOCATION OF IOB             45200017
         LA    R6,IOBFLAG1-IOBAR        GET OFFSET TO IO TABLES         45600017
         SR    R11,R6                   HAVE START OF TABLES            46000017
         USING IOBAR,R11                                                46400017
         ST    R14,IOEXU                SAVE RETURN ADDRESS             46800017
*IS ENTRY FROM TRUNCATE                                                 47200017
         LTR   R15,R15                  TEST FOR CAME TO TRUNCATE       47600017
         BNZ   FAKPT                    IF NOT BRANCH TO FAKED PUT      48000017
*TEST FOR NO PUTS ISSUED                                                48400017
         TM   IOSWT,IOCLB              TEST FOR IST TIME IF SO          48800021
         BZ   FINGO                    BRANCH TO DONE                   49200021
*DO FAKE TRUNC                                                          49600017
         OI    IOSWT,IOTRN              TURN ON TRUNCATE SWITCH         50000017
*END CCW CHAIN                                                          50400017
         L     R12,IOCHA                SAVE ADD OF CCW MADE END        50800017
*SAVE CHAIN BIT OF CCW MADE END                                         51200017
         MVC   IOEXT(1),NXTCCFLG(R12)   SAVE FLAGS OF NEXT CCW   A29072 51400019
         MVI   NXTCCFLG(R12),SILINOCC   PROVIDE NOP CCW AT TRUNC A29072 51600019
         MVI   CCWLGN(R12),NOP            END FOR IOS/ERP OF SKIPA29072 51800019
         MVI   EOCFLAG(R12),EOCBITS     TO ONE CARRIAGE SENSE    A66896 52000021
*TURN ON FIRST REAL END INDICATION                                      52400017
         OI    IOSWT,IOEN1                                              52800017
*FAKE PUT                                                               53200017
* IS THIS THE FIRST TIME FOR THIS DATASET OR SMBS                       53600017
FAKPT    TM    IOSWT,IOCLB              TEST FOR NOT 1ST TIME IF SO     54000017
         BO    TACCW                    BRANCH TO CONTINUING            54400017
*SET UP FOR FIRST TIME                                                  54800017
         OI    IOSWT,IOCLB              TURN ON NOT FIRST TIME SW       55200017
         L     R12,IOOFF                GET ADDRESS OF FIRST CCW        55600017
         OI    IOECB,X'7F'              INDICATE GOOD END ON ECB        56000017
         XC    WOLCL(4),WOLCL           CLEAR SPAN LENGTH          VS0H 56200017
         B     TFVOP                    BRANCH TO FILL BUFFER           56400017
*GET INFORMATION ON RECORD TO BE OUTPUT                            VS0H 56600017
TACCW    L     R12,IOCHA                GET LAST CCW USED          VS0H 56800017
         LH    R4,6(R12)                GET LENGTH FROM CCW      A35926 57000020
         L     R6,0(R12)                GET LOCATION OF RECORD     VS0H 57200017
         LA    R6,0(R6)                 REMOVE TOP BYTE            VS0H 57400017
*IS OUTPUT LENGTH GENERATED IN SPAN ROUTINE                        VS0H 57600017
         NC    WOLCL(2),WOLCL           IF THERE IS NO SPANNING    VS0H 57800017
         BZ    CCGET                    THEN BRANCH TO GET C.C.    VS0H 58000017
*GET LENGTH OF OUTPUT RECORD FROM SPAN DATA                        VS0H 58200017
         LH    R4,WOLCL                 GET LENGTH OF SEGMENT    A35926 58400020
*IS THERE A CONTROL CHARACTER IN THE RECORD                        VS0H 58600017
         TM    DCBRECFM,VARSP           IF NOT SPANNED OUTPUT      VS0H 58800017
         BNO   CCGET                    GO GET CONTROL CHAR.       VS0H 59000017
         TM    WOLCL+2,NOTFI            IF FIRST SEG. THEN         VS0H 59200017
         BZ    CCGET                    BRANCH TO GET C.C.         VS0H 59400017
         TM    IOSWT,IOTRN              IF TRANSITION RECORD THEN  VS0H 59460017
         BO    CCGET                    BRANCH TO GET C.C.         VS0H 59520017
*MAKE CONTROL CHARACTER FOR CCW OF BUFFER JUST FILLED              VS0H 59600017
         MVI   0(R12),X'09'             PUT IN SPACE 1 MACH. C.C.  VS0H 59800017
*FIX DATA ADDRESS TO START WHERE CONTROL CHARACTER WOULD HAVE BEEN VS0H 60000017
         NI    3(R12),255-1                                        VS0H 60200017
         B     SVLEN                    GO TO FIX LENGTH           VS0H 60400017
*MOVE CONTROL CHARACTER INTO CCW FOR BUFFER JUST FILLED            VS0H 60600017
CCGET    BCTR  R6,0                     GET LOCATION OF C.C.       VS0H 60800017
         MVC   0(1,R12),0(R6)           MOVE C.C. INTO CCW         VS0H 61000017
*GET LENGTH OF RECORD TO BE WRITTEN                                VS0H 61200017
         BCTR  R4,0                     GET LENGTH WITHOUT CC    A35926 61400020
         TM    IOSWT,IOVAR              TEST FOR V RECORD          VS0H 61600017
         BZ    HVLEN                    IF NOT HAVE LENGTH         VS0H 61800017
SVLEN    S     R4,FOURY                 GET LENGTH PROPER        A35926 62100020
HVLEN    STH   R4,6(R12)                SAVE ACTUAL LENGTH I/CCW A35926 62400020
         MVI   4(R12),SILICC            REINSTATE COMMAND CHAIN BA29072 62700019
*ARE ALL CCWS FULL                                                      63200021
         TM    NXTCCFLG(R12),NOCC       TEST FOR FILLED ALL CCWS A29072 63600019
         BZ    TFUCC                    IF SO CK USER SUPPLIED CCA29072 64000019
         LA    R12,8(R12)               UP POINTER TO NEXT CCW          64400017
*SAVE ADDRESS OF CCW TO BE USED                                         64800017
TFVOP    ST    R12,IOCHA                SAVE CCW                        65200017
*GET START OF NEXT BUFFER TO BE FILLED                                  65600017
         MVC   6(2,R12),DCBLRECL        SAVE RECORD LENGTH IN CCW       66000017
         OI    3(R12),1                 INITIALIZE START OF REC.   VS0H 66100017
         LH    R0,IOEXT+1               GET LENGTH FOR SPAN PUT    VS0H 66200017
         L     R1,0(R12)                GET LOCATION OF RECORD          66400017
         LA    R1,0(R1)                 GET RID OF TOP BYTE             66800017
         BCTR  R1,0                     POINT TO CONTROL CHAR.          67200017
         TM    IOSWT,IOVAR              TEST FOR VARIABLE OUTPUT        67600017
         BZ    FINGO                    IF NOT HAVE ADDRESS             68000017
         S     R1,FOURY                 GET START ADD. FOR V REC.       68400017
*LEAVE THIS MODULE                                                      68800017
FINGO    L     R14,IOEXU                GET RETURN ADDRESS              69200017
         RETURN (2,12)                                                  69600017
TFUCC    EQU   *                                                 A29072 69650019
         MVI   CHCCIND(R12),CLEAR       SET CCIND TO SKIP        A29072 69700021
         MVI   CCWLGN(R12),NOP          REINSTATE NOP CCW        A29072 69750019
         LA    R8,IHADCB+DCBLN          ADDRESS OF PARLIST       A69301 69750421
         USING PARLIST,R8                                        A69301 69750821
         TM    PARSWCH,PARTTE           PROCESSING SMB           A69301 69751821
         BO    TFOCH                      YES, WE DO SKIPPING    A69301 69752221
         TM    PARSWCH,PARTTE1          PROCESSING SEPARATOR     A69301 69752621
         BO    USCC                       YES, GO STOP SKIPS     A69301 69753021
         L     R8,WJFCB                 IS DSB. CHECK JFCB       YA4295 69760021
         USING EAJFCB,R8                ADDR OF INPUT JFCB       YA4295 69780021
         TM    JFCRECFM,JFCASA+JFCMAC   TEST FOR USER CTL CHAR   YA4295 69800021
         BZ    TFOCH                      NO, BRANCH TO EXCP     M3018  69820021
         DROP  R8                                                M3018  69840021
USCC     EQU   *                                                 A35780 69870020
         MVI   CHCCIND(R12),FLAGF       FLAG=USER SUPPLIED C.C.  A29072 69900021
*IS THERE ONE CHAIN                                                     70000017
TFOCH    CLC   IOOFF+1(3),IOBSIOCC+1    TEST FOR ONE CHAIN, IF NOT      70400017
         BNE   TEXDO                    BRANCH AROUND EXCP              70800017
*DO EXCP FOR ONE CHAIN                                                  71200017
         NI    IOECB,X'00'              TURN OFF ECB FLAGS              71600017
         LA    R1,IOBFLAG1              GET IOB ADDRESS                 72000017
         EXCP  (1)                      DO EXCP                         72400017
*IS EXCP DONE                                                           72800017
TEXDO    TM    IOECB,X'40'              TEST FOR ECB POSTED,IF SO       73200017
         BO    TOTER                    BRANCH AROUND WAIT              73600017
*WAIT FOR COMPLETION OF EXCP                                            74000017
         LA    R1,IOECB                 GET ECB ADDRESS                 74400017
         WAIT  ECB=(1)                                                  74800017
*CHECK FOR OUTPUT ERROR                                                 75200017
TOTER    TM    IOECB,X'7F'              TEST FOR O.K. IF NOT            75600017
         BNO   SDERX                    BRANCH TO ERROR EXIT            76000017
*CLEAR OUT ECB                                                          76400017
         XC    IOECB(4),IOECB                                           76800017
*GET FIRST CCW FOR NEXT CHAIN                                           77200017
         L     R12,IOBSIOCC             GET FIRST CCW OF DONE CHAIN     77600017
*IS THERE ONE CHAIN                                                     78000017
         CLC   IOOFF+1(3),IOBSIOCC+1    TEST FOR ONE CHAIN, IF NOT      78400017
         BNE   TWCEX                    BRANCH TO EXCP                  78800017
*IS REAL END ON FOR 1 CHAIN                                             79200017
         TM    IOSWT,IOEN1              TEST FOR REAL END. IF NOT       79600017
         BZ    TFVOP                    BRANCH TO MOVE IN DATA          80000017
*PUT CORRECT CCW CHAIN BIT BACK ON CCW WHICH WAS LAST FOR EOF           80400017
PCCCW    L     R12,IOCHA                GET ADD OF CCW TO INITIAL       80800017
         MVC   NXTCCFLG(1,R12),IOEXT    INITIALIZE IT            A29072 81200019
*TURN OFF SWITCHES                                                      81600017
FINGN    NI    IOSWT,X'FF'-IOTRN-IOEN2-IOEN1-IOCLB                 VS0H 82000017
         B     FINGO                    BRANCH OUT AS DONE              82400017
*SWITCH CHAIN TO BE PUT OUT AND CHAIN OF BUFFERS TO FILL                82800017
TWCEX    XC    IOOFF+1(3),IOBSIOCC+1    SWITCH ADDRESSES                83200017
         XC    IOBSIOCC+1(3),IOOFF+1    OF CURRENT AND                  83600017
         XC    IOOFF+1(3),IOBSIOCC+1    NEXT CCW CHAINS                 84000017
*IS THE SECOND FINAL END SWITCH ON                                      84400017
         TM    IOSWT,IOEN2              TEST FOR END OF TWO BUFFERS     84800017
         BO    PCCCW                    BRANCH TO END IF SO             85200017
*DO EXCP FOR TWO CHAINS ROUTINE                                         85600017
         LA    R1,IOBFLAG1              GET IOB ADDRESS                 86000017
         EXCP  (1)                      DO EXCP                         86400017
*IS THE FIRST FINAL END SWITCH ON                                       86800017
         TM    IOSWT,IOEN1              TEST FOR PRE-END                87200017
         BZ    TFVOP                    BRANCH TO FILL BUFF IF NOT      87600017
*TURN ON SECOND FINAL END SWITCH                                        88000017
         OI    IOSWT,IOEN2              TURN ON END OF TWO BUFF SW      88400017
         B     TEXDO                    BRANCH TO TEST EXCP DONE        88800017
*IS ERROR FROM TRUNCATION                                               89200017
SDERX    TM    IOSWT,IOTRN              TEST FOR TRUNCATE ERROR         89600017
         BZ    SDERY                    IF NOT GO TO USER ROUT.         90000017
*TRUNCATION ERROR                                                       90400017
         SR    R1,R1                    INDICATE AN ERROR               90800017
         B     FINGN                    BRANCH TO GO BACK TO TRUNC VS0H 91200017
*PUT ERROR                                                              91600017
SDERY    L     R15,DCBSYNAD             GET USERS SYNAD ROUTINE         92000017
         NI    IOSWT,X'FF'-IOTRN-IOEN2-IOEN1-IOCLB  SWITCHES OFF   VS0H 92200017
         L     R14,IOEXU                GET RETURN ADDRESS              92400017
         LM    R2,R12,28(R13)           RESTORE REGISTERS               92800017
         BR    R15                      RETURN                          93200017
         DS    0F                                                       93600017
FOURY    DC    X'00000004'              FOUR                            94000017
ONELY    DC    X'00000001'                                         VS0H 94040017
CLEAR    EQU   X'00'                    CLEAR CC INDR FLAG       A66896 94043021
CCWLGN   EQU   8                        LGN OF 1 CCW             A29072 94046019
NXTCCFLG EQU   12                       FLAG IN NEXT CCW         A29072 94049019
EOCFLAG  EQU   14                       END-OF-CHAIN BYTE        A66896 94052021
EOCBITS  EQU   X'07'                    EOC INDICATOR            A66896 94054021
CHCCIND  EQU   15                       CHAIN CNTRL CHAR IND     A29072 94055019
SILINOCC EQU   X'20'                    SILI - NO COMMAND CHAIN  A29072 94058019
NOCC     EQU   X'40'                    NO CNTRL CHARACTER       A29072 94061019
SILICC   EQU   X'60'                    SILI AND COMMAND CHAIN   A29072 94064019
NOP      EQU   X'03'                    NOP CCW OP CODE          A29072 94067019
FLAGF    EQU   X'FF'                    ONE BYTE FLAG TO MARK    A29072 94070019
*                                         END OF CCW CHAIN OR    A29072 94073019
*                                         USER SPECIFIED CNTRL C A29072 94076019
VARSP    EQU   X'48'                    VARIABLE SPAN INDICATION   VS0H 94080017
NOTFI    EQU   X'2'                     NOT FIRST SEG. INDICATION  VS0H 94120017
         DC    C'ZAPSZAPSZAPSZAPS'                                 VS0H 94160017
         DC    C'ZAPSZAPSZAPSZAPS'                                 VS0H 94200017
         DC    C'ZAPSZAPSZAPSZAPS'                                 VS0H 94240017
         DC    C'ZAPSZAPSZAPSZAPS'                                 VS0H 94280017
         DC    C'ZAPSZAPSZAPSZAPS'                                 VS0H 94320017
         END                                                            94400017
