 TITLE 'IEFXMPCP - PCP TRANSIENT QUEUE MANAGER'                   M2973 00100019
IEFXMPCP CSECT                                                          00200019
*********************************************************************** 00400019
*********************************************************************** 00600019
*                                                                     * 00800019
*          MODULE IGC00090 - TRANSIENT QUEUE MANAGER I/O AND          * 01000019
*                            RECORD ASSIGNMENT ROUTINE                * 01200019
*                                                                     * 01400019
*********************************************************************** 01600019
*********************************************************************** 01800019
*                                                                     * 02000019
*STATUS- CHANGE LEVEL 000                                             * 02200019
*                                                                     * 02400019
*FUNCTIONS- (1)ASSIGN- TO ASSIGN JOB QUEUE RECORDS.                   * 02600019
*           (2)READ/WRITE- TO GET CORE FOR AND TO INITIALIZE AN       * 02800019
* ECB/IOB;TO PERFORM THE CONVERSION OF A TTR TO AN MBBCCHHR AND TO    * 03000019
* EITHER READ OR WRITE UP TO 15 RECORDS OF THE QUEUE MANAGER EXTENT.  * 03200019
*                                                                     * 03400019
*ENTRY POINT- IGC00090       FROM- SVC INTERRUPT HANDLER              * 03600019
*                                                                     * 03800019
*INPUT- A QUEUE MANAGER PARAMETER AREA,POINTED TO BY REGISTER 1.      * 04000019
* AN EXTERNAL PARAMETER LIST POINTED TO BY THE PARAMETER AREA.        * 04200019
*                                                                     * 04400019
*OUTPUT- WRITE FUNCTION=NONE,READ FUNCTION=THE APPROPRIATE RECORDS IN * 04600019
* THE CORE AREAS SPECIFIED BY THE CALLER.                             * 04800019
* ASSIGN FUNCTION=A TABLE OF TTRS CONTAINING ONE TTR FOR EACH RECORD  * 05000019
* ASSIGNMENT REQUESTED.                                               * 05200019
*                                                                     * 05400019
*EXTERNAL REFERENCES- LOCATION I6 TO LOCATE THE C.V.T. WHICH IS USED  * 05600019
* TO OBTAIN THE Q MNGR RESIDENT CORE AREA AND THE ENTRY POINT OF THE  * 05800019
* SUPERVISOR CONVERT ROUTINE.                                         * 06000019
*                                                                     * 06200019
* EXITS- RETURN TO CALLER VIA REGISTER 14.                            * 06400019
*        ABEND JOB IF I/O ERROR OCCURS WHILE PERFORMING READ/WRITE    * 06600019
*                                                                     * 06800019
*ERROR CODES- SPECIFIED IN REGISTER 15, 0= NORMAL RETURN              * 07000019
*                                       8= CALLER NOT IN PROTECT KEY 0* 07200019
*                                       ABEND CODE X'00080000'= I/O   * 07400019
*                                                               ERROR * 07600019
*                                                                     * 07800019
*TABLES/WORK AREAS- QUEUE MANAGER PARAMETER AREA,QUEUE MANAGER        * 08000019
* RESIDENT CORE AREA.                                                 * 08200019
*                                                                     * 08400019
*ATTRIBUTES- REENTRANT                                                * 08600019
*                                                                     * 08800019
*********************************************************************** 09000019
         EJECT                                                          09200019
*********************************************************************** 09400019
*                                                                     * 09600019
*                           REGISTER EQUATES                          * 09800019
*                                                                     * 10000019
*********************************************************************** 10200019
R0       EQU   0                                                        10400019
R1       EQU   1                                                        10600019
R2       EQU   2                                                        10800019
R3       EQU   3                                                        11000019
R4       EQU   4                                                        11200019
R5       EQU   5                                                        11400019
R6       EQU   6                                                        11600019
R7       EQU   7                                                        11800019
R8       EQU   8                                                        12000019
R9       EQU   9                                                        12200019
R10      EQU   10                                                       12400019
R11      EQU   11                                                       12600019
R12      EQU   12                                                       12800019
R13      EQU   13                                                       13000019
R14      EQU   14                                                       13200019
R15      EQU   15                                                       13400019
*********************************************************************** 13600019
D0       EQU   0                                                        13800019
D1       EQU   1                                                        14000019
D2       EQU   2                                                        14200019
D4       EQU   4                                                        14400019
D5       EQU   5                                                        14600019
D8       EQU   8                                                        14800019
D12      EQU   12                                                       15000019
D16      EQU   16                                                       15200019
L1       EQU   1                                                        15400019
L2       EQU   2                                                        15600019
L3       EQU   3                                                        15800019
L4       EQU   4                                                        16000019
L32      EQU   32                                                       16200019
L40      EQU   40                                                       16400019
*********************************************************************** 16600019
         BALR  R8,D0               ESTABLISH ADDRESSABILITY             16800019
         USING *,R8                                                     17000019
*  THIS SECTION OF CODE IS FOR DUMP RECOGNITION ONLY                    17200019
         B     XQMGO                                                    17400019
         DC    X'CCCC'                                                  17600019
         DC    C'IEFXMPCP'                                              17800019
         DC    C'10101969'                                              18000019
         DC    X'CCCC'                                                  18200019
XQMGO    DS    0H                                                       18400019
         EJECT                                                          18600019
*********************************************************************** 18800019
*                                                                     * 19000019
*                     TEST FOR PROTECTION KEY 0                       * 19200019
*                                                                     * 19400019
*********************************************************************** 19600019
QMRES    EQU   12                                                       19800019
PROTKEY  EQU   17                                                       20000019
ZERO     EQU   X'F0'                                                    20200019
*********************************************************************** 20400019
         SSM   ENABLE             ENABLE INTERRUPTS                     20600019
         TM    PROTKEY(R5),ZERO   DOES CALLER HAVE PROTECTION KEY 0     20800019
         BO    NOTSUPV            NO-SET PROPER RETURN CODE             21000019
         LR    R4,R1                                                    21200019
         USING IOPARAMS,R4         ADDRESSABILITY FOR QMPA              21400019
         L     R3,QMRES(R3)                                             21600019
         USING QJOB,R3             ADDRESSABILITY FOR RESIDENT CORE     21800019
         LR    R6,R14              SAVE RETURN ADDRESS                  22000019
*********************************************************************** 22200019
*                                                                     * 22400019
*                    DETERMINE REQUESTED FUNCTION                     * 22600019
*                                                                     * 22800019
*********************************************************************** 23000019
ASGQAGST EQU   2                                                        23200019
VALREQST EQU   5                                                        23400019
*********************************************************************** 23600019
         CLI   QMPOP,ASGQAGST      IS THIS AN ASSIGN OR ASSIGN/START    23800019
         BL    ASGN10              YES-BR TO ASSIGN RECORDS             24000019
         CLI   QMPOP,VALREQST      IS THIS REQUEST FOR AN AVAILABLE     24200019
*                                    FUNCTION                           24400019
         BH    NORMAL              NO-BR TO RETURN TO CALLER            24600019
         EJECT                                                          24800019
*********************************************************************** 25000019
*                                                                     * 25200019
*                         GET CORE FOR ECB/IOB                        * 25400019
*                                                                     * 25600019
*********************************************************************** 25800019
         LA    R0,QIOBL+D12        LENGTH OF ECB/IOB + 12               26000019
         LR    R12,R0              SAVE LENGTH                          26200019
         GETMAIN R,LV=(0)          GET CORE FOR ECB/IOB                 26400019
         LR    R6,R1               SAVE PT TO GOTTEN CORE               26600019
*********************************************************************** 26800019
*                                                                     * 27000019
*                      INITIALIZATION OF ECB/IOB                      * 27200019
*                                                                     * 27400019
*********************************************************************** 27600019
ECBIOBLN EQU   0                                                        27800019
RETADDR  EQU   4                                                        28000019
XQMCCW1  EQU   44                                                       28200019
XQMCCW2  EQU   52                                                       28400019
XQMCCWPT EQU   20                                                       28600019
XQMECBPT EQU   8                                                        28800019
XQMOP    EQU   X'31'                                                    29000019
*********************************************************************** 29200019
         ST    R12,ECBIOBLN(R1)    SAVE LENGTH OF ECB/IOB               29400019
         ST    R14,RETADDR(R1)     SAVE RETURN ADDRESS                  29600019
         LA    R2,D12(R1)          ECB/IOB PT                           29800019
         MVC   D0(QIOBL,R2),QMECB  INITIALIZE ECB/IOB                   30000019
         ST    R2,XQMECBPT(R2)     PUT ECB PT INTO IOB                  30200019
         LA    R1,XQMCCW1(R2)      PUT CCW1 PT                          30400019
         ST    R1,XQMCCWPT(R2)       INTO IOB                           30600019
         MVC   XQMCCW2+1(L3,R2),XQMCCWPT+1(R2) AND INTO CCW2            30800019
         LA    R1,XQMCCW1-D5(R2)   PUT PT TO IOBSEEK FLD + 3            31000019
         ST    R1,XQMCCW1(R2)        INTO IOB                           31200019
         OI    XQMCCW1(R2),XQMOP   CCW1 OP CODE BYTE                    31400019
         EJECT                                                          31600019
*********************************************************************** 31800019
*                                                                     * 32000019
*                 DETERMINE NO. OF READ/WRITE REQUESTS                * 32200019
*                                                                     * 32400019
*********************************************************************** 32600019
ECBPT    EQU   8                                                        32800019
MASK     EQU   X'0F'                                                    33000019
*********************************************************************** 33200019
         L     R7,QMPCL            EXTERNAL PARAMETER AREA PT           33400019
         LA    R1,MASK             MASK TO CLEAR UNUSED BITS            33600019
         IC    R5,QMPNC            NO. OF RECORDS TO READ OR WRITE      33800019
         NR    R5,R1               CLEAR UNUSED BITS                    34000019
         ST    R2,ECBPT(R6)        SAVE ECB/IOB PT                      34200019
*********************************************************************** 34400019
*                                                                     * 34600019
*                    CONVERSION OF TTR TO MBBCCHHR                    * 34800019
*                                                                     * 35000019
*********************************************************************** 35200019
CVTPT    EQU   16                                                       35400019
QMSPCV   EQU   28                                                       35600019
READ     EQU   4                                                        35800019
XQMSKAD  EQU   36                                                       36000019
*********************************************************************** 36200019
IOLOOP   L     R0,D4(R7)           RECORD TTR0                          36400019
         LA    R2,XQMSKAD(R2)      IOBSEEK FLD FOR MBBCCHHR             36600019
         LA    R1,SCADEB           RESIDENT DEB PT                      36800019
         L     R15,CVTPT           CVT PT                               37000019
         L     R15,QMSPCV(R15)     SUPERVISOR CONVERT ROUTINE ADDRESS   37200019
         BALR  R14,R15                                                  37400019
         L     R2,ECBPT(R6)        RESTORE ECB/IOB PT                   37600019
         L     R9,D0(R7)           RECORD CORE ADDRESS                  37800019
         CLI   QMPOP,READ          IS THIS A READ                       38000019
         BNE   WRTEXDAP            NO-BR TO WRITE A RECORD              38200019
         EJECT                                                          38400019
*********************************************************************** 38600019
*                                                                     * 38800019
*                        READ OR WRITE A RECORD                       * 39000019
*                                                                     * 39200019
*********************************************************************** 39400019
         XDAP  (2),RI,(3),(9),176,,,MF=E     YES-READ A RECORD          39600019
         B     IOWAIT              BR TO WAIT FOR I/O COMPLETION        39800019
WRTEXDAP EQU   *                                                        40000019
         XDAP  (2),WI,(3),(9),176,,,MF=E     WRITE A RECORD             40200019
         EJECT                                                          40400019
*********************************************************************** 40600019
*                                                                     * 40800019
*                      WAIT FOR I/O COMPLETION                        * 41000019
*                                                                     * 41200019
*********************************************************************** 41400019
NORMALIO EQU   X'7F'                                                    41600019
*********************************************************************** 41800019
IOWAIT   LR    R1,R2               ECB/IOB PT                           42000019
         LA    R1,D0(R1)           CLEAR HIGH-ORDER BYTE OF REG 1       42200019
         WAIT  1,ECB=(1)           WAIT FOR I/O COMPLETION              42400019
         CLI   D0(R2),NORMALIO     IS I/O COMPLETION NORMAL             42600019
         BNE   IOERR               NO-BR TO WRITE MESSAGE,ABEND         42800019
*********************************************************************** 43000019
*                                                                     * 43200019
*                  TEST FOR MORE RECORDS TO BE READ OR WRITTEN        * 43400019
*                                                                     * 43600019
*********************************************************************** 43800019
WRTEASGN EQU   2                                                        44000019
*********************************************************************** 44200019
         LA    R7,D8(R7)           INCREMENT EXTERNAL PARAMETER AREA PT 44400019
         BCT   R5,IOLOOP           IF MORE RECORDS ARE TO BE READ OR    44600019
*                                    WRITTEN-BR TO CONTINUE             44800019
         CLI   QMPOP,WRTEASGN      IS THIS A WRITE/ASSIGN REQUEST       45000019
         BNE   RWEXIT              NO-BR TO RETURN                      45200019
         EJECT                                                          45400019
*********************************************************************** 45600019
*                                                                     * 45800019
*            DETERMINE NO. OF REQUESTED RECORD ASSIGNMENTS            * 46000019
*                                                                     * 46200019
*********************************************************************** 46400019
AGST     EQU   0                                                        46600019
*********************************************************************** 46800019
ASGN10   SR    R5,R5               CLEAR REGISTER                       47000019
         IC    R5,QMPCM            NO. OF RECORDS TO ASSIGN             47200019
         SRL   R5,D4               CLEAR UNUSED BITS                    47400019
         L     R7,QMPCL            EXTERNAL PARAMETER AREA PT           47600019
         CLI   QMPOP,AGST          IS THIS AN ASSIGN/START              47800019
         BNE   ASGN20              NO-BR TO ASSIGN FUNCTION             48000019
*********************************************************************** 48200019
*                                                                     * 48400019
*                   INITIALIZATION FOR ASSIGN/START                   * 48600019
*                                                                     * 48800019
*********************************************************************** 49000019
         LA    R9,ASGN20           PT TO CONTINUE ASSIGN/START          49200019
         LH    R10,SCASTRKS        TT OF FIRST JOBQ TRACK               49400019
         SLL   R10,D16             SHIFT TT TO HIGH-ORDER POSITION      49600019
ASGN15   ST    R10,SCATALLY        SAVE TT                              49800019
         MVI   SCATALLY+D2,D1      SET UP FIRST TTR0 OF TRACK           50000019
         BR    R9                                                       50200019
*********************************************************************** 50400019
*                                                                     * 50600019
*                  ASSIGN RECORDS TO SATISFY REQUEST                  * 50800019
*                                                                     * 51000019
*********************************************************************** 51200019
ASGN20   LA    R9,NORMAL           PT TO SET NORMAL RETURN CODE IF      51400019
*                                    NO AVAILABLE TRACKS                51600019
         MVC   D0(L4,R7),SCATALLY  PUT TTR0 INTO PARAMETER LIST         51800019
         CLC   SCATALLY(L2),SCALTRKS IS THIS THE LAST TRACK OF THE      52000019
*                                     QMNGR EXTENT                      52200019
         BNE   ASGN30              NO-BR TO CONTINUE RECORD ASSIGNS     52400019
         EJECT                                                          52600019
*********************************************************************** 52800019
*                                                                     * 53000019
*   IF ALL BUT 10 RECORDS OF QMNGR EXTENT ARE ASSIGNED,ISSUE JOB Q    * 53200019
*           OVERFLOWED MESSAGE AND SET PROPER RETURN CODE             * 53400019
*                                                                     * 53600019
*********************************************************************** 53800019
NOSPACE  EQU   4                                                        54000019
OVWTOBUF EQU   32                                                       54200019
TEN      EQU   X'0A00'                                                  54400019
*********************************************************************** 54600019
         LH    R10,SCATALLY+D2     NO. OF LAST ASSIGNED RECORD          54800019
         LA    R10,TEN(R10)        ADD 10 TO RECORD NO.                 55000019
         CH    R10,SCARECPT        WAS LAST ASSIGNED RECORD THE TENTH   55200019
*                                    FROM LAST AVAILABLE RECORD         55400019
         BH    ERRCODE             BR IF MESSAGE ALREADY ISSUED         55600019
         BL    ASGN30              NO-BR TO CONTINUE RECORD ASSIGNS     55800019
         GETMAIN R,LV=OVWTOBUF     YES-GET CORE FOR WTO BUFFER          56000019
         LA    R2,OVFLWMSG         PT TO OVERFLOW MESSAGE               56200019
         MVC   D0(L32,R1),D0(R2)   MOVE 'SYSJOBQE OVERFLOWED'           56400019
*                                    MESSAGE INTO BUFFER                56600019
         LR    R11,R1              SAVE PT TO GOTTEN CORE               56800019
         WTO   MF=(E,(1))          WTO-IEF405I                          57000019
         LR    R1,R11              PT TO GOTTEN CORE                    57200019
         FREEMAIN R,LV=OVWTOBUF,A=(R1) FREE GOTTEN CORE                 57400019
ERRCODE  LA    R15,NOSPACE         SET OVERFLOW ERROR CODE              57600019
         LA    R9,EXIT             PT TO RETURN IF NO AVAILABLE TRACKS  57800019
         EJECT                                                          58000019
*********************************************************************** 58200019
*                                                                     * 58400019
*                      CONTINUE RECORD ASSIGNMENTS                    * 58600019
*                                                                     * 58800019
*********************************************************************** 59000019
ASGN30   CLC   SCATALLY+D2(L1),SCARECPT IS LAST AVAILABLE RECORD ON     59200019
*                                       TRACK ASSIGNED                  59400019
         BE    ASGN50              YES-BR TO INCREMENT ASSIGNED TRACKS  59600019
         L     R10,SCATALLY        CURRENT TTR0                         59800019
         A     R10,ADDREC          INCREMENT RECORD NO. BY 1            60000019
         ST    R10,SCATALLY        RESTORE TTR0                         60200019
ASGN40   LA    R7,D4(R7)           INCREMENT EXTERNAL PARAMETER AREA PT 60400019
         BCT   R5,ASGN20           IF MORE RECORDS ARE TO BE ASSIGNED-  60600019
*                                    BR TO CONTINUE                     60800019
*********************************************************************** 61000019
*                                                                     * 61200019
*                       SET NORMAL RETURN CODE                        * 61400019
*                                                                     * 61600019
*********************************************************************** 61800019
NORMAL   SR    R15,R15             SET NORMAL RETURN CODE               62000019
*********************************************************************** 62200019
*                                                                     * 62400019
*                           RETURN TO CALLER                          * 62600019
*                                                                     * 62800019
*********************************************************************** 63000019
EXIT     LR    R14,R6              RETURN ADDRESS                       63200019
         LR    R1,R4              RESTORE QMPA PT                       63400019
RETURN   RETURN RC=(15)            RETURN TO CALLER                     63600019
RWEXIT   LR    R1,R6               PT TO GOTTEN CORE                    63800019
         L     R6,RETADDR(R1)      RETURN ADDRESS                       64000019
         L     R0,ECBIOBLN(R1)     LENGTH OF GOTTEN CORE                64200019
         FREEMAIN R,LV=(0),A=(1)   FREE GOTTEN CORE                     64400019
         B     NORMAL              BR TO RETURN TO CALLER               64600019
*********************************************************************** 64800019
*                                                                     * 65000019
*                INCREMENT NO. OF ASSIGNED TRACKS BY 1                * 65200019
*                                                                     * 65400019
*********************************************************************** 65600019
ASGN50   CLC   SCATALLY(L2),SCALTRKS IS THIS THE LAST TRACK OF THE      65800019
*                                     QMNGR EXTENT                      66000019
         BCR   8,R9                YES-BR TO RETURN TO CALLER           66200019
         L     R10,SCATALLY        CURRENT TTR0                         66400019
         A     R10,ADDTRK          INCREMENT TRACK NO. BY 1             66600019
         LA    R9,ASGN40           PT TO CONTINUE FOR MORE ASSIGNS      66800019
         B     ASGN15              BR TO SAVE TTR0                      67000019
         EJECT                                                          67200019
*********************************************************************** 67400019
*                                                                     * 67600019
*                       WRITE I/O ERROR MESSAGE                       * 67800019
*                                                                     * 68000019
*********************************************************************** 68200019
IOWTOBUF EQU   40                                                       68400019
*********************************************************************** 68600019
IOERR    GETMAIN R,LV=IOWTOBUF     GET CORE FOR WTO BUFFER              68800019
         LA    R2,IOERRMSG         PT TO I/O ERROR MESSAGE              69000019
         MVC   D0(L40,R1),D0(R2)   MOVE I/O ERROR MESSAGE INTO BUFFER   69200019
         LR    R11,R1              SAVE PT TO GOTTEN CORE               69400019
         WTO   MF=(E,(1))          WTO-IEF400W                          69600019
         LR    R1,R11              PT TO GOTTEN CORE                    69800019
         FREEMAIN R,LV=IOWTOBUF,A=(R1) FREE GOTTEN CORE                 70000019
*********************************************************************** 70200019
*                                                                     * 70400019
*                              ABEND JOB                              * 70600019
*                                                                     * 70800019
*********************************************************************** 71000019
         L     R1,ABENDCD          ABEND CODE                           71200019
         ABEND (1),DUMP                                                 71400019
*********************************************************************** 71600019
*                                                                     * 71800019
*           SET ERROR CODE - CALLER NOT IN PROTECTION KEY 0           * 72000019
*                                                                     * 72200019
*********************************************************************** 72400019
KEYERR   EQU   8                                                        72600019
*********************************************************************** 72800019
NOTSUPV  LA    R15,KEYERR         SET RETURN CODE FOR CALLER NOT IN     73000019
         B     RETURN               PROTECTION KEY 0 AND BR TO RETURN   73200019
         EJECT                                                          73400019
*********************************************************************** 73600019
*                                                                     * 73800019
*                              CONSTANTS                              * 74000019
*                                                                     * 74200019
*********************************************************************** 74400019
         DS    0F                                                       74600019
ADDREC   DC    X'00000100'                                              74800019
ADDTRK   DC    X'00010000'                                              75000019
ABENDCD  DC    X'00080000'                                              75200019
ENABLE   DC    X'FF'                                                    75400019
*********************************************************************** 75600019
         DS    0F                                                       75800019
OVFLWMSG DC    AL1(0)                                                   76000019
         DC    AL1(32)                                                  76200019
         DC    AL2(0)                                                   76400019
         DC    C'IEF405I   SYSJOBQE OVERFLOWED   '                      76600019
*********************************************************************** 76800019
         DS    0F                                                       77000019
IOERRMSG DC    AL1(0)                                                   77200019
         DC    AL1(40)                                                  77400019
         DC    AL2(0)                                                   77600019
         DC    C'IEF400W  ERROR IN SCHEDULER WORK AREA   '              77800019
         EJECT                                                          78000019
         XDAP  QMECB,RI,QMECB,,,,,MF=L                                  78200019
QMPTE    EQU   *                                                        78400019
QIOBL    EQU   QMPTE-QMECB                                              78600019
         EJECT                                                          78800019
         IEFQMNGR                                                       79000019
         EJECT                                                          79200019
QJOB     DSECT                                                          79400019
SCALADCB DS    F                   QMNGR DCB                            79600019
         DS    12F                                                      79800019
SCADEB   DS    12F                 QMNGR DEB                            80000019
SCATALLY DS    F                   TTR0 FOR ASSIGN                      80200019
SCASTRKS DS    H                   TT OF FIRST JOBQ TRACK               80400019
SCALTRKS DS    H                   TT OF LAST TRACK IN QMNGR EXTENT     80600019
SCARECPT DS    C                   NO. OF FIXED LENGTH RECORDS WITH     80800019
*                                    WHICH TRACK IS FORMATTED           81000019
         DS    CL2                 INTERPRETER SWITCHES                 81200019
         END                                                            81400019
