         TITLE 'TEST JOB STATEMENT CONDITION CODES'                     00020000
IEFVJ    CSECT                                                          00040000
* 031900C                                                         M0682 00040421
* 023014-023028C,023005A,023011A                                 A38466 00042021
* 023000,318000                                                  A27022 00045019
* 023950-024000,029500                                           A24159 00050018
*7217                                                              4562 00060000
*40069                                                             4601 00070013
*1571 023150-023250,024575,030100-030183                           SMCS 00075018
*********************************************************************** 00080000
*                                                                     * 00100000
*  MODULE IEFVJ              CURRENT STATUS ON X LIBRARY              * 00120000
*                                                                     * 00140000
*        AUGUST 10, 1965               STORED ON X-Y                  * 00160000
*                                                                     * 00180000
*********************************************************************** 00200000
*********************************************************************** 00220000
*                                                                     * 00240000
*                       TEST JOB STATEMENT CONDITION CODES ROUTINE    * 00260000
* FUNCTION: TO DETERMINE WHETHER THE PROCESSING OF THE JOB SHOULD     * 00280000
* CONTINUE, OR SHOULD BE TERMINATED, BECAUSE AN ERROR CONDITION       * 00300000
* PREVIOUSLY SPECIFIED BY THE PROGRAMMER ON THE JOB STATEMENT CARD HAS* 00320000
* BEEN DETECTED.                                                      * 00340000
* ENTRY POINTS: IEFVJ        FROM: IEFLB         ROUT. SYSTEM CONTROL * 00360000
*                                                                     * 00380000
* INPUT: THE LCT ADDRESS IN GENERAL REGISTER 12. THE LCT CONTAINING   * 00400000
* THE CURRENT STEP NUMBER; THE JCT CORE ADDRESS, THE CORE ADDRESS OF  * 00420000
* THE PREVIOUS STEP'S SCT. THE JCT IN CORE CONTAINING EIGHER THE JOB  * 00440000
* CONDITION CODES AND THE DEPENDENCY OPERATORS FOR EACH OR AN         * 00460000
* INDICATION THAT THERE ARE NO CONDITION CODES FOR THIS JOB. THE      * 00480000
* PREVIOUS SCT IN CORE CONTAINING THE STEP STATUS (COMPLETION) CODE OF* 00500000
* THE STEP JUST RUN.                                                  * 00520000
* OUTPUT: ANY CONDITION CODE SATISFIED CAUSES THE JCT JOB STATUS BYTE * 00540000
* TO BE SET TO INDICATE JOB FAILED, BIT FOUR IN THE Q-MANAGER         * 00550019
* JOB STATUS BYTE(QMSTA) IS SET ON FOR RJE, AND AN ERROR MESSAGE TO BE* 00560019
* PRINTED, OTHERWISE THERE IS NO OUTPUT.                              * 00580000
* EXTERNAL REFERENCES: IEFYS - STEP SYSOUT SUBROUTINE TO PRINT        * 00600000
* TERMINATE MESSAGE WHEN A CONDITION CODE HAS BEEN SATISFIED.         * 00620000
* EXITS: NORMAL EXIT IS TO MODULE IEFVK TEST EXECUTE STATEMENT        * 00640000
* CONDITION CODES, WHEN NO CONDITION CODES ARE SATISFIED, OTHERWISE   * 00660000
* EXIT IS MADE TO MODULE IEFZA, JOB TERMINATIO(.                      * 00680000
* ERROR MESSAGES: - JOB TERMINATED BECAUSE OF CONDITION CODES         * 00700000
* TABLES/WORK AREAS: THE LCT, JCT AND PREVIOUS SCT ARE ALL REFERENCED * 00720000
* AND UNCHANGED WHEN NORMAL EXIT IS MADE. THE JCT IS CHANGED ONLY WHEN* 00740000
* A CONDITION HAS BEEN SATISFIED.                                     * 00760000
*                                                                     * 00780000
*********************************************************************** 00800000
*  A24159 REFERS TO AN APAR WHICH REMOVED AN EDIT INSTRUCT.      A24159 00806018
*   THE EDIT INSTRUCTION IS NOT IN THE STANDARD INSTRUCTION SET. A24159 00812018
R0       EQU   0                                                        00820000
R1       EQU   1                                                        00840000
R2       EQU   2                                                        00860000
R3       EQU   3                                                        00880000
R4       EQU   4                                                        00900000
R5       EQU   5                                                        00920000
R6       EQU   6                                                        00940000
R7       EQU   7                                                        00960000
R8       EQU   8                                                        00980000
R9       EQU   9                                                        01000000
R10      EQU   10                                                       01020000
R11      EQU   11                                                       01040000
R12      EQU   12                                                       01060000
R13      EQU   13                                                       01080000
R14      EQU   14                                                       01100000
R15      EQU   15                                                       01120000
*********************************************************************   01140000
*                                                                       01160000
* MODULE IEFVJ - (OPTIONAL) - TEST JOB STATEMENT CONDITION CODES        01180000
*                                                                       01200000
*  DETERMINE WHETHER THE JOB PROCESSING SHOULD CONTINUE OR SHOULD BE    01220000
*   TERMINATED BECAUSE A PREVIOUSLY DEFINED CONDITION CODE, SPECIFIED   01240000
*   ON THE JOB CARD, HAS BEEN RECEIVED FROM A COMPLETED STEP            01260000
*                                                                       01280000
*********************************************************************   01300000
VJ200    BALR  R9,0                          SETUP MODULE BASE REG      01320000
         USING *,R9                                                     01340000
         USING LCT,R12                       LCT BASE REG.              01360000
         USING JCT,R8                        JCT BASE REG.              01380000
         USING SCT,R7                                                   01400000
         B     VJIMPID                                            M0395 01405020
         DC    C'IEFVJIMP'                  MODULE IDENTIFIER     M0395 01410020
VJIMPID  EQU   *                                                  M0395 01415020
         L     R8,LCTJCTAD                   LOAD JCT CORE ADDR         01420000
*********************************************************************   01440000
*                                                                       01460000
* DETERMINE IF JOB CONDITION CODES SHOULD BE CHECKED                    01480000
*        SKIP CHECKING IF THERE ARE NO CONDITION CODES SPECIFIED        01520000
*                                                                       01540000
*********************************************************************** 01560000
         CLC   JCTJDPCD(4),CF0               ANY JOB CONDITION CODES    01580000
         BE    VJ400                         NO  - GO TO EXIT           01600000
*********************************************************************** 01620000
*                                                                       01640000
*  SETUP TO TEST JOB DEPENDENCY CODES WITH THE PREVIOUS STEPS CONDITION 01660000
*        CODE  (STEP STATUS CODE PASSED BY INITIATOR AT STEP            01680000
*               TERMINATION TIME)                                       01700000
*        SKIP CHECKING IF STEP FLUSHED OR ABENDED (NO NORMAL       HW16 01706016
*        COMPLETION CODE FROM STEP TO BE TESTED)                   HW16 01712016
*                                                                       01720000
*********************************************************************** 01740000
         L     R7,LCTSCTAD                   ADDR OF PREVIOUS SCT       01760000
         TM    SCTSSTAT,1          WAS THIS STEP CANCELED?         HW16 01762016
         BO    VJ400               YES, EXIT TO NEXT MODULE        HW16 01764016
         CLI   SCTABCND+2,0        8TH COND CODE PRESENT?          HW16 01766016
         BNE   VJ210               YES, STEP DID NOT ABEND         HW16 01768016
         TM    SCTABCND,SCTABEND   DID THIS STEP ABEND?            HW16 01770016
         BO    VJ400               YES, BYPASS RETURN CODE TEST    HW16 01772016
*                                  THIS STEP                       HW16 01774016
*                                                                  HW16 01776016
VJ210    DS    0H                                                  HW16 01778016
         LA    R3,JCTJDPCD+32                END ADDR OF COND CODES     01780000
         SR    R2,R2                         CLEAR REGISTER             01800000
         SR    R4,R4                         CLEAR REGISTER             01820000
VJ220    IC    R4,JCTJDPOP                   LOAD DEPENDENCY OPERATOR   01840000
         LTR   R4,R4               ANY MORE CONDITION CODES?       HW16 01846016
         BC    8,VJ400             NO, INITIATE NEXT STEP          HW16 01852016
         CLC   JCTJDPCD(2),SCTSEXEC          COMPARE COND-STATUS CODES  01860000
*********************************************************************** 01880000
*                                                                       01900000
* THE INSTRUCTION BELOW (VJ240), TESTS THE RESULT OF THE COMPARE OF THE 01920000
*   DEPENDENCY CODE AND THE STEP STATUS CODE ACCORDING TO THE DEPEND.   01940000
*   OPERATOR CONTAINED IN REGISTER 4                                    01960000
*                                                                       01980000
*********************************************************************** 02000000
VJ240    EX    R4,VJ600                      TEST IF CONDITION MET      02020000
*                                  FALSE CONDITION                      02040000
         LA    R8,4(0,R8)          INCREMENT TO NEXT CODE SLOT     HW16 02060016
         CR    R8,R3                         HAVE ALL CODES BEEN TESTED 02080000
         BE    VJ400                         YES - BRANCH               02100000
         B     VJ220               NO, CONTINUE CHECK              HW16 02130016
*                                                                       02160000
VJ400    L     R15,VJ970                     ACCOUNT RTN                02180000
         MVI   LCTPARM1+3,12                                       4562 02200000
         BALR  R14,R15                                                  02220000
         L     R15,VJ980                                                02240000
         BALR  R14,R15                      *EXIT TO NEXT MODULE        02260000
*********************************************************************** 02280000
* TRUE (CONDITION CODE MET) SET JOB STATUS BYTE TO JOB FAILED,     KMSA 02285016
* PRINT JOB TERM MSG & EXIT TO JOB TERM MODULE.                    KMSA 02290016
*********************************************************************** 02292021
VJ500    L     R8,LCTJCTAD             REINITIALIZE JCT BASE       KMSA 02295016
         OI    JCTJSTAT,4              SET JOB STATUS TO TERMINATE KMSA 02300016
         SPACE 2                                                        02300421
*********************************************************************** 02300721
* ADDED FOR RJE INDICATOR IF JOB FAILED BECAUSE OF CONDITION CODES.   * 02300821
*********************************************************************** 02301121
         L     R1,LCTSOQMP       ADDRESS MSG CLASS QMPA          A38466 02301421
         USING IOPARAMS,R1       BASE FOR FIELDS IN QMPA         A38466 02302821
         OI    QMSTA,BIT4         TURN ON JOB FAILED FOR RJE     A27022 02303519
         DROP  R1                 REMOVE R1 FROM USING TABLE     A27022 02304219
         TM    LCTQENTY,LCTERRM        HAS ERROR MSG BEEN ISSUED   KMSA 02305016
         BO    VJ520                   YES, DON'T REISSUE          KMSA 02310016
         GETMAIN R,LV=75               GET AREA FOR MESSAGE        KMSA 02315018
         L     R5,WTOL                 ADDR OF MSG CSECT           KMSA 02320018
         MVC   0(75,R1),0(R5)          SET UP MSG COPY             KMSA 02325018
         L     R5,CVTPTR               POINTER TO CVT              KMSA 02330016
         L     R5,BASEPTR(R5)         MSTR SCHED LINK T PTR       KMSA  02335016
         USING BASE,R5                                             KMSA 02340016
         TM    MSBTN,MSTN              IS TIME NOTE WANTED ?      KMSA  02345016
         DROP  R5                                                 KMSA  02350016
         BZ    VJ505                   NO,BRANCH AROUND            KMSA 02355016
         LR    R5,R1                   SAVE GETMAIN @             KMSA  02360016
         TIME  DEC                     ISSUE TIME MACRO            KMSA 02365016
         SRL   R0,4                    DROP HUNDREDTHS OF SEC.     KMSA 02370016
         LR    R1,R5                   MOVE MSG @ BACK TO R1       KMSA 02375016
         USING WTERMDST,R1             ESTABLISH ADDRESSABILITY    KMSA 02380016
         ST    R0,JOBNAME2             MOVE TIME INTO MSG REGION  KMSA  02385016
         OI    JOBNAME2+3,X'0F'        ZONE OUT TENTHS OF SEC      KMSA 02390016
         UNPK  TIME2+DISPTIME(TIMEFLDL),JOBNAME2(TIMEFLDV)       A24159 02391018
*                                      CONVERT TIME TO EBCDIC    A24159 02392018
         MVC   TIME2+HHDISP(TIMEUNIT),TIME2+HHDISP1              A24159 02393018
*                                      MOVE HOURS TO HRS FIELD   A24159 02394018
         MVC   TIME2+MMDISP(TIMEUNIT),TIME2+MMDISP1              A24159 02395018
*                                      MOVE MIN TO MIN FIELD     A24159 02396018
         MVI   TIME2+DELIMDIS,DELIM1   PUT DELIMITER IN MESSAGE  A24159 02397018
         MVI   TIME2+PERIODD,DELIM1    PUT DELIMITER IN MESSAGE  A24159 02398018
         MVI   TIME2,C'='              BLANK OUT FIRST NO.         KMSA 02405016
         B     VJ507                                               KMSA 02415016
VJ505    EQU   *                                                   KMSA 02420016
         USING WTERMDST,R1             ESTABLISH ADDRESSABILITY    KMSA 02425016
         LR    R5,R1                   SAVE MSG ADDR.              KMSA 02430016
         MVC   CONCODE+4(6),MCSCODES   INSERT MCS CODES IN MESSAGE SMCS 02431018
         MVI   LENGTH2,LEN             STORE SHORT MSG LEN         SMCS 02432018
LEN      EQU   55                      LEN MSG WITHOUT TIME        SMCS 02433018
VJ507    EQU   *                                                   KMSA 02435016
         MVC   JOBNAME2(8),JCTJNAME    MOVE JOBNAME INTO LIST      4601 02445013
         MVC   STPNAME2(8),SCTSNAME    MOVE STEP NAME TO LIST      4601 02446013
         MVC   PROCSTP2(8),SCTSCLPC    MOVE PROCSTEP NAME TO LIST  4601 02447013
         CLI   SCTSCLPC,X'40'          TEST FOR PROCEDURE          4601 02448013
         BE    VJ510                   BRANCH NO                   4601 02449013
         MVC   STPNAME2(8),SCTSCLPC    MOVE STEP NAME TO LIST      4601 02450013
         MVC   PROCSTP2(8),SCTSNAME    MOVE PROCSTEP NAME TO LIST  4601 02451013
VJ510    LH    R13,SCTSEXEC                                        KMSA 02452016
         CVD   R13,CF0                 CONVERT CODE TO DECIMAL     KMSA 02453016
         UNPK  CONCODE(4),CD0+1(3)     UNPACK COMPLETION CODE      4601 02454013
         OI    CONCODE+3,X'F0'         CONVERT SIGN TO 'F' ZONE    4601 02455013
         OI    LCTQENTY,LCTERRM        TURN ON MESSAGE BIT         4601 02456013
         WTO   MF=(E,(1))              ISSUE TERMINATION MESSAGE   4601 02457013
         FREEMAIN R,LV=75,A=(R5)       FRRE GOTTEN CORE FOR MSG    KMSA 02457518
VJ520    EQU   *                                                   4601 02458013
         L     R13,LCTCMCBA                  REG SAVE AREA              02460000
         L     R10,VJ900                     MESSAGE ADDRESS            02480000
         LH    R11,0(0,R10)                  LOAD MESSAGE LENGTH        02500000
         LA    R10,2(0,R10)                  ADJUST MESSAGE ADDRESS     02520000
         STM   R10,R11,LCTPARM1              STORE INTO LCT             02540000
         L     R15,VJ950                     STEP SYSOUT ENTRY POINT    02560000
         BALR  R14,R15                       GO TO PRINT OUT MESSAGE    02580000
         MVI   LCTPARM1+3,12                                       4562 02600000
         L     R15,VJ970                     ACCOUNT RTN                02620000
         BALR  R14,R15                                                  02640000
         L     R15,VJ960                     JOB TERMINATION ENTRY PNT  02660000
         BALR  R14,R15                      /EXIT TO JOB TERMINATION    02680000
*                                                                       02700000
VJ600    BC    0,VJ500                       BRANCH IF CONDITION MET    02720000
*                                                                       02740000
*********************************************************************** 02760000
*                                                                       02780000
*        IEFVJ - MODULE DATA                                            02800000
*                                                                       02820000
*********************************************************************** 02840000
WTOL     DC    V(WTERM030)             V-CON TO WTO LIST           4601 02850013
VJ900    DC    V(IEFVJMSG)                   MESSAGE ADDRESS            02860000
VJ950    DC    V(IEFYS)                      STEP SYSOUT ENTRY POINT    02880000
VJ960    DC    V(IEFW22SD)                   NEXT MOD ENTRY             02900000
VJ970    DC    V(IEFACTLK)                                              02920000
VJ980    DC    V(IEFW22SD)                   NORMAL EXIT                02940000
*                                                                       02960000
         DS    0D                      DBL WORD BOUNDARY FOR CVD   4601 02970013
CF0      DC    F'0'                                                     02980000
CD0      DC    F'0'                                                4601 02990013
         EJECT                                                          03001013
*********************************************************************** 03002013
*                                                                     * 03003013
*        FORMAT V TYPE WTO LIST FOR JOB TERMINATION MESSAGE        4601 03004013
*        CONSOLE MESSAGE JOBNAME.STEPNAME.PROCSTEP ENDED CC XX     4601 03005013
*                                                                     * 03006013
*********************************************************************** 03007013
*                                                                     * 03008013
WTERM030 CSECT                                                     4601 03009013
         WTO   'IEF451I         .        .         ENDED BY CC XXXX TIMC03012018
               E         ',MF=L,DESC=6,MSGTYP=JOBNAMES                  03015018
WTERMDST DSECT                                                     KMSA 03018416
         DS    0F                                                  KMSA 03018516
         DS    CL1                                                KMSA  03018616
LENGTH2  DS    CL11                                                KMSA 03018716
JOBNAME2 DS    CL9                                                 KMSA 03018816
STPNAME2 DS    CL9                                                KMSA  03018916
PROCSTP2 DS   CL21                                                 KMSA 03019016
CONCODE  DS    CL9                                                 KMSA 03019116
TIME2    DS    CL9                                                KMSA  03019216
MCSCODES DS    CL6                                                 SMCS 03019618
         TITLE 'DUMMY LCT AREA DEFINITIONS'                             03020000
DISPTIME EQU   3                       THIS DISPLACEMENT IS      A24159 03021018
*                                      SUCH THAT THE SECONDS     A24159 03022018
*                                      WILL UNPACK INTO THE      A24159 03023018
*                                      CORRECT PLACE IN THE      A24159 03024018
*                                      MESSAGE TO BE PUT OUT.    A24159 03025018
*                                      THE OTHER FIELDS MUST     A24159 03026018
*                                      BE ADJUSTED               A24159 03027018
TIMEFLDL EQU   6                       THIS IS THE LENGTH OF     A24159 03028018
*                                      THE FIELD NEEDED TO       A24159 03029018
*                                      RECIEVE THE FULL TIME     A24159 03030018
*                                      STAMP VALUE (HHMMSS)      A24159 03031018
TIMEFLDV EQU   4                       THIS IS THE LENGTH OF     A24159 03032018
*                                      THE MEANINGFUL PART OF    A24159 03033018
*                                      THE TIME STAMP RECIEVED   A24159 03034018
*                                      FROM ISSUING THE TIME     A24159 03035018
*                                      MACRO.                    A24159 03036018
HHDISP   EQU   1                       DISPLACEMENT TO HOURS     A24159 03037018
*                                      FIELD IN OUTPUT MSG       A24159 03038018
TIMEUNIT EQU   2                       LENGTH OF TIME UNIT       A24159 03039018
*                                      FIELDS                    A24159 03040018
HHDISP1  EQU   3                       DISPLACEMENT OF HOURS     A24159 03041018
*                                      FIELD IN AREA IN WHICH    A24159 03042018
*                                      THE TIME STAMP WAS        A24159 03043018
*                                      UNPACKED.                 A24159 03044018
MMDISP   EQU   4                       DISPLACEMENT TO MINUITS   A24159 03045018
*                                      FIELD IN OUTPUT MSG.      A24159 03046018
MMDISP1  EQU   5                       DISPLACEMENT OF MINUITS   A24159 03047018
*                                      FIELD IN AREA IN WHICH    A24159 03048018
*                                      THE TIME STAMP WAS        A24159 03049018
*                                      UNPACKED.                 A24159 03050018
DELIMDIS EQU   3                       DISPLACEMENT OF PERIOD    A24159 03051018
DELIM1   EQU   C'.'                    DELIMITER IN TIME STAMP   A24159 03052018
*                                      IN TIME STAMP MSG.        A24159 03053018
PERIODD  EQU   6                       DISPLACEMENT OF SECOND    A24159 03054018
*                                      PERIOD IN TIME STAMP MSG  A24159 03055018
LCT      DSECT                                                          03056018
         IEFALLCT                                                       03060000
         IEEBASEA                                                       03065016
CVTPTR   EQU   16                      CVT ADDR                    KMSA 03070016
BASEPTR  EQU   60                      PTR TO MSTR LINKAGE TABLE   KMSA 03075016
         TITLE 'DUMMY JCT AREA DEFINITIONS'                             03080000
JCT      DSECT                                                          03100000
         IEFAJCTB                                                       03120000
         TITLE 'DUMMY SCT AREA DEFINITIONS'                             03140000
SCT      DSECT                                                          03160000
         IEFASCTB                                                       03180000
         IEFQMNGR                                                 M0682 03190021
         END                                                            03200000
