         TITLE 'IEFVRR2 - TABLE MERGE ROUTINE'                          00060018
*********************************************************************** 00120018
*TITLE 'IEFVRR2' TABLE MERGE ROUTINE                                  * 00180018
*                                                                     * 00240018
*FUNCTION/OPERATION                                                   * 00300018
*                                                                     * 00360018
*              1. INITIALIZE FOR TABLE MERGE.                         * 00420018
*              2. MERGE JCT.                                          * 00480018
*              3. LOCATE SCT OF ABENDED STEP.                         * 00540018
*              4. MERGE SELECTED FIELDS IN TABLES FOR ABENDED         * 00600018
*                 STEP.  MERGE FROM REINTERPRETED TABLES (NEW         * 00660018
*                 TABLES) INTO ABENDED STEP'S TABLES (OLD TABLES).    * 00720018
*              5. WRITE MERGED TABLES BACK OUT TO JOB QUEUE.          * 00780018
*                                                                     * 00840018
*ENTRY POINTS  IEFVRR2 - MERGE TABLES FOR ABENDED STEP                * 00900018
*              IEFV2AE - MERGE TABLES FOR DSDR PROCESSING             * 00960018
*                                                                     * 01020018
*EXTERNAL ROUTINES                                                    * 01080018
*                                                                     * 01140018
*              NONE                                                   * 01200018
*                                                                     * 01260018
*                                                                     * 01320018
*EXITS - NORMAL RETURN                                                * 01380018
*      - ERROR  SCT NOT FOUND                                         * 01440018
*               I/O ERROR                                             * 01500018
*               JCL ERROR IN REINTERPRETED TABLES                     * 01560018
*                                                                     * 01620018
*                                                                     * 01680018
*TABLES/WORK AREAS                                                    * 01740018
*                                                                     * 01800018
*              REINTERPRETATION CONTROL WORK AREA                     * 01860018
*              QMPA                                                   * 01920018
*              JCT                                                    * 01980018
*              ACT                                                    * 02040018
*              SMB                                                    * 02100018
*              SCT                                                    * 02160018
*              SIOT                                                   * 02220018
*              JFCB                                                   * 02280018
*              DSENQ                                                  * 02340018
*              VOLT                                                   * 02400018
*              JFCBX                                                  * 02460018
*              NEL                                                    * 02520018
*                                                                     * 02580018
*                                                                     * 02640018
*ATTRIBUTES REENTRANT                                                 * 02700018
*                                                                     * 02760018
*********************************************************************** 02820018
         EJECT                                                          02880018
         IEFQMNGR                                                       02940018
         EJECT                                                          03000018
JCT      DSECT                                                          03060018
         IEFAJCTB                                                       03120018
         SPACE 2                                                        03180018
SCT      DSECT                                                          03240018
         IEFASCTB                                                       03300018
         SPACE 2                                                        03360018
DDSIOT   DSECT                                                          03420018
         IEFASIOT                                                       03480018
         SPACE 2                                                        03540018
DDJFCB   DSECT                                                          03600018
         IEFJFCBN                                                       03660018
         EJECT                                                          03720018
IEFVRR2  CSECT                                                          03780018
*A 395914-395918  C 395900-395910,395950                         A38511 03780421
* D-395810-395890                                                A44097 03782021
* A-378064-378184,C-850800,A-956800                              A38666 03790021
* 954700-955500                                                   19200 03810019
         SPACE 1                                                        03840018
         ENTRY IEFVR2AE                                                 03900018
         SPACE 1                                                        03960018
R0       EQU   0                                                        04020018
R1       EQU   1                                                        04080018
R2       EQU   2                                                        04140018
R3       EQU   3                                                        04200018
R4       EQU   4                                                        04260018
R5       EQU   5                                                        04320018
R6       EQU   6                                                        04380018
R7       EQU   7                                                        04440018
R8       EQU   8                                                        04500018
R9       EQU   9                                                        04560018
RA       EQU   10                                                       04620018
RB       EQU   11                  MODULE BASE                          04680018
RC       EQU   12                  WORK AREA BASE                       04740018
RD       EQU   13                                                       04800018
RE       EQU   14                                                       04860018
RF       EQU   15                                                       04920018
         SPACE 2                                                        04980018
         SAVE  (14,12)                                                  05040018
         BALR  RB,ZERO   ESTABLISH MODULE BASE                          05100018
         USING *,RB                                                     05160018
         LA    R5,BRSETUP                                               05220018
         B     RR20010            BRANCH AROUND MODULE NAME             05280018
         DC    X'CCCC'        MODULE NAME AND DATE WRITTEN              05340018
         DC    CL8'IEFVRR2 '                                            05400018
         DC    X'CCCC'                                                  05460018
         DC    X'8058'                8-5-68                            05520018
IEFVR2AE SAVE  (14,12)                                                  05580018
         LA    R5,BRAFTER                                               05640018
RR20010  BALR  RB,ZERO   ESTABLISH MODULE BASE                          05700018
         USING *,RB                                                     05760018
         USING RRCWKAR,RC                                               05820018
         L     R2,RRCRIADC                                              05880018
         USING NELDSECT,R2                                              05940018
         IEFSAVER                                                       06000018
         B     *+4(R5)        BRANCH ACCORDING TO REG. 5                06060018
         B     RR20020             NORMAL TBL MRG                       06120018
         B     RRC0172             MERGE DSDRP'S TABLES                 06180018
         SPACE 2                                                        06240018
*********************************************************************** 06300018
*    INITIAL SET UP FOR TABLE MERGING                                   06360018
         SPACE 1                                                        06420018
RR20020  LA    R6,TBLINCNT                                              06480018
         SR    R3,R3               ZERO R3                              06540018
         SPACE 1                                                        06600018
*    SET UP FOR MERGE TBL SUBROUTINE FOR JOB CONTROL TABLE              06660018
         SPACE 1                                                        06720018
         LA    R5,RCJCMB           MASK TBL BEGIN ADDR                  06780018
         LA    R7,RCJCME           MASK TBL END ADDR                    06840018
         L     R8,NELJCT          SET R8 WITH ADDR OF NEW JCT           06900018
         LA    R9,RRCOJCT          SET R9 WITH ADDR OF OLD JCT          06960018
         SPACE                                                          07020018
         TM    RRCOJCT+JCTJSTAT-INJMJCT,ERRMKJCT  IS JCTABEND ON IN OLD 07080018
         BZ    RR20028                            NO - DON'T SET NEW    07140018
         OI    JCTJSTAT-INJMJCT(R8),ERRMKJCT      YES- SET ON IN NEW    07200018
         SPACE                                                          07260018
RR20028  DS    0H                                                       07320018
         CLI   PS90NJCT(R8),ZERO   IS THERE A DSENQ TABLE ( NEW )       07380018
         BNE   RR20040             YES - DO NOT CLEAR PTR IN OLD        07440018
         XC    PS88OJCT(LPTR,R9),PS88OJCT(R9)     NO - CLEAR IT         07500018
RR20040  DS    0H                                                       07560018
         DROP  R2                  DROP R/I INTERFACE AREA ADDRESSABIL  07620018
         BAL   RA,SISCHTBM         GO TO TABLE MERGE SUBROUTINE         07680018
         SPACE 1                                                        07740018
*    DO NOT MERGE 2 BITS IN THE OLD TABLES AT JCTRSW1                   07800018
*                                                                       07860018
         USING JCT,R9                                                   07920018
         NI    JCTRSW1,CLRMK               CLEAR ALL BUT 2 BITS IN OLD  07980018
         NI    JCTRSW1-INJMJCT(R8),RTNMK  RETAIN ALL BUT 2 BITS IN NEW  08040018
         OC    JCTRSW1(ONE),JCTRSW1-INJMJCT(R8)  MASK NEW TBL ONTO OLD  08100018
         SPACE 1                                                        08160018
         LA    R7,RRCOQTBL                                              08220018
         ST    R7,RRCCARI          SET READ IN ADDR FOR Q MGR           08280018
         MVC   RRCTTR0(LTTR),JCTSSTR    SET TTR OF ABENDED STEPS SCT    08340018
         LA    R1,RRCQEL           PTR TO QMPA                          08400018
         BAL   RA,RRCQMGRW   SUBRTN - GO TO Q MGR , CHECK FOR I/O ERR   08460018
         SPACE 1                                                        08520018
         DROP  R9                                                       08580018
         USING JCT,R8              SET ADDR. FOR NEW JCT                08640018
         LA    R7,RRCOQTBL                                              08700018
         USING SCT,R7              SET ADDR. FOR OLD SCT                08760018
         CLC   SCTSNAME,RRCDSDRN   IS ABENDED STEP DSDR PROC            08820018
         BNE   RRC0118             NO - BYPASS SW SETTING               08880018
         OI    RRCSWA,RRCASDSP     INDICATE STEP IS DSDRP               08940018
RRC0118  DS    0H                                                       09000018
         SPACE 1                                                        09060018
*    THE SCT IN THE REINTERPRETED QUEUE THAT IS EQUAL TO THE ABENDED    09120018
*        STEP'S SCT IS FOUND USING AN SCT READ LOOP. THE QMPA THAT IS   09180018
*        USED FOR THIS READING IS THE ONE THAT WAS RETURNED BY THE      09240018
*        READER/INTERPRETER                                             09300018
         MVC   RRCTTR0(LTTR),JCTSDKAD     SET TTR OF 1ST SCT FOR READ   09360018
         MVC   RRCTTSMB(LTTR),JCTSMBAD    SAVE SMB TTR OF NEXT STEP     09420018
         SPACE 1                                                        09480018
RRC0120  L     R2,RRCRIADC         SET UP ADDRESSABILITY FOR OBTAINING  09540018
         USING NELDSECT,R2         DATA FROM R/I INTERFACE AREA         09600018
         L     RA,NELQMPA                                               09660018
         USING IOPARAMS,RA         SET UP ADDRESSABILITY FOR QMPA       09720018
         MVI   QMPOP,FCTCODE       SET FUNCTION CODE FOR READ           09780018
         NI    QMPRI,LNKBIT        SET LINKOR BIT TO INDICATE INTPRT    09840018
         LA    R5,RRCCARI                                               09900018
         ST    R5,QMPCL            SET ADDR OF EXTERNAL PARAMETER AREA  09960018
         LA    R5,ONE                                                   10020018
         STC   R5,QMPNC            SET NO. RCDS TO READ EQ 1            10080018
         LA    R5,RRCNQTBL                                              10140018
         ST    R5,RRCCARI          SET READ IN ADDR FOR 0 MGR           10200018
RRC0140  LR    R1,RA               SET UP PTR TO QMPA                   10260018
         BAL   RA,RRCQMGRW   SUBRTN - GO TO Q MGR , CHECK FOR I/O ERR   10320018
         SPACE 1                                                        10380018
         CLC   SCTSNAME,SCTSNAME-INSMSCT(R5) IS THIS ABENDED STEP       10440018
         BE    RRC0170                            YES                   10500018
RRC0145  DS    0H                                                       10560018
         MVC   RRCTTSMB,SCTAFSMB-INSMSCT(R5)      SAVE TTR OF 1ST SMB   10620018
*                                                OF NEXT STEP           10680018
         CLC   SCTSNAME,RRCDSDRN   IS THIS DSDR SCT                     10740018
         BE    RRC0150                       YES                        10800018
         NI    RRCSWA,255-RRCSPASD NOT DSDR                             10860018
RRC0160  SR    R4,R4                                                    10920018
         C     R4,SCTANSCT-INSMSCT(R5)  IF THE TTR OF THIS SCT IS ZERO  10980018
         BE    RR2ERTC1            THE ABENDED STEPS SCT                11040018
*                                      WAS NOT FOUND                    11100018
         MVC   RRCTTR0(LTTR),SCTANSCT-INSMSCT(R5)   SET TTR FOR NEXT RD 11160018
         B     RRC0120             GO BACK TO READ NEXT SCT             11220018
         SPACE 2                                                        11280018
RRC0170  EQU   *                                                        11340018
         CLC   SCTSCLPC,SCTSCLPC-INSMSCT(R5)      PROC STEPNAMES EQ     11400018
         BNE   RRC0145            NO CONTINUE READING SCTS              11460018
         DROP  R2,R7,R8,RA                                              11520018
RRC0172  DS    0H                                                       11580018
         LA    R6,TBLINCNT                                              11640018
         SR    R3,R3                                                    11700018
         LA    R5,RCSCMB                MASK TBL BEGIN ADDR             11760018
         LA    R7,RCSCME           MASK TBL END ADDR                    11820018
         LA    R8,RRCNQTBL              SET ADDR OF NEW SCT             11880018
         LA    R9,RRCOQTBL              SET ADDR OF OLD SCT             11940018
         BAL   RA,SISCHTBM              GO TO MERGE SUBROUTINE          12000018
         SPACE 1                                                        12060018
*    THE TTR FOR THE FIRST DSB IS SET BY SCANNING THE OLD QUEUE'S SIOT  12120018
*        CHAIN FOR THE 1ST SIOT INDICATED AS BEING SYSOUT IN THE        12180018
*        MESSAGE CLASS. IF NONE EXIST (INDICATED IN THE SCT) THIS FIELD 12240018
*        IS MADE ZERO. MESSAGE CLASS IS INDICATED IN THE JCT AND SIOT.  12300018
*    THE CURRENT AND LAST SMB POINTERS ARE SET BY COUNTING HOW MANY     12360018
*        SMB'S EXIST IN THE NEW QUEUE. USING THIS COUNT WE SCAN THRU    12420018
*        THE OLD QUEUE'S SMB'S UNTIL WE EQUAL THE COUNT. THIS SMB'S     12480018
*        TTR IS THEN THE DUMMY AND LAST INTERPRETER SMB POINTERS        12540018
*        SPACE 1                                                        12600018
         LA    R8,RRCNQTBL                                              12660018
         USING SCT,R8              SET ADDRESSABILITY FOR NEW SCT       12720018
         MVC   RRCSTNQS,SCTFSIOT   SAVE TTR OF NEW QUEUE SIOT           12780018
         MVC   RRCSTNQV,SCTVOLTB   SAVE TTR OF NEW QUEUE VOLT           12840018
         MVC   RRCNSIOT,SCTNSIOT   SAVE COUNT OF SIOTS THIS STEP        12900018
         MVC   RRCLSMBP(LPTR),SCTADSMB SAVE PTR TO LAST NTR SMB THIS S. 12960018
         TM    RRCSWA,RRCMDPT      ARE DSDR TABLES BEING MERGED         13020018
         BO    RRC0250             YES BYPASS SMB & DSB MERGE           13080018
         DROP  R8                                                       13140018
         LA    R9,RRCOJCT          SET UP ADDRESSABILITY OF OLD Q JCT   13200018
         USING JCT,R9                                                   13260018
*    A SCT READ LOOP IS USED TO FIND THE TTR OF THE 1ST SMB OF THE      13320018
*        ABENDED STEP. THIS TTR IS IN THE SCT IMMEDIATELY BEFORE THE    13380018
*        SCT OF THE ABENDED STEP.                                       13440018
         SPACE 1                                                        13500018
         MVC   RRCTSMBO,JCTSMBAD   SAVE IN CASE 1ST STEP ABENDED        13560018
         MVC   RRCWKAR1(LTTR),JCTSMBAD  SAVE SMB TTR FOR LATE USE       13620018
         MVC   RRCTLOSM,JCTSMBAD                                        13680018
         MVC   RRCTTR0(LTTR),JCTSDKAD   READ IN SCT TTR                 13740018
         LA    R4,RRCWQTBL         SET UP ADDRESSABILITY OF SCT         13800018
         ST    R4,RRCCARI          SET RD IN ADDR FOR Q MGR             13860018
         USING SCT,R4                                                   13920018
RRC0180  LA    R1,RRCQEL           SET PTR TO QMPA                      13980018
         BAL   RA,RRCQMGRW   SUBRTN - GO TO Q MGR , CHECK FOR I/O ERR   14040018
         SPACE 1                                                        14100018
         LA    R5,RRCOQTBL                                              14160018
         CLC   SCTSNAME-INSMSCT(LENGTH8,R5),SCTSNAME       STEPNAMES EQ 14220018
         BE    RRC0190                                     YES          14280018
RRC0185  DS    0H                                                       14340018
         MVC   RRCTTR0(LTTR),SCTANSCT   SET UP TO RD NEXT SCT           14400018
         TM    RRCSWA,RRCASDSP    IS ABENDED STEP DSDR                  14460018
         BO    RRC0180            YES GO READ NEXT SCT                  14520018
         MVC   RRCTSMBO,SCTAFSMB   SAVE PTR TO 1ST SMB OF NEXT STEP     14580018
         MVC   RRCWKAR1(LTTR),SCTAFSMB SAVE SMB TTR                     14640018
         MVC   RRCTLOSM(LTTR),LASTTTR  SAVE LAST NTR TTR                14700018
         B     RRC0180             GO TO READ                           14760018
         SPACE 2                                                        14820018
RRC0190  EQU   *                                                        14880018
         CLC   SCTSCLPC,SCTSCLPC-INSMSCT(R5)      PROC STEPNAMES EQ     14940018
         BNE   RRC0185             NO--GET NEXT STEP NAME               15000018
         TM    RRCSWA,RRCASDSP    IS ABENDED STEP DSDR                  15060018
         BZ    RRC0200            NO                                    15120018
         MVC   SCTAFSMB,RRCTSMBO   SET SMB PTRS IN SCT                  15180018
         MVC   LASTTTR(LTTR),RRCTLOSM                                   15240018
         B     RRC0250             BYPASS SMB+DSB PROC                  15300018
         SPACE 2                                                        15360018
         DROP  R4,R9                                                    15420018
*    SET UP TO READ IN SMB OF OLD QUEUE                                 15480018
         SPACE 1                                                        15540018
RRC0200  DS    0H                                                       15600018
         MVC   RRCTTR0(LTTR),RRCWKAR1   TTR OF SMB TO READ              15660018
         LA    R5,RRCWQTBL                                              15720018
         ST    R5,RRCCARI          READ IN AREA                         15780018
         LA    R1,RRCQEL           SET PTR TO QMPA                      15840018
         BAL   RA,RRCQMGRW         GO TO SET UP TO GO TO Q MGR          15900018
         SPACE 1                                                        15960018
         MVC   RRCWKAR1(LTTR),RRCWQTB4                                  16020018
         SPACE 1                                                        16080018
*    SET UP TO READ IN SMB OF NEW QUEUE                                 16140018
         SPACE 1                                                        16200018
         L     R2,RRCRIADC         SET UP ADDRESSABILITY FOR OBTAINING  16260018
         USING NELDSECT,R2         QMPA FOR NEW QUEUE FOR Q MGR         16320018
         L     R1,NELQMPA           SET PTR TO QMPA                     16380018
         LA    R5,RRCNQTBL                                              16440018
         ST    R5,RRCCARI          SET READ IN ADDR FOR Q MGR           16500018
         MVC   RRCTTR0(LTTR),RRCTTSMB   TTR OF SMB TO BE READ           16560018
         BAL   RA,RRCQMGRW         GO TO SET UP TO GO TO Q MGR          16620018
         SPACE 1                                                        16680018
         MVC   RRCTTSMB(LTTR),RRCNQTB4  SAVE TTR OF NEXT SMB            16740018
         DROP  R2                                                       16800018
*    SET UP TO MERGE SMB TABLES                                         16860018
         SPACE 1                                                        16920018
         LA    R6,TBLINCNT                                              16980018
         SR    R3,R3                                                    17040018
         LA    R5,RCSMMB           MASK TBL BEGIN ADDR                  17100018
         LA    R7,RCSMME           MASK TBL END ADDR                    17160018
         LA    R8,RRCNQTBL         SET ADDR OF NEW SMB                  17220018
         LA    R9,RRCWQTBL         SET ADDR OF OLD SMB                  17280018
         BAL   RA,SISCHTBM         GO TO MERGE SUBROUTINE               17340018
         SPACE 1                                                        17400018
*    WRITE OUT SMB                                                      17460018
         SPACE 1                                                        17520018
         LA    R7,RRCQEL                                                17580018
         USING IOPARAMS,R7                                              17640018
         MVI   QMPOP,FCTCODEW           SET FUNCTION CODE FOR WRITE     17700018
         LA    R4,RRCWQTBL                                              17760018
         ST    R4,RRCCARI          SET ADDR TO WRITE FROM               17820018
         MVC   RRCTTR0(LTTR),RRCWQTBL                                   17880018
         NI    RRCTTR03,HEXZERO      ZERO SMB ID                        17940018
         LR    R1,R7                                                    18000018
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR TO WRITE OLD SMB 18060018
         SPACE 1                                                        18120018
         DROP  R7                                                       18180018
         CLC   RRCLSMBP(LTTR),RRCNQTBL  IS THIS THE LAST SMB THIS STEP  18240018
         BNE   RRC0200             IF NOT GO READ IN MORE SMBS          18300018
         SPACE 1                                                        18360018
*    IF THIS IS THE LAST INTERPRETER SMB SET THE TTR OF THE OLD QUEUE   18420018
*        SMB IN THE CURRENT AND LAST INTERPRETER FIELDS OF THE OLD      18480018
*        QUEUE'S SCT                                                    18540018
         SPACE 1                                                        18600018
         LA    R8,RRCOQTBL                                              18660018
         USING SCT,R8                                                   18720018
         NI    RRCWQTB3,HEXZERO              ZERO SMB ID                18780018
         MVC   SCTADSMB,RRCWQTBL   RESET CURRENT SMB TTR                18840018
         MVC   LASTTTR(LTTR),RRCWQTBL        RESET LAST WTR SMB TTR     18900018
         MVC   RRCTLOSM(LTTR),RRCWQTBL       SAVE  LAST INTPR SMB TTR   18960018
*                                      FOR POSSIBLE CHAINING BY RR3     19020018
         SPACE 2                                                        19080018
*    TEST IF SYSOUT EXISTS IN THE MESSAGE CLASS                         19140018
         SPACE 1                                                        19200018
         TM    SCTSTYPE,SYSOUTMK                                        19260018
         BZ    RRC0240             NO MESSAGE CLASS SYSOUT              19320018
         SPACE 1                                                        19380018
*    FIND FIRST SIOT WHICH IS SYSOUT IN THAT MESSAGE CLASS. NOTE THAT   19440018
*        THE OLD QUEUE SIOT'S ARE BEING SEARCHED HERE                   19500018
         SPACE 1                                                        19560018
         LA    R5,RRCWQTBL                                              19620018
         ST    R5,RRCCARI          SET READ IN ADDR FOR SIOT            19680018
         MVC   RRCTTR0(LTTR),SCTFSIOT   SET TTR OF SIOT TO BE READ      19740018
         LA    R1,RRCQEL           SET PTR TO QMPA                      19800018
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR                  19860018
         SPACE 1                                                        19920018
         USING DDSIOT,R5           SET ADDRESSABILITY FOR SIOT          19980018
         LA    R9,RRCOJCT                                               20040018
         USING JCT,R9              SET ADDRESSABILITY FOR JCT           20100018
RRC0210  TM    SCTSBYT3,SIOTSOMK   IS SIOT SYSOUT                       20160018
         BZ    RRC0220             NO  PREPARE TO READ IN NEXT SIOT     20220018
         CLC   SCTOUTPN,JCTJMGPO   IS SIOT IN MESSAGE CLASS             20280018
         BE    RRC0230                     YES                          20340018
         SPACE 1                                                        20400018
*    PREPARE TO READ IN NEXT SIOT                                       20460018
         SPACE 1                                                        20520018
RRC0220  EQU   *                                                        20580018
         MVC   RRCTTR0(LTTR),SCTPSIOT SET TTR OF NEXT SIOT TO BE READ   20640018
         LA    R1,RRCQEL           SET PTR TO QMPA                      20700018
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR                  20760018
         B     RRC0210             GO TO TEST IF SIOT EQ SYSOUT         20820018
         SPACE 2                                                        20880018
RRC0230  DS    0H                                                       20940018
         MVC   SCT168(LTTR),SIOTDPOP  RESET TTR OF 1ST DSB IN MSG CLASS 21000018
         SPACE 1                                                        21060018
RRC0250  EQU   *                                                        21120018
         LA    R8,RRCOQTBL         RE ESTABLISH SCT ADDR IF DSDR MRG    21180018
         MVC   RRCWKAR3(LTTR),SCTVOLTB  SAVE TTR OF OLD VOLT FOR SYSIN  21240018
         CLI   RRCSTQV2,ZERO          DOES NEW SCT HAVE A VOLT PTR      21300018
         BNE   RRC0252                YES - DO NOT CLEAR PTR IN OLD     21360018
         XC    SCTVOLTB(LTTR),SCTVOLTB    NO - CLEAR IT                 21420018
RRC0252  DS    0H                                                       21480018
         SPACE 1                                                        21540018
         SPACE 1                                                        21600018
*     PREPARE TO READ IN OLD Q AND NEW Q VOLT                           21660018
         SPACE                                                          21720018
*  FIRST CHECK IF THERE IS AN OLD VOLT                                  21780018
         SPACE                                                          21840018
         CLI   SCTVOL2,ZERO        IS THERE AN OLD VOLT                 21900018
         BE    RRC0280             NO - THEREFORE NO PROCESSING         21960018
*                                  YES- READ IN OLD VOLT                22020018
         SPACE 1                                                        22080018
         LA    R4,RRCWQTBL                                              22140018
         ST    R4,RRCCARI          SET READ IN ADDR  (OLD Q)            22200018
         MVC   RRCTTR0,SCTVOLTB    SET TTR0 OF OLD Q VOLT FOR READ      22260018
         DROP  R5,R8,R9                                                 22320018
RRC0260  LA    R1,RRCQEL           SET PTR TO QMPA                      22380018
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR                  22440018
         SPACE 1                                                        22500018
         LA    R4,RRCNQTBL                                              22560018
         ST    R4,RRCCARI          SET READ IN ADDR (NEW Q)             22620018
         MVC   RRCTTR0,RRCSTNQV    SET TTR0 OF NEW Q VOLT FOR READ      22680018
         NI    RRCTTR03,HEXZERO                                         22740018
         L     R2,RRCRIADC                                              22800018
         USING NELDSECT,R2                                              22860018
         L     R1,NELQMPA           SET PTR TO QMPA                     22920018
         DROP  R2                                                       22980018
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR                  23040018
         SPACE 1                                                        23100018
*    SET UP TO MERGE VOLUME TABLE                                       23160018
         SPACE 1                                                        23220018
         LA    R6,TBLINCNT                                              23280018
         SR    R3,R3                                                    23340018
         LA    R5,RCVLMMB          MASK TBL BEGIN ADDR                  23400018
         LA    R7,RCVLMME          MASK TBL END ADDR                    23460018
         LA    R8,RRCNQTBL         SET ADDR OF NEW VOLT                 23520018
         LA    R9,RRCWQTBL         2ET ADDR OF OLD VOLT                 23580018
         BAL   RA,SISCHTBM         GO TO MERGE SUBROUTINE               23640018
         SPACE                                                          23700018
RRC0274  DS    0H                                                       23760018
         CLI   RRCNQTB6,ZERO            IS THIS THE LAST VOLT           23820018
         BNE   RRC0276                  NO  - DO NOT ZERO CHAIN PTR     23880018
         XC    RRCWQTB4(LPTR),RRCWQTB4  YES - ZERO THE PTR              23940018
RRC0276  DS    0H                                                       24000018
         SPACE 1                                                        24060018
         LA    R7,RRCQEL                                                24120018
         USING IOPARAMS,R7         SET ADDRESSABILITY FOR QMPA          24180018
         SPACE 1                                                        24240018
         MVI   QMPOP,FCTCODEW           SET FUNCTION CODE FOR WRITE     24300018
         LA    R4,RRCWQTBL                                              24360018
         ST    R4,RRCCARI          SET ADDR TO WRITE OUT FROM           24420018
         MVC   RRCTTR0,RRCWQTBL    SET TTR OF VOLT FOR WRITE AREA       24480018
         NI    RRCTTR03,HEXZERO                                         24540018
         LA    R1,RRCQEL           SET PTR TO QMPA                      24600018
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR TO WRITE VOLT    24660018
         SPACE 1                                                        24720018
         SR    R4,R4                                                    24780018
         C     R4,RRCNQTB4         IS THIS LAST VOLUME TBL              24840018
         BNE   RRC0270             NO GO TO RD IN OTHER VOLTS           24900018
         SPACE 1                                                        24960018
RRC0280  EQU   *                                                        25020018
         SPACE 1                                                        25080018
*    PREPARE TO READ IN SIOTS                                           25140018
         SPACE 1                                                        25200018
         DROP  R7                                                       25260018
         LA    R6,RRCOQTBL                                              25320018
         USING SCT,R6                                                   25380018
         CLI   RRCNSIOT,ZERO        DOES THIS STEP HAVE ANY SIOTS       25440018
         BE    RRC0460             BYPASS AND RETURN                    25500018
         MVC   RRCTTR0(LTTR),SCTFSIOT  SET TTR OF SIOT FOR RD FOR Q MGR 25560018
         DROP  R6                                                       25620018
RRC0290  DS    0H                                                       25680018
         LA    R7,RRCQEL                                                25740018
         USING IOPARAMS,R7                                              25800018
         LA    R5,RRCWQTBL         SET READ IN ADDR FOR QMAN            25860018
         ST    R5,RRCCARI                                               25920018
         LA    R1,RRCQEL           SET PTR TO QMPA                      25980018
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR TO RD OLD SIOT   26040018
         SPACE 1                                                        26100018
*    SIOTS WHICH WERE CREATED FOR GDG ALL BY JFCB HOUSEKEEPING ARE NOT  26160018
*        MERGED BECAUSE ALLOCATION WILL BE EXECUTED AGAIN AND THEREFORE 26220018
*        THESE SIOTS WILL BE CREATED AGAIN                              26280018
         SPACE 1                                                        26340018
         USING DDSIOT,R5                                                26400018
         TM    SCTSBYT4,GDGALLMK    IS THIS A GDG ALL SIOT              26460018
         BZ    RRC0300             IF NOT GO TO CONTINUE PROCESS        26520018
         MVC   RRCTTR0(LTTR),SCTPSIOT        TTR OF NEXT SIOT           26580018
         OI    RRCSWA,GDGSW        SET GDG INDICATOR                    26640018
         B     RRC0290                                                  26700018
         SPACE 2                                                        26760018
RRC0300  L     R2,RRCRIADC                                              26820018
         USING NELDSECT,R2                                              26880018
         L     R1,NELQMPA           SET ADDR FOR NEW QUEUE QMPA         26940018
         DROP  R2                                                       27000018
         MVC   RRCTTR0,RRCSTNQS    SET TTR OF NEW Q SIOT FOR READ       27060018
         NI    RRCTTR03,HEXZERO      ZERO ID                            27120018
         LA    R4,RRCNQTBL                                              27180018
         ST    R4,RRCCARI          SET READ IN ADDR                     27240018
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR TO RD NEW SIOT   27300018
         DROP  R5                                                       27360018
         USING DDSIOT,R4                                                27420018
         SPACE 2                                                        27480018
         CLC   SCTDDNAM,SCTDDNAM-INDMSIOT(R5)     COMPARE DD NAMES      27540018
         BNE   RR2ERTC3            IF DD NAME NOT EQ AN ERROR COND      27600018
         MVC   RRCSTNQS,SCTPSIOT   SAVE NEXT NEW SIOT TTR FOR LOOP      27660018
         MVC   RRCOSIOT,SCTPSIOT-INDMSIOT(R5)     SAVE OLD Q SIOT TTR   27720018
         TM    SCTSBYT1-INDMSIOT(R5),SIOTSIMK       IS THIS SIOT SYSIN  27780018
         BO    RRC0350             YES BRANCH TO PROCESS SYSIN SIOT     27840018
         TM    RRCSWA,GDGSW                                             27900018
         BO    RRC0302                  BYPASS                          27960018
         MVC   RRCWKAR0(LTTR),RRCWQTBL  SAVE TTR OF THIS SIOT           28020018
RRC0302  DS    0H                                                       28080018
         DROP  R4,R7                                                    28140018
         SPACE 1                                                        28200018
*    SET UP TO MERGE SIOT                                               28260018
         SPACE 1                                                        28320018
         LA    R6,TBLINCNT                                              28380018
         SR    R3,R3                                                    28440018
         LA    R5,RCSIMB           MASK TBL BEGIN ADDR                  28500018
         LA    R7,RCSIME           MASK TBL END ADDR                    28560018
         LA    R8,RRCNQTBL         ADDR NEW SIOT                        28620018
         LA    R9,RRCWQTBL         ADDR OLD SIOT                        28680018
*                                  CLEAR SIOT SWITCHES                  28740018
         NI    RRCSWA,255-SYSOUT-NEWSIOT-GDGSNGLE-PGMAST                28800018
*                                                                       28860018
*     CHECK IF THIS IS 'PGM=*.DD' SIOT.                                 28920018
*           IF YES, THIS SIOT IS MERGED BUT JFCB IS NOT                 28980018
*                                                                       29040018
         CLC   RRCWQTBL+SCTDDNAM-INDMSIOT(EIGHT),PSTARDOT   'PGM=*.DD'  29100018
         BNE   RRC0303             BR NO                                29160018
         OI    RRCSWA,PGMAST       SET INDICATOR FOR JFCB MERGE RTN     29220018
RRC0303  DS    0H                                                       29280018
         TM    RRCWQTBL+SCTSBYT3-INDMSIOT,DIPNEWMK DISP=NEW IN OLD TBL  29340018
         BZ    RRC0304                          NO - DO NOT SET SW      29400018
         OI    RRCSWA,NEWSIOT                   YES- SET IT             29460018
RRC0304  DS    0H                                                       29520018
         TM    RRCNQTBL+SCTSBYT4-INDMSIOT,GDGSNGMK   IS THIS GDG SINGLE 29580018
         BZ    RRC0305            NO - BR                               29640018
         OI    RRCSWA,GDGSNGLE    YES- SET INDICATOR                    29700018
RRC0305  DS    0H                                                       29760018
         TM    RRCNQTBL+SCTSBYT3-INDMSIOT,SIOTSOMK  IS THIS SYSOUT SIOT 29820018
         BZ    RRC0306                           NO LEAVE SWITCH CLEAR  29880018
         OI    RRCSWA,SYSOUT                     SET SYSOUT SWITCH      29940018
RRC0306  DS    0H                                                       30000018
         SPACE                                                          30060018
RRC0307  DS    0H                                                       30120018
*    DO NOT MERGE PUBLIC/PVT BIT IN SIOT                                30180018
*        SAVE THE BIT BY SETTING BIT IN THE NEW TABLE SAME AS           30240018
*        IN THE OLD                                                     30300018
*                                                                       30360018
         NI    RRCWQTBL+SIOTALTD-INDMSIOT,ALLMK CLEAR ALL BUT ONE BIT   30420018
         NI    RRCNQTBL+SIOTALTD-INDMSIOT,ONEMK CLEAR ONE IN NEW TBL    30480018
         OC   RRCNQTBL+SIOTALTD-INDMSIOT(1),RRCWQTBL+SIOTALTD-INDMSIOT  30540018
*                                  MAKE BIT IN NEW SAME AS OLD          30600018
**  PRESERVE LABEL INFORMATION                                          35514817
         NI    RRCWQTBL+SCTSBYT2-INDMSIOT,255-SCTRECVD   CLEAR LOW BIT  35515217
         OC    RRCNQTBL+SCTSBYT2-INDMSIOT(1),RRCWQTBL+SCTSBYT2-INDMSIOT 35515617
*                                  MOVE OLD TO NEW FOR MERGE            35516017
         SPACE                                                          35516417
*                                                                       35546418
*   FOR PDQ PROCESSING - IF NO DISP IN THE NEW SIOT THEN                35576418
*       DON'T MERGE DISP FIELD                                          35606418
*                                                                       35636418
         TM    RRCNQTBL+SCTSDISP-INDMSIOT,DISPCKMK     ANY DISP IN NEW  35666418
         BM    RRC03070           YES- ALLOW FIELD TO BE MERGED         35696418
*                                 NO - MOVE OLD TO NEW TO BYPASS MERGE  35726418
*                                                                       35756418
*              CLEAR ALL BUT PVT BIT                                    35786418
         NI    RRCNQTBL+SCTSDISP-INDMSIOT,BUTPVTMK                      35816418
*         CLEAR PVT BIT IN NEW                                          35846418
         NI    RRCWQTBL+SCTSDISP-INDMSIOT,PVTMK                         35876418
*              MOVE BITS IN OLD TO NEW PRIOR TO MERGE RTN               35906418
         OC    RRCNQTBL+SCTSDISP-INDMSIOT(1),RRCWQTBL+SCTSDISP-INDMSIOT 35936418
RRC03070 DS    0H                                                       35966418
         BAL   RA,SISCHTBM         GO TO TABLE MERGE                    35996418
         SPACE 1                                                        36026418
*    WRITE OUT REMASKED SIOT                                            36056418
         MVC   RRCWKAR2(LTTR),RRCWQTBL       SAVE TTR OF THIS SIOT      36086418
         SPACE 1                                                        36116418
         LA    R7,RRCQEL                                                36146418
         USING IOPARAMS,R7                                              36176418
         SPACE 1                                                        36206418
         MVI   QMPOP,FCTCODEW      SET FUNCTION CODE FOR WRITE          36236418
         LA    R4,RRCWQTBL                                              36266418
         ST    R4,RRCCARI          SET WRITE OUT ADDR                   36296418
         MVC   RRCTTR0,RRCWQTBL    SET TTR FOR WRITE                    36326418
         NI    RRCTTR03,HEXZERO         ZERO SIOT ID                    36356418
         LR    R1,R7               SET PTR TO QMPA                      36386418
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR TO WRITE SIOT    36416418
         SPACE 1                                                        36446418
         DROP  R7                                                       36476418
*    SET UP TO READ JFCB                                                36506418
*                                                                       36536418
*   IF THE SIOT WAS 'PGM=*.DD' THEN THIS JFCB NOT MERGED                36566418
*                                                                       36596418
         TM    RRCSWA,PGMAST                                            36626418
        BO    RRC0334              BR YES- BYPASS JFCB MERGE            36656418
         SPACE 1                                                        36686418
         LA    R5,RRCNQTBL                                              36716418
         USING DDSIOT,R5                                                36746418
         MVC   RRCTTR0(LTTR),SCTPJFCB   SET TTR TO RD NEW JFCB          36776418
         LA    R4,RRCNQTBL                                              36806418
         ST    R4,RRCCARI          SET RD IN ADDR                       36836418
         L     R2,RRCRIADC                                              36866418
         USING NELDSECT,R2                                              36896418
         L     R1,NELQMPA           SET PTR TO QMPA                     36926418
         DROP  R2                                                       36956418
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR TO RD NEW JFCB   36986418
         SPACE 1                                                        37016418
         LA    R4,RRCWQTBL                                              37046418
         MVC   RRCTTR0(LTTR),SCTPJFCB-INDMSIOT(R4)   TTR TO RD OLD JFCB 37076418
         SPACE                                                          37106418
*    BEFORE READING THE JFCB CHECK IF THIS IS THE CHECKPOINT            37136418
*        DATA SET.   IF SO THEN DO NOT READ BECAUSE DSDR                37166418
*        PROCESSING WILL HANDLE THIS ONE.                               37196418
         SPACE                                                          37226418
         CLC   SCTPJFCB-INDMSIOT(LTTR,R4),RRCOJCT+JCTCKTTR-INJMJCT      37256418
*                                                                       37286418
*                                      IF THE TTR OF THIS IS SAME       37316418
*                                      AS CHECKPOINT THEN BYPASS        37346418
         BE    RRC0334                  FOLLOWING                       37376418
         MVC   RRCOJFPT,RRCTTR0                                         37406418
         ST    R4,RRCCARI          SET READ IN ADDR                     37436418
         LA    R1,RRCQEL           SET PTR TO QMPA                      37466418
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR TO RD OLD JFCB   37496418
         DROP  R5                                                       37526418
         SPACE 1                                                        37556418
*    SET UP TO MERGE JFCB                                               37586418
         SPACE 1                                                        37616418
         LA    R6,TBLINCNT                                              37646418
         SR    R3,R3                                                    37676418
         LA    R5,RCJFMB           MASK TBL BEGIN ADDR                  37706418
         LA    R7,RCJFME           MASK TBL END ADDR                    37736418
         LA    R8,RRCNQTBL         SET ADDR OF NEW JFCB                 37766418
         LA    R9,RRCWQTBL         SET ADDR OF OLD JFCB                 37796418
         TM    RRCSWA,SYSOUT        IS THIS SYSOUT?              A38666 37806421
         BZ    RRC0308              NO-CONT. NORMAL PROCESS      A38666 37816421
* YES-MOVE NVOL, VOLS,AND EXTL FROM OLD TO NEW JFCB TO SET UP    A38666 37816821
* FOR LATER MERGE FROM NEW TO OLD                                A38666 37817221
         MVC   JFCBNVOL-INFMJFCB(HEX20,R8),JFCBNVOL-INFMJFCB(R9) A38666 37818421
        SPACE                                                           37826418
*                                                                       37856418
*    SPECIAL PROCESSING IS NECESSARY FOR STEP RESTARTS.                 37886418
         SPACE                                                          37916418
         TM    RRCOJCT+JCTRSW1-INJMJCT,STPMK IS THIS INTRA STEP RESTART 37946418
         BO    RRC0308                       YES- BYPASS SPECIAL CODE   37976418
*                                                                       38006418
*    DO NOT MERGE THE JFCB FIELD USED BY DATA MNGMT TO SAVE TTR INFO    38036418
*         FOR DATA SETS THAT ARE NOT NEW.                               38066418
*                                                                       38096418
         TM    RRCSWA,NEWSIOT      IS THIS DISP=NEW                     38126418
         BO    RRC0309             YES- ALLOW JFCB FIELD TO BE MERGED   38156418
*                                  NO - MOVE FIELD FROM OLD TO NEW      38186418
         MVC   RRCNQTBL+MODTTR(LTTR),RRCWQTBL+MODTTR  TO PREVENT MERGE  38216418
*      DO NOT MERGE TRK BALANCE FIELD                                   38246418
         MVC   JFCLIMCT-INFMJFCB(LTRKBAL,R8),JFCLIMCT-INFMJFCB(R9)      38276418
         SPACE 1                                                        38306418
*      INSURE SETTING OF MOD DATA SET INDICATOR IN NEW JFCB SO THAT     38336418
*        IT WILL BE MERGED CORRECTLY                                    38366418
         NI    JFCBTSDM-INFMJFCB(R8),ALLMK   CLEAR MOD IND BIT NEW TBL  38396418
         NI    JFCBTSDM-INFMJFCB(R9),ONEMK   KEEP MOD IND BIT OLD TBL   38426418
         OC    JFCBTSDM-INFMJFCB(LMODIND,R8),JFCBTSDM-INFMJFCB(R9)      38456418
RRC0309  DS    0H                                                       38486418
*    DSNAMES ARE NOT NORMALLY MERGED THE EXCPTION IS SYSOUT             38516418
*        DATA SETS ON STEP RESTARTS ONLY.                               38546418
*                                                                       38576418
         SPACE                                                          38606418
         TM    RRCSWA,SYSOUT+GDGSNGLE SYSOUT OR GDG SINGLE              38636418
         BZ    RRC0308             NO-PROCESS NORMALLY                  38666418
*                                     YES- MOVE DSNAME TO OLD JFCB      38696418
         MVC   RRCWQTBL(JFCBTSDM-JFCBDSNM),RRCNQTBL                     38726418
         SPACE                                                          38756418
RRC0308  DS    0H                                                       38786418
*   MERGE JFCB DSNAME FIELD FOR GDG ALL & GDG SINGLE-            A38511 39590021
*   MOVE DSNAME FROM NEW TO OLD                                  A38511 39591021
         TM    RRCSWA,GDGSNGLE     IS THIS GDG SINGLE?           A38511 39591421
         BO    RRC308A             YES, MERGE DSNAME             A38511 39591821
         TM    RRCWQTBL+JFCBIND2-INFMJFCB,HEXFOUR                       39592018
*                                                IS THIS GDG ALL        39593017
         BZ    RRC0312                           NO - BYPASS DSN MERGE  39594017
RRC308A MVC  RRCWQTBL+JFCBDSNM-INFMJFCB(52),RRCNQTBL+JFCBDSNM-INFMJFCB  39595021
         SPACE                                                          39596017
RRC0312  DS    0H                                                       39597017
         BAL   RA,SISCHTBM         GO TO MERGE SUBROUTINE               39667018
         SPACE 1                                                        39737018
         USING DDJFCB,R8                                                39807018
*    MASK LABEL TYPE INFORMATION FROM NEW TO OLD JFCB                   39877018
         SPACE 1                                                        39947018
         NI    JFCBLTYP-INFMJFCB(R9),LBLTMK1                            40017018
         NI    JFCBLTYP,LBLTMK2                                         40087018
         OC    JFCBLTYP-INFMJFCB(LLBLT,R9),JFCBLTYP                     40157018
*    CHECK IF THERE IS A JFCB EXTENSION BLOCK FROM NEW JFCB             40227018
         SPACE 1                                                        40297018
         L     R5,JFCBEXTL                                              40367018
         N     R5,RRCJFNM          JFCBEXAD ARE CAST 3 BYTES            40437018
         LTR   R5,R5                                                    40507018
         BZ    RRC0340             NO JFCB EXTENSION BLOCKS EXITS       40577018
         SPACE 1                                                        40647018
*    WRITE OUT THE JFCB                                                 40717018
         SPACE 1                                                        40787018
RRC0310  EQU   *                                                        40857018
         LA    R7,RRCQEL                                                40927018
         USING IOPARAMS,R7                                              40997018
         MVI   QMPOP,FCTCODEW        SET FUNCTION CODE FOR WRITE        41067018
         LA    R4,RRCWQTBL                                              41137018
         ST    R4,RRCCARI          SET ADDR TO WRITE FROM               41207018
         MVC   RRCTTR0(LTTR),RRCOJFPT        SET TTR FOR WRITE          41277018
         LR    R1,R7               SET PTR TO QMPA                      41347018
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR TO WRITE JFCB    41417018
         SPACE 1                                                        41487018
         DROP  R7                                                       41557018
         L     R5,JFCBEXTL-INFMJFCB(R4)                                 41627018
         N     R5,RRCJFNM                                               41697018
         LTR   R5,R5                                                    41767018
         BZ    RRC0330             BRANCH ZERO                          41837018
         L     R5,JFCBEXTL-INFMJFCB(R4) STORE TTR OF JFCBX FOR WRITE    41907018
         SLL   R5,EIGHT            NOTE THAT THIS TTR IS IN FROM TTR0   41977018
         ST    R5,RRCOJFEP         THIS IS FROM OLD JFCB                42047018
*    SET UP TO READ JFCB EXTENSION BLOCK                                42117018
         SPACE 1                                                        42187018
         MVC   RRCTTR0(LTTR),JFCBEXAD        SET TTR FOR READ           42257018
RRC0320  NI    RRCTTR03,HEXZERO                                         42327018
         LA    R5,RRCNQTBL                                              42397018
         ST    R5,RRCCARI          SET READ IN ADDR                     42467018
         L     R2,RRCRIADC                                              42537018
         USING NELDSECT,R2                                              42607018
         L     R1,NELQMPA           SET PTR TO QMPA                     42677018
         DROP  R2                                                       42747018
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR TO RD NEW JFCBX  42817018
         SPACE 1                                                        42887018
         MVC   RRCTTR0(LTTR),RRCOJFEP       SET TTR FOR RD OF OLD JFCBX 42957018
         LA    R5,RRCWQTBL                                              43027018
         ST    R5,RRCCARI          SET RD IN ADDR                       43097018
         LA    R1,RRCQEL           SET PTR TO QMPA                      43167018
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR TO RD OLD JFCBX  43237018
         SPACE 1                                                        43307018
         DROP  R8                                                       43377018
         SPACE 1                                                        43447018
*    SET UP TO MERGE JFCBX                                              43517018
         SPACE 1                                                        43587018
         LA    R6,TBLINCNT                                              43657018
         SR    R3,R3                                                    43727018
         LA    R5,RCJFXMB          MSK TBL BEGIN ADDR                   43797018
         LA    R7,RCJFXME          MSK TBL END ADDR                     43867018
         LA    R8,RRCNQTBL         SET ADDR OF NEW JFCBX                43937018
         LA    R9,RRCWQTBL         SET ADDR OF OLD JFCBX                44007018
         BAL   RA,SISCHTBM         GO TO MERGE SUBROUTINE               44077018
         SPACE 1                                                        44147018
*    SET UP TO WRITE OUT REMASKED JFCBX                                 44217018
         SPACE 1                                                        44287018
         LA    R7,RRCQEL                                                44357018
         USING IOPARAMS,R7                                              44427018
         MVI   QMPOP,FCTCODEW     SET FUNCTION CODE FOR WRITE           44497018
         LA    R4,RRCWQTBL                                              44567018
         ST    R4,RRCCARI          SET ADDR TO WRITE FROM               44637018
         MVC   RRCTTR0(LTTR),RRCOJFEP        SET TTR FOR WRITE          44707018
         LR    R1,R7               SET PTR                              44777018
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR TO WRITE JFCBX   44847018
         DROP  R7                                                       44917018
         SPACE 1                                                        44987018
         NI    RRCNQTB3,HEXZERO                                         45057018
         L     R5,RRCNQTBL         TEST IF THIS IS LAST                 45127018
         LTR   R5,R5               EXTENSION BLOCK                      45197018
         BZ    RRC0330             YES GO TO CONTINUE PROCESSING SIOTS  45267018
         NI    RRCWQTB3,HEXZERO                                         45337018
         MVC   RRCOJFEP,RRCWQTBL   SAVE TTR OF NEXT EXT BLK             45407018
         MVC   RRCTTR0,RRCNQTBL    SET TTR OF NEW JFCBX                 45477018
         B     RRC0320                                                  45547018
         SPACE 2                                                        45617018
RRC0330  EQU   *                                                        45687018
         TM    RRCSWA,GDGSW        IS THIS GDG ALL ( SPECIAL CASE )     45757018
         BZ    RRC0334             NO - NORMAL PROCESSING               45827018
         MVC   RRCTTR0(LTTR),RRCWKAR0  GET TTR OF FIRST SIOT OF GDG ALL 45897018
*                                                                       45967018
*   READ IN THE LAST NON-GDG ALL SIOT  SO THAT THE PTR TO NEXT          46037018
*        SIOT CAN BE UPDATED TO BYPASS THE GDG ALL SIOTS                46107018
*                                                                       46177018
         LA    R5,RRCNQTBL                                              46247018
         ST    R5,RRCCARI                                               46317018
         LA    R1,RRCQEL                                                46387018
         BAL   RA,RRCQMGRW         GO TO READ IN LAST NON-GDG SIOT      46457018
*                                                                       46527018
*   RE-CHAIN THE SIOTS                                                  46597018
*                                                                       46667018
         MVC   RRCNQTBL+SCTPSIOT-INDMSIOT(LCHN),RRCWKAR2  RECHAIN SIOTS 46737018
         MVC   RRCWKAR0(THREE),RRCWKAR2  SAVE TTR OF THIS SIOT          47137018
*                                      FOR CASE WHERE IT IS GDG ALL     47553217
         NI    RRCSWA,255-GDGSW    CLEAR GDG ALL SWITCH                 47623218
         LA    R5,RRCNQTBL                                              47693218
         ST    R5,RRCCARI                                               47763218
         MVC   RRCTTR0(LTTR),RRCNQTBL        SELF TTR                   47833218
         MVI   RRCQEL+QMPOP-QMNAM,QMWRTE                                47903218
         LA    R1,RRCQEL                                                47973218
         BAL   RA,RRCQMGRW         WRITE OUT THE OLD SIOT               48043218
RRC0334  DS    0H                                                       48113218
         SR    R5,R5                                                    48183218
         IC    R5,RRCNSIOT        GET COUNT UNPROCESSED SIOTS           48253218
         BCT   R5,RRC0335         REDUCE COUNT BY ONE, CONTIN IF MORE   48323218
         STC   R5,RRCNSIOT                                              48393218
         B     RRC0440            ALL SIOTS PROCESSED - GO PROCESS DSNQ 48463218
RRC0335  DS    0H                                                       48533218
         STC   R5,RRCNSIOT                                              48603218
         MVC   RRCTTR0,RRCOSIOT    SET TTR OF NEXT SIOT TO READ         48673218
         NI    RRCTTR03,HEXZERO                                         48743218
         B     RRC0290             GO TO CONTINUE PROCESSIN SIOTS       48813218
         SPACE 2                                                        48883218
RRC0340  EQU   *                                                        48953218
         SPACE 1                                                        49023218
*    NO JFCBX EXIST                                                     49093218
         SPACE 1                                                        49163218
         XC    JFCBEXAD-INFMJFCB(LJFCB,R9),JFCBEXAD-INFMJFCB(R9) CLR IT 49233218
         B     RRC0310                                         GO BACK  49303218
         SPACE 2                                                        49373218
RRC0350  EQU   *                                                        49443218
         SPACE 1                                                        49513218
*    PROCESS SYSIN SIOT                                                 49583218
*        TO PROCESS THE SYSIN SIOT NO MERGING OF TABLES IS DONE.        49653218
*        THE VOLUME SERIAL NUMBERS ARE MOVED INTO THE VOLT FROM         49723218
*        THE JFCB AND JFCBX IF IT EXISTS.                               49793218
*        THE FOLLOWING SIOT INFORMATION IS UPDATED -                    49863218
*        (A) SCTVOLCT - NO. OF VOLUMES IN VOLT THAT BELONG TO THIS      49933218
*                       DATA SET                                        50003218
*        (B) SCTVLPTR - RELATIVE PTR FROM BEGINNING OF VOLT TO VOLUME   50073218
*                       SERIAL FOR THIS DD                              50143218
*        (C) SIOTVLCT - VALUE OF SPECIFIED VOLUME COUNT(EQ JFCBVLCT)    50213218
*        (D) SCTSDISP - SET BIT 5 FOR DELETING THE DATA SET             50283218
*        THE FOLLOWING SCT INFORMATION IS UPDATED -                     50353218
*        (A) SCTVOLTL - LENGTH OF VOLUME TABLE                          50423218
         SPACE 2                                                        50493218
*    READ IN OLD JFCB INTO CORE FOR RE INTERPRETED TBLS                 50563218
         SPACE 1                                                        50633218
         LA    R6,RRCNQTBL                                              50703218
         ST    R6,RRCCARI          SET RD IN ADDR                       50773218
         MVC   RRCTTR0,SCTPJFCB-INDMSIOT(R5)      SET TTR OF JFCB       50843218
         LA    R1,RRCQEL                                                50913218
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR TO RD OLD JFCB   50983218
         SPACE 1                                                        51053218
         USING DDJFCB,R6           SET OLD JFCB ADDRESSABILITY          51123218
         LA    R4,RRCOQTBL                                              51193218
         USING SCT,R4                                                   51263218
         SR    R7,R7                                                    51333218
         IC    R7,JFCBNVOL         TEST IF THERE ARE ANY VOL SER NO.    51403218
         LTR   R7,R7                                                    51473218
         BZ    RR2ERTC3            NO AN ERROR COND                     51543218
         LH    R9,SCTVOLTL         OBTAIN LNG OF VOLUME TBL             51613218
         LR    R8,R9               SAVE VOLT LNG FOR FUTURE PROCESSING  51683218
RRC0360  LA    R8,VOLTINC(ZERO,R8)                                      51753218
         BCT   R7,RRC0360          NO. OF VOL SER NO.                   51823218
         STH   R8,SCTVOLTL         STORE NEW VOLT LNG                   51893218
         SPACE 1                                                        51963218
*    WRITE OUT THE SCT                                                  52033218
         SPACE 1                                                        52103218
         LA    R7,RRCQEL                                                52173218
         USING IOPARAMS,R7                                              52243218
         SPACE 1                                                        52313218
         LR    R8,R9                                                    52383218
         LA    R8,SCTINC(ZERO,R8)                                       52453218
         STH   R8,SCTVLPTR-INDMSIOT(R5) SET RELATIVE VOLT PTR IN SIOT   52523218
         IC    R8,JFCBNVOL                                              52593218
         STC   R8,SCTVOLCT-INDMSIOT(R5)  SET NO. VOLUMES IN SIOT        52663218
         IC    R8,JFCBVLCT                                              52733218
         STC   R8,SIOTVLCT-INDMSIOT(R5)  SET VALUE OF VOL COUNT         52803218
         NI    SCTSDISP-INDMSIOT(R5),HEXZERO                            52873218
         OI    SCTSDISP-INDMSIOT(R5),DISPDEL SET DISP TO DELETE         52943218
         SPACE 1                                                        53013218
*    WRITE OUT SIOT                                                     53083218
         SPACE 1                                                        53153218
         MVC   RRCTTR0(LTTR),RRCWQTBL        SET TTR FOR WRITE          53223218
         NI    RRCTTR03,HEXZERO                                         53293218
         ST    R5,RRCCARI          SET ADDR TO WRITE FROM               53363218
         LR    R1,R7               SET PTR TO QMPA                      53433218
         MVI   RRCQEL+QMPOP-QMNAM,QMWRTE                                53503218
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR TO WRITE SIOT    53573218
         SPACE 1                                                        53643218
         DROP  R7                                                       53713218
         SPACE 1                                                        53783218
*    READ IN VOLT                                                       53853218
         SPACE 1                                                        53923218
         LA    R7,RRCWQTBL                                              53993218
         ST    R7,RRCCARI          SET RD IN ADDR                       54063218
         MVC   RRCTTR0(LTTR),RRCWKAR3        GET SAVED TTR OF OLD VOLT  54133218
         DROP  R4                                                       54203218
RRC0370  LA    R1,RRCQEL           SET PTR TO QMPA                      54273218
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR TO RD VOLT       54343218
         CLI   RRCOQTBL+SCTVOL2-INSMSCT,ZERO      DID TBLS HAVE A VOLT  54413218
         BNE   RRC0374             YES- PROCESS NORMALLY                54483218
*                                  NO - THEREFORE SYSIN VOL SERS ARE    54553218
*                                       THE ONLY ENTRIES IN VOLT        54623218
         XC    RRCWQTB4(LVOLTTBL),RRCWQTB4                              54693218
         MVI   RRCWQTB8,SPACE                                           54763218
         MVC   RRCWQTB9(LBLKVOLT),RRCWQTB8     BLANK VOLT               54833218
         MVC   RRCOQTBL+SCTVOLTB-INSMSCT(LPTR),RRCWQTBL RSTORE VOLT PTR 54903218
RRC0374  DS    0H                                                       54973218
         SPACE 1                                                        55043218
         L     R4,RRCWQTB4                                              55113218
         LTR   R4,R4               IS THIS LAST VOLT                    55183218
         BZ    RRC0380             YES PROCESS VOL SER NO.              55253218
         LA    R4,ADDVOLTS    NO PREPARE TO READ IN ADD. VOLTS AND      55323218
         SR    R9,R4               SUBTRACT LNG OF VOLT FOR FUTURE      55393218
*                                  INSERTIONS OF VOL SER NO.            55463218
         MVC   RRCTTR0(LTTR),RRCWQTB4   SET TTR OF VOLT FOR RESD        55533218
         B     RRC0370                  GO BACK                         55603218
         SPACE 2                                                        55673218
RRC0380  EQU   *                                                        55743218
         MVC   RRCNJFTR(LTTR),JFCBEXAD  SAVE TTR FOR RD JFCBX IF REQ    55813218
         NI    RRCNJFR3,HEXZERO                                         55883218
         LA    R5,NOVOLSER              SET NO. OF VOL SER IN JFCB      55953218
         SR    R3,R3                                                    56023218
         IC    R3,JFCBNVOL         SET TOTAL NO. OF VOL SER NO.         56093218
         DROP  R6                                                       56163218
         LA    R6,POIN1ST(ZERO,R6)      POINT TO 1ST VOL SER IN JFCB    56233218
         AR    R7,R9               POINT TO NEXT AVAIL SPOT IN VOLT     56303218
RRC0390  EQU   *                                                        56373218
         LA    R4,ADDVOLTS                                              56443218
         CLR   R4,R9               IS THIS VOLT FULL                    56513218
         BE    RRC0420             YES GO TO ASSIGN TO OBTAIN MORE SPAC 56583218
RRC0430  MVC   EIGHT(VOLTINC,R7),ZERO(R6)  VOL SER FROM JFCB(X) TO VOLT 56653218
         LA    R6,VOLTINC(ZERO,R6) INCR COUNTERS BY LNG OF A VOL SER NO 56723218
         LA    R7,VOLTINC(ZERO,R7)                                      56793218
         LA    R9,VOLTINC(ZERO,R9)                                      56863218
         BCT   R5,RRC0400          MUST WE OBTAIN A JFCB EXTENSION BLK  56933218
         B     RRC0410             YES                                  57003218
         SPACE 2                                                        57073218
RRC0400  BCT   R3,RRC0390          NO ARE THERE ANY MORE VOL SER NO.    57143218
         LA    R7,RRCWQTBL         ADDR OF UPDATED VOLT                 57213218
         ST    R7,RRCCARI                                               57283218
         MVC   RRCTTR0(LTTR),RRCWQTBL   TTR OF UPDATED VOLT             57353218
         MVI   RRCQEL+QMPOP-QMNAM,QMWRTE                                57423218
         LA    R1,RRCQEL                                                57493218
         BAL   RA,RRCQMGRW   SUBRTN - GO TO Q MGR , CHECK FOR I/O ERR   57563218
         B     RRC0330             NO GO TO PROCESS REMAINING SIOTS     57633218
         SPACE 2                                                        57703218
RRC0410  EQU   *                                                        57773218
*    READ IN NEXT JFCBX                                                 57843218
         SPACE 1                                                        57913218
         LA    R8,RRCNQTBL         SET OLD JFCB ADDR                    57983218
         USING DDJFCB,R8                                                58053218
         CLC   JFCBEXAD,RRCZ       ONLY 5 VOL SER IN JFCB NO RD JFCBX   58123218
         DROP  R8                                                       58193218
         BE    RRC0330             YES GO TO PROCESS REMAINING SIOTS    58263218
         MVC   RRCTTR0(LTTR),RRCNJFTR        SET TTR FOR READ           58333218
         LA    R8,RRCNQTBL                                              58403218
         ST    R8,RRCCARI          SET READ IN ADDR                     58473218
         LA    R1,RRCQEL           SET PTR TO QMPA                      58543218
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR TO RD JFCBX      58613218
         SPACE 1                                                        58683218
         MVC   RRCNJFTR(LTTR),RRCNQTBL  SAVE TTR OF NEXT JFCBX          58753218
         NI    RRCNJFR3,HEXZERO                                         58823218
         LA    R6,RRCNQTBL                                              58893218
         LA    R6,VOLSER1(ZERO,R6) SET R6 PT TO 1ST VOL SER NO.         58963218
         LA    R5,CTR15            SET CTR BEFORE GETTING NEXT JFCBX    59033218
         B     RRC0400             GO BACK                              59103218
         SPACE 2                                                        59173218
RRC0420  EQU   *                                                        59243218
         SPACE 1                                                        59313218
*    GO TO ASSIGN TO OBTAIN NEW TTR FOR ANOTHER VOLT                    59383218
         LA    R8,RRCQEL                                                59453218
         USING IOPARAMS,R8                                              59523218
         MVI   QMPOP,FCTASSMK SET FUNCTION CODE FOR ASSIGN              59593218
         NI    QMPCL,HEXZERO                                            59663218
         OI    QMPCL,ONEMK    SET NO RCDS TO ASSIGN EQ 1                59733218
         LR    R1,R8                                                    59803218
         BAL   RA,RRCQMGRW         GO TO Q MGR FOR ASSIGN               59873218
         SPACE 1                                                        59943218
         MVC   RRCWQTB4(LTTR4),RRCCARI  MOVE RETURNED TTR TO NEXT VOLT  60013218
*                                     POSITION IN TBL                   60083218
         NI    QMPCL,HEXZERO                                            60153218
         OI    QMPCL,HEXONE   SET NO RCD RD/WRITE EQ 1                  60223218
         LA    R4,RRCWQTBL                                              60293218
         ST    R4,RRCCARI          SET ADDR TO WRITE FROM               60363218
         MVI   QMPOP,FCTCODEW             SET FUNCTION CODE FOR WRITE   60433218
         MVC   RRCTTR0(LTTR),RRCWQTBL     SET TTR FOR WRITE             60503218
         LR    R1,R8               SET PTR TO QMPA                      60573218
         BAL   RA,RRCQMGRW         GO TO Q MGR TO WRITE VOLT            60643218
         SPACE 1                                                        60713218
         MVC   RRCWQTBL(LTTR),RRCWQTB4  RESET TTR OF THIS VOLT          60783218
         SR    R4,R4                    ZERO REMAINDER OF VOLT          60853218
         ST    R4,RRCWQTB4                                              60923218
         MVI   RRCWQTB8,SPACE                                           60993218
         MVC   RRCWQTB9(LBLKVOLT),RRCWQTB8        BLANK VOLT            61063218
         MVI   RRCWQTB3,HEXSIX               VOLT ID                    61133218
         LA    R7,RRCWQTBL              SET VOLT TBL ADDR               61203218
         LR    R9,R4                    SET VOLT LNG REG EQ 0           61273218
         DROP  R8                                                       61343218
         B     RRC0430             GO TO MOVE VOL SER TO VOLT           61413218
         SPACE 2                                                        61483218
RRC0440  EQU   *                                                        61553218
         TM    RRCSWA,RRCASDSP    IS ABENDED STEP DSDR                  61623218
         BO    RRC0460             YES - BRANCH                         61693218
         SPACE 2                                                        61763218
         SPACE 1                                                        61833218
*    PREPARE TO READ DATA SET ENQUEUE TABLE                             61903218
         SPACE                                                          61973218
         L     R2,RRCRIADC                                              62043218
         USING NELDSECT,R2                                              62113218
         L     R4,NELJCT                                                62183218
         CLI   TTROJCT(R4),ZERO    IS THERE A DSENQ TABLE(NEW)          62253218
*                                  IF NOT THE TTR IN THE OLD JCT        62323218
*                                  HAS ALREADY BEEN CLEARED.            62393218
         BE    RRC0460             NO - BYPASS AND RETURN               62463218
         SPACE 1                                                        62533218
         LA    R5,RRCOJCT                                               62603218
         USING JCT,R5                                                   62673218
        LA    R4,RRCWQTBL              SET RD IN ADDR                   62743218
         ST    R4,RRCCARI                                               62813218
         MVC   RRCTTR0(LTTR),JCT88 TTR OF DSENQ TBL                     62883218
         LA    R1,RRCQEL           SET PTR TO QMPA                      62953218
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR TO RD OLD DSENQ  63023218
         SPACE 1                                                        63093218
         L     R2,RRCRIADC                                              63163218
         USING NELDSECT,R2                                              63233218
         LA    R4,RRCNQTBL                                              63303218
         ST    R4,RRCCARI          SET RD IN ADDR                       63373218
         L     R4,NELJCT          JCT PTR AS RETURNED BY RDR/INTR       63443218
         MVC   RRCTTR0(LTTR),TTRDSENQ(R4)    SET TTR OF DSENQ FOR READ  63513218
         L     R1,NELQMPA           SET PTR TO QMPA                     63583218
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR TO RD NEW DSENQ  63653218
         SPACE 1                                                        63723218
         DROP  R2,R5                                                    63793218
         SPACE 1                                                        63863218
*    PREPARE TO MERGE DSENQ                                             63933218
         SPACE 1                                                        64003218
RRC0450  LA    R6,TBLINCNT                                              64073218
         SR    R3,R3                                                    64143218
         LA    R5,RCDSQMB          MASK TBL BEGIN ADDR                  64213218
         LA    R7,RCDSQME          MASK TBL END ADDR                    64283218
         LA    R8,RRCNQTBL         SET ADDR OF NEW DSENQ                64353218
        LA    R9,RRCWQTBL              SET ADDR OF OLD DSENQ TBL        64423218
         BAL   RA,SISCHTBM         GO TO MERGE SUBROUTINE               64493218
         SPACE 1                                                        66780017
*                                                                       66787017
*   CHECK IF OLD TABLE HAS FEWER ENTRIES THAN NEW TABLE                 66794017
*       IF SO ASSIGN A TTR FOR OLD TABLES TO MERGE INTO                 66801017
*                                                                       66808017
         CLI   RRCWQTB6,ZERO       IS THIS LAST OLD TABLE               66815018
         BNE    RRC0454            NO - CONTINUE                        66822017
         CLI   RRCNQTB6,ZERO       YES-CHECK IF ANY MORE NEW            66829018
         BE     RRC0454                NO MORE NEW - CONTINUE           66836017
*                                                                       66843017
*     THE FOLLOWING ASSIGNS A TTR FOR OLD QUEUE                         66850017
*                                                                       66857017
         MVI   RRCQEL+QMPOP-QMNAM,QMASGN CODE TO ASSIGN A TTR           66864017
         OI    RRCQEL+QMPCL-QMNAM,HEX16  ASSIGN ONE RECORD              66867018
         LA    R1,RRCQEL                                                66871017
         BAL   RA,RRCQMGRW         GO ASSIGN TTR                        66878017
         SPACE                                                          66885017
         MVC   RRCWQTB4(THREE),RRCCARI  MOVE TTR TO OLD DSENQ TABLE     66892018
         SPACE                                                          66899017
*   WRITE OUT MERGED TABLE                                              66906017
         SPACE                                                          66913017
RRC0454  DS    0H                                                       67003018
         SPACE 1                                                        67093018
         LA    R5,RRCQEL                                                67183018
         USING IOPARAMS,R5                                              67273018
         MVI   QMPOP,FCTCODEW        SET FUNCTION CODE FOR WRITE        67363018
        LA    R4,RRCWQTBL                                               67453018
         ST    R4,RRCCARI          SET ADDR TO WRITE FROM               67543018
         MVC   RRCTTR0(LTTR),RRCWQTBL        TTR FOR WRITE              67633018
         LR    R1,R5                                                    67723018
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR TO WRITE DSENQ   67813018
         SPACE 1                                                        67903018
         DROP  R5                                                       67993018
         L     R4,RRCNQTB4           IS THIS LAST DSENQ                 68083018
         LTR   R4,R4                                                    68173018
         BZ    RRC0460            YES GO TO DELETE NEW SYSOUT CLASSES   68263018
*                                                                       68370017
*   INITIALIZE FOR THE OLD DSENQ TABLE BY MOVING ITS SELF TTR           68430017
*       AND CLEARING THE CHAIN TTR                                      68490017
         MVC   RRCTTR0(LTTR),RRCWQTB4        SET READ TTR               68550018
         XC    RRCWQTB4(FOUR),RRCWQTB4  CLEAR CHAIN TTR                 68610018
         SPACE 1                                                        68670017
         LA    R4,RRCNQTBL                                              68750018
         ST    R4,RRCCARI          SET RD IN ADDR                       68830018
         MVC   RRCTTR0(LTTR),RRCNQTB4        SET TTR FOR RD             68910018
         L     R2,RRCRIADC                                              68990018
         USING NELDSECT,R2                                              69070018
         L     R1,NELQMPA           SET PTR TO QMPA                     69150018
         DROP  R2                                                       69230018
         BAL   RA,RRCQMGRW         GO TO BALR TO Q MGR TO READ DSENQ    69310018
         B     RRC0450             GO TO MERGE TBLS                     69390018
         SPACE 2                                                        69470018
RRC0460  EQU   *                                                        69550018
*                                                                       69630018
*       WRITE OUT THE SCT                                               69710018
*                                                                       69790018
        LA    R4,RRCOQTBL                                               69870018
        ST    R4,RRCCARI               ADDR OF SCT TO REMOTE LIST       69950018
         MVC   RRCTTR0(LTTR),RRCOQTBL        TTR OF SCT                 70030018
        MVI   RRCQEL+QMPOP-QMNAM,QMWRTE                                 70110018
        LA    R1,RRCQEL                                                 70190018
        BAL   RA,RRCQMGRW              GO TO WRITE SCT                  70270018
        SPACE 2                                                         70350018
         BAL   RA,RRC0480          FREE-MAIN SUB-ROUTINE                70430018
         SR    RF,RF                                                    70510018
RR2RTRN  RETURN (14,12),RC=(15)                                         70590018
         SPACE 2                                                        70670018
RR2ERTC1 DS    0H                                                       70750018
         BAL   RA,RRC0480          FREE-MAIN SUB-ROUTINE                70830018
         LA    RF,NOSCTIND         SCT NOT FOUND                        70910018
         B     RR2RTRN             RETURN                               70990018
         SPACE                                                          71070018
RR2ERTC2 DS    0H                                                       71150018
         BAL   RA,RRC0480          FREE-MAIN SUB-ROUTINE                71230018
         LA    RF,IOERRIND         RETURN                               71310018
         B     RR2RTRN            I/O ERROR                             71390018
         SPACE                                                          71470018
RR2ERTC3 DS    0H                                                       71550018
         BAL   RA,RRC0480          FREE-MAIN SUB-ROUTINE                71630018
         LA    RF,JCLERRIN         RETURN                               71710018
         B     RR2RTRN            JCL ERROR                             71790018
         SPACE                                                          71870018
RRC0480  DS    0H                                                       71950018
         IEFRELSE                                                       72030018
         BR    RA                      EXIT                             72110018
         SPACE 2                                                        72190018
*********************************************************************** 72270018
*    THE MERGE TABLE SUBROUTINE USES THE FOLLOWING REGISTER CONVENTIONS 72350018
*        REG 2 - USED AS THE BASE REG FOR THE OLD QUEUE TABLES          72430018
*        REG 3 - TABLE DISPLACEMENT AND FIELD LENGTH                    72510018
*        REG 4 - USED AS THE BASE REG FOR THE NEW QUEUE TABLES          72590018
*        REG 5 - BEGIN ADDR OF MASK TBL                                 72670018
*        REG 6 - CONSTANT OF TWO USED FOR INCREMENTING THRU MASK TBL    72750018
*        REG 7 - END ADDR OF MASK TBL                                   72830018
*        REG 8 - IN CORE ADDR OF NEW QUEUE TBL                          72910018
*        REG 9 - IN CORE ADDR OF OLD QUEUE TBL                          72990018
*        REG A - RETURN REG                                             73070018
*********************************************************************** 73150018
         SPACE 1                                                        73230018
SISCHTBM IC    R3,ZERO(ZERO,R5)    SET DISPLACEMENT OF FLD TO BE MERGED 73310018
         LR    R2,R9               SET BASE FOR OLD TBL FOR MVC INSTR   73390018
         LR    R4,R8               SET BASE FOR NEW TBL FOR MVC INSTR   73470018
         AR    R2,R3               INCR BASE TO PROPER FIELD            73550018
         AR    R4,R3               INCR BASE TO PROPER FIELD            73630018
         IC    R3,ONE(ZERO,R5)     SET LENGTH OF FIELD TO BE MERGED     73710018
         BCTR  R3,ZERO             DECR LENGTH BY 1 FOR MVC INSTR       73790018
         EX    R3,SISCHTMM         EXECUTE MOVE                         73870018
         AR    R5,R6               INCREMENT TO NEXT MASK TBL ENTRY     73950018
         CR    R5,R7               CHECK IF TABLE END                   74030018
         BL    SISCHTBM            DO NEXT FIELD IF NOT TBL END         74110018
         BR    RA                  MERGING COMPLETE FOR THIS TABLE      74190018
         SPACE 2                                                        74270018
*    SYSTEM INDEPENDENT SCHEDULER TABLE MERGE MOVE INSTR                74350018
         SPACE 1                                                        74430018
SISCHTMM MVC   ZERO(ZERO,R2),ZERO(R4)   MOVE INFO FROM NEW TO OLD TBL   74510018
         SPACE 2                                                        74590018
         SPACE 2                                                        74670018
RRC0150  DS    0H                                                       74750018
         OI    RRCSWA,RRCSPASD     SET PRIOR STEP IS DSDR               74830018
         MVC   RRCDSTTR,SCTDISKA-INSMSCT(R5)      TTR OF DSDR           74910018
         B     RRC0160                                                  74990018
         SPACE 2                                                        75070018
RRCQMGRW L     RF,RRCAQMGR         Q MGR ADDR                           75150018
         BALR  RE,RF               GO TO Q MGR                          75230018
         LTR   RF,RF               IF REG 15 IS NOT ZERO AN I/O ERROR   75310018
         BNZ   RR2ERTC2                                                 75390018
         MVI   RRCQEL+QMPOP-QMNAM,QMREAD                                75470018
         BR    RA                                                       75550018
         SPACE 2                                                        75630018
RRC0240  SR    R4,R4                                                    75710018
         USING SCT,R8                                                   75790018
         STH   R4,SCT168                                                75870018
         STC   R4,SCT170                                                75950018
         B     RRC0250                                                  76030018
         SPACE 2                                                        76110018
RRC0270  MVC   RRCTTR0,RRCWQTB4    SET TTR OF NEXT VOLT                 76190018
         NI    RRCTTR03,HEXZERO                                         76270018
         LA    R5,RRCWQTBL                                              76350018
         ST    R5,RRCCARI               SET READ IN ADDR                76430018
         MVC   RRCSTNQV(FOUR),RRCNQTB4                                  76510018
         USING IOPARAMS,R7                                              76590018
         B     RRC0260                  GO TO READ LOOP FOR VOLT        76670018
         SPACE 2                                                        76750018
*********************************************************************** 76830018
*    THE FOLLOWING MASKS  ARE USED IN THE MERGE PROCESSING OF AN      * 76910018
*        ABENDED STEPS QUEUE TABLES. EACH QUEUE TABLE INVOLVED IN THE * 76990018
*        MERGE IS ASSOCIATED WITH A SET OF MASKS.  EACH MASK MEMBER   * 77070018
*        CONSISTS OF TWO BYTES.                                       * 77150018
*              (A) 1ST BYTE - FIELD'S DISPLACEMENT IN TABLE           * 77230018
*              (B) 2ND BYTE - LENGTH OF DATA TO BE MERGED             * 77310018
*********************************************************************** 77390018
         SPACE 2                                                        77470018
*    MASKINGS FOR THE JOB CONTROL TABLE                                 77550018
         SPACE 1                                                        77630018
RCJCMB   EQU   *                                                        77710018
RCJCM1D  DC    AL1(JCTJSTAT-INJMJCT)  JOB STATUS BITS DISPLACEMENT      77790018
RCJCM1L  DC    AL1(JCTJMGPO-JCTJSTAT) LENGTH OF JCTJSTAT                77870018
RCJCME   EQU   *                                                        77950018
         SPACE 2                                                        78030018
*    MASKINGS FOR THE STEP CONTROL TABLE                                78110018
         SPACE 1                                                        78190018
RCSCMB   EQU   *                                                        78270018
RCSCM1D  DC    AL1(SCTSSTAT-INSMSCT)    INTERNAL STEP STATUS DISP       78350018
RCSCM1L  DC    AL1(SCTSTIME-SCTSSTAT)   LENGTH                          78430018
RCSCM2D  DC    AL1(SCTSEXEC-INSMSCT)    STEP STATUS CODE DISP           78510018
RCSCM2L  DC    AL1(SCTLALOC-SCTSEXEC)   LNG                             78590018
RCSCM3D  DC    AL1(SCTLALOC-INSMSCT)    LNG ALLOCATE WRK AREA DISP      78670018
RCSCM3L  DC    AL1(SCTFSIOT-SCTLALOC)   LNG                             78750018
RCSCM4D  DC    AL1(SCTSCLPC-INSMSCT)    NAME OF STEP THAT CALLED PROC   78830018
RCSCM4L  DC    AL1(SCTSNAME-SCTSCLPC)   LNG                             78910018
RCSCM5D  DC    AL1(SCTSNAME-INSMSCT)    STEPNAME DISP                   78990018
RCSCM5L  DC    AL1(SCTRPACT-SCTSNAME)   LNG                             79070018
RCSCM6D  DC    AL1(SCTRPACT-INSMSCT)    RELAT PTR TO STEP ENTRY IN ACT  79150018
RCSCM6L  DC    AL1(SCTVOLTL-SCTRPACT)   LNG                             79230018
RCSCM7D  DC    AL1(SCTVOLTL-INSMSCT)    LNG OF VOLUME TBL DISP          79310018
RCSCM7L  DC    AL1(SCTNSIOT-SCTVOLTL)   LNG                             79390018
RCSCM8D  DC    AL1(SCTNSIOT-INSMSCT)    NO. SIOT'S THIS STEP DISP       79470018
RCSCM8L  DC    AL1(SCTNSMSG-SCTNSIOT)   LNG                             79550018
RCSCM9D  DC    AL1(SCTNSMSG-INSMSCT)    NO. OF SET UP MESSAGES DISP     79630018
RCSCM9L  DC    AL1(SCTNJFCB-SCTNSMSG)   LNG                             79710018
RCSCM10D DC    AL1(SCTNJFCB-INSMSCT)    NO. OF JFCB'S TO ALLOCATE DISP  79790018
RCSCM10L DC    AL1(SCTSTYPE-SCTNJFCB)   LNG                             79870018
RCSCM11D DC    AL1(SCTSTYPE-INSMSCT)    STEP TYPE DISP                  79950018
RCSCM11L DC    AL1(SCTXBTTR-SCTSTYPE)    LNG                            80030018
RCSCM12D DC    AL1(SCTPGMNM-INSMSCT)    PROGRAM NAME DISP               80110018
RCSCM12L DC    AL1(SCTLDSTB-SCTPGMNM)   LNG                             80190018
RCSCM13D DC    AL1(SCTLDSTB-INSMSCT)    LNG. OF DSNAME TBL DISP         80270018
RCSCM13L DC    AL1(SCTSDPCD-SCTLDSTB)   LNG                             80350018
RCSCM14D DC    AL1(INSMSCT+171-INSMSCT)  COUNT OF MESSAGE CLASS DSB'S   80430018
RCSCM14L DC    AL1(INSMSCT+172-INSMSCT-171)  LNG OF SCTEQCMC            80510018
RCSCM15D DC    AL1(INSMSCT+172-INSMSCT)   STEP START/END (SCTSTEND)     80590018
RCSCM15L DC    AL1(INSMSCT+173-INSMSCT-172)  LNG OF SCTSTEND            80670018
RCSCM16D DC    AL1(SCTPGMNM-3-INSMSCT)   TIOT PTR                       80750018
RCSCM16L DC    AL1(3)                    LENGTH                         80830018
RCSCME   EQU   *                                                        80910018
         SPACE 2                                                        80990018
*    MASKINGS FOR THE STEP INPUT/OUTPUT TABLE                           81070018
         SPACE 1                                                        81150018
RCSIMB   EQU   *                                                        81230018
RCSIM1D  DC    AL1(SCTDDNAM-INDMSIOT)   DD NAME FROM DD CARD DISP       81310018
RCSIM1L  DC    AL1(SCTCSADD-SCTDDNAM)   LNG OF SCTDDNAM FIELD           81390018
RCSIM2D  DC    AL1(SCTCSADD-INDMSIOT)   DD NO. FOR CHANNEL AFFINITY     81470018
RCSIM2L  DC    AL1(SCTUSADD-SCTCSADD)   LNG                             81550018
RCSIM3D  DC    AL1(SCTUSADD-INDMSIOT)   DD NO. FOR UNIT SEPARATION      81630018
RCSIM3L  DC    AL1(SCTPSIOT-SCTUSADD)   LNG                             81710018
RCSIM5D  DC    AL1(SCTSPOOL-INDMSIOT)   INTERNAL NO. OF POOL DD         81790018
RCSIM5L  DC    AL1(SCTVOLCT-SCTSPOOL)   LNG                             81870018
RCSIM6D  DC    AL1(SCTVOLCT-INDMSIOT)   NO. OF VOLUMES IN VOLT DISP     81950018
RCSIM6L  DC    AL1(SCTVLPTR-SCTVOLCT)   LNG                             82030018
RCSIM7D  DC    AL1(SCTVLPTR-INDMSIOT)   RELATIVE POINTER                82110018
RCSIM7L  DC    AL1(SCTDDINO-SCTVLPTR)   LNG                             82190018
RCSIM8D  DC    AL1(SCTDDINO-INDMSIOT)   INTERNAL NO. OF DD STATEMENT    82270018
RCSIM8L  DC    AL1(SCTNMBUT-SCTDDINO)   LNG                             82350018
RCSIM9D  DC    AL1(SCTNMBUT-INDMSIOT)   NO. OF UNITS FOR DATA SET       82430018
RCSIM9L  DC    AL1(SIOTVLCT-SCTNMBUT)   LNG                             82510018
RCSIM10D DC    AL1(SIOTVLCT-INDMSIOT)   VALUE OF SPECIFIED VOL COUNT    82590018
RCSIM10L DC    AL1(SCTSDISP-SIOTVLCT)   LNG                             82670018
RCSIM11D DC    AL1(SCTSDISP-INDMSIOT)   SCHED. DISPOSITION OF DATA SET  82750018
RCSIM11L DC    AL1(SCTSBYT1-SCTSDISP)   LNG                             82830018
RCSIM12D DC    AL1(SCTSBYT1-INDMSIOT)   INDICATOR BYTE 1                82910018
RCSIM12L DC    AL1(SCTSBYT2-SCTSBYT1)   LNG                             82990018
RCSIM13D DC    AL1(SCTSBYT2-INDMSIOT)   INDICATOR BYTE 2                83070018
RCSIM13L DC    AL1(SCTSBYT3-SCTSBYT2)   LNG                             83150018
RCSIM14D DC    AL1(SCTSBYT3-INDMSIOT)   INDICATOR BYTE 3                83230018
RCSIM14L DC    AL1(SCTSBYT4-SCTSBYT3)   LNG                             83310018
RCSIM15D DC    AL1(SCTSBYT4-INDMSIOT)   INDICATOR BYTE 4                83390018
RCSIM15L DC    AL1(SCTUTYPE-SCTSBYT4)   LNG                             83470018
RCSIM16D DC    AL1(SCTUTYPE-INDMSIOT)   UNIT TYPE OF DATA SET           83550018
RCSIM16L DC    AL1(SCTOUTNM-SCTUTYPE)   LNG                             83630018
RCSIM17D DC    AL1(SCTDDDUP-INDMSIOT)   DUPLICATE NO. OF DD STATEMENT   83710018
RCSIM17L DC    AL1(SIOTDPCD-SCTDDDUP)   LNG                             83790018
RCSIM18D DC    AL1(SIOTALTD-INDMSIOT)   ALTERNATE DISPOSITION           83870018
RCSIM18L DC    AL1(SIOTALTD+1-SIOTALTD) LNG                             83950018
RCSIM19D DC    AL1(SIOTDCBR-INDMSIOT)   DCB REFERENCE NAME              84030018
RCSIM19L DC    AL1(SIOTDCBR+44-SIOTDCBR)  LNG                           84110018
RCSIME   EQU   *                                                        84190018
         SPACE 2                                                        84270018
*    MASKINGS FOR THE JOB FILE CONTROL BLOCK                            84350018
         SPACE 1                                                        84430018
*                                                                 M4312 84440019
*   JFCBEXAD, THE TTR OF THE FIRST JFCB EXTENSION BLOCK, JFCBLTYP,THE * 84470019
*   LABEL TYPE, JFCBNVOL, NUMBER OF VOLUME SERIALS, JFCBVOLS, THE     * 84510019
*   VOLUME SERIAL NUMBERS, AND JFCBEXTL, THE LENGTH OF THE BLOCK      * 84550019
*   OF EXTRA VOLUME SERIALS, ARE NOT MERGED.                          * 84590019
*                                                                 M4312 84600019
         SPACE 1                                                        84670018
RCJFMB   EQU   *                                                        84750018
RCJFM1D  DC    AL1(JFCBTSDM-INFMJFCB)                                   84830018
RCJFM1L  DC    AL1(JFCBLTYP-JFCBTSDM)                                   84910018
RCJFM2D  DC    AL1(JFCBLTYP+1-INFMJFCB)                                 84990018
RCJFM2L  DC    AL1(JFCBEXAD-JFCBUFOF)                            A38666 85080021
RCJFM3D  DC    AL1(JFCBPQTY-INFMJFCB)                                   85150018
RCJFM3L  DC    AL1(JFCBSPTN+1-JFCBPQTY)                                 85230018
RCJFME   EQU   *                                                        85310018
         SPACE 2                                                        85390018
*    MASKINGS FOR THE JOB FILE CONTROL EXTENSION BLOCK                  85470018
         SPACE 1                                                        85550018
RCJFXMB  EQU   *                                                        85630018
RCJFXM1D DC    AL1(4)              MAINTAIN TTR CHAIN                   85710018
RCJFXM1L DC    AL1(172)            MERGE ALL OF TBL EXCEPT TTR CHAIN    85790018
RCJFXME  EQU   *                                                        85870018
         SPACE 2                                                        85950018
*    MASKINGS FOR THE SYSTEM MESSAGE BLOCK                              86030018
         SPACE 1                                                        86110018
RCSMMB   EQU   *                                                        86190018
RCSMM1D  DC    AL1(SMBDUMMY-SMBDSKAD)   MERGE ALL OF SMB EXCEPT FOR     86270018
RCSMM1L  DC    AL1(168)                 SELF IDENTIFING  AND CHAIN TTRS 86350018
RCSMME   EQU   *                                                        86430018
         SPACE 2                                                        86510018
*    MASKINGS FOR THE VOLUME TABLE                                      86590018
         SPACE 1                                                        86670018
RCVLMMB  EQU   *                                                        86750018
RCVLMM1D DC    AL1(8)                   MERGE ALL OF VOLT EXCEPT FOR    86830018
RCVLMM1L DC    AL1(168)                 SELF IDENTIFING AND CHAIN TTRS  86910018
RCVLMME  EQU   *                                                        86990018
         SPACE 2                                                        87070018
*    MASKINGS FOR THE DATA SET ENQUEUE TABLE                            87150018
         SPACE 1                                                        87230018
RCDSQMB  EQU   *                                                        87310018
RCDSQM1D DC    AL1(8)                   MERGE ALL OF DSENQ EXCEPT FOR   87390018
RCDSQM1L DC    AL1(168)                 SELF IDENTIFING AND CHAIN TTRS  87470018
RCDSQME  EQU   *                                                        87550018
         EJECT                                                          87630018
         DS    0F                                                       87710018
RRCDSDRN DC    C'IEFDSDRP'         STEPNAME FOR DSDR PROCESSING         87790018
RRCJFNM  DC    X'00FFFFFF'         USED TO 'AND' JFCBEXAD               87870018
RRCZ     DC    X'000000'           USED TO FIND END OF CHAIN            87950018
PSTARDOT DC    C'PGM=*.DD'         USED TO FIND PGM=*.DD SIOT           88030018
*                                                                       88110018
MODTTR   EQU   JFCBLTYP+1-INFMJFCB FIELD USED BY DATA MNGMT TO SAVE     88190018
*                                  TTR INFO FOR NON-NEW DATA SETS.      88270018
*                                                                       88350018
NELDSECT DSECT                                                          88430018
         IEFNEL EXITS=IAM                                               88510018
         SPACE 2                                                        88590018
         IEFVWKAR                                                       88670018
*                                                                       88750018
*               DECIMAL CONSTANTS, LENGTHATTRIBUTES, POSITIONINDICATORS 88830018
*                                                                       88910018
ZERO     EQU   0         DECIMAL 0                                      88990018
ONE      EQU   1         DECIMAL 1                                      89070018
THREE    EQU   3         DECIMAL 3                                      89110018
FOUR     EQU   4         DECIMAL 4                                      89150018
EIGHT    EQU   8         DECIMAL 8                                      89230018
*                                                                       89310018
LENGTH8  EQU   8         LENGTH OF  -   STEPNAME                        89390018
LPTR     EQU   3                        PTR                             89470018
LTTR     EQU   3                        TTR                             89550018
LTTR4    EQU   4                        TTR SPECIAL (TTR0)              89630018
LSIOT    EQU   1                        SIOT                            89710018
LSMB     EQU   4                        SMB                             89790018
LTRKBAL  EQU   2                        TRK                             89870018
LMODIND  EQU   1                        MOD INDICATOR                   89950018
LLBLT    EQU   1                        LABEL TYPE                      90030018
LCHN     EQU   3                        ITEMS IN CHAIN                  90110018
LJFCB    EQU   3                        JFCB                            90190018
LBLKVOLT EQU   167                      BLANK VOLT                      90270018
LVOLTTBL EQU   4                        ITEMS IN VOLT TABLE             90350018
*                                                                       90430018
BRSETUP  EQU   0         SWITCH TO SETUP ROUTINE                        90510018
BRAFTER  EQU   4         SWITCH TO BYPASS SETUP ROUTINE                 90590018
TBLINCNT EQU   2         CONSTANT TO BE USED IN REG 6 DURING TBL MERGE  90670018
VOLTINC  EQU   6         INCREMENT FOR VOLT                             90750018
SCTINC   EQU   1         INCREMENT FOR SCT                              90830018
ADDVOLTS EQU   168       POINTER TO ADD.VOLTS                           90910018
NOVOLSER EQU   5         NO VOL SER INDICATOR                           90990018
JCLERRIN EQU   12        SW  IF JCL ERROR                               91070018
IOERRIND EQU   8         SW  IF I/O ERROR                               91150018
NOSCTIND EQU   4         SW  IF NO MORE SCT                             91230018
CTR15    EQU   15        CTR CONSTANT  15                               91310018
POIN1ST  EQU   118       POINTER TO 1ST                                 91390018
*                                                                       91470018
PS90NJCT EQU   90        POS 90  IN NEW JCT                             91550018
PS88OJCT EQU   88        POS 88  IN OLD JCT                             91630018
VOLSER1  EQU   4         VOL SER 1ST                                    91710018
TTROJCT  EQU   90        TTR OLD JCT                                    91790018
TTRDSENQ EQU   88        TTR  DSENQ                                     91870018
SPACE    EQU   C' '      CONSTANT - -                                   91950018
*                                                                       92030018
JCT88    EQU   JCT+88         POSITIONS IN RELATION TO FIELD PREVIOUSLY 92110018
RRCNJFR3 EQU   RRCNJFTR+3     DEFINED  (MOST ARE SELFEXPLANATORY)       92190018
RRCNQTB3 EQU   RRCNQTBL+3     *                                         92270018
RRCNQTB4 EQU   RRCNQTBL+4     *                                         92350018
RRCNQTB6 EQU   RRCNQTBL+6     *                                         92430018
RRCSTQV2 EQU   RRCSTNQV+2     *                                         92510018
RRCTTR03 EQU   RRCTTR0+3      *                                         92590018
RRCWQTB3 EQU   RRCWQTBL+3     *                                         92670018
RRCWQTB4 EQU   RRCWQTBL+4     *                                         92750018
RRCWQTB6 EQU   RRCWQTBL+6     *                                         92790018
RRCWQTB8 EQU   RRCWQTBL+8     *                                         92830018
RRCWQTB9 EQU   RRCWQTBL+9     *                                         92910018
SCT168   EQU   SCT+168        *    FIRST DSB TTR IN MSG CLASS           92990018
SCT170   EQU   SCT+170        *                                         93070018
LASTTTR  EQU   SCT+173        *    LAST TTR                             93150018
SCTVOL2  EQU   SCTVOLTB+2     *                                         93230018
*                                                                       93310018
*               HEXADECIMAL CONSTANTS   CODES, MASKS                    93390018
*                                                                       93470018
HEXZERO  EQU   X'00'     HEXADECIMAL  0                                 93550018
HEXONE   EQU   X'01'     HEXADECIMAL  1                                 93630018
HEXFOUR  EQU   X'04'     HEXADECIMAL  4                                 93670018
HEXSIX   EQU   X'06'     HEXADECIMAL  6                                 93710018
HEX16    EQU   X'10'     HEXADECIMAL 16                                 93730018
HEX251   EQU   X'FB'     HEXADECIMAL 251                                93750018
*                                                                       93790018
FCTCODE  EQU   X'04'     FUNCTION CODE                                  93870018
FCTCODEW EQU   X'03'     FUNCTION CODE FOR WRITE                        93950018
LNKBIT   EQU   X'20'     LINK BIT                                       94030018
DISPDEL  EQU   X'04'     DISPOSITION DELETE                             94110018
*                             MASKS TO TEST FIELDS AND CHANGE BITPOSTNS 94190018
ERRMKJCT EQU   X'08'     TEST JCT ERRORS                                94270018
CLRMK    EQU   X'18'     CLEAR                                          94350018
RTNMK    EQU   X'EF'     RETAIN                                         94430018
SYSOUTMK EQU   X'20'     SYSOUT                                         94510018
SIOTSOMK EQU   X'08'     SIOT SYSOUT                                    94590018
SIOTSIMK EQU   X'40'     SIOT SYSIN                                     94670018
GDGALLMK EQU   X'40'     GDG ALL                                        94750018
GDGSNGMK EQU   X'80'     GDG SINGLE                                     94830018
DIPNEWMK EQU   X'04'     DISPOSITION NEW                                94910018
DISPCKMK EQU   X'1F'     CHECK DISPOSITION                              94990018
ALLMK    EQU   X'EF'     ALL                                            95070018
ONEMK    EQU   X'10'     ALL BUT ONE                                    95150018
BUTPVTMK EQU   X'20'     ALL BUT PVT                                    95230018
PVTMK    EQU   X'DF'     PVT ONLY                                       95310018
STPMK    EQU   X'08'     STP                                            95390018
LBLTMK1  EQU   X'77'                   LABEL TYPE - 1             19200 95470019
LBLTMK2  EQU   255-LBLTMK1             LABEL TYPE - 2             19200 95550019
FCTASSMK EQU   X'01'     ASSIGN FUNCTION                                95630018
HEX20    EQU   X'20'     LENGTH OF JFCB NVOL,VOLS,AND EXTL FLD   A38666 95680021
*                                                                       95710018
*                                                                       95790018
         EJECT                                                          95870018
         END                                                            95950018
                                                                        96030018
                                                                        96110018
                                                                        96190018
                                                                        96270018
                                                                        96350018
                                                                        96430018
                                                                        96510018
