 TITLE 'IEFXQM02 - TRANSIENT QUEUE MANAGER ASSIGN RECORDS MODULE' M2973 00100019
IEFXQM02 CSECT                                                          00200019
*********************************************************************** 00400019
*********************************************************************** 00600019
*                                                                     * 00800019
*   MODULE IGC02090 - TRANSIENT QUEUE MANAGER ASSIGN RECORDS ROUTINE  * 01000019
*                                                                     * 01200019
*********************************************************************** 01400019
*********************************************************************** 01600019
*                                                                     * 01800019
*STATUS- CHANGE LEVEL 000                                             * 02000019
*                                                                     * 02200019
*FUNCTION- TO ASSIGN RECORDS FROM A QUEUE ENTRY TO BE USED TO CONTAIN * 02400019
* JOB SCHEDULER TABLES.                                               * 02600019
*                                                                     * 02800019
*ENTRY POINT- IGC02090        FROM- IGC01090 - TRANSIENT Q MNGR       * 03000019
*                                   ASSIGN TRACKS ROUTINE             * 03200019
*                                                                     * 03400019
*INPUT- AN ECB/IOB POINTED TO BY REGISTER 2.                          * 03600020
* A QUEUE MANAGER RESIDENT CORE AREA POINTED TO BY REGISTER 3.        * 03650020
* A QUEUE MANAGER PARAMETER AREA POINTED TO BY REGISTER 4.            Q 03700020
* A WORK AREA FROM IGC02090, POINTED TO BY REGISTER 6, WHICH IS       * 03750020
* COMPLETELY INITIALIZED.                                             * 03800020
* AN EXTERNAL PARAMETER LIST POINTED TO BY THE PARAMETER AREA.        * 04000019
*                                                                     * 04200019
*OUTPUT- A TABLE OF TTRS CONTAINING ONE TTR FOR EACH RECORD           * 04400019
* ASSIGNMENT REQUESTED.                                               * 04600019
*                                                                     * 04800019
*EXTERNAL REFERENCES- LOCATION 16 TO LOCATE THE C.V.T. WHICH IS USED  * 05000019
* TO OBTAIN THE Q MNGR RESIDENT CORE AREA AND THE ENTRY POINT OF THE  * 05200019
* SUPERVISOR CONVERT ROUTINE.                                         * 05400019
*                                                                     * 05600019
         EJECT                                                          05800019
*EXITS- RETURN TO CALLER VIA REGISTER 14.                             * 06000019
*                                                                     * 06200019
*ERROR CODES- SPECIFIED IN REGISTER 15, 0= NORMAL RETURN              * 06400019
*                                       12= I/O ERROR                 * 06600019
*                                                                     * 06800019
*TABLES/WORK AREAS- 56 BYTES OF CORE ARE GOTTEN VIA GETMAIN FOR A     * 07000020
* WORK AREA WHICH IS USED AS FOLLOWS                                  * 07200019
*  BYTES 0-1 - NO. OF RECORDS NOW ASSIGNED                            * 07400019
*  BYTES 2-3 - NO. OF RECORDS TO ASSIGN                               * 07600019
*  BYTES 4-23 - AREA INTO WHICH TO READ LTH                           * 07800019
*  BYTES 24-35 - 6 2-BYTE FIELDS FOR LOGICAL TRACK NN'S               * 08000019
*  BYTES 36-39 - RETURN ADDRESS                                       * 08200019
*  BYTE 40 - INDICATOR SWITCHES                                       * 08400019
*            BIT 4 - WRITE MASTER HANDLE                              * 08600019
*            BIT 5 - MASTER HANDLE ENQUEUED UPON                      * 08800019
*  BYTES 41-43 - PT TO SUPERVISOR REQUEST BLOCK                       * 09000019
*  BYTES 44-47 - LENGTH OF TABLE AND SUBPOOL NO                       * 09200020
*  BYTES 48-51 - TTRSAVE AREA FOR RPS                                 * 09250020
*  BYTES 52-55 - UNUSED                                               * 09300020
* THE Q MNGR PARAMETER AREA AND THE EXTERNAL PARAMETER LIST TO WHICH  * 09400019
* IT POINTS. THE Q MNGR RESIDENT CORE AREA-TO OBTAIN LOGICAL TRACK    * 09600019
* POINTERS.                                                           * 09800019
*                                                                     * 10000019
*ATTRIBUTES- REENTRANT                                                * 10200019
*                                                                     * 10400019
*********************************************************************** 10600019
         EJECT                                                          10800019
*********************************************************************** 11000019
*                                                                     * 11200019
*                           REGISTER EQUATES                          * 11400019
*                                                                     * 11600019
*********************************************************************** 11800019
R0       EQU   0                                                        12000019
R1       EQU   1                                                        12200019
R2       EQU   2                                                        12400019
R3       EQU   3                                                        12600019
R4       EQU   4                                                        12800019
R5       EQU   5                                                        13000019
R6       EQU   6                                                        13200019
R7       EQU   7                                                        13400019
R8       EQU   8                                                        13600019
R9       EQU   9                                                        13800019
R10      EQU   10                                                       14000019
R11      EQU   11                                                       14200019
R12      EQU   12                                                       14400019
R13      EQU   13                                                       14600019
R14      EQU   14                                                       14800019
R15      EQU   15                                                       15000019
*********************************************************************** 15200019
D0       EQU   0                                                        15400019
D1       EQU   1                                                        15600019
D2       EQU   2                                                        15800019
D4       EQU   4                                                        16000019
D8       EQU   8                                                        16200019
D20      EQU   20                                                       16400019
L2       EQU   2                                                        16600019
L8       EQU   8                                                        16800019
*********************************************************************** 17000019
         BALR  R8,D0               ESTABLISH ADDRESSABILITY             17200019
         USING *,R8                                                     17400019
*  THIS SECTION OF CODE IS FOR DUMP RECOGNITION ONLY                    17600019
         B     XQMGO                                                    17800019
         DC    X'CCCC'                                                  18000019
         DC    C'IEFXQM02'                                              18200019
         DC    C'10101969'                                              18400019
         DC    X'CCCC'                                                  18600019
XQMGO    DS    0H                                                       18800019
         EJECT                                                          19000019
*********************************************************************** 19200019
*                                                                     * 19400019
*              ASSIGN RECORDS FROM CURRENT LOGICAL TRACK              * 19600019
*                                                                     * 19800019
*********************************************************************** 20000019
NUMASGND EQU   0                                                        20200019
NMTOASGN EQU   2                                                        20400019
*********************************************************************** 20600019
         USING IOPARAMS,R4         ADDRESSABILITY FOR QMPA              20800019
         USING QMRCAR,R3           ADDRESSABILITY FOR RESIDENT CORE     21000019
ASGNRC10 L     R7,QMPCL            EXTERNAL PARAMETER AREA PT           21200019
ASGNRC20 LH    R13,NMTOASGN(R6)    NO. OF RECORDS TO ASSIGN             21400019
         LH    R5,QMTID            NN OF CURRENT LOGICAL TRACK + NO.    21600019
         AH    R5,NUMASGND(R6)       OF RECORDS NOW ASSIGNED            21800019
ASGNRC30 CLC   NUMASGND(L2,R6),QMLPT TEST AND BR IF CURRENT LOGICAL     22000019
         BNL   FULTRK10              TRACK IS TOTALLY ASSIGNED          22200019
         LA    R5,D1(R5)           NN FOR NEXT RECORD                   22400019
         LR    R11,R5                                                   22600019
         BAL   R9,TTRCNVT1         BR TO CONVERT NN TO TTR0             22800019
         ST    R0,D0(R7)           PUT TTR INTO EXTERNAL PARAMETER AREA 23000019
         LA    R7,D4(R7)           INCREMENT EXTERNAL PARAMETER AREA PT 23200019
         LH    R1,NUMASGND(R6)     NO. OF RECORDS NOW ASSIGNED          23400019
         LA    R1,D1(R1)           ADD 1 FOR RECORD JUST ASSIGNED       23600019
         STC   R1,QMTST            UPDATE FLD IN CURRENT LTH            23800019
         STH   R1,NUMASGND(R6)     RESTORE NO. NOW ASSIGNED IN WORK     24000019
*                                    AREA                               24200019
*********************************************************************** 24400019
*                                                                     * 24600019
*              TEST IF MORE RECORD ASSIGNMENTS REQUESTED              * 24800019
*                   YES - BR TO CONTINUE ASSIGNMENTS                  * 25000019
*                   NO - IF MASTER HANDLE ENQUEUED UPON,WRITE OUT     * 25200019
*                        UPDATED VERSION                              * 25400019
*                                                                     * 25600019
*********************************************************************** 25800019
ENQBIT   EQU   X'04'                                                    26000019
SVRBPT   EQU   40                                                       26200019
SWITCHES EQU   SVRBPT                                                   26400019
*********************************************************************** 26600019
         BCT   R13,ASGNRC30        IF MORE RECORDS ARE TO BE ASSIGNED,  26800019
*                                    BR TO CONTINUE                     27000019
         TM    SWITCHES(R6),ENQBIT WAS HASTER HANDLE ENQUEUED UPON      27200019
         BO    WRITEMH             YES-BR TO WRITE OUT NEW LTH AND      27400019
*                                    MASTER HANDLE AND DEQUEUE OFF      27600019
*                                    MASTER HANDLE                      27800019
         EJECT                                                          28000019
*********************************************************************** 28200019
*                                                                     * 28400019
*                        SET NORMAL RETURN CODE                       * 28600019
*                                                                     * 28800019
*********************************************************************** 29000019
NORMAL   SR    R7,R7               NO-SET NORMAL RETURN CODE            29200019
*********************************************************************** 29400019
*                                                                     * 29600019
*                           RETURN TO CALLER                          * 29800019
*                                                                     * 30000019
*********************************************************************** 30200019
RETADDR  EQU   36                                                       30400019
LNGTH2   EQU   44                                                 M3698 30700019
*********************************************************************** 30800019
RETURN   L     R14,RETADDR(R6)     RETURN ADDRESS                       31000019
         LR    R1,R6               PT TO GOTTEN CORE                    31200019
         L     R0,LNGTH2(R6)       S.P. AND LENGTH OF WORK AREA   M3698 31300019
         FREEMAIN R,LV=(0),A=(1)   FREE CORE FROM IEFXQM01        M3698 31400019
         LR    R15,R7              RETURN CODE                          31600019
         LR    R1,R4               RESTORE QMPA PT                      31800019
         RETURN RC=(15)            RETURN TO CALLER                     32000019
         EJECT                                                          32200019
*********************************************************************** 32400019
*                                                                     * 32600019
*                       WRITE OUT MASTER HANDLE                       * 32800019
*                                                                     * 33000019
*********************************************************************** 33200019
MHLNGTH  EQU   36                                                       33400019
SAVQMPA  EQU   52                                                 M5274 33410020
SECT     EQU   X'4C'                                             S20201 33450020
SECTLG   EQU   1                                                 S20201 33500020
WRITE    EQU   X'08'                                                    33600019
*********************************************************************** 33800019
WRITEMH  MVC   QMTLN(L2),CH0       ZERO NN OF NEXT LOGICAL TRACK PT     34000019
*                                    IN NEW LTH                         34200019
         MVC   XQMSKAD(L8,R2),QMHDA PUT MBBCCHHR INTO IOB               34400019
         MVC   SECT(SECTLG,R2),QMSECT   MOVE IN SECTOR VALUE     S20201 34500020
         ST    R4,SAVQMPA(R6)      QMPA PT                        M5274 34600020
         LA    R4,QMHDA            CORE ADDRESS OF MASTER HANDLE        34800019
         LA    R15,MHLNGTH         MASTER HANDLE RECORD LENGTH          35000019
         BAL   R9,WRTEXDAP         BR TO WRITE OUT MASTER HANDLE        35200019
         L     R4,SAVQMPA(R6)      RESTORE QMPA PT                M5274 35400020
*********************************************************************** 35600019
*                                                                     * 35800019
*                      DEQUEUE OFF MASTER HANDLE                      * 36000019
*                                                                     * 36200019
*********************************************************************** 36400019
         LA    R14,IEFSQCBS        PUT PT TO MAJOR NAME                 36600019
         ST    R14,QNAME             INTO PARAMETER LIST                36800019
         LA    R14,IEFQ2QCB        PUT PT TO MINOR NAME                 37000019
         ST    R14,RNAME             INTO PARAMETER LIST                37200019
         DEQ   MF=(E,IEFQASGA)     DEQUEUE OFF MASTER HANDLE            37400019
         LH    R11,QMTID           NN OF NEW LTH                        37600019
         OI    SWITCHES(R6),WRITE  SET WRITE SWITCH                     37800019
         B     CNVTMB10            BR TO CONVERT NN TO MBBCCHHR         38000019
         EJECT                                                          38200019
*********************************************************************** 38400019
*                                                                     * 38600019
*                          CONVERT NN TO TTR                          * 38800019
*                                                                     * 39000019
*********************************************************************** 39200019
CNVTMB10 LA    R9,CNVTMB20         PT TO COMPLETE CONVERSION            39400019
TTRCNVT1 LH    R14,QMKTT           TT OF FIRST TRACK OF ALL             39600019
*                                    LOGICAL RECORDS                    39800019
         SH    R11,QMFQR           SUBTRACT NN OF FIRST RECORD ON TRACK 40000019
*                                    OF ALL LOGICAL RECORDS FROM        40200019
*                                    CURRENT NN                         40400019
         BM    MIXEDTRK            BR IF CURRENT NN ON MIXED TRACK      40600019
         LH    R12,QMRPT           NO. OF RECORDS PER PHYSICAL TRACK    40800019
         SR    R10,R10             CLEAR REGISTER                       41000019
         DR    R10,R12             DIVIDE CURRENT NN BY NO. OF RECORDS  41200019
*                                    PER PHYSICAL TRACK                 41400019
         AR    R11,R14             DETERMINE NEW TT                     41600019
         SLL   R11,D8              SHIFT TT TO PROPER POSITION          41800019
         LA    R11,D1(R10,R11)     TTR=TT + CURRENT NN + 1              42000019
TTRCNVT2 LA    R0,D0(R11)          PUT TTR INTO REG 0                   42200019
         SLL   R0,D8               SHIFT TTR TO PROPER POSITION         42400019
         BR    R9                  BR BACK WITH TTR0 OR BR TO           42600019
*                                    COMPLETE CONVERSION                42800019
MIXEDTRK AH    R11,QMFQR           RESTORE CURRENT NN                   43000019
         AH    R11,QMNHM           ADD NO. OF HANDLES ON MIXED TRACK    43200019
         BCTR  R14,D0              DETERMINE TT ON WHICH CURRENT NN     43400019
*                                    RESIDES                            43600019
         SLL   R14,D8              SHIFT TT TO PROPER POSITION          43800019
         AR    R11,R14             TTR= TT + CURRENT NN                 44000019
         B     TTRCNVT2            BR TO PUT TTR INTO REG 0             44200019
         EJECT                                                          44400019
*********************************************************************** 44600019
*                                                                     * 44800019
*                       CONVERT TTR TO MBBCCHHR                       * 45000019
*                                                                     * 45200019
*********************************************************************** 45400019
CNVTQ    EQU   4                                                 S20201 45450020
CVTPT    EQU   16                                                       45600019
LTHLNGTH EQU   20                                                       45800019
QMSPCV   EQU   28                                                       46000019
RPSON    EQU   X'10'                                             S20201 46050020
TTRSAVE  EQU   48                                                S20201 46100020
XQMSKAD  EQU   36                                                       46200019
*********************************************************************** 46400019
CNVTMB20 TM    QMRPS,RPSON         IS Q ON AN RPS DEVICE         S20201 46410020
         BNO   CNVTMB30            NO-BR TO CONTINUE             S20201 46420020
         ST    R0,TTRSAVE(R6)      YES-SAVE TTR                  S20201 46430020
         L     R15,CVTPTR          CVT PT                        S20201 46440020
         USING CVTD,R15            ADDRESSABILITY FOR CVT        S20201 46450020
         L     R15,CVT0SCR1        SUPERVISOR SECTOR CONVERT     S20201 46460020
         DROP  R15                   ROUTINE ADDRESS             S20201 46470020
         L     R15,CNVTQ(R15)      SECTOR CONVERT ROUTINE ADDR   S20201 46480020
         BALR  R14,R15             BR TO CONVERT ROUTINE         S20201 46490020
         L     R11,QMEIA           RESTORE ECB/IOB PT            S20201 46500020
         LA    R11,SECT(R11)       PLACE DEVICE TYPE CODE AND    S20201 46510020
         SLL   R11,D8                ADDR OF WHERE TO SAVE       S20201 46520020
         LH    R10,QMRPS             SECTOR INTO REGISTER TWO    S20201 46530020
         SRDL  R10,D8                FOR SECTOR CONVERT ROUTINE  S20201 46540020
         LR    R2,R11                                            S20201 46550020
         L     R15,CVTPTR          CVT PT                        S20201 46560020
         USING CVTD,R15            ADDRESSABILITY FOR CVT        S20201 46570020
         L     R15,CVT0SCR1        SUPERVISOR SECTOR CONVERT     S20201 46580020
         DROP  R15                   ROUTINE ADDRESS             S20201 46590020
         BALR  R14,R15             BR TO SUPERVISOR CONVERT      S20201 46600020
         L     R0,TTRSAVE(R6)      RESTORE TTR                   S20201 46610020
         L     R2,QMEIA            RESTORE ECB/IOB PT            S20201 46620020
CNVTMB30 LA    R2,XQMSKAD(R2)      PT TO MBBCCHHR IN IOB         S20201 46630020
         LA    R1,QMRDEB           PT TO RESIDENT DEB                   46800019
         L     R15,CVTPT           CVT PT                               47000019
         L     R15,QMSPCV(R15)     PT TO SUPERVISOR CONVERSION ROUTINE  47200019
         BALR  R14,R15             BR TO CONVERT TTR TO MBBCCHHR        47400019
         L     R2,QMEIA            RESTORE ECB/IOB PT                   47600019
WRITELTH LA    R15,LTHLNGTH        LTH RECORD LENGTH                    47800019
         LA    R9,ADDTRKS          PT TO ROUTINE WHICH INCREMENTS NO.   48000019
*                                    OF TRACKS ASSIGNED FLD             48200019
         TM    SWITCHES(R6),WRITE  IS THIS A SPECIAL RETURN (I.E. IS    48400019
*                                    THIS A WRITE OF THE LTH OF A NEW   48600019
*                                    LOGICAL TRACK-HAVING A 0 PTR TO    48800019
*                                    THE LTH OF NEXT LOGICAL TRACK      49000019
         BZ    WRTEXDAP            NO-BR TO WRITE OUT THE LTH           49200019
         LA    R9,NORMAL           PT TO SET NORMAL RETURN CODE,RETURN  49400019
*********************************************************************** 49600019
*                                                                     * 49800019
*                            WRITE A RECORD                           * 50000019
*                                                                     * 50200019
*********************************************************************** 50400019
WRTEXDAP LA    R11,SECT(R2)        GET ADDR OF SECTOR FOR XDAP   S20201 50600020
         XDAP  (2),WI,(3),(4),(15),,,(11),MF=E                   S20201 50650020
         EJECT                                                          51000019
*********************************************************************** 51200019
*                                                                     * 51400019
*                       WAIT FOR I/O COMPLETION                       * 51600019
*                                                                     * 51800019
*********************************************************************** 52000019
NORMALIO EQU   X'7F'                                                    52200019
WRTEOFF  EQU   X'F7'                                                    52400019
*********************************************************************** 52600019
IOWAIT   LR    R1,R2               ECB/IOB PT                           52800019
         LA    R1,D0(R1)           CLEAR HIGH-ORDER BYTE OF REG 1       53000019
         WAIT  1,ECB=(1)           WAIT FOR I/O COMPLETION              53200019
         NI    SWITCHES(R6),WRTEOFF ZERO WRITE SWITCH,IF ON             53400019
         CLI   0(R2),NORMALIO      IS I/O COMPLETION NORMAL             53600019
         BCR   8,R9                YES-BR TO CONTINUE                   53800019
*********************************************************************** 54000019
*                                                                     * 54200019
*                      DEQUEUE OFF MASTER HANDLE                      * 54400019
*                                                                     * 54600019
*********************************************************************** 54800019
         LA    R14,IEFSQCBS        PUT PT TO MAJOR NAME                 55000019
         ST    R14,QNAME             INTO PARAMETER LIST                55200019
         LA    R14,IEFQ2QCB        PUT PT TO MINOR NAME                 55400019
         ST    R14,RNAME             INTO PARAMETER LIST                55600019
         DEQ   MF=(E,IEFQASGA)     DEQUEUE OFF MASTER HANDLE            55800019
*********************************************************************** 56000019
*                                                                     * 56200019
*                      SET I/O ERROR RETURN CODE                      * 56400019
*                                                                     * 56600019
*********************************************************************** 56800019
IOERR    EQU   12                                                       57000019
*********************************************************************** 57200019
         LA    R7,IOERR            I/O ERROR RETURN CODE                57400019
         B     RETURN              BR TO EXIT LINKAGE                   57600019
         EJECT                                                          57800019
*********************************************************************** 58000019
*                                                                     * 58200019
*                      ASSIGN A NEW LOGICAL TRACK                     * 58400019
*                                                                     * 58600019
*********************************************************************** 58800019
FREETRK  EQU   24                                                       59000019
*********************************************************************** 59200019
FULTRK10 ST    R13,NUMASGND(R6)    SAVE NO. OF RECORDS LEFT TO ASSIGN   59400019
*                                    AND ZERO OUT NO. NOW ASSIGNED FLD  59600019
         LA    R5,FREETRK(R6)      PT TO NN LIST IN WORK AREA           59800019
FULTRK20 CLC   D0(L2,R5),CH0       IS NN FLD ZERO                       60000019
         BNE   FULTRK30            NO-BR TO CONTINUE                    60200019
         LA    R5,D2(R5)           YES-INCREMENT NN PT TO NEXT SLOT     60400019
         B     FULTRK20            CONTINUE SEARCH FOR NN               60600019
FULTRK30 LH    R11,QMTID           NN OF CURRENT LOGICAL TRACK          60800019
         MVC   QMTID(L2),D0(R5)    PUT NEW NN INTO QMPA FLD             61000019
         MVC   QMTLN(L2),QMTID     LINK FLD TO NEW LOGICAL TRACK        61200019
         LTR   R11,R11             IS CURRENT NN FLD ZERO,I.E.-IS THIS  61400019
*                                    AN ASSIGN START                    61600019
         BP    FULTRK40            NO-BR TO WRITE OUT LTH               61800019
         MVC   QMFLT(L2),QMTID     YES-NN OF CURRENT LOGICAL TRACK IS   62000019
*                                    ALSO NN OF FIRST TRACK ASSIGNED    62200019
         STH   R11,QMTLN           ZERO OUT LINK FLD FOR FIRST LOGICAL  62400019
*                                    TRACK ASSIGNED TO JOB              62600019
         LH    R11,QMTID           NN OF CURRENT LOGICAL TRACK          62800019
FULTRK40 B     CNVTMB10            BR TO CONVERT NN TO MBBCCHHR AND     63000019
*                                    WRITE OUT LTH                      63200019
*********************************************************************** 63400019
*                                                                     * 63600019
*               INCREMENT NO. OF ASSIGNED LOGICAL TRACKS              * 63800019
*                                                                     * 64000019
*********************************************************************** 64200019
ADDTRKS  XC    D0(L2,R5),D0(R5)    ZERO NN SLOT IN WORK AREA JUST USED  64400019
         IC    R10,QMNOT           NO. OF LOGICAL TRACKS ASSIGNED TO    64600019
*                                    THIS JOB                           64800019
         LA    R10,D1(R10)         ADD 1 FOR LOGICAL TRACK JUST         65000019
*                                    ASSIGNED                           65200019
         STC   R10,QMNOT           RESTORE NO. ASSIGNED FLD IN LTH      65400019
         B     ASGNRC20            BR TO ASSIGN RECORDS FOR JOB         65600019
         EJECT                                                          65800019
*********************************************************************** 66000019
*                                                                     * 66200019
*                              CONSTANTS                              * 66400019
*                                                                     * 66600019
*********************************************************************** 66800019
         DS    0H                                                       67000019
CH0      DC    H'0'                                                     67200019
*********************************************************************** 67400019
IEFQASGA DS    0F                                                       67600019
         DC    AL1(255)                                                 67800019
         DC    AL1(2)                                                   68000019
         DC    BL1'01000001'                                            68200019
         DC    AL1(0)                                                   68400019
QNAME    DC    A(0)                                                     68600019
RNAME    DC    A(0)                                                     68800019
*********************************************************************** 69000019
IEFSQCBS DC    C'SYSIEFSD'                                              69200019
IEFQ2QCB DC    C'Q2'                                                    69400019
         EJECT                                                          69600019
CVTD     DSECT                                                          69800019
         CVT   SYS=VMS                                                  70000019
         EJECT                                                          70200019
QMRCAR   DSECT                                                          70400019
         IEFQMRES                                                       70600019
QMSECT   EQU   QMRPS+2            DISP FOR SECTOR OF MH          S20201 70700020
         EJECT                                                          70800019
         IEFQMNGR                                                       71000019
QMCAP    EQU   IOPARAMS+24         PT TO TRACK STACKING,Q-BREAKING      71200019
*                                    INFORMATION                        71400019
SYSTASK  EQU   64                  BIT SET IN QMPRI BY L-SHAPED         71600019
*                                    PROGRAM WHEN STARTING SYSTEM TASK  71800019
         EJECT                                                          72000019
IEFCSCB  DSECT                                                          72200019
         IEECHAIN                                                       72400019
         END                                                            72600019
