         START                                                          01000015
 TITLE 'IEFVHHB  JOB AND STEP ENQUEUE HOUSEKEEPING ROUTINE'             02000015
*********************************************************************** 03000015
*TITLE - IEFVHHB                                                      * 04000015
*                                                                     * 05000015
*STATUS - CHANGE LEVEL IS 000                                         * 06000015
*                                                                     * 07000015
*FUNCTION - THIS MODULE CLEARS THE IWA JCT SPACE, HOUSEKEEPS          * 08000015
*           FLAGS AND SETS UP PARMLIST PTR AND STMT PTR REGS.         * 09000015
*                                                                     * 10000015
*INPUT - REG 12 - IWA PTR, REG 13 - REG SAVE AREA PTR.                * 11000015
*                                                                     * 12000015
*OUTPUT - REG 9 - STMT PTR, REG 10 - STMT PARMLIST PTR,               * 13000015
*         REG 13 - REG SAVE AREA PTR.                                 * 14000015
*                                                                     * 15000015
*EXTERNAL ROUTINES - NONE                                             * 16000015
*                                                                     * 17000015
*EXITS - 1. READER NULL STMT RECEIVED EXIT TO IEFVHA.                 * 18000015
*        2. STMT TO BE PROCESSED EXIT TO IEFVHEB.                     * 19000015
*                                                                     * 20000015
*TABLES/WORK AREA - IWA                                               * 21000015
*                                                                     * 22000015
*ATTRIBUTES - READ ONLY REENTRANT                                     * 23000015
*                                                                     * 24000015
*OPERATION - THIS MODULE CLEARS THE JCT SPACE IN THE IWA IF THE       * 25000015
*            JCT-TO-ENQUEUE FLAG IS ON, DETERMINES IF THE PROC        * 26000015
*            IS BEING ACCESSED AND IF SO SET UP STMT PARMLIST         * 27000015
*            AND STMT PTR REGS FOR PRE-SCAN ROUTINE (IEFVHCB).        * 28000015
*            IF THE PROC IS NOT BEING ACCESSED AND A NULL STMT        * 29000015
*            HAS BEEN RECEIVED, THE JOB-TO-PROCESS FLAG IS            * 30000015
*            CLEARED AND CONTROL PASSED TO IEFVHA. OTHERWISE,         * 31000015
*            THE SYSIN STMT PARMLIST PTR AND STMT PTR REGS            * 32000015
*            ARE SET UP FOR EXIT TO IEFVHEB.                          * 33000015
*                                                                     * 34000015
*REGISTER USAGE - REG 9 - STMT PTR, REG 10 - STMT PARMLIST PTR,       * 35000015
*                 REG 11 - BASE, REG 12 - IWA PTR,                    * 36000015
*                 REG 13 - REG SAVE AREA PTR.                         * 37000015
*                                                                     * 38000015
*NOTES - NONE                                                         * 39000015
*********************************************************************** 40000015
*        IEFVHHB  JOB & STEP ENQUEUE HOUSEKEEPING                       41000015
         IEFVMIWA                                                       42000015
IEFVHHB  CSECT                                                          43000015
*              RC = PTR TO IWA                                          44000015
*              RD = PTR TO CURRENT REG. SAVE AREA                       45000015
         BALR  RB,0                                                     46000015
         USING *,RB                                                     47000015
         B     HB                                                       48000015
         DC    X'7277'             DATE 10/4/67                         49000015
         DC    4X'11'              MODULE IDENT.                        50000015
         DC    C'HHB'                                                   51000015
HB       DS    0H                                                       52000015
         TM    SWA,JCTTQ           Q. JCT TO BE PUT TO Q                53000015
         BZ    HB2                  BR - NO                             54000015
         XC    JCT,JCT             CLEAR JCT SPACE IN IWA               55000015
HB2      DS    0H                                                       56000015
         NI    SWA,255-SCTTQ-JCTTQ CLEAR SCT & JCT TO Q FLAGS           57000015
         TM    SWE,GPI             Q. ACCESSING PROC LIB                58000015
         BO    HB4                  BR - YES                            59000015
         TM    SWC,NRCV            Q. PROCESSING RDR NULL STMT          60000015
         BO    HB8                  BR - YES                            61000015
         LA    RA,RSTMT            LOAD ADDR OF RDR STMT PARMLIST       62000015
         B     HB6                                                      63000015
HB4      DS    0H                                                       64000015
         LA    RA,PSTMT            LOAD ADDR OF PROC STMT PARMLIST      65000015
HB6      DS    0H                                                       66000015
         L     R9,0(0,RA)          LOAD STMT PTR                        67000015
         L     RF,IEFVHEB          EXIT TO PRE-SCAN ROUTINE             68000015
         BR    RF                                                       69000015
HB8      DS    0H                                                       70000015
         NI    SWA,255-JTOP        CLEAR JOB-TO-PROCESS FLAG            71000015
         L     RF,IEFVHA           EXIT TO GET ROUTINE                  72000015
         BR    RF                                                       73000015
         SPACE                                                          74000015
IEFVHEB  DC    V(IEFVHEB)          PRE-SCAN ROUTINE ADDR                75000015
IEFVHA   DC    V(IEFVHA)           GET ROUTINE ADDR                     76000015
         END                                                            77000015
