         TITLE 'IEFVSMBR'                                               00300017
*                                                                       00600017
* FUNCTION     TO READ SMB CHAIN, CONVERTING JCL ENTRIES INTO           00900017
*              ORIGINAL JCL FORMAT SO AS TO ENABLE A RESTARTED          01200017
*              JOB TO BE REINTERPRETED.                                 01500017
*                                                                       01800017
* BASIC FLOW                                                            02100017
*        INITIAL ENTRY                                                  02400017
*                                                                       02700017
*              INITIALIZATION IS ACCOMPLISHED ONLY DURING THE           03000017
*              INITIAL PASS FOR A PARTICULAR DCB.(A SWITCH IS           03300017
*              SET IN THE DCB TO ASCERTAIN INITIAL ENTRY.)              03600017
*              INITIAL ENTRY PROCESSING CONSISTS OF-                    03900017
*                   GETTING CORE FOR WORK AREA, BUFFER, AND QMPA        04200017
*                   INITIALIZING QMPA,LOADING Q MANAGER                 04500017
*                   READING IN THE JOBS SCTS TO GET THE TTR OF THE SMB* 04600017
*                          ALLOCATED AFTER THE LAST STEP, - TO USE AS * 04700017
*                          A COMPARE FOR END OF THE SMB CHAIN.        * 04800017
*                   CLEARING 'DCBRECAD'  TO INDICATE SECOND PASS      * 04900017
*                   READING FIRST SMB                                   05100017
*                   LOADING POINTERS FOR END OF BLOCK, START OF         05400017
*                        ENTRY, END OF ENTRY, END OF FIELD, ETC         05700017
*                   BRANCHING TO NORMAL ENTRY PROCESSING                06000017
*        SUBSEQUENT ENTRY                                               06300017
*                                                                       06600017
*              AFTER INITIALIZATION, EACH ENTRY CAUSES A RECONSTRUCTED  06900017
*              JCL STATEMENT TO BE PREPARED IN THE BUFFER,POINTED TO    07200017
*              BY REG 1. STEPS INCLUDE-                                 07500017
*                   CHECKING CURRENT ENTRY START ADDRESS TO SEE         07800017
*                   IF SMB IN CORE IS EXHAUSTED                         08100017
*                   READING ANOTHER SMB IF NECESSARY,SKIPPING DSB(S)    08400017
*                   IGNORING NON-COMPRESSED MESSAGES                    08700017
*                   EXPANDING NEXT COMPRESSED MESSAGE, MOVING TO        09000017
*                   OUTPUT BUFFER,AND RETURNING.                        09300017
*                                                                       09600017
*        END OF CHAIN                                                   09900017
*              AT EOC, CLEANUP IS ACCOMPLISHED AND CONTROL IS PASSED    10200017
*                   TO END OF FILE ROUTINE POINTED TO BY DCB.           10500017
*              CLEANUP CONSISTS OF-                                     10800017
*                   ZEROING SPECIAL POINTERS AND SWITCHES BEING         11100017
*                        CARRIED IN DCB                                 11400017
*                   FREEING ALL GOTTEN CORE                             11700017
*                   DELETING Q MANAGER                                  12000017
*              .ENTRY REQUIREMENTS - DCB POINTED TO BY R1               12300018
*                                                                       12600017
*        ATTRBIUTES. REENTRANT                                          12900017
         EJECT                                                          13200017
         IEFQMPAM                                                       15300017
QMPCA    DS    F                  REMOTE LIST - READIN AREA PTR         15400018
QMPEX    DS    F                  REMOTE LIST - TTR OF CONTROL BLOCK    15500018
         EJECT                                                          15600017
         DS    0D                                                       15900017
OWNCR    DSECT                                                          16200017
*                                                                       16400017
*    THIS WORK SPACE IS USED BY IEFVSMBR TO READ IN SMB'S AND TO        16600017
*        EXPAND THEM INTO A BUFFER FOR THE READER/INTERPRETER.          16800017
*                                                                       17000017
JCLSTMNT DS    CL88                JCL STATEMENT PASSED TO R/I          17100018
INBUF    DS    CL176              SMB INPUT AREA.                       17200017
CRQM     DS    CL44               QMNGR PARAMETER AREA + QMPCA & QMPEX. 17600017
NXTSMB   DS    F                  TTR OF NEXT SMB.                      18000017
CURPT    DS    F                  PTR TO CURRENT ENTRY IN SMB.          18200017
SMBRWORK DS    F                                                        18500018
QMPTR    DS    F                                                        18800018
         DS    0H                                                       19000018
BFER     DSECT                                                          19200018
BUFFER   DS    C                  DIVISION FOR CLEARING AREA            19400018
BUFF     DS    CL79               LENGTH OF ENTIRE BUFFER               19600018
         EJECT                                                          19800017
         DCBD  DSORG=(PS)                                               20100017
         EJECT                                                          20200017
         IEFAJCTB                                                       20800017
         ORG   SMBMSGLN           ORG BACK TO DIVIDE AREA FOR           20810018
SMBCMPMS DS    C                  COMPRESSED MESSAGE FORMAT - INDICATOR 20820018
SMBTOTLN DS    C                  LENGTH OF TOTAL MESSAGE               20830018
SMBFLDLN DS    C                  LENGTH OF THIS FIELD                  20840018
         ORG   SMBMSGLN           ORG BACK TO FORMAT                    20850018
SMBNOBLN DS    C                  SECOND FIELD - NUMBER OF BLANKS       20860018
SMBFDLN2 DS    C                  LENGTH OF SECOND FIELD                20870018
         EJECT                                                          20900017
         IEFVWKAR                                                       21000017
         EJECT                                                          21070017
SCT      DSECT                                                          21140017
         IEFASCTB                                                       21210017
RRCWORK2 DSECT                                                          21212018
RRC2JOB  DS    CL88                DSDR JOB STATEMENT                   21214018
RRC2EXEC DS    CL88                DSDR EXEC STATEMENT                  21216018
RRC2DD   DS    CL88                DSDR DD STATEMENT                    21218018
RRC2QMPA DS    CL36                QMPA                                 21220018
RRC2EPRM DS    CL8                 EXTERNAM PARMS                       21222018
RRC2SMR1 DS    F                   USED BY SMB READER                   21224018
RRC2SMR2 DS    F                   USED BY SMB READER                   21226018
RRC2WORK DS    F                                                        21228018
RRC2QMGR DS    F                   ADDR OF QMGR                         21230018
RRC2WTTR DS    F                                                        21232018
RRC2ILST DS    F                   ADDR OF R/I PARMS                    21234018
RRC2CIBP DS    F                   CIB ADDR                             21236018
RRC2WEND EQU   *                                                        21238018
RRCW2LN  EQU   RRC2WEND-RRC2JOB                                         21240018
SVRBSECT DSECT                                                          21242018
SVRBAA   DS    CL28                FIRST PART OF SVRB                   21244018
SVRBNXT  DS    F                   POINTER TO NEXT RB                   21246018
SVRBREG0 DS    F                   REGISTER 0                           21248018
SVRBREG1 DS    F                   REGISTER 1                           21250018
SVRBREG2 DS    F                   REGISTER 2                           21252018
SVRBREG3 DS    F                   REGISTER 3                           21254018
SVRBREG4 DS    F                   REGISTER 4                           21256018
SVRBREG5 DS    F                   REGISTER 5                           21258018
SVRBREG6 DS    F                   REGISTER 6                           21260018
SVRBREG7 DS    F                   REGISTER 7                           21262018
SVRBREG8 DS    F                   REGISTER 8                           21264018
SVRBREG9 DS    F                   REGISTER 9                           21266018
SVRBREGA DS    F                   REGISTER A                           21268018
SVRBREGB DS    F                   REGISTER B                           21270018
SVRBREGC DS    F                   REGISTER C                           21272018
SVRBREGD DS    F                   REGISTER D                           21274018
SVRBREGE DS    F                   REGISTER E                           21276018
SVRBREGF DS    F                   REGISTER F                           21278018
SVRBEXSV DS    12F                 EXTENDED SAVE AREA                   21280018
XCTLLIST EQU   SVRBEXSV+8                                               21282018
         EJECT                                                          21300017
IGC0005B CSECT                                                          21400018
* A 360700-362100,367000                                        SA62541 21500021
*                                                                       21640017
*              R1 = PTR TO DCB                                          21680017
*              RC = PTR TO IWA                                          21720017
*              RD = PTR TO RSA                                          21760017
*              RE = RETURN REGISTER                                     21800017
*                                                                       21840017
         BALR  RB,R0              ESTABLISH                             21920018
         USING *,RB                  ADDRESSABILITY                     22000018
         SSM   SYSMASK                                                  22080018
         LR    RC,R5               RB ADDR TO RC                        22160018
         USING SVRBSECT,RC                                              22240018
         L     RC,SVRBNXT          LOAD ADDR OF NEXT RB                 22320018
         L     RF,SVRBNXT          LOAD ADDR OF NEXT RB                 22400018
         LA    RF,0(RF)                                                 22480018
         LA    R4,0(R4)                                                 22560018
         LR    RC,R5               RESTORE RB ADDR TO RC                22640018
         CR    R4,RF               DOES NEXT RB POINT TO TCB            22720018
         BNE   BR00                IF NOT--REINT                        22800018
         MVC   SVRBEXSV(8),RESTART MOVE NAME OF FIRST LOAD OF RESTART   22880018
         LA    RF,SVRBEXSV                                              22960018
         ST    RF,XCTLLIST                                              23040018
         LA    RF,XCTLLIST                                              23120018
         XCTL  SF=(E,(15))         XCTL TO RESTART                      23200018
BR00     EQU   *                                                        23280018
         SPACE                                                          23500017
         LR    R8,R1              SET UP DCB ADDRESSING.                23700017
         USING IHADCB,R8                                                23900017
         L     R7,DCBBLKCT        SET UP ADDRESSING TO WORK CORE.       24100017
         USING OWNCR,R7           WILL BE ZERO IF THIS IS FIRST TIME.   24300017
         SPACE                                                          24500017
*   CHECK FOR FIRST TIME                                                24700017
         L     R4,DCBRECAD        LOAD ADDR OF RRC'S WORK AREA          24900017
         USING RRCWORK2,R4                                              25100018
         LTR   R4,R4              IS IT ZERO                            25300018
         BZ    BR000              B IF NOT FIRST TIME.                  25500017
*                                                                       26400018
*                                                                       27300017
*        INITIALIZATION                                                 27600017
*                                                                       28200018
         LR    R7,R4               SET UP ADDRESSING FOR LOCAL WORK     28800018
         ST    R7,DCBBLKCT         SAVE ADDRESS                         29400018
         SPACE                                                          30000017
         LA    R6,CRQM            QMNGR PARAMETER AREA ADDRESSING.      30300017
         USING IOPARAMS,R6                                              30600017
         LA    RF,INBUF            GET ADDR OF INPUT BUFFER             30800018
         ST    RF,QMPCA            STORE IN QMPA EXTERNAL PARMS         31000018
         MVI   QMPOP,QMREAD       SET TO READ.                          31200017
         LA    R2,QMPCA           SET POINTER                           31500017
         ST    R2,QMPCL                TO REMOTE LIST.                  31800017
         MVI   QMPNC,ONE          NBR OF RECORDS TO READ                32100018
         SPACE                                                          32400017
         MVI   NXTSMB+L3,ZERO     CLEAR LOW ORDER BYTE OF TTR FIELD     33100018
*  PREPARE TO READ THE SCTS TO END OF CHAIN                             33905017
*  TTR OF THE DUMMY SMB PLACED IN RRC2WORK                              33915018
         XC    SMBRWORK,SMBRWORK                                        33925018
         BAL   RA,BRSMB           1ST PASS - GO TO READ SCTS TO EOC     33935018
*  CLEAR 'DCBRECAD' TO INDICATE SECOND PASS                             33946017
*  THIS IS USED AS A SECOND PASS INDICATOR BY THE READ ROUTINE ALSO     33952017
         XC    DCBRECAD,DCBRECAD                                        33972018
         MVC   NXTSMB(3),RRC2SMR2                                       34032018
*                                 TO LOCAL CORE FOR THE READ.           34100017
         BAL   RA,BRSMB           GO TO READ IN THE FIRST SMB.          34500017
         B     BR001              GO TO NORMAL PROCESSING.              34800017
         SPACE                                                          35100017
BR000    DS    0H                 ENTRY.   NOT FIRST TIME.              35400017
         L     R9,CURPT           POINTER TO THE PREVIOUS ENTRY IN SMB  35700017
         USING SMBMSGLN,R9                                              35800018
BR001    DS    0H                 ENTRY.                                36000017
         LA    RF,CRQM            GET COMPARAND                 SA62541 36070021
         CR    RF,R9              END OF SMB?                   SA62541 36140021
         BNH   BR001A             YES, GET NEXT SMB             SA62541 36210021
         CLI   SMBMSGLN,ZERO      IS IT END OF SMB                      36300018
         BNE   BR002              B ON NOT END OF SMB.                  36600017
BR001A   DS    0H                 LABEL                         SA62541 36700021
         BAL   RA,BRSMB           LINK TO READ NEXT SMB.                36900017
*                      RETURNED WITH R9 = CURRENT ENTRY.                37200017
BR002    DS    0H                                                       37500017
         CLI   SMBCMPMS,CONDMSG   CHECK FOR CONDENSED MESSAGE           37800018
         BE    BR003              B ON YES TO EXPAND MESSAGE.           38100017
*                                                                       38700017
* * *    NON-CONDENSED MSG NOW UP                                       39000017
*                                                                       39300017
         SR    R2,R2                                                    39500017
         IC    R2,SMBMSGLN                                              39700018
         LA    R9,ONE(R2,R9)      TO POINT TO NEXT MESSAGE              39900018
         B     BR001              TRY NEXT MESSAGE                      40100018
         SPACE                                                          40300017
*                                                                       40500017
*   EXPANDS CONDENSED MESSAGE AND MOVES INTO OUTPUT BUFFER.             40700017
*        R9 POINTS TO FRONT OF ENTRY                                    41100017
*                                                                       41700017
BR003    DS    0H                                                       42000017
         LA    R9,ONE(R9)         POINT AT ENTRY LENGTH.                42200018
         LR    R5,R7               ADDR OF BUFFER TO REG 5              42400018
         USING BFER,R5                                                  42500018
         MVI   BUFFER,BLANK       BLANK OUT                             42600018
         MVC   BUFF,BUFFER           BUFFER AREA                        42700018
         DROP  R5                                                       42800018
         SR    R3,R3              LENGTH COMPRESSED RECORD.             43200017
         SR    R4,R4              FIELD LENGTH.                         43500017
         IC    R3,ZERO(R9)        PICK UP TOTAL ENTRY LEGNTH            43800018
         BCTR  R3,R0              DECREMENT FOR END COUNT               44100018
BR004    DS    0H                 ENTER.                                44400017
         BCTR  R3,R0              DECREMENT TOTAL LENGTH FOR END COUNT. 44700018
         IC    R4,ONE(R9)         PICK UP ENTRY LENGTH.                 44900018
         BCTR  R4,R0                   DEC ENTRY LENGTH FOR MOVE        45100018
         EX    R4,BRMVC1          MOVE ENTRY TO OUTPUT BUFFER           45400017
         LA    R4,ONE(R4)              INCR FOR INDEXING                45600018
         AR    R5,R4              INCREMENT BUF POINTER BY FLD LENGTH.  45900017
         LA    R9,TWO(R4,R9)      POINT AT NBR BLANKS OR NEXT ENTRY.    46200018
         BCTR  R3,R0              DECREMENT TOTAL LENGTH FOR END COUNT. 46500018
         SR    R3,R4              SUBTRACT FIELD LENGTH FROM TOTAL.     46800017
         BZ    BR005              B IF END OF SMB ENTRY.                47100017
         IC    R4,ZERO(R9)        PICK UP NBR OF BLANKS.                47800018
         AR    R5,R4              INCR BUFF POINTER BY NBR BLANKS.      48600017
         B     BR004              GO TO MOVE NEXT ENTRY.                48900017
         SPACE                                                          49200017
BRMVC1   MVC   ZERO(ONE,R5),TWO(R9)    EXECUTED                         49600018
         SPACE                                                          50100017
BR005    DS    0H                 ENTER.                                50400017
         ST    R9,CURPT           SAVE PTR TO NEXT SMB ENTRY.           50700017
         LR    R5,R7                                                    50900018
         CLC   ZERO(TWO,R5),BRSLASH    IS THIS A JCL STATEMENT          51100018
         BNE   BR001              B ON NO TO GET NEXT STATEMENT.        51300017
         CLI   TWO(R5),ASTRK      IS IT A CONVERTED COMMENT CARD        51360018
         BNE   BR005A             BRANCH ON NO                          51420017
         MVI   TWO(R5),BLANK      BLANK IT OUT IF IT IS                 51480018
BR005A   DS    0H                                                       51540017
*                                                                       51600017
*   THIS SECTION SCANS JCL STATEMENTS FOR 'DD *' OR 'DD DATA' AND       51900017
*        REPLACES '*' OR 'DATA' WITH 'DUMMY '.                          52200017
*                                                                       52500017
         LA    R1,CRDLN           EXTENT OF STATEMENT TO BE SCANNED.    52700018
         LR    R4,R7                                                    52900018
*   SCAN FOR FIRST BLANK INDICATING END OF STMT NAME.                   53100017
BR006    DS    0H                                                       53400018
         CLI   ONE(R4),BLANK      SCANNING FOR FIRST BLANK              53700018
         BE    BR007              B ON FIRST BLANK FOUND.               54000017
         LA    R4,ONE(R4)         NOT FOUND. POINT TO NEXT CHARACTER.   54300018
         BCT   R1,BR006           DECREMENT COUNT AND TRY NEXT.         54600017
         B     BREXIT             NO BLANKS ON CARD AT ALL. EXIT.       54900017
*   SCAN FOR VERB.  FIRST NON-BLANK                                     55200017
BR007    DS    0H                                                       55500017
         CLI   ONE(R4),BLANK      SCANNING FOR NON-BLANK                55800018
         BNE   BR008              B ON NONBLANK CHARACTER.              56100017
         LA    R4,ONE(R4)         POINT TO NEXT.                        56400018
         BCT   R1,BR007           DECREMENT COUNT AND TRY NEXT          56700017
         B     BREXIT             NO VERB.  EXIT.                       57000017
*   LOOK AT VERB AND SEE IF IT'S A DD STATEMENT.                        57300017
BR008    DS    0H                                                       57600017
         CLC   ONE(L3,R4),BRDD    IS THIS A DD STATEMENT                57900018
         BNE   BREXIT             B TO EXIT ON NOT DD.                  58200017
         LA    R4,TWO(R4)         FOUND DD - POINT TO FIELD BEYOND.     58500018
         BCTR  R1,R0              SET COUNT FOR END CHECK.              58800018
         BCTR  R1,R0              SET COUNT FOR END CHECK.              59100018
*   SCAN FOR OPERAND.  LOOKING FOR '*' OR 'DATA'                        59400017
BR009    DS    0H                                                       59700017
         CLI   ONE(R4),BLANK      IS THERE AN OPERAND                   60000018
         BNE   BR010              B ON OPERAND FOUND.                   60300017
         LA    R4,ONE(R4)         POINT TO NEXT.                        60600018
         BCT   R1,BR009           DECREMENT END COUNT.                  60900017
         B     BREXIT             NO OPERAND.  EXIT                     61200017
BR010    DS    0H                                                       61500017
         CLI   ONE(R4),ASTRK      IS OPERAND '*'                        61800018
         BE    BR011              B ON YES.                             62100017
         CLC   ONE(L4,R4),BRDATA  IS OPERAND 'DATA'                     62400018
         BNE   BREXIT             B ON NO TO EXIT.                      62700017
BR011    DS    0H                                                       63000017
         CLI   ZERO(R4),CHARD     NEED TO BACK UP TO DD TO DETERMINE    63040018
*                                  WHETHER THE COMMENT WILL FIT ON THE  63080017
*                                  DD DUMMY CARD                        63120017
         BE    BR0110              BRANCH WHEN IT IS HIT                63160017
         BCT   R4,BR011            ELSE, BACK UP ONE MORE               63200017
BR0110   DS    0H                  ENTER * R4 AT 2ND D IN DD            63240017
         LR    R1,R4               SAVE POINTER TO 2ND D IN DD          63280017
         SR    R4,R5               SUBTRACT FROM IT THE BEG OF BUFFER   63320017
         CH    R4,BR27            THE COMMENT WILL NOT FIT IF THE '*'   63340017
*                                 OR 'DATA' IS TOO FAR TO THE RIGHT     63360017
         BH    BRMVCDD             YES - THEN MOVE IN DD DUMMY+ COMMENT 63400017
         MVC   TWO(BRLEN,R1),BRCOMENT  ELSE MOVE ONLU DUMMY + COMMENT   63440018
         B     BREXIT              BRANCH OUT                           63480017
BRMVCDD  DS    0H                                                       63520017
         MVC   DEC24(BRLENP3,R5),BRDD  MOVE IN 'DD DUMMY + COMMENT'     63560018
         B     BREXIT             EXIT.                                 63600017
         SPACE 3                                                        63630017
BRERROR  DS    0H                 ENTER. **ERROR**                      63660017
         SR    R5,R5                                                    63690017
         ST    R5,NXTSMB          CLEAR NEXT SMB PTR                    63720017
         LA    R9,NXTSMB          POINT CURRENT PTR TO ZEROES.          63750017
         ST    R9,CURPT                                                 63780017
         MVC   SVRBREGE,DCBSYNAD   RETURN TO SYNAD                      63840018
         SPACE 3                                                        63900017
BREXIT   DS    0H                 ENTER.  ** EXIT **                    64200017
         ST    R7,SVRBREG1         STMNT ADDR TO REG1                   64600018
BRRTN    DS    0H                                                       65100017
         L     R0,SVRBREG0         RELOAD REGS 0,1, AND 15              65200018
         L     R1,SVRBREG1                                              65300018
         L     RF,SVRBREGF                                              65400018
         SVC   EXIT                                                     65500018
         SPACE 3                                                        65700017
BREND    DS    0H                 ENTER.  ** END OF SMB'S **            66000017
         SPACE                                                          66600017
         MVI   DCBMODE,X01        CLEAR SWITCH IN DCB                   67200018
         MVC   SVRBREGE,DCBEODAD   RETURN TO END OF FILE                67800018
         B     BRRTN              RETURN.                               68400017
         SPACE 3                                                        68700017
*                                                                       69000017
*  THIS SUBROUTINE READS THE SMB CHAIN FROM THE JOBQUEUE AND RETURNS    69300017
*        A POINTER TO THE FIRST ENTRY IN REG 9.  IT ALSO CHECKS FOR     69600017
*        END OF SMB'S,   BYPASSES DSB'S IN THE SMB CHAIN AND UPDATES    69900017
*        THE TTR OF THE NEXT SMB IN NXTSMB OF WORK CORE.                70200017
*        INPUT IS A TTR IN NXTSMB.                                      70500017
*                                                                       70800017
BRSMB    DS    0H                 ENTER.                                71100017
         LR    R4,R7               SET UP ADDRESSING TO RRC2WKAR        71200018
         LA    R6,CRQM            Q-MANAGER PARAMETER AREA              71400017
         USING IOPARAMS,R6              ADDRESSING.                     71700017
BRSMB1   DS    0H                 ENTER.                                72000017
         CLC   NXTSMB(L3),BRHZR   IS THIS THE END OF THE SMB CHAIN.     72300018
         BE    BREND              B ON YES TO EODAD.                    72600017
*  'RRC2WORK' CONTAINS ZEROS UNTIL ALL SCTS ARE READ.                   72620018
*  THEN IT WILL CONTAIN THE TTR OF THE DUMMY SMB CREATED FOR            72640017
*  STEP NUMBER + 1.                                                     72660017
         CLC   NXTSMB(3),RRC2WORK                                       72730018
         BE    BREND              BR EQUAL TO END OF FILE EXIT          72810018
         MVC   QMPEX(L3),NXTSMB   MOVE SMB TTR TO REMOTE LIST.          72910018
*                                 QMPA ALREADY POINTS TO INPUT BUFFER.  73200017
         MVI   QMPEX+L3,ZERO      CLEAR LOW ORDER BYTE OF TTR           73300018
         SPACE                                                          73500017
         SPACE                                                          74400017
         LR    R1,R6              R1 = Q-MANAGER PARAMETER AREA.        74700017
         L     RF,QMPTR           Q-MANAGER ADDRESS.                    75000017
         BALR  RE,RF              LINK.                                 75300017
         SPACE                                                          75600017
         LR    R5,RF              SAVE RETURN CODE FROM Q MNGR OVER FRM 75700017
         SPACE                                                          76600017
         LTR   R5,R5              CHECK FOR ERROR RETURN FROM QMNGR     77000017
         BNZ   BRERROR            B ON ERROR                            77400017
*  IF DCBRECAD DOES NOT EQUAL ZERO, THIS IS THE FIRST PASS,             77460017
*  AND THE SCT CHAIN IS BEING READ.                                     77520017
         CLC   DCBRECAD,BRHZR                                           77620018
         BNE   BRSCTRD            BR NOT EQ TO FIRST PASS PROCESSING    77720018
         MVC   NXTSMB(L3),INBUF+SMBNEXT-SMBDSKAD MOVE NEXT SMB PTR TO   77920018
*                                 WORK SLOT.                            78300017
         CLI   INBUF+SMBMSGLN-SMBDSKAD,DSBIND CHECK MSG LEN SLOT        78600018
*              TO DETERMINE IF THIS IS A DSB.                           78900017
         BE    BRSMB1             B ON DSB TO READ NEXT SMB.            79200017
         SPACE                                                          80700017
         LA    R9,INBUF+SMBMSGLN-SMBDSKAD   POINT R9 AT FIRST ENTRY.    81000017
         ST    R9,CURPT           SAVE IN WORK AREA.                    81300017
         BR    RA                 RETURN.                               81600017
*  ROUTINE FOR FIRST PASS SCT READS.                                    81620017
*  IT CHECKS FOR END OF SCT CHAIN, AND AT END MOVES THE TTR OF THE      81640017
*  DUMMY SMB ALLOCATED FOR LAST STEP+1 TO 'RRCWKAR4' FOR COMPARISON     81660017
BRSCTRD  DS    0H                                                       81680017
         CLC   INBUF+SCTANSCT-INSMSCT(L3),BRHZR   IS PTR TO NEXT ZERO   81700018
         BE    BRMOVE             YES - END OF CHAIN - BRANCH           81720017
         MVC   NXTSMB(L3),INBUF+SCTANSCT-INSMSCT NO - MOVE NEXT TO      81740018
         B     BRSMB1             TO CURRENT AND BRANCH TO READ         81760017
BRMOVE   DS    0H                 ENTRY * MOVE TTR TO WORK AREA         81780017
         MVC   RRC2WORK(3),INBUF+SCTAFSMB-INSMSCT                       81800018
         BR    RA                 RETURN FROM FIRST PASS                81820017
         EJECT                                                          81900017
BR27     DC    H'27'              CONSTANT FOR COMPARE                  82000018
BRHZR    DC    F'0'               ZERO FOR COMPARES                     82100018
BRSLASH  DC    CL2'//'            CONSTANT FOR LOCATING JCL STATEMENTS  82200018
BRDATA   DC    CL4'DATA'          FOR COMPARE AGAINST DD CARDS          82300018
BRDD     DC    CL3'DD '           TO FIND DD CARDS AND PUT IN DD *      82400018
BRCOMENT DC    C'DUMMY RESTART REPLACEMENT FOR DD * OR DATA' COMMENT ON 82500018
*                                 DD CARDS DEFINING SYSIN               82600018
CHARD    EQU   C'D'                                                     82700018
CRDLN    EQU   71                                                       82800018
BLANK    EQU   C' '                                                     82900018
ASTRK    EQU   C'*'                                                     83000018
DSBIND   EQU   X'FF'                                                    83100018
CONDMSG  EQU   X'FE'                                                    83200018
ZERO     EQU   0                                                        83300018
X01      EQU   1                                                        83400018
ONE      EQU   1                                                        83500018
TWO      EQU   2                                                        83600018
L3       EQU   3                                                        83700018
L4       EQU   4                                                        83800018
DEC12    EQU   12                                                       83900018
DEC24    EQU   24                                                       84000018
L32      EQU   32                                                       84100018
BRCOMEND EQU   *                                                        84600017
BRLEN    EQU   BRCOMEND-BRCOMENT                                        85100017
BRLENP3  EQU   BRLEN+3                                                  85300018
RESTART  DC    CL8'IGC0105B'                                            85600018
SYSMASK  DC    X'FF'               MASK TO ALLOW INTERRUPTS             85900018
R0       EQU   0                                                        86300017
R1       EQU   1                                                        86500017
R2       EQU   2                                                        86700017
R3       EQU   3                                                        86900017
R4       EQU   4                                                        87100017
R5       EQU   5                                                        87300017
R6       EQU   6                                                        87500017
R7       EQU   7                                                        87700017
R8       EQU   8                                                        87900017
R9       EQU   9                                                        88100017
RA       EQU   10                                                       88300017
RB       EQU   11                                                       88500017
RC       EQU   12                                                       88700017
RD       EQU   13                                                       88900017
RE       EQU   14                                                       89100017
RF       EQU   15                                                       89300017
EXIT     EQU   3                                                        89600018
         END                                                            90000017
