 TITLE 'IEFXQM00 - TRANSIENT QUEUE MANAGER INITIALIZATION,READ/WRITE MOX00100019
               DULE'                                              M2973 00200019
IEFXQM00 CSECT                                                          00300019
*C 552000,648000,654100,844000,085000,644000                      21016 00310021
*A 654500-656000,648500-649900                                    21016 00320021
*A389000,790800-794800,834600-835200                             S20033 00330020
* 298000,318000-326000,406000-454000,604000-630000               S20201 00350020
*D792000-794000                                                  S20033 00360020
* A282500,283000,  C304500,306000,308000                         A48880 00370021
*********************************************************************** 00400019
*********************************************************************** 00600019
*                                                                     * 00800019
*         MODULE IGC00090 - TRANSIENT QUEUE MANAGER INITIALIZATION,   * 01000019
*                           READ/WRITE ROUTINE                        * 01200019
*                                                                     * 01400019
*********************************************************************** 01600019
*********************************************************************** 01800019
*                                                                     * 02000019
*STATUS- CHANGE LEVEL 000                                             * 02200019
*                                                                     * 02400019
*FUNCTIONS- (1)CONTROL- TO BRANCH TO THE APPROPRIATE TRANSIENT QUEUE  * 02600019
* MANAGER ROUTINE(S),DETERMINED BY THE FUNCTION CODE SPECIFIED BY     * 02800019
* THE CALLER.                                                         * 03000019
*           (2)READ/WRITE- TO PERFORM THE CONVERSION OF A TTR TO AN   * 03200019
* MBBCCHHR AND TO EITHER READ OR WRITE UP TO 15 RECORDS OF THE        * 03400019
* QUEUE MANAGER EXTENT.                                               * 03600019
*           (3)ASSIGN/START-TO INITIALIZE AN ECB/IOB FOR THE CALLER   * 03800019
* AND TO PREPARE THE QUEUE MANAGER PARAMETER AREA FOR THE ASSIGN      * 04000019
* FUNCTION WHICH WILL PERFORM ACTUAL RECORD ASSIGNMENT(S).            * 04200019
*                                                                     * 04400019
*ENTRY POINT- IGC00090        FROM- SVC INTERRUPT HANDLER             * 04600019
*                                                                     * 04800019
*INPUT- A QUEUE MANAGER PARAMETER AREA,POINTED TO BY REGISTER 1.      * 05000019
* AN ECB/IOB POINTED TO BY THE PARAMETER AREA.                        * 05200020
* IF READ OR WRITE SPECIFIED:AN EXTERNAL PARAMETER LIST CONTAINING    * 05600019
* A CORE ADDRESS AND A TTR FOR EACH RECORD TO BE READ OR WRITTEN.     * 05800019
*                                                                     * 06600019
*OUTPUT- CONTROL FUNCTION=NONE,WRITE FUNCTION=NONE,READ FUNCTION=THE  * 06800019
* APPROPRIATE RECORDS IN THE CORE AREAS SPECIFIED BY THE CALLER.      * 07000019
* ASSIGN/START FUNCTION=A CORE AREA CONTAINING AN ECB/IOB FOR THE     * 07200019
* CALLER'S I/O ON SUBSEQUENT ENTRIES TO TRANSIENT QUEUE MANAGER       * 07400019
* ROUTINES. THE ADDRESS OF THE ECB/IOB IN THE PARAMETER AREA,AND THE  * 07600019
* PARAMETER AREA SET UP FOR THE ASSIGN FUNCTION.                      * 07800019
*                                                                     * 08000019
*EXTERNAL REFERENCES- REGISTER 3 POINTS TO THE CVT WHICH IS USED      * 08200020
* TO OBTAIN THE Q MNGR RESIDENT CORE AREA AND THE ENTRY POINT OF THE  * 08400019
* SUPERVISOR CONVERT ROUTINE AND THE SUPERVISOR SECTOR CONVERT ROUTINE* 08600020
* WHICH ALSO POINTS TO ANOTHER SECTOR CONVERT ROUTINE.                * 08650020
* REGISTER 5 POINTS TO THE SVRB WHICH CONTAINS THE PROTECT KEY.       * 08700020
* IF READ OR WRITE SPECIFIED,THE CALLER'S ECB/IOB.                    * 08800019
*                                                                     * 09000019
         EJECT                                                          09200019
* THE QUEUE MANAGER PARAMETER AREA,POINTED TO BY REGISTER 1.          * 09400019
* FIELDS IN THE PARAMETER AREA WHICH ARE REFERENCED ARE-              * 09600019
*        (1) A FUNCTION CODE AT DISP + 8 (QMPOP)                      * 09800019
*        (2) AT DISP + 28 A BYTE CONTAINING SWITCHES                  * 10000019
*            (A)X'40' MEANS THAT THE ECB/IOB PASSED BY THE CALLER     * 10200020
*              MUST BE INITIALIZED                                    * 10800019
*            (B)X'20' MEANS THAT THE CALLER WILL ISSUE WAIT FOR       * 11000020
*              COMPLETION OF I/O OPERATIONS.                          * 11200019
*        (3) AT DISP + 29 A 3 BYTE PT TO AN ECB/IOB                   * 11400019
*        (4) AT DISP + 32 THE 4 LOW-ORDER BITS INDICATE THE NUMBER OF * 11600019
*        READ OR WRITE OPERATIONS REQUESTED                           * 11800019
*        (5) AT DISP + 33 A 3 BYTE PT TO AN 8 BYTE ELEMENT,THE FIRST  * 12000019
*        4 BYTES OF WHICH CONTAIN A PT TO THE AREA IN CORE TO OR FROM * 12200019
*        WHICH THE RECORD IS TO BE READ OR WRITTEN,THE NEXT 3 BYTES   * 12400019
*        OF WHICH CONTAIN THE TTR OF THE RECORD,AND THE LAST BYTE OF  * 12600019
*        WHICH IS 0.                                                  * 12800019
*                                                                     * 13000019
*   NOTE-(1),(2),(3),(4),AND(5) ABOVE ARE PROVIDED BY THE CALLER IN   * 13200019
*        ORDER TO PERFORM A READ OR WRITE FUNCTION. SINCE UP TO 15    * 13400019
*        RECORDS CAN BE READ OR WRITTEN,DISP + 33 IN THE CALLER'S     * 13600019
*        QMPA MAY POINT TO A LIST OF 1 TO 15 8-BYTE ELEMENTS.         * 13800020
*        ONLY (1) MUST BE PROVIDED TO PERFORM AN ASSIGN/START.        * 14600019
*                                                                     * 14800019
*EXITS- IGC01090 - IF REQUEST IS FOR ASSIGN FUNCTION,OR NORMAL RETURN * 15000019
*                  CODE IS GIVEN FROM ASSIGN/START OR WRITE/ASSIGN.   * 15200019
*       IGC03090 - IF REQUEST IS FOR ENQUEUE FUNCTION.                * 15250020
*       RETURN TO CALLER VIA REGISTER 14                              * 15400019
*                                                                     * 15600019
*ERROR CODES- SPECIFIED IN REGISTER 15, 0= NORMAL RETURN              * 15800019
*                                       8= CALLER NOT IN PROTECT KEY 0* 16000019
*                                       12= I/O ERROR                 * 16200019
*                                                                     * 17000019
*TABLES/WORK AREAS- QUEUE MANAGER PARAMETER AREA,QUEUE MANAGER        * 17200019
* RESIDENT CORE AREA,CALLER'S ECB/IOB.                                * 17400019
*                                                                     * 17600019
*ATTRIBUTES- REENTRANT                                                * 17800019
*                                                                     * 18000019
*********************************************************************** 18200019
         EJECT                                                          18400019
*********************************************************************** 18600019
*                                                                     * 18800019
*                           REGISTER EQUATES                          * 19000019
*                                                                     * 19200019
*********************************************************************** 19400019
R0       EQU   0                                                        19600019
R1       EQU   1                                                        19800019
R2       EQU   2                                                        20000019
R3       EQU   3                                                        20200019
R4       EQU   4                                                        20400019
R5       EQU   5                                                        20600019
R6       EQU   6                                                        20800019
R7       EQU   7                                                        21000019
R8       EQU   8                                                        21200019
R9       EQU   9                                                        21400019
R10      EQU   10                                                       21600019
R11      EQU   11                                                       21800019
R12      EQU   12                                                       22000019
R13      EQU   13                                                       22200019
R14      EQU   14                                                       22400019
R15      EQU   15                                                       22600019
*********************************************************************** 22800019
D0       EQU   0                                                        23000019
D4       EQU   4                                                        23200019
D5       EQU   5                                                        23400019
D8       EQU   8                                                        23600019
D12      EQU   12                                                       23800019
D24      EQU   24                                                       24000019
D43      EQU   43                                                       24200019
D116     EQU   116                                                      24400019
L3       EQU   3                                                        24600019
L8       EQU   8                                                        24800019
L16      EQU   16                                                       25000019
*********************************************************************** 25200019
         BALR  R8,D0               ESTABLISH ADDRESSABILITY             25400019
         USING *,R8                                                     25600019
*  THIS SECTION OF CODE IS FOR DUMP RECOGNITION ONLY                    25800019
         B     XQMGO                                                    26000019
         DC    X'CCCC'                                                  26200019
         DC    C'IEFXQM00'                                              26400019
         DC    C'10101969'                                              26600019
         DC    X'CCCC'                                                  26800019
XQMGO    DS    0H                                                       27000019
         EJECT                                                          27200019
*********************************************************************** 27400019
*                                                                     * 27600019
*                     TEST FOR PROTECTION KEY 0                       * 27800019
*                                                                     * 28000019
*********************************************************************** 28200019
RBLNK     EQU   X'1C'                                            A48880 28250021
NOTZERO   EQU   5                                                A48880 28300021
QMRES    EQU   12                                                       28400019
PROTKEY  EQU   17                                                       28600019
RETADDR  EQU   0                                                        28800019
SVRBPT   EQU   4                                                        29000019
LNGTH1   EQU   12                                                 M3698 29100019
WKAREA1  EQU   16                                                       29200019
ZERO     EQU   X'F0'                                                    29400019
*********************************************************************** 29600019
IOBINIT  EQU   X'40'                                                    30000019
*********************************************************************** 30200019
         SSM   ENABLE              ENABLE INTERRUPTS                    30400019
         L     R4,RBLNK(R5)        SET R4 TO CALLER RB           A48880 30450021
         TM    PROTKEY(R4),ZERO    IS CALLER'S PROTECT KEY 0     A48880 30600021
         BC    NOTZERO,NOTSUPV     NO-SET PROPER RETURN CODE     A48880 30800021
         LR    R4,R1                                                    31000019
         USING IOPARAMS,R4         ADDRESSABILITY FOR QMPA              31200019
         L     R3,QMRES(R3)                                             31400019
         USING QMRCAR,R3           ADDRESSABILITY FOR RESIDENT CORE     31600019
         L     R2,QMEIA            ECB/IOB PT                    S20201 31800020
         EJECT                                                          33000019
*********************************************************************** 33200019
*                                                                     * 33400019
*                    GET CORE FOR INTERNAL WORK AREA                  * 33600019
*                                                                     * 33800019
*********************************************************************** 34000019
         LA    R1,SP255            GET CORE FORM SUBPOOL 255     S20201 34050020
         SLL   R1,D24              SHIFT TO HIGH-ORDER BYTE       M3698 34100019
         LA    R0,WKAREA1          LENGTH OF WORK AREA            M3698 34150019
         OR    R0,R1               PUT S.P. AND LENGTH INTO REG0  M3698 34200019
         LR    R6,R0               SAVE S.P. AND LENGTH           M3698 34250019
         GETMAIN R,LV=(0)          GET CORE FOR WORK AREA         M3698 34300019
         XC    D0(WKAREA1,R1),D0(R1) ZERO OUT GOTTEN CORE               34400019
         ST    R14,RETADDR(R1)     SAVE RETURN ADDRESS                  34600019
         LA    R5,D0(R5)           CLEAR HIGH-ORDER BYTE                34800019
         ST    R5,SVRBPT(R1)       SAVE SVRB PT                         35000019
         ST    R6,LNGTH1(R1)       SAVE S.P. AND LENGTH           M3698 35100019
         LR    R6,R1               PT TO GOTTEN CORE                    35200019
         TM    QMEIA,IOBINIT       IS ECB/IOB CORE PASSED BY CALLER     35400019
*                                    TO BE INITIALIZED                  35600019
         BNO   XQM30               NO-DETERMINE REQUESTED FUNCTION      35800019
         BAL   R9,AGST20           YES-BR TO INITIALIZE ECB/IOB         36000019
*********************************************************************** 36200019
*                                                                     * 36400019
*                    DETERMINE REQUESTED FUNCTION                     * 36600019
*                                                                     * 36800019
*********************************************************************** 37000019
XQM30    SR    R15,R15             CLEAR REGISTER FOR FUNCTION CODE     37200019
         IC    R15,QMPOP           LOAD FUNCTION CODE                   37400019
         SLL   R15,2               MULTIPLY FUNCTION CODE BY 4 AND      37600019
         B     BRNCHTAB(R15)         BR TO PERFORM APPROPRIATE FUNCTION 37800019
BRNCHTAB B     AGST10              ASSIGN/START                         38000019
         B     ASGQ                ASSIGN                               38200019
         B     RDWR00              WRITE/ASSIGN                         38400019
         B     RDWR00              WRITE                                38600019
         B     RDWR00              READ                                 38800019
         B     ASGQ                ENQUEUE                        20033 38900020
         EJECT                                                          39000019
*********************************************************************** 39200019
ECBPT    EQU   8                                                 S20201 39250020
MASK     EQU   X'0F'                                                    39400019
*********************************************************************** 39600019
RDWR00   L     R7,QMPCL            EXTERNAL PARAMETER AREA PT           39800019
         LA    R1,MASK             MASK TO CLEAR UNUSED BITS            40000019
         IC    R5,QMPNC            NO. OF RECORDS TO READ OR WRITE      40200019
         NR    R5,R1               CLEAR UNUSED BITS                    40400019
         ST    R2,ECBPT(R6)        SAVE ECB/IOB PT               S20201 40600020
         EJECT                                                          45800019
*********************************************************************** 46000019
*                                                                     * 46200019
*                    CONVERSION OF TTR TO MBBCCHHR                    * 46400019
*                                                                     * 46600019
*********************************************************************** 46800019
CNVTQ    EQU   4                                                 S20201 46850020
CVTPT    EQU   16                                                       47000019
QMSPCV   EQU   28                                                       47200019
READ     EQU   4                                                        47400019
RPSON    EQU   X'10'                                             S20201 47450020
SECT     EQU   X'4C'                                             S20201 47500020
XQMSKAD  EQU   36                                                       47600019
*********************************************************************** 47800019
RDWR10   L     R0,D4(R7)           LOAD RECORD TTR0                     48000019
         TM    QMRPS,RPSON         IS Q ON AN RPS DEVICE         S20201 48050020
         BNO   RDWR15              NO-BR TO CONTINUE             S20201 48100020
         L     R15,CVTPTR          YES-GET CVT PT                S20201 48150020
         USING CVTD,R15            ADDRESSABILITY FOR CVT        S20201 48160020
         L     R15,CVT0SCR1        SUPERVISOR SECTOR CONVERT     S20201 48170020
         DROP  R15                   ROUTINE ADDRESS             S20201 48180020
         L     R15,CNVTQ(R15)      SECTOR CONVERT ROUTINE ADDR   S20201 48190020
         BALR  R14,R15             BR TO CONVERT SECTOR ROUTINE  S20201 48192020
         L     R11,ECBPT(R6)       RESTORE ECB/IOB PT            S20201 48194020
         LA    R11,SECT(R11)       PLACE DEVICE TYPE CODE AND    S20201 48196020
         SLL   R11,D8                ADDR OF WHERE TO SAVE       S20201 48198020
         LH    R10,QMRPS             SECTOR INTO REGISTER TWO    S20201 48198420
         SRDL  R10,D8                FOR SECTOR CONVERT ROUTINE  S20201 48198820
         LR    R2,R11                                            S20201 48199220
         L     R15,CVTPTR          CVT PT                        S20201 48199620
         USING CVTD,R15            ADDRESSABILITY FOR CVT        S20201 48199720
         L     R15,CVT0SCR1        SUPERVISOR SECTOR CONVERT     S20201 48199820
         DROP  R15                   ROUTINE ADDRESS             S20201 48199920
         BALR  R14,R15             BR TO SUPERVISOR CONVERT      S20201 48249920
*                                    SECTOR ROUTINE              S20201 48259920
         L     R2,ECBPT(R6)        RESTORE ECB/IOB PT            S20201 48269920
         L     R0,D4(R7)           RESTORE TTR                   S20201 48279920
RDWR15   LA    R2,XQMSKAD(R2)      IOBSEEK FLD FOR MBBCCHHR      S20201 48299920
         LA    R1,QMRDEB           RESIDENT DEB ADDRESS                 48400019
         L     R15,CVTPT           CVT PT                               48600019
         L     R15,QMSPCV(R15)     SUPERVISOR CONVERT ROUTINE ADDRESS   48800019
         BALR  R14,R15             BR TO CONVERT TTR TO MBBCCHHR        49000019
         L     R2,ECBPT(R6)        RESTORE ECB/IOB PT                   49200019
         LA    R11,SECT(R2)        GET SECTOR ADDR               S20201 49250020
         L     R9,D0(R7)           RECORD CORE ADDRESS                  49400019
         TM    QMPOP,READ          IS THIS A READ FUNCTION              49600019
         BZ    RDWR20              NO-BR TO WRITE A RECORD              49800019
 EJECT                                                                  49850020
*********************************************************************** 50000019
*                                                                     * 50200019
*                        READ OR WRITE A RECORD                       * 50400019
*                                                                     * 50600019
*********************************************************************** 50800019
         XDAP  (2),RI,(3),(9),176,,,(11),MF=E  YES-READ A RECORD S20201 51000020
         B     RDWR30              BR TO WAIT FOR I/O COMPLETION        51200019
RDWR20   XDAP  (2),WI,(3),(9),176,,,(11),MF=E     WRITE A RECORD S20201 51400020
         EJECT                                                          51600019
*********************************************************************** 51800019
*                                                                     * 52000019
*                      WAIT FOR I/O COMPLETION                        * 52200019
*                                                                     * 52400019
*********************************************************************** 52600019
IOERR    EQU   12                                                       52800019
NORMALIO EQU   X'7F'                                                    53000019
NOWAIT   EQU   X'20'                                                    53200019
*********************************************************************** 53400019
RDWR30   TM    QMEIA,NOWAIT        IS WAIT FOR I/O COMPLETION TO BE     53600019
*                                    DONE BY CALLER                     53800019
         BO    RDWR40              YES-BR TO TEST FOR MORE REQUESTS     54000019
         LR    R1,R2               NO-ECB/IOB PT                        54200019
         LA    R1,D0(R1)           CLEAR HIGH-ORDER BYTE OF REG 1       54400019
         WAIT  1,ECB=(1)           WAIT FOR I/O COMPLETION              54600019
         CLI   D0(R2),NORMALIO     IS I/O COMPLETION NORMAL             54800019
         BE    RDWR40              YES-BR TO TEST FOR ADDITIONAL I/O    55000019
         IC    R15,D0(R2)          NO-SAVE IOS RETURN CODE        21016 55200021
         B     RDWR60              BR TO WRITE MESSAGE TO CONSOLE       55400019
*********************************************************************** 55600019
*                                                                     * 55800019
*                  TEST FOR MORE RECORDS TO BE READ OR WRITTEN        * 56000019
*                                                                     * 56200019
*********************************************************************** 56400019
WRTASGN  EQU   2                                                        56600019
*********************************************************************** 56800019
RDWR40   LA    R7,D8(R7)           INCREMENT EXTERNAL PARAMETER AREA PT 57000019
         BCT   R5,RDWR10           IF MORE RECORDS ARE TO BE     S20201 57200020
*                                    READ OR                     S20201 57250020
*                                    WRITTEN-BR TO CONTINUE             57400019
         SR    R15,R15             SET NORMAL RETURN CODE               57600019
         CLI   QMPOP,WRTASGN       IS THIS A WRITE/ASSIGN REQUEST       57800019
         BE    ASGQ                YES-BR TO ASSIGN FUNCTION            58000019
         EJECT                                                          58200019
*********************************************************************** 58400019
*                                                                     * 58600019
*                           RETURN TO CALLER                          * 58800019
*                                                                     * 59000019
*********************************************************************** 59200019
FREE     L     R14,RETADDR(R6)     LOAD RETURN ADDRESS                  59400019
         LR    R5,R15              SAVE RETURN CODE               M5318 59450020
         LR    R1,R6               PT TO GOTTEN CORE                    59600019
         L     R0,LNGTH1(R1)       S.P. AND LENGTH OF WORK AREA   M3698 59700019
         FREEMAIN R,LV=(0),A=(1)   FREE WTP WORK AREA CORE        M3698 59800019
         LR    R15,R5              RESTORE RETURN CODE            M5318 59850020
         LR    R1,R4               RESTORE QMPA PT                      60000019
RDWR50   RETURN RC=(15)            RETURN TO CALLER                     60200019
         EJECT                                                          63200019
*********************************************************************** 63400019
*                                                                     * 63600019
*                       WRITE I/O ERROR MESSAGE                       * 63800019
*                                                                     * 64000019
*********************************************************************** 64200019
ERRMSGLN EQU   66                                                 21016 64400021
MFT      EQU   X'20'                                                    64600019
WTOBUF   EQU   72                                                 21016 64800021
D59      EQU   59                   OFFSET INTO MESSAGE TEXT      21016 64900021
D60      EQU   60                   OFFSET INTO MESSAGE TEXT      21016 64950021
D68      EQU   68                   OFFSET INTO MESSAGE TEXT      21016 64952021
LEN3     EQU   3                    LENGTH FOR UNPACK INSTR       21016 64960021
LEN2     EQU   2                    LENGTH FOR TRANSLATE INSTR    21016 64970021
CVRTAB   DC    C'0123456789ABCDEF'  TRANSLATE TABLE ADDRESS       21016 64990021
TRTAB    EQU   CVRTAB-240           TRANSLATE TABLE ADDRESS       21016 64992021
*********************************************************************** 65000019
RDWR60   GETMAIN R,LV=WTOBUF       GET CORE FOR WTO BUFFER              65200019
         LA    R2,XQMWTO           ADDRESS OF I/O ERROR MESSAGE         65400019
         MVC   D0(ERRMSGLN,R1),D0(R2) PUT I/O ERROR MESSAGE INTO BUFFER 65410021
         STC   R15,D59(R1)         SAVE RET CODE IN MSG BUFFER    21016 65450021
         UNPK  D68(LEN3,R1),D59(LEN2,R1) PREPARE FOR TRANSLATE    21016 65500021
         TR    D68(LEN2,R1),TRTAB     CONVERT CODE TO PRINT. HEX  21016 65550021
         MVC   D60(LEN2,R1),D68(R1) MOVE RET CODE INTO MSG TEXT   21016 65560021
         MVI   D59(R1),X'40'       BLANK CHAR. BEFORE RET CODE    21016 65600021
         L     R5,CVTPT            CVT PT                               65800019
         L     R10,D0(R5)          PT TO NEXT,CURRENT TCB PT            66000019
         L     R11,D4(R10)         TCB ADDRESS OF CURRENT TASK          66200019
         TM    D116(R5),MFT        IS THIS AN MFT SYSTEM                66400019
         BO    RDWR70              YES-BR TO WRITE ERROR MESSAGE        66600019
         LA    R11,D0(R11)         CLEAR HIGH-ORDER BYTE OF TCB PT      66800019
         L     R10,D12(R11)        TIOT PT                              67000019
         MVC   D43(L16,R1),D0(R10) MOVE JOB AND STEP NAMES INTO BUFFER  67200019
RDWR70   LR    R5,R1               SAVE PT TO GOTTEN CORE               67400019
         WTO   MF=(E,(1))          WTO-IEF440I                          67600019
         LR    R1,R5               PT TO WTO BUFFER                     67800019
         FREEMAIN R,LV=WTOBUF,A=(R1) FREE WTO BUFFER                    68000019
         LA    R15,IOERR           I/O ERROR RETURN CODE                68200019
         B     FREE                BR TO RETURN TO CALLER               68400019
         EJECT                                                          68600019
*********************************************************************** 68800019
*                                                                     * 69000019
*                         GET CORE FOR ECB/IOB                        * 69200019
*                                                                     * 69400019
*********************************************************************** 69600019
SP255    EQU   255                                                M3698 69800019
*********************************************************************** 70000019
AGST10   LA    R9,AGST30           PT TO CONTINUE ASSIGN/START          70200019
         LA    R0,QIOBL+12         LENGTH OF ECB/IOB + 4 FOR     S20201 70400020
*                                    SUBPOOL NO AND LENGTH AND   S20201 70450020
*                                    8 FOR SECTOR                S20201 70500020
         LA    R14,SP255           GET CORE FROM SUBPOOL 255      M3698 70600019
         SLL   R14,D24             SHIFT NO. TO HIGH-ORDER BYTE         70800019
         OR    R0,R14              PUT SUBPOOL NO. AND LENGTH INTO REG0 71000019
         LR    R12,R0              SAVE SUBPOOL NO. AND LENGTH          71200019
         GETMAIN R,LV=(0)          GET CORE FOR ECB/IOB                 71400019
         ST    R12,D0(R1)          SAVE SUBPOOL NO. AND LENGTH          71600019
*                                    OF ECB/IOB                         71800019
         LA    R2,D4(R1)           ECB/IOB PT                           72000019
         ST    R2,QMEIA            PUT ECB/IOB PT INTO QMPA             72200019
 EJECT                                                                  72250020
*********************************************************************** 72400019
*                                                                     * 72600019
*                      INITIALIZATION OF ECB/IOB                      * 72800019
*                                                                     * 73000019
*********************************************************************** 73200019
QIOBB    EQU   20                                                S20201 73400020
QIOBC    EQU   44                                                S20201 73450020
QIOBD    EQU   52                                                S20201 73500020
QIOBE    EQU   61                                                S20201 73550020
QIOBF    EQU   3                                                 S20201 73600020
QIOBG    EQU   39                                                S20201 73650020
QIOBH    EQU   60                                                S20201 73700020
QMOPC1   EQU   X'08'                                             S20201 73750020
XQMECBPT EQU   8                                                        74000019
XQMOP    EQU   X'31'                                                    74200019
*********************************************************************** 74400019
AGST20   MVC   D0(QIOBL,R2),QMECB  INITIALIZE ECB/IOB                   74600019
         ST    R2,XQMECBPT(R2)     PUT ECB PT INTO IOB                  74800019
         TM    QMRPS,RPSON         IS RPS PRESENT                S20201 75000020
         BNO   AGST25              NO-BR TO CONTINUE             S20201 75050020
         LA    R1,QIOBC(R2)        YES-PUT SET SECTOR ADDR       S20201 75100020
         ST    R1,QIOBB(R2)          INTO CCW1 PT                S20201 75150020
         LA    R1,QIOBD(R2)        PUT CCW1 PT                   S20201 75200020
         ST    R1,QIOBH(R2)          INTO CCW2 AND SET           S20201 75250020
         OI    QIOBH(R2),QMOPC1      CCW2 OP CODE BYTE           S20201 75300020
         B     SETSEEK             BR TO CONTINUE                S20201 75350020
AGST25   LA    R1,QIOBD(R2)        PUT CCW1 PT                   S20201 75400020
         ST    R1,QIOBB(R2)          INTO IOB                    S20201 75450020
         MVC   QIOBE(QIOBF,R2),QIOBB+1(R2)       AND INTO CCW2   S20201 75500020
SETSEEK  LA    R1,QIOBG(R2)        PUT PT TO IOBSEEK FLD + 3     S20201 75550020
         ST    R1,QIOBD(R2)          INTO CCW1                   S20201 75600020
         OI    QIOBD(R2),XQMOP     SET CCW1 OP CODE BYTE         S20201 75650020
         BR    R9                  BR TO CONTINUE                       76200019
AGST30   XC    QMTID(2),QMTID      SET CURRENT NN FLD TO ZERO           76400019
         MVC   QMTST(1),QMLPT+1    FAKE TOTAL ASSIGNMENT OF TRACK       76600019
         B     ASGQ                BR TO ASSIGN FUNCTION                76800019
         EJECT                                                          77000019
*********************************************************************** 77200019
*                                                                     * 77400019
*                 TRANSFER CONTROL TO ASSIGN FUNCTION                 * 77600019
*                                                                     * 77800019
*********************************************************************** 78000019
HEX60    EQU   X'60'                                                    78200019
HEX68    EQU   X'68'                                                    78400019
*********************************************************************** 78600019
ASGQ     L     R9,SVRBPT(R6)       PT TO SVRB                           78800019
         XC    HEX60(L16,R9),HEX60(R9) CLEAR EXTENDED SAVE AREA         79000019
         C    R15,TWENTY           IS THIS AN ENQUEUE             20033 79080020
         BNE   ASGQ2               NO-BR TO ASSIGN                20033 79160020
         MVC   HEX68(L8,R9),MNQQNAME SET UP NAME FOR XCTL         20033 79240020
         B     GOON                BR TO CONTINUE                 20033 79320020
ASGQ2    MVC   HEX68(L8,R9),ASGQNAME SET UP NAME FOR XCTL         20033 79400020
GOON     LA    R15,HEX68(R9)       PT TO ENTRY PT OF MODULE       20033 79480020
         ST    R15,HEX60(R9)       STORE ENTRY PT ADDRESS               79600019
         LA    R15,HEX60(R9)       SET UP REG 15 FOR XCTL               79800019
         XCTL  SF=(E,(15))         XCTL TO ASSIGN LOAD                  80000019
*********************************************************************** 80200019
*                                                                     * 80400019
*           SET ERROR CODE - CALLER NOT IN PROTECTION KEY 0           * 80600019
*                                                                     * 80800019
*********************************************************************** 81000019
KEYERR   EQU   8                                                        81200019
*********************************************************************** 81400019
NOTSUPV  LA    R15,KEYERR          SET RETURN CODE FOR CALLER NOT IN    81600019
         B     RDWR50                PROTECTION KEY 0 AND BR TO RETURN  81800019
         EJECT                                                          82000019
*********************************************************************** 82200019
*                                                                     * 82400019
*                              CONSTANTS                              * 82600019
*                                                                     * 82800019
*********************************************************************** 83000019
         DS    0F                                                       83200019
ASGQNAME DC    C'IGC0109{'                                              83400019
MNQQNAME DC    C'IGC0309{'                                        20033 83460020
TWENTY   DC    F'20'                                              20033 83520020
ENABLE   DC    X'FF'                                                    83600019
*********************************************************************** 83800019
         DS    0F                                                       84000019
XQMWTO   DC    AL1(0)                                                   84200019
         DC    AL1(62)                                            21016 84400021
         DC    X'8000'                                            21016 84600021
         DC    C'IEF440I I/O ERROR IN SYS1.SYSJOBQE FOR '               84800019
         DC    C'                   '                             21016 85000021
         DC    B'0001000000000000'                                      85200019
         DC    B'0100000001000000'                                      85400019
*********************************************************************** 85600019
         EJECT                                                          85800019
         XDAP  QMECB,RI,QMECB,,,,,QMECB,MF=L     ECB/IOB PATTERN S20201 86000020
QMPTE    EQU   *                   END OF PATTERN ECB/IOB               86200019
QIOBL    EQU   QMPTE-QMECB         LENGTH OF ECB/IOB                    86400019
         EJECT                                                          86600019
         IEFQMNGR                                                       86800019
QMCAP    EQU   IOPARAMS+24         PT TO STACK AND Q-BREAK INFORMATION  87000019
         EJECT                                                          87200019
QMRCAR   DSECT                                                          87400019
         IEFQMRES                                                       87600019
 EJECT                                                                  87650020
CVTD     DSECT                                                   S20201 87700020
         CVT                                                     S20201 87750020
         END                                                            87800019
