 TITLE 'IEFXQM01 - TRANSIENT QUEUE MANAGER ASSIGN TRACKS MODULE'  M2973 00060019
IEFXQM01 CSECT                                                          00120019
* A 180100-180500,184500                                        SA68340 00130021
*                                                                       00140021
* 418000-419000,421000,426000,446000,449000                       M2067 00160020
*********************************************************************** 00200019
*********************************************************************** 00300019
*                                                                     * 00400019
*   MODULE IGC01090 - TRANSIENT QUEUE MANAGER ASSIGN TRACKS ROUTINE   * 00500019
*                                                                     * 00600019
*********************************************************************** 00700019
*********************************************************************** 00800019
*                                                                     * 00900019
*STATUS- CHANGE LEVEL 000                                             * 01000019
*                                                                     * 01100019
*FUNCTION- TO ALLOCATE NEW LOGICAL TRACKS FROM THE QUEUE MANAGERS     * 01200019
* 'NULL' LIST IF THE CURRENT LOGICAL TRACK DOES NOT CONTAIN ENOUGH    * 01300019
* RECORDS TO SATISFY A REQUEST. IF AN INITIATOR IS ASSIGNING TRACKS   * 01400019
* FOR A JOB AND IT USES MORE TRACKS THAN ARE RESERVED FOR AN INITIATOR* 01500019
* THE JOB IS CANCELLED. IF THERE ARE NO AVAILABLE LOGICAL TRACKS,THIS * 01600019
* ROUTINE RETURNS CONTROL TO THE CALLER.                              * 01700019
* WHEN A NEW LOGICAL TRACK IS REQUIRED,IT IS ALLOCATED FROM THE FREE- * 01800019
* TRACK QUEUE AND ITS LTH READ IN VIA AN XDAP MACRO. THEN THE LTH OF  * 01900019
* THE PREVIOUSLY ASSIGNED LOGICAL TRACK IS UPDATED WITH THE TTR OF THE* 02000019
* LTH OF THE NEWLY ASSIGNED LOGICAL TRACK AND WRITTEN OUT VIA XDAP.   * 02100019
* THE LTH OF THE NEWLY ASSIGNED LOGICAL TRACK IS THEN UPDATED WITH A  * 02200019
* ZERO POINTER TO THE LTH OF THE NEXT LOGICAL TRACK(SINCE THERE ARE NO* 02300019
* MORE ASSIGNED) AND ALSO WRITTEN OUT VIA XDAP.                       * 02400019
*                                                                     * 02500019
*ENTRY POINT- IGC01090        FROM- IGC00090- TRANSIENT Q MNGR        * 02600019
*                                   INITIALIZATION,READ/WRITE ROUTINE * 02700019
*                                                                     * 02800019
*INPUT- A QUEUE MANAGER RESIDENT CORE AREA POINTED TO BY REGISTER 3.  * 02900020
* A QUEUE MANAGER PARAMETER AREA POINTED TO BY REGISTER 4.            * 02921520
* A WORK AREA FROM IGC00090, POINTED TO BY REGISTER 6, WHICH CONTAINS * 02943020
* THE RETURN ADDRESS AND SVRB ADDRESS.                                * 02964520
* AN ECB/IOB POINTED TO BY THE PARAMETER AREA.                        * 03000019
* AN EXTERNAL PARAMETER LIST POINTED TO BY THE PARAMETER AREA.        * 03100019
*                                                                     * 03200019
*OUTPUT- AN UPDATED MASTER HANDLE IN RESIDENT CORE.                   * 03300019
*                                                                     * 03400019
         EJECT                                                          03500019
*EXTERNAL REFERENCES- LOCATION 16 TO LOCATE THE C.V.T. WHICH IS USED  * 03600019
* TO OBTAIN THE Q MNGR RESIDENT CORE AREA AND THE ENTRY POINT OF THE  * 03700019
* SUPERVISOR CONVERT ROUTINE.                                         * 03800019
*                                                                     * 03900019
*EXITS- IGC02090 - TO ASSIGN RECORDS FROM A LOGICAL TRACK               04000019
*       RETURN TO CALLER VIA REGISTER 14.                             * 04100019
*                                                                     * 04200019
*ERROR CODES- SPECIFIED IN REGISTER 15, 0= NORMAL RETURN              * 04300019
*                                       4= REQUESTED SPACE UNAVAILABLE* 04400019
*                                       12= I/O ERROR                 * 04500019
*                                                                     * 04600019
*TABLES/WORK AREAS- 56 BYTES OF CORE ARE GOTTEN VIA GETMAIN FOR A     * 04700020
* WORK AREA WHICH IS USED AS FOLLOWS                                  * 04800019
*  BYTES 0-1 - NO. OF RECORDS NOW ASSIGNED                            * 04900019
*  BYTES 2-3 - NO. OF RECORDS TO ASSIGN                               * 05000019
*  BYTES 4-23 - AREA INTO WHICH TO READ LTH                           * 05100019
*  BYTES 24-35 - 6 2-BYTE FIELDS FOR LOGICAL TRACK NN'S               * 05200019
*  BYTES 36-39 - RETURN ADDRESS                                       * 05300019
*  BYTE 40 - INDICATOR SWITCHES                                       * 05400019
*            BIT 0 - USED FOR ERROR RETURN TYPE                 SA66651 05420021
*                    0 = NO SPACE                               SA66651 05440021
*                    1 = I/O ERROR                              SA66651 05460021
*            BIT 5 - MASTER HANDLE ENQUEUED UPON                      * 05500019
*  BYTES 41-43 - PT TO SUPERVISOR REQUEST BLOCK                       * 05600019
*  BYTES 44-47 - LENGTH OF TABLE AND SUBPOOL NO                       * 05700020
*  BYTES 48-51 - TTRSAVE AREA FOR RPS                                 * 05721520
*  BYTES 52-55 - UNUSED                                               * 05743020
*                                                                     * 05800019
* THE Q MNGR PARAMETER AREA AND THE EXTERNAL PARAMETER LIST TO WHICH  * 05900019
* IT POINTS. THE Q MNGR RESIDENT CORE AREA-TO OBTAIN LOGICAL TRACK    * 06000019
* POINTERS. 80 BYTES OF CORE IS OBTAINED AND FREED-THIS CORE IS USED  * 06100019
* TO CANCEL A JOB AND WRITE THE CANCEL MESSAGE.                       * 06200019
*                                                                     * 06300019
* ATTRIBUTES- REENTRANT                                               * 06400019
*                                                                     * 06500019
*********************************************************************** 06600019
         EJECT                                                          06700019
*********************************************************************** 06800019
*                                                                     * 06900019
*                           REGISTER EQUATES                          * 07000019
*                                                                     * 07100019
*********************************************************************** 07200019
R0       EQU   0                                                        07300019
R1       EQU   1                                                        07400019
R2       EQU   2                                                        07500019
R3       EQU   3                                                        07600019
R4       EQU   4                                                        07700019
R5       EQU   5                                                        07800019
R6       EQU   6                                                        07900019
R7       EQU   7                                                        08000019
R8       EQU   8                                                        08100019
R9       EQU   9                                                        08200019
R10      EQU   10                                                       08300019
R11      EQU   11                                                       08400019
R12      EQU   12                                                       08500019
R13      EQU   13                                                       08600019
R14      EQU   14                                                       08700019
R15      EQU   15                                                       08800019
*********************************************************************** 08900019
D0       EQU   0                                                        09000019
D1       EQU   1                                                        09100019
D2       EQU   2                                                        09200019
D4       EQU   4                                                        09300019
D8       EQU   8                                                        09400019
D36      EQU   36                                                       09500019
L2       EQU   2                                                        09600019
L8       EQU   8                                                        09700019
L16      EQU   16                                                       09800019
*********************************************************************** 09900019
         BALR  R8,D0               ESTABLISH ADDRESSABILITY             10000019
         USING *,R8                                                     10100019
*  THIS SECTION OF CODE IS FOR DUMP RECOGNITION ONLY                    10200019
         B     XQMGO                                                    10300019
         DC    X'CCCC'                                                  10400019
         DC    C'IEFXQM01'                                              10500019
         DC    C'10101969'                                              10600019
         DC    X'CCCC'                                                  10700019
XQMGO    DS    0H                                                       10800019
         EJECT                                                          10900019
*********************************************************************** 11000019
*                                                                     * 11100019
*  DETERMINE IF ASSIGN REQUEST MAY BE SATISFIED FROM CURRENT LOGICAL  * 11200019
*         TRACK: YES- BRANCH TO IGC02090 TO ASSIGN RECORDS            * 11300019
*                 NO- OBTAIN NEW LOGICAL TRACKS AS REQUIRED           * 11400019
*                                                                     * 11500019
*********************************************************************** 11600019
NUMASGND EQU   0                                                        11700019
NMTOASGN EQU   2                                                        11800019
RETADDR  EQU   36                                                       11900019
SVRBPT   EQU   40                                                       12000019
WKAREA1  EQU   16                                                       12100019
WKAREA2  EQU   56                                                S20201 12200020
SP255    EQU   255                                                M3698 12220019
LNGTH1   EQU   12                                                 M3698 12240019
LNGTH2   EQU   44                                                 M3698 12260019
D24      EQU   24                                                 M3698 12280019
*********************************************************************** 12300019
         USING IOPARAMS,R4         ADDRESSABILITY FOR QMPA              12400019
         USING QMRCAR,R3           ADDRESSABILITY FOR RESIDENT CORE     12500019
         LA    R1,SP255            GET CORE FROM SUBPOOL 255      M3698 12520019
         SLL   R1,D24              SHIFT TO HIGH-ORDER BYTE       M3698 12540019
         LA    R0,WKAREA2          LENGTH OF WORK AREA            M3698 12560019
         OR    R0,R1               PUT S.P. AND LENGTH INTO REG0  M3698 12580019
         LR    R5,R0               SAVE S.P. AND LENGTH           M3698 12600019
         GETMAIN R,LV=(0)          GET CORE FOR WORK AREA         M3698 12620019
         XC    D0(WKAREA2,R1),D0(R1) ZERO OUT WORK AREA                 12700019
         MVC   RETADDR(L8,R1),D0(R6) MOVE RETURN ADDRESS AND SVRB PT TO 12800019
*                                    GOTTEN CORE                        12900019
         ST    R5,LNGTH2(R1)       SAVE S.P. AND LENGTH           M3698 12950019
         LR    R5,R1               PT TO GOTTEN CORE                    13000019
         LR    R1,R6               PT TO CORE GOTTEN IN IEFXQM00        13100019
         L     R0,LNGTH1(R6)       S.P. AND LENGTH OF WORK AREA   M3698 13160019
         FREEMAIN R,LV=(0),A=(1)   FREE CORE FROM IEFXQM00        M3698 13220019
         LR    R6,R5               PT TO GOTTEN CORE                    13300019
         L     R2,QMEIA            ECB/IOB PT                           13400019
         SR    R10,R10             CLEAR REGISTER                       13500019
         IC    R10,QMPCM           NO. OF RECORDS TO ASSIGN             13600019
         SRDL  R10,D36             PUT NO. TO ASSIGN INTO REG 11        13700019
         ST    R11,NUMASGND(R6)    SAVE NO. TO ASSIGN                   13800019
         IC    R10,QMTST           NO. OF RECORDS NOW ASSIGNED          13900019
         STH   R10,NUMASGND(R6)    SAVE NO. NOW ASSIGNED                14000019
         LA    R0,D0(R10,R11)      ADD NO. ASSIGNED TO NO. REQUESTED    14100019
         LH    R9,QMLPT            NO. OF RECORDS PER LOGICAL TRACK     14200019
         CR    R0,R9               CAN REQUEST BE FULFILLED FROM        14300019
*                                    CURRENT TRACK                      14400019
         BNH   ASGQLD2             YES-BR TO ASSIGN RECORDS             14500019
         EJECT                                                          14600019
         LR    R12,R9              NO. OF RECORDS PER LOGICAL TRACK     14700019
         SR    R12,R10             SUBTRACT NO. OF RECORDS NOW ASSIGNED 14800019
         BZ    ASGQ10              BR IF NO RECORDS AVAILABLE IN        14900019
*                                    CURRENT TRACK                      15000019
         SR    R11,R12             SUBTRACT NO. AVAILABLE IN CURRENT    15100019
*                                    TRACK FROM NO. TO ASSIGN           15200019
ASGQ10   SR    R10,R10             CLEAR REGISTER                       15300019
         DR    R10,R9              DETERMINE NECESSARY NO. OF           15400019
*                                    LOGICAL TRACKS                     15500019
         LTR   R10,R10             IS THERE A REMAINDER                 15600019
         BZ    ASGQ20              NO-BR TO TEST FOR AVAILABLE TRACKS   15700019
         LA    R11,D1(R11)         YES-INCREMENT NO. OF REQUIRED        15800019
*                                    TRACKS BY 1                        15900019
ASGQ20   LR    R7,R11              NO. OF REQUIRED LOGICAL TRACKS       16000019
*********************************************************************** 16100019
*                                                                     * 16200019
*                      ENQUEUE ON MASTER HANDLE                       * 16300019
*                                                                     * 16400019
*********************************************************************** 16500019
ASGQ30   EQU   *                                                        16900019
         LA    R14,IEFSQCBS        PUT PT TO MAJOR NAME                 17000019
         ST    R14,QNAME             INTO PARAMETER LIST                17100019
         LA    R14,IEFQ2QCB        PUT PT TO MINOR NAME                 17200019
         ST    R14,RNAME             INTO PARAMETER LIST                17300019
         ENQ   MF=(E,IEFQASGA)     ENQUEUE ON MASTER HANDLE             17400019
*********************************************************************** 17500019
*                                                                     * 17600019
*             TEST FOR AVAILABLE SPACE TO SATISFY REQUEST             * 17700019
*                                                                     * 17800019
*********************************************************************** 17900019
INIT     EQU   32                                                       17950020
*********************************************************************** 17960020
         LH    R12,QMNOTM          NO. OF AVAILABLE LOGICAL TRACKS      18000019
         L     R11,CVTPTR                                       SA68340 18010021
         USING CVTD,R11                                         SA68340 18015021
         L     R11,CVTTCBP         PT. TO TCB ADDRESSES         SA68340 18020021
         L     R11,D4(,R11)        PT. TO CURRENT TCB           SA68340 18025021
         USING TCB,R11                                          SA68340 18030021
         TM    TCBTSFLG,TCBTSTSK   TEST FOR TSO, IE SUBMIT BRDR SA68340 18035021
         DROP  R11                                              SA68340 18040021
         BO    TSOBYPSS            YES, BYPASS INIT TEST        SA68340 18050021
         TM    QMPRI,INIT          IS REQUEST FROM AN INITIATOR         18100019
         BO    INITREQ             YES-BR TO TEST INITIATOR LIMIT       18200019
         TM    QMPRI,SYSTASK       IS REQUEST FROM SYSTEM TASK          18300019
         BO    TESTSPAC            YES-BR TO TEST FOR AVAILABLE SPACE   18400019
TSOBYPSS EQU   *                                                SA68340 18450021
         SH    R12,QMTBT           NO-SUBTRACT THRESHOLD FROM NO. OF    18500019
*                                    AVAILABLE LOGICAL TRACKS           18600019
         CR    R7,R12              CAN REQUEST BE SATISFIED FROM        18700019
*                                    AVAILABLE TRACKS                   18800019
         LA    R12,DEQOFF          ADDRESS FOR DEQUEUE                  18900019
         BH    SYSTEST             NO-BR TO RETURN TO CALLER            19000019
         EJECT                                                          19100019
*********************************************************************** 19200019
*                                                                     * 19300019
*               ASSIGN FIRST AVAILABLE LOGICAL TRACK                  * 19400019
*                                                                     * 19500019
*********************************************************************** 19600019
FREETRK  EQU   24                                                       19650020
*********************************************************************** 19660020
ASGNPT   LA    R5,FREETRK(R6)      PT TO LOGICAL TRACK NN'S IN WORKAREA 19700019
ASGNTRK  MVC   D0(L2,R5),QMFLTM    PUT NN OF FIRST AVAILABLE LOGICAL    19800019
*                                    TRACK INTO WORK AREA               19900019
         LH    R11,D0(R5)          PUT NN INTO REG 11 FOR CONVERSION    20000019
         LA    R5,D2(R5)           INCREMENT NN PT TO NEXT SLOT         20100019
*********************************************************************** 20200019
*                                                                     * 20300019
*                        CONVERT NN TO TTR                            * 20400019
*                                                                     * 20500019
*********************************************************************** 20600019
CNVTMB10 LA    R9,CNVTMB20         PT TO COMPLETE CONVERSION            20700019
TTRCNVT1 LH    R14,QMKTT           TT OF FIRST TRACK OF ALL             20800019
*                                    LOGICAL RECORDS                    20900019
         SH    R11,QMFQR           SUBTRACT NN OF FIRST RECORD ON TRACK 21000019
*                                    OF ALL LOGICAL RECORDS FROM        21100019
*                                    CURRENT NN                         21200019
         BM    MIXEDTRK            BR IF CURRENT NN ON MIXED TRACK      21300019
         LH    R12,QMRPT           NO. OF RECORDS PER PHYSICAL TRACK    21400019
         SR    R10,R10             CLEAR REGISTER                       21500019
         DR    R10,R12             DIVIDE CURRENT NN BY NO. OF RECORDS  21600019
*                                    PER PHYSICAL TRACK                 21700019
         AR    R11,R14             DETERMINE NEW TT                     21800019
         SLL   R11,D8              SHIFT TT TO PROPER POSITION          21900019
         LA    R11,D1(R10,R11)     TTR=TT + CURRENT NN + 1              22000019
TTRCNVT2 LA    R0,D0(R11)          PUT TTR INTO REG 0                   22100019
         SLL   R0,D8               SHIFT TTR TO PROPER POSITION         22200019
         BR    R9                  BR BACK WITH TTR0 OR BR TO           22300019
*                                    COMPLETE CONVERSION                22400019
MIXEDTRK AH    R11,QMFQR           RESTORE CURRENT NN                   22500019
         AH    R11,QMNHM           ADD NO. OF HANDLES ON MIXED TRACK    22600019
         BCTR  R14,D0              DETERMINE TT ON WHICH CURRENT NN     22700019
*                                    RESIDES                            22800019
         SLL   R14,D8              SHIFT TT TO PROPER POSITION          22900019
         AR    R11,R14             TTR= TT + CURRENT NN                 23000019
         B     TTRCNVT2            BR TO PUT TTR INTO REG 0             23100019
         EJECT                                                          23200019
*********************************************************************** 23300019
*                                                                     * 23400019
*                       CONVERT TTR TO MBBCCHHR                       * 23500019
*                                                                     * 23600019
*********************************************************************** 23700019
CVTPT    EQU   16                                                       23800019
CNVTQ    EQU   4                                                 S20201 23850020
LTHAREA  EQU   4                                                        23900019
QMSPCV   EQU   28                                                       24000019
RPSON    EQU   X'10'                                             S20201 24050020
SECT     EQU   X'4C'                                             S20201 24060020
TTRSAVE  EQU   48                                                S20201 24070020
XQMSKAD  EQU   36                                                       24100019
*********************************************************************** 24200019
CNVTMB20 TM    QMRPS,RPSON         IS Q ON AN RPS DEVICE         S20201 24207020
         BNO   CNVTMB30            NO-BR TO CONTINUE             S20201 24209020
         ST    R0,TTRSAVE(R6)      YES-SAVE TTR                  S20201 24211020
         L     R15,CVTPTR          CVT PT                        S20201 24213020
         USING CVTD,R15            ADDRESSABILITY FOR CVT        S20201 24213420
         L     R15,CVT0SCR1        SUPERVISOR SECTOR CONVERT     S20201 24213820
         DROP  R15                   ROUTINE ADDRESS             S20201 24213920
         L     R15,CNVTQ(R15)      SECTOR CONVERT ROUTINE ADDR   S20201 24214020
         BALR  R14,R15             BR TO CONVERT ROUTINE         S20201 24216020
         L     R11,QMEIA           RESTORE ECB/IOB PT            S20201 24218020
         LA    R11,SECT(R11)       PLACE DEVICE TYPE CODE AND    S20201 24220020
         SLL   R11,D8                ADDR OF WHERE TO SAVE       S20201 24220420
         LH    R10,QMRPS             SECTOR INTO REGISTER TWO    S20201 24220820
         SRDL  R10,D8                FOR SECTOR CONVERT ROUTINE  S20201 24220920
         LR    R2,R11                                            S20201 24221020
         L     R15,CVTPTR          CVT PT                        S20201 24223020
         USING CVTD,R15            ADDRESSABILITY FOR CVT        S20201 24225020
         L     R15,CVT0SCR1        SUPERVISOR SECTOR CONVERT     S20201 24227020
         DROP  R15                   ROUTINE ADDRESS             S20201 24227420
         BALR  R14,R15             BR TO SUPERVISOR CONVERT      S20201 24227820
         L     R0,TTRSAVE(R6)      RESTORE TTR                   S20201 24227920
         L     R2,QMEIA            RESTORE ECB/IOB PT            S20201 24228020
CNVTMB30 LA    R2,XQMSKAD(R2)      PT TO MBBCCHHR IN IOB         S20201 24230020
         LA    R1,QMRDEB           PT TO RESIDENT DEB                   24400019
         L     R15,CVTPT           CVT PT                               24500019
         L     R15,QMSPCV(R15)     PT TO SUPERVISOR CONVERSION ROUTINE  24600019
         BALR  R14,R15             BR TO CONVERT TTR TO MBBCCHHR        24700019
         L     R2,QMEIA            RESTORE ECB/IOB PT                   24800019
         LA    R10,LTHAREA(R6)     NO-PT TO AREA INTO WHICH TO          24900019
*                                    READ AN LTH                        25000019
 EJECT                                                                  25050020
*********************************************************************** 25100019
*                                                                     * 25200019
*                             READ LTH                                * 25300019
*                                                                     * 25400019
*********************************************************************** 25500019
         LA    R11,SECT(R2)        LOAD SECTOR ADDR FOR XDAP     S20201 25560020
         XDAP  (2),RI,(3),(10),20,,,(11),MF=E                    S20201 25570020
         LA    R9,NEWTRK10         PT TO NEW TRACK ROUTINE              25700019
         EJECT                                                          25800019
*********************************************************************** 25900019
*                                                                     * 26000019
*                       WAIT FOR I/O COMPLETION                       * 26100019
*                                                                     * 26200019
*********************************************************************** 26300019
BADIO    EQU   X'80'                                            SA66651 26350021
NORMALIO EQU   X'7F'                                                    26400019
*********************************************************************** 26500019
IOWAIT   LR    R1,R2               ECB/IOB PT                           26600019
         LA    R1,D0(R1)           CLEAR HIGH-ORDER BYTE OF REG 1       26700019
         WAIT  1,ECB=(1)           WAIT FOR I/O COMPLETION              26800019
         CLI   D0(R2),NORMALIO     IS I/O COMPLETION NORMAL             26900019
         BCR   8,R9                YES-BR TO CONTINUE                   27000019
         OI    SWITCHES(R6),BADIO  INDICATE I/O ERROR RETURN    SA66651 27050021
         B     DEQOFF              NO-BR TO DEQ                  S20201 27100020
         EJECT                                                          29000019
*********************************************************************** 29100019
*                                                                     * 29200019
*  THIS SECTION OF CODE GETS CONTROL IF THERE IS NOT ENOUGH AVAILABLE * 29300019
*  SPACE TO SATISFY A REQUEST - IF REQUEST IS FROM A SYSTEM TASK IN   * 29400019
*  AN MVT ENVIRONMENT, A 'QUEUE CRITICAL' MESSAGE IS ISSUED; ELSE,A   * 29500019
*  RETURN CODE IS SET AND CONTROL IS RETURNED TO THE CALLER           * 29600019
*                                                                     * 29700019
*********************************************************************** 29800019
MFT      EQU   X'20'                                                    29900019
*********************************************************************** 30000019
SYSTEST  TM    QMPRI,INIT          IS REQUEST FROM AN INITIATOR         30100019
         BO    DEQOFF              YES-BR TO DEQUEUE OFF MASTER HANDLE  30200019
         L     R5,CVTPTR           CVT PT                               30300019
         USING CVTD,R5             ADDRESSABILITY FOR CVT               30400019
         TM    CVTDCB,MFT          IS THIS AN MFT ENVIRONMENT           30500019
         BZ    D0(R12)             NO-BR TO WRITE MESSAGE AND           30600019
*                                    DEQUEUE OFF MASTER HANDLE          30700019
*********************************************************************** 30800019
*                                                                     * 30900019
*                      DEQUEUE OFF MASTER HANDLE                      * 31000019
*                                                                     * 31100019
*********************************************************************** 31200019
DEQOFF   EQU   *                                                        31300019
         LA    R14,IEFSQCBS        PUT PT TO MAJOR NAME                 31400019
         ST    R14,QNAME             INTO PARAMETER LIST                31500019
         LA    R14,IEFQ2QCB        PUT PT TO MINOR NAME                 31600019
         ST    R14,RNAME             INTO PARAMETER LIST                31700019
         DEQ   MF=(E,IEFQASGA)     DEQUEUE OFF MASTER HANDLE            31800019
         TM    SWITCHES(R6),BADIO  IS IT AN I/O ERROR RETURN    SA66651 31850021
         BZ    NOSPACES           NO,BR. MUST BE OUT OF SPACE   SA66651 31860021
*********************************************************************** 31870020
*                                                                     * 31880020
*                      SET I/O ERROR RETURN CODE                      * 31890020
*                                                                     * 31892020
*********************************************************************** 31894020
IOERR    EQU   12                                                S20201 31896020
*********************************************************************** 31898020
         LA    R7,IOERR            I/O ERROR RETURN CODE         S20201 31898420
         B     RETURN              BR TO EXIT LINKAGE            S20201 31898820
*********************************************************************** 31900019
*                                                                     * 32000019
*                  SET SPACE UNAVAILABLE RETURN CODE                  * 32100019
*                                                                     * 32200019
*********************************************************************** 32300019
NOSPACE  EQU   4                                                        32400019
*********************************************************************** 32500019
NOSPACES LA    R7,NOSPACE          NO SPACE AVAILABLE RETN CODE  S20201 32600020
         B     RETURN              BR TO EXIT LINKAGE                   32700019
         EJECT                                                          32800019
*********************************************************************** 32850020
*                                                                     * 32860020
*                       UPDATE FREE TRACK POINTER                       32870020
*                                                                     * 32880020
*********************************************************************** 32890020
NEWTRK10 MVC   QMFLTM(L2),QMTLN-QMCAN(R10) UPDATE PT TO FIRST LOGICAL   32900019
*                                           TRACK IN FREE TRACK QUEUE   33000019
         CLC   QMFLTM(L2),CH0      IS TOP OF NULL ZERO                  33100019
         BNE   NEWTRK20            NO-BR TO DECREMENT AVAILABLE TRACKS  33200019
         MVC   QMTIDM(L2),CH0      YES-ZERO OUT BOTTOM OF NULL          33300019
*********************************************************************** 33400019
*                                                                     * 33500019
*                  DECREMENT NO. OF AVAILABLE TRACKS                  * 33600019
*                                                                     * 33700019
*********************************************************************** 33800019
NEWTRK20 LH    R15,QMNOTM          NO. OF AVAILABLE LOGICAL TRACKS      33900019
         BCTR  R15,D0              SUBTRACT 1                           34000019
         STH   R15,QMNOTM          RESTORE IN MASTER HANDLE             34100019
         TM    QMPRI,INIT          IS REQUEST FROM AN INITIATOR         34200019
         BZ    NEWTRK30            NO-BR TO DECREMENT TRACK REQUEST     34300019
         L     R11,QMWTQ           YES-TRACK STACK INFORMATION PT       34400019
         LTR   R11,R11             IS PT ZERO                           34500019
         BZ    NEWTRK30            YES-THIS IS A SYSTEM TASK            34600019
         LH    R15,QMTBT           THRESHOLD SIZE                       34700019
         BCTR  R15,D0              SUBTRACT 1                           34800019
         STH   R15,QMTBT           RESTORE IN MASTER HANDLE             34900019
*********************************************************************** 35000019
*                                                                     * 35100019
*            INCREMENT NO. OF TRACKS USED BY AN INITIATOR             * 35200019
*                                                                     * 35300019
*********************************************************************** 35400019
         IC    R15,D4(R11)         NO. OF TRACKS USED BY AN INITIATOR   35500019
         LA    R15,D1(R15)         ADD 1                                35600019
         STC   R15,D4(R11)         RESTORE NO. USED BY INITIATOR        35700019
NEWTRK30 BCT   R7,ASGNTRK          IF MORE LOGICAL TRACK ASSIGNMENTS    35800019
*                                    REQUESTED,BR TO CONTINUE           35900019
*********************************************************************** 36000019
ENQBIT   EQU   X'04'                                                    36100019
SWITCHES EQU   SVRBPT                                                   36150019
*********************************************************************** 36200019
         OI    SWITCHES(R6),ENQBIT SET MASTER HANDLE ENQUEUED UPON BIT  36300019
         EJECT                                                          36400019
*********************************************************************** 36500019
*                                                                     * 36600019
*           TRANSFER CONTROL TO IGC02090 - TO ASSIGN RECORDS          * 36700019
*                                                                     * 36800019
*********************************************************************** 36900019
HEX60    EQU   X'60'                                                    37000019
HEX68    EQU   X'68'                                                    37100019
*********************************************************************** 37200019
ASGQLD2  L     R9,SVRBPT(R6)       PT TO SVRB                           37300019
         XC    HEX60(L16,R9),HEX60(R9) CLEAR EXTENDED SAVE AREA         37400019
         MVC   HEX68(L8,R9),ASGQNAME SET UP NAME FOR XCTL               37500019
         LA    R15,HEX68(R9)       PT TO ENTRY PT OF MODULE             37600019
         ST    R15,HEX60(R9)       STORE ENTRY PT ADDRESS               37700019
         LA    R15,HEX60(R9)       SET UP REG 15 FOR XCTL               37800019
         XCTL  SF=(E,(15))         XCTL TO ASSIGN LOAD                  37900019
*********************************************************************** 38000019
*                                                                     * 38100019
*                           RETURN TO CALLER                          * 38200019
*                                                                     * 38300019
*********************************************************************** 38400019
RETURN   L     R14,RETADDR(R6)     RETURN ADDRESS                       38500019
         LR    R1,R6               PT TO GOTTEN CORE                    38600019
         L     R0,LNGTH2(R6)       S.P. AND LENGTH OF WORK AREA   M3698 38660019
         FREEMAIN R,LV=(0),A=(1)   FREE CORE FROM IEFXQM01        M3698 38720019
         LR    R15,R7              RETURN CODE                          38800019
         LR    R1,R4               RESTORE QMPA PT                      38900019
         RETURN RC=(15)            RETURN TO CALLER                     39000019
         EJECT                                                          39100019
*********************************************************************** 39200019
*                                                                     * 39300019
*    IF INITIATOR REQUEST WILL EXCEED LIMIT - ISSUE CANCEL COMMAND    * 39400019
*                                                                     * 39500019
*********************************************************************** 39600019
INITREQ  L     R11,QMWTQ           TRACK STACKING PT                    39700019
         LTR   R11,R11             IS THERE Q-BREAKING INFORMATION      39800019
         BZ    TESTSPAC            NO-THIS IS A SYSTEM TASK             39900019
         SR    R15,R15             CLEAR REGISTER                       40000019
         IC    R15,D4(R11)         NO. OF TRACKS USED BY AN INITIATOR   40100019
         CH    R15,QMTRS           TEST LIMIT AND AVOID CANCEL COMMAND  40200019
         BH    TESTSPAC              IF ALREADY ISSUED                  40300019
         AR    R15,R7              TEST LIMIT AND AVOID CANCEL COMMAND  40400019
         CH    R15,QMTRS             IF AFTER GETTING TRACKS INITIATOR  40500019
         BNH   TESTSPAC              WILL NOT EXCEED LIMIT              40600019
         LA    R0,QMCAN20-QMCAN00+QMASM20-QMASM15 MESSAGE LENGTH        40700019
         GETMAIN R,LV=(0)          GET CORE FOR CANCEL MESSAGE          40800019
         MVC   D0(QMCAN20-QMCAN00,R1),QMCAN00 PUT CANCEL COMMAND INTO   40900019
         MVC   QMCAN20-QMCAN00(QMASM20-QMASM15,R1),QMASM15  CORE        41000019
         L     R12,D4(R11)         JOB NAME PT                          41100019
         MVC   QMCAN10-QMCAN00(L8,R1),D0(R12) PUT JOB NAME INTO         41200019
         MVC   QMCAN20-QMCAN00+QMASM17-QMASM15(L8,R1),D0(R12) COMMANDS  41300019
         LA    R11,CHKEY-IEFCSCB   COMPUTE DISPLACEMENT OF CHKEY        41400019
         SR    R12,R11             CSCB PT                              41500019
         LR    R11,R12             ADDRESSABILITY FOR CSCB              41600019
         USING IEFCSCB,R11                                              41700019
         OI    CHSTS,CHQSPC        SET THE BIT IN THE CSCB TO     M2067 41750020
*                                  INDICATE INSUFFICIENT Q-SPACE  M2067 41800020
*                                  THEREBY CAUSING 422 ABEND      M2067 41850020
         DROP  R11                                                      42000019
         LR    R12,R1                AND PT TO GOTTEN CORE              42200019
         SR    R0,R0               ZERO OUT R0 FOR CANCEL         M2938 42250019
         MGCR  (1)                 ISSUE CANCEL COMMAND                 42300019
         LA    R1,QMCAN20-QMCAN00(R12)  WRITE CANCEL COMMAND            42400019
         WTO   MF=(E,(1))                 TO CONSOLE                    42500019
         LA    R0,QMCAN20-QMCAN00+QMASM20-QMASM15    GOTTEN CORE  M2067 42560020
*                                  FOR MESSAGE                    M2067 42620020
         LR    R1,R12                GOTTEN CORE                        42700019
         FREEMAIN R,LV=(0),A=(1)   FREE GOTTEN CORE                     42800019
         EJECT                                                          42900019
*********************************************************************** 43000019
*                                                                     * 43100019
*            IF SYSTEM TASK REQUEST CANNOT BE SATISFIED -             * 43200019
*                  BR TO MAKE SYSTEM ENVIRONMENT TEST                 * 43300019
*                                                                     * 43400019
*********************************************************************** 43500019
TESTSPAC LH    R12,QMNOTM          NO. OF AVAILABLE LOGICAL TRACKS      43600019
         CR    R7,R12              ARE ENOUGH LOGICAL TRACKS AVAILABLE  43700019
         BNH   ASGNPT              YES-BR TO ASSIGN LOGICAL TRACKS      43800019
         LA    R12,CRITMSG         PT FOR QUEUE CRITICAL MESSAGE IF     43900019
*                                    NOT MFT                            44000019
         B     SYSTEST             BR TO MAKE ENVIRONMENT TEST          44100019
CRITMSG  LA    R0,QMASM10-QMASM00  MESSAGE LENGTH                       44200019
         GETMAIN R,LV=(0)          GET CORE FOR QUEUE CRITICAL MESSAGE  44300019
         MVC   D0(QMASM10-QMASM00,R1),QMASM00 PUT QUEUE CRITICAL        44400019
*                                              MESSAGE INTO CORE        44500019
         LR    R12,R1                AND PT TO GOTTEN CORE              44700019
         WTO   MF=(E,(1))          WRITE MESSAGE TO CONSOLE             44800019
         LA    R0,QMASM10-QMASM00  GOTTEN CORE LENGTH FOR MESSAGE M2067 44900020
         LR    R1,R12                GOTTEN CORE                        45000019
         FREEMAIN R,LV=(0),A=(1)   FREE GOTTEN CORE                     45100019
         B     DEQOFF              BR TO NO SPACE ROUTINE               45200019
         EJECT                                                          45300019
*********************************************************************** 45400019
*                                                                     * 45500019
*                               CONSTANTS                               45600019
*                                                                     * 45700019
*********************************************************************** 45800019
         DS    0F                                                       45900019
ASGQNAME DC    C'IGC0209{'                                              46000019
CH0      DC    H'0'                                                     46100019
*********************************************************************** 46200019
QMCAN00  DS    0F                                                       46300019
QMCAN02  DC    H'21'                                                    46400019
QMCAN04  DC    H'00'                                                    46500019
QMCAN06  DC    C' CANCEL '                                              46600019
QMCAN10  DC    C'XXXXXXXX'                                              46700019
QMCAN15  DC    C' '                                                     46800019
QMCAN20  DS    0F                                                       46900019
*********************************************************************** 47000019
QMASM00  DS    0F                                                       47100019
QMASM05  DC    H'26'                                                    47200019
         DC    X'8000'                                            M2938 47300019
QMASM07  DC    C'IEF426I QUEUE CRITICAL'                                47400019
         DC    B'0001000000000000'                                M2938 47430019
         DC    B'0100000000000000'                                M2938 47460019
QMASM10  EQU   *                                                        47500019
QMASM15  DC    H'51'                                                    47600019
         DC    X'8000'                                            M2938 47700019
QMASM16  DC    C'IEF425I '                                        M2938 47800019
QMASM17  DC    C'XXXXXXXX'                                              47900019
QMASM18  DC    C' EXCEEDED'                                             48000019
         DC    C' SPECIFIED QUEUE SPACE'                                48100019
         DC    B'0000010000000000'                                M2938 48130019
         DC    B'0100000000000000'                                M2938 48160019
QMASM20  EQU   *                                                        48200019
*********************************************************************** 48300019
*********************************************************************** 48400019
IEFQASGA DS    0F                                                       48500019
         DC    AL1(255)                                                 48600019
         DC    AL1(2)                                                   48700019
         DC    BL1'01000001'                                            48800019
         DC    AL1(0)                                                   48900019
QNAME    DC    A(0)                                                     49000019
RNAME    DC    A(0)                                                     49100019
IEFSQCBS DC    C'SYSIEFSD'                                              49200019
IEFQ2QCB DC    C'Q2'                                                    49300019
         EJECT                                                          49400019
CVTD     DSECT                                                          49500019
         CVT   SYS=VMS                                                  49600019
         EJECT                                                          49700019
QMRCAR   DSECT                                                          49800019
         IEFQMRES                                                       49900019
         EJECT                                                          50000019
         IEFQMNGR                                                       50100019
QMCAP    EQU   IOPARAMS+24         PT TO TRACK STACKING,Q-BREAKING      50200019
*                                    INFORMATION                        50300019
SYSTASK  EQU   64                  BIT SET IN QMPRI BY L-SHAPED         50400019
*                                    PROGRAM WHEN STARTING SYSTEM TASK  50500019
         EJECT                                                          50600019
IEFCSCB  DSECT                                                          50700019
         IEECHAIN                                                       50800019
         EJECT                                                          50830021
         IKJTCB                                                         50860021
         END                                                            50900019
