        TITLE 'IEFWEXTA - EVENTUAL ACTION MOUNT VERIFICATION MODULE'    09030020
*********************************************************************** 09040020
*                                                                     * 09050020
*                             PROLOGUE                                * 09060020
*                                                                     * 09070020
* TITLE: IEFWEXTA - EXTENDED ACTION MOUNT VERIFICATION MODULE         * 09080020
*                                                                     * 09090020
* STATUS: CHANGE LEVEL 000                                            * 09100020
*                                                                     * 09110020
* FUNCTION/OPERATION: THIS MODULE VERIFIES ALL VOLUME MOUNTING        * 09120020
*        SITUATIONS NOT VERIFIED BY IEFWD000                          * 09130020
*        THOSE REQUESTS THAT REQUIRE MOUNTING OF A VOLUME ON          * 09131020
*        A DIRECT ACCESS FOR OLD DATA SETS ARE REFERED TO AS          * 09132020
*        EVENTUAL ACTION MOUNTS                                       * 09133020
*                                                                     * 09140020
* ENTRY POINTS: IEFWEXTA - MAIN AND ONLY ENTRY POINT FROM             * 09150020
*        MODULE IEFXT002 ONLY                                         * 09160020
*                                                                     * 09170020
* INPUT: TIOT LIST POINTER IN LCTPARM1 (FROM IEFXT002)                * 09180020
*        UCB'S                                                        * 09190020
*        PPL LIST POINTER (FROM IEFWD000)                             * 09200020
*                                                                     * 09210020
* OUTPUT: TIOT LIST POINTER IN LCTPARM1                               * 09220020
*                                                                     * 09230020
* EXITS NORMAL: IEFSD41Q                                              * 09240020
*                                                                     * 09250020
* EXITS ERROR: IEFXKIMP                                               * 09260020
*                                                                     * 09270020
* TABLES/WORKAREAS:                                                   * 09280020
*                                                                     * 09290020
* ATTRIBUTES: SERIALLY REUSEABLE                                      * 09300020
*                                                                     * 09310020
* NOTES: THIS MODULE IS CHARACTER CODE DEPENDENT.                     * 09320020
*                                                                     * 09330020
*********************************************************************** 09340020
UCBD     DSECT                                                          09350020
         IEFUCBOB                                                       09360020
CSCBD    DSECT                                                          09370020
         IEECHAIN                                                       09380020
CVTD     DSECT                                                          09390020
         CVT                                                            09400020
TIOTD    DSECT                                                          09410020
         IEFTIOT1                                                       09420020
MRDAD    DSECT                                                          09430020
         IEEBASEA                                                       09440020
JFCBD    DSECT                                                          09450020
         IEFJFCBN                                                       09460020
LCTD     DSECT                                                          09470020
         IEFALLCT                                                       09480020
         IEFQMPAM                                                       09490020
SCTD     DSECT                                                          09500020
         IEFASCTB                                                       09510020
         SPACE 2                                                        09520020
ATCD     DSECT                                                          09530020
         IEFATCOM                                                       09540020
         SPACE 2                                                        09550020
JCT      DSECT                                                          09552020
         IEFAJCTB                                                       09554020
DOMIDS   DSECT                                                          09560020
DOMID1   DS    F                       FIRTS DOMID                      09570020
DOMID2   DS    F                       SECOND DOM ID FOR DSN           *09580020
                                       FOR DSN PART OF MSG IF PRESENT   09590020
DOMUCBS  DSECT                                                          09600020
DOMUCB1  DS    F                       FIRST UCB POINTER                09610020
DOMUCB2  DS    F                       SECOND UCB POINTER  IF PRESENT   09620020
         SPACE 2                                                        09630020
GETPARMS DSECT                                                          09640020
GET1     EQU   *                       BEGINING OF LIST                 09650020
         GETMAIN EC,LV=AMOUNT,MF=L                                      09660020
GET2     EQU   *                       END OF LIST                      09670020
GOTCORE  DS    1F                      RETURNED PARAMETERS              09680020
GETSAVE  DS    18F                     REG SAVE AREA FOR GETMAIN        09690020
         SPACE 2                                                        09700020
WORKAREA DSECT                                                          09710020
         DS    3F                      TO PRESERVE VOL SER NUMBER       09720020
MSGBUF   DS    0F                      START OF MSG BUFFER              09730020
MSGLNGTH EQU   MSGBUF+1                MSG LENGTH BYTE                  09740020
MSGID    DC    C'    IEF233A M'        MESSAGE ID                       09750020
MSGBLANK DC    C' '                    BLANK                            09760020
MSGUNIT  DC    C'UUU'                  UNIT FIELD                       09770020
MSGSLASH DC    C'/'                    SLASH                            09780020
MSGDCELL DC    C'0'                    SUB CELL NUMBER                  09790020
MSGCOMA1 DC    C','                    COMMA                            09800020
MSGSER   DC    C'SERIAL'               VOLUME SERIAL NUMBER             09810020
MSGCOMA2 DC    C','                    COMMA                            09820020
MSGMCSD  DC    FL4'0'                  RT & DESC FLAGS                  09830020
MSGENDD  EQU   *                       END OF MSG MARKER                09840020
         ORG   MSGCOMA2+1                                               09850020
MSGCOMA3 DC    C','                    COMMA                            09860020
MSGJOB   DC    C'JOBNAMEX'             JOB NAME                         09870020
MSGCOMA4 DC    C','                    COMMA                            09880020
MSGSTEP  DC    C'STEPNAME'             STEP NAME                        09890020
MSGMCSM  DC    FL4'0'                  RT AND DESC CODES-MCS            09900020
MSGENDM  EQU   *                       END OF MSG MARKER                09910020
         ORG   WORKAREA                                                 09920020
VOLLABI  DC    C'VOL'                  LABEL ID FIELD - VOL LABEL       09930020
VOLNO    DC    C'1'                    LABEL NUMBER=1 = VOL LABEL       09940020
VOLSERNO DC    CL6'SERIAL'             VOL SERIAL FIELD                 09950020
         DC    C'0'                    RESERVED                         09960020
VOLVTOC  DC    C'CCHHR'                VTOC DISC ADDRESS                09970020
         DC    XL25'00'                RESERVED                         09980020
VOLOWNER DC    CL10'OWNER NAME'        OWNER NAME                       09990020
         DC    XL29'00'                RESERVED                         10000020
VOLEND   EQU   *                       END OF LABEL MARKER              10010020
WORK1    DS    F                       SCRATCH SPACE/R13 SAVE           10020020
WORK2    DS    F                       SCRATCH SPACE                    10030020
WORK2A   EQU   WORK2+1                 GENERAL USE                      10040020
WORK2C   EQU   WORK2+3                 GENERAL USE                      10050020
WORK3    DS    F                       SCRATCH SPACE                    10060020
WORK4    DS    F                       SCRATCH SPACE                    10070020
WORKEND  EQU   *                       END OF LONGEST SECTION OF       *10080020
                                       WORK AREA                        10090020
         EJECT                                                          10092021
         IGFIORMS                                                A59873 10094021
         EJECT                                                          10119021
IEFWEXTA CSECT                                                          10119521
*********************************************************************** 10123621
*                                                                       10127721
* THIS MODULE WAS CREATED FOR EVENTUAL ACTION MOUNTS            20029   10131821
*        DELETIONS 25                                                   10135921
*        DELETIONS 24                                                   10140020
*        DELETIONS 23                                                   10150020
*        DELETIONS 22                                                   10160020
*        DELETIONS 21                                                   10170020
*        DELETIONS 20                                                   10180020
* C103400                                                        A41238 10180421
*                                                                 M3057 10187221
* 110500-110600                                                  A25134 10190421
*                                                                 M0726 10193621
* A 108920, A 173120, A 173520-173560                            A47599 10194000
* C 173120                                                        M4160 10194400
* A-100940,106320,108720-108933                                  A59873 10195621
         SPACE 2                                                        10196821
*        PUT EQUATES RELATED TO DSECTS HERE                             10200020
UCBDEVCL EQU   UCBTYP+2                DEVICE CLASS FIELD               10210020
DCELBNR  EQU   DCELBBNR+1              ACTUAL BIN NUMBER                10220020
AMOUNT   EQU   WORKEND-WORKAREA        GETMAIN WORK AREA LENGTH         10230020
         SPACE 2                                                        10240020
*        PUT EQUATES HERE                                               10250020
ALL      EQU   255                     GENERAL USE                      10260020
EBCDIC   EQU   X'F0'                   EBCDIC MASK                      10270020
READCODE EQU   X'06'                   READ CCW  OP-CODE                10280020
WAIT     EQU   X'40'                   INDICATES THAT THE SCAN ROUTINE *10290020
                                       REQUIRES A WAIT BE ISSUED.       10300020
CANCEL   EQU   X'20'                   INDICATE TO THE SCAN            *10310020
                                       SUBROUTINE THAT CANCEL PROCESSING10320020
                                       SHOULD BE INVOKED.               10330020
CANCELX  EQU   X'90A'                  IEFXKIMP JOB CANCEL CODE  A41238 10340021
GETERROR EQU   X'815'                  IEFXKIMP GETMAIN ERROR INDICATOR 10350020
JCANCEL  EQU   X'40'                   MASK TO DETECT JOB CANCEL  M3057*10360020
                                       VIA THE CSCB CANCEL ECB.         10370020
DA       EQU   X'20'                   DIRECT ACCESS BIT                10380020
DATACEL  EQU   X'FF'                   DATA CELL ID MASK                10390020
COMMA    EQU   C','                    COMMA FOR MESSAGES               10400020
IOERROR  EQU   X'7F'                   ECB ERROR FLAGS                  10410020
NOTEQU   EQU   7                       BRANCH MASK                      10420020
BLANK    EQU   C' '                    BLANK                            10430020
WAITOFF  EQU   255-WAIT                TO TURN OFF WAIT SWITCH          10440020
EQU      EQU   8                       BRANCH MASK                      10450020
EVENTACT EQU   X'80'                   EVENTUAL ACTION INTERFACE BIT    10460020
ZERO     EQU   0                       GENERAL USE                      10470020
ONE      EQU   1                       GENERAL USE                      10480020
TWO      EQU   2                       GENERAL USE                      10490020
THREE    EQU   3                       GENERAL USE                      10500020
FOUR     EQU   4                       GENERAL USE                      10510020
FIVE     EQU   5                       GENERAL USE                      10520020
NOTREADY EQU   X'40'                   NOT READY BIT UCB                10530020
INDEX    EQU   X'0C'                   ALLOCATION ATTEN TABLE INDEX     10540020
DOMEND   EQU   X'80'                   END OF DOM LIST MARKER           10550020
ERPS     EQU   X'0C'                   ERROR RECOVERY                   10560020
CPCHAIN  EQU   X'40'                   CHAINING                         10570020
UNREL    EQU   X'02'                   UNRELATED EXCP                   10580020
EXCEPT   EQU   X'FB'                   IOB EXCEPTION BIT                10590020
SLASH    EQU   C'/'                    SLASH                            10600020
ALWAYS   EQU   15                      BRANCH MASK                      10610020
VERIFYED EQU   ALL-EVENTACT            VERIFY OFF MASK                  10620020
FLSHFAIL EQU   X'44'                                             A25134 10630020
CVT      EQU   16                                                A59873 10632021
         SPACE 1                                                        10640020
R0       EQU   0                       GENERAL REG 0                    10650020
R1       EQU   1                       GENERAL REG 1                    10660020
R2       EQU   2                       GENERAL REG 2                    10670020
R3       EQU   3                       GENERAL REG 3                    10680020
R4       EQU   4                       GENERAL REG 4                    10690020
R5       EQU   5                       GENERAL REG 5                    10700020
R6       EQU   6                       GENERAL REG 6                    10710020
R7       EQU   7                       GENERAL REG 7                    10720020
R8       EQU   8                       GENERAL REG 8                    10730020
R9       EQU   9                       GENERAL REG 9                    10740020
R10      EQU   10                      GENERAL REG 10                   10750020
R11      EQU   11                      GENERAL REG 11                   10760020
R12      EQU   12                      GENERAL REG 12                   10770020
R13      EQU   13                      GENERAL REG 13                   10780020
R14      EQU   14                      GENERAL REG 14                   10790020
R15      EQU   15                      GENERAL REG 15                   10800020
         EJECT                                                          10810020
         BALR  R9,R0                   ADDRESSABILITY                   10820020
         USING *,R9                    ADDRESSABILITY                   10830020
         USING LCTD,R12                ADDRESSIBILITY                   10840020
         B     FIRST                   BRANCH AROUND MODULE IDENT.      10850020
         DC    C'IEFWEXTA'             MODULE IDENTIFIER.               10860020
FIRST    EQU   *                                                        10870021
*****************************************************************A59873 10872021
*                                                                A59873 10874021
*              IORMS STANDS FOR INPUT/OUTPUT RECOVERY            A59873 10876021
*              MANAGEMENT SERVICES                               A59873 10878021
*                                                                A59873 10878421
*****************************************************************A59873 10878821
*                         CLEAR THE POINTER TO ALLOCATION'S      A59873 10879221
*                         TCB AND TJID                           A59873 10879621
*                         FROM IORMS COM AREA TO SIGNIFY ALLOC   A59873 10879721
*                         NOT IN PROCESS                         A59873 10879821
DDRPRES  EQU   X'20'                   DDR IS IN SYSTEM          A59873 10879921
         L     R2,CVT                  GET PTR TO CVT            A59873 10883221
         USING CVTD,R2                                           A59873 10885200
         TM    CVTOPTA,DDRPRES         IS DDR IN SYSTEM          A59873 10885621
         BZ    NODDR                   NO-DON'T CLEAR TCB PTR    A59873 10886021
         L     R2,CVTDCB               GET PTR TO LOGREC         A59873 10886421
         DROP  R2                                                A59873 10886521
IORMSPTR EQU   0                       PTR TO IORMS COMM A       A59873 10886621
         L     R2,IORMSPTR(,R2)        1ST WORD IN LOGREC PTS    A59873 10889921
*                                      TO IORMS COMM AREA        A59873 10892000
         USING IGFIORMS,R2                                       A59873 10892121
         XC    ALLOCTCB(4),ALLOCTCB    CLEAR TCB PTR AND TJID    A59873 10892421
         XC    ALLOTJID(4),ALLOTJID                              A59873 10892821
         DROP  R2                                                A59873 10893221
NODDR    EQU   *                                                 A59873 10893321
         DEQ   MF=(E,Q4)               DEQ OFF INTER/ALLOCATION RESOURC 10893421
         DEQ   MF=(E,Q9)          DEQ OFF BATCH/DYNAMIC RESOURCE A47599 10895000
         DEQ   MF=(E,Q5)               DEQ OFF TERMINATION.             10896721
* HOUSEKEEP SWITCHES AND PLACE DEVICE END ECB INTO THE MVI ECB CHAIN.   10900020
         SR    R2,R2                   THIS REGISTER IS USED TO        *10910020
                                       INDICATE THE ISSUANCE OF A      *10920020
                                       GETMAIN BY THE SUBROUTINE.       10930020
         ST    R2,LCTPARM2             CLEAR SWITCH AREA.               10940020
         L     R7,LCTPSPAR             GET THE ATCOM ADDRESS.           10950020
         USING ATCD,R7                                                  10960020
         L     R8,ATCMRQE              OBTAIN THE POINTER TO THE       *10970020
                                       MVI PASSED BY IEFWD000.          10980020
         LTR   R8,R8                   ANY EVENTUAL ACTION             *10990020
                                       MOUNTS ?                         11000020
         BZ    TO41SD                  NO, SO EXIT.                     11010020
         L     R3,LCTQDRTY             OBTAIN THE CSCB ADDRESS.         11020020
         USING CSCBD,R3                                                 11030020
         TM    CHCECB,JCANCEL          WAS THIS JOB CANCELLED?          11040020
         BO    CANCEL1                 TEST FOR JOB FLUSH         M3057 11050020
* SET UP MOUNT VERIFICATION INTERFACE.                                  11070020
SETIF    EQU   *                  HERE IF JOBFLUSH,SYSIN NOT MNTD 25134 11075020
         LA    R7,ATCLINK-ATCD(R7)     ADJUST BASE TO POINT TO THE     *11080020
                                       FIRST ELEMENT IN THE ECB QUE.    11090020
         DROP  R7                                                       11100020
         USING MVI,R7                                                   11110020
         LA    R6,MVILINK-MVIEAI(0,0)  MAKE ATCOM DISPLACEMENT LOOK    *11120020
                                       LIKE MVI SO FOLLOWING LOOP      *11130020
                                       WILL FUNCTION.                   11140020
         SR    R7,R6                   MAKE FINAL BASE ADJUSTMENT.      11150020
COMPARE  OC    MVILINK,MVILINK         IS THIS A ZERO INDICATING END   *11160020
                                       OF THE ECB CHAIN ?               11170020
         BZ    ENDCHAIN                YES,SO GO INSERT THIS LINK.      11180020
         L     R7,MVILINK              GET POINTER TO NEXT ELEMENT.     11190020
         B     COMPARE                 LOOP TILL END IS FOUND.          11200020
CANCEL1  L     R14,LCTJCTAD       JCT ADDR                       A25134 11201020
         USING JCT,R14                                           A25134 11202020
         TM    JCTJSTAT,FLSHFAIL  JOB FLUSH OR JOB FAIL          A25134 11203020
         DROP  R14                                               A25134 11204020
         BZ    CANCELED           NO. SET UP FOR XKIMP EXIT      A25134 11205020
         B     SETIF              ATTEMPT TO GET SYSIN MNTD      A25134 11206020
ENDCHAIN ST    R8,MVILINK              END FOUND SO INSERT NEXT LINK.   11210020
         DROP  R3                                                A25134 11215020
         DROP  R7                                                       11220020
         USING MVI,R8                                                   11230020
         L     R3,MVIEAI               GET THE EAI ADDRESS.             11240020
         USING EAI,R3                                                   11250020
         OI    EAISWTCH,EAICHAIN       INDICATE THAT THIS ELEMENT      *11260020
                                       IS CHAINED.                      11270020
         DROP  R3                                                       11280020
SUBVERFY BAL   R3,SCAN                 GO TO SCAN SUBROUTINE TO CHECK  *11290020
                                       FOR EVENTUAL ACTION MOUNTS.      11300020
         TM    LCTPARM2,WAIT           IS IT NECESSARY FOR SCAN TO WAIT*11310020
                                       FOR A DEVICE END?                11320020
         BZ    TO41SD                  NO, SO EXIT NORMALLY.            11330020
         EJECT                                                          11340020
* THE SCAN ROUTINE HAS DETERMINED EVENTUAL ACTION MOUNTS HAVE BEEN      11350020
* ISSUED AND NO VOLUMES HAVE BEEN MOUNTED TO SERVICE THOSE REQUESTS     11360020
* THEREFORE A WAIT FOR DEVICE END OR CANCEL IS NECESSARY.               11370020
         L     R7,LCTPSPAR             GET THE ATCOM ADDRESS.           11380020
         USING ATCD,R7                 ATC ADDRESSABILITY               11390020
         XC    ATCMRQE,ATCMRQE         CLEAR POINTER FOR OTHER         *11400020
                                       ALLOCATIONS TO USE IT.           11410020
         DEQ   MF=(E,Q8)               DEQ TO LET OTHER ALLOCATIONS    *11420020
                                       PROCESS WHILE THIS ONE IS       *11430020
                                       WAITING FOR VOLUMES TO          *11440020
                                       COME READY.                      11450020
         L     R4,MVIEAI               SET UP PARAMETERS FOR WAIT.      11460020
         SPACE 1                                                        11470020
*                                      R1 NOW CONTAINS THE POINTER      11480020
*                                      TO THE ECB LIST FOR THE          11490020
*                                      DEVICE END OR CANCEL.            11500020
         SPACE 1                                                        11510020
         USING EAI,R4                  ADDRESSABILITY                   11520020
         LA    R1,EAIECBP1             OBTAIN THE ADDRESS OF THE WAIT  *11530020
                                       LIST.                            11540020
         WAIT  ECBLIST=(R1)            ISSUE WAIT FOR DEVICE END OR    *11550020
                                       CANCEL.                          11560020
         SPACE 1                                                        11570020
         ENQ   MF=(E,Q8)               RE-ENQ FOR UCB INTEGRITY.        11580020
         ST    R8,ATCMRQE              RESTORE THIS ALLOCATIONS POINTER 11590020
         DROP  R7                                                       11600020
         SR    R3,R3                   CLEAR WORK REGISTER.             11610020
         ST    R3,EAIDEECB             CLEAR DEVICE END ECB.            11620020
         L     R4,LCTQDRTY             GET BASE FOR THE CSCB.           11630020
         DROP  R4                                                       11640020
         USING CSCBD,R4                BASE FOR THE CSCB.               11650020
         TM    CHCECB,JCANCEL          WAS THE JOB CANCELLED?           11660020
         BZ    SUBVERFY                NO, GO TO SCAN TO VERIFY   M3057 11665020
         L     R14,LCTJCTAD       JCT ADDRESS                    A25134 11671020
         USING JCT,R14                                           A25134 11672020
         TM    JCTJSTAT,FLSHFAIL  JOB FLUSH OR JOB FAIL          A25134 11673020
         BZ    CANCELED           NO. PROCEED TO XKIMP           A25134 11674020
         OI    JCTSTAT2,JCTENDIT  SET JOB TERM INDIC. FOR YNIMP  A25134 11675020
         DROP  R14                                               A25134 11676020
CANCELED OI    LCTPARM2,CANCEL         INDICATE JOB CANCEL TO SCAN.     11680020
TOKIMP   LA    R14,CANCELX             LOAD PARAMETERS KIMP NEEDS      *11690020
                                       TO ISSUE JOB CANCELLED AND      *11700020
                                       NOT TO FREE THE VOLT.            11710020
GOTOKIMP ST    R14,LCTPARM3            STORE PROPER MESSAGE INDICATOR  *11720020
                                       (COULD BE JOB CANCELLED OR      *11730020
                                       GETMAIN ERROR MESSAGE).          11740020
         L     R3,VCONKIMP             GET XKIMP ADDRESS.               11750020
         SPACE 2                                                        11760020
****    EXIT PREPARATION   ****                                         11770020
CORETEST LTR   R2,R2                   WAS GETMAIN ISSUED?              11780020
         BZ    NOCORE                  NO, SO DON'T TRY TO FREE.        11790020
         LA    R0,AMOUNT               OBTAIN LENGTH OF THE GETMAIN    *11800020
                                       ISSUED BY THE SCAN ROUTINE.      11810020
         FREEMAIN R,LV=(0),A=(R2)      YES SO FREE CORE.                11820020
NOCORE   EQU   *                                                        11830020
         L     R4,LCTPSPAR             GET THE ATCOM ADDRESS.           11840020
         USING ATCD,R4                                                  11850020
         ST    R8,ATCMRQE              STORE QUE ELEMENT POINTER FOR   *11860020
                                       IEFW41SD.                        11870020
         LR    R15,R3                  GET EXIT ADDRESS  (ERROR OR     *11880020
                                       NORMAL).                         11890020
         DROP  R4                                                       11900020
         BALR  R14,R15                 BALR SO FROM MODULE IS SEEN.     11910020
TO41SD   L     R3,VCON41SD             GET IEFW41SD ADDRESS.            11920020
         B     CORETEST                GO CHECK FOR FREEMAIN NEEDED.    11930020
         EJECT                                                          11940020
*********************************************************************** 11950020
*        TIOT SCAN SUBROUTINE - LOOKS FOR EVENTUAL ACTION MOUNTS      * 11960020
*********************************************************************** 11970020
SCAN     EQU   *                       SCAN SUBROUTINE                  11980020
         L     R4,LCTPARM1             FIND TIOT LIST ADR.              11990020
         L     R4,0(R4)                FIND TIOT ADR.                   12000020
         LR    R7,R4                   SAVE TIOT ADR.                   12010020
         NI    LCTPARM2,WAITOFF        INITIALIZE WAIT SWITCH           12020020
         USING TIOT1,R4                TIOT ADDRESSABILITY              12030020
         LA    R4,TIOENTRY             GET TO FIRST DD ENTRY            12040020
         USING TIOENTRY,R4             DD ADDRESSABILITY                12050020
DDLOOP   EQU   *                       BEGINING OF DD LOOP              12060020
         SR    R5,R5                   INITIALIZE LENGTH REGISTER       12070020
         IC    R5,TIOELNGH             GET LENGTH OF THIS DD ENTRY      12080020
         LTR   R5,R5                   IS THIS THE END OF THE TIOT      12090020
         BCR   EQU,R3                  YES. THEN RETURN                 12100020
         AR    R5,R4                   FIND BEGINING OF NEXT DD ENTRY   12110020
         LA    R4,TIOESTTB             GET TO DEVICE ENTRY              12120020
         USING TIOESTTB,R4             DEVICE ENTRY ADDRESSABILITY      12130020
DEVLOOP  EQU   *                       DEVICE LOOP BEGINING             12140020
         L     R13,TIOESTTB            FIND UCB ENTRY                   12150020
         LA    R13,0(R13)              CLEAR HIGH ORDER BYTE.           12160020
         LTR   R13,R13                 IS THERE A UCB POINTER ?         12170020
         BZ    NOTEAM                  NO, THIS MUST BE DD DUMMY.       12180020
         USING UCBOB,R13               UCB ADDRESSABILITY               12190020
         CLI   UCBID,DATACEL           IS THIS A DATACELL ?             12200020
         BNE   DMCT1                   YES. TEST DATA MNG COUNT IN CELL 12210020
         OC    SRTEVOLI,SRTEVOLI       IS THIS A DEFERRED MOUNT ?       12220020
         BZ    NOTEAM                  YES, SO DON'T PROCESS.           12230020
         TM    SRTEDMCT,EVENTACT       IS THIS A POSSIBLE              *12240020
                                       EVENTUAL ACTION MOUNT            12250020
         DROP  R13                                                      12260020
DMCT1R   EQU   *                       RETURN POINT AFTER DM COUNT TEST 12270020
         BO    EAMOUNT                 YES IT MAY BE. GO SEE            12280020
NOTEAM   EQU   *                       RETURN HERE  IF NOT EAM          12290020
*        RETURN HERE TO CONTINUE TIOT SCAN                              12300020
         LA    R4,FOUR(R4)             GET TO NEXT DEVICE ENTRY         12310020
         CR    R4,R5                   ARE WE FINISHED WITH THIS DD     12320020
         BL    DEVLOOP                 NO. PROCESS NEXT DEVICE          12330020
         B     DDLOOP                  YES. PROCESS NEXT DD             12340020
         DROP  R4                                                       12350020
DMCT1    EQU   *                       HERE TO TEST DATA MNG COUNT      12360020
         USING DATACELL,R13            SUBCELL ADDRESSABILITY           12370020
         OC    DCELVOLI,DCELVOLI       IS THIS A DEFERRED MOUNT ?       12380020
         BZ    NOTEAM                  YES, SO DON'T PROCESS.           12390020
         TM    DCELDMCT,EVENTACT       IS THIS A POSSIBLE              *12400020
                                       EVENTUAL ACTION MOUNT ?          12410020
         B     DMCT1R                  GO FINISH TEST                   12420020
         DROP  R13                                                      12430020
         SPACE 2                       *                                12440020
**********************************************************************  12450020
EAMOUNT  EQU   *                       TEST FOR EAM                     12460020
         USING UCBOB,R13               UCB ADDRESSABILITY               12470020
         LA    R13,0(R13)              CLEAR HIGH ORDER BYTE            12480020
         CLI   UCBID,DATACEL           IS THIS DATA CELL                12490020
         BNE   DCELLTYP                YES. GO PROCESS MOUNT            12500020
         TM    UCBDEVCL,DA             IS THIS DEVICE DIRECT-ACCESS     12510020
         BNO   NOTEAM                  EVENTUAL ACTION MOUNT           *12520020
                                       APPLIES ONLY TO DA               12530020
DCELLTYP EQU   *                       PROCESS MOUNT                    12540020
         LTR   R2,R2                   DID WE DO GETMAIN YET            12550020
         BZ    GM                      NO. GO GET WORK SPACE            12560020
GMRETURN EQU   *                       GETMAIN RETURN POINT             12570020
SETWAIT  EQU   *                                                        12580020
         BAL   R15,FINDMAIN            FIND MAIN UCB IF DCELL           12590020
         MVI   UCBATI,INDEX            PUT IN ATTN TABLE INDEX          12600020
         TM    UCBFL2,NOTREADY         IS DEVICE READY ?                12610020
         BZ    READY                   YES. GO CHECK FOR VERIFY         12620020
         OI    LCTPARM2,WAIT           INDICATE WAIT IS NEEDED          12630020
         B     NOTEAM                  RETURN TO TIOT SCAN              12640020
         SPACE 2                                                        12650020
*********************************************************************** 12660020
READY    EQU   *                       DEVICE HAS COME READY            12670020
         USING WORKAREA,R2             WORK AREA ADDRESSABILITY         12680020
         MVI   UCBATI,ZERO             REMOVE ATTN TABLE INDEX          12690020
         BAL   R14,INIT                INITIALIZE I/O BLOCKS           *12700020
               ON RETURN R13 POINTS TO THE SUBCELL IF DCELL             12710020
         LA    R14,CCWSRCH             GET CHANNEL PROG ADR             12720020
         ST    R14,IOBSTART            PUT ADDRESS IN IOB               12730020
         ST    R2,CCWRCODE             PUT ADDRESS IN CHANNEL PROG      12740020
         MVI   CCWRCODE,READCODE       PUT IN CCW READ OPT CODE         12750020
         LA    R1,IOB                  SET PARM TO READ LABEL           12760020
*        $$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$  12770020
         EXCP  (1)                     READ LABEL                       12780020
         LA    R1,ECB                  SET PARM TO WAIT ON EXCP         12790020
         WAIT  ECB=(1)                 WAIT FOR READ COMPLETION         12800020
*        $$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$  12810020
         CLI   ECB,IOERROR             WAS THERE AN I/O ERROR           12820020
         BNE   READERR                 YES. GO HANDLE IT                12830020
         USING MVI,R8                  MVI ADDRESSABILITY               12840020
         L     R6,MVIEAI               SET BASE FOR EAI CONTROL BLOCK   12850020
         USING EAI,R6                  EAI ADDRESSABILITY               12860020
         TM    EAISWTCH,EAIDOML        ANYTHING TO DOM ?                12870020
         BO    DODOM                   YES. GO TO DOM ROUTINE           12880020
DODOMR   EQU   *                       RETURN POINT FROM DOM CODE       12890020
         DROP  R8                                                       12900020
         DROP  R6                                                       12910020
         CLI   UCBID,DATACEL           IS THIS DATACELL ?               12920020
         BNE   TESTSER                 YES. GO TEST SERIAL NO.          12930020
         USING VOLLABI,R2              LABEL ADDRESSABILITY             12940020
         CLC   SRTEVOLI,VOLSERNO       WAS THE CORRECT VOLUME MOUNTED   12950020
         BNE   REMOUNT                 NO. GET IT MOUNTED               12960020
         NI    SRTEDMCT,VERIFYED       INDICATE MOUNT VERIFIED          12970020
TESTSERR EQU   *                       RETURN AFTER TESTING SERIAL      12980020
         XC    WORK2,WORK2             PREPARE INPUT PARAMETER CCHHR    12990020
         MVC   WORK2C(FIVE),VOLVTOC    PREPARE INPUT PARAMETER CCHHR    13000020
         STM   R1,R15,WORKAREA         SAVE REGS                        13010020
         LR    R3,R2                   SAVE SAVE AREA POINTER          X13020020
               THE CONVERT ROUTINE DOES NOT TOUCH REG 3                 13030020
         LA    R1,DEB                  INPUT - DEB                      13040020
         LA    R2,WORK2                INPUT - MBBCCHHR POINTER         13050020
         L     R15,CVTPTR              GET ADDRESS OF CONVERT RTN       13060020
         USING CVTD,R15                CVT ADDRESSABILITY               13070020
         L     R15,CVTPRLTV            GET ADDRESS OF CONVERT RTN       13080020
         DROP  R15                                                      13090020
         BALR  R14,R15                 CONVERT DISK ADR. TO TTR         13100020
         LM    R1,R15,0(R3)            RESTORE REGS                     13110020
         CLI   UCBID,DATACEL           IS THIS A DATACELL ?             13120020
         BNE   STORE                   YES. GO STORE TTR IN UCB         13130020
         ST    R0,SRTEFSCT             STORE TTR                        13140020
STORER   EQU   *                       RETURN POINT FROM STORE          13150020
         B     NOTEAM                  RETURN TO TIOT SCAN              13160020
         DROP  R13                                                      13170020
         DROP  R2                                                       13180020
         SPACE 2                                                        13190020
*********************************************************************** 13200020
TESTSER  EQU   *                       TEST DCELL SERIAL NO.            13210020
         USING VOLLABI,R2              LABEL ADDRESSABILITY             13220020
         USING DATACELL,R13            SUBCELL ADDRESSABILITY           13230020
         CLC   DCELVOLI,VOLSERNO       WAS THE CORRECT VOLUME MOUNTED   13240020
         BNE   REMOUNT                 NO. GET IT MOUNTED               13250020
         NI    DCELDMCT,VERIFYED       INDICATE MOUNT VERIFIED          13260020
         B     TESTSERR                RETURN TO FINISH TEST            13270020
         DROP  R13                                                      13280020
         DROP  R2                                                       13290020
         SPACE 2                                                        13300020
*********************************************************************** 13310020
STORE    EQU   *                       STORE VTOC TTR IN SUBCELL        13320020
         USING WORKAREA,R2             WORK AREA ADDRESSABILITY         13330020
         USING DATACELL,R13            DATACELL ADDRESSABILITY          13340020
         ST    R0,WORK2                TEMPORARY STORE                  13350020
         MVC   DCELVTOC,WORK2          MOVE TTR TO SUBCELL              13360020
         B     STORER                  RETURN                           13370020
         DROP  R2                                                       13380020
         DROP  R13                                                      13390020
         SPACE 2                                                        13400020
*********************************************************************** 13410020
DODOM    EQU   *                       DOM PREVIOUS MOUNT MSG           13420020
         USING WORKAREA,R2             WORK AREA ADDRESSABILITY         13430020
         USING EAI,R6                  EAI ADDRESSABILITY               13440020
         L     R1,EAIUCBAD             GET TO UCB LIST                  13450020
         USING DOMUCBS,R1              UCB LIST ADDRESSABILITY          13460020
         LH    R10,EAILNTH             POINT TO END OF UCB LIST         13470020
         AR    R10,R6                  POINT TO END OF UCB LIST         13480020
DOMLOOP  EQU   *                       HERE TO TRY NEXT UCB POINTER     13490020
         CR    R1,R10                  DID WE REACH END OF UCB LIST     13500020
         BNL   DODOMR                  YES. NOT IN LIST - SKIP IT      *13510020
               THIS BRANCH IS FOR SAFTY. IT SHOULD NEVER BE TAKEN.      13520020
         CH    R13,DOMUCB1             IS THIS THE CURRENT UCB          13530020
         BE    DOMFIND1                YES. DOM THE CORRESPONDING ID    13540020
         LA    R1,L'DOMUCB1(R1)        GO TO NEXT ENTRY                 13550020
         B     DOMLOOP                 TEST NEXT ENTRY                  13560020
DOMFIND1 EQU   *                       HERE ON FINDING CORRECT  UCB PTR 13570020
         S     R1,EAIUCBAD             FIND RELATIVE OFFSET IN UCB LIST 13580020
         SLL   R1,ONE                  IDENT OFFSET IS TWICE AS MUCH    13590020
         LA    R1,EAIDMLST(R1)         POINT TO CORRESPONDING DOM ID    13600020
         USING DOMIDS,R1               DOM ID ADDRESSABILITY            13610020
         TM    EAISWTCH,EAIDDSN        IS THIS A TWO LINE MESSAGE       13620020
         BO    DOM2LINE                YES. DOM BOTH LINES              13630020
         OI    DOMID1,DOMEND           MARK END OF DOM LIST             13640020
         B     DOM                     ISSUE DOM SVC                    13650020
DOM2LINE EQU   *                       HERE TO DO DOUBLE DOM            13660020
         OI    DOMID2,DOMEND           MARK END OF DOMLIST              13670020
DOM      EQU   *                       HERE TO ISSUE DOM SVC            13680020
         ST    R1,WORK2                SAVE IN CASE R1 DESTROYED BY SVC 13690020
         DOM   MSGLIST=(1)                                              13700020
         L     R1,WORK2                RESTORE R1                       13710020
         TM    EAISWTCH,EAIDDSN        IS THIS A TWO LINE MSG           13720020
         BZ    DOM1LINE                NO.  CLEAR ONLY ONE LINE         13730020
         XC    DOMID2,DOMID2           CLEAR 2ND ID                     13740020
DOM1LINE EQU   *                       HERE TO CLEAR ONLY ONE ID FIELD  13750020
         XC    DOMID1,DOMID1           CLEAR 1ST ID                     13760020
         B     DODOMR                  RETURN TO MAIN LINE CODE         13770020
         DROP  R2                                                       13780020
         DROP  R1                                                       13790020
         SPACE 2                                                        13800020
*********************************************************************** 13810020
REMOUNT  EQU   *                       DISMOUNT AND MOUNT               13820020
READERR  EQU   *                       MOUNT AGAIN IF READ ERROR        13830020
*        DISMOUNT MESSAGE FORMATTING ROUTINE FOLLOWS                    13840020
         BAL   R15,FINDMAIN            FIND MAIN UCB IF DCELL           13850020
         LR    R14,R2                  SET PSUDO BASE REGISTER          13860020
         USING WORKAREA,R14            PSUDO ADDRESSABILITY FOR MSGS    13870020
         USING UCBOB,R13               UCB ADDRESSABILITY               13880020
         MVC   MSGID(MSGUNIT-MSGID),DISMNTID DISMOUNT MSG MAIN PART     13890020
         MVC   MSGUNIT(MSGENDD-MSGUNIT),MSGBLANK CLEAR BUFFER           13900020
         MVC   MSGUNIT,UCBNAME         PUT UNIT NAME IN MESSAGE         13910020
         BAL   R15,CELLNO              CHECK FOR DATACELL              X13920020
               R13 POINTS TO A SUB UCB ON RETURN IF DATACELL            13930020
         LA    R1,MSGCOMA1             POINT TO COMMA                   13940020
         BAL   R15,COMPRESS            ADJUST FOR BLANKS                13950020
         MVI   MSGCOMA1,COMMA          PUT IN COMMA                     13960020
         MVC   MSGSER,VOLSERNO-WORKAREA(R2) PUT VOL SER IN MSG          13970020
*        PUT DISPLAY SPACE CODE HERE IF THE FEATURE IS EVER ADDED       13980020
         LA    R1,MSGMCSD              POINT TO RT & DESC CODES         13990020
         BAL   R15,COMPRESS            ADJUST FOR BLANKS IN MSG         14000020
         MVC   MSGMCSD,DISMNTCD        PUT RT & DESC CODES IN MSG       14010020
         LA    R0,MSGMCSD              POINT TO RT & DESC CODES         14020020
         DROP  R14                                                      14030020
         USING WORKAREA,R2             ADDRESSABILITY MSG BUFFER        14040020
         LA    R1,MSGBUF               POINT TO MSG FOR WTO             14050020
         SR    R0,R1                   FIND LENGTH OF MSG TEXT          14060020
         STC   R0,MSGLNGTH             SET MSG LENGTH PARM              14070020
         DROP  R2                                                       14080020
         WTO   MF=(E,(1))              PUT OUT DISMOUNT MSG             14090020
         SPACE                                                          14100020
         CLI   UCBID,DATACEL           IS THIS DATACELL ?               14110020
         BNE   NOPRTN                  YES. MAKE DCELL NOT READY        14120020
         OI    UCBFL2,NOTREADY         A DISMOUNTED DEVICE             *14130020
                                       MUST BE MADE NOT READY           14140020
NOPRTNR  EQU   *                       RETURN POINT NOPRTN              14150020
         MVI   UCBATI,INDEX            PUT IN OUR INDEX FOR POST        14160020
         SPACE                                                          14170020
*        MOUNT MESSAGE FORMATTING ROUTINE FOLLOWS                       14180020
         BAL   R15,FINDMAIN            FIND MAIN UCB IF DCELL           14190020
         LR    R14,R2                  SET PSUDO BASE REGISTER          14200020
         USING WORKAREA,R14            PSUDO ADDRESSABILITY FOR MSGS    14210020
         MVC   MSGID(MSGUNIT-MSGID),MOUNTID MOUNT MSG MAIN PART         14220020
         MVC   MSGUNIT(MSGENDM-MSGUNIT),MSGBLANK CLEAR BUFFER           14230020
         MVC   MSGUNIT,UCBNAME         PUT UNIT NAME IN MSG             14240020
         BAL   R15,CELLNO              CHECK FOR DATACELL              X14250020
               R13 POINTS TO A SUB UCB ON RETURN IF DATACELL            14260020
         LA    R1,MSGCOMA1             POINT TO COMMA                   14270020
         BAL   R15,COMPRESS            ADJUST FOR BLANKS                14280020
         MVI   MSGCOMA1,COMMA          PUT IN COMMA                     14290020
         CLI   UCBID,DATACEL           IS THIS DATACELL ?               14300020
         BNE   DCELSER                 YES. PUT IN SERIAL NO            14310020
         MVC   MSGSER,SRTEVOLI         PUT VOL SER IN MSG               14320020
DCELSERR EQU   *                       RETURN POINT FROM DCELSER        14330020
         LA    R1,MSGCOMA2             POINT TO COMMA POSITION          14340020
         BAL   R15,COMPRESS            ADJUST FOR BLANKS IN MSG         14350020
         MVI   MSGCOMA2,COMMA          PUT IN COMMA                     14360020
         MVI   MSGCOMA3,COMMA          PUT IN COMMA                     14370020
         USING TIOT1,R7                TIOT ADDRESSABILITY              14380020
         MVC   MSGJOB,TIOCNJOB         PUT JOBNAME IN MSG               14390020
         LA    R1,MSGCOMA4             POINT TO COMMA                   14400020
         BAL   R15,COMPRESS            ADJUST BASE FOR BLANKS           14410020
         CLI   TIOCSTEP,BLANK          IS THERE A STEP NAME             14420020
         BE    SKIPSTEP                NO SKIP STEP NAME                14430020
         MVI   MSGCOMA4,COMMA          PUT IN COMMA                     14440020
         MVC   MSGSTEP,TIOCSTEP        PUT IN STEP NAME                 14450020
SKIPSTEP EQU   *                       HERE TO SKIP STEPNAME            14460020
*        PUT DISPLAY DSN CODE HERE IF THE FEATURE IS EVER ADDED         14470020
         LA    R1,MSGMCSM              POINT TO RT AND DESC CODES       14480020
         BAL   R15,COMPRESS            GO ADJUST FOR BLANKS             14490020
         MVC   MSGMCSM,MNTCD           PUT RT & DESC CODES IN MSG       14500020
         LA    R0,MSGMCSM              POINT TO RT AND DESC CODES       14510020
         DROP  R14                                                      14520020
         USING WORKAREA,R2             ADDRESSABILITY MSG BUFFER        14530020
         LA    R1,MSGBUF               POINT TO MSG FOR WTO             14540020
         SR    R0,R1                   FIND LENGTH OF MSG TEXT          14550020
         STC   R0,MSGLNGTH             SET MSG LENGTH PARM              14560020
         DROP  R2                                                       14570020
         DROP  R13                                                      14580020
         WTO   MF=(E,(1))              PUT OUT MOUNT MSG                14590020
         USING MVI,R8                  MVI ADDRESSABILITY               14600020
         L     R6,MVIEAI               SET BASE FOR EAI BLOCK           14610020
         USING EAI,R6                  EAI ADDRESSABILITY               14620020
         TM    EAISWTCH,EAIDOML        IS THIS AN MCS SYSTEM ?          14630020
         BO    IDSTORE                 YES. GO STORE ID IN LIST         14640020
IDSTORER EQU   *                       RETURN POINT FROM DOM CODE       14650020
         DROP  R8                                                       14660020
         DROP  R6                                                       14670020
         B     SETWAIT                 GO SET UP TO WAIT ON MNT         14680020
         DROP  R7                                                       14690020
         SPACE 2                                                        14700020
*********************************************************************** 14710020
DCELSER  EQU   *                       HERE TO PUT SERIAL NO IN MSG     14720020
         USING WORKAREA,R14            WORKAREA ADDRESSABILITY          14730020
         USING DATACELL,R13            SUBCELL ADDRESSABILITY           14740020
         MVC   MSGSER,DCELVOLI         PUT SERIAL NO IN MSG             14750020
         B     DCELSERR                RETURN TO FINISH MSG             14760020
         DROP  R13                                                      14770020
         DROP  R14                                                      14780020
         SPACE 2                                                        14790020
*********************************************************************** 14800020
CELLNO   EQU   *                       PUT BIN NUMBER IN                14810020
         USING WORKAREA,R2             WORK AREA ADDRESSABILITY         14820020
         L     R13,WORK1               RESTORE UCB                      14830020
         USING UCBOB,R13               UCB ADDRESSABILITY               14840020
         DROP  R2                                                       14850020
         CLI   UCBID,DATACEL           IS THIS DATACELL ?               14860020
         BCR   EQU,R15                 NO. RETURN                       14870020
         USING WORKAREA,R14            MESSAGE ADDRESSABILITY           14880020
         MVI   MSGSLASH,SLASH          PUT SLASH IN MSG                 14890020
         USING DATACELL,R13            DATA CELL ADDRESSABILITY         14900020
         MVC   MSGDCELL,DCELBNR        PUT IN BIN NUMBER                14910020
         OI    MSGDCELL,EBCDIC         MAKE IT EBCDIC                   14920020
         BR    R15                     RETURN                           14930020
         DROP  R14                                                      14940020
         DROP  R13                                                      14950020
         SPACE 2                                                        14960020
*********************************************************************** 14970020
IDSTORE  EQU   *                       HERE TO STORE DOM ID             14980020
         USING EAI,R6                  EAI ADDRESSABILITY               14990020
         L     R14,EAIUCBAD            GET TO UCB LIST                  15000020
         USING DOMUCBS,R14             UCB LIST ADDRESSABILITY          15010020
         LH    R10,EAILNTH             POINT TO END OF UCB LIST         15020020
         AR    R10,R6                  POINT TO END OF UCB LIST         15030020
STLOOP   EQU   *                       HERE TO CHECK NEXT UCB PTR       15040020
         CR    R14,R10                 DID WE REACH END OF UCB LIST     15050020
         BNL   IDSTORER                YES. SKIP THIS ENTRY            *15060020
               THIS BRANCH SHOULD NEVER BE TAKEN. IT IS A SAFTY MEASURE 15070020
         CH    R13,DOMUCB1             IS THIS THE CURRENT UCB          15080020
         BE    DOMFIND2                YES. GO PUT DOM ID IN LIST       15090020
         LA    R14,L'DOMUCB1(R14)      GO TO NEXT UCB POINTER           15100020
         B     STLOOP                  GO TO NEXT ENTRY                 15110020
DOMFIND2 EQU   *                       HERE TO ADD DOM ID TO LIST       15120020
         S     R14,EAIUCBAD            FIND RELATIVE OFFSET IN UCB LIST 15130020
         SLL   R14,ONE                 IDENT OFFSET IS TWICE AS MUCH    15140020
         LA    R14,EAIDMLST(R14)       POINT TO CORRECT DOM ID          15150020
         USING DOMIDS,R14              DOM ID LIST ADDRESSABILITY       15160020
         ST    R1,DOMID1               STORE DOM ID IN DOM LIST         15170020
         B     IDSTORER                RETURN TO MAIN LINE CODE         15180020
         SPACE 2                                                        15190020
*********************************************************************** 15200020
GM       EQU   *                       GETMAIN ROUTINE                  15210020
         L     R1,LCTCMCBA             PROVIDE PARM AREA                15220020
         LR    R6,R1                   SET UP BASE FOR PARM AREA        15230020
         USING GETPARMS,R6             GETMAIN PARM AREA                15240020
         LR    R2,R13                  SAVE REGISTER                    15250020
         LA    R13,GETSAVE             SAVE AREA FOR GET MAIN           15260020
         MVC   GET1(GET2-GET1),GETLIST SET UP GETMAIN LIST              15270020
         GETMAIN A=GOTCORE,MF=(E,(1))                                   15280020
         LR    R13,R2                  RESTORE R13/UCB POINTER          15290020
         L     R2,GOTCORE              SET UP WORKAREA BASE             15300020
         LTR   R15,R15                 GETMAIN ERROR                    15310020
         BZ    GMRETURN                NO. CONTINUE                     15320020
         SR    R2,R2                   INDICATE NO MAIN STORAGE GOTTEN  15330020
         LA    R14,GETERROR            INDICATE GETMAIN ERROR           15340020
         B     GOTOKIMP                GO TO EXIT PREPARATION.          15350020
         DROP  R6                                                       15360020
         SPACE 2                                                        15370020
*********************************************************************** 15380020
COMPRESS EQU   *                       BLANKS ADJUST RTN                15390020
         BCTR  R1,0                    DECREMENT POINTER TO MSG END     15400020
         CLI   0(R1),BLANK             IS THERE A BLANK IN THE MSG      15410020
         BCR   NOTEQU,R15              NO. RETURN                       15420020
         BCTR  R14,0                   DECREMENT MSG BASE REG           15430020
         B     COMPRESS                TEST FOR MORE COMPRESSION        15440020
         SPACE 2                                                        15450020
*********************************************************************** 15460020
FINDMAIN EQU   *                       FIND MAIN UCB IF SUBCELL         15470020
         USING WORKAREA,R2             WORK AREA ADDRESSABILITY         15480020
         USING UCBOB,R13               UCB ADDRESSABILITY               15490020
         ST    R13,WORK1               SAVE FOR RESTORE                 15500020
         CLI   UCBID,DATACEL           IS THIS DATACELL                 15510020
         USING DATACELL,R13            DATACELL ADDRESSABILITY          15520020
         BCR   EQU,R15                 RETURN IF NOT CELL               15530020
         ST    R14,WORK2               SAVE R14                         15540020
         LH    R14,DCELBBNR            LOAD SUB UCB NUMBER              15550020
         SLA   R14,FOUR                TIMES 16                         15560020
         LA    R14,DATACELL-UCBOB(R14) ADD MAIN UCB LENGTH              15570020
         SR    R13,R14                 GETS MAIN UCB ADDRESS            15580020
         L     R14,WORK2               RESTORE R14                      15590020
         BCR   ALWAYS,R15              RETURN                           15600020
         DROP  R13                                                      15610020
         DROP  R2                                                       15620020
         SPACE 2                                                        15630020
*********************************************************************** 15640020
*    ROUTINE TO SET VIA NOP & APENDADGES, THE 2321 IN PROPER STATUS     15650020
*            1. SET MAIN UCB NOT READY FOR MOUNT                        15660020
*********************************************************************** 15670020
NOPRTN   EQU   *                       MAKE DCELL NOT READY VIA NOP SIO 15680020
         USING WORKAREA,R2             WORK AREA ADDRESSABILITY         15690020
         USING UCBOB,R13               UCB ADDRESSABILITY               15700020
         CLI   UCBID,DATACEL           IS DEVICE A 2321 ?               15710020
         BE    NOPRTNR                 BRANCH NO                        15720020
         BAL   R15,FINDMAIN            GET A MAIN UCB                   15730020
         TM    UCBFL2,NOTREADY         TEST FOR NOT READY               15740020
         BO    NTRDY                   BRANCH NOT READY                 15750020
         CLI   UCBATI,INDEX            DEVICE PREPARED FOR MOUNT        15760020
         BE    NTRDY                   BRANCH YES                       15770020
         BAL   R14,INIT                GO INITIALIZE I/O BLOCKS        *15780020
               ON RETURN R13 POINTS TO THE SUBCELL                      15790020
         NI    IOBFLAG1,ALL-CPCHAIN    INDICATE NO CHAINING             15800020
         OI    DCBIFLGS,ERPS           OVERIDE IOS ERROR                15810020
         LA    R14,CANCELAP            POINT TO CLEAN UP APPENDAGE      15820020
         ST    R14,SIOAPEND            SET CLEAN UP APPENDAGE           15830020
         TM    LCTPARM2,CANCEL         TIOT CLEANUP ON CANCEL ?         15840020
         BO    CLEANUP                 BRANCH CANCEL CLEANUP            15850020
         MVI   DCBIFLGS,ZERO           ALLOW IOS ERROR                  15860020
         LA    R14,APPEND              POINT TO APPEND ROUTINE          15870020
         ST    R14,SIOAPEND            SET NORMAL APPENDAGE             15880020
         LA    R14,CHANAP              POINT TO CHANNEL APPEND RTN      15890020
         ST    R14,CHANEND             SET CHANNEL END APPENDAGE        15900020
         ST    R14,ABNMEND             SET ABNORMAL END APPENDAGE       15910020
CLEANUP  EQU   *                                                        15920020
         LA    R14,CCWNOP              GET CHANNEL PROG ADR             15930020
         ST    R14,IOBSTART            PUT ADDRESS IN IOB               15940020
         LA    R1,IOB                  GET IOB ADR                      15950020
*        $$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$  15960020
         EXCP   (1)                    ISSUE NOP                        15970020
         NI    ECB,ALL-ECBWAIT         SET WAIT COMPL FLAG OFF          15980020
         LA    R1,ECB                  GET ECB ADR                      15990020
         WAIT  ECB=(1)                 WAIT                             16000020
*        $$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$ 16010020
         LA    R0,APPEND               POINT TO APPEND ROUTINE          16020020
         ST    R0,CHANEND              RESTORE CHANNEL END APPEND       16030020
         ST    R0,ABNMEND              RESTORE ABEND APPENDAGE          16040020
         ST    R0,SIOAPEND             RESTORE SIO APPENDAGE            16050020
         MVI   DCBIFLGS,ZERO           ALLOW IOS ERROR                  16060020
         B     NOPRTNR                 RETURN TO CALLER                 16070020
NTRDY    EQU   *                       HERE WHEN NOP NOT NEEDED         16080020
         L     R13,WORK1               RESTORE UCB PTR                  16090020
         B     NOPRTNR                 RETURN TO CALLER                 16100020
         DROP  R2                                                       16110020
*********************************************************************** 16120020
APPEND   BR    R14                     DUMMY APPENDAGE ROUTINE          16130020
*********************************************************************** 16140020
CANCELAP B     FOUR(R4)                SIO APPENDAGE FOR CANCEL         16150020
*********************************************************************** 16160020
CHANAP   EQU   *                       CHANNEL END APPENDAGE FOR DCELL  16170020
         USING UCBOB,R7                UCB APPENDAGE ADDRESSABILITY     16180020
         NI    0(R2),EXCEPT            CLEAR EXCEPTION BIT              16190020
         OI    UCBFL2,NOTREADY         MAKE WHOLE DEVICE NOT RDY        16200020
         DROP  R7                                                       16210020
         BR    R14                     RETURN TO IOS                    16220020
         SPACE 2                                                        16230020
*********************************************************************** 16240020
INIT     EQU   *                       DEB INITIALIZATION SUBROUTINE    16250020
         USING WORKAREA,R2             WORKAREA ADDRESSABILITY          16260020
         USING UCBOB,R13               UCB ADDRESSABILITY               16270020
         ST    R13,DEBDVMOD            STORE UCB ADR. IN DEB           *16280020
               SINCE THE H.O. BYTE IS ZERO THIS TAKES CARE OF DEBDVMOD *16290020
               AS WELL AS THE UCB ADDRESS.                              16300020
         XC    IOBFLAG1(FOUR),IOBFLAG1 CLEAR IOB ERROR FLAGS            16310020
         MVI   DCBIFLGS,ZERO           CLEAR DCB FLAGS                  16320020
         MVI   IOBFLAG1,UNREL+CPCHAIN  IOB UNRELATED EXCP               16330020
         XC    IOBSEEK1(TWO),IOBSEEK1  BIN NUMBER TO IOB @@@@@@@@@@     16340020
         XC    DEBBINUM,DEBBINUM       BIN NUMBER TO DEB @@@@@@@@@@     16350020
         L     R13,WORK1               RESTORE UCB PTR                  16360020
         CLI   UCBID,DATACEL           IS THIS A DATACELL               16370020
         BCR     EQU,R14               NO SKIP BIN SETTING              16380020
         USING DATACELL,R13            SUBCELL ADDRESSIBLITY            16390020
         MVC   IOBSEEK1(TWO),DCELBBNR  BIN NUMBER TO IOB                16400020
         MVC   DEBBINUM,DCELBBNR       BIN NUMBER TO DEB                16410020
         BR    R14                     RETURN                           16420020
         DROP  R13                                                      16430020
         DROP  R2                                                       16440020
         EJECT                                                          16450020
*        PUT CONSTANTS HERE                                             16460020
         SPACE 2                                                        16470020
*   TABLES TO BE USED BY EXCP (EXECUTE CHANNEL PROGRAM)                 16480020
*   EVENT CONTROL BLOCK - ECB                                           16490020
         SPACE 1                                                        16500020
ECB      DC    A(0)                                                     16510020
ECBWAIT  EQU   128                           BIT-0/WAIT BIT             16520020
*   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *       16530020
         SPACE 2                                                        16540020
*   INPUT/OUTPUT BLOCK  - IOB                                           16550020
IOB      DS    0F                                                       16560020
IOBFLAG1 DC    X'02'                      UNRELATED EXCPS               16570020
         DC    AL3(0)                                                   16580020
IOBECBAD DC    A(ECB)                  ADDR OF ECB                      16590020
         DC    2A(0)                                                    16600020
IOBSTART DC    A(0)                    ADDRESS OF CHANNEL COMMAND       16610020
IOBDCBAD DC    A(DCBDEBAD-44)                                           16620020
         DC    2A(0)                                                    16630020
*        IOB EXTENSION SEGMENT FOR DIRECT ACCESS                        16640020
IOBSEEK  DC    A(0),A(3)               SEEK ADDR FOR DA                 16650020
IOBSEEK1 EQU   IOBSEEK+1               BIN PART OF SEEK ADR             16660020
IOBSEEK3 EQU   IOBSEEK+3               CCHHR FIELD                      16670020
*   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *       16680020
         SPACE 2                                                        16690020
*   DATA CONTROL BLOCK  - DCB                                           16700020
DCB      EQU   *                                                        16710020
DCBIFLGS DS    0C                            I-FLAGS                    16720020
DCBDEBAD DC    A(DEB)                        ADDR OF DEB                16730020
*   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *       16740020
         SPACE 2                                                        16750020
*   DATA EVENT BLOCK    - DEB                                           16760020
DEB      DC    6F'0'                   FIRST PART OF DEB ALL ZERO       16770020
DEBPROTG DC    X'0F'                   PROTECT KEY AND DEB ID FIELDS    16780020
DEBDCBAD DC    AL3(DCBDEBAD-44)        DCB POINTER                      16790020
DEBEXSCL DC    X'00'                   EXTENT SCALE                     16800020
DEBAPPAD DC    AL3(APPENDL)            APPENDAGE ADDRS                  16810020
*        DEB EXTENSION FOR DIRECT ACCESS                                16820020
DEBDVMOD DC    X'00'                   MODE SETTING                     16830020
DEBUCBAD DC    AL3(0)                  UCB POINTER                      16840020
DEBBINUM DC    X'0000'                 BIN NUMBER                       16850020
DEBSTRCC DC    X'0000'                 CYLINDER START ADDRESS           16860020
DEBSTRHH DC    X'0000'                 TRACK START ADDRESS              16870020
DEBENDCC DC    X'7FFF'                 CYLINDER END ADDRESS             16880020
DEBENDHH DC    X'7FFF'                 TRACK END ADDRESS                16890020
         DC    X'7FFF'                 NO. OF TRACKS THIS EXTENT        16900020
*   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *       16910020
*   CHANNEL PROGRAMS                                                    16920020
*   ***DIRECT ACCESS***                                                 16930020
*        READ LABEL CHANNEL PROGRAM                                     16940020
         DS    0D                                                       16950020
CCWSRCH  DC    X'31'                         SEARCH                     16960020
         DC    AL3(IOBSEEK3)                 SEEK ADDR (ID)             16970020
         DC    X'40000005'                                              16980020
CCWRDAAD DC    X'08'                         TIC                        16990020
         DC    AL3(CCWSRCH)                                             17000020
         DC    X'40000000'                                              17010020
CCWRCODE DC    X'06'                         READ DATA                  17020020
CCWLABEL DC    AL3(0)                        LABEL BUFFER ADDR          17030020
         DC    X'00000050'                   LENGTH                     17040020
*        NOP CHANNEL PROGRAM                                            17050020
CCWNOP   DC    X'03'                                                    17060020
         DC    AL3(0)                                                   17070020
         DC    X'00000001'                                              17080020
         SPACE 3                                                        17090020
APPENDL  EQU   *                       APPENDAGE LIST                   17100020
SIOAPEND DC    A(APPEND)               SIO APPENDAGE                    17110020
         DC    A(APPEND)               DUMMY APPENDAGE                  17120020
         DC    A(APPEND)               DUMMY APPENDAGE                  17130020
CHANEND  DC    A(APPEND)               CHANNEL END APPENDAGE            17140020
ABNMEND  DC    A(APPEND)               ABEND APPENDAGE                  17150020
MOUNTID  WTO   'IEF533A M ',MF=L,ROUTCDE=(4),DESC=2,  MOUNT            *17160020
               MCSFLAG=(NOTIME)        WTO LIST FORM                    17170020
DISMNTID WTO   'IEF234E D ',MF=L,ROUTCDE=(4),DESC=4,  DISMOUNT    M0726*17180020
               MCSFLAG=(NOTIME)        WTO LIST FORM                    17190020
DISMNTCD EQU   DISMNTID+14             RT AND DESC CODE FIELDS          17200020
MNTCD    EQU   MOUNTID+14              RT AND DESC CODE FIELDS          17210020
         DS    0F                                                       17220020
         SPACE 1                                                        17230020
* EXTERNAL REFERENCES.                                                  17240020
VCON41SD DC    V(IEFW41SD)             NORMAL EXIT.                     17250020
VCONKIMP DC    V(IEFXK000)             ERROR EXIT.                      17260020
         SPACE 2                                                        17270020
* ENQ - DEQ LIST FORMS.                                                 17280020
Q4       ENQ   (IEFSQCBS,IEFQ4QCB,E,2,SYSTEM),MF=L,RET=HAVE             17290020
Q5       ENQ   (IEFSQCBS,IEFQ5QCB,E,2,SYSTEM),MF=L,RET=HAVE             17300020
Q8       ENQ   (IEFSQCBS,IEFQ8QCB,E,2,SYSTEM),MF=L                      17310020
Q9       ENQ   (IEFSQCBS,IEFQ9QCB,E,2,SYSTEM),MF=L,RET=HAVE       M4160 17315000
IEFSQCBS DC    C'SYSIEFSD'                                              17320020
IEFQ4QCB DC    C'Q4'                                                    17330020
IEFQ5QCB DC    C'Q5'                                                    17340020
IEFQ8QCB DC    C'Q8'                                                    17350020
IEFQ9QCB DC    C'Q9'              THIS RESOURCE IS USED TO       A47599 17352000
*                                 SERIALIZE BATCH AND            A47599 17354000
*                                 DYNAMIC ALLOCATIONS.           A47599 17356000
         SPACE 2                                                        17360020
*        GETMAIN LIST FORM                                              17370020
         DS    0F                                                       17380020
GETLIST  EQU   *                       GETMAIN LIST                     17390020
         GETMAIN EC,LV=AMOUNT,MF=L                                      17400020
H4       DC    H'4'                    FOR DOMLIST ALGORITHM            17410020
         END                                                            17420020
