         TITLE 'IEFVSDRA-MVT RESTART ACTIVATION'                        00700017
IEFVSDRA CSECT                                                          01400017
*C 456700-457600                                                 A50108 01450021
*464500-465000                                                     I250 01500019
* 454300-455200,462000-462400                                       O99 01700019
**********************************************************************  02100017
*                                                                       02800017
* NAME        .IEFVSDRA                                                 03500017
*                                                                       04200017
* FUNCTION     .TO ACTIVATE THE RESTART READER WHICH WILL START THE     04900018
*              RESCHEDULING PROCESS FOR JOB RESTART                     05600017
*                                                                       06300017
* INPUT       .A TABLE OF ONE OR MORE JOBNAMES- GENERAL REGISTER 1      07000017
*              CONTAINS THE TABLE POINTER -ZERO INDICATES TABLE END     07700017
*                                                                       08400017
* OUTPUT       .ONE OR MORE START IEFREINT COMMANDS                     08600018
*                ONE IF ONE P/P ABENDS                                  08800018
*                TWO IF WARM START AND FIFTEEN JOBS WERE GOING          09000018
*              .THE COMMAND CONTAINS                                    09200018
*              THE JOBNAME(S) TO BE PROCESSED BY THE READER             09800017
*                IN THE FORM  S IEFREINT,,,(JOBNAMES,,,) FOR MVT        09900018
*                             S IEFREINT.PXX,,,(JOBNAME) FOR MFTPPABEND 10000018
*                             S IEFREINT.S,,,(JOBNAMES,,,) IF MFT WS    10100018
*                                                                       10500017
* BASIC FLOW  .GET CORE FOR COMMAND BUFFER                              11200017
*             .SET UP THE COMMAND OP CODE AND SPECIFIC READER PROCEDURE 11900017
*              TO BE CALLED                                             12600017
*             .SCAN JOBNAME TO ELIMINATE TRAILING BLANKS                13300017
*             .INSERT JOBNAME INTO COMMAND  -WITH COMMA IF MORE EXIST   14000017
*             .MGCR WHEN LIST END REACHED OR COMMAND BUFFER FILLED      14700017
*                                                                       15400017
* ENTRY       .FROM INITIATOR -IEFSD168  - WITH  JOBNAME TABLE OF ONE   16100017
*                                          NAME                         16800017
*             .FROM WARM START-IEFSD305  - WITH JOBNAME TABLE OF FROM   17500017
*                                          ONE TO FIFTEEN JOBNAMES      18200017
**********************************************************************  18900017
*                                                                       19600017
R0       EQU   0                                                        20300017
R1       EQU   1                                                        21000017
R2       EQU   2                                                        21700017
R3       EQU   3                                                        22400017
R4       EQU   4                                                        23100017
R5       EQU   5                                                        23800017
R6       EQU   6                                                        24500017
R7       EQU   7                                                        25200017
R8       EQU   8                                                        25900017
R9       EQU   9                                                        26600017
RA       EQU   10                                                       27300017
RB       EQU   11                                                       28000017
RC       EQU   12                                                       28700017
RD       EQU   13                                                       29400017
RE       EQU   14                                                       30100017
RF       EQU   15                                                       30800017
D4       EQU   4                                                    O99 31100019
*                                                                       31500017
*                                                                       32200017
*              MODULE USES GENERAL REGISTER 9 AS A BASE                 32900017
         SAVE  (14,12)                                                  33600017
         BALR  R9,R0              ESTABLISH ADDRESSABILITY              34300018
         USING *,R9                                                     35000017
         B     RA100              BR AROUND DUMP IDENTIFIER             35700018
         DC    X'EEEE'             CORE DUMP EYE CATCHER                36400017
         DC    CL8'IEFVSDRA'       MODULE IDENTIFICATION                37100017
         DC    X'EEEE'            CONTINUED                             37800018
RA100    EQU   *                                                        38500017
         LR    R2,R1          SAVE JOBNAME POINTER                      39200017
         GETMAIN R,LV=128     GET CORE FOR COMMAND BUFFER               39900017
         LR    R8,R1          SAVE POINTER                              40600017
         USING COMMND,R8      SET UP DSECT BASE                         41300017
RA110    EQU   *                                                        42000017
         BAL   RA,RA999           GO TO CLEAR MSGBUF - RET R7 AT BUFFER 43000017
*                                                                       43600018
         L     R3,CVTPTR          LOAD CVT POINTER                      44200018
         USING CVT,R3                                                   44860017
         CLI   CVTDCB,MFT2        IS THE SYSTEM MFT 2                   44890018
         BNE   RA114              NO - GO TO FORMAT COMMAND             44920017
         L     R4,CVTTCBP         YES - LOAD PTR TO TCB PTRS            44950017
         L     R4,OLD(R4)         LOAD PTR TO CURRENT TCB               44980018
         DROP  R3                 REG 4 CONTAINS TCB POINTER            45010017
         USING IEFSD033,R5                                              45040017
         L     R5,TCBPIB(R4)      LOAD PTR TO PIB                       45070017
         LA    R5,ZERO(R5)        CLEAR OUT STATUS BYTE           MFTCR 45075018
         LTR   R5,R5              IF NO PIB PTR - WARM START            45080018
*   WE ARE RUNNING UNDER THE MASTERS TCB AT WARM START AND THERE IS     45090018
*   NO PIB FOR THE MASTERS REGION                                       45100018
         BNE   RA115              IF NOT - PARTITION RESTART            45130017
         MVC   COMWS,WSCMND       MOVE '.S,,,(' TO BUFFER               45150018
*   NEED TO START SYSTEM ASSIGNED RDR AT WARM START IN MFT2             45170018
         LA    R6,COMWSLEN        LOAD LENGTH OF CMND TO POSITION       45190018
*                                 FOR INSERTION OF JOBNAMES             45220017
         B     RA124              GO TO MOVE VERB AND IEFCHKPT TO BUF   45250017
RA114    DS    0H                 ENTER.  ** NON MFT II RESTART COMMAND 45280017
         MVC   COMMVT,MVTCMND     MOVE ',,,(' TO BUFFER                 45310018
         LA    R6,COMVTLEN        LOAD LENGTH OF COMMAND                45340018
         B     RA124              GO TO MOVE VERB AND READER            45370017
RA115    DS    0H                 ENTER.  PARTITION RESTART             45400017
         L     R3,SD33PEND         ADDR PENDING COMMAND'S CSCB      O99 45420019
         LTR   R3,R3               TEST FOR PENDING COMMAND         O99 45440019
         BE    RA120               NONE - GOTO FORMAT RESTART CMND  O99 45460019
         USING CHAIN,R3                                             O99 45480019
         MVC   SD33PEND(D4),CHPEND SAVE ADDRESS NEXT PENDING CSCB   O99 45500019
*                                                                       45550017
*        ISSUE MESSAGES TO OPERATOR ABOUT CANCELLING THE COMMANDS       45580017
*                                                                       45610017
         MVC   COMLEN(MSGLEN),WTOMSG   MOVE MSG TEST TO BUFFER          45620018
TWENTY   EQU   20                     PUT OUT 1ST 19 CHARACTERS  A50108 45670021
         LA    R1,CHBUF+TWENTY         OF THE PENDING COMMAND    A50108 45720021
         LA    R0,CHBUFP1         GET BEG OF OPERNDS FOR LNG CALC       45770018
         SR    R1,R0              R1 CONTAINS LENGTH-1 FOR AN EXECUTE   45850017
*        THE ONLY CMNDS WHICH WILL BE PENDING ARE START COMMANDS        45910017
         EX    R1,MVCCMND         EXECUTE THE MOVE                      45940017
         SR    R0,R0              CLEAR REG 0 FOR WTO/MCS STYLE         45970018
         IC    R0,CHUCMP          PICK UP CONSOLE IDENT FOR MCS WTO     46000018
         LR    R1,R8              LOAD ADDR OF COMMAND AND HEADER       46030017
         WTO   MF=(E,(1))         ISSUE WTO                             46060017
         BAL   RA,RA999           CLEAR MSG HDR AND BUFFER              46070017
*                                                                       46090017
         OI    CHSTS,CHFC         SET BITS FOR UNCHAIN AND DELETE       46120017
         OI    CHSTS,CHDL         FOR SVC 34                            46130018
         LR    R1,R3              LOAD CSCB ADDRESS INTO R1             46150017
         MGCR  (1),CHAIN          ISSUE THE UNCHAIN SVC                 46180017
         B     RA115               UNCHAIN NEXT PENDING CSCB        O99 46220019
*                                                                       46270017
RA120    DS    0H                 ENTER   FORMAT PARTITION RESTART COMN 46300017
         TM    SD33STAT,DEFINE    IS THERE A DEFINE PENDING       MFTCR 46302018
         BZ    RA121              NO - CONTINUE                   MFTCR 46304018
*                                                                       46306018
         NI    SD33STAT,DEFINOFF  IF SO TURN OFF BIT SO THIS      MFTCR 46308018
*                                 START COMMAND WILL BE HONORED   MFTCR 46310018
         LNR   R5,R5              SAVE NEG PIB PTR AS INDICATOR TOMFTCR 46312018
*                                 TURN BIT BACK ON WHEN THE START MFTCR 46314018
*                                 HAS BEEN EXECUTED               MFTCR 46316018
DEFINOFF EQU   X'FB'                                              MFTCR 46318018
RA121    DS    0H                                                 MFTCR 46320018
         MVC   COMID,PSCMND       MOVE '.P  ,,,(' TO COM BUFFER         46330018
         LA    R6,COMFTLEN        LOAD LENGTH OF TOTAL CMND             46360018
         SR    R3,R3              CLEAR REG                             46390017
         IC    R3,TCBIDF(R4)      PICK UP TCB ID                        46420017
         USING CVT,RB                   CVT ADDRESSABILITY         I250 46430019
         L     RB,CVTPTR                POINTER TO CVT             I250 46440019
         L     RB,CVTTSKS               POINTER TO P0 TCB          I250 46450019
         DROP  RB                                                  I250 46460019
         L     RB,ZERO(RB)              P0 TCB ADDRESS             I250 46470019
         SR    R0,R0                    CLEAR RGISTER FOR INSERT   I250 46480019
         IC    R0,TCBIDF(RB)            P0 ID FIELD                I250 46490019
         SR    R3,R0                    CALCULATE PARTITION NUMBER I250 46500019
         CVD   R3,COMMND          USE BEG OF BUFFER FOR WORK AREA       46530017
         UNPK  COMIDP2(L2),COMMNDP6(L2)     UNPACK                      46550018
         OI    COMIDP3,CZERO      OR OUT THE SIGN                       46570018
         XC    COMHDR,COMHDR      CLEAR WTO HEADER                      46590018
*                                                                       46630017
RA124    DS    0H                                                       46660017
         MVC   COMBUF,SCMND       MOVE VERB AND PROCNAME TO BUFFER      46690018
         AR    R7,R6              ADD LENGTH TO POSITION FOR JOBNAMES   46720017
RA125    EQU   *                                                        46900017
         BAL   RB,RA800       GO GET FIRST JOBNAME LENGTH -R2 POINTS TO 47600017
*                             FIRST JOBNAME - R3 WILL RETURN WITH LEN   48300017
         EX    R3,RAMVC       TO EXECUTE JOBNAME MOVE                   49000017
         LA    R7,ONE(R3,R7)      POINT PAST JOBNAME                    49500018
         MVI   ZERO(R7),RTPAREN   MOVE IN PARM DELIMITER                50000018
         CLI   EIGHT(R2),ZERO     AMY MORE JOBNAMES                     50500018
         BNE   RA200          BRANCH ON YES                             51100017
         LA    RB,RA300          SET UP EXIT ADDR                       51800017
*                                                                       52500017
*              SCHEDULE  COMMAND VIA MGCR  SUBROUTINE                   53200017
*              REG RB CONTAINS RETURN  LOCATION                         53900017
RA150    EQU   *                                                        54600017
         LA    R7,ONE(R7)         POINT TO BLANK AFTER RT PAREN         54900018
         LA    R6,COMHDR          LOAD BEGIN OF BUFFER TO CALCULATE     55200017
*                                 LENGTH OF COMMAND                     55500017
         SR    R7,R6            SUBTRACTED FROM END OF COMMAND GIVES    56000017
         STH   R7,COMLEN        LENGTH  TO BE SAVED                     56700017
         USING CVT,R7                                                   56900018
         L     R7,CVTPTR           PICK UP PTR TO CVT                   57100018
         LR    R1,R8                                                    57400017
         SR    R0,R0               CLEAR REG ZERO FOR MGCR              57700018
         MGCR  (1)                                                      58100017
         TM    CVTDCB,MFT2        IS THIS AN MFT SYSTEM                 58200018
         BCR   EIGHT,RB            NO DON'T TEST FOR PEND CMND    MFTCR 58300018
         LTR   R5,R5              IS PIB PTR NEGATIVE             MFTCR 58310018
         BNL   RA250              NO - CONTINUE                   MFTCR 58320018
         LPR   R5,R5              YES - MAKE IT POSITIVE AND      MFTCR 58330018
         OI    SD33STAT,DEFINE    TURN THE DEFINE BIT BACK ON     MFTCR 58340018
RA250    DS    0H                                                 MFTCR 58350018
         LTR   RF,RF               YES - DID THE START GO         MFTCR 58400018
         BNE   RA110               NO - START ALL OVER TO CANCEL  MFTCR 58500018
*                                  THE PENDING COMMAND            MFTCR 58600018
         BR    RB                  OTHERWISE - CONTINUE - RETURN  MFTCR 58700018
RA300    EQU   *                                                        59500017
         LR    R1,R8          SETUP TO FREE BUFFER                      60200017
         FREEMAIN R,LV=128,A=(1)   FREE COMMAND AREA                    60900017
         RETURN (14,12),T                                               61600017
RA200    EQU   *                                                        62300017
*                                                                       63000017
*              MORE JOBNAMES TO PROCESS- SEE IF NEXT JOBNAME WILL FIT   63700017
*              IF NOT - EXECUTE FIRST COMMAND AND SETUP NEXT            64400017
*              IF WILL FIT - JUST ADJUST REGISTERS AND INSERT COMMA     65100017
*              R7 - HAS BEGIN OF NEXT JOBNAME SPACE                     65800017
*              R2 - POINTS TO START OF LAST JOBNAME                     66500017
         LA    R2,EIGHT(R2)   POINT TO CURRENT JOBNAME                  67200018
         LA    R6,LASTNAME        LAST JOBNAME CAN FIT IN COMBUF+116 -  67900018
         CR    R7,R6          ADDR  IS HIGHER THAN THAT ADDR -NEW COMND 68600017
         BNL   RA210          MUST BE CREATED -BCH TO PUT OUT COMMAND   69300017
         MVI   ZERO(R7),COMMA     INSERT SEPARATING COMMA               70000018
         LA    R7,ONE(R7)         POINT TO NEXT SLOT AFTER COMMA        70700018
         B     RA125              GO BACK TO INSERT NEXT                71400018
*                                                                       72100017
RA210    EQU   *                                                        72800017
         BAL   RB,RA150       GO PUT OUT FIRST COMMAND                  73500017
         B     RA110          GO INITIALIZE NEW COMMAND                 74200017
*              SUBROUTINE SCANS A JOBNAME TO CALCULATE THE LENGTH OF    74900017
*              THE JOBNAME. SCAN OPERATES RIGHT TO LEFT-TESTING BLANKS  75600017
*              R2  - CONTAINS THE POINTER TO THE FIRST CHARACTER        76300017
*              R3  - WILL CONTAIN THE EXECUTABLE LENGTH - ONE LESS THAN 77000017
*                    TRUE LENGTH                                        77700017
*              R4  - IS USED AS A WORK REGISTER                         78400017
RA800    EQU   *                                                        79100017
         LA    R3,JNLENL1      MAX JNAME LEN MINUS ONE                  79800018
RA805    EQU   *                                                        80500017
         LA    R4,ZERO(R2,R3)     ADDRESS OF CHARACTER TO TEST          81200018
         CLI   ZERO(R4),BLANK     IS CHARACTER A BLANK                  81900018
         BNE   RA815          BCH NO TO EXIT SUBROUTINE                 82600017
         BCT   R3,RA805    BCH TO TEST NEXT CHAR                        83300017
RA815    EQU   *                                                        84000017
         BR    RB             EXIT SUBROUTINE                           84700017
*                                                                       85400017
RA999    DS    0H                 ENTER * CLEAR MSGHEADER AND BUFFER    85470017
         XC    COMHDR,COMHDR      CLEAR MESSAGE HEADER                  85540018
         MVI   COMBUF,BLANK       MOVE IN A BLANK                       85610018
         MVC   BUFP1,COMBUF                                             85680018
         LA    R7,COMBUF                                                85750017
         BR    RA                 RETURN WITH REG 7 POINTING TO BUFFER  85820018
*                                                                       85890017
*                                                                       85960017
RAMVC    MVC   ZERO(ONE,R7),ZERO(R2)   EXECUTED MOVE OF JOBNAMES        86360018
*                                                                       86800017
MVCCMND  MVC   MSGOPRND,CHBUF     EXECUTED MOVE OF PENDNG CMND TO BUFF  86880018
*                                 BUFFER FOR MSG TO THE OPERATOR        86960017
SCMND    DC    C'S IEFREINT'      RESTART READER VERB + PROCNAME        87040018
PSCMND   DC    C'.P  ,,,('        MFT P/P RESTART PARTITION ID          87120018
WSCMND   DC    C'.S'     * THESE TWO   * MFT W/S RESTART SYSTEM ID      87200018
MVTCMND  DC    C',,,('   * MUST BE CONTIG *MVT COMMAND                  87280018
WTOMSG   WTO   'IEF185I COMMAND CANCELED BY RESTART READER - START     *87287018
                      ',MF=L,DESC=(5),MCSFLAG=(REG0)                    87294018
*    MSG ISSUED WHEN A START COMMAND IS ALREADY PENDING AT RESTART      87301018
*        READER INITIATE TIME                                           87308018
MSGEND   EQU   *                                                        87315018
MSGLEN   EQU   MSGEND-WTOMSG      LENGTH OF MSG ITSELF                  87322018
L2       EQU   2                                                        87329018
L3       EQU   3                                                        87336018
OLD      EQU   4                                                        87343018
BLANK    EQU   C' '                                                     87350018
ZERO     EQU   0                                                        87357018
ONE      EQU   1                                                        87364018
JNLENL1 EQU 7                                                           87371018
INC7     EQU   7                                                        87378018
EIGHT    EQU   8                                                        87385018
TWO      EQU   2                                                        87392018
FOUR     EQU   4                                                        87399018
RTPAREN  EQU   C')'                                                     87406018
COMMA    EQU   C','                                                     87413018
SEVEN    EQU   7                                                        87420018
CZERO    EQU   C'0'                                                     87427018
         DS    0D                 ALIGNMENT                             87450017
COMMND   DSECT                                                          87500017
COMHDR   DS    F                  HEADR FOR WTO OR MGCR                 87590018
COMMNDP6 EQU   COMHDR+6                                                 87680018
         ORG   COMMND             ORG BACK TO SPLIT IT UP               87770018
COMLEN   DS    1H                 HALFWORD FOR LENGTH                   87860018
         DS    1H                 HALFWORD OF ZEROS                     87950018
BUFBEG   EQU   *                                                        88040018
COMBUFF  DS    C                  START OF BUFFER                       88130018
BUFP1    DS    CL123              REST OF BUFFER - TOTAL LENGTH - 124   88220018
         ORG   COMBUFF            ORG BACK TO SECTION BUFFER            88310018
COMBUF   DS    CL10               'S IEFREINT'                          88400018
COMID    DS    CL8                .P  ,,,( MFT2 P/P RESTART             88490018
COMIDP2  EQU   COMID+2                                                  88580018
COMIDP3  EQU   COMID+3                                                  88670018
LEN1     EQU   *                                                        88760018
         ORG   COMID              ORG BACK FOR WS AND MVT CMNDS         88850018
COMWS    DS    CL6                .S,,,( MFT2 WARM START RESTART        88940018
LEN2     EQU   *                                                        89030018
         ORG   COMID              FOR MVT COMMAND                       89120018
COMMVT   DS    CL4                ,,,( MVT RESTART                      89210018
LEN3     EQU   *                                                        89300018
         ORG   COMBUFF            ORG BACK TO SECTION DSECT FOR LAST    89390018
         DS    116C               DISPLACEMENT TO LASTNAME              89480018
LASTNAME DS    C                  ONE MORE NAME WILL FIT AFTER THIS     89570018
COMFTLEN EQU   LEN1-BUFBEG        LENGTH OF THE RESPECTIVE              89660018
COMWSLEN EQU   LEN2-BUFBEG        FORMS OF THE START                    89750018
COMVTLEN EQU   LEN3-BUFBEG        RESTART READER COMMAND                89840018
         ORG   COMBUFF            ORG BACK TO SECTION FOR OTHER MSG     89930018
MSGTXT   DS    CL45               TEST OF MSG 'COMMAND CANCELED         90020018
MSGVRB   DS    CL6                VERB - 'S' ONLY START CMND PENDING    90110018
MSGOPRND DS    C                  OPERAND OF CMND - NOT ITS PARMS       90200018
         EJECT                                                          90360017
         IEFSD033                                                       90420017
PENDBIT  EQU   X'20'                                                    90450018
DEFINE   EQU   X'04'                                                    90460018
         EJECT                                                          90480017
CHN      DSECT                                                          90540017
         IEECHAIN                                                       90600017
CHBUFP1  EQU   CHBUF+1                                                  90630018
         EJECT                                                          90660017
CVT      DSECT                                                          90720017
         CVT                                                            90780017
MFT2     EQU   X'20'                                                    90810018
         EJECT                                                          90840017
         TCBEQU                                                         90900017
         END                                                            91000017
