* TITLE: IEFVINB-DIRECTORY SEARCH                                     * 00600000
*                                                                     * 01200000
* FUNCTION: THIS MODULE SEARCHES THROUGH THE DIRECTORY FOR A DUPLICATE* 01800000
*           PROCEDURE NAME. IT SETS A RETURN CODE INDICATING WHETHER  * 02400000
*           THE PROCEDURE WAS FOUND OR NOT. A ZERO INDICATES THE PRO-*  03000000
*           CEDURE WAS NOT FOUND.  IF THE PROCEDURE WAS FOUND, THE    * 03600000
*           RETURN CODE WILL CONSIST OF THE TTR OF THE FIRST RECORD   * 04200000
*           OF THAT PROCEDURE.                                        * 04800000
*                                                                     * 05400000
* ENTRY POINT: IEFVINB                                                * 06000000
*                                                                     * 06600000
* INPUT: R1 POINTS TO A 20 BYTE PARAMETER LIST                        * 07200000
*                                                                     * 07800000
*        ***************************************************          * 08400000
*        *                                                 *          * 09000000
*        *     BYTES     PURPOSE                           *          * 09600000
*        *                                                 *          * 10200000
*        *     0-3       ADDRESS OF THE PARAMETER LIST     *          * 10800000
*        *     4-11      PROCEDURE NAME                    *          * 11400000
*        *     12-15     ADDRESS OF THE DIRECTORY          *          * 12000000
*        *     16-19     RETURN CODE FROM IEFVINB          *          * 12600000
*        *     20-23     RETURN CODE FROM IEFVINC          *          * 13200000
*        *                                                 *          * 13800000
*        ***************************************************          * 14400000
*                                                                     * 15000000
* EXITS: RETURNS TO CALLER                                            * 15600000
*                                                                     * 16200000
* OUTPUT: RETURN CODE                                                 * 16800000
*           0-PROCEDURE WAS NOT FOUND IN DIRECTORY                    * 17400000
*         TTR-TTR OF FIRST RECORD IN PROCEDURE                        * 18000000
*                                                                     * 18600000
* WORKAREAS OR TABLES                                                 * 19200000
*       PARM-PARAMETER LIST                                           * 19800000
*       WORK AREA-WORK BUFFER AND DIRECTORY                           * 20400000
*       IEFQMNGR-QMPA                                                 * 21000000
*       IEFVMIWA-IWA                                                  * 21600000
*                                                                     * 22200000
* REGISTER USEAGE-R8-QMPA                                             * 22800000
*                 R7-WORK BUFFER                                      * 23400000
*                                                                     * 24000000
* MACROES USED-RETURN                                                 * 24600000
*              SAVE                                                   * 25200000
*                                                                     * 25800000
* OPERATION-.SETS UP ADDRESSIBILITY FOR QMPA AND WORK AREA            * 26400000
*           .COMPARES EACH PROCEDURE NAME IN THE DIRECTORY WITH THE   * 27000000
*            PROCEDURE NAME PASSED AS A PARAMETER                     * 27600000
*           .IF THE PROCEDURE DOES NOT EXIST, A ZERO IS PLACED IN THE * 28200000
*            RTCD FIELD IN THE PARAMETER LIST                         * 28800000
*           .IF THE PROCEDURE NAME DOES EXIST, THE TTR OF THE FIRST   * 29400000
*            RECORD OF THAT PROCEDURE IS PLACED IN THE RTCD FIELD     * 30000000
*            OF THE PARAMETER LIST                                    * 30600000
*                                                                     * 31200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 31800000
         EJECT                                                          32400000
         IEFVMIWA                                                       33000000
         EJECT                                                          33600000
         IEFQMNGR                                                       34200000
QMPADDR  DS    CL4                     ADDRESS OF WORK BUFFER           34800000
QMPATTR  DS    CL3                     TTR OF JOB QUEUE RECORD          35400000
QMPAZER  DS    CL1  N                  RESERVED FIELD                   36000000
         EJECT                                                          36600000
WORKAREA DSECT                                                          37200000
         USING WORKAREA,R7                                              37800000
WKTTR    DS    CL4                     POINTER TO NEXT RECORD           38400000
WKQMPAPT DS    CL4                     ADDRESS OF QMPA                  39000000
WKRECORD DS    CL168                   COMPRESSED RECORD                39600000
WKPTR1   DS    CL4                     POINTER TO ITSELF                40200000
WKCT     DS    CL1                     NUMBER OF ENTRIES MADE IN        40800000
*                                      THIS SEGMENT OF THE DIRECTORY    41400000
WKPTR2   DS    CL3                     HOLDER OF TTR ASSIGNED BY  O106  42000000
*                                      THE QUEUE MANAGER          O106  42600000
WKPROCN1 DS    CL8                     PROCEDURE NAME                   43200000
WKTTR1   DS    CL3                     TTR OF FIRST RECORD              43800000
WKPROCN2 DS    CL8                     PROCEDURE NAME                   44400000
WKTTR2   DS    CL3                     TTR OF FIRST RECORD              45000000
WKPROCN3 DS    CL8                     PROCEDURE NAME                   45600000
WKTTR3   DS    CL3                     TTR OF FIRST RECORD              46200000
WKPROCN4 DS    CL8                     PROCEDURE NAME                   46800000
WKTTR4   DS    CL3                     TTR OF FIRST RECORD              47400000
WKPROCN5 DS    CL8                     PROCEDURE NAME                   48000000
WKTTR5   DS    CL3                     TTR OF FIRST RECORD              48600000
WKPROCN6 DS    CL8                     PROCEDURE NAME                   49200000
WKTTR6   DS    CL3                     TTR OF FIRST RECORD              49800000
WKPROCN7 DS    CL8                     PROCEDURE NAME                   50400000
WKTTR7   DS    CL3                     TTR OF FIRST RECORD              51000000
WKPROCN8 DS    CL8                     PROCEDURE NAME                   51600000
WKTTR8   DS    CL3                     TTR OF FIRST RECORD              52200000
WKPROCN9 DS    CL8                     PROCEDURE NAME                   52800000
WKTTR9   DS    CL3                     TTR OF FIRST RECORD              53400000
WKPROCNA DS    CL8                     PROCEDURE NAME                   54000000
WKTTRA   DS    CL3                     TTR OF FIRST RECORD              54600000
WKPROCNB DS    CL8                     PROCEDURE NAME                   55200000
WKTTRB   DS    CL3                     TTR OF FIRST RECORD              55800000
WKPROCNC DS    CL8                     PROCEDURE NAME                   56400000
WKTTRC   DS    CL3                     TTR OF FIRST RECORD              57000000
WKPROCND DS    CL8                     PROCEDURE NAME                   57600000
WKTTRD   DS    CL3                     TTR OF FIRST RECORD              58200000
WKPROCNE DS    CL8                     PROCEDURE NAME                   58800000
WKTTRE   DS    CL3                     TTR OF FIRST RECORD              59400000
WKPROCNF DS    CL8                     PROCEDURE NAME                   60000000
WKTTRF   DS    CL3                     TTR OF FIRST RECORD              60600000
         EJECT                                                          61200000
PARAM    DSECT                                                          61800000
         USING PARMADDR,R1                                              62400000
PARMADDR DS    CL4                     ADDRESS OF PARAMETER LIST        63000000
PROCNAME DS    CL8                     PROCEDURE NAME                   63600000
DIRECT   DS    CL4                     ADDRESS OF DIRECTORY             64200000
IWAPTR   DS    CL4                     ADDRESS OF IWA                   64800000
RTCD     DS    CL4                     RETURN CODE FORM IEFVINB         65400000
         EJECT                                                          66000000
IEFVINB  CSECT                                                          66600000
         SAVE  (14,12)                                                  67200000
         BALR  RB,0                                                     67800000
         USING *,RB                                                     68400000
         B     VINB000                 BRANCH AROUND IDENTIFICATION     69000000
         DC    X'11111111'                                              69600000
         DC    C'VINB'                                                  70200000
         DC    C'L.01'                                                  70800000
         SPACE                                                          71400000
VINB000  DS    0H                                                       72000000
         L     R7,IWAWKBF              ADDRESSIBILITY OF WORK AREA      72600000
         XR    R3,R3                   CLEAR REGISTER FOR COUNT         73200000
         IC    R3,WKCT                 NUMBER OF ENTRIES IN SEGMENT     73800000
         LA    R4,WKPROCN1             ADDRESS OF FIST PROCNAME         74400000
         SPACE                                                          75000000
****************************************************************        75600000
*                                                              *        76200000
* SEE IF PROCEDURE NAME EXISTS IN DIRECTORY                    *        76800000
*                                                              *        77400000
****************************************************************        78000000
VINB030  DS    0H                                                       78600000
         CLC   DISPLZER(MVEIGHT,R4),PROCNAME COMPARE FOR PROC NAME      79200000
         BE    VINB050                 PROCNAME WAS FOUND               79800000
         LA    R4,DISPLELE(R4)         INCREMENT TO NEXT PROCNAME       80400000
         BCT   R3,VINB030              SEE IF MORE ENTRIES EXIST        81000000
         SPACE                                                          81600000
****************************************************************        82200000
*                                                              *        82800000
*  PROCEDURE NAME WAS NOT FOUND.  RETURN CODE EQUALS ZERO      *        83400000
*                                                              *        84000000
****************************************************************        84600000
         XC    RTCD(CLFOUR),RTCD       PROCEDURE NAME NOT FOUND         85200000
         RETURN (14,12)                                                 85800000
         SPACE                                                          86400000
****************************************************************        87000000
*                                                              *        87600000
* PROCEDURE NAME WAS FOUND.  RETURN CODE EQUALS THE TTR        *        88200000
* OF THE FIRST RECORD OF THE PROCEDURE                         *        88800000
*                                                              *        89400000
****************************************************************        90000000
         SPACE                                                          90600000
VINB050  DS    0H                                                       91200000
         MVC   RTCD(MVTHREE),DISPLATE(R4) PROCEDURE WAS FOUND           91800000
         RETURN (14,12)                                                 92400000
MVTHREE  EQU   3                       LENGTH OF MOVE                   93000000
MVEIGHT  EQU   8                       LENGTH OF MOVE                   93600000
CLFOUR   EQU   4                       LENGTH OF CORE TO BE CLEARED     94200000
DISPLZER EQU   0                       DISPLACEMENT                     94800000
DISPLATE EQU   8                       DISPLACEMENT                     95400000
DISPLELE EQU   11                      DISPLACEMENT                     96000000
         END                                                            96600000
