 TITLE 'IEFXQM03 - TRANSIENT QUEUE MANAGER ENQUEUE MODULE'              00050020
IEFXQM03 CSECT                                                          00200020
* 582100,582300,583000-583600                                    S20201 00210020
*  582500                                                         M2068 00250020
*A002000-754000                                                  S20033 00300020
*********************************************************************** 00400020
*********************************************************************** 00600020
*                                                                     * 00800020
*      MODULE IGC03090 - TRANSIENT QUEUE MANAGER ENQUEUE ROUTINE      * 01000020
*                                                                     * 01200020
*********************************************************************** 01400020
*********************************************************************** 01600020
*                                                                     * 01800020
*STATUS- CHANGE LEVEL 000                                             * 02000020
*                                                                     * 02200020
*FUNCTION- TO PUT A JOB ON A JOB QUEUE OR A SYSOUT QUEUE AT THE       * 02400020
* PROPER PRIORITY.                                                    * 02600020
*                                                                     * 02800020
*ENTRY POINT-IGC03090         FROM- IGC00090- TRANSIENT Q MNGR        * 03000020
*                                   INITIALIZATION,READ/WRITE ROUTINE * 03200020
*                                                                     * 03400020
*INPUT- AN ECB/IOB POINTED TO BY REGISTER 2.                          * 03600020
* A QUEUE MANAGER RESIDENT CORE AREA POINTED TO BY REGISTER 3.        * 03650020
* A QUEUE MANAGER PARAMETER AREA POINTED TO BY REGISTER 4.            * 03700020
* THE FIRST 20 BYTES OF THE PARAMETER AREA ARE THE LTH FOR THE JOB    * 03800020
* TO BE PLACED ON THE QUEUE.                                          * 04000020
* A WORK AREA FROM IGC00090, POINTED TO BY REGISTER 6, WHICH CONTAINS * 04200020
* THE RETURN ADDRESS AND SVRB ADDRESS.                                * 04250020
* AN EXTERNAL PARAMETER LIST POINTED TO BE THE PARAMETER AREA.        * 04400020
*                                                                     * 04600020
*OUTPUT- THE JOB WILL BE ON THE APPROPRIATE QUEUE AND THE CORE        * 04800020
* FOR THE ECB/IOB WILL BE FREED.                                      * 05000020
*                                                                     * 05200020
*EXTERNAL REFERENCES- LOCATION 16 TO LOCATE THE C.V.T. WHICH IS USED  * 05400020
* TO OBTAIN THE Q MNGR RESIDENT CORE AREA AND THE ENTRY POINT OF THE  * 05600020
* SUPERVISOR CONVERT ROUTINE.                                         * 05800020
*                                                                     * 06000020
 EJECT                                                                  06050020
*EXITS- RETURN TO CALLER VIA REGISTER 14.                             * 06200020
*                                                                     * 06400020
*ERROR CODES- SPECIFIED IN REGISTER 15, 0= NORMAL RETURN              * 06600020
*                                       12= I/O ERROR                 * 06800020
*                                                                     * 07000020
*TABLES/WORK AREAS- 88 BYTES OF CORE ARE GOTTEN VIA GETMAIN FOR A     * 07200020
* WORK AREA WHICH IS USED AS FOLLOWS                                  * 07400020
*  BYTES 0-3 - RETURN ADDRESS                                         * 07600020
*  BYTES 4-7 - SVRB PT                                                * 07800020
*  BYTES 8-11 - ECB/IOB(S) PT                                         * 08000020
*  BYTES 12-19 - MBBCCHHR FOR QCR                                     * 08200020
*  BYTES 20-55 - AREA INTO WHICH TO READ QCR                          * 08400020
*  BYTES 56-75 - AREA INTO WHICH TO READ LTH                          * 08600020
*  BYTES 76-83 - MBBCCHHR FOR LTH                                     * 08800020
*  BYTE  84 - SECTOR VALUE FOR QCR                                    * 09000020
*  BYTE  85 - SECTOR VALUE FOR LTH                                    * 09050020
*  BYTE  86 - QCR INDICATOR                                           * 09100020
*  BYTE  87 - UNUSED                                                  * 09150020
*                                                                     * 09200020
*ATTRIBUTES- REENTRANT                                                * 09400020
*                                                                     * 09600020
*********************************************************************** 09800020
         EJECT                                                          10000020
*********************************************************************** 10200020
*                                                                     * 10400020
*                            REGISTER EQUATES                         * 10600020
*                                                                     * 10800020
*********************************************************************** 11000020
R0       EQU   0                                                        11200020
R1       EQU   1                                                        11400020
R2       EQU   2                                                        11600020
R3       EQU   3                                                        11800020
R4       EQU   4                                                        12000020
R5       EQU   5                                                        12200020
R6       EQU   6                                                        12400020
R7       EQU   7                                                        12600020
R8       EQU   8                                                        12800020
R9       EQU   9                                                        13000020
R10      EQU   10                                                       13200020
R11      EQU   11                                                       13400020
R12      EQU   12                                                       13600020
R13      EQU   13                                                       13800020
R14      EQU   14                                                       14000020
R15      EQU   15                                                       14200020
*********************************************************************** 14400020
D0       EQU   0                                                        14600020
D1       EQU   1                                                        14800020
D4       EQU   4                                                        15000020
D8       EQU   8                                                        15200020
D30      EQU   30                                                       15400020
D32      EQU   32                                                       15600020
D33      EQU   33                                                       15800020
D36      EQU   36                                                       16000020
D64      EQU   64                                                       16200020
L1       EQU   1                                                        16400020
L2       EQU   2                                                        16600020
L3       EQU   3                                                        16800020
L8       EQU   8                                                        17000020
*********************************************************************** 17200020
         BALR  R8,D0               ESTABLISH ADDRESSABILITY             17400020
         USING *,R8                                                     17600020
*  THIS SECTION OF CODE IS FOR DUMP RECOGNITION ONLY                    17800020
         B     XQMGO                                                    18000020
         DC    X'CCCC'                                                  18200020
         DC    C'IEFXQM03'                                              18400020
         DC    C'12051969'                                              18600020
         DC    X'CCCC'                                                  18800020
XQMGO    DS    0H                                                       19000020
         EJECT                                                          19200020
*********************************************************************** 19400020
*                                                                     * 19600020
*                   GET CORE FOR INTERNAL WORK AREA                   * 19800020
*                                                                     * 20000020
*********************************************************************** 20200020
WKAREA1  EQU   16                                                       20400020
RETADDR  EQU   0                                                        20600020
WKAREA3  EQU   88                                                       20800020
*********************************************************************** 21000020
         USING IOPARAMS,R4         ADDRESSABILITY FOR QMPA              21200020
         USING QMRCAR,R3           ADDRESSABILITY FOR RESIDENT CORE     21400020
         GETMAIN R,LV=WKAREA3      GET CORE FOR WORK AREA               21600020
         XC    D0(WKAREA3,R1),D0(R1) ZERO OUT WORK AREA                 21800020
         MVC   RETADDR(L8,R1),D0(R6) MOVE RETURN ADDRESS AND SVRB PT    22000020
*                                      TO WORK AREA                     22200020
         LR    R5,R1               PT TO WORK AREA                      22400020
         LR    R1,R6               PT TO WORK AREA FOR IGC00090         22600020
         L     R0,12(R6)               S.P. & LENGTH OF WORK AREA M0366 22700020
         FREEMAIN R,LV=(0),A=(1)       FREE WORK AREA GOTTEN BY   M0366 22800020
*                                      IGC00090                   M0366 22900020
         LR    R6,R5               PT TO WORK AREA                      23000020
*********************************************************************** 23200020
*                                                                     * 23400020
*                       IF NECESSARY - WRITE JCT                      * 23600020
*                                                                     * 23800020
*********************************************************************** 24000020
JCTLNGTH EQU   176                                                      24200020
*********************************************************************** 24400020
         L     R5,QMPCL            EXTERNAL PARAMETER AREA PT           24600020
         LTR   R5,R5               IS THERE A JCT TO BE WRITTEN         24800020
         BZ    XQMNQQ10            NO-BR TO CONTINUE                    25000020
         L     R0,D4(R5)           YES-LOAD TTR OF JCT                  25200020
         BAL   R7,CNVTMBB          BR TO CONVERT TTR TO MBBCCHHR        25400020
         L     R5,QMPCL            GET ADDR OF EXT. PARM AREA    S20201 25450020
         L     R9,D0(R5)           CORE ADDRESS OF JCT                  25600020
         LA    R10,JCTLNGTH        LENGTH OF JCT                        25800020
         BAL   R7,WRTEXDAP         BR TO WRITE OUT JCT                  26000020
         EJECT                                                          26200020
*********************************************************************** 26400020
*                                                                     * 26600020
*                           READ PROPER QCR                           * 26800020
*                                                                     * 27000020
*********************************************************************** 27200020
ONES     EQU   X'FF'                                             S20201 27400020
QCRAREA  EQU   20                                                       27450020
QCRINOT  EQU   86                                                S20201 27500020
QCRLNGTH EQU   36                                                       27550020
QCRSECT  EQU   84                                                S20201 27600020
SECT     EQU   X'4C'                                             S20201 27650020
SECTLG   EQU   1                                                 S20201 27700020
ZERO     EQU   X'00'                                             S20201 27750020
*********************************************************************** 27800020
XQMNQQ10 SR    R11,R11             INITIALIZE REGISTER FOR NN OF QCR    28000020
         IC    R11,QMTPY           QUEUE TYPE FROM WHICH JOB TO BE      28200020
*                                    GOTTEN                             28400020
         SR    R12,R12             NN ON WHICH QCR'S START              28600020
         LH    R9,QMHPT            NO. OF RECORDS PER PHYSICAL TRACK    28800020
         MVI   QCRINOT(R6),ONES    INDICATE QCR TO CONVERT       S20201 28850020
         LA    R15,CNVTMBB         PT TO CONTINUE CONVERSION            29000020
         BAL   R7,TTRCNVT2         BR TO CONVERT NN TO TTR              29200020
         MVI   QCRINOT(R6),ZERO    ZERO INDICATOR                S20201 29250020
         LA    R10,QCRLNGTH        QCR LENGTH                           29400020
         LA    R14,IEFSQCBS        PUT PT TO MAJOR NAME                 29600020
         ST    R14,QNAME             INTO PARAMETER LIST                29800020
         LA    R14,IEFQ1QCB        PUT PT TO MINOR NAME                 30000020
         ST    R14,RNAME             INTO PARAMETER LIST                30200020
         ENQ   MF=(E,IEFQMNQA)     ENQUEUE ON MASTER HANDLE             30400020
         LA    R9,QCRAREA(R6)      PT TO AREA INTO WHICH TO READ QCR    30600020
         BAL   R7,READXDAP         BR TO READ                           30800020
         MVC   QCRDAD(L8,R6),XQMSKAD(R2) SAVE MBBCCHHR OF QCR           31000020
         MVC   QCRSECT(SECTLG,R6),SECT(R2)  SAVE SECTOR OF QCR   S20201 31050020
         EJECT                                                          31200020
*********************************************************************** 31400020
*                                                                     * 31600020
*                   DETERMINE PRIORITY OF THIS JOB                    * 31800020
*                                                                     * 32000020
*********************************************************************** 32200020
PRIMASK  EQU   X'0F'                                                    32400020
QCREND   EQU   30                                                       32600020
*********************************************************************** 32800020
         LA    R1,PRIMASK          LOAD MASK WHICH WILL BE USED TO      33000020
*                                    ZERO ALL BUT FOUR PRIORITY BITS    33200020
         IC    R13,QMPRI           PRIORITY FLD                         33400020
         NR    R13,R1              ZERO ALL BUT PRIORITY BITS           33600020
         LCR   R12,R13             COMPLEMENT THE PRIORITY(TO BE USED   33800020
*                                    AS NEGATIVE OFFSET TO OBTAIN       34000020
*                                    PROPER SLOT IN THE JOB QUEUE       34200020
*                                    HANDLE FOR THIS PRIORITY)          34400020
         SLL   R12,D1              MULTIPLY BY TWO TO GET PROPER OFFSET 34600020
         LH    R14,QMTID           CURRENT NN                           34800020
         LH    R11,QCREND(R9,R12)  GET NN OF QUEUE ENTRY FOR THE LAST   35000020
*                                    JOB IN THE CHAIN WITH THE SAME     35200020
*                                    PRIORITY AS PRESENT JOB            35400020
         STH   R14,QCREND(R9,R12)  STORE CURRENT NN AS LAST OF THIS     35600020
*                                    PRIORITY                           35800020
         LTR   R11,R11             IS THERE ANOTHER JOB WITH THIS       36000020
*                                    PRIORITY                           36200020
         BNZ   XQMNQQ50            YES-BR TO CONTINUE                   36400020
         EJECT                                                          36600020
*********************************************************************** 36650020
*                                                                     * 36700020
*                  IF NECESSARY, UPDATE MASTER QCR                    * 36750020
*                                                                     * 36760020
*********************************************************************** 36800020
QSTATUS  EQU   32                                                       37000020
STATMASK EQU   X'F0'                                                    37200020
*********************************************************************** 37400020
         IC    R1,QSTATUS(R9)      GET STATUS OF QUEUE AND HIGHEST      37600020
*                                    PRIORITY JOB IN THE QUEUE          37800020
         LA    R7,STATMASK         MASK TO ZERO PRIORITY BITS           38000020
         NR    R7,R1               GET THE STATUS BITS                  38200020
         OR    R7,R13              COMBINE STATUS BITS WITH THIS        38400020
*                                    JOB'S PRIORITY                     38600020
         CR    R1,R7               IS THIS JOB'S PRIORITY GREATER THAN  38800020
*                                    THE TOP OF THE QUEUE               39000020
         BH    XQMNQQ30            NO-BR TO CONTINUE                    39200020
         STC   R7,QSTATUS(R9)      YES-MAKE THIS JOB'S PRIORITY THE     39400020
*                                    HIGHEST IN THE QUEUE               39600020
         MVC   QMLNK(L2),D0(R9)    LINK THE LTH OF THE CURRENT JOB TO   39800020
*                                    THE TOP OF QUEUE LTH               40000020
         STH   R14,D0(R9)          PUT CURRENT NN  INTO TOP OF          40200020
*                                    QUEUE SLOT                         40400020
         L     R7,QSTATUS(R9)      GET STATUS OF QUEUE                  40600020
         LTR   R7,R7               IS THIS QUEUE BEING HELD             40800020
         BM    XQMNQQ60            YES-BR TO CONTINUE                   41000020
         XC    D33(L3,R9),D33(R9)  ZERO PT TO NO WORK QUEUE             41200020
         EJECT                                                          41400020
*********************************************************************** 41600020
*                                                                     * 41800020
*                     POST ANY TASKS AWAITING WORK                    * 42000020
*                                                                     * 42200020
*********************************************************************** 42400020
LTHAREA  EQU   56                                                       42600020
LTHLNGTH EQU   20                                                       42800020
LTHSECT  EQU   85                                                S20201 42850020
*********************************************************************** 43000020
XQMNQQ20 LA    R7,D0(R7)           CLEAR HIGH-ORDER(STATUS) BYTE        43200020
         LTR   R7,R7               ARE THERE ANY TASKS WAITING FOR WORK 43400020
         BZ    XQMNQQ60            NO-BR TO CONTINUE                    43600020
         LR    R1,R7               YES-LOAD ECB PT                      43800020
         POST  (R1)                POST THE TASK                        44000020
         L     R7,D4(R7)           LOAD ADDRESS OF NEXT TASK'S 8-BYTE   44200020
*                                    CONTROL AREA                       44400020
         B     XQMNQQ20            BR TO TEST FOR ANOTHER TASK          44600020
*                                    WAITING FOR WORK                   44800020
XQMNQQ30 L     R14,MTWO            NEGATIVE INCREMENT BETWEEN PRIORITY  45000020
*                                    ENTRIES IN THE QCR                 45200020
XQMNQQ40 AR    R12,R14             ADD NEGATIVE INCREMENT TO NEGATIVE   45400020
*                                    OFFSET FOR NEXT PRIORITY           45600020
         LH    R11,QCREND(R9,R12)  GET NN OF LAST QUEUE ENTRY OF        45800020
*                                    THIS PRIORITY                      46000020
         LTR   R11,R11             IS THERE A JOB OF THIS PRIORITY      46200020
         BZ    XQMNQQ40            NO-BR TO PICK UP NEXT PRIORITY       46400020
XQMNQQ50 LA    R15,CNVTMBB         PT TO COMPLETE CONVERSION            46600020
         BAL   R7,TTRCNVT0         BR TO CONVERT NN TO MBBCCHHR         46800020
         LA    R9,LTHAREA(R6)      PT TO AREA INTO WHICH TO READ LTH    47000020
         LA    R10,LTHLNGTH        LTH LENGTH                           47200020
         BAL   R7,READXDAP         BR TO READ LTH                       47400020
         MVC   QMLNK(L2),QMLNK-QMCAN(R9) LINK LTH JUST READ IN TO       47600020
*                                          THE CURRENT JOB'S LTH        47800020
         MVC   QMLNK-QMCAN(L2,R9),QMTID LINK CURRENT JOB'S LTH TO       48000020
*                                         LTH JUST READ IN              48200020
         XC    QMTLN(L2),QMTLN     ZERO OUT PT TO NEXT LOGICAL TRACK    48400020
*                                    IN NEW LTH                         48600020
         MVC   LTHDAD(L8,R6),XQMSKAD(R2) SAVE MBBCCHHR OF CURRENT       48800020
*                                          JOB'S LTH                    49000020
         MVC   LTHSECT(SECTLG,R6),SECT(R2)  SAVE SECTOR OF LTH   S20201 49050020
         EJECT                                                          49200020
*********************************************************************** 49400020
INITSW   EQU   X'04'                                                    49600020
LTHDAD   EQU   76                                                       49800020
XQMSKAD  EQU   36                                                       50000020
*********************************************************************** 50200020
XQMNQQ60 LH    R11,QMTID           NN OF NEW LTH                        50400020
         CLI   QMDPI,D0            WILL DISPATCHING PRIORITY DIFFER     50600020
*                                    FROM SCHEDULING                    50800020
         BE    XQMNQQ70            NO-BR TO CONTINUE                    51000020
         XI    QMDPI,CHNGPRI       YES-TURN OFF CHANGE INDICATOR        51200020
         MVC   QMPRI(L1),QMDPI     INSERT DISPATCHING PRIORITY          51400020
         XC    QMDPI(L1),QMDPI     ZERO PRIORITY CHANGE BYTE            51600020
XQMNQQ70 LA    R15,CNVTMBB         PT TO COMPLETE CONVERSION            51800020
         BAL   R7,TTRCNVT0         BR TO CONVERT NN TO MBBCCHHR         52000020
         OI    QMSTA,INITSW        TURN ON INITIATOR SWITCH IN LTH      52200020
         MVC   QMPOP,QMOSC         MOVE INTO QMPOP(FLD THAT IS          52400020
*                                    MEANINGLESS FOR AN ENQUEUED JOB)   52600020
*                                    THE ORIGINAL STEP CLASS NAME OR,   52800020
*                                    FOR A JOB TO BE PUT INTO THE HOLD  53000020
*                                    Q,THE NAME OF ITS JOB CLASS,TO BE  53200020
*                                    USED FOR THE RELEASE OF THE JOB    53400020
*                                    TO ITS PROPER CLASS                53600020
         XC    QMTLN(L2),QMTLN     ZERO OUT PT TO NEXT LOGICAL TRACK    53800020
         LR    R9,R4               PT TO LTH                            54000020
         LA    R10,LTHLNGTH        LTH LENGTH                           54200020
         BAL   R7,WRTEXDAP         BR TO WRITE OUT LTH                  54400020
         CLC   QMTID(L2),QCRAREA(R6) IS THERE ANOTHER LTH TO BE WRITTEN 54600020
         BE    XQMNQQ80            NO-BR TO CONTINUE                    54800020
         MVC   XQMSKAD(L8,R2),LTHDAD(R6) YES-RESTORE MBBCCHHR           55000020
         MVC   SECT(SECTLG,R2),LTHSECT(R6)  AND SECTOR OF LTH    S20201 55050020
         LA    R9,LTHAREA(R6)      PT TO LTH                            55200020
         BAL   R7,WRTEXDAP         BR TO WRITE OUT PREIVOUS LTH         55400020
         EJECT                                                          55600020
*********************************************************************** 55650020
*                                                                     * 55700020
*                           RETURN TO CALLER                          * 55750020
*                                                                     * 55760020
*********************************************************************** 55770020
XQMNQQ80 MVC   XQMSKAD(L8,R2),QCRDAD(R6) RESTORE MBBCCHHR OF QCR        55800020
         MVC   SECT(SECTLG,R2),QCRSECT(R6)  AND SECTOR VALUE     S20201 55850020
         LA    R9,QCRAREA(R6)      PT TO QCR                            56000020
         LA    R10,QCRLNGTH        QCR LENGTH                           56200020
         BAL   R7,WRTEXDAP         BR TO WRITE QCR                      56400020
         SR    R7,R7               SET NORMAL RETURN CODE               56600020
RETURN   LA    R14,IEFSQCBS        PUT PT TO MAJOR NAME                 56800020
         ST    R14,QNAME             INTO PARAMETER LIST                57000020
         LA    R14,IEFQ1QCB        PUT PT TO MINOR NAME                 57200020
         ST    R14,RNAME             INTO PARAMETER LIST                57400020
         DEQ   MF=(E,IEFQMNQA)     DEQUEUE OFF MASTER HANDLE            57600020
JCTRETN  LR    R1,R6               PT TO WORK AREA                      57800020
         L     R14,RETADDR(R6)     RETURN ADDRESS                       58000020
         FREEMAIN R,LV=WKAREA3,A=(R1) FREE WORK AREA                    58200020
ECBFREE  EQU   X'10'                                                    58220020
         TM    QMEIA,ECBFREE       IS ECB/IOB CORE TO BE FREED          58240020
         BO    RETCODE             NO-BR TO CONTINUE             S20201 58250020
         LR    R1,R2               YES-ECB/IOB PT                S20201 58260020
         S     R1,FOUR             DECREMENT PT TO LENGTH FLD           58270020
         L     R0,D0(R1)           LENGTH OF ECB/IOB CORE               58280020
         FREEMAIN R,LV=(0),A=(1)   FREE ECB/IOB                         58290020
RETCODE  LR    R15,R7              RETURN CODE                          58460020
         LR    R1,R4               RESTORE QMPA PT                      58600020
         RETURN RC=(15)            RETURN TO CALLER                     58800020
         EJECT                                                          59000020
*********************************************************************** 59050020
*                                                                     * 59100020
*                        CONVERT NN TO TTR                            * 59150020
*                                                                     * 59160020
*********************************************************************** 59170020
TTRCNVT0 LH    R12,QMKTT           TT OF FIRST JOBQ TRACK               59200020
         SH    R11,QMFQR           SUBTRACT NN OF FIRST RECORD ON TRACK 59400020
*                                    CONTAINING ONLY JOB Q ENTRIES      59600020
         BM    TTRCNVT1            BR IF RECORD ON MIXED TRACK          59800020
         LH    R9,QMRPT            NO. OF JOB Q RECORDS PER PHYSICAL    60000020
*                                    TRACK                              60200020
TTRCNVT2 SR    R10,R10             CLEAR REGISTER FOR DIVIDE            60400020
         DR    R10,R9              DIVIDE NN BY NO. OF RECORDS PER      60600020
*                                    PHYSICAL TRACK                     60800020
         AR    R11,R12             ADJUST TT JUST CALCULATED TO REFLECT 61000020
*                                    A TRUE TT FROM THE BEGINNING OF    61200020
*                                    THE QUEUE MANAGER'S EXTENT         61400020
         SLL   R11,D8              SHIFT TT TO PROPER POSITION          61600020
         LA    R0,D1(R10,R11)      TTR= TT + CURRENT NN + 1             61800020
TTRCNVT3 SLL   R0,D8               SHIFT TTR TO PROPER POSITION         62000020
         BR    R15                 BR BACK WITH TTR0 OR BR TO           62200020
*                                    COMPLETE CONVERSION                62400020
TTRCNVT1 AH    R11,QMFQR           RESTORE ORIGINAL NN                  62600020
         AH    R11,QMNHM           ADD NO. OF QCRS ON MIXED TRACK       62800020
         BCTR  R12,D0              GET TT OF MIXED TRACK                63000020
         SLL   R12,D8              SHIFT TT TO PROPER POSITION          63200020
         LA    R0,D0(R12,R11)      PUT TTR0 INTO REG 0                  63400020
         B     TTRCNVT3                                                 63600020
         EJECT                                                          63800020
*********************************************************************** 64000020
*                                                                     * 64050020
*                       CONVERT TTR TO MBBCCHHR                       * 64100020
*                                                                     * 64150020
*********************************************************************** 64160020
CNVTQ    EQU   4                                                 S20201 64170020
RPSON    EQU   X'10'                                             S20201 64180020
*********************************************************************** 64190020
CNVTMBB  TM    QMRPS,RPSON         IS Q ON AN RPS DEVICE         S20201 64192020
         BNO   CNVTMB30            NO-BR TO CONTINUE             S20201 64194020
         LR    R5,R0               YES-SAVE TTR                  S20201 64196020
         TM    QCRINOT(R6),ONES    IS THIS A QCR                 S20201 64198020
         BO    QCRCNVRT            YES-GO SET UP FOR QCR         S20201 64198420
         L     R15,CVTPTR          NO-GET CVT PTR                S20201 64198820
         USING CVTD,R15            ADDRESSABILITY FOR CVT        S20201 64199220
         L     R15,CVT0SCR1        SUPERVISOR SECTOR CONVERT     S20201 64199620
         DROP  R15                   ROUTINE ADDRESS             S20201 64199720
         L     R15,CNVTQ(R15)      SECTOR CONVERT ROUTINE ADDR   S20201 64199820
         BALR  R14,R15             BR TO CONVERT ROUTINE         S20201 64199920
SECTCNVT L     R11,QMEIA           RESTORE ECB/IOB PT            S20201 64249920
         LA    R11,SECT(R11)       PLACE DEVICE TYPE CODE AND    S20201 64259920
         SLL   R11,D8                ADDR OF WHERE TO SAVE       S20201 64269920
         LH    R10,QMRPS             SECTOR INTO REGISTER TWO    S20201 64279920
         SRDL  R10,D8                FOR SECTOR CONVERT ROUTINE  S20201 64289920
         LR    R2,R11                                            S20201 64291920
         L     R15,CVTPTR          CVT PT                        S20201 64293920
         USING CVTD,R15            ADDRESSABILITY FOR CVT        S20201 64295920
         L     R15,CVT0SCR1        SUPERVISOR SECTOR CONVERT     S20201 64297920
         DROP  R15                   ROUTINE ADDRESS             S20201 64298320
         BALR  R14,R15             BR TO SUPERVISOR CONVERT      S20201 64298720
         LR    R0,R5               RESTORE TTR                   S20201 64299120
         L     R2,QMEIA            RESTORE ECB/IOB PT            S20201 64299520
CNVTMB30 ST    R2,ECBPT(R6)        SAVE ECB/IOB PT               S20201 64299620
         LA    R2,XQMSKAD(R2)      PT TO MBBCCHHR IN IOB                64299920
         LA    R1,QMRDEB           PT TO RESIDENT DEB                   64400020
         L     R15,CVTPT           CVT PT                               64600020
         L     R15,QMSPCV(R15)     PT TO SUPERVISOR CONVERSION ROUTINE  64800020
         BALR  R14,R15             BR TO CONVERT TTR TO MBBCCHHR        65000020
         L     R2,ECBPT(R6)        RESTORE ECB/IOB PT                   65200020
         BR    R7                  BR TO CONTINUE                       65400020
QCRCNVRT SRDL  R0,16               SET UP REG 0 FOR SECTOR       S20201 65600020
         LA    R0,QCRLNGTH           CONVERT RTN WITH QCR        S20201 65650020
         SLL   R0,D8                 LENGTH, ZERO AND RECORD     S20201 65700020
         SRDL  R0,24                 NUMBER                      S20201 65750020
         LR    R0,R1               LOAD REG 0 FOR CONVERT        S20201 65800020
         B    SECTCNVT             BRANCH TO ROUTINE             S20201 65850020
 EJECT                                                                  65900020
*********************************************************************** 65950020
*                                                                     * 65960020
*                           READ OR WRITE                             * 65970020
*                                                                     * 65980020
*********************************************************************** 65990020
WRTEXDAP LA    R11,SECT(R2)        LOAD SECTOR ADDR FOR XDAP     S20201 65992020
         XDAP  (2),WI,(3),(9),(10),,,(11),MF=E                   S20201 65994020
         B     IOWAIT              BR TO WAIT FOR I/O COMPLETION        66000020
READXDAP LA    R11,SECT(R2)        LOAD SECTOR ADDR FOR XDAP     S20201 66200020
         XDAP  (2),RI,(3),(9),(10),,,(11),MF=E                   S20201 66250020
         EJECT                                                          66600020
*********************************************************************** 66650020
*                                                                     * 66700020
*                       WAIT FOR I/O COMPLETION                       * 66750020
*                                                                     * 66760020
*********************************************************************** 66800020
NORMALIO EQU   X'7F'                                                    67000020
IOERR    EQU   12                                                       67200020
*********************************************************************** 67400020
IOWAIT   LR    R1,R2               ECB/IOB PT                           67600020
         LA    R1,D0(R1)           CLEAR HIGH-ORDER BYTE OF REG 1       67800020
         WAIT  1,ECB=(1)           WAIT FOR I/O COMPLETION              68000020
         CLI   D0(R2),NORMALIO     IS I/O COMPLETION NORMAL             68200020
         BCR   8,R7                YES-BR TO CONTINUE                   68400020
         LA    R7,IOERR            I/O ERROR RETURN CODE                68600020
         C     R10,JCTWRT          DID ERROR OCCUR WHILE WRITING JCT    68800020
         BE    JCTRETN             YES-SKIP DEQUEUE AND RETURN          69000020
         B     RETURN              NO-BR TO EXIT LINKAGE                69200020
         EJECT                                                          69400020
*********************************************************************** 69600020
QCRDAD   EQU   12                                                       69800020
ECBPT    EQU   8                                                        70000020
CVTPT    EQU   16                                                       70200020
QMSPCV   EQU   28                                                       70400020
CHNGPRI  EQU   X'80'                                                    70600020
*********************************************************************** 70800020
         DS    0F                                                       71000020
MTWO     DC    F'-2'                                                    71200020
FOUR     DC    F'4'                                                     71400020
JCTWRT   DC    F'176'                                                   71600020
IEFQMNQA DS    0F                                                       71800020
         DC    AL1(255)                                                 72000020
         DC    AL1(2)                                                   72200020
         DC    BL1'01000000'                                            72400020
         DC    AL1(0)                                                   72600020
QNAME    DC    A(0)                                                     72800020
RNAME    DC    A(0)                                                     73000020
IEFSQCBS DC    C'SYSIEFSD'                                              73200020
IEFQ1QCB DC    C'Q1'                                                    73400020
         EJECT                                                          73600020
         IEFQMNGR                                                       73800020
QMCAP    EQU   IOPARAMS+24         PT TO STACK AND Q BREAK INFO         74000020
QMOSC    EQU   QMTID+2             1-BYTE FLD FOR 'REMEMBERING' OLD     74200020
*                                    STEP CLASS OR JOB CLASS            74400020
QMDPI    EQU   QMTID+3                                                  74600020
         EJECT                                                          74800020
QMRCAR   DSECT                                                          75000020
         IEFQMRES                                                       75200020
 EJECT                                                                  75400020
CVTD     DSECT                                                          75450020
         CVT                                                            75500020
         END                                                            75600020
