*********************************************************************** 00020000
*                                                                     * 00040000
*  TITLE  IEFVGK (GET KEY/POSITIONAL UTILITY ROUTINE).                * 00060000
*                                                                     * 00080000
*  FUNCTION/OPERATION   THIS UTILITY ROUTINE GETS THE NEXT KEYWORD    * 00100000
*        OR POSITIONAL PARAMETER IN THE INTERNAL TEXT BUFFER FOR      * 00120000
*        THE CALLING PROCESSOR ROUTINE (IEFVDA, IEFVEA OR IEFVJA).    * 00140000
*        IT ALSO HANDLES THE GETTING OF CHAINED BUFFERS FROM DISK     * 00160000
*        WHEN A LONG JCL STATEMENT CAUSES OVERFLOW.                   * 00180000
*                                                                     * 00200000
*  ENTRY POINT   IEFVGK (FROM IEFVDA, IEFVEA OR IEFVJA).              * 00220000
*                                                                     * 00240000
*  INPUT      1. R10 = POINTER TO JOB, EXEC OR DD WORK AREA.          * 00260000
*             2. R11 = BASE REGISTER OF JOB, EXEC OR DD WORK AREA.    * 00280000
*             3. R12 = POINTER TO INTERPRETER WORK AREA.              * 00300000
*             4. R13 = POINTER TO THE CURRENT REGISTER SAVE AREA.     * 00320000
*             5. R14 = RETURN ADDRESS.                                * 00340000
*        NOTE  R10 THRU R14 ARE STANDARD INTERPRETER CONVENTION.      * 00360000
*                                                                     * 00380000
*  OUTPUT     1. R2 = LENGTH OF CURRENT POSITIONAL PARAMETER.         * 00400000
*             2. R3 = POINTER TO LENGTH BYTE OF CURRENT PARAMETER.    * 00420000
*             3. R4 = POINTER TO PARAMETER DESCRIPTOR TABLE.          * 00440000
*                                                                     * 00460000
*  EXTERNAL ROUTINES    1. IEFVHQ - QMNGR INTERFACE ROUTINE.          * 00480000
*                                                                     * 00500000
*  EXIT  RETURN ON REGISTER 14.                                       * 00520000
*                                                                     * 00540000
*  ERROR EXIT  RETURN TO THE CLEANUP PORTION OF THE PROCESSING        * 00560000
*              ROUTINE.                                               * 00580000
*                                                                     * 00600000
*  TABLES/WORK AREAS   1. INTERPRETER WORK AREA (IEFVMIWA).           * 00620000
*                      2. AUXILIARY WORK AREA (IEFVMAWA).             * 00640000
*                      3. QMANAGER PARAMETER AREA (IEFQMNGR).         * 00660000
*                      4. INTERPRETER KEYS (IEFVKEYS).                * 00680000
*                                                                     * 00700000
*  ATTRIBUTES   READ ONLY / REENTRANT.                                * 00720000
*                                                                     * 00740000
*  NOTES    ERROR MESSAGES                                            * 00760000
*              1. IEF640I - EXCESSIVE NO. OF POSITIONAL SUBPARAMETERS * 00780000
*              2. IEF641I - IMPROPER SUBPARAMETER LIST.               * 00800000
*                                                                     * 00820000
*********************************************************************** 00840000
*                                                                     * 00860000
         TITLE 'IEFVGK - KEYS'                                          00880000
         IEFVKEYS                                                       00900000
         TITLE 'IEFVGK - IEFQMNGR'                                      00920000
         IEFQMNGR                                                       00940000
         TITLE 'IEFVGK - IWA'                                           00960000
         IEFVMIWA                                                       00980000
         TITLE 'IEFVGK - AWA'                                           01000000
GKWORK   DSECT                                                          01020000
         IEFVMAWA                                                       01040000
         TITLE 'IEFVGK - CSECT'                                         01060000
*                                                                     * 01080000
*********************************************************************** 01100000
*                                                                     * 01120000
*              EQUATES - ERROR MESSAGE NUMBERS.                       * 01140000
*                                                                     * 01160000
*********************************************************************** 01180000
*                                                                     * 01200000
GKER1    EQU   X'28'   IEF640I EXCESSIVE NBR OF POS. SUBPARAMETERS.     01220000
GKER2    EQU   X'29'   IEF641I IMPROPER SUBPARAMETER LIST.              01240000
         EJECT                                                          01260000
IEFVGK   CSECT                                                          01280000
*0654022400,022600                                                19378 01285017
*0058                                                              AABA 01290016
* 039600                                                          M3139 01295019
*********************************************************************** 01300000
*                                                                     * 01320000
*        INPUT TO THIS ROUTINE:                                       * 01340000
*                                                                     * 01360000
*              RA POINTS TO JOB, EXEC OR DD WORK AREA.                * 01380000
*              RB IS BASE REGISTER OF JOB, EXEC OR DD ROUTINE.        * 01400000
*              RC POINTS TO INTERPRETER WORK AREA.                    * 01420000
*              RD POINTS TO CURRENT REGISTER SAVE AREA.               * 01440000
*              RE RETURN ADDRESS.                                     * 01460000
*                                                                     * 01480000
*********************************************************************** 01500000
*                                                                       01520000
         SPACE 2                                                        01540000
         STM   R5,R1,12(RD)       SAVE ALL REGISTERS BUT R2,R3 & R4.    01560000
         SPACE                                                          01580000
         BALR  RB,0               REGISTER 11 IS THE BASE               01600000
         USING *,RB                    OF THIS ROUTINE.                 01620000
GKBASE   EQU   *                                                        01640000
         B     GKA3                                                     01660000
         DC    X'1048'                                             AABA 01680016
         DC    X'11111111'        MODULE ID CONVENTION.                 01700000
         DC    C'GK'                                                    01720000
GKA3     DS    0H                                                       01740000
         USING IWA,RC             INTERPRETER WORK AREA.                01760000
         USING GKWORK,RA          LOCAL WORK AREA (GOTTEN IN CALLING    01780000
*                                      PROGRAM).                        01800000
         LM    R2,R5,TNUM         GET CURRENT PARAM/SUBPARAM STATUS.    01820000
         CLR   R2,R3              PARAMETERS TO PROCESS.                01840000
         BNE   GKB2               YES. GO TO GET POSITIONAL.            01860000
         CLR   R4,R5              SUBPARAMETER TO PROCESS.              01880000
         BNE   GKB2               YES. GO TO GET POSITIONAL.            01900000
         EJECT                                                          01920000
*********************************************************************** 01940000
**                                                                   ** 01960000
**             GET KEY PROCESSING.                                   ** 01980000
**                                                                   ** 02000000
*********************************************************************** 02020000
GKB4     DS    0H                                                       02040000
         LM    R6,R9,TKEYPX       R6 = CURRENT KEY POINTER.             02060000
*                                 R7 = CURRENT NUMBER POINTER.          02080000
*                                 R8 = CURRENT LENGTH.                  02100000
*                                 R9 = CURRENT LENGTH POINTER.          02120000
         LTR   R6,R6              CURRENT KEY POINTER = ZERO.           02140000
         BE    GKB5A              YES. INITIAL ENTRY TO GET KEY.        02160000
         LR    R6,R9              TAKE TLENP.                           02180000
         AR    R6,R8              ADD TLEN.                             02200000
         LA    R6,1(R6,0)         PLUS ONE. R6 NOW POINTS TO NEXT KEY.  02220000
         CLI   0(R6),KCONT        CONTINUE KEY.                         02280000
         BNE   GKF3               NO. GO TO PROCESS CURRENT KEY.        02300000
         BAL   R7,GKC5            YES. GO GET NEXT BUFFER.              02320000
         LR    R6,R9              R9 POINTS TO NEW KEY.                 02340000
GKF3     DS    0H                                                       02360000
         CLI   0(R6),ENDK          END KEY                        19378 02366017
         BE    GKE4                YES. GO TO CLEANUP             19378 02372017
         LA    R7,1(R6,0)         R7 NOW POINTS TO NEW NBR.             02380000
         LR    R9,R7              SET R9 (TLENP) TO BE INCREMENTED      02400000
*                                      BY GET POS.                      02420000
         L     R4,TBRANCH         BRANCH TABLE ADDRESS TO R4.           02440000
         SR    R5,R5                                                    02460000
         IC    R5,0(R6)           THIS KEY TO R5.                       02480000
         STC   R5,MSGKEY          STORE KEY IN IWA FOR POSS ERROR MSG.  02500000
         SR    R1,R1                                                    02520000
         IC    R1,TBASE           COMPUTE TABLE ENTRY ADDRESS FROM BASE 02540000
         SR    R1,R5                   KEY AND CURRENT KEY.             02560000
         MH    R1,GK06                                                  02580000
         LA    R1,0(R1,R4)        R1 NOW POINTS AT TABLE ENTRY.         02600000
         CLC   0(1,R7),0(R1)      TOO MANY PARAMETERS FOR THIS KEY.     02620000
         BH    GKG5               YES. GO TO SET ERROR MSG.             02640000
         XC    TNUM(16),TNUM      ZERO STATUS TABLE.                    02660000
         MVC   TNUM+3(1),0(R7)    MOVE NBR OF PARAMS TO TABLE.          02680000
         SR    R8,R8              SET LENGTH SLOT TO ZERO.              02700000
         STM   R6,R9,TKEYPX       STORE UPDATED STATUS OF KEY,NUM & LEN 02720000
         LH    R9,2(R1)           BRANCH RETURN RELATIVE ADDRESS TO R9. 02740000
         L     R8,36(RD)          JOB,EXEC OR DD BASE TO R8.            02760000
         LA    R9,0(R9,R8)        ABSOLUTE BRANCH RTN ADDR TO R9.       02780000
         ST    R9,48(RD)          STORE INTO R14 RETURN SLOT.           02800000
         LH    R9,4(R1)           PDT RELATIVE ADDRESS TO R9.           02820000
         LA    R9,0(R9,R8)        PDT ADDRESS TO R9.                    02840000
         ST    R9,TPDTSAVE        SAVE TO PICK UP ON EXIT.              02860000
         MVC   TSUBPARM(1),1(R1)  SAVE SUBPARM CHECK FIELD FOR GET POS. 02880000
         CLI   TNUM+3,X'00'       DOES NBR PARAMS EQUAL ZERO.           02900000
         BE    GKJ2A              YES. GO TO EXIT.                      02920000
         B     GKB2               GO TO GET POS.                        02940000
*                                                                       02960000
*   INITIALIZE WORK AREA.                                               02980000
*                                                                       03000000
GKB5A    DS    0H                                                       03020000
         LA    R6,TEXTBUF         TEXT BUFFER ADDRESS TO R6.            03040000
         ST    R6,TBEGPX          STORE IN WORK AREA.                   03060000
         MVC   TRR1(3),0(R6)      MOVE TTR OF OVERFLOW TEXTBUF TO LWA.  03080000
         MVC   TBASE(1),4(R6)     MOVE BASE KEY TO LWA.                 03100000
         LA    R6,4(0,R6)         POINT R6 AT FIRST KEY.                03120000
         B     GKF3               GO TO PROCESS KEY.                    03140000
         SPACE                                                          03160000
GKG5     DS    0H                                                       03180000
         MVI   MSGSEC,GKER1       SET ERROR MSG CODE 'TOO MANY PARAMS'. 03200000
GKE4     DS    0H                                                       03220000
         MVC   48(4,RD),TCLEANUP  MOVE CLEANUP ADDRESS TO R14 SLOT.     03240000
         B     GKK2               GO TO EXIT.                           03260000
         EJECT                                                          03280000
*********************************************************************** 03300000
**                                                                   ** 03320000
**             GET POSITIONAL PROCESSING.                            ** 03340000
**                                                                   ** 03360000
*********************************************************************** 03380000
         SPACE                                                          03400000
GKB2     DS    0H                                                       03420000
         LM    R2,R5,TNUM                                               03440000
*        R2 = TNUM                                                      03460000
*        R3 = TCT                                                       03480000
*        R4 = TNUM1                                                     03500000
*        R5 = TCT1                                                      03520000
         SPACE                                                          03540000
         LM    R8,R9,TLEN                                               03560000
*        R8 = TLEN                                                      03580000
*        R9 = TLENPX                                                    03600000
         SPACE                                                          03620000
         CLR   R4,R5              SUBPARAMETERS TO PROCESS.             03640000
         BNE   GKB1               YES. GO TO INCREMENT TCT1.            03660000
         LA    R3,1(R3,0)         NO. PROCESSING PARAMETER. INCR. TCT.  03680000
         B     GKD1               GO TO INCREMENT TO NEXT LENGTH.       03700000
         SPACE                                                          03720000
GKE2     DS    0H                                                       03740000
         CLI   0(R9),LCONT         IS THIS A CONTINUE LENGTH      M3139 03746019
         BC    8,GKH3            YES. GET NEXT BUFFER             M3139 03752019
         SR    R8,R8                                                    03760000
         IC    R8,0(R9)           PUT CURRENT LENGTH INTO R8.           03780000
         LR    R7,R8              TLEN OR N' TO R7.                     03800000
         SRL   R7,7                                                     03820000
         LTR   R7,R7              IS THERE A HIGH ORDER ONE.            03840000
         BNE   GKE1               YES. SUBPARAMETER. GO TO SET UP       03860000
         SPACE                                                          03880000
GKH2     DS    0H                                                       03900000
         CLI   0(R9),LCONT        IS THIS A CONTINUE LENGTH.            03920000
         BNE   GKJ2               NO. GO TO SAVE STATUS & EXIT.         03940000
GKH3     BAL   R7,GKC5             YES. GO GET NEXT TEXT BUFFER   M3139 03960019
         B     GKE2               GO TO CHECK STATUS.                   03980000
         SPACE 2                                                        04000000
*   S A V E  S T A T U S  A N D  R E T U R N  O N  R E G  1 4.          04020000
GKJ2     DS    0H                                                       04040000
         STM   R8,R9,TLEN         STORE LENGTH AND LENGTH POINTER.      04060000
         STM   R2,R5,TNUM         STORE PARAM/SUBPARAM STATUS.          04080000
GKJ2A    DS    0H                                                       04100000
         LM    R2,R4,TLEN         R2 = LENGTH.                          04120000
*                                 R3 = LENGTH POINTER.                  04140000
*                                 R4 = PDT POINTER.                     04160000
GKK2     DS    0H                                                       04180000
         LM    R5,R1,12(RD)       RESTORE REGISTERS.                    04200000
         BR    RE                 RETURN.                               04220000
         SPACE 2                                                        04240000
GKB1     DS    0H                                                       04260000
         LA    R5,1(R5,0)         INCREMENT TCT1.                       04280000
GKD1     DS    0H                                                       04300000
         AR    R9,R8              ADD OLD LENGTH.                       04320000
         LA    R9,1(R9,0)         POINT AT NEXT LENGTH SLOT.            04340000
         B     GKE2                                                     04360000
         SPACE                                                          04380000
GKE1     DS    0H                                                       04400000
         LR    R4,R8              PICK UP NBR SUBPARAMS.                04420000
         N     R4,GKPATRN2        TURN OFF HIGH ORDER BIT.              04440000
         LA    R5,1               SET TCT1 TO ONE.                      04460000
         LA    R9,1(R9,0)         INCREMENT POINTER TO LENGTH.          04480000
         IC    R8,0(R9)           PUT CURRENT LENGTH IN R8.             04500000
         CLI   TSUBPARM,X'FF'     IF SUBPARAMETERS ARE ALLOWED IN  AABA 04504016
         BE    GKH2               THE FIRST 8 PARAMETERS, ALLOW    AABA 04508016
*                                 THEM ANYWHERE.                   AABA 04512016
         SPACE                                                          04516016
         SPACE                                                          04520000
         SR    R6,R6              *    THIS SEQUENCE CHECKS TO SEE      04540000
         IC    R6,TSUBPARM        *    IF A SUBPARAMETER IS OK IN       04560000
         LH    R7,GKPATRN1        *    THIS POSITION OF THE PARAM       04580000
         SRL   R7,0(R3)           *    FIELD. R3 IS THE NUMBER OF THE   04600000
         NR    R7,R6              *    CURRENT PARAM UNDER THIS KEY.    04620000
         BC    4,GKH2             SUBPARAMETER IS OK. CONTINUE.         04640000
         MVI   MSGSEC,GKER2       ERROR. SET ERROR CODE. SUBPARM ERROR. 04660000
         B     GKE4               GO TO GET CLEANUP ADDRESS.            04680000
         EJECT                                                          04700000
*********************************************************************** 04720000
**                                                                   ** 04740000
**             GET INTERNAL TEXT BUFFER FROM DISK.                   ** 04760000
**                                                                   ** 04780000
*********************************************************************** 04800000
*        R7 = RETURN  - INPUT                                           04820000
*        R9 = 1ST KEY OR LENGTH  - OUTPUT                               04840000
         SPACE                                                          04860000
GKC5     DS    0H                                                       04880000
         LA    R8,QPARM           Q-MANAGER PARAMETER AREA ADDRESS.     04900000
         USING IOPARAMS,R8                                              04920000
         L     R9,QMPCL           GET ADDRESS OF QMPCA/QMPEX.           04940000
         MVC   0(4,R9),TBEGPX     MOVE TABLE ADDRESS TO QMPCA.          04960000
         MVI   QMPOP,QMREAD       SET READ FLAG.                        04980000
         MVC   4(4,R9),TRR1       MOVE TTR TO QMPEX.                    05000000
         IEFSAVER SAVEPTR         GET NEW REG SAVE AREA.                05020000
         L     RF,GKVHQ           LINK TO IEFVHQ TO GET TABLE READ IN.  05040000
         BALR  RE,RF                                                    05060000
         IEFRELSE SAVEPTR         RELEASE NEW REG SAVE AREA.            05080000
         SPACE                                                          05100000
         L     R9,TBEGPX          BEGIN ADDRESS OF NEW TABLE TO R9.     05120000
         MVC   TRR1(3),0(R9)      MOVE NEXT TEXT BUFFER TTR TO LWA.     05140000
         LA    R9,4(0,R9)         POINT R9 AT KEY OR LENGTH BYTE.       05160000
         BR    R7                 RETURN                                05180000
GKVHQ    DC    V(IEFVHQ)                                                05200000
         DROP  R8                                                       05220000
         EJECT                                                          05240000
*********************************************************************** 05260000
*                                                                     * 05280000
*              CONSTANTS                                              * 05300000
*                                                                     * 05320000
*********************************************************************** 05340000
GK06     DC    H'6'                                                     05360000
GKPATRN1 DS    0H                 CHECK HIGH ORDER ONE PATTERN.         05380000
         DC    XL2'0100'                                                05400000
GKPATRN2 DS    0F                 TURN OFF HIGH ORDER ONE PATTERN.      05420000
         DC    XL4'0000007F'                                            05440000
         END                                                            05460000
