         TITLE 'TEST EXEC STATEMENT CONDITION CODES'                    00020000
IEFVK    CSECT                                                          00022021
* D 018268                                                       A52928 00032021
* A 18001-18020   SAME AREA HIT BY APARS 41879 AND 41389                00034021
* D 18008-18016   SAME AREA HIT BY APARS 41879 AND 41389                00036021
* A 40684-40692                                                  A40860 00038021
* 051600C                                                         M0682 00040421
* A 10300,11300,12640-12644,18020-18031,18140-18142              A40837 00040521
* D 18024,18104,18112,36200-36960,40620-40640,40720-41000,46500  A40837 00040821
* D 46660,46720,47400,47800,48800,49400                          A40837 00041221
* C 38904-38918,39000-39060                                      A38466 00043221
* A 39160                                                        A38466 00043621
* 018176-018400,019000,022400-022600,023800,024000,024740-024792, M1855 00044021
* 024860-024870,024910,028200,028700-029900,030650,031040,        M1855 00046021
* 033500-033600                                                   M1855 00048021
* 024792-024796,029800                                            M1855 00050021
*                                                                A25134 00052021
* 018040-018064,018152-018168,024850,033600                      A30578 00054021
*                                                                A29228 00056021
*0688022800,030440                                                18157 00058021
*********************************************************************** 00060000
*                                                                     * 00080000
*  MODULE IEFVK              CURRENT STATUS ON X LIBRARY              * 00100000
*                                                                     * 00120000
*        AUGUST 11, 1965               LATEST UPDATE TO VKMOD         * 00140000
*                                                                     * 00160000
*********************************************************************** 00180000
*********************************************************************** 00200000
*                                                                     * 00220000
*                       TEST EXECUTE STATEMENT CONDITION CODE ROUTINE * 00240000
*                                                                     * 00260000
* FUNCTION: TO DETERMINE WHETHER THE NEXT STEP OF A JOB BEING         * 00280000
* PROCESSED SHOULD BE EXECUTED OR SHOULD NOT BE EXECUTED BECAUSE A    * 00300000
* CONDITION CODE SPECIFIED BY THE PROGRAMMER ON THE EXEC STATEMENT    * 00320000
* CARD HAS BEEN DETECTED.                                             * 00340000
* ENTRY POINTS: IEFVK        FROM: IEFVJ         ROUTINE TEST JOB     * 00360000
*                                                STATEMENT            * 00380000
* INPUT: THE LCT ADDRESS IN GENERAL REGISTER 12. THE LCT CONTAINING   * 00400000
* THE CURRENT STEP NUMBER; THE JCT ADDRESS; THE CURRENT SCT ADDRESS;  * 00420000
* AND THE RELATIVE LOCATION OF THE QUEUE MANAGER PARAMETER AREA AND   * 00440000
* RESISTER SAVE AREA. THE JCT IN CORE CONTAINING THE DISK ADDRESS OF  * 00460000
* THE SCT FOR THE FIRST STEP OF A JOB. THE CURRENT SCT IN CORE        * 00480000
* CONTAINING THE DEPENDENCY CODES AND OPERATIONS AND EITHER THE TTR OF* 00500000
* THE ASSOCIATED PREVIOUS SCT OR ZERO IF ALL COMPLETED STEPS ARE TO BE* 00520000
* TESTED. THE PREVIOUS STEP SCT'S, ON DISK, CONTAINING THE STEP STATUS* 00540000
* (COMPLETION) CODE TO BE TESTED AGAINST.                             * 00560000
* OUTPUT: NONE - UNLESS A CONDITION CODE IS SATISFIED IN WHICH CASE,  * 00580000
* THE CURRENT STEP NUMBER IN THE LCT IS UPDATED, THE STEP STATUS BYTE * 00600000
* IS SET TO INDICATE STEP CANCEL, THE MESSAGE INDICATING THE STEP WAS * 00620000
* NOT RUN IS PRINTED AND EXIT IS MADE TO THE SYSTEM CONTROL MODULE    * 00640000
* IEFZQ- CORE MANAGEMENT - TO GET AND RELEASE CORE FOR PREVIOUS SCT'S.* 00660000
* IEFQMSSS - QUEUE MANAGER-TO READ AND WRITE TABLES TO AND FROM CORE. * 00680000
* EXITS: IEFVS - NORMAL EXIT TO THE NEXT MODULE - TEST DD STATEMENT   * 00700000
* CONDITION CODES.IEFLB - EXIT OCCURS IF ANY CONDITION CODE FOR THE   * 00720000
* STEP IS SATISFIED.                                                  * 00740000
* ERROR MESSAGES: - STEP XXXXXXXX, WAS NOT RUN BECAUSE OF CONDITION   * 00760000
* CODES. - NOT ENOUGH CORE AVAILABLE FOR PROCESSING. - QUEUE MANAGER  * 00780000
* ERROR WHILE PROCESSING CONTROL TABLES. - INCORRECT TABLE READ FROM  * 00800000
* QUEUE MANAGER.                                                      * 00820000
* TABLES/WORK AREAS: REFERENCED TABLES ARE THE JCT, LCT, CURRENT SCT  * 00840000
* AND PREVIOUS STEP'S SCT'S. ALL REMAIN UNCHANGED UNLESS A CONDITION  * 00860000
* IS SATISFIED, WHEN THE LCTSNUMB IS UPDATED AND THE SCTSSTAT BYTE IS * 00880000
* SET TO INDICATE STEP CANCELLED, IN THE CURRENT SCT.                 * 00900000
*                                                                     * 00920000
*********************************************************************** 00940000
R0       EQU   0                                                        00960000
R1       EQU   1                                                        00980000
R2       EQU   2                                                        01000000
R3       EQU   3                                                        01020000
THREE    EQU   3                                                        01030021
R4       EQU   4                                                        01040000
R5       EQU   5                                                        01060000
R6       EQU   6                                                        01080000
R7       EQU   7                                                        01100000
R8       EQU   8                                                        01120000
EIGHT    EQU   8                                                        01130021
R9       EQU   9                                                        01140000
R10      EQU   10                                                       01160000
R11      EQU   11                                                       01180000
R12      EQU   12                                                       01200000
R13      EQU   13                                                       01220000
R14      EQU   14                                                       01240000
R15      EQU   15                                                       01260000
JCTSTPFL EQU   16                 BIT-3 STEP FLUSH               A25134 01262020
VKSTNM   EQU   17                                                       01264021
VKONLY   EQU   50                 DISPLACEMENT FOR ONLY IN MSG          01264421
QMBIT4   EQU   X'08'                   REMOTE JOB ENTRY          A27022 01265019
*        SETTING THIS BIT TELLS RJE THAT THE JOB FAILED DUE TO          01270019
*        CONDITION CODES.                                               01275019
TBLENGTH EQU   176                           LENGTH OF TABLES           01280000
*********************************************************************** 01300000
*                                                                       01320000
* MODULE IEFVK - (OPTIONAL) - TEST EXECUTE STATEMENT CONDITION CODES    01340000
*                                                                       01360000
*  DETERMINE WHETHER TO EXECUTE AFTER ABEND, BYPASS IF NO ABEND,   HW16 01366016
*    BYPASS BECAUSE A RETURN CODE TEST IS SATISFIED; OR BYPASS   A30578 01372020
*  BECAUSE A RETURN CODE DOES NOT EXIST.                         A30578 01378020
*                                                                A30578 01380020
*  IF AN ABEND (PROBLEM PROGRAM FAILURE) HAS OCCURRED, AND IF EVEN HW16 01384016
*   OR ONLY WERE SPECIFIED, MAKE RETURN CODE TESTS.                HW16 01390016
*  IF AN ABEND (PROBLEM PROGRAM FAILURE) HAS OCCURRED, AND IF EVEN HW16 01396016
*   OR ONLY WERE NOT SPECIFIED, BYPASS STEP (DEFAULT).             HW16 01402016
*  IF NO ABEND (PROBLEM PROGRAM FAILURE) HAS OCCURRED, AND IF ONLY HW16 01408016
*   WAS SPECIFIED, BYPASS STEP.                                    HW16 01414016
*  IF  ABEND PROCESSING ALLOWS INITIATION TO CONTINUE, TEST ANY    HW16 01420016
*   RETURN CODES SPECIFIED, AND                                    HW16 01426016
*    IF ALL TESTS ARE FALSE, EXECUTE THE STEP.                     HW16 01432016
*    IF ANY TEST IS TRUE, BYPASS THE STEP.                         HW16 01438016
*    (UP TO EIGHT RETURN CODE TESTS MAY BE SPECIFIED, AND EACH OF  HW16 01444016
*     THESE MAY APPLY TO EITHER ONE SPECIFIC STEP OR TO ALL        HW16 01450016
*     PREVIOUS STEPS IN THE JOB.)                                  HW16 01456016
*                                                                  HW16 01462016
* IF THE TEST IS FOR A RETURN CODE WHICH DOES NOT EXIST, BECAUSE A30578 01464020
* THE STEP BEING TESTED IS PRIOR TO A DEFERRED RESTART STEP,     A30578 01466020
* BYPASS THE STEP.                                               A30578 01466420
*                                                                A30578 01466820
*  TO EXECUTE THE STEP, EXIT TO THE NEXT MODULE.                   HW16 01468016
*  TO BYPASS THE STEP, SET THE STEP STATUS INDICATOR IN THE SCT,   HW16 01474016
*   UPDATE THE CURRENT STEP NUMBER TO THE NEXT STEP IN THE JCT,    HW16 01480016
*   SET THE SPECIAL 'STPC' CODE IN THE LCTERROR SLOT IN THE LCT    HW16 01486016
*   (FOR STEP TERMINATE) AND EXIT TO MODULE IEFYN (STEP TERMINATE).HW16 01492016
*                                                                       01520000
*********************************************************************** 01540000
VK200    BALR  R9,0                          SETUP MODULE BASE REG.     01560000
         USING *,R9                                                     01580000
         USING LCT,R12                       LCT BASE REG.              01600000
         USING JCT,R7                                                   01620000
         USING SCT,R8                                                   01640000
         B     VKIMPID                                            M0395 01645020
         DC    C'IEFVKIMP'                  MODULE IDENTIFIER     M0395 01650020
VKIMPID  EQU   *                                                  M0395 01655020
         LM    R7,R8,LCTJCTAD                LOAD JCT AND SCT ADDRESSES 01660000
*********************************************************************** 01680000
*                                                                       01700000
* DETERMINE WHETHER ONE OR MORE PROBLEM PROGRAM FAILURES HAVE      HW16 01720016
*   OCCURRED.                                                      HW16 01740016
*                                                                       01780000
*********************************************************************** 01800000
         TM    JCTJSTAT,JCTABEND   HAVE ANY ABENDS OCCURRED?       HW16 01800121
         BZ    VK204               NO,TEST FOR ONLY                HW16 01800221
         SPACE 1                                                        01800321
*********************************************************************** 01800421
* IF A JOB OR PROC TIME ABEND HAS OCCURRED,REMAINING STEPS WITHIN THE * 01800521
* JOB OR PROC WILL BE FLUSHED.AFTER A TIME ABEND,STEPS FOLLOWING A    * 01800621
* PROC OR STEP WILL BE RUN PROVIDED EVEN/ONLY ARE SPECIFIED.          * 01800721
*********************************************************************** 01800821
         CLC   LCTTMWRK+9(3),CF0  WAS IT A TIMER ABEND?          A41879 01800921
         BNE   VK201              NO,CONTINUE ABEND PROCESSING   A41879 01801021
         CLC   LCTTMWRK+5(3),CF0  DOES THIS STEP HAVE ANY TIME?  A41389 01801121
         BE    VK202              YES,CONTINUE ABEND PROCESSING  A41389 01801221
*                                 NO,JOB/PROC TIME ABEND-FLUSH   A41389 01801321
*                                 THIS STEP                      A41389 01801421
         SPACE 1                                                        01801921
*********************************************************************** 01802021
* IF THE 8TH COND CODE IS > 255 PART OF THE COND CODE IS IN THE EVEN  * 01802121
* ONLY FLAG FIELD SO A DOUBLE CHECK FOR EVEN/ONLY IS NECESSARY        * 01802521
*********************************************************************** 01802621
VK201    CLC   SCTABCND+2(1),CF0  DOES THE 8TH COND CODE SLOT    A40837 01802821
*                                 CONTAIN EVEN/ONLY INFORMATION  A40837 01802921
         BNZ   VK202              NO-BYPASS THE STEP-IT ABENDED  A40837 01803021
*                                 BUT EVEN/ONLY WERE NOT GIVEN   A40837 01803121
         TM    SCTABCND,SCTEVEN+SCTONLY  EVEN OR ONLY SPECIFIED    HW16 01803216
         BNZ   VK206              YES. CONTINUE INITIATION.      A30578 01803620
*                                 IF NO, CANCEL STEP (DEFAULT)   A30578 01804020
VK202    DS    0H                                                  HW16 01807216
         XC    SCTABCND(3),SCTABCND   ZERO 8TH COND CODE SLOT      HW16 01808016
         OI    SCTABCND,SCTABCAN   INDICATE DEFAULT CANCEL         HW16 01808816
         OI    SCTSSTAT,INCMSSTS   INDICATE STEP BYPASSED          HW16 01809616
         B     VK465               EXIT TO STEP TERMINATION        HW16 01812016
VK204    DS    0H                                                  HW16 01813616
         CLC   SCTABCND+2(1),CF0  DOES THE 8TH COND CODE SLOT    A40837 01814021
*                                 CONTAIN EVEN/ONLY INFORMATION  A40837 01814121
         BNE   VK207              NO-CONTINUE NORMAL PROCESSING  A40837 01814221
         TM    SCTABCND,SCTONLY    WAS ONLY SPECIFIED?             HW16 01814416
         BO    VK440               YES, CANCEL STEP              A30578 01816820
VK206    DS    0H                                                  HW16 01850016
         CLI   SCTSDPOP,0          ANY CONDITION CODES?            HW16 01860016
         BE    VK300               NO, INITIATE STEP               HW16 01870016
VK207    EQU   *                                                  M1855 01880020
         L     R6,SCTDISKA             LOAD CURRENT SCT TTR       M1855 01890020
         SRL   R6,EIGHT                SHIFT OUT ID FIELD         M1855 01900020
         SLL   R6,EIGHT                REPOSITION TTR IN REG      M1855 01910020
*********************************************************************** 01920000
*                                                                       01940000
*  GET CORE FOR THE SCT CONTAINING THE STEP STATUS CODE                 01960000
*  (ALSO USED FOR SYSOUT MESSAGE ON STEP CANCEL CONDITION)         HW16 01970016
*                                                                       01980000
*********************************************************************** 02000000
VK208    DS    0H                                                  HW16 02010016
         L     R0,CFTBLN                     SET UP AMOUNT TO GET       02020000
         SR    R1,R1                         CLEAR POINTER              02040000
         GETMAIN R,LV=(0)                                               02060000
         LR    R3,R1                         ADDD OF OBTAINED CORE      02100000
         CLI   SCTABCND+2,0        IF EIGHTH COND CODE IS PRESENT, HW16 02103016
         BNE   VK215               NOT CANCELED BECAUSE OF ONLY    HW16 02106016
         TM    SCTABCND,SCTONLYC   CANCELLED BECAUSE OF ONLY?      HW16 02109016
         BO    VK450               YES, ISSUE MSG AND EXIT         HW16 02112016
*                                                                  HW16 02115016
*********************************************************************** 02120000
*                                                                       02140000
* SETUP TO TEST EXECUTE CARD CONDITION CODES AGAINST THE PROPER         02160000
*        STEPS COMPLETION CODE                                          02180000
*                                                                       02200000
*********************************************************************** 02220000
VK215    DS    0H                                                  HW16 02226016
         XR    R5,R5               CLEAR REGISTER                  HW16 02232016
         LA    R10,SCT+42          POINT TO 8TH COND CODE SLOT     8157 02280016
         SR    R4,R4                         CLEAR REGISTER             02300000
VK220    IC    R4,SCTSDPOP                   LOAD DEPENDENCY OPERATOR   02320000
         CLC   SCTSDPSA(3),CF0               IS TEST WITH ALL STEP CCS  02340000
         BNE   VK230                         NO - BRANCH                02360000
         CLC   SCTSNAME,CKPTRSRT       IS IT DSDRP STEP           M1855 02368020
         BE    VK280                   YES. INITIATE STEP         M1855 02376020
         L     R11,JCTSDKAD            TTR OF FIRST SCT           M1855 02384020
         CR    R11,R6                  IS CURRENT STEP 1ST SCT    M1855 02392020
         BE    VK280                   YES. INITIATE STEP         M1855 02400020
         ST    R11,LCTPARM2            SCT TO BE READ             M1855 02408020
         B     VK240                                                    02420000
VK230    MVC   LCTPARM2(4),SCTSDPSA          LOAD REQ SCT DISK ADDR     02440000
VK240    BAL   R2,VK650                      GO TO SET Q MNGR PARMS     02460000
         TM    172(R3),X'C0'      WAS STEP RUN                   A30578 02470020
         BO    VK241              YES. TEST CODES.               A30578 02472020
VK240A   CLC   SCTSDPSA(THREE),CF0     IS TEST WITH ALL STEPS     M1855 02473020
         BNE   VK260                   NO, CHECK NEXT CODE        M1855 02474020
         L     R11,SCTANSCT-SCT(R3)    TTR OF NEXT SCT            M1855 02475020
         CR    R11,R6                  NEXT SCT=CURRENT SCT       M1855 02476020
         BE    VK260                   YES, THIS TEST DONE        M1855 02477020
         ST    R11,LCTPARM2            NEXT SCT TO READ           M1855 02478020
         B     VK240              GET NEXT SCT                    M1855 02479620
*                                                                       02480000
*                                                                  HW16 02481016
*   DETERMINE IF THIS STEP ABENDED OR WAS BYPASSED.  IF SO, NO     HW16 02482016
*        RETURN CODE TESTS NEED BE PERFORMED .                     HW16 02483016
*                                                                  HW16 02484016
VK241    TM    SCTSSTAT-SCT(R3),X'01'  WAS THIS STEP CANCELED?   A30578 02485020
         BO    VK240A                  YES. BYPASS TEST           M1855 02486020
         CLI   SCTABCND+2-SCT(R3),0  IS 8TH COND CODE PRESENT?     HW16 02488016
         BNE   VK245               YES, STEP DID NOT ABEND         HW16 02489016
         TM    SCTABCND-SCT(R3),SCTABEND  DID THIS STEP ABEND?     HW16 02490016
         BO    VK240A                  YES. BYPASS TEST.          M1855 02491020
*                                  THIS STEP                       HW16 02492016
VK245    DS    0H                                                  HW16 02493016
*                                                                  HW16 02494016
         CLC   SCTSDPCD(2),SCTSEXEC-SCT(R3)  COMPARE COND-STATUS CODES  02500000
*********************************************************************** 02520000
*                                                                       02540000
* THE FOLLOWING EXECUTE INST. TESTS THE RESULTS OF THE COMPARE USING    02560000
*  THE SPECIFIED DEPEND. OPERATOR IN REG. 4.  IF THE RESULT IS -        02580000
*        FALSE- TESTING WILL CONTINUE ON THE NEXT CONDITION CODE UNTIL  02600000
*               ALL CODES ARE TESTED                                    02620000
*        TRUE - THE STEP STATUS IS SET, CURRENT STEP NUMBER IS UPDATED, 02640000
*               AND EXIT IS MADE TO THE DETERMINE NEXT STEP TO BE RUN   02660000
*               MODULE                                                  02680000
*                                                                       02700000
*********************************************************************** 02720000
         EX    R4,VK400                      TEST TRUE-FALSE CONDITION  02740000
*********************************************************************** 02760000
*                                  FALSE CONDITION                      02780000
*                                                                       02800000
*                                                                       02840000
*********************************************************************** 02860000
         B     VK240A                  TEST FOR ALL STEPS         M1855 02930020
*                                                                       03000000
VK260    LA    R8,6(0,R8)                    UPDATE TO NEXT COND CODE   03020000
         CR    R8,R10              IS THIS THE 8TH COND CODE SLOT  HW16 03026016
         BNE   VK270               NO, CONTINUE                    HW16 03032016
*                                                                  HW16 03038016
         CLI   120(10),0           YES,TEST FOR CODE               8157 03044016
         BE    VK280               NO CODE, EXIT (ALL TESTED)      HW16 03050016
*                                                                  HW16 03056016
         LA    R5,6(0,R10)         POINT TO END OF COND CODES      HW16 03062016
         B     VK220               PROCESS LAST CODE               HW16 03068016
*                                                                  HW16 03074016
VK270    DS    0H                                                  HW16 03080016
         CR    R8,R5               WAS THIS THE LAST CODE?         HW16 03086016
         BE    VK280               YES, EXIT TO INITIATE STEP      HW16 03092016
*                                                                  HW16 03098016
         CLI   SCTSDPOP,0          ANY MORE CODES?                 HW16 03110016
         BNE   VK220                         YES - CONTINUE             03120000
*                                                                       03140000
*********************************************************************** 03160000
*                                                                       03180000
*  NORMAL EXIT - RELEASE CORE FOR SUBPOOL 5 AND EXIT TO THE NEXT MODULE 03200000
*                                                                       03220000
*********************************************************************** 03240000
VK280    L     R0,CFTBLN                     SET AMOUNT TO FREE         03260000
         LR    R1,R3                         POINT TO AREA TO FREE      03280000
         FREEMAIN R,LV=(0),A=(1)                                        03300000
*                                                                       03320000
VK300    L     R15,VK960                     LOAD NEXT MOD ENTRY POINT  03340000
         BALR  R14,R15                 EXIT TO NEXT MODULE        M1855 03360020
*                                  TRUE CONDITION                       03380000
VK400    BC    0,VK450                       BRANCH IF CONDITION MET    03400000
*                                                                       03420000
*********************************************************************** 03440000
*                                                                       03460000
*  TRUE CONDITION - SET STEP STATUS BYTE TO CANCEL, PRINT CANCEL        03480000
*  MESSAGE, UPDATE THE CURRENT STEP NUMBER AND EXIT TO THE STEP CONTROL 03500000
*  MODULE                                                               03520000
*                                                                       03540000
*********************************************************************** 03560000
VK440    DS    0H                                                  HW16 03565016
         OI    SCTABCND,SCTONLYC   FLAG CANCEL BECAUSE OF ONLY     HW16 03570016
         B     VK208               GETMAIN FOR MESSAGE             HW16 03575016
VK450    L     R8,LCTSCTAD                   LOAD CURRENT SCT ADDR      03580000
         OI    SCTSSTAT,1                    SET STEP STATUS TO CANCEL  03600000
         LR    R13,R3                        REGISTER SAVE AREA         03700000
         L     R1,VK992                      MESSAGE ADDRESS            03720000
         LH    R2,0(0,R1)                    LOAD MESSAGE LENGTH        03740000
         LA    R1,2(0,R1)                    UPDATE TO TRUE MSG ADDR    03760000
         ST    R2,LCTPARM2         MESSAGE LENGTH FOR SYSOUT       HW16 03780016
         BCTR  R2,0                -1 FOR CORRECT MVC LENGTH       HW16 03800016
         EX    R2,VK940                      MOVE MSG INTO WORK SPACE   03820000
         LA    R1,60(0,R13)                  MESSAGE LOCATION           03840000
         ST    R1,LCTPARM1                   MESSAGE ADDRESS            03860000
         MVC   VKSTNM(8,R1),SCTSNAME         MOVE STEPNAME INTO MESSAGE 03880000
         CLI   SCTABCND+2,0        IF EIGHTH COND CODE IS PRESENT, HW16 03882016
         BNE   VK460               NOT CANCELED BECAUSE OF ONLY    HW16 03884016
         TM    SCTABCND,SCTONLYC  TEST FOR CANCEL BECAUSE OF ONLY  HW16 03886016
         BO    VK470              YES, MOVE COND=ONLY INTO MESSAGE HW16 03888016
         SPACE 2                                                        03890421
*********************************************************************** 03890821
*        SETTING THIS BIT HAS NOTHING TO DO WITH THE MESSAGE          * 03891221
*        BEING WRITTEN.  THIS BIT IS FOUND BY REMOTE                  * 03891621
*        JOB ENTRY MODULES AFTER THE JOB HAS TERMINATED.              * 03891721
*********************************************************************** 03891821
VK460    DS    0H                                                  HW16 03892016
         L     R14,LCTSOQMP      ADDRESS MSG CLASS QMPA          A38466 03900021
         USING IOPARAMS,R14      BASE FOR FIELDS IN QMPA         A38466 03902021
         OI    QMSTA,QMBIT4      NOTIFY RJE WHY JOB FAILED       A38466 03906021
         DROP  R14                                               A27022 03914019
         L     R13,LCTCMCBA       GET SAVE AREA ADDRESS          A38466 03916021
         L     R15,VK965                     STEP SYSOUT ENTRY POINT    03920000
         BALR  R14,R15                       GO TO WRITE MESSAGE        03940000
*                                                                       03960000
         L     R0,CFTBLN                     SET AMOUNT TO FREE         03980000
         LR    R1,R3                         POINT TO AREA TO FREE      04000000
         FREEMAIN R,LV=(0),A=(1)                                        04020000
VK465    DS    0H                                                  HW16 04030016
         XR    R15,R15                                                  04040000
         ST    R15,LCTPARM1                  STORE0-NO TIOT STEP TERM   04060000
         XC    LCTERROR,LCTERROR  CLEAR ERROR INDICATOR          A25134 04066020
         OI    JCTJSTAT,JCTSTPFL  TURN ON STEP FLUSH             A25134 04068020
         MVC   LCTTMWRK+9(3),LCTTMWRK+5 MAKE FAILING STEP'S TIME A40860 04068421
*                                 AVAILABLE TO THE INITIATOR FOR A40860 04068821
*                                 PROC TIME PROCESSING           A40860 04069221
         B     VK300              GO TO JFCB HOUSEKEEPING        A25134 04070020
VK470    DS    0H                                                  HW16 04104016
         MVC   VKONLY(15,R1),CFONLY  MOVE 'COND=ONLY' INTO MESSAGE HW16 04108016
         B     VK460               CONTINUE                        HW16 04112016
*                                                                  HW16 04116016
*********************************************************************** 04120000
*                                                                       04140000
*  ROUTINE TO SETUP PARAMETERS FOR THE QUEUE MANAGER AND READ AN SCT    04160000
*  INTO CORE- CONTAINING THE STEP STATUS CODE                           04180000
*                                                                       04200000
*********************************************************************** 04220000
VK650    ST    R3,LCTPARM1                   CORE ADDR FOR THE SCT      04240000
         MVI   LCTPARM2+3,0                  ZERO DISK ADDR LO BYTE     04260000
         L     R13,LCTCMCBA                  CORE ADDR TO PARAMETERS    04280000
         LA    R1,LCTQMPAM(0,R13)            ADDR OF Q MNG FIXED PARMS  04300000
         LA    R13,LCTREGSV(0,R13)           REGISTER SAVE AREA         04320000
         USING IOPARAMS,R1                                              04340000
         LA    R15,LCTPARM1                  ADDR OF EXTERNAL PARMS     04360000
         ST    R15,QMPCL                     INTO FIXED PORTION         04380000
         MVI   QMPOP,QMREAD                  READ FUNCTION CODE         04400000
         MVI   QMPNC,1                       READ ONE RECORD            04420000
         L     R15,VK955                     Q MNGR ENTRY POINT         04440000
         BALR  R14,R15                       GO TO READ SCT             04460000
         BR    R2                            RETURN BRANCH              04480000
*                                                                       04500000
VK940    MVC   60(1,R13),0(R1)               MOVE MSG INTO WORKAREA     04520000
*********************************************************************** 04540000
*                                                                       04560000
*        IEFVK - MODULE DATA                                            04580000
*                                                                       04600000
*********************************************************************** 04620000
CKPTRSRT DC    CL8'IEFDSDRP'                                     A30578 04660020
VK955    DC    V(IEFQMSSS)                   Q MANAGER ENTRY POINT      04680000
VK960    DC    V(IEFVM)                      NEXT MODULE ENTRY POINT    04700000
VK965    DC    V(IEFYS)                      STEP SYSOUT ENTRY POINT    04720000
VK992    DC    V(IEFVKMJ1)                   CONDITION CODE MSG ADDR    04760000
CFTBLN   DC    A(TBLENGTH)                   LENGTH OF 1 TABLE          04800000
CD0      DC    2F'0'                                                    04820000
CF0      EQU   CD0                                                      04840000
CFONLY   DC    CL15'COND=ONLY'     MESSAGE INSERT FOR ONLY CANCEL  HW16 04920016
         TITLE 'DUMMY LCT AREA DEFINITIONS'                             04960000
LCT      DSECT                                                          04980000
         IEFALLCT                                                       05000000
         TITLE 'DUMMY JCT AREA DEFINITIONS'                             05020000
JCT      DSECT                                                          05040000
         IEFAJCTB                                                       05060000
         TITLE 'DUMMY SCT AREA DEFINITIONS'                             05080000
SCT      DSECT                                                          05100000
         IEFASCTB                                                       05120000
         TITLE 'QUEUE MANAGER PARAMETER AREA'                           05140000
         IEFQMNGR                                                 M0682 05160021
         END                                                            05180000
