*********************************************************************** 00020000
*                                                                     * 00040000
*                                                                     * 00060000
*  FUNCTION/OPERATION  THIS IS THE MAIN PROCESSING MODULE FOR A JOB   * 00080000
*        STATEMENT.   IT INITIALIZES A JCT FOR A JOB BY SETTING       * 00100000
*        MSGCLASS=A, MSGLEVEL=0, INTERNAL JOB SERIAL NBR = 1, JCT     * 00120000
*        ID = 0, TYPRUN = SETUP AND SETS THE DEFAULT PRIORITY WHICH   * 00140000
*        HAD BEEN SPECIFIED IN THE READER PROCEDURE.  IEFVJA ALSO     * 00160000
*        SETS UP A JOB ACCOUNT CONTROL TABLE EVEN IF ACCOUNTING       * 00180000
*        INFORMATION HAS NOT BEEN SPECIFIED. IT INITIALIZES THE NBR   * 00200000
*        OF SIOTS SLOT (DDINO) IN THE IWA AND SETS THE FIRST TIME     * 00220000
*                                                                     * 00240000
*  ENTRY POINTS  IEFVJA (FROM IEFVFA)                                 * 00260000
*                                                                     * 00280000
*  INPUT   REGISTER 12 POINTS TO THE INTERPRETER WORK AREA.           * 00300000
*          REGISTER 13 POINTS TO THE REGISTER SAVE AREA.              * 00320000
*                                                                     * 00340000
*  OUTPUT  REGISTERS 12 & 13  REMAIN UNCHANGED.                       * 00360000
*                                                                     * 00380000
*  EXTERNAL ROUTINES    1. IEFVGK - GET KEY/POSITIONAL UTILITY RTN.   * 00400000
*                       2. IEFVGT - TEST & STORE UTILITY ROUTINE.     * 00420000
*                       3. IEFVGM - MESSAGE UTILITY ROUTINE.          * 00440000
*                       4. IEFVHQ - QMNGR INTERFACE UTILITY ROUTINE.  * 00460000
*                                                                     * 00480000
*  EXITS   TO IEFVHF-POST PROCESSING CONTROL ROUTINE.                 * 00500000
*                                                                     * 00520000
*  ERROR EXIT  TO IEFVHF AFTER PUTTING ERROR MSG INTO SMB THRU IEFVGM * 00540000
*              AND SETTING JOB FAIL BIT IN JCT.                       * 00560000
*                                                                     * 00580000
*  TABLES/WORK AREAS    1. INTERPRETER WORK AREA (IEFVMIWA).          * 00600000
*                       2. JOB (LOCAL) WORK AREA (IEFVMJWA).          * 00620000
*                       3. TABLE OF INTERPRETER KEYS (IEFVKEYS).      * 00640000
*                       4. JOB CONTROL TABLE. (IEFAJCTB).             * 00660000
*                       5. QUEUE MANAGER PARAMETER AREA (IEFQMNGR).   * 00680000
*                                                                     * 00700000
*  ATTRIBUTES   READ ONLY / REENTRANT.                                * 00720000
*                                                                     * 00740000
*  NOTES  NONE                                                        * 00760000
*                                                                     * 00780000
*********************************************************************** 00800000
*                                                                     * 00820000
         EJECT                                                          00840000
         MACRO                                                          00860000
         KKK   &A,&B,&C,&D                                              00880000
         DC    XL1'&A'            NBR PARAMS THIS KEY.                  00900000
         DC    BL1'&B'       1 MEANS SUBPARAM OK THIS POS.              00920000
         DC    Y(&C)            OFFSET TO KEY PROCESSOR.                00940000
         DC    Y(&D)            OFFSET TO PDT.                          00960000
         MEND                                                           00980000
         MACRO                                                          01000000
         SSS   &A,&B                                                    01020000
         DC    XL1'&A'            NBR CNTRL BYTES/NBR BYTES COMPARE.    01040000
         DC    C'&B'              COMPARE PATTERN.                      01060000
         MEND                                                           01080000
         MACRO                                                          01100000
         MMM   &A,&B,&C                                                 01120000
         DC    FL1'&A'            MAX PARAMETER LENGTH.                 01140000
         DC    XL1'&B'            FUNCT/TABLE.                          01160000
         DC    AL1(&C)            OFFSET IN TABLE.                      01180000
         MEND                                                           01200000
         MACRO                                                          01220000
         DDD   &A,&B,&C,&D                                              01240000
         DC    XL1'&A'            FUNCT/TABLE.                          01260000
         DC    AL1(&B)            OFFSET IN TABLE.                      01280000
         DC    FL&C'&D'           MAX NBR (CVB).                        01300000
         MEND                                                           01320000
         MACRO                                                          01340000
         CCC   &A,&B                                                    01360000
         DC    FL1'&A'            LENGTH OF THIS POSITIONAL PDT.        01380000
         DC    XL1'&B'            NBR CNTRL BYTES/NBR BYTES COMPARE.    01400000
         MEND                                                           01420000
         MACRO                                                          01440000
         BBB   &A,&B,&C                                                 01460000
         DC    XL1'&A'            FUNCT/TABLE.                          01480000
         DC    AL1(&B)          OFFSET IN TABLE.                        01500000
         DC    XL1'&C'            BIT PATTERN.                          01520000
         MEND                                                           01540000
         MACRO                                                          01560000
         BBC   &A,&B,&C                                                 01580000
         DC    XL1'&A'            FUNCT/TABLE.                          01600000
         DC    AL1(&B)            OFFSET IN TABLE.                      01620000
         DC    AL1(&C)            BIT PATTERN.                          01640000
         MEND                                                           01660000
         TITLE 'IEFVJA - KEYS'                                          01680000
         IEFVKEYS                                                       01700000
         TITLE 'IEFVJA - IEFQMNGR'                                      01720000
         IEFQMNGR                                                       01740000
         TITLE 'IEFVJA - JCT'                                           01760000
JAJCT    DSECT                                                          01780000
JAACT    EQU   JAJCT                                                    01800000
         IEFAJCTB                                                       01820000
         TITLE 'IEFVJA - IWA'                                           01840000
         IEFVMIWA                                                       01860000
         TITLE 'IEFVJA - JWA'                                           01880000
         IEFVMJWA                                                       01900000
JAWORK   EQU   JWA                                                      01920000
         TITLE 'IEFVJA - JOB ROUTINE'                                   01940000
IEFVJA   CSECT                                                          01960000
* A-056373-056376, C-056240, D-056250                           SA65276 01960121
* C 069380,069390                                               SA63409 01960221
* A 053736-053791, C 053720,111296                               A43678 01960421
* 052800                                                          M1715 01961020
*2565 087600                                                      22297 01963018
*3259 030300,035800,051400,068000-069000,069400-069603,            AACA 01966017
*     089640-089760,094600-094760,104000,110000,111000-111375      AACA 01973017
*031430,031460                                                    M4137 01974018
* 094606,094630                                                   M0444 01976018
*********************************************************************** 01980000
*                                                                     * 02000000
*        INPUT TO THIS ROUTINE:                                       * 02020000
*                                                                     * 02040000
*              RC = ADDRESS OF INTERPRETER WORK AREA.                 * 02060000
*              RD = CURRENT REGISTER SAVE AREA.                       * 02080000
*                                                                     * 02100000
*********************************************************************** 02120000
         SPACE                                                          02140000
JAERMAX  EQU   X'25'              ERROR NBR USED TO INDEX TO ERROR RTN. 02160000
JAFORMAT EQU   32                 ERROR MSG NBR FO FORMAT ERROR.   287  02180000
JABADCLS EQU   39                 IEF639I INVALID CLASS DESIGNATION.    02184015
JAMISSIN EQU   46                 IEF646I ERROR MSG - POS PARAM MISSING 02188015
JAOUTABL EQU   128                ROLLOUTABLE FLAG.                     02192015
JACAUSER EQU   64                 CAUSE ROLLOUT FLAG.                   02196015
JAREGOFF EQU   92                 OFFSET TO REGION STORE SLOT IN JCT.   02200000
JALENGTH EQU   42            IEF642I - EXCESSIVE PARAMETER LENGTH  AACA 02210017
JAZERO   EQU   0                   ZERO DISPLACEMENT              M1715 02213020
LENZERO  EQU   X'00'               PARAM LENGTH ZERO              M1715 02216020
         SPACE 2                                                        02220000
         BALR  RB,0               REGISTER 11 IS THE BASE REGISTER      02240000
         USING *,RB                    OF THE JOB ROUTINE.              02260000
JABASE   EQU   *                                                        02280000
         B     JAA1               ********************                  02300000
         DC    X'9108'                                             AACA 02320017
         DC    X'11111111'                                              02340018
         DC    C'JA'                                                    02360000
         DC    C'L.07'      LEVEL NUMBER                                02370018
*                                 ********************                  02380000
         EJECT                                                          02400000
*********************************************************************** 02420000
**                                                                   ** 02440000
**             HEADER PORTION OF JOB ROUTINE.                        ** 02460000
**                                                                   ** 02480000
*********************************************************************** 02500000
*                                                                       02520000
*        REGISTER USAGE:                                                02540000
*                                                                       02560000
*              R5 = ERROR MESSAGE CODE REGISTER.                        02580000
*              R8 = JCT ADDRESSING.                                     02600000
*              R9 = ADDRESS OF TEST AND STORE.                          02620000
*              RA = LOCAL AND GET-T+S WORK AREA.                        02640000
*              RB = JOB ROUTINE BASE REGISTER.                          02660000
*              RC = INTERPRETER WORK AREA.                              02680000
*              RD = REGISTER SAVE AREA.                                 02700000
*              RE = LINK RETURN REGISTER.                               02720000
*              RF = ADDRESS OF GET KEY/POS ROUTINE.                     02740000
*                                                                       02760000
         SPACE                                                          02780000
JAA1     DS    0H                                                       02800000
         USING IWA,RC             IWA.                                  02820000
         L     RA,CTRLWAP         LOCAL WORK AREA                       02840000
         USING JAWORK,RA               ADDRESSING.                      02860000
         L     R9,JATESTOR        T AND S ADDRESS.                      02880000
         XC    JAWORK(JATEMP2+2-JAWORK),JAWORK   ZERO WORK AREA.        02900000
         L     RF,JAGETKEP        GET KEY/POS ADDRESS.                  02920000
         LA    R8,JCT             JCT                                   02940000
         USING JAJCT,R8                ADDRESSING.                      02960000
*                                                                       02980000
*   INITIALIZE JCT - JOBNAME SLOT TO BLANKS, DEFAULT MSGLEVEL,     I68  03000018
*        DEFAULT PRTY, INTERNAL JOB SER = 1,TYPRUN=SETUP, & JCT ID=0.   03020000
*        DEFAULT JOBCLASS=A, STEP NUMBER=1, CHECKPOINT ID TO BLANKSAACA 03030017
*                                                                       03040000
         MVI   JCTJNAME,C' '                                            03060000
         MVC   JCTJNAME+1(7),JCTJNAME  BLANK JOBNAME SLOT.              03080000
         MVI   JCTJSRNO,X'01'      SET INTERNAL JOB SER NBR TO 1        03100000
         MVC   JCTJMGPO(1),DMSCLAS GET DEFAULT MSGCLASS FROM IWA   AAAA 03120015
         MVN   JCTJPRTY(1),DINPRTY     DEFAULT PRTY TO JCT.             03140000
         MVI   QPARM+QMTPY-IOPARAMS,40 SET DEFAULT JOBCLASS=A      AAAA 03150015
         MVI   JCTSNUMB,X'01'     SET STEP NUMBER=1                AACA 03152017
         MVI   JCTCKIDT,C' '           * MOVE BLANKS INTO          AACA 03154017
         MVC   JCTCKIDT+1(15),JCTCKIDT * CHECKPOINT ID SLOT        AACA 03156017
         OC    JCTJMGLV,IWAJDJCL   SET JCL LEVEL DEFAULT IN JCT    I68  03157018
         OC    JCTJMGLV,IWAJDALL  SET ALLOC LEVEL DEFAULT IN JCT   I68  03158018
*                                                                       03160000
*   NOTE - IEFVHA ORIGINALLY ZEROES JCT, IEFVHH ZEROES JCT AFTER        03180000
*        EACH JOB STATEMENT.  THEREFORE, JCT ID IS ALREADY = 0,         03200000
*        AND TYPRUN = SETUP                                        I68  03220018
         SPACE                                                          03240000
*                                                                       03260000
*   CLEAR ACT                                                           03280000
*                                                                       03300000
         LA    R4,JACT            ACT ADDRESS.                          03320000
         XC    0(176,R4),0(R4)    ZERO 176 BYTE ACT.                    03340000
         MVI   ACTPRGNM-ACTDSKAD(R4),C' '   BLANK PGMNM SLOT.           03360000
         MVC   ACTPRGNM-ACTDSKAD+1(19,R4),ACTPRGNM-ACTDSKAD(R4)         03380000
*                                                                  AACA 03382017
* BLANK RESTART STEPNAME SLOT IN IWA, CLEAR CHKPT/RESTART SWITCHES AACA 03384017
*                                                                  AACA 03386017
         TM    SWH,CPSTPFL        IS C/R STEP FLUSH ON             AACA 03388017
         BO    JAAA1              BRANCH YES                       AACA 03390017
         MVC   IWAJOBS1(16),ACTPRGNM-ACTDSKAD(R4) USE BLANKS IN ACTAACA 03392017
*                                 TO BLANK OUT SLOT IN IWA              03394017
JAAA1    DS    0H                                                       03396017
         MVI   IWAINTS8,X'00'     CLEAR SWITCHES.                  AACA 03398017
*                                                                       03400000
*   ERROR MESSAGES SETUP.                                               03420000
*                                                                       03440000
         OI    JASW1,JANOJBNM+JANOPGNM+JANOACTN+JAACTPUT  SET ERROR SWS 03460000
         LA    R5,JAERMAX         SET ERROR MESSAGE REGISTER FOR        03480000
*                                      INDEXING ON ERROR RETURNS.       03500000
*                                                                       03520000
*   INITIALIZE DICTIONARY SWITCH FOR ENTRIES TO DICT 1 (SREFB).         03540000
*   CLEAR DDINO IN IWA (NECESSARY FOR JOBLIB WHEN NOT 1ST JOB).         03560000
*   CLEAR REGION AND ROLL SWITCHES IN IWA - CLEAR ROLL FIELD.      AACA 03570017
*   CLEAR REGION SPACE IN IWA.                                     AACA 03580017
*   SET NORESTART FLAG IN JCT - TO BE CLEARED IF RESTART SPECIFIED.AACA 03590017
*                                                                       03600000
         NI    SWD,FF-DCTFST-JOBREGNS-JOBROLLF  CLEAR SWITCHES IN SWD.  03606015
         MVI   IWAJBROL,X'00'     CLEAR ROLL FLAGS.                     03612015
*********************************************************************** 03618015
         MVI   DJBCLAS,C'O'  TEMPORARILY SET MAX DEFAULT CLASS.         03624015
*********************************************************************** 03630015
         OI    SWD,DBFST          TURN ON FIRST ENTRY DSENQ SW     750  03640000
         MVI   DDINO,X'00'        CLEAR NBR OF DD STMTS SLOT IN IWA.    03660000
         XC    IWAJOBS6(4),IWAJOBS6     CLEAR REGION SPACE.        AACA 03670017
*                                                                       03680000
*   INITIALIZE CORE FOR GET KEY/POS AND TEST & STORE.                   03700000
*                                                                       03720000
         LA    R7,JACLEANP        CLEANUP ADDRESS.                      03740000
         ST    R7,TCLEANUP                                              03760000
         LA    R7,JABRANCH        BRANCHING TABLE ADDRESS.              03780000
         ST    R7,TBRANCH                                               03800000
*                                                                       03820000
*   GET FIRST KEY.                                                      03840000
*                                                                       03860000
         BALR  RE,RF              GO TO GET FIRST KEY.                  03880000
         EJECT                                                          03900000
*********************************************************************** 03920000
*                                                                     * 03940000
*              JOB KEY PROCESSING.                                    * 03960000
*                                                                     * 03980000
*********************************************************************** 04000000
JAJOB    DS    0H                                                       04020000
*                                                                       04040000
*   JOBNAME.                                                            04060000
*                                                                       04080000
         BALR  RE,R9              GO TO TEST AND STORE JOBNAME.         04100000
*                                                                       04120000
*   ACCOUNT NUMBER.                                                     04140000
*                                                                       04160000
         BALR  RE,RF              GET NEXT POSITIONAL - ACCOUNT NBR.    04180000
         SPACE                                                          04200000
         LA    R7,JACT+ACTJNFLD-ACTDSKAD+1  ADDR OF ACCNT FIELD TO R7.  04220000
         LA    R0,1               CNTR1 = NBR OF ACCNT FIELDS.          04240000
         L     R6,TNUM1           CNTR2 = TOTAL LENGTH ACCNT FIELD.     04260000
         LTR   R2,R2              NULL PARAMETER.                       04280000
         BZ    JAC3               YES. GO CHECK FOR ACCNTING INFO.      04300000
         SPACE                                                          04320000
         NI    JASW1,X'FF'-JANOACTN-JAACTPUT     TURN OFF NO ACT SW &   04340000
*                                           NO ACT PUT SWITCH.          04360000
         EX    R2,JAJOBMV1        MOVE LENGTH AND ACNT NBR TO ACT.      04380000
         AR    R6,R2                   OF ACNT FIELDS + LENGTH.         04400000
JAC3     DS    0H                                                       04420000
         LA    R7,1(R7,R2)        POINT TO NEXT ACT STORE POSITION.     04440000
         CLC   TNUM1,TCT1         ACCOUNTING INFO TO STORE.             04460000
         BE    JAE2               NO GO TO GET NEXT POSITIONAL.         04480000
         SPACE                                                          04500000
         BALR  RE,RF              GET POSITIONAL - ACCOUNTING INFO.     04520000
         SPACE                                                          04540000
         A     R0,JA1             INCREMENT CNTR1 BY ONE.               04560000
         LTR   R2,R2              IS THIS A NULL PARAMETER.             04580000
         BZ    JAC3               NO.  GO GET NEXT POSITIONAL.          04600000
         SPACE                                                          04620000
         AR    R6,R2              ADD LENGTH TO CNTR 2.                 04640000
         NI    JASW1,X'FF'-JAACTPUT    TURN OFF NO ACT TO PUT SW.       04660000
         CL    R6,JA144           DOES TOTAL ACCNTING FIELD EXCEDE 144. 04680000
         BH    JAER6              YES. -ERROR- ACCNT FIELD EXCEDES 144. 04700000
         SPACE                                                          04720000
         EX    R2,JAJOBMV1        NO. MOVE ACTNG INFO TO ACT.           04740000
         SPACE                                                          04760000
         B     JAC3               GO TO CHECK FOR MORE ACTNG INFO.      04780000
         SPACE                                                          04800000
JAE2     DS    0H                                                       04820000
         STC   R0,JACT+ACTJNFLD-ACTDSKAD   STORE NBR ACCNT FIELDS.      04840000
         SPACE                                                          04860000
*                                                                       04880000
*   PROGRAMMER NAME.                                                    04900000
*                                                                       04920000
         BALR  RE,RF              GET NEXT POSITIONAL - PROG NAME.      04940000
         SPACE                                                          04960000
         BALR  RE,R9              TEST AND STORE PROGRAMMER NAME.       04980000
         SPACE                                                          05000000
         BALR  RE,RF              GO GET NEXT KEY.                      05020000
         SPACE                                                          05040000
JAJOBMV1 MVC   0(1,R7),0(R3)      MOVE ACNTNG FIELDS TO ACT (EXECUTED). 05060000
         EJECT                                                          05080000
*********************************************************************** 05100000
*                                                                     * 05120000
*              TYPRUN/MSGLEVEL/MSGCLASS/RD KEY PROCESSING.         AACA 05140017
*                                                                     * 05160000
*********************************************************************** 05180000
JARD     DS    0H                                                 M1715 05182020
         CLI   JAZERO(R3),LENZERO      PARAMETER LENGTH ZERO?     M1715 05184020
         BE    JAER1                   YES-ERROR CONDITION.       M1715 05186020
JANOTIFY DS    0H                                                 20001 05190020
JATYP    DS    0H                                                       05200000
JAMSCL   DS    0H                                                       05240000
         BALR  RE,R9              TEST AND STORE.                       05320000
         BALR  RE,RF              GO TO GET NEXT KEY               I68  05321018
JAMSLV   DS    0H   PARM OR SYSGEN DEFAULT VALUES ARE ALREADY SET  I68  05322018
         LTR   R2,R2          IS LENGTH OF JCL LEVEL ZERO          I68  05323018
         BZ    JAMSLGET       YES - GO GET ALLOCATION LEVEL        I68  05324018
         NI    JCTJMGLV,X'8F' NO - CLEAR DEFAULT JCL LEVEL         I68  05325018
JAMSLGET BALR  RE,R9                   TEST AND STORE             M3309 05326018
         BALR  RE,RF                   GET NEXT KEY               M3309 05327018
         LTR   R2,R2          IS LENGTH OF ALLOCATION LEVEL ZERO   I68  05328018
         BZ    JAMSLOUT       YES - BRANCH NO MORE MSGLEVEL PROCESSING  05329018
         NI    JCTJMGLV,X'7F' NO - CLEAR DEFAULT ALLOCATION LEVEL  I68  05330018
         BALR  RE,R9          GO TO TEST AND STORE                 I68  05331018
JAMSLOUT BALR  RE,RF          GO TO GET NEXT KEY                   I68  05332018
         SPACE                                                          05340000
         EJECT                                                          05360217
*******************************************************************AACA 05360417
*                                                                  AACA 05360617
*              RESTART KEY PROCESSING.                             AACA 05360817
*                                                                  AACA 05361017
*******************************************************************AACA 05361217
JAREST   DS    0H                                                  AACA 05361417
*                                                                  AACA 05361617
*        IF RESTART=STEPNAME OR STEPNAME.PROCSTEPNAME, IEFVGT      AACA 05361817
*        CHECKS 1ST CHARACTER ALPHA AND TEMPORARILY MOVES UP TO 17 AACA 05362017
*        BYTES TO SRCHL1.  (THIS IS A REFERBACK WORK AREA WHICH IS AACA 05362217
*        NOT USED DURING JOB STATEMENT PROCESSING.)  ALSO          AACA 05362417
*        SETS BITS JATCKPTR AND JATSTEPR IN JCT. IF THERE IS A CHECKID, 05362617
*        JATSTEPR IS TURNED OFF AND UP TO 16 BYTES ARE MOVED TO    AACA 05362817
*        JATCKIDT OF JCT.  JATCKIDL IS SET BY STC OF R2.           AACA 05363017
         TM    CRSW1,CRIMRS       IS IT PCP AUTOMATIC RESTART      AACA 05363217
         BO    JAREST5            YES, BYPASS KEYWORD PROCESSING   AACA 05363417
         OI    SWH,CPFLGXX        INDICATE RESTART                 AACA 05363617
         LTR   R2,R2              1ST PARAMETER IS REQUIRED.       AACA 05363817
         BZ    JAER1              NOT THERE - ERROR.               AACA 05364017
         CLI   1(R3),C'*'         IS IT RESTART = *.               AACA 05364217
         BNE   JAREST1            NO. GO CHECK STEPNAME            AACA 05364417
         C     R2,JA1             ONE CHARACTER ONLY.              AACA 05364617
         BNE   JAER1              NO - ERROR.                      AACA 05364817
         ST    R4,TPDTP           * SET UP PDT POINTERS FOR GT SO  AACA 05365017
         LA    R6,JAST5           * THAT IT WILL LOOK AT 2ND ENTRY AACA 05365217
         ST    R6,TCPDTP          * IN RESTART PDT BYPASSING 1ST.  AACA 05365417
         MVI   IWAJOBS3,C'*'      INDICATE CHECKPOINT IS 1ST STEP. AACA 05365617
         B     JAREST5            GO TO PROCESS CHECKID.           AACA 05365817
         SPACE                                                          05366017
JAREST1  DS    0H                                                  AACA 05366217
         BALR  RE,R9         ERROE CHECK STEPNAME & MVC TO SRCHL1  AACA 05366417
         SPACE                                                          05366617
         LA    R4,8          SET UP FOR SCAN OF STEPNAME.PROCSTEP  AACA 05366817
         LR    R6,R2              TOTAL LENGTH.                    AACA 05367017
         LR    R7,R3              POINTER TO PARAMETER.            AACA 05367217
JAREST2  DS    0H                                                  AACA 05367417
         CLI   1(R3),C'.'         SCAN FOR PERIOD.                 AACA 05367617
         BE    JAREST3       STEPNAME.PROCSTEP - GO SAVE STEPNAME  AACA 05367817
         LA    R3,1(R3,0)         NO HIT - POINT AT NEXT BYTE.     AACA 05368017
         BCT   R6,JAREST2         DECREMENT COUNT AND TRY AGAIN.   AACA 05368217
         LR    R6,R2              STEPNAME.   - RESTORE R6.        AACA 05368417
         B     JAREST4            GO TO SAVE STEPNAME.             AACA 05368617
JAREST3  DS    0H                                                  AACA 05368817
         SR    R2,R6         DETERMINE LENGTH OF CALLING STEPNAME  AACA 05369017
         CLR   R2,R4                                               AACA 05369217
         BH    JAER1                                               AACA 05369417
         BCTR  R2,0                                                AACA 05369617
         EX    R2,JARESTM1        MOVE CALLING STEPNAME TO IWAJOBS1AACA 05369817
         LA    R7,1(R3)           POINT R7 AT PROCSTEP-1.          AACA 05370017
         BCTR  R6,0               DECREMENT BECAUSE OF PERIOD.     AACA 05370217
JAREST4  DS    0H                                                  AACA 05370417
         CLR   R6,R4              DOES STEPNAME EXCEED 8 CHARACTERSAACA 05370617
         BH    JAER1              YES - ERROR                      AACA 05370817
         BCTR  R6,0               DECREMENT FOR EX STMT.           AACA 05371017
         EX    R6,JARESTM2   MOVE STEPNAME OR PROCSTEP TO IWAJOBS3 AACA 05371217
JAREST5  DS    0H                                                  AACA 05371417
         BALR  RE,RF              GET CHECKID.                     AACA 05371817
         SPACE 1                                                        05371921
*****************************************************************A43678 05373621
*              THE CHECKID MAY BE UP TO 16 CHARACTERS LONG AND   A43678 05374021
*              CONSIST OF ALPHAMERIC,PRINTABLE SPECIAL CHARACTERSA43678 05376021
*              AND BLANKS IN ANY COMBINATION.THEREFORE,THE PDT   A43678 05376421
*              CHECKS ONLY THE LENGTH AND HAS A VALID PARAMETER  A43678 05376821
*              MOVED INTO THE JCT.                                      05377621
*****************************************************************A43678 05379121
         SPACE 1                                                        05382021
         BALR  RE,R9              MOVE CHECKID TO JCT.           A43678 05385221
         TM    CRSW1,CRIMRS       IS IT PCP AUTOMATIC RESTART      AACA 05388121
         BO    JAREST6            YES                              AACA 05391021
         STC   R2,JCTCKIDL        IF NOT SAVE CHECKID LENGTH IN JCTAACA 05393921
JAREST6  NI    CRSW1,255-CRIMRS   TURN OFF PCP AUTOMATIC RESTART SWAACA 05396821
*                                                                  AACA 05399721
         BALR  RE,RF              GET NEXT KEYWORD                 AACA 05402621
         SPACE 2                                                        05405521
JARESTM1 MVC   IWAJOBS1(1),1(R7)       EXECUTED.                   AACA 05408421
JARESTM2 MVC   IWAJOBS3(1),1(R7)       EXECUTED.                   AACA 05411321
         EJECT                                                          05414221
*********************************************************************** 05417121
*                                                                     * 05420000
*              PRTY KEY PROCESSING.                                   * 05440000
*                                                                     * 05460000
*********************************************************************** 05480000
JAPRTY   DS    0H                                                       05500000
         SPACE                                                          05520000
         BALR  RE,R9              TEST AND STORE PRTY.                  05540000
         SPACE                                                          05560000
         MVN   JCTJPRTY(1),JATEMP1     MOVE PRTY TO JCT.                05580000
         SPACE                                                          05600000
         BALR  RE,RF              GET NEXT KEY.                         05620000
*********************************************************************** 05621018
*                            TIME KEY PROCESSING                      * 05622018
*********************************************************************** 05623018
JATIME   EQU   *                                                SA65276 05624021
         BALR  RE,R9                   CONVETT MIN TO BINARY       SMF1 05626018
         CLC   TNUM(DEC4),TCT          ARE ALL SUB PARAMS DONE     SMF1 05627018
         BE    JATIME1                 YES                         SMF1 05628018
         BALR  RE,RF                   NO, GO GET 2ND ONE (SECS)   SMF1 05629018
         BALR  RE,R9                   AND CONVERT TO BINARY       SMF1 05630018
JATIME1  L     R6,JCTJMRSS+DEC1        *                           SMF1 05631018
         MH    R6,JA6000               MIN TO 1/100 SECS           SMF1 05632018
         L     R7,JCTJMRSS+DEC5        *                           SMF1 05633018
         MH    R7,JA100                SECS TO 1/100 SECS          SMF1 05634018
         AR    R6,R7                   ADD TOGETHER                SMF1 05635018
         SLL   R6,DEC8                 SHIFT LEFT ONE BYTE         SMF1 05636018
         ST    R6,JCTJMRTL             AND STORE                   SMF1 05637018
         XC    JCTJMRSS+DEC1(DEC8),JCTJMRSS+DEC1                SA65276 05637321
* CLEAR THE FIELDS IN THE JCT USED FOR WORK AREA.               SA65276 05637621
         BALR  RE,RF                   AND GO AWAY FOR NEXT        SMF1 05638018
*                                           KEYWORD                SMF1 05639018
         EJECT                                                          05640000
*********************************************************************** 05660000
*                                                                     * 05680000
*              COND KEY PROCESSING                                    * 05700000
*                                                                     * 05720000
*********************************************************************** 05740000
JACOND   DS    0H                                                       05760000
         SPACE                                                          05780000
         LA    R7,JCTJDPCD        DEPENDENCY CODE ADDR TO R7.           05800000
JBB2     DS    0H                                                       05820000
         OI    JASW1,JACONDER     SET COND ERROR FLAG.                  05840000
*                                                                       05860000
*   DEPENDENCY CODE                                                     05880000
*                                                                       05900000
         BALR  RE,R9              TEST & STORE CODE. (TEMP1)            05920000
*                                                                       05940000
*   CHECK FOR THE COND AS A SUBPARAMETER. (PROPER NBR PARENTHESIS).     05960000
*                                                                       05980000
         BCTR  R3,0               POINT TO BYTE BEFORE TLENP. HOPEFULLY 06000000
*                                      IT IS THE SUBPARAMETER BYTE.     06020000
         SR    R2,R2                                                    06040000
         IC    R2,0(R3)           PICK UP BYTE.                         06060000
         SRL   R2,4               SHIFT TO GET HIGH ORDER BITS ONLY.    06080000
         X     R2,JAMSK1          CHECK FOR SUBPARM INDICATOR ONLY.     06100000
         BC    4,JAER1            IF OTHER BITS ON NOT SUBPARM -ERROR-  06120000
*                                                                       06140000
*   DEPENDENCY OPERATOR                                                 06160000
*                                                                       06180000
         BALR  RE,RF              GET OPERATOR.                         06200000
         SPACE                                                          06220000
         LTR   R2,R2              IS THERE AN OPERATOR.                 06240000
         BZ    JAER1              NO. ERROR.                            06260000
         SPACE                                                          06280000
         CLC   TNUM1(4),TCT1      ARE THERE MORE PARAMS IN COND FIELD.  06300000
         BNE   JAER1              YES. ERROR.                           06320000
         SPACE                                                          06340000
         XC    JATEMP2(2),JATEMP2      ZERO TEMP2 FOR OR OF OP CODE.    06360000
*                                                                       06380000
*   DEPENDENCY OPERATOR                                                 06400000
*                                                                       06420000
         BALR  RE,R9              TEST & STORE OPERATOR. (TEMP 2)       06440000
         SPACE                                                          06460000
         ST    RB,TPDTP           SPOIL PDTP SO THAT T&S WILL START AT  06480000
*                                      TOP AND CYCLE THRU TABLE AGAIN.  06500000
         MVC   0(4,R7),JATEMP1    MOVE CODE & OPERATOR TO JCT.          06520000
         LA    R7,4(R7,0)         INCREMENT TO NEXT STORE POSITION.     06540000
         NI    JASW1,X'FF'-JACONDER    TURN OFF COND ERROR FLAG.        06560000
         SPACE                                                          06580000
         BALR  RE,RF              GO TO GET NEXT COND CODE OR NEXT KEY. 06600000
         SPACE                                                          06620000
         B     JBB2               IF ANOTHER COND GO TO PROCESS.        06640000
         EJECT                                                          06660000
*********************************************************************** 06680000
*                                                                     * 06700000
*              REGION KEY PROCESSING.                                 * 06720000
*                                                                     * 06740000
*********************************************************************** 06760000
JAREG    DS    0H                                                       06780000
         LTR   R2,R2              IS PRIMARY REGION SPECIFIED      AACA 06810017
         BZ    JAREG01            NO-GO GET NEXT KEY               AACA 06840017
         BAL   RE,JAREG1          CHECK HIGH SPEED REGION SYNTAX.  AACA 06870017
         BALR  RE,R9              LINK TO TEST NUMERICS, CVB & MVC-JCT. 06920000
         MVC   IWAJOBS6(2),JAREGOFF(R8) MOVE REGION TO IWA FOR SCT.AACA 06921017
         SPACE                                                          06922017
JAREG01  DS    0H                                                  AACA 06923017
         ST    R4,TPDTP           * SET UP PDT POINTERS FOR GT SO  AACA 06924017
         LA    R6,JAREGB+1        * THAT IT WILL LOOK AT 2ND ENTRY AACA 06925017
         ST    R6,TCPDTP          * IN REGION PDT, BYPASSING 1ST.  AACA 06926017
         BALR  RE,RF                                               AACA 06927017
         SPACE                                                          06928017
         BAL   RE,JAREG1          CHECK LCS.                       AACA 06929017
         BALR  RE,R9              CVB & MOVE TO JATEMP1.           AACA 06930017
         MVC   IWAJOBS6+2(2),JATEMP1 MOVE LCS REGION TO IWA FOR SCTAACA 06931017
         BALR  RE,RF              GET NEXT KEY.                    AACA 06932017
         SPACE                                                          06933017
JAREG1   DS    0H                                                  AACA 06934017
         LA    R6,0(R2,R3)        CHECK FOR REGION OF XXXXXK.      AACA 06935017
         CLI   0(R6),C'K'                                          AACA 06936017
         BNE   JAER1              NO 'K'.  GO TO ERROR.            AACA 06937017
         BCTR  R2,RE            DECREMENT R2 TO GET NBRS ONLY   SA63409 06938021
         B     JAER1            R2=0  FORMAT ERROR.             SA63409 06939021
         EJECT                                                          06940017
*********************************************************************** 06960615
*                                                                     * 06960915
*                                                                     * 06961215
*              ROLL KEY PROCESSING.                                   * 06961515
*                                                                     * 06961815
*********************************************************************** 06962115
JAROLL   DS    0H                                                       06962415
         SPACE                                                          06962715
         LTR   R2,R2              IS ROLLOUTABLE SPECIFIED.             06963015
         BZ    JAER7              NO - EIF646I REQ POS PARAM MISSING.   06963315
         MVI   JATEMP1,X'00'      SET TEMP FLAGS BYTE TO ZEROES.        06963615
         BALR  RE,R9              CHECK YES/NO & SET BITS.              06963915
         SPACE                                                          06964215
         CLC   TNUM(4),TCT        IS CAUSEROLLOUT SPECIFIED.            06964515
         BE    JAER7              NO - IEF646I REQ POS PARAM MISSING.   06964815
         SPACE                                                          06965115
         BALR  RE,RF              GET PARAM.                            06965415
         BALR  RE,R9              CHECK YES/NO & SET BITS.              06965715
         MVC   IWAJBROL(1),JATEMP1     MOVE ROLL FLAGS TO IWA.          06966015
         OI    SWD,JOBROLLF       SET ROLL ON JOB STMT FLAG.            06966115
         SPACE                                                          06966315
         BALR  RE,RF              GET NEXT KEYWORD.                     06966615
         EJECT                                                          06966915
*********************************************************************** 06967215
*                                                                     * 06967515
*              CLASS KEY PROCESSING.                                  * 06967815
*                                                                     * 06968115
*********************************************************************** 06968415
JACLASS  DS    0H                                                       06968715
         SPACE                                                          06969015
         LA    R6,40              SET R6 FOR JOBCLASS CODE OF 'A'.      06969315
         LA    R7,JACLASSS-1      POINT R7 AT TABLE OF CLASS ENTRIES.   06969615
JACLASS1 DS    0H                                                       06969915
         CLC   0(1,R7),1(R3)      IS THIS THE CORRECT CLASS.            06970215
         BE    JACLASS2           YES. GO TO STORE CLASS CODE IN QMTPY. 06970515
         LA    R6,1(R6,0)         NO. INCREMENT TO NEXT CLASS CODE.     06970815
         BCTR  R7,0               POINT TO NEXT CLASS.                  06971115
         CLC   0(1,R7),DJBCLAS    HAVE WE EXCEDED SYSTEM MAX.           06971415
         BNH   JACLASS1           NO. GO TO SCAN NEXT TABLE CLASS.      06971715
*   JOBCLASS SPECIFIED NOT IN RANGE LIMIT OF SYSTEM.                    06972015
         MVI   MSGSEC,JABADCLS    SET MSG NBR FOR IEF639I               06972315
         B     JACLEANP           GO TO CLEANUP.                        06972615
         SPACE 3                                                        06972915
JACLASS2 DS    0H                                                       06973215
         BALR  RE,R9              TEST FOR ONE BYTE ONLY.               06973515
         STC   R6,QPARM+QMTPY-IOPARAMS  SET JOBCLASS CODE.              06973815
         BALR  RE,RF              GO TO GET NEXT KEYWORD.               06974115
         SPACE 3                                                        06974415
         DC    X'FF'              END OF TABLE ERROR CHECK.             06974715
         DC    C'9876543210'      TABLE                                 06975015
         DC    C'ZYXWVUTS'             OF                               06975315
         DC    C'RQPONMLKJ'              JOBCLASSES.                    06975615
         DC    C'IHGFEDCBA'                                             06975915
JACLASSS DS    0C                                                       06976215
         EJECT                                                          06980000
*********************************************************************** 07000000
**                                                                   ** 07020000
**             CLEANUP PORTION OF JOB ROUTINE.                       ** 07040000
**                                                                   ** 07060000
*********************************************************************** 07080000
JACLEANP DS    0H                                                       07100000
*                                                                       07120000
*   ERROR CHECK.                                                        07140000
*                                                                       07160000
         CLI   MSGSEC,X'00'       IS ERROR FLAG EQUAL ZERO.             07180000
         BNE   JAERRTN            NO - ERROR.                           07200000
*                                                                       07220000
*   JOBNAME CHECK.                                                      07240000
*                                                                       07260000
JAE1     DS    0H                                                       07280000
         TM    JASW1,JANOJBNM     IS THE NO JOBNAME SWITCH ON.          07300000
         BO    JAER4              YES. -ERROR- -NO JOBNAME-             07320000
*                                                                       07340000
*   CONDITION CHECK.                                                    07360000
*                                                                       07380000
         MVI   MSGKEY,CONDJK      SET SECONDARY MESSAGE FOR COND.       07400000
         TM    JASW1,JACONDER     IS THE CONDITION ERROR SWITCH ON.     07420000
         BO    JAER1              YES. -ERROR- -OPERATOR MISSING-       07440000
*                                                                       07460000
*   CHECK FOR ACCOUNT NUMBER OR PROGRAMMER NAME NEEDED AND MISSIOG.     07480000
*                                                                       07500000
         TM    JASW1,JANOPGNM     IS THERE A PROGRAMMER NAME.           07520000
         BZ    JAE12              YES. GO TO CHECK ACCNT NBR.           07540000
         SPACE                                                          07560000
         TM    OSW1,FAIL1         NO PROG. NAME.  IS IT REQUIRED.       07580000
         BO    JAER2              YES. ERROR -PROGRAMMER NAME MISS-     07600000
         SPACE                                                          07620000
JAE12    DS    0H                                                       07640000
         TM    JASW1,JANOACTN     IS THERE AN ACCOUNT NUMBER.           07660000
         BZ    JAACTCK            YES. GO TO PUT OUT ACT.               07680000
         SPACE                                                          07700000
         TM    OSW1,FAIL2         NO ACTNBR.  IS IT REQUIRED.           07720000
         BO    JAER3              YES. -ERROR-  -ACT NBR MISSING-       07740000
*                                                                       07760000
*   ACT TO PUT OUT.                                                     07780000
*                                                                       07800000
JAACTCK DS     0H                                                       07820000
         LA    R4,JACT            JOB ACT ADDRESS TO R4.                07840000
         MVC   0(3,R4),TNEXT      DISK ADDR THIS ACT TO ACT.            07860000
         MVI   3(R4),ACTID        ACT IDENT = 1.                        07880000
         LA    R7,QPARM           Q-MANAGER PARAMETER AREA.             07900000
         USING IOPARAMS,R7             LIST ADDRESSING.                 07920000
         L     R6,QMPCL           QMPCA ADDRESS TO R6.                  07940000
         ST    R4,0(R6)           ACT ADDRESS TO QMPCA.                 07960000
         MVC   4(4,R6),TNEXT      TTR TO QMPEX.                         07980000
         L     RF,JAVHQ           IEFVHQ ADDRESS TO R15.                08000000
         SPACE                                                          08020000
         BALR  RE,RF              LINK TO QMANAGER TO WRITE AND ASSIGN. 08040000
         SPACE                                                          08060000
         MVC   JCTACTAD(4),TNEXT  MOVE ACT TTR TO JCT.                  08080000
         MVC   TNEXT(4),0(R6)     REPLACE TTR IN IWA.                   08100000
*   FALL THROUGH TO EXIT.                                               08120000
         SPACE                                                          08140000
*                                                                       08160000
*   EXIT TO IEFVHF.                                                     08180000
*                                                                       08200000
JAEXIT   DS    0H                                                       08220000
         SPACE                                                          08240000
         L     RF,JAVHF           IEFVHF ADDRESS TO R15.                08260000
         SPACE                                                          08280000
         BR    RF                 ***   EXIT   ***                      08300000
         EJECT                                                          08320000
*********************************************************************** 08340000
**                                                                   ** 08360000
**             ERROR ROUTINES.                                       ** 08380000
**                                                                   ** 08400000
*********************************************************************** 08420000
         SPACE                                                          08440000
JAER2    BCTR  R5,0               IEF633I - PROGRAMMER NAME MISSING.    08460000
JAER3    BCTR  R5,0               IEF634I - ACCOUNT NUMBER MISSING.     08480000
JAER4    BCTR  R5,0               IEF635I - JOBNAME MISSING.            08500000
JAER5    BCTR  R5,0               NOT USED BY IEFVJA.                   08520000
JAER6    STC   R5,MSGSEC          IEF637I - ACCT FIELD EXCEEDS MAXIMUM. 08540000
*                                      MSG NBR IS STORED INTO IWA.      08560000
         MVI   MSGKEY,JOBK        SET MSGKEY TO JOB KEY.                08580000
         SPACE                                                          08600000
*                                                                       08620000
*   FAIL JOB - ENTER MESSAGE INTO SMB.                                  08640000
*                                                                       08660000
JAERRTN  DS    0H                                                       08680000
         OI    JCTJSTAT,INCMSTS   FAIL JOB.                             08700000
         OI    JCTJMGLV,INCMMGL1  DEFAULT TO MESSAGE LEVEL = 1.         08720000
         SPACE                                                          08740000
         CLI   JCTJNAME,C' '      TEST FOR JOBNAME IN JCT         22297 08746018
         BNE   JAERMSG             YES,GO PUT OUT MESSAGE         22297 08752018
         MVC   JCTJNAME(8),JAERDUM  NO,PUT DUMMY NAME IN JCT      22297 08758018
*                                       THEN GO PUT OUT MESSAGE   22297 08764018
JAERMSG  SR    R2,R2                                              22297 08770018
         IC    R2,MSGSEC          MSG NBR TO R2.                        08780000
         L     RF,JAVGM           IEFVGM ADDRESS TO R15.                08800000
         SPACE                                                          08820000
         BALR  RE,RF              LINK TO MESSAGE MODULE.               08840000
         SPACE                                                          08860000
         B     JAACTCK            GO TO PUT OUT ACT & EXIT.             08880000
         SPACE 2                                                        08900000
JAER1    DS    0H                                                       08920000
         MVI   MSGSEC,JAFORMAT    SET MESSAGE FOR FORMAT ERROR.         08940000
         B     JAERRTN                                                  08960000
         SPACE 3                                                        08962017
JAER7    DS    0H                                                  AACA 08964017
         MVI   MSGSEC,JAMISSIN    IEF646I - REQ POS PARAM MISSING. AACA 08966017
         B     JAERRTN                                             AACA 08968017
         SPACE 3                                                   AACA 08970017
JAER8    DS    0H                                                  AACA 08972017
         MVI   MSGSEC,JALENGTH IEF642I-EXCESSIVE PARAMETER LENGTH  AACA 08974017
         B     JAERRTN                                             AACA 08976017
         EJECT                                                          08980000
*********************************************************************** 09000000
**                                                                   ** 09020000
**             TABLES FOR JOB ROUTINE.                               ** 09040000
**                                                                   ** 09060000
*********************************************************************** 09080000
*                                                                       09100000
*   BRANCHING TABLE FOR GET KEY/POS.                                    09120000
*                                                                       09140000
         SPACE                                                          09160000
JABRANCH DS    0H                                                       09180000
JAJOBA   EQU   *                  JOB KEY.                              09200000
         KKK   03,01000000,JAJOB-JABASE,JAJOBB-JABASE                   09220000
JAMSLVA  EQU   *                  MSGLEVEL KEY.                         09240000
         KKK   02,00000000,JAMSLV-JABASE,JAMSLVB-JABASE            I68  09260018
JAMSCLA  EQU   *                  MSGCLASS KEY.                         09280000
         KKK   01,00000000,JAMSCL-JABASE,JAMSCLB-JABASE                 09300000
JATYPA   EQU   *                  TYPRUN KEY.                           09320000
         KKK   01,00000000,JATYP-JABASE,JATYPB-JABASE                   09340000
JAPRTYA  EQU   *                  PRTY KEY.                             09360000
         KKK   01,00000000,JAPRTY-JABASE,JAPRTYB-JABASE                 09380000
JACONDA  EQU   *                  COND KEY.                             09400000
         KKK   08,11111111,JACOND-JABASE,JACONDB-JABASE                 09420000
JAREGA   EQU   *                  REGION KEY.                           09440000
         KKK   02,0,JAREG-JABASE,JAREGB-JABASE                     AACA 09444017
JACLASSA EQU   *                  CLASS KEY.                       AACA 09448017
         KKK   01,0,JACLASS-JABASE,JACLASSB-JABASE                 AACA 09452017
JAROLLA  EQU   *                  ROLL KEY.                        AACA 09456017
         KKK   02,0,JAROLL-JABASE,JAROLLB-JABASE                   AACA 09460017
JARDA    EQU   *                  RD KEY.                          AACA 09464017
         KKK   01,0,JARD-JABASE,JARDB-JABASE                       AACA 09468017
JARESTA  EQU   *                  RESTART KEY.                     AACA 09472017
         KKK   02,0,JAREST-JABASE,JARESTB-JABASE                   AACA 09476017
JATIMEA  EQU   *                       TIME KEY               M0444SMF1 09477018
         KKK   02,00000000,JATIME-JABASE,JATIMEB-JABASE       M0444SMF1 09478018
JANOTIFA EQU   *                  NOTIFY KEY                      20001 09478620
         KKK   01,0,JANOTIFY-JABASE,JANOTIFB-JABASE               20001 09479220
         EJECT                                                          09480000
*                                                                       09500000
*   PARAMETER DESCRIPTER TABLE FOR TEST AND STORE (PDT).                09520000
*                                                                       09540000
         SPACE                                                          09560000
JAJOBB   EQU   *                  JOB PDT.                              09580000
         DC    FL1'17'            LENGTH OF PDT FOR JOB.                09600000
*   JOBNAME                                                             09620000
         CCC   8,50                                                     09640000
         MMM   8,61,JCTJNAME-INJMJCT                                    09660000
         BBC   40,JASW1-JAWORK,FF-JANOJBNM                              09680000
*   PROGRAMMER NAME.                                                    09700000
         CCC   8,50                                                     09720000
         MMM   20,53,ACTPRGNM-ACTDSKAD                                  09740000
         BBC   40,JASW1-JAWORK,FF-JANOPGNM-JAACTPUT                     09760000
         SPACE                                                          09780000
JATYPB   EQU   *                  TYPRUN PDT.                           09800000
         DC    AL1(JATYPEND-JATYPB)    LENGTH OF PDT             244    09810015
JATYPST  EQU   *                                                 244    09820015
         DC    AL1(JATYPEND-JATYPST)   LENGTH OF FIRST POSITION. 244    09830015
*   HOLD                                                         244    09840015
         SSS   34,HOLD                                           244    09850015
         BBC   01,JCTJSTAT-INJMJCT,INCMNSET                      244    09860015
*   NONSETUP                                                     244    09870015
         SSS   08,NONSETUP                                       244    09880015
*   SETUP                                                               09920000
         SSS   05,SETUP                                                 09940000
JATYPEND EQU   *                                                 244    09950015
         SPACE                                                          09960000
JAMSLVB  EQU   *                  MSGLEVEL PDT.                         09980000
         DC    AL1(MSLENDX-JAMSLVB)     LENGTH OF MSGLEVEL PDT     I68  09983018
JAMSLVC  DC    AL1(JAMSLVD-JAMSLVC)     LENGTH OF FIRST POSITIONAL PDT  09986018
*   TWO        JCL LEVEL                                           I68  09989018
         SSS   31,2                                                I68  09992018
         BBC   01,JCTJMGLV-INJMJCT,INCMMGL2                        I68  09995018
*   ONE                                                                 10040000
         SSS   31,1                                                     10060000
         BBC   01,JCTJMGLV-INJMJCT,INCMMGL1                             10080000
*   ZERO                                                                10100000
         SSS   01,0                                                     10120000
JAMSLVD  DC    AL1(MSLENDX-JAMSLVD)     LENGTH OF SECOND POSITIONAL PDT 10122018
*   ONE        ALLOCATION LEVEL                                    I68  10124018
         SSS   31,1                                                I68  10126018
         BBC   01,JCTJMGLV-INJMJCT,INCMALL                         I68  10128018
*   ZERO                                                           I68  10130018
         SSS   01,0                                                I68  10132018
MSLENDX  EQU   *                                                   I68  10134018
         SPACE                                                          10140000
JAMSCLB  EQU   *                  MSGCLASS PDT.                         10160000
         DC    FL1'7'             LENGTH OF MSGCLASS PDT.               10180000
         CCC   6,30                                                     10200000
         DC    FL1'1'             MAX PARAMETER LENGTH.                 10220000
         DC    XL1'70'            FUNCT/TABLE.                          10240000
         DC    XL1'51'            FUNCT/TABLE.                          10260000
         DC    AL1(JCTJMGPO-INJMJCT)   OFFSET IN TABLE.                 10280000
         SPACE                                                          10300000
JAPRTYB  EQU   *                  PRTY PDT.                             10320000
         DC    FL1'7'             LENGTH OF PRTY PDT.                   10340000
         CCC   6,30                                                     10360000
         DC    XL1'02'            MAXIMUM PARAMETER LENGTH.             10380000
         DDD   10,JATEMP1-JAWORK,1,13                              AACA 10400017
JATIMEB  EQU   *                       TIME PDT                    SMF1 10402018
         DC    FL1'17'                 LENGTH OF TIME PDT          SMF1 10404018
         CCC   8,50                                                     10406018
         MMM   4,31,JCTJMRSS+2-INJMJCT                                  10408018
         DC    FL3'1440'               MAXIMUM NUMBER OF MINUTES   SMF1 10410018
         CCC   8,50                                                     10412018
         MMM   2,31,JCTJMRSS+6-INJMJCT                                  10414018
         DC    FL3'59'                 MAXIMUM NUMBER OF SECONDS   SMF1 10416018
JANOTIFB DS    0C                 START OF ENTRY                  20001 10416320
         DC    AL1(JANOT03-JANOTIFB) LENGTH OF ENTRY              20001 10416620
*              *                                                  20001 10416920
*              * FIRST POSITION FOR KEYWORD                       20001 10417220
*              *                                                  20001 10417520
JANOT01  DS    0C                 START OF POSITION               20001 10417820
         DC    AL1(JANOT03-JANOT01) LENGTH OF POSITION            20001 10418120
         DC    XL1'20'             COUNT BYTE                     20001 10418420
JANOT02  DS    0C                 START OF CONTROL BYTES          20001 10418720
         MMM   7,61,JCTTSOID-INJMJCT                              20001 10419020
JANOT03   DS    0C                END OF ENTRY                    20001 10419320
         SPACE                                                          10420000
JACONDB  EQU   *                  COND PDT.                             10440000
         DC    FL1'45'            LENGTH OF COND PDT.                   10460000
*   CODE.                                                               10480000
         CCC   7,40                                                     10500000
         DC    FL1'4'             MAXIMUM PARAMETER LENGTH.             10520000
         DDD   20,JATEMP1-JAWORK,2,4095                                 10540000
         DC    FL1'37'            LENGTH THIS POSITIONAL PDT.           10560000
*   OPERATORS.                                                          10580000
*   GT                                                                  10600000
         SSS   32,GT                                                    10620000
         BBB   00,JATEMP2-JAWORK,20                                     10640000
*   GE                                                                  10660000
         SSS   32,GE                                                    10680000
         BBB   00,JATEMP2-JAWORK,B0                                     10700000
*   EQ                                                                  10720000
         SSS   32,EQ                                                    10740000
         BBB   00,JATEMP2-JAWORK,80                                     10760000
*   NE                                                                  10780000
         SSS   32,NE                                                    10800000
         BBB   00,JATEMP2-JAWORK,70                                     10820000
*   LE                                                                  10840000
         SSS   32,LE                                                    10860000
         BBB   00,JATEMP2-JAWORK,D0                                     10880000
*   LT                                                                  10900000
         SSS   32,LT                                                    10920000
         BBB   00,JATEMP2-JAWORK,40                                     10940000
         SPACE                                                          10960000
JAREGB   EQU   *                  REGION PDT.                           10980000
         DC    AL1(JAEND7-JAREGB)       LENGTH OF REGION PDT.      AACA 11000017
         CCC   10,70                                                354 11020000
         DC    FL1'5'             MAXIMUM PARAMETER LENGTH.             11040000
         DC    XL1'21' FUNCT/TABLE.                                     11060000
         DC    AL1(JAREGOFF) OFFSET IN TABLE.                           11080000
         DC    XL2'3FFF'          MAX REGION SEZE.                 AACA 11080817
         BBC   0F,SWD-IWA,JOBREGNS                                 AACA 11081617
JAST7    EQU   *                                                   AACA 11082417
         DC    AL1(JAEND7-JAST7)  LENGTH LCS PDT.                  AACA 11083217
         DC    XL1'40'            CONTROL/COMPARE.                 AACA 11084017
         DC    FL1'5'             MAX PARAMETER LENGTH.            AACA 11084817
         DC    XL1'20'            CVB (2)/ JWA.                    AACA 11085617
         DC    AL1(JATEMP1-JAWORK)      OFFSET.                    AACA 11086417
         DC    XL2'3FFF'          MAX   LCS SIZE.                  AACA 11087217
JAEND7   EQU   *                                                   AACA 11088017
         SPACE                                                          11088817
JAROLLB  EQU   *                  ROLL PDT.                        AACA 11089617
         DC    AL1(JAEND2-JAROLLB)     LENGTH OF ROLL PDT.         AACA 11090417
JAST1    EQU   *                                                   AACA 11091217
         DC    AL1(JAEND1-JAST1)       LENGTH OF 1ST POSITIONAL PDTAACA 11092017
*   ROLLOUTABLE                                                    AACA 11092817
         SSS   33,YES                                              AACA 11093617
         BBC   00,JATEMP1-JAWORK,JAOUTABL                          AACA 11094417
         SSS   02,NO                                               AACA 11095217
JAEND1   EQU   *                                                   AACA 11096017
JAST2    EQU   *                                                   AACA 11096817
         DC    AL1(JAEND2-JAST2)       LENGTH OF 2ND POSITIONAL PDTAACA 11097617
*   CAUSE ROLLOUT                                                  AACA 11098417
         SSS   33,YES                                              AACA 11099217
         BBC   00,JATEMP1-JAWORK,JACAUSER                          AACA 11100017
         SSS   02,NO                                               AACA 11100817
JAEND2   EQU   *                                                   AACA 11101617
JACLASSB EQU   *                  CLASS PDT.                       AACA 11102417
         DC    AL1(JAEND3-JACLASSB)    LENGTH OF CLASS PDT.        AACA 11103217
JAST3    EQU   *                                                   AACA 11104017
         DC    AL1(JAEND3-JAST3)       LENGTH OF 1ST POS PARAM.    AACA 11104817
         DC    XL1'10'                 CONTROL/COMPARE             AACA 11105617
         DC    XL1'01'                 MAX PARAMETER LENGTH.       AACA 11106417
         DC    XL1'70'                 CHECK FOR ALPHA/NUMERIC.    AACA 11107217
JAEND3   EQU   *                                                   AACA 11108017
         SPACE                                                          11108817
JARDB    EQU   *                  RD PDT.                          AACA 11109617
         DC    AL1(JAEND4-JARDB)                                   AACA 11110417
JAST4    EQU   *                                                   AACA 11111217
         DC    AL1(JAEND4-JAST4)                                   AACA 11112017
         SSS   31,R                                                AACA 11112817
         BBC   0F,IWAINTS8-IWA,JOBRDR                              AACA 11113617
         SSS   32,NR                                               AACA 11114417
         BBC   0F,IWAINTS8-IWA,JOBRDNR                             AACA 11115217
         SSS   32,NC                                               AACA 11116017
         BBC   0F,IWAINTS8-IWA,JOBRDNC                             AACA 11116817
         SSS   63,RNC                                              AACA 11117617
         BBC   0F,IWAINTS8-IWA,JOBRDR                              AACA 11118417
         BBC   0F,IWAINTS8-IWA,JOBRDNC                             AACA 11119217
JAEND4   EQU   *                                                   AACA 11120017
         SPACE                                                          11120817
JARESTB  EQU   *                  RESTART PDT.                     AACA 11121617
         DC    AL1(JAEND6-JARESTB)     LENGTH TOTAL PDT.           AACA 11122417
JAST5    EQU   *                                                   AACA 11123217
         DC    AL1(JAEND5-JAST5)       LENGTH 1ST PARAM PDT.       AACA 11124017
         DC    XL1'20'            CTRL BYTES/COMPARE BYTES         AACA 11124817
         MMM   17,60,SRCHL1-JAWORK                                 AACA 11125617
JAEND5   EQU   *                                                   AACA 11126417
JAST6    EQU   *                                                   AACA 11127217
         DC    AL1(JAEND6-JAST6)       LENGTH CHKID PDT.           AACA 11128017
         DC    XL1'20'            CTRL BYTES/COMPARE BYTES         AACA 11128817
         MMM   16,51,JCTCKIDT-INJMJCT                            A43678 11129621
JAEND6   EQU   *                                                   AACA 11130417
         EJECT                                                          11140000
*********************************************************************** 11160000
*                                                                     * 11180000
*              CONSTANTS                                              * 11200000
*                                                                     * 11220000
*********************************************************************** 11240000
JA100    DC    H'100'                  CONVERSION OF SECS TO       SMF1 11242018
*                                           100THS SECS.           SMF1 11244018
JA6000   DC    H'6000'                 CONVERSION OF MINS TO       SMF1 11246018
*                                           100THS SECS            SMF1 11248018
DEC3     EQU   3                       NUMERIC EQUATE                   11250018
DEC1     EQU   1                       NUMERIC EQUATE                   11252018
DEC8     EQU   8                       NUMERIC EQUATE                   11254018
DEC4     EQU   4                       NUMERIC EQUATE                   11256018
DEC5     EQU   5                       NUMERIC EQUATE                   11258018
JATESTOR DC    V(IEFVGT)          TEST AND STORE.                       11260000
JAGETKEP DC    V(IEFVGK)          GET KEY/POS.                          11280000
JAVHQ    DC    V(IEFVHQ)          QMANAGER INTERFACE.                   11300000
JAVGM    DC   V(IEFVGM)           MESSAGE MODULE.                       11320000
JAVHF    DC    V(IEFVHF)          CONTROL ROUTINE (EXIT).               11340000
JAERDUM  DC    C'JOBFAIL '                                        22297 11350018
JAMSK1   DC    F'8'               MASK FOR COND SUBPARM CHECK.          11360000
JA144    DC    F'144'                                                   11380000
JA1      DC    F'1'                                                     11400000
         END                                                            11420000
