*********************************************************************** 00020000
*                                                                     * 00040000
*  TITLE  IEFVGT (TEST & STORE UTILITY ROUTINE).                      * 00060000
*                                                                     * 00080000
*  FUNCTION/OPERATION   THIS IS A UTILITY ROUTINE USED BY MODULES     * 00100000
*        IEFVDA, IEFVEA & IEFVJA TO PERFORM THE FOLLOWING FUNCTIONS:  * 00120000
*              0. OR A BYTE(STORAGE-TO-STORAGE).                      * 00140000
*              1. CVB (1 CHARACTER) & MVC.                            * 00160000
*              2. CVB (2 CHARACTERS) & MVC.                           * 00180000
*              3. CVB (3 CHARACTERS) & MVC.                           * 00200000
*              4. AND A BYTE (STORAGE-TO-STORAGE).                    * 00220000
*              5. MVC (STORAGE-TO-STORAGE).                           * 00240000
*              6. CHECK 1ST CHARACTER FOR ALPHA & MVC.                * 00260000
*              7. ALPHA/NUMERIC CHARACTER CHECK & MVC.                * 00280000
*        A PARAMETER DESCRIPTOR TABLE IN EACH OF THE THREE PROCESSOR  * 00300000
*        MODULES DESCRIBES THE FUNCTIONS TO BE PERFORMED.             * 00320000
*        REGISTER FOUR POINTS TO THE PDT ON ENTRY TO IEFVGT.  WITH    * 00340000
*        THIS INFORMATION IEFVGT CAN NOT ONLY PERFORM THE ABOVE       * 00360000
*        FUNCTIONS BUT CAN ALSO MAKE CHECKS FOR UNIQUE KEYWORDS,      * 00380000
*        MAXIMUM PARAMETER LENGTH AND MAXIMUM NUMBER OF PARAMETERS.   * 00400000
*                                                                     * 00420000
*  ENTRY POINT    IEFVGT (FROM IEFVDA,IEFVEA OR IEFVJA).              * 00440000
*                                                                     * 00460000
*  INPUT      1.  R2 = LENGTH OF PARAMETER TO BE PROCESSED.           * 00480000
*             2.  R3 = POINTER TO PARAMETER LENGTH BYTE.              * 00500000
*             3.  R4 = POINTER TO PDT FOR THIS KEYWORD.               * 00520000
*             4.  R10 = POINTER TO JOB, EXEC OR DD WORK AREA.         * 00540000
*             5.  R11 = BASE REGISTER OF JOB, EXEC OR DD ROUTINE.     * 00560000
*             6.  R12 = POINTER TO THE INTERPRETER WORK AREA.         * 00580000
*             7.  R13 = POINTER TO THE CURRENT REGISTER SAVE AREA.    * 00600000
*             8.  R14 = RETURN ADDRESS.                               * 00620000
*        NOTE  R10 THRU R14 ARE STANDARD INTERPRETER CONVENTION.      * 00640000
*                                                                     * 00660000
*  OUTPUT  ALL REGISTERS ARE RETURNED EXACTLY AS RECEIVED.            * 00680000
*              THE PARAMETER HAS BEEN ERROR CHECKED AND THE FUNCTION  * 00700000
*              PERFORMED OR, IF THERE WAS AN ERROR, AN ERROR MESSAGE  * 00720000
*              NUMBER IS SET IN MSGSEC.                               * 00740000
*                                                                     * 00760000
* EXTERNAL ROUTINES   NONE                                            * 00780000
*                                                                     * 00800000
*  EXIT   RETURN ON REGISTER 14 OR TO CLEANUP ROUTINE IF AN ERROR     * 00820000
*              WAS DETECTED.                                          * 00840000
*                                                                     * 00860000
*  ERROR EXIT  TO THE CLEANUP PORTION OF THE PROCESSING ROUTINE.      * 00880000
*                                                                     * 00900000
*  TABLES/WORK AREAS   1. INTERPRETER WORK AREA (IEFVMIWA).           * 00920000
*                      2. AUXILIARY WORK AREA (IEFVMAWA).             * 00940000
*                                                                     * 00960000
*  ATTRIBUTES   READ ONLY/REENTRANT.                                  * 00980000
*                                                                     * 01000000
*  NOTES:   ERROR MESSAGES                                            * 01020000
*              1.  IEF638I - SPECIFIED NUMERIC EXCEEDS MAXIMUM.       * 01040000
*              2.  IEF639I - INVALID CLASS DESIGNATION.               * 01060000
*              3.  IEF640I - EXCESSIVE NBR. OF POSITIONAL SUBPARAMS.  * 01080000
*              4.  IEF642I - EXCESSIVE PARAMETER LENGTH.              * 01100000
*              5.  IEF643I - UNIDENTIFIED SUBPARAMETER.               * 01120000
*              6.  IEF644I - INVALID NUMERIC.                         * 01140000
*              7.  IEF647I - NON-ALPHA 1ST CHARACTER OF NAME.         * 01160000
*                                                                     * 01180000
*********************************************************************** 01200000
*                                                                     * 01220000
         EJECT                                                          01240000
         TITLE 'IEFVGT - IWA'                                           01260000
         IEFVMIWA                                                       01280000
         TITLE 'IEFVGT - AWA'                                           01300000
GTWORK   DSECT                                                          01320000
         IEFVMAWA                                                       01340000
         TITLE 'IEFVGT - EQUATES'                                       01360000
*                                                                     * 01380000
*********************************************************************** 01400000
*                                                                     * 01420000
*              ERROR MESSAG NUMBERS                                   * 01440000
*                                                                     * 01460000
*********************************************************************** 01480000
*                                                                     * 01500000
GTERR1   EQU   X'2A'    IEF642I  EXCESSIVE PARAMETER LENGTH.            01520000
GTERR2   EQU   X'2B'    IEF643I  UNIDENTIFIED SUBPARAMETER.             01540000
GTERR3   EQU   X'2C'    IEF644I  INVALID NUMERIC.                       01560000
GTERR4   EQU   X'2F'    IEF647I  NON-ALPHA 1ST CHARACTER OF NAME.       01580000
GTERR5   EQU   X'26'    IEF638I  SPECIFIED NUMERIC EXCEEDS MAXIMUM.     01600000
GTERR6   EQU   X'28'    IEF640I  EXCESSIVE NBR OF POS. SUBPARAMETERS.   01620000
GTERR7   EQU   X'27'    IEF639I  INVALID CLASS DISIGNATION.             01640000
         TITLE 'IEFVGT - CSECT'                                         01660000
IEFVGT   CSECT                                                          01680000
*********************************************************************** 01700000
*                                                                     * 01720000
*        INPUT TO THIS ROUTINE:                                       * 01740000
*                                                                     * 01760000
*              R2 = TLEN - LENGTH OF PARAMETER TO BE PROCESSED.       * 01780000
*              R3 = TLENP - POINTER TO LENGTH BYTE OF PARAMETER.      * 01800000
*              R4 = POINTER TO PROCESS DESCRIPTER TABLE THIS KEY.     * 01820000
*              RA = POINTER TO JOB, EXEC OR DD WORK AREA.             * 01840000
*              RB = BASE OF JOB, EXEC OR DD ROUTINE.                  * 01860000
*              RC = POINTER TO INTERPRETER WORK AREA.                 * 01880000
*              RD = POINTER TO CURRENT REGISTER SAVE AREA.            * 01900000
*              RE = RETURN ADDRESS.                                   * 01920000
*                                                                     * 01940000
*********************************************************************** 01960000
*                                                                       01980000
         SPACE 2                                                        02000000
         STM   RE,RC,12(RD)       SAVE REGISTERS.                       02020000
         SPACE                                                          02040000
         BALR  RB,0               REGISTER 11 IS THE BASE REGISTER      02060000
         USING *,RB                    OF THIS ROUTINE.                 02080000
GTBASE   EQU   *                                                        02100000
         B     GTA1                                                     02120000
         DC    X'3217'                                              318 02140000
         DC    X'11111111'        MODULE ID CONVENTION.                 02160000
         DC    C'GT'                                                    02180000
GTA1     DS    0H                                                       02200000
         USING IWA,RC             INTERPRETER WORK AREA.                02220000
         USING GTWORK,RA          LOCAL WORK AREA. (GOTTEN IN CALLING   02240000
*                                      PROGRAM.)                        02260000
         CL    R4,TPDTP           IS THIS THE SAME KEY AS LAST TIME.    02280000
         BNE   GTB2               NO. GO TO SET UP NEW KEY.             02300000
         L     R4,TCPDTP          SAME KEY. POINT TO NEXT PARAMETER     02320000
*                                      TO PROCESS WITHIN THIS KEY.      02340000
         B     GTD2A              GO TO BEGIN PROCESSING.               02360000
         SPACE                                                          02380000
GTB2     DS    0H                                                       02400000
         ST    R4,TPDTP           SAVE NEW PDT POINTER.                 02420000
         SPACE                                                          02440000
         SR    R8,R8                                                    02460000
         IC    R8,3(R4)           DOES THIS KEY REQUIRE AN              02480000
         LTR   R8,R8                   UNCONDITIONAL BIT SETTING.       02500000
         BNE   GTC3               NO. GO TO UPDATE TCPDTP.              02520000
         SPACE                                                          02540000
*     UNCONDITIONAL BIT SETTING REQUIRED FOR THIS KEYWORD.              02560000
         LA    R7,4(R4)           POINT R7 AT TAB/FUNCT BYTE.           02580000
         LA    R4,2(R4)           POINT R4 AT CONTROL BYTE.             02600000
         SPACE                                                          02620000
         BAL   R5,GTSUB           GO TO PROCESS PARAM.                  02640000
         SPACE                                                          02660000
         BCTR  R4,0               POINT R4 AT PDT LENGTH BYTE.          02680000
         SR    R5,R5              *                                     02700000
         SR    R6,R6              *                                     02720000
         IC    R5,0(R4)           *   CHECK FOR UNCONDITIONAL           02740000
         L     R7,TPDTP           *                                     02760000
         IC    R6,0(R7)           *      ACTION ONLY.                   02780000
         BCTR  R6,0               *                                     02800000
         CLR   R5,R6              *                                     02820000
         BE    GTJ4               GO TO EXIT.                           02840000
         SPACE                                                          02860000
GTD2A    DS    0H                                                       02880000
         SR    R5,R5                                                    02900000
         IC    R5,0(R4)           SET UP R5 FOR INDEXING.               02920000
         B     GTD3               GO TO BEGIN PROCESSING.               02940000
         SPACE                                                          02960000
GTC3     DS    0H                                                       02980000
         LA    R5,1               SET UP R5 TO BE INDEXED TO TCPDTP.    03000000
         SPACE                                                          03020000
GTD3     DS    0H                                                       03040000
         LA    R4,0(R5,R4)        POINT R4 AT TCPDTP.                   03060000
         ST    R4,TCPDTP          SAVE CURRENT PDT POINTER.             03080000
         SPACE                                                          03100000
         L     R6,TPDTP           *                                     03120000
         IC    R5,0(R6)           *    CHECK TO DETERMINE END OF        03140000
         LR    R8,R4              *    PDT - TOO MANY PARAMETERS IF     03160000
         SR    R8,R6              *    THE PDT HAS BEEN COMPLETED.      03180000
         CLR   R8,R5              *                                     03200000
         BE    GTG5A              *                                     03220000
         SPACE                                                          03240000
         LA    R6,1               SET CNTR TO ONE (TCPDT LENGTH BYTE).  03260000
         LR    RE,R4              SAVE TCPDTP IN RE.                    03280000
         LA    R4,1(R4,0)         POINT R4 AT FIRST CONTROL BYTE.       03300000
         LTR   R2,R2              IS THIS A KEYWORD=(NULL).             03320000
         BZ    GTJ4               YES. GO TO EXIT.                      03340000
         SPACE                                                          03360000
GTF3     DS    0H                                                       03380000
         IC    R5,0(R4)           PUT NBR OF BYTES FOR COMPARE IN R5.   03400000
         N     R5,GTMSK1          IS THIS PDT A REQUIRED FORMAT.        03420000
         BC    8,GTF4             NO. GO TO PROCESS CONTROL INFORMATION 03440000
*   FALL THRU TO DO REQUIRED FORMAT PROCESSING.                         03460000
         EJECT                                                          03480000
*********************************************************************** 03500000
**                                                                   ** 03520000
**             REQUIRED FORMAT PROCESSING.                           ** 03540000
**                                                                   ** 03560000
*********************************************************************** 03580000
*                                                                       03600000
*        R4 = ADDRESS OF CONTROL BYTE.                                  03620000
*                                                                       03640000
GTF2     DS    0H                                                       03660000
         CLR   R2,R5              ARE BOTH LENGTHS EQUAL (BUFF VS PDT). 03680000
         BNE   GTF1               NO. GO TO INCREMENT & TRY NEXT PATRN. 03700000
         LR    R1,R5              MOVE LENGTH TO R1.                    03720000
         BCTR  R1,0               DECREMENT LENGTH FOR COMPARE.         03740000
         EX    R1,GTCMP1          COMPARE PATTERN TO BUFFER.            03760000
         BE    GTH2               EQUAL. GO TO GET CONTROL INFO.        03780000
GTF1     DS    0H                 GET NEXT PATTERN.                     03800000
         AR    R6,R5              ADD LENGTH.                           03820000
         IC    R5,0(R4)                                                 03840000
         SRL   R5,4                                                     03860000
         AR    R6,R5              PLUS NBR OF CONTROL BYTES.            03880000
         LA    R6,1(R6,0)         PLUS ONE TO CNTR.                     03900000
         IC    R5,0(RE)                                                 03920000
         CLR   R6,R5              HAVE WE LOOKED AT ALL POSSIBILITIES   03940000
*                                      FOR THIS KEY.                    03960000
         BE    GTJ1               YES. GO TO PUT OUT ERRORMSG.          03980000
         LA    R4,0(R6,RE)        NO. POINT R4 AT NEXT CONTROL BYTE.    04000000
         B     GTF3               GO TO CHECK NEXT CONTROL INFORMATION. 04020000
         SPACE                                                          04040000
GTCMP1   CLC   1(1,R3),1(R4)      COMPARE PATTERN TO BUFFER. (EXECUTED) 04060000
         SPACE                                                          04080000
GTH2     DS    0H                                                       04100000
         SR    R1,R1                                                    04120000
         IC    R1,0(R4)           CONTROL INFO TO R1.                   04140000
         SRL   R1,4               DOES THE THIS PATTERN REQUIRE ANY     04160000
         LTR   R1,R1                   BIT SETTINGS, MOVES, ETC.        04180000
         BZ    GTJ4               NO. GO TO EXIT.                       04200000
         LA    R7,1(R5,R4)        YES. POINT R7 AT TABLE/FUNCTION BYTE. 04220000
         B     GTH4               GO TO PROCESS CONTROL INFO.           04240000
         SPACE 2                                                        04260000
*    ERROR MESSAGE 'PARAMETER MISSPELLED'.                              04280000
GTJ1     DS    0H                                                       04300000
         MVI   MSGSEC,GTERR2      SET ERROR MESSAGE CODE.               04320000
         B     GTG5               GO TO ERROR RETURN.                   04340000
         EJECT                                                          04360000
*********************************************************************** 04380000
**                                                                   ** 04400000
**             NON-REQUIRED FORMAT PROCESSING.                       ** 04420000
**                                                                   ** 04440000
*********************************************************************** 04460000
*                                                                       04480000
*        R4 = ADDRESS OF CONTROL BYTE.                                  04500000
*                                                                       04520000
GTF4     DS    0H                                                       04540000
         IC    R5,0(R4)           CONTROL INFO TO R5.                   04560000
         SRL   R5,4               DOES THIS PARAMETER REQUIRE ANY       04580000
         LTR   R5,R5                   BIT SETTINGS, MOVES, ETC.        04600000
         BZ    GTJ4               NO. GO TO EXIT.                       04620000
         IC    R5,1(R4)           MAX ALLOWABLE LENGTH TO R5.           04640000
         CLR   R2,R5              DOES THIS PARAMETER EXCEDE MAL.       04660000
         BH    GTF5               YES. GO TO PUT OUT ERROR CODE.        04680000
         LA    R7,2(R4)           NO. POINT R7 AT TABLE/FUNCTION BYTE.  04700000
GTH4     DS    0H                                                       04720000
         BAL   R5,GTSUB           GO TO PROCESS PARAMETERS.             04740000
*   FALL THROUGH TO EXIT.                                               04760000
         SPACE                                                          04780000
*                                                                       04800000
*   RETURN POINT FROM TEST AND STORE.                                   04820000
*                                                                       04840000
GTJ4     DS    0H                                                       04860000
         LM    RE,RC,12(RD)       RESTORE REGISTERS.                    04880000
         BR    RE                 RETURN.                               04900000
         SPACE 2                                                        04920000
GTF5     DS    0H                                                       04940000
*    ERROR MESSAGE 'PARAMETER EXCEDES MAXIMUM ALLOWABLE LENGTH'.        04960000
         MVI   MSGSEC,GTERR1      SET ERROR MESSAGE CODE.               04980000
GTG5     DS    0H                                                       05000000
         MVC   12(4,RD),TCLEANUP  MOVE CLEANUP ADDRESS TO R14 SLOT      05020000
*                                      IN REGISTER SAVE AREA.           05040000
         B     GTJ4               GO TO RESTORE REGS AND RETURN.        05060000
         SPACE                                                          05080000
*   ERROR MESSAGE 'TOO MANY PARAMETERS'.                                05100000
GTG5A    DS    0H                                                       05120000
         MVI   MSGSEC,GTERR6      SET ERROR MESSAGE CODE.               05140000
         B     GTG5               GO TO ERROR RETURN.                   05160000
         EJECT                                                          05180000
*********************************************************************** 05200000
**                                                                   ** 05220000
**             SUBROUTINE TO PROCESS PARAMETER DESCRIPTER TABLE.     ** 05240000
**                                                                   ** 05260000
*********************************************************************** 05280000
*        R2 = TLEN.                                                     05300000
*        R3 = TLENP.                                                    05320000
*        R4 = ADDRESS OF CONTROL BYTE.                                  05340000
*        R5 = RETURN ADDRESS.                                           05360000
*        R7 = ADDRESS OF TABLE/FUNCTION BYTE.  /FUNCTION:TABLE/         05380000
*        RE = CURRENT PDT ADDRESS.                                      05400000
         SPACE                                                          05420000
GTSUB    DS    0H                                                       05440000
         SR    R8,R8                                                    05460000
         IC    R8,0(R7)           PICK UP /FUNCT:TABLE/ BYTE.           05480000
         N     R8,GTMSK1          ZERO ALL BUT TABLE NBR.               05500000
         CL    R8,GTMSK1          IS TABLE THE IWA.                     05520000
         BE    GTSUB4             YES. GO TO SET R9=IWA ADDRESS.        05540000
         SLL   R8,1               MULTIPLY TABLE INDEX BY TWO.          05560000
         LH    R9,JEDSWS(R8)      PICK UP SCON OF TABLE.                05580000
         MVC   TSP3(2),GTMSK2     MOVE LA MASK TO WORK AREA.            05600000
         STH   R9,TSP3+2          STORE SCON FOR EXECUTION.             05620000
         EX    0,TSP3             LOAD ADDRESS INTO R9.                 05640000
GTSUB1   DS    0H                                                       05660000
         IC    R8,1(R7)           PICK UP OFFSET IN TABLE FROM PDT.     05680000
         AR    R9,R8              R9 NOW HAS ADDRESS WITHIN TABLE.      05700000
         SR    R6,R6                                                    05720000
         IC    R6,0(R7)           PICK UP /FUNCT:TABLE/ BYTE.           05740000
         SRL   R6,4               SHIFT TO GET FUNCT ONLY.              05760000
         SLL   R6,1               MULTIPLY BY TWO.                      05780000
         LH    R6,GTFUNCT(R6)     PICK UP RELATIVE ADDRESS OF FUNCT.    05800000
         AR    R6,RB              ACTUAL 360 ADDRESS.                   05820000
         SPACE                                                          05840000
         BALR  RF,R6              GO TO PROCESS.                        05860000
         SPACE 2                                                        05880000
*                                                                       05900000
*   CHECK TO SEE IF THIS PDT IS COMPLETED.                              05920000
*                                                                       05940000
         SR    RF,RF                                                    05960000
         SR    R6,R6                                                    05980000
         IC    R6,0(R4)           PICK UP CONTROL BYTE.                 06000000
         N     R6,GTMSK1          AND OUT NBR OF CONTROL BYTES AND GET  06020000
*                                      NBR OF BYTES FOR COMPARE ONLY.   06040000
         BC    8,GTSUB3           IF IT IS A NON-REQUIRED FORMAT PDT,   06060000
*                                      INCREMENT R6 TO ALLOW FOR THE    06080000
*                                      MAXIMUM ALLOWABLE LENGTH BYTE.   06100000
GTSUB2   DS    0H                                                       06120000
         IC    RF,0(R4)           GET CONTROL BYTE AGAIN.               06140000
         SRL   RF,4               GET NBR OF CONTROL BYTES ONLY.        06160000
         AR    R6,RF              ADD LENGTH.                           06180000
         LA    R6,1(R6,0)         INCREMENT BY ONE FOR CONTROL BYTE.    06200000
         LR    RF,R7              PUT NEXT FUNCT/TABLE BYTE ADDR OR     06220000
*                                      END OF PDT+1 ADDR INTO R15.      06240000
         SR    RF,R4              SUBTRACT ADDR OF CONTROL BYTE.        06260000
         CLR   RF,R6              HAVE WE COMPLETED THIS PDT.           06280000
         BNE   GTSUB              NO. GO TO PROCESS NEXT PARAM.         06300000
         BR    R5                 COMPLETED. RETURN.                    06320000
         SPACE                                                          06340000
GTSUB3   DS    0H                                                       06360000
         LA    R6,1(R6,0)         INCREMENT R6 BY ONE.                  06380000
         B     GTSUB2             RETURN.                               06400000
         SPACE                                                          06420000
GTSUB4   DS    0H                                                       06440000
         LR    R9,RC              SET R9 = IWA ADDRESS.                 06460000
         B     GTSUB1             RETURN.                               06480000
         EJECT                                                          06500000
*********************************************************************** 06520000
*                                                                     * 06540000
*              OR A BIT PATTERN.                                      * 06560000
*                                                                     * 06580000
*********************************************************************** 06600000
GTX0     DS    0H                                                       06620000
         OC    0(1,R9),2(R7)      OR 1 CHAR BIT PATTERN INTO TABLE.     06640000
         LA    R7,3(R7,0)         POINT R7 AT NEXT /FUNCT:TABLE/ BYTE.  06660000
         BR    RF                 RETURN.                               06680000
         EJECT                                                          06700000
*********************************************************************** 06720000
*                                                                     * 06740000
*              CONVERT TO BINARY                                      * 06760000
*                                                                     * 06780000
*********************************************************************** 06800000
GTX123   DS    0H                                                       06820000
         ST    RF,TSP3            SAVE R15.                             06840000
         SR    RF,RF              SET UP TO STORE VALID NBRS INTO       06860000
         LA    R1,TWORK+7              WORK AREA FOR CONVERT-TO-BINARY. 06880000
         XC    TWORK(8),TWORK     ZERO WORK AREA.                       06900000
         LR    R6,R2              SET UP R6 FOR VALID NUMERIC CHECK.    06920000
GTX123A  DS    0H                                                       06940000
         LA    R8,0(R6,R3)        ADDR OF NBR TO R8.                    06960000
         CLI   0(R8),C'0'         IS NBR LESS THAN ZERO.                06980000
         BL    GTX3ER                  YES. ERROR.                      07000000
         CLI   0(R8),C'9'         IS NBR GTR THAN NINE.                 07020000
         BH    GTX3ER                  YES. ERROR.                      07040000
         IC    RF,0(R6,R3)        PICK UP VALID NBR (RIGHT-TO-LEFT).    07060000
         STC   RF,0(R1)           STORE INTO WORK AREA. (RIGHT-TO-LEFT) 07080000
         BCTR  R1,0               DECREMENT POINTER FOR STORE.          07100000
         BCT   R6,GTX123A         DECREMENT INDEX FOR COMPARE & RETURN. 07120000
         SPACE                                                          07140000
         MVZ   TWORK+7(1),GTPLUS  IF ALL NBRS VALID, SET ZONE TO PLUS.  07160000
         PACK  TWORK(8),TWORK     PACK NBRS INTO FORMAT FOR CVB.        07180000
         CVB   R6,TWORK           CONVERT NBRS TO BINARY.               07200000
         ST    R6,TWORK           SAVE BINARY NBRS IN WORK SPACE.       07220000
         SPACE                                                          07240000
         SR    R6,R6                                                    07260000
         IC    R6,0(R7)           PICK UP FUNCT/TABLE BYTE AND          07280000
         SRL   R6,4                    SHIFT TO GET FUNCTION.           07300000
         BCTR  R6,0               DECREMENT FOR EXECUTE.                07320000
         XC    TWORK+4(4),TWORK+4 ZERO SECOND WORD OF WORK AREA.        07340000
         LA    R1,TWORK+7                                               07360000
         SR    R1,R6              R1 NOW HAS ADDRESS OF LEFT STORE POS. 07380000
         EX    R6,GTX3MVC1        MOVE MAXIMUM ALLOWABLE NBR INTO       07400000
*                                      WORK SPACE FOR COMPARE.          07420000
         CLC   TWORK(4),TWORK+4   COMPARE NBR PROCESSED WITH MAX.       07440000
         BH    GTX3ER1            IF HIGH GO TO ERROR.                  07460000
         LA    R1,TWORK+3                                               07480000
         SR    R1,R6              SET UP R1 FOR MOVE INTO TABLE.        07500000
         EX    R6,GTX3MVC2        MOVE NBR INTO TABLE.                  07520000
         LA    R7,3(R6,R7)        POINT R7 AT NEXT /FUNCT:TABLE/ BYTE.  07540000
         L     RF,TSP3            RESTORE R15.                          07560000
         BR    RF                 RETURN.                               07580000
         SPACE                                                          07600000
GTX3ER   DS    0H                                                       07620000
         MVI   MSGSEC,GTERR3      SET VERB CODE FOR INVALID NUMERICS.   07640000
         B     GTG5               GO TO ERROR RETURN.                   07660000
         SPACE                                                          07680000
GTX3ER1  DS    0H                                                       07700000
         MVI   MSGSEC,GTERR5      SET ERROR CODE FOR EXCEEDING MAXIMUM. 07720000
         B     GTG5               GO TO ERROR EXIT.                     07740000
         SPACE                                                          07760000
GTX3MVC1 MVC   0(1,R1),2(R7)      MOVE MAX NBR INTO WORK SPACE          07780000
GTX3MVC2 MVC   0(1,R9),0(R1)      MOVE NBR INTO TABLE.                  07800000
         EJECT                                                          07820000
*********************************************************************** 07840000
*                                                                     * 07860000
*              AND A BIT PATTERN.                                     * 07880000
*                                                                     * 07900000
*********************************************************************** 07920000
GTX4     DS    0H                                                       07940000
         NC    0(1,R9),2(R7)      AND 1 CHARAC BIT PATTERN INTO TABLE.  07960000
         LA    R7,3(R7,0)         POINT R7 AT NEXT /FUNCT:TABLE/ BYTE.  07980000
         BR    RF                 RETURN.                               08000000
         EJECT                                                          08020000
*********************************************************************** 08040000
*                                                                     * 08060000
*              MOVE CHARACTERS.                                       * 08080000
*                                                                     * 08100000
*********************************************************************** 08120000
GTX5     DS    0H                                                       08140000
         LR    R6,R2              DECREMENT LENGTH TO EXECUTE           08160000
         BCTR  R6,0                    MOVE INSTRUCTION.                08180000
         EX    R6,GTX5MV1         EXECUTE MOVE.                         08200000
         LA    R7,2(R7,0)         POINT R7 AT NEXT /FUNCT:TABLE/ BYTE.  08220000
         BR    RF                 RETURN.                               08240000
         SPACE                                                          08260000
GTX5MV1  MVC   0(1,R9),1(R3)      MOVE FROM INTERNAL TEXT BUFF TO TABLE 08280000
         EJECT                                                          08300000
*********************************************************************** 08320000
*                                                                     * 08340000
*              1ST CHARACTER ALPHA CHECK AND MVC.                     * 08360000
*        (TEST IS BASED ON THE FACT THAT ONLY ALPHA/NUMERIC CHARACTERS* 08380000
*              AND CERTAIN SPECIAL CHARACTERS IN DSNAME & PGM KEYWORDS* 08400000
*              ARE ALLOWED THROUGH THE SCAN ROUTINE).                 * 08420000
*                                                                     * 08440000
*********************************************************************** 08460000
GTX6     DS    0H                                                       08480000
         MVC   TWORK(1),1(R3)     MOVE 1ST CHARACTER TO WORK SPACE.     08500000
         NI    TWORK,X'F0'        ZERO LOW ORDER BITS.                  08520000
         XI    TWORK,C'0'         TEST FOR DIFFERENCE IN ZONE BITS.     08540000
         BC    8,GTERR4X          NUMERIC - ERROR.                  318 08560000
         CLI   1(R3),C'*'         ASTERISK.                         318 08580000
         BE    GTERR4X            YES - ERROR                       318 08600000
         CLI   1(R3),C'/'         SLASH.                            318 08620000
         BE    GTERR4X            YES - ERROR                       318 08640000
         CLI   1(R3),C'+'         PLUS.                             318 08660000
         BE    GTERR4X            YES - ERROR                       318 08680000
         CLI   1(R3),C'-'         MINUS.                            318 08700000
         BNE   GTX5               GOOD FIRST CHAR - GO MOVE NAME.   318 08720000
*                                                                       08740000
*   ERROR      -INVALID CHARACTER-                                      08760000
*                                                                       08780000
GTERR4X  DS    0H                                                       08800000
         MVI   MSGSEC,GTERR4      SET ERROR MESSAGE CODE.               08820000
         B     GTG5               GO TO ERROR EXIT.                     08840000
         EJECT                                                          08860000
*********************************************************************** 08880000
*                                                                     * 08900000
*              CHECK FOR ALPHA/NUMERIC CHARACTER.                     * 08920000
*                                                                     * 08940000
*   NOTE. SCAN ALLOWS THREE INTERNATIONAL CHARACTERS TO PASS WHICH    * 08960000
*        MAY BE INVALID IN SOME CASES.                                * 08980000
*                                                                     * 09000000
*********************************************************************** 09020000
*                                                                     * 09040000
GTX7     DS    0H                                                       09060000
         CLI   1(R3),C'$'         CHECK FOR DOLLAR SIGN.                09080000
         BE    GTERR7X            ERROR-INVALID CLASS DESIGNATION       09100000
         CLI   1(R3),C'#'         CHECK FOR POUND SIGN.                 09120000
         BE    GTERR7X            ERROR - INVALID CLASS DESIGNATION.    09140000
         CLI   1(R3),C'@'         CHECK FOR AT SIGN.                    09160000
         BE    GTERR7X            ERROR - INVALID CLASS DESIGNATION.    09180000
         LA    R7,1(R7,0)         POINT TO NEXT FUNCT/TABLE BYTE.       09200000
         BR    RF                 RETURN.                               09220000
         SPACE 2                                                        09240000
GTERR7X  DS    0H                                                       09260000
         MVI   MSGSEC,GTERR7      SET ERROR MSG.                        09280000
         B     GTG5               GO TO ERROR EXIT.                     09300000
         EJECT                                                          09320000
*********************************************************************** 09340000
*                                                                     * 09360000
*        CONSTANTS AND TABLES FOR TEST AND STORE ROUTINE.             * 09380000
*                                                                     * 09400000
*********************************************************************** 09420000
GTMSK1   DS    0F                                                       09440000
         DC    XL4'0000000F'                                            09460000
GTMSK2   DC    XL2'4190'          MASK FOR LOAD ADDRESS INTO R9.        09480000
GTPLUS   DC    X'C0'                                                    09500000
         SPACE 2                                                        09520000
*                                                                       09540000
*   TABLE OF FUNCTION ADDRESSES WITHIN TEST AND STORE.                  09560000
*                                                                       09580000
         DS    0H                                                       09600000
GTFUNCT  EQU   *                                                        09620000
         DC    AL2(GTX0-GTBASE)   OR.                                   09640000
         DC    AL2(GTX123-GTBASE) CVB AND MVC (1).                      09660000
         DC    AL2(GTX123-GTBASE) CVB AND MVC (2).                      09680000
         DC    AL2(GTX123-GTBASE) CVB AND MVC (3).                      09700000
         DC    AL2(GTX4-GTBASE)   AND.                                  09720000
         DC    AL2(GTX5-GTBASE)   MVC.                                  09740000
         DC    AL2(GTX6-GTBASE)   1ST CHARACTER ALPHA CHECK & MVC.      09760000
         DC    AL2(GTX7-GTBASE)   ALPHA/NUMERIC CHARACTER CHECK.        09780000
         END                                                            09800000
