*********************************************************************** 00100019
*                                                                     * 00200019
* TITLE:  IEFVINA                                                     * 00300019
*                                                                     * 00400019
*                                                                     * 00500019
* FUNCTION:  THIS MODULE ACTS AS THE ROUTING ROUTINE FOR IN-LINE      * 00600019
*            PROCEDURES.  IT GETS CORE FOR A PARAMETER LIST (24 BYTES * 00700019
*            AND INITIALIZES IT FOR VARIOUS ROUTINES AND FOR A QMPA   * 00800019
*            AND EXTERNAL PARAMETER LIST.  BOTH PARAMETER LIST AND    * 00900019
*            QMPA ARE FREED BEFORE EXIT FROM THE MODULE.              * 01000019
*                                                                     * 01100019
*            THE MODULE CONSISTS OF A MAIN FLOW AND FIVE SUBROUTINES, * 01200019
*            ONE OF WHICH CONTAINS AN INTERNAL SUBROUTINE.            * 01300019
*                                                                     * 01400019
*            VINAPARM:  THIS SUBROUTINE GETS CORE FOR THE PARAMETER   * 01500019
*            LIST AND INITIALIZES IT FOR IEFVINB AND/OR IEFVINC.        01600019
*                                                                     * 01700019
*            VINAERR:  THIS SUBROUTINE HANDLES ERROR CONDITIONS       * 01800019
*            AND UTILIZES THE INTERNAL SUBROUTINE VINAMSG1 TO CREATE  * 01900019
*            AN SMB FOR THE ERROR STATEMENT AND THE ERROR MESSAGE.    * 02000019
*            THE ERROR MESSAGES ARE AS FOLLOWS:                       * 02100019
*            IEF662I INVALID LABEL ON THE PROC STATEMENT              * 02200019
*            IEF662I INVALID LABEL ON THE PEND STATEMENT              * 02300019
*            IEF663I NO LABEL ON THE PROC STATEMENT                   * 02400019
*            IEF664I MISSING DELIMITER ON COMMENTS FIELD ON THE PEND  * 02500019
*            STATEMENT                                                * 02600019
*            IEF664I MISSING DELIMITER ON COMMENTS FIELD ON THE PROC  * 02700019
*            STATEMENT                                                * 02800019
*            IEF665I EXCESSIVE NUMBER OF IN-LINE PROCEDURES           * 02900019
*                                                                     * 03000019
*            THE JOB FAILED BIT IS SET ON THE JCT AND CONTROL IS      * 03100019
*            TRANSFERRED TO IEFVHA (PROC) OR THE COMPRESS SUBROUTINE  * 03200019
*            (PEND) TO GET ANOTHER RECORD                             * 03300019
*                                                                     * 03400019
*            VINACONT:  THIS SUBROUTINE PROCESSES THE PROC OR PEND    * 03500019
*            STATEMENT WHICH IS TO BE CONTINUED.  IT SETS A HIGH      * 03600019
*            ORDER BIT TO INDICATE THAT THIS IS A CONTINUED STATEMENT * 03700019
*            AND BRANCHES TO THE SYNTAX SUBROUTINE, VINASYNT.         * 03800019
*                                                                     * 03900019
*            VINAMSG:  THIS ROUTINE UTILIZES AN INTERNAL ROUTINE,     * 04000019
*            VINAMSG1 TO CREATE AN SMB FOR THE STATEMENT IF ONE IS    * 04100019
*            NEEDED.  IT BUILDS A PARAMETER LIST FOR IEZNCODE AND     * 04200019
*            USES IEZNCODE TO COMPRESS THE RECORD.  IT USES IEFVHQ AND  04300019
*            THE QUEUE MANAGER TO ASSIGN AND WRITE RECORDS TO THE     * 04400019
*            JOB QUEUE.                                               * 04500019
*                                                                     * 04600019
*            VINASYNT:  THIS SUBROUTINE BRANCHES TO IEFVINE TO        * 04700019
*            SYNTAX CHECK THE PROC AND PEND STATEMENTS.  IT TESTS FOR * 04800019
*            COMMON ERROR CONDITIONS.  INVALID LABEL AND DELIMITER    * 04900019
*            ERRORS IN THE COMMENTS FIELD.                            * 05000019
*                                                                     * 05100019
*                                                                     * 05200019
* ENTRY POINT:  IEFVINA                                               * 05300019
*                                                                     * 05400019
*                                                                     * 05500019
* INPUT:  RC-ADDRESS OF THE IWA                                       * 05600019
*         RD-ADDRESS OF A SAVE AREA                                   * 05700019
*         IWAWKBF-A WORD IN THE IWA POINTS TO A 352 BYTE WORK AREA    * 05800019
*         WHICH CONSISTS OF A 176 BYTE WORK AREA AND A 176 BYTE       * 05900019
*         DIRECTORY                                                   * 06000019
*         THE WORKAREA IS MAPPED IN THE DSECT, WORKAREA               * 06100019
*                                                                     * 06200019
*                                                                     * 06300019
* EXITS:  IEFVHA-WHEN A PEND STATEMENT IS ENCOUNTERED                 * 06400019
*                WHEN AN ERROR OCCURS ON THE PROC OR PEND STATEMENT   * 06500019
*         IEFVHCB-WHEN A JOB STATEMENT IS ENCOUNTERED                 * 06600019
*                 WHEN A NULL STATEMENT IS ENCOUNTERED          A39900* 06650020
*                                                                     * 06700019
*                                                                     * 06800019
* OUTPUT:  IWAPARM-A WORD IN THE IWA WHICH CONTAINS THE ADDRESS OF    * 06900019
*          A 24 BYTE PARAMETER LIST                                   * 07000019
*                                                                     * 07100019
*                                                                     * 07200019
* INTERNAL EXISTS:  IEFVHQ-ASSIGN/START, ASSIGN, WRITE                * 07300019
*                   IEFVINB-SEARCHES THE DIRECTORY FOR A DUPLICATE    * 07400019
*                   ENTRY                                             * 07500019
*                   IEFVINC-BUILDS AN ENTRY IN THE DIRECTORY          * 07600019
*                   IEFVINE-SYNTAX CHECKS THE PROC AND PEND STATEMENTS  07700019
*                   IEFVGM-CREATES AN SMB FOR THE INPUT STATEMENT OR  * 07800019
*                   OR FOR AN ERROR STATEMENT.                        * 07900019
*                   IEZNCODE-COMPRESSES THE RECORD                    * 08000019
*                                                                     * 08100019
*                                                                     * 08200019
* INPUT FOR INTERNAL ROUTINES:                                        * 08300019
*                                                                     * 08400019
*        IEFVINB AND IEFVINC                                          * 08500019
*        R1 POINTS TO A 24 BYTE PARAMETER LIST                        * 08600019
*        ADDRESS-ADDRESS OF THE PARAMETER LIST                        * 08700019
*        PROCEDURE-PROCEDURE NAME                                     * 08800019
*        DIRECT-ADDRESS OF THE DIRECTORY                              * 08900019
*        IWAPT-ADDRESS OF THE IWA                                     * 09000019
*        RTCD-RETURN CODE                                             * 09100019
*                                                                     * 09200019
*        IEFVINE                                                      * 09300019
*        R1 POINTS TO THE BSAM INPUT BUFFER                           * 09400019
*                                                                     * 09500019
*        IEFVGM                                                       * 09600019
*        FOR THE SMB FOR AN ERROR MESSAGE                             * 09700019
*        R2 CONTAINS THE PRIMARY MESSAGE CODE                         * 09800019
*        MSGKEY CONTAINS THE SECONDARY MESSAGE CODE                   * 09900019
*                                                                     * 10000019
*        FOR AN SMB FOR AN INPUT STTMENT                              * 10100019
*        R2 CONTAINS A ZERO                                           * 10200019
*        R9 POINTS TO THE BPAM INPUT BUFFER                  M3739O106* 10300019
*        IEZNCODE                                                     * 10400019
*        R1 POINTS TO A PARAMETER LIST                                * 10500019
*        IEZUNCOM - ADDRESS OF BPAM INPUT BUFFER             M3739O106* 10600019
*        IEZCOMPR-ADDRESS OF THE OUTPUT BUFFER                        * 10700019
*        IEZLEN - LENGTH OF BPAM INPUT BUFFER(80)            M3739O106* 10800019
*        IEZOUT-LENGTH OF THE OUTPUT BUFFER (168)                     * 10900019
*        IEZCHAR-X'40' TO INDICATE BLANKS ARE TO BE REMOVED           * 11000019
*        IEZTYPE-X'00' TO INDICATE NO SPECIAL RECORD                  * 11100019
*                                                                     * 11200019
*                                                                     * 11300019
* WORKAREAS AND/OR TABLES:                                            * 11400019
*        IEFVMIWA-INTERPRETER WORK AREA                               * 11500019
*        IEFVMEWA-EXECUTE CONTROL WORK AREA                           * 11600019
*        IEFAJCTB-JOB CONTROL TABLE                                   * 11700019
*        IEFQMNGR-QUEUE MANAGER PARAMETER AREA                        * 11800019
*        WORKAREA-IN-LINE PROCEDURE WORK AREA                         * 11900019
*        IEZPARM-PARAMETER LISTS                                      * 12000019
*                                                                     * 12100019
* REGISTER USEAGE;                                                    * 12200019
*        R6-QMPA ADDRESSIBILITY                                       * 12300019
*        R7-WORK AREA ADDRESSIBILITY                                  * 12400019
*        R8-JCT ADDRESSIBILITY                                        * 12500019
*        RA-EWA ADDRESSIBILITY                                        * 12600019
*        RB-MODULE ADDRESSIBILITY                                     * 12700019
*        RC-ADDRESS OF THE IWA                                        * 12800019
*        RD-POINTER TO THE SAVE AREA                                  * 12900019
*                                                                     * 13000019
* MACROS USED:                                                        * 13100019
*        IEFSAVER                                                     * 13200019
*        SAVE                                                         * 13300019
*        IEFRELSE                                                     * 13400019
*        GET                                                          * 13500019
*        FREEMAIN                                                     * 13600019
*        XCTL                                                         * 13700019
*        GETMAIN                                                      * 13800019
* OPERATION:  .ADDRESSIBILITY IS ESTABLISHED FOR THE WORK AREA, THE   * 13900019
*              QMPA, THE JCT AND THE MODULE                           * 14000019
*             .A SAVE AREA IS GOTTEN                                  * 14100019
*             . MSGKEY IS STORED FOR THE PROC VERB                    * 14200019
*             .VINASYNT SUBROUTINE IS EXECUTED                        * 14300019
*             .CHECK MADE FOR NO PROCEDURE NAME                       * 14400019
*             . IF AN ERROR EXISTS, CONTROL IS PASSED TO VINAERR TO   * 14500019
*              CREATE AN SMB FOR THE STATEMENT AND THE ERROR MSG      * 14600019
*             .IF NO ERROR EXISTS, THE LENGTH OF THE PROCEDURE NAME   * 14700019
*              IS SAVED                                               * 14800019
*             .A CHECK IS MADE TO SEE IF THIS IS A FIRST IN-LINE      * 14900019
*              PROCEDURE                                              * 15000019
*             .IF IT IS NOT, A PARM LIST IS MADE FOR IEFVINB AND      * 15100019
*              CONTROL IS PASSEDTO IEFVINB TO SEARCH THE DIRECTORY    * 15200019
*              CONTROL IS THEN PASSED TO IEFVINC                      * 15300019
*             . IF THE COUTN FIELD IN THE WORK AREA IS ONE, INDICATING  15400019
*              THAT THIS IS THE FIRST IN-LINE PROCEDURE, THE QMPA IS  * 15500019
*              INITIALIZED AND AN ASSIGN/START DONE.                  * 15600019
*             .A PARM LIST IS GOTTEN AND BUILT FOR IEFVINC AND CONTROL  15700019
*              IS TRANSFERRED TO BUILD A DIRECTORY ENTRY.             * 15800019
*             .A CHECK IS MADE TO SEE IF TOO MANY PROCEDURES WERE     * 15900019
*              ALREADY ENCOUNTEREE.                                   * 16000019
*             . IF THEY WERE, CONTROL IS TRANSFERRED TO VINAERR TO    * 16100019
*              CREATE AN SMB FOR THE ERROR MESSAGE                    * 16200019
*             . THE NEXT STATEMNET IS READ AND TESTED FOR A PEND OR   * 16300019
*              JOB VERB                                               * 16400019
*             .IF IT IS NEITHER AN SMB IS CREATED IF IT IS NEEDED     * 16500019
*              THE RECORD IS COMPRESSED AND IF NECESSARY WRITTEN TO   * 16600019
*              JOB QUEUE.  ANOTHER RECORD IS READ                     * 16700019
*             .IF IT IS A PEND STATEMENT THE PARAMETER LIST AND SAVE  * 16800019
*              AREA ARE FREED AND AN XCTL ISSUED TO IEFVHA            * 16900019
*             .IF IT IS A JOB STATEMENT OR A NULL STATEMENT, THEA39900* 17000020
*               PARAMETER LIST AND SAVE AREA ARE FREED AND AN   A39900* 17060020
*               XCTL ISSUED TO IEFVHCB                          A39900* 17070020
*                                                                     * 17200019
*********************************************************************** 17300019
         EJECT                                                          17400019
         IEFVMIWA                                                       17500019
         EJECT                                                          17600019
         IEFVMEWA                                                       17700019
         EJECT                                                          17800019
JAJCT    DSECT                                                          17900019
         IEFAJCTB                                                       18000019
         EJECT                                                          18100019
         IEFQMNGR                                                       18200019
QMPADDR  DS    CL4                     ADDRESS OF WORK BUFFER           18300019
QMPATTR  DS    CL3                     TTR OF JOB QUEUE RECORD          18400019
QMPAZER  DS    CL1  N                  RESERVED FIELD                   18500019
         DCBD  DSORG=(PS)                                               18520019
         EJECT                                                          18540019
         IEFVKEYS                                                       18560019
         EJECT                                                          18580019
         EJECT                                                          18600019
WORKAREA DSECT                                                          18700019
         USING WORKAREA,R7                                              18800019
WKTTR    DS    CL4                     POINTER TO NEXT RECORD           18900019
WKQMPAPT DS    CL4                     ADDRESS OF QMPA                  19000019
WKRECORD DS    CL168                   COMPRESSED RECORD                19100019
WKPTR1   DS    CL4                     POINTER TO ITSELF                19200019
WKCT     DS    CL1                     NUMBER OF ENTRIES MADE IN        19300019
WKPTR2   DS    CL3                     HOLDER FOR TTR ASSIGNED FROM     19400019
*                                      THE QUEUE MANAGER          O106  19500019
WKPROCN1 DS    CL8                     PROCEDURE NAME                   19600019
WKTTR1   DS    CL3                     TTR OF FIRST RECORD              19700019
WKPROCN2 DS    CL8                     PROCEDURE NAME                   19800019
WKTTR2   DS    CL3                     TTR OF FIRST RECORD              19900019
WKPROCN3 DS    CL8                     PROCEDURE NAME                   20000019
WKTTR3   DS    CL3                     TTR OF FIRST RECORD              20100019
WKPROCN4 DS    CL8                     PROCEDURE NAME                   20200019
WKTTR4   DS    CL3                     TTR OF FIRST RECORD              20300019
WKPROCN5 DS    CL8                     PROCEDURE NAME                   20400019
WKTTR5   DS    CL3                     TTR OF FIRST RECORD              20500019
WKPROCN6 DS    CL8                     PROCEDURE NAME                   20600019
WKTTR6   DS    CL3                     TTR OF FIRST RECORD              20700019
WKPROCN7 DS    CL8                     PROCEDURE NAME                   20800019
WKTTR7   DS    CL3                     TTR OF FIRST RECORD              20900019
WKPROCN8 DS    CL8                     PROCEDURE NAME                   21000019
WKTTR8   DS    CL3                     TTR OF FIRST RECORD              21100019
WKPROCN9 DS    CL8                     PROCEDURE NAME                   21200019
WKTTR9   DS    CL3                     TTR OF FIRST RECORD              21300019
WKPROCNA DS    CL8                     PROCEDURE NAME                   21400019
WKTTRA   DS    CL3                     TTR OF FIRST RECORD              21500019
WKPROCNB DS    CL8                     PROCEDURE NAME                   21600019
WKTTRB   DS    CL3                     TTR OF FIRST RECORD              21700019
WKPROCNC DS    CL8                     PROCEDURE NAME                   21800019
WKTTRC   DS    CL3                     TTR OF FIRST RECORD              21900019
WKPROCND DS    CL8                     PROCEDURE NAME                   22000019
WKTTRD   DS    CL3                     TTR OF FIRST RECORD              22100019
WKPROCNE DS    CL8                     PROCEDURE NAME                   22200019
WKTTRE   DS    CL3                     TTR OF FIRST RECORD              22300019
WKPROCNF DS    CL8                     PROCEDURE NAME                   22400019
WKTTRF   DS    CL3                     TTR OF FIRST RECORD              22500019
         EJECT                                                          22530019
         IEFNEL EXITS=SMF                                               22560019
         EJECT                                                          22600019
IEZPARM  DSECT                         PARAMETER AREA                   22700019
         USING IEZPARM,R1                                               22800019
IEZADDR  DS    CL4                     ADDRESS OF PARAMETER LIST        22900019
IEZUNCOM DS    A                       PTR TO UNCOMPRESSED RECORD       23000019
IEZCOMPR DS    A                       PTR TO NEXT COMPRESSED RECORD    23100019
IEZLEN   DS    H                       LENGTH OF UNCOMPRESSED RECORD    23200019
IEZOUT   DS    H                       LENGTH OF AREA FOR OUTPUT RECORD 23300019
IEZCHAR  DS    C                       CHARACTER CODE OF BLANK          23400019
IEZTYPE  DS    B                       FLAG ASSOCIATED WITH RECORD      23500019
IEZRES   DS    H                       WORK AREA                        23600019
         ORG IEZADDR                                                    23700019
ADDSS    DS    CL4                     ADDRESS OF PARAMETER LIST        23800019
PROCNAME DS    CL8                     PROCEDURE NAME                   23900019
DIRECT   DS    CL4                     ADDRESS OF DIRECTORY             24000019
IWAPTR   DS    CL4                     ADDRESS OF IWA                   24100019
RTCD     DS    CL4                     RETURN CODE FROM VINB            24200019
         EJECT                                                          24300019
IEFVINA  CSECT                                                          24400019
* A 353500-355900,C 356000, A 815500                             A52677 24401021
*A785000                                                         A49933 24402021
* 339600                                                         A39049 24410020
*A-532100-532920,C-066500,170000-170700,348600                   A39900 24410120
* 542000,623000                                                  A34832 24420020
* 335000,867000                                                  A35012 24425020
* 337000                                                         A35013 24430020
* A 505100-505200                                                 M1867 24432021
* C 413500                                                       A40299 24440021
* A 395500-395700,414500-414800,456000,505500-505900             A40299 24442021
* C 554110 A 554626-554632                                       A52632 24444021
* 481000-482000                                                   M4268 24450019
         SAVE (14,12)                                                   24500019
         BALR  RB,0                                                     24600019
         USING *,RB                                                     24700019
         B     VINA000                                                  24800019
         SPACE                                                          24900019
         DC    X'11111111'                                              25000019
         DC    C'VINA'                                                  25100019
         DC    C'L.01'                                                  25200019
         SPACE                                                          25300019
VINA000  DS    0H                                                       25400019
         L     R7,IWAWKBF              ADDRESSIBILITY FOR WORK AREA     25500019
         L     R8,CSCBP                ADDRESS OF NEL              3391 25510019
         USING NELLIST,R8                                               25520019
         L     R6,NELOPLST             ADDRESS OF OPTION LIST      3391 25530019
         USING NELOPLEN,R6                                              25540019
         TM    NELSYS,NELPCP           IS THIS PCP?                3391 25550019
         BO    VINA00A                 YES, USE R/I QMPA           3391 25560019
         DROP  R6                                                       25570019
         DROP  R8                                                       25580019
         L     R6,WKQMPAPT             ADDRESS OF IN-STREAM QMPA   3391 25590019
         B     VINA00B                 ESTABLISH ADDRESSIBILITY FOR3391 25600019
*                                      QMPA                        3391 25610019
VINA00A  DS    0H                                                  3391 25620019
         L     R6,QPARMP               ADDRESS OF R/I QMPA         3391 25630019
VINA00B  DS    0H                                                  3391 25640019
         USING IOPARAMS,R6             FOR QMPA                         25650019
         SPACE                                                          25800019
         LA    R8,JCT                  ADDRESSIBILITY                   25900019
         USING JAJCT,R8                  FOR JCT                        26000019
         SPACE                                                          26100019
         IEFSAVER                                                       26200019
         L     R3,PDCBP                ADDRESS OF PROC DCB        19093 26210019
         USING IHADCB,R3                                                26220019
*                                                             M3739O106 26226019
         MVC   IWABPAM(MVTHREE),DCBREAD+DISPLONE SAVE ADDR OF BPAM O106 26232019
         L     R3,RDCBP                ADDRESS OF READER DCB      19093 26240019
         XR    R4,R4                                                    26243019
         IC    R4,DCBEODAD             SAVE BFTEK PARM             3168 26246019
         LA    R2,VINAEOF               ADDRESS OF EODAD ROUTINE  19093 26250019
         ST    R2,DCBEODAD              ADDRESS OF EODAD ROUTINE  19093 26260019
         STC   R4,DCBEODAD             BFTEK PARM                  3168 26263019
         IC    R4,DCBSYNAD             LENGTH OF IOB               3168 26266019
         LA    R2,VINASYND              ADDRESS OF SYNAD ROUTINE  19093 26270019
         ST    R2,DCBSYNAD             ADDRESS OF SYNAD ROUTINE   19093 26280019
         STC   R4,DCBSYNAD             LENGTH OF IOB               3168 26285019
         DROP  R3                                                       26290019
         SPACE                                                          26300019
**********************************************************************  26400019
*                                                                    *  26500019
* SYNTAX CHECK PROC AND PEND STATEMENTS                              *  26600019
*                                                                    *  26700019
**********************************************************************  26800019
         SPACE                                                          26900019
         L     RA,CTRLWAP              ADDRESS OF CONTROL AREA          27000019
         MVI   MSGKEY,INTKEY3          SECONDARY MSG IF NEEDED     4360 27100019
         BAL   R2,VINASYNT             SYNTAX CHECKER                   27200019
         SPACE                                                          27300019
         LTR   R4,R4                   TEST FOR EXISTENCE OF PROC NAME  27400019
         BZ    VINAERR                 NO PROC NAME                     27500019
VINA010  DS    0H                                                 4329  27550019
         LR    R3,R4                   LENGTH OF PROC NME               27620019
         BCTR  R3,R0                   DECREMENT FOR MOVE               27700019
         CLI   WKCT,NOENTRY            SEE IF THIS IS THE               27800019
         BNE   VINA130                 IN-LINE PROCEDURE                27900019
         LA    R1,QPARM                ADDRESS OF R/I QMPA         3391 27910019
         CR    R1,R6                   IS THIS PCP?                3391 27920019
         BNE   VINA020                 NO, ISSUE ASSIGN/START      3391 27930019
         MVI   QMPOP,QMASGN            SET FUNCTION BYTE TO ASSIGN 3391 27940019
         L     R5,RSTMT                ADDRESS OF READER BUFFER    3391 27950019
         B     VINA025                 ISSUE AN ASSIGN             3391 27960019
         SPACE                                                          28000019
**********************************************************************  28100019
*                                                                    *  28200019
* INITIALIZE CORE FOR THE QMPA AND DO ASSIGN/START                   *  28300019
*                                                                    *  28400019
**********************************************************************  28500019
         SPACE                                                          28600019
VINA020  DS    0H                                                  3391 28660019
         MVI   QMNAM,INITBLK           BLANK OUT                        28720019
         MVC   QMNAM+DISPLONE(MVSEVEN),QMNAM      NAME FIELD            28800019
         OI    QMPOP,QMASGS            ASSIGN/START                     29000019
         MVI   QMTPY,QMSYSOUT          DEQUEUE TYPE                     29100019
         L     R5,RSTMT                ADDRESS OF INPUT BUFFER          29200019
         EX    R3,VINAMOVE             MOVE IN PROCEDURE NAME           29300019
         LA    R1,QMPADDR              ADDRESS OF EXTERNAL PARM LIST    29400019
         ST    R1,QMPCL                ADDRESS OF EXTERNAL PARAMETER    29500019
*                                      LIST                             29600019
VINA025  DS    0H                                                  3391 29650019
         MVI   QMPCM,ASSIGN1           NUMBER OF RECORDS TO ASSIGN      29700019
         ST    R6,QPARMP               IN LINE PROCEDURE QMPA ADDRESS   29800019
         L     RF,VIEFVHQ              Q MANAGER INTERFACE              29900019
         BALR  RE,RF                                                    30000019
         LA    R1,QPARM                ADDRESS OF QMPA (R/I)            30100019
         ST    R1,QPARMP               REPLACE IN-LINE PROC QMPA PTR    30200019
         L     R1,QMPCL                ADDR OF EXTERNAL PARM LIST  3391 30260019
         MVC   WKPTR1+DISPLONE(MVTHREE),DISPLZER(R1)   TTR RETURNED3391 30320019
         SPACE                                                          30400019
         BAL   R2,VINAPARM             GET CORE FOR PARM LIST, ESTAB-   30500019
         XC    RTCD(MVFOUR),RTCD       RETURN CODE FOR IEFVINB          30600019
         SPACE                                                          30700019
VINA030  DS    0H                                                       30800019
*                                      LIST ADDRESSIBILITY FOR DSECT,   30900019
*                                      BUILD PARM LIST FOR VINB AND/OR  31000019
*                                      VINC                             31100019
         ST    R6,QPARMP               REPLACE R/I QMPA PTR             31200019
         L     RF,VIEFVINC             DIRECTORY BUILD ROUTINE          31300019
         BALR  RE,RF                                                    31400019
         LA    R1,QPARM                ADDRESS OF QMPA (R/I)            31500019
         ST    R1,QPARMP               REPLACE IN-LINE PROC QMPA PTR    31600019
         L     R1,IWAPARM              ADDRESS OF PARM LIST             31700019
         L     RF,RTCD                 RETURN CODE FROM IEFVINC         31800019
         LTR   RF,RF                   EXCESSIVE NAMBER OF              31900019
         BNE   VINAERR3                IN-LINE PROCEDURES               32000019
         BAL   R4,VINAMSG              CREATE AN SMB IF NECESSARY       32400019
         SPACE                                                          32800019
VINA040  DS    0H                                                       32900019
         NI    SWZ,X'FF'-CMT           INITIALIZE COMMENT SWITCH F39049 32950020
         L     R1,RDCBP                ADDRESS OF READER DCB            33000019
         GET   (1)                                                      33100019
         ST    R1,RSTMT               SAVE ADDR OF INPUT BUFFER  A34832 33110020
         SPACE                                                          33130019
VINA043  DS    0H                                                  3156 33160019
         L     R1,RSTMT                ADDRESS OF INPUT BUFFER          33200019
         LA    R2,VINAEND(R1)          COLUMN 71 OF STMT           3156 33230019
         LA    R4,VINA040              GET ANOTHER REOCRD          3156 33260019
         CLC   DISPLZER(MVTWO,R1),VINASLH SEE IF THE FIRST 2 CHARACTERS 33300019
         BE    VINA045                 CHECK THE VERB                   33400019
         MVC   DISPLZER(MVONE,R1),VINABLNK     MOVE BLANK TO     A35012 33440020
*                                              FIRST BYTE OF     A35012 33480020
*                                              BUFFER            A35012 33520020
         MVC   DISPLONE(MV79,R1),DISPLZER(R1)  AND CLEAR.        A35012 33560020
         MVC   DISPLZER(MV46,R1),VINASLH GENERATE //SYSIN DD *    M3738 33600019
         B     VINA140                  SET DATA FLUSH BUT       A35013 33700020
         SPACE                                                          33800019
VINA045  DS    0H                                                       33900019
         CLI   DISPLTWO(R1),VINASTE    IS THIS A COMMENT STMT     4362  33930019
         BE    VINA072                 CREATE AN SMB             A39049 33960020
         LA    R1,DISPLONE(R1)         BUMP STATEMENT POINTER           34000019
         SPACE                                                          34100019
VINA050  DS    0H                                                       34200019
         LA    R1,DISPLONE(R1)         BUMP STATEMENT POINTER           34300019
         CLI   DISPLZER(R1),INITBLK    TEST FOR A BLANK                 34400019
         BNE     VINA075               LABEL ON STATEMENT               34500019
         SPACE                                                          34600019
VINA060  DS    0H                                                       34700019
         LA    R1,DISPLONE(R1)         BUMP STTEMENT POINTR             34800019
         CR    R2,R1                   END OF STMT                 3156 34830019
         BL    VINACNT0                YES, CHECK FOR CONTINUATIOA39900 34860020
*                                      NULL SO FAR               A39900 34870020
         CLI   DISPLZER(R1),INITBLK    NEXT NON-BLNAK SHOULD BE VERB    34900019
         BE    VINA060                 A  BLANK                         35000019
VINA065  DS    0H                                                 4362  35050019
         SPACE                                                          35100019
         CLC   DISPLZER(MVFIVE,R1),VINAPEND     IS THERE A PEND VERB    35200019
         BE    VINA080                 PEND VERB                        35300019
         CLC   DISPLZER(COMPFIVE,R1),VINAEXEC EXEC VERB?         A52677 35330021
         BNE   VINA066            BRANCH. NOT AN EXEC CARD       A52677 35360021
         LA    R1,DISPLFOR(R1)    BUMP PTR PAST VERB.            A52677 35390021
VINA068  LA    R1,DISPLONE(R1)    BUMP PTR BY ONE.               A52677 35420021
         CR    R2,R1              END OF STMT?                   A52677 35450021
         BL    VINACNT            YES, CHECK FOR CONTINUATION.   A52677 35480021
         CLI   DISPLZER(R1),INITBLK  CHECK FOR OPERAND.          A52677 35510021
         BE    VINA068            CONTINUE SCAN FOR NON-BLANK.   A52677 35540021
         B     VINACNT8           CHECK FOR CONTINUATION.        A52677 35570021
VINA066  CLC   DISPLZER(COMTHREE,R1),VINADD    DD VERB           A52677 35600021
         BNE   VINA073                 GET ANOTHER RECORD               35700019
         LA    R1,DISPLTWO(R1)         BUMP POINTER PAST VERB           35800019
         SPACE                                                          35900019
*********************************************************************** 36000019
*                                                                     * 36100019
* CHECK FOR DD * OR DD DATA.  IF EITHER EXIST THE DATA WILL BE FLUSHED  36200019
* BY THE READER/INTERPRETER                                           * 36300019
*                                                                     * 36400019
*********************************************************************** 36500019
VINA070  DS    0H                                                       36600019
         LA    R1,DISPLONE(R1)         BUMP POINTER                     36700019
         CR    R2,R1                   END OF STMT?                3156 36730019
         BL    VINACNT                 YES, CHECK FOR CONTINUATION 3156 36760019
         CLI   DISPLZER(R1),INITBLK    CHECK FOR OPERAND                36800019
         BE    VINA070                 NO OPERAND                       36900019
         SPACE                                                          37000019
         CLC   DISPLZER(COMPTWO,R1),VINAST   COMPARE FOR DD *           37100019
         BE    VINA140                 DD *                             37200019
         CLC   DISPLZER(COMPFIVE,R1),VINADATA    DD DATA                37300019
         BE    VINA150                 DD DATA                          37400019
         CLC   DISPLZER(COMPTWO,R1),VINASTCM   DD *,?             4362  37420019
         BE    VINA140                 SET THE DATA FLUSH BIT     4362  37440019
         CLC   DISPLZER(COMPFIVE,R1),VINADATC  DD  DATA,?         4362  37460019
         BE    VINA150                 SET THE DATA FLUSH BITS    4362  37480019
         B     VINA073                 CONTINUE THE SCAN         A39049 37490020
         SPACE                                                          37500019
VINA072  DS    0H                                                A39049 37550020
         OI    SWZ,CMT                 INDICATE COMMENT CARD     A39049 37560020
         SPACE                                                          37570020
VINA073  DS    0H                                                       37600019
         BAL   R5,VINACNT8             CHECK FOR CONTINUATION           37700019
         SPACE                                                          37900019
VINA075  DS    0H                                                       38000019
         LA    R1,DISPLONE(R1)         BUMP POINTER                     38100019
         CR    R2,R1                   END OF STMT?                3156 38130019
         BL    VINACNT                 YES, CHECK FOR CONTINUATION 3156 38160019
         CLI   DISPLZER(R1),INITBLK    END OF LABEL                     38200019
         BNE   VINA075                 END OF LABEL                     38300019
         SPACE                                                          38320019
VINA078  DS    0H                                                 4362  38340019
         LA    R1,DISPLONE(R1)         BUMP POINTER               4362  38360019
         CR    R2,R1                   END OF STMT?                3156 38366019
         BL    VINACNT                 YES, CHECK FOR CONTINUATION 3156 38372019
         CLI   DISPLZER(R1),INITBLK    BEGINING OF VERB?          4362  38380019
         BE    VINA078                 NO                         4362  38400019
         SPACE                                                          38420019
         CLC   DISPLZER(MVFOUR,R1),VINAJOB   THIS A JOB VERB?     4362  38440019
         BE    VINA120                 XCTL TO IEFVHCB            4362  38460019
         B     VINA065                 CHECK FOR PEND STMT        4362  38480019
         SPACE                                                          38500019
VINA080  DS    0H                                                       38600019
         MVI   MSGKEY,INTKEY6          ON THE PEND STMT            4360 38700019
         L     R1,IWAPARM              ADDRESS OF PARAMETER LIST        38800019
         CLI   IEZLEN+DISPLONE,INPLN    SEE IF RECORD WAS COMPRESS19086 38810019
         BE    VINA085                  PROCEDURE HAD STATEMENTS. 19086 38820019
         LA    R2,WKRECORD              ADDRESS OF WORK RECORD    19086 38830019
         ST    R2,IEZCOMPR              NEXT AVAILABLE BYTE FOR   19086 38840019
*                                       COMPRESSED RECORD         19086 38850019
         SPACE                                                          38860019
VINA085  DS    0H                                                 19086 38870019
         L     R2,IEZCOMPR             ADDRESS OF WHERE EOF MARKER      38900019
*                                      SHOULD GO                        39000019
         XC    DISPLZER(MVTWO,R2),DISPLZER(R2)  EOF MARKER              39100019
         BAL   R2,VINASYNT             SUNTAX CHECKER                   39200019
         SPACE                                                          39300019
VINA090  DS    0H                                                       39400019
         BAL   R5,VINAMSG0             CREATE AN SMB IF NECESSARY       39500019
         LA    R5,VINA096              RETURN FROM QUEUE WRITE   A40299 39550021
*                                      SUBROUTINE TO XCTL TO VHA A40299 39570021
         SPACE                                                          39600019
*********************************************************************** 39700019
*                                                                     * 39800019
* WRITE THE LAST RECORD OF THE PROCEDURE ONTO THE JOB QUEUE           * 39900019
*                                                                     * 40000019
*********************************************************************** 40100019
VINA095  DS    0H                                                 19086 40150019
         XC    WKTTR(MVFOUR),WKTTR     CLEAR TTR OF NEXT RECORD FIELD   40200019
*                                      TO INDICATE END OF PROCEDURE     40300019
         ST    R6,QPARMP               PTR TO IN-LINE PROC QMPA         40400019
         L     RF,VIEFVHQ              ADDRESS OF IEFVHQ                40500019
         MVI   QMPOP,QMWRTE            SET FUNCTION BYTE TO WRITE       40600019
         L     R6,QMPCL                ADDR OF EXTERNAL PARM LIST  3391 40700019
         MVC   DISPLZER(MVFOUR,R6),IWAWKBF  ADDR OF WORK AREA      3391 40800019
         MVC   DISPLFOR(MVTHREE,R6),WKPTR2  TTR OF WHERE RECORD SHOULD  40900019
*                                      GO ON JOB QUEUE             3391 41000019
         BALR  RE,RF                   WRITE RECORD ON JOB QUEUE        41100019
         LA    R6,QPARM                ADDRESS OF R/I QMPA              41200019
         ST    R6,QPARMP               POINTER TO QMPA                  41300019
         BR    R5                      RETURN TO CALLER          A40299 41450021
         SPACE                                                          41452021
VINA096  DS    0H                                                A40299 41460021
         BAL   R5,VINAEXIT             FREE SAVE AREA AND CORE   A40299 41470021
         SPACE                                                          41480021
VINA100  DS    0H                                                       41500019
         SPACE                                                          42400019
         XCTL  EP=IEFVHA                                                42500019
         SPACE                                                          42600019
VINA120  DS    0H                                                       42700019
         LA    RA,RSTMT                ADDRESS OF PARM LIST       19093 42900019
         L     R9,RSTMT                ADDRESS OF READER BUFFER   19093 43100019
         SPACE                                                          43300019
         BAL   R5,VINAEXIT                                        19093 43500019
         SPACE                                                          43700019
         XCTL  EP=IEFVHCB                                               43800019
         SPACE                                                          43900019
VINA130  DS    0H                                                       44000019
         L     R5,RSTMT                ADDRESS OF BSAM BUFFER           44100019
         BAL   R2,VINAPARM             GET CORE FOR PARM LIST           44200019
         L     RF,VIEFVINB             ADDRESS OF DIRECTORY SEARCH      44300019
*                                      ROUTINE                          44400019
         BALR  RE,RF                                                    44500019
         B     VINA030                 CREATE AN SMB IF ONE IS NEEDED   44600019
         SPACE                                                          44700019
VINA140  DS    0H                                                       44800019
         OI    SWA,DFSH            SET DATA FLUSH BIT             M3738 44900019
         B     VINA160                 CREATE AN SMB FOR STATEMNT       45000019
         SPACE                                                          45100019
VINA150  DS    0H                                                       45200019
         OI    SWA,DFSH+SAFSH           SET DATA FLUSH BITS       19085 45300019
VINA160  DS    0H                                                       45400019
         BAL   R4,VINAMSG              CREATE AN SMB FOR STATEMENT      45500019
         L     R1,IWAPARM               ADDRESS OF PARM LIST      19086 45530019
         L     R2,IEZCOMPR              NEXT AVAILABLE BYTE       19086 45560019
         XC    DISPLZER(MVTWO,R2),DISPLZER(R2) EODAD MARKER       19086 45590019
         LA    R5,VINA096               DON'T RETURN FROM SUBRRTNA40299 45600021
         B     VINA095                  WRITE PROC ON JOB QUEUE   19086 45620019
         EJECT                                                          45650019
         EJECT                                                          45700019
**********************************************************************  45800019
*                                                                    *  45900019
* THIS SUBROUTINE WILL GET CORE FOR A 20 BYTE PARAMETER LIST         *  46000019
* THIS PARAMETER LIST IS USED FOR THE DIRECTORY SEARCH ROUTINE       *  46100019
* IEFVINB, THE DIRECTORY BUILD ROUTINE, IEFVINC AND FOR THE COMPRESS *  46200019
* ROUTINE, IEZNCODE.  THE SUBROUTINE WILL INITIALIZE THE PARM LIST   *  46300019
* TO CONTAIN THE VALUES NEEDED FOR BOTH IEFVINB AND IEFVINC.  THAT IS   46400019
*     BYTES        VALUE                                             *  46500019
*     0-3          ADDRESS OF ITSELF                                 *  46600019
*     4-11         PROCEDURE NAME                                       46700019
*     12-15        ADDRESS OF THE DIRECTORY                          *  46800019
*     16-19        RETURN CODE FOR IEFVINB                           *  46900019
*     20-23        RETURN CODE FROM IEFVINC                          *  47000019
*                                                                    *  47100019
* CONTROL IS TRANSFERRED ON REGISTER 2                               *  47200019
* THIS ROUTINE WILL ESTABLISH ADDRESSIBILITY ON THE DSECT FOR THE    *  47300019
* PARAMETER LIST USED BY IEZNCODE                                    *  47400019
*                                                                    *  47500019
**********************************************************************  47600019
         SPACE                                                          47700019
VINAPARM DS    0H                                                       47800019
         LA    R0,VINACORE             LENGTH OF CORE                   47900019
         GETMAIN R,LV=(0)                                               48000019
         ST    R1,ADDSS                ADDR OF PARM LIST          M4268 48060019
         O     R1,IWAPARM              RETAIN INFO IN HIGH ORDER  M4268 48120019
*                                      BYTE OF FIELD              M4268 48180019
         ST    R1,IWAPARM              ADDR OF PARM LIST          M4268 48240019
         MVI   PROCNAME,INITBLK        CLEAR PROCNAME FIELD             48300019
         MVC   PROCNAME+DISPLONE(MVSEVEN),PROCNAME   TO BLANKS          48400019
         EX    R3,VINAMV2              MOVE PROCNAME TO PARM LIST       48500019
         LA    R3,WKPTR1               ADDRESS OF DIRECTORY             48600019
         ST    R3,DIRECT               ADDRESS OF DIRECTORY             48700019
         ST    RF,RTCD                 RETURN CODE FROM VINB            48800019
         ST    RC,IWAPTR               ADDRESS OF IWA                   48900019
         BR    R2                                                       49000019
         EJECT                                                          49100019
**********************************************************************  49200019
*                                                                    *  49300019
* THIS SUBROUTINE WILL INITIALIZE REGISTER 2 WITH AN ERROR CODE AND  *  49400019
* BRANCH TO A SUBROUTINE WHICH PRINTS THE ERROR MESSAGE.  THE JOB    *  49500019
* FAILED BIT IS SET AND CONTROL RETURNED TO XCTL TO IEFVHA.          *  49600019
*                                                                    *  49700019
**********************************************************************  49800019
         SPACE                                                          49900019
VINAERR  DS    0H                                                       50000019
         MVI   MSGSEC,PRIMARY1         NO PROCEDURE NAME                50100019
         B     VINAERR0                NO PROCEDURE NAME                50200019
         SPACE                                                          50300019
VINAERR2 DS    0H                      LABEL ERROR                      50400019
         MVI   MSGSEC,PRIMARY2         LABEL ERROR                      50500019
         CLI   MSGKEY,INTKEY6          IS  ERROR ON PEND CARD?    M1867 50510021
         BNE   VINAERR0                NO - ONLY ISSUE ERROR MSG  M1867 50520021
         BAL   R5,VINA095              QUEUE RECORDS SHOULD BE...A40299 50550021
*                                      ...WRITTEN FOR THIS ERROR A40299 50560021
*                                      CONDITION TO PREVENT THE  A40299 50570021
*                                      R/I FROM ABENDING WHEN IT A40299 50580021
*                                      EXPANDS THE PROCEDURE.    A40299 50590021
         SPACE                                                          50592021
         B     VINAERR0                LABEL ERROR                      50600019
         SPACE                                                          50700019
         SPACE                                                          51100019
VINAERR3 DS    0H                                                       51200019
         MVI   MSGSEC,PRIMARY4         EXCESSIVE NUMBER OF PROCS        51300019
         MVI   MSGKEY,DISPLZER         CLEAR SECONDARY MSG KEY          51400019
         SPACE                                                          51500019
VINAERR0 DS    0H                      ERROR                            51600019
         BAL   R5,VINAMSG0         CREATE AN SMB                  19085 51900019
         SPACE                                                          52200019
VINAERR4 DS    0H                                                       52300019
         XR    R2,R2                   INSERT PRIMARY MSG CODE          52400019
         IC    R2,MSGSEC               FOR ERROR MESSAGE                52500019
         BAL   R5,VINAMSG1             CREATE SMB FOR ERROR MSG         52600019
         OI    JCTJSTAT,INCMSTS        SET JOB FAILED BIT               52700019
         L     R2,IWAPARM              ADDRESS OF PARM LIST       19093 52750021
         LTR   R2,R2                   PARM LIST GOTTEN?          19093 52760021
         LA    R5,VINA100              XCTL TO IEFVHA             19093 52810021
         BZ    VINAEXT1                PARMLIST WASN'T GOTTEN     19093 52820021
         B     VINAEXIT                FREE CORE FOR PARM LIST    19093 52870021
         EJECT                                                          53200019
VINACNT0 DS    0H                                                A39900 53210020
         CLI  DISPLONE(R2),INITBLK     IS THIS TRULY A NULL      A39900 53220020
*                                      STATEMENT                 A39900 53260020
         BNE  VINACNT1                 NO, IT HAS CONTINUATION   A39900 53270020
         BAL  R5,VINAMSG0              GO TO WRITE OUT NULL      A39900 53280020
         B    VINA120                  XCTL TO IEFVHCB AS FOR    A39900 53290020
*                                      JOB CARD                  A39900 53292020
VINACNT  DS    0H                                                       53300019
         CLI   DISPLONE(R2),INITBLK    IS THIS STMT CONTINUED      3156 53400019
         BE    VINAMSG                 NO, CREATE AN SMB           3156 53500019
*  CONTINUATION ON STATEMENT                                      3156* 53600019
         SPACE                                                          53700019
VINACNT1 DS    0H                                                  3156 53800019
         BAL   R4,VINAMSG              CREATE AN SMB               3156 53900019
         SPACE                                                          53950020
         TM    SWZ,CMT                 IS A COMMENT CARD BEING   A39049 53960020
*                                      PROCESSED?                A39049 53962020
         BO    VINA040                 RETURN TO MAINLINE PROCES.A39049 53970020
         SPACE                                                          53980020
         L     R1,RDCBP                ADDRESS OF READER DCB       3156 54000019
         GET   (1)                                                      54100019
         ST    R1,RSTMT               SAVE ADDR OF INPUT BUFFER  A34832 54200020
         LA    R2,VINAEND(R1)          POINTER TO COLUMN 71        3156 54300019
         LA    R1,MVTHREE(R1)          INCREMENT TO COLUMN 4 WHERE 3156 54400019
*                                      CONTINUATION CAN BEGIN      3156 54500019
         SPACE                                                          54600019
VINACNT3 DS    0H                                                  3156 54700019
         CLC   DISPLZER(MVFIVE,R1),VINAPEND   IS THIS A PEND COMMENT    54800019
         LA    R4,VINA040              GET ANOTHER RECORD          3156 54900019
         BE    VINACNT                 YES, CHECK FOR CONTINUTAION 3156 55000019
         LA    R1,DISPLONE(R1)         INCREMENT POINTER           3156 55100019
         CR    R2,R1                   END OF 2TATEMENT?           3156 55200019
         BL    VINA043                 YES, SC1N STATEMENT         3156 55300019
         B     VINACNT3                CHECK FOR PEND COMMENT      3156 55400019
VINACNT8 DS    0H                                                       55402019
         XR    R3,R3                                               3157 55404019
VINACT10 DS    0H                                                  3157 55406019
         CLI   DISPLZER(R1),VINAQUOT   CHECK FOR LITERAL           3157 55408019
         BNE   VINACT16                NOT A LITERAL               3157 55410019
         CLI   DISPLONE(R1),VINAQUOT   CHECK FOR A LITERAL       A52632 55412021
         LA    R5,VINACT10             ONLY ONE QUOTE, A LITERAL   3157 55414019
         BE    VINACT14                NOT A LITERAL               3157 55416019
*****  QUOTE INDICATES A LITERAL, SET SWITCH                      3157* 55418019
         SPACE                                                          55420019
         LTR   R3,R3                   END OR BEGINNING OF LITERAL 3157 55422019
         LA    R5,VINACNT8             CLEAR LITERAL SWITCH        3157 55424019
         BNZ   VINACT12                END OF LITERAL, CHECK FOR   3157 55426019
*                                      ', ' TO INDICATE CONTIN     3157 55428019
         LA    R3,DISPLONE             START OF LITERAL, SET SW    3157 55430019
         LA    R5,VINACT10             CHECK FOR LITERAL           3157 55432019
         SPACE                                                          55434019
VINACT12 DS    0H                                                  3157 55436019
         LA    R1,DISPLONE(R1)         INCREMENT POINTER           3157 55438019
         SPACE                                                          55440019
VINACT14 DS    0H                                                  3157 55442019
         LA    R1,DISPLONE(R1)         INCREMENT POINTER           3157 55444019
         CR    R2,R1                   END OF STATEMENT            3157 55446019
         BL    VINACNT                 CHECK FOR CONTINUATION      3157 55448019
         BR    R5                      RETURN TO CALLER            3157 55450019
VINACT16 DS    0H                                                  3157 55452019
         LA    R5,VINACT10             CHECK FOR LITERAL           3157 55454019
         LTR   R3,R3                   IS THIS IN A LITERAL?       3157 55456019
         BNZ   VINACT14                IN A LITERAL, CHECK FOR END 3157 55458019
         CLC   DISPLZER(MVTWO,R1),VINACONT      CONTINUATION?      3157 55460019
         BE    VINACNT1                CONTINUATION OF STMT        3157 55462019
         CLI   DISPLZER(R1),INITBLK    THIS THE END OF OPERANDS  A52632 55462421
         BE    VINACNT                 YES- BRANCH               A52632 55462821
         B     VINACT14                INCREMENT POINTER           3157 55464019
         EJECT                                                          55466019
         EJECT                                                          55500019
         EJECT                                                          57000019
**********************************************************************  57100019
*                                                                    *  57200019
* THIS SUBROUTINE CREATES AN SMB IF ONE IS NEEDED.  IT INITIALIZES    * 57300019
* THE PARAMETER LIST FOR IEZNCODE WHEN THE FIRST IN-LINE PROCEDURE IS * 57400019
* ENCOUNTERED.  THE PARAMETER LIST IS MAPPED IN THE DSECT, IEZPARM.   * 57500019
*                                                                     * 57600019
* IT BRANCHES TO IEZNCODE TO COMPRESS THE RECORD AND CHECKS A         * 57700019
* RETURN CODE UPON RETURN.  IF THE OUTPUT AREA IS FULL, IT USES IEFVHQ  57800019
* AND THE QUEUE MANAGER TO ASSIGN A NEW RECORD, AND WRITE THE RECORD  * 57900019
* TO THE JOB QUEUE.  CONTROL IS THEN RETURNED TO IEZNCODE.  WHEN THE  * 58000019
* COMPRESSED RECORD HAS BEEN PLACED IN THE OUTPUT BUFFER, CONTROL IS  * 58100019
* RETURNED TO THE CALLER THROUGH REGISTER 4.                          * 58200019
         SPACE                                                          58300019
*                                                                    *  58400019
**********************************************************************  58500019
VINAMSG  DS    0H                                                       58600019
         LA    R5,VINACOMP             NEXT INSTRUCTION TO BE EXECUTED  58700019
         SPACE                                                          58800019
VINAMSG0 DS    0H                                                       58900019
         TM    JCTJMGLV,INCMMGL1+INCMMGL2  MSGLEVEL=0?                  59000019
         BCR   R8,R5               RETURN TO CALLER               19085 59100019
         L     R9,RSTMT                ADDRESS OF INPUT BUFFER          59200019
**********************************************************************  59300019
*                                                                    *  59400019
* CREATE SMB                                                            59500019
*                                                                    *  59600019
**********************************************************************  59700019
         SPACE                                                          59800019
         XR    R2,R2                   INDICATE NO ERROR MESSAGE        59900019
*                                      AFTER THE FOLLOWING SUBROUTINE   60000019
*                                      WHICH BRANCHES TO IEFVGM TO      60100019
*                                      CREATE SMB'S                     60200019
         SPACE                                                          60300019
**********************************************************************  60400019
*                                                                    *  60500019
* THIS SUBROUTINE USES IEFVGM TO CREATE AN SMB FOR AN ERROR OR A STMT*  60600019
* IT RETURNS CONTROL ON REGISTER 5                                   *  60700019
*                                                                    *  60800019
**********************************************************************  60900019
         SPACE                                                          61000019
VINAMSG1 DS    0H                                                       61100019
         OI    SWA,JTOP                SET JOB TO PROCESS BIT           61200019
         L     RF,VIEFVGM              CREATE                           61300019
         BALR  RE,RF                                                    61400019
         BR    R5                                                       61500019
         SPACE                                                          61600019
VINACOMP DS    0H                                                       61700019
         L     R1,IWAPARM              ADDRESS OF PARAMETER AREA        61800019
         TM    IEZLEN+DISPLONE,INPLN   SEE IF PARM LIST IS INITIALIZED  61900019
         BO    VINACOM2                PARAMETER LIST IS INITIALIZED    62000019
         LA    R5,DISPLFOR(R1)         ADDRESS OF PARAMETER LIST        62100019
         ST    R5,IEZADDR              PARAMETER LIST                   62200019
         LA    R3,INPLN                LENGTH OF INPUT BUFFER           62400019
         STH   R3,IEZLEN                                                62500019
         LA    R3,WKRECORD             ADDRESS OF WORK RECORD           62600019
         ST    R3,IEZCOMPR                                              62700019
         MVI   IEZCHAR,INITBLK         BLANKS TO BE COMPRESSED          62800019
         LA    R3,OUTLN                LENGTH OF OUTPUT BUFFER          62900019
         STH   R3,IEZOUT               AREA                             63000019
         MVI   IEZTYPE,TYPEZER         NOT SPECIAL                      63100019
         SPACE                                                          63200019
VINACOM2 DS    0H                                                       63300019
         MVC   IEZUNCOM(MVFOUR),RSTMT   ADDRESS OF INPUT BUFFER  A34832 63350020
         L     R1,IWAPARM              ADDRESS OF PARAMETER LIST        63400019
         L     RF,VIEZN                ADDRESS OF COMPRESS ROUTINE      63500019
         BALR  RE,RF                                                    63600019
         SPACE                                                          63700019
         LTR   RF,RF                                                    63800019
         BCR   EQU,R4                  RECORD WAS COMPRESSED            63900019
**********************************************************************  64000019
*                                                                    *  64100019
* IF THIS IS A PEND VERB CONTROL IS TRANSFERRED TO VIN015 TO XCTL       64200019
* TO VHA.  FOR ANY OTHER STATEMNT ANOTHER STATEMENT WILL BE READ.       64300019
*                                                                    *  64400019
**********************************************************************  64500019
         SPACE                                                          64600019
         MVI   QMPOP,QMASGN            ASSIGN                           64700019
         ST    R6,QPARMP               REPLACE R/I QMPA PTR             64800019
         L     RF,VIEFVHQ              Q MANAGER INTERFACE              64900019
         BALR  RE,RF                   Q MANAGER INTERFACE              65000019
         L     R2,QMPCL                ADDR OF EXTERNAL PARM LIST  3391 65100019
         MVC   DISPLFOR(MVTHREE,R2),WKPTR2   RECORD ON QUEUE       3391 65200019
         MVC   WKPTR2(MVTHREE),DISPLZER(R2) TTR RETURNED FROM ASSIGN    65300019
         MVC   WKTTR(MVTHREE),DISPLZER(R2) ADDR OF NEXT RECORD IN PROC  65400019
         MVC   DISPLZER(MVFOUR,R2),IWAWKBF CORE ADDR OF WORK BUFFER3391 65500019
         MVI   QMPOP,QMWRTE            WRITE THE RRCORD TO THE Q        65600019
         BALR  RE,RF                                                    65900019
         LA    R2,QPARM                ADDRESS OF QMPA (R/I)            66000019
         ST    R2,QPARMP               REPLACE IN-LINE PROC QMPA PTR    66100019
         LA    R2,WKRECORD             REINITIALIZE POINTER TO          66200019
         ST    R2,IEZCOMPR             WHERE NEXT COMPRESSED RECORD     66300019
*                                      SHOULD GO                        66400019
         LA    R2,OUTLN                LENGTH OF OUTPUT BEFFER          66500019
         STH   R2,IEZOUT               LENGTH OF OUTPUT BUFFER          66600019
         B     VINACOM2                COMPRESS THE RECORD              66700019
         EJECT                                                          66800019
**********************************************************************  66900019
*                                                                    *  67000019
* THIS SUBROUTINE BRANCHES TO IEFVINE TO SYNTAX THE PROC OR PEND     *  67100019
* STATEMENTS.  UPON RETURN IT TESTS COMMON ERROR CONDITIONS.         *  67200019
*        IF THE HIGH ORDER BIT OF THE RETURN CODE IS SET A CONTINUA- *  67300019
*        TION IS EXPECTED.  CONTROL IS PASSED TO THE CONTINUATION SUB*  67400019
*        ROUTINE                                                     *  67500019
*                                                                    *  67600019
*        IF THE RETURN CODE IS 12, AN ERROR EXISTS IN THE LABEL FIELD*  67700019
*        CONTROL IS PASSED TO AN ERROR ROUTINE                       *  67800019
*        IF THE RETURN CODE IS 16, AN ERROR EXISTS IN THE USE OF     *  67900019
*        COMMENTS.  CONTROL IS PASSED TO AN ERROR ROUTINE            *  68000019
*                                                                    *  68100019
*        IF NONE OF THESE ERROR EXIST CONTROL IS RETURNED THROUGH    *  68200019
*        REGISTER 2                                                  *  68300019
*                                                                    *  68400019
**********************************************************************  68500019
         SPACE                                                          68600019
VINASYNT DS    0H                                                       68700019
         L     R1,RSTMT                ADDRESS OF INPUT BUFFER          68800019
         L     RF,VIEFVINE             SYNTAX CHECKER                   68900019
         BALR  RE,RF                                                    69000019
         L     R4,DISPL10(RD)          RETURN CODE FROM IEFVINE   4329  69100019
         LA    R3,ERRTEST              CHECK FOR ERROR                  69400019
         CR    R4,R3                   ARE THERE ANY ERRORS?      4329  69500019
         BE    VINAERR2                ERROR IN THE LABEL FIELD         69700019
         BR    R2                      RETURN TO CALLER            O106 69900019
         EJECT                                                          70100019
*********************************************************************** 70300019
*                                                                     * 70500019
*  THIS SUBROUTINE IS THE FIRST PORTION OF THE READER END OF FILE     * 70700019
*  ROUTINE.  IT IS USED ONLY IF THE CONDITION OCCURS IN IEFVINA.  IT  * 70900019
*    SETS THE READER END OF FILE BIT IN IWA AND FREES CORE.       O106* 71100019
*    IT THEN XCTL'S TO IEFVHA TO FINISH CLOSING SYSIN                 * 71400019
*                                                                     * 71700019
*********************************************************************** 71900019
         SPACE                                                          72100019
VINAEOF  DS    0H                                                 19093 72300019
         SPACE                                                          72500019
         OI    IWAPARM,EOFRINPR        SET READER EOF BIT         19093 72700019
         LA    R5,VINA100              XCTL TO IEFVHA             19093 72900019
         SPACE                                                          73100019
VINAEXIT DS    0H                                                 19093 73300019
         SPACE                                                          73500019
         LA    R0,VINACORE             LENGTH OF CORE             19093 73700019
         L     R1,IWAPARM              ADDRESS OF PARM LIST       19093 73900019
         FREEMAIN  R,LV=(0),A=(1)                                       74100019
         XC    IWAPARM+DISPLONE(MVTHREE),IWAPARM+DISPLONE         19093 74300019
*                                      CLEAR PARM LIST POINTER    19093 74500019
         SPACE                                                          74700019
VINAEXT1 DS    0H                                                 19093 74900019
         MVI   MSGKEY,DISPLZER         CLEAR SECONDARY MESSAGE KEY19093 75100019
         SPACE                                                          75300019
         IEFRELSE                                                       75500019
         SPACE                                                          75700019
         BR    R5                      RETURN TO THE CALLER       19093 75900019
*********************************************************************** 76100019
*                                                                     * 76300019
*  THIS SUBROUTINE IS THE FIRST PORTION OF THE SYNAD ROUTINE FOR N      76500019
*  AN I/O ERROR SHOULD IT OCCUR WHILE READING AN INPUT RECORD IN  O106* 76700019
*  LOAD MODULE.  THE I/O ERROR BIT IN THE IWA IS SET, THE EODAD   O106* 76900019
*  AND SYNAD ROUTINE ADDRESSES ARE REPLACED IN THE QAAM DCB, CORE O106* 77100019
*  IS FREED AND CONTROL IS RETURNED TO IEFVHA TO COMPLETE PROCESSING  * 77300019
*  OF THE I/O ERROR                                               O106* 77500019
*                                                                     * 77700019
*********************************************************************** 77900019
         SPACE                                                          78100019
VINASYND DS    0H                                                 19093 78300019
         OI    SWC,IOERR               SET I/O ERROR SWITCH IN IWA19093 78500019
         LA    R5,VINA100              XCTL TO IEFVHA            A49933 78550021
         B     VINAEXIT                REPLACE DCB ADDRESSES      19093 78700019
         EJECT                                                          78900019
         DS    0F                                                       79100019
VIEFVINB DC    V(IEFVINB)              ADDRESS OF DIRECTORY SEARCH      79300019
VIEFVINC DC    V(IEFVINC)              ADDRESS OF DIRECTORY BUILD       79500019
VIEFVINE DC    V(IEFVINE)              ADDRESS OF SYNTAX CHECKER        79700019
VIEFVHQ  DC    V(IEFVHQ)               ADDRESS OF Q MANAGER INTERFACE   79900019
VIEFVGM  DC    V(IEFVGM)               ADDRESS OF MESSAGE MODULE        80100019
VIEZN    DC    V(IEZNCODE)             ADDRESS OF COMPRESS ROUTINE      80300019
         SPACE                                                          80500019
VINASTCM DC    C'*,'                   DD    *,   STATEMENT       4362  80700019
VINADATC DC    C'DATA,'                SYSIN  DD  DATA,DCB=       4362  80900019
VINADATA DC    C'DATA '                DD DATA STATEMENT                81100019
VINAPEND DC    C'PEND '                                                 81300019
VINAJOB  DC    C'JOB '                                                  81500019
VINAEXEC DC    C'EXEC '           EXEC STATEMENT                 A52677 81600021
         SPACE                                                          81700019
VINAMV2  MVC   PROCNAME(0),2(R5)                                        81900019
VINAMOVE MVC   QMNAM(0),2(R5)          PROCNAME TO QMPA                 82100019
         SPACE                                                          82300019
* THE FOLLOWING FIVE DC'S MUST REMAIN IN THIS ORDER.  THEY FORM THE   * 82500019
* GENERATED DD * STATEMENT.                                           * 82700019
VINASLH  DC    X'6161'                 FIRST TWO CHARACTERS OF STMT     82900019
VINASYS  DC    C'SYSIN '               PART OF GENERATED STMT           83100019
VINADD   DC    C'DD '                  DD VERB                          83300019
VINAST   DC    C'* '               OPERAND OF GENERATED STMT            83400019
         DC    C'INSTREAM PROC GENERATED STATEMENT ' COMMENT OF GEN DD  83500019
VINABLNK DC    C' '                     BLANK TO CLEAR READER    A35012 83560020
*                                       BUFFER                   A35012 83620020
         SPACE                                                          83700019
VINAPLUS DC    C'++'                   IN-LINE PROCEDURE                83900019
VINACORE EQU   24                      LENGTH OF THE PARAMETER LIST     84100019
QMSYSOUT EQU   X'3'                    DEQUEUE TYPE                     84300019
WORKLN   EQU   352                     LENGTH OF WORK BUFFER       O106 84500019
QMPALN1  EQU   48                      LENGTH OF QMPA              O106 84700019
EOFRINPR EQU   X'40'                   INDICATE END OF READER           84800019
VINAQUOT EQU   C''''                   TEST FOR A LITERAL               84900019
VINACONT DC    C', '                   CHECK FOR CONTINUATION      3157 85000019
VINASTE  EQU   C'*'                    CHECK FOR COMMENT STATEMENT4362  85100019
MVONE    EQU   1                        LENGTH OF MOVE           A35012 85200020
MVTWO    EQU   2                       LENGTH OF MOVE                   85300019
MVTHREE  EQU   3                       LENGTH OF MOVE                   85500019
MVFOUR   EQU   4                       LENGTH OF MOVE                   85700019
MVFIVE   EQU   5                       LENGTH OF MOVE                   85900019
MVSEVEN  EQU   7                       LENGTH OF MOVE                   86100019
MVEIGHT  EQU   8                       LENGTH OF MOVE                   86300019
MV46     EQU   46                                                 M3738 86500019
MV79     EQU   79                       LENGTH OF READER STATE-  A35012 86600020
*                                       MENT MINUS ONE FOR MOVE  A35012 86700020
DISPLZER EQU   0                       DISPLACEMENT                     86900019
DISPLONE EQU   1                       DISPLACEMENT                     87100019
DISPLTWO EQU   2                       DISPLACEMENT                     87300019
DISPL3   EQU   3                       DISPLACEMENT                     87500019
DISPLFOR EQU   4                       DISPLACEMENT                     87700019
DISPL10  EQU   16                      REGISTER 15 IN THE SAVE AREA,    87900019
*                                      RETURN CODE FROM IEFVINE         88100019
DISPL24  EQU   X'24'                   REGISTER 4 IN THE SAVE AREA4329  88300019
COMPTWO  EQU   2                       LENGTH OF COMPARE                88500019
COMTHREE EQU   3                       LENGTH OF COMPARE                88700019
COMPFIVE EQU   5                       LENGTH OF COMPARE                88900019
NOENTRY  EQU   0                       NO IN-LINE PROCEDURES HAVE BEEN  89100019
*                                      ENCOUNTERED YET                  89300019
VINAEND  EQU   70                      END OF STATEMENT            3156 89400019
INPLN    EQU   80                      LENGTH OF INPUT BUFFER FOR       89500019
*                                      IEZNCODE                         89700019
OUTLN    EQU   168                     LENGTH OF OUTPUT BUFFER FOR      89900019
*                                      IEZNCODE                         90100019
TYPEZER  EQU   X'00'                   NOT A SPECIAL RECORD             90300019
EQU      EQU   8                       BRANCH ON EQUAL-RECORD FIT IN    90500019
*                                      THE BUFFER                       90700019
INITBLK  EQU   X'40'                   INITIALIZE QMNAM TO BLANKS       90900019
QMPALN   EQU   36                  LENGTH OF QMPA                       91100019
QMTPYONE EQU   1                       LENGTH OF QMTPY FIELD            91300019
QMTPYF   EQU   15                      DISPLACEMENT INTO QMPA TO        91500019
*                                      QMPTY FIELD                      91700019
ASSIGN1  EQU   X'10'                   NUMBER OF RECORDS TO ASSIGN      91900019
PRIMARY1 EQU   X'3F'                   NO PROCEDURE NAME                92100019
PRIMARY2 EQU   X'3E'                   SYNTAX ERROR                     92300019
PRIMARY4 EQU   X'41'                   EXCESSIVE NUMBER OF PROCEDURES   92700019
HIORDER  EQU   X'80'                   CONTINUATION OF A PEND OR PROC   92900019
*                                      STATEMENT                        93100019
ERRTEST  EQU   12                      TEST FOR ERROR ON PROCEDURE      93300019
*                                      DELIMITERS                       93500019
LENGONE  EQU   1                       NUMBER OF BITS TO SHIFT TO TURN  93700019
*                                      OFF HIGH ORDER BIT               93900019
CLFOUR   EQU   4                       CLEAR PTRS IN IWA          19093 94100019
SYMPARM  EQU   X'40'                   SYMBOLIC PARAMETERS EXIST  4329  94300019
         END                                                            94500019
