         TITLE 'IEFYSVMS - MESSAGE BLOCKING ROUTINE'                    00020000
*********************************************************************** 00040000
*                       MESSAGE BLOCKING ROUTINE                      * 00060000
*********************************************************************** 00080000
*                                                                     * 00100000
* STATUS - CHANGE LEVEL 000                                           * 00120000
*                                                                     * 00140000
* FUNCTION: TO BLOCK SYSTEM MESSAGES INTO STANDARD SIZE RECORDS,      * 00160000
* CALLED SYSTEM MESSAGE BLOCKS, AND TO LINK THESE BLOCKS TOGETHER.    * 00180000
*                                                                     * 00200000
* ENTRY POINTS: IEFYS                                                 * 00220000
*                                                                     * 00240000
* INPUT: LCTPARM1 CONTAINS THE ADDRESS OF THE MESSAGE, LCTPARM2       * 00260000
* CONTAINS THE MESSAGE LENGTH IN THE LOW ORDER BYTE, GR12 CONTAINS    * 00280000
* THE ADDRESS OF THE LCT.                                        A35715 00310020
*                                                                     * 00340000
* OUTPUT: THE MESSAGE IS PLACED IN AN SMB                             * 00360000
* EXTERNAL REFERENCES - TO THE FOLLOWING QUEUE MANAGER SUBROUTINES -  * 00380000
*     IEFQASGQ - TO ASSIGN A RECORD FOR A NEW SMB                     * 00400000
*       IEFQMRAW - TO WRITE AN SMB TO EXTERNAL STORAGE                * 00420000
*                                                                     * 00440000
*                                                                     * 00460000
* EXIT - NORMAL RETURN IS MADE VIA REGISTER 14                        * 00480000
*                                                                     * 00500000
* NOTES: THE MESSAGE LENGTH CANNOT BE GREATER THAN 161 BYTES.    A35715 00520020
*        THERE MUST BE A SMB IN CORE POINTED TO BY LCTSMBAD.     A35715 00540020
*                                                                     * 00580000
* TABLES/WORK AREAS: LCT,SCT,THE SMB                             A35715 00610020
*                                                                     * 00640000
* ATTRIBUTES - REENTRANT                                              * 00660000
*                                                                     * 00680000
*********************************************************************** 00700000
IEFYS    CSECT                                                          00720000
* C 047800                                                        M0691 00720421
*003000-003200,005200-005600,006000-006200,007400-008000         A35715 00721020
*018800-020200                                                   A35715 00722020
*1094025400,030000,037280,037320                                  17371 00725017
*0050013000,018600,025400,030000,037000                           15764 00730016
         STM   R0,R15,0(R13)           STORE USERS REGISTERS     A35715 00770020
         BALR  R10,0                    LOAD THE BASE REG.FOR THIS ROUT 00820000
*********************************************************************** 00840000
**                 THE REGISTERS DEFINED BY THE FOLLOWING USING      ** 00860000
**             STATEMENTS WILL BE LOADED WITH THE CORRECT VALUE      ** 00880000
**             BEFORE IT BECOMES NECESSARY TO USE THEM AS BASE       ** 00900000
**             REGISTERS.                                            ** 00920000
*********************************************************************** 00940000
         USING LCT,R12                  THE LCT IS A DSECT DEFINING     00960000
*                                       THE LINKAGE CONTROL TABLE       00980000
         USING *,R10                    THIS SETS UP GENERAL REGISTER   01000000
*                                       TEN AS THE BASE REGISTER FOR    01020000
*                                       THIS ROUTINE                    01040000
         USING SMB,R8                   THE SMB IS A DSECT DEFINING A   01060000
*                                       SYSTEM MESSAGE BLOCK            01080000
         USING SCT,R7                   THE SCT IS A DSECT DEFINING THE 01100000
*                                       STEP CONTROL TABLE              01120000
         USING IOPARAMS,R1              IOPARAMS IS A DSECT DEFINING    01140000
*                                       THE QUEUE MANAGER PARAMETER     01160000
*                                       AREA                            01180000
         L     R8,LCTSMBAD              LOAD ADDR.OF THE SMB FROM A     01200000
*                                       HOLD AREA IN THE LCT            01220000
         LTR   R8,R8                    IS THE ADDR.ZERO DENOTING NO    01240000
*                                       SMB IN CORE                     01260000
         BC    7,NOERR1                 BRANCH IF NOT ZERO              01280000
         BC    15,ACCTERR               YES, WTO AND RETURN       15764 01300016
*********************************************************************** 01320000
**             DETERMINE IF MESSAGE CAN BE ADDED TO THE CURRENT SMB  ** 01340000
*********************************************************************** 01360000
NOERR1   LH    R6,SMBNABPT              LOAD RELATIVE POINTER TO NEXT   01380000
*                                       AVAILABLE BYTE IN THE SMB       01400000
         SR    R5,R5                    INITIALIZE REGISTER TO BE USED  01420000
*                                       TO HOLD THE MESSAGE LENGTH      01440000
         IC    R5,LCTPARM2+3            PICK UP THE ONE BYTE MESSAGE    01460000
*                                       LENGTH FROM INPUT PARAMETER     01480000
         LTR   R5,R5                    IS MSG. LENGTH ZERO       15764 01482016
         BZ    ACCTERR                  YES, WTO AND RETURN       15764 01484016
         LA    R4,1(R5,R6)              CALCULATE TOTAL LENGTH OF THE   01500000
*                                       MESSAGES IN THE SMB INCLUDING   01520000
*                                       THE NEW MESSAGE                 01540000
         C     R4,SMBLGTH               WILL THE NEW MESSAGE CAUSE AN   01560000
*                                       OVERFLOW OF THE SMB             01580000
         BNH   MSGADDA                  BRANCH IF MESSAGE WILL FIT IN   01600000
*                                       THE SMB                         01620000
*********************************************************************** 01640000
**               THE CURRENT SMB DOES NOT CONTAIN SUFFICIENT ROOM    ** 01660000
**             TO ACCOMODATE THE NEW MESSAGE.  A NEW TTR WILL BE     ** 01680000
**             ASSIGNED FOR THE NEXT SMB AND STORED IN THE CHAIN     ** 01700000
**             ADDRESS PORTION OF THE CURRENT SMB.  THE CURRENT SMB  ** 01720000
**             WILL THEN BE WRITTEN ON DISK AND THE CORE IT OCCUPIED ** 01740000
**             WILL BE INITIALIZED FOR THE NEW SMB.                  ** 01760000
*********************************************************************** 01780000
         C     R5,SMBLGTH               IS THE MESSAGE TO LONG          01800000
*                                      (GREATER THAN 161 BYTES)         01820000
         BL    NOERR2                   BRANCH NO                       01840000
         SR    R5,R5                    CLEAR R5,  MSG TO LONG    15764 01850016
         LA    R5,161                   TRUNCATE TO 161 BYTES.    15764 01860016
NOERR2   DS    0H                                                       02040000
         GETMAIN    R,LV=8                   CORE FOR EXT PARM LIST     02060000
         LR    R3,R1                         R3 = ADDR OF EXT PARM LIST 02080000
         L     R1,LCT+68                     R1 = ADDR OF S/O QMPA      02100000
*                                       MANAGER PARAMETER AREA          02120000
         LA    R13,64(R13)              BUMP GR 13 TO THE NEXT REG.     02140000
*                                       SAVE AREA (THIS AREA WILL BE    02160000
*                                       USED WHEN CONTROL IS PASSED TO  02180000
*                                       THE QMGR.TO SAVE THE REGISTERS  02200000
         MVI   QMPOP,X'01'              MOVE THE OPERATION CODE FOR     02220000
*                                       ASSIGN TO THE QMGR.PARA.AREA    02240000
         LA    R2,SMBNEXT               LOAD THE ADDR.OF THE HOLD AREA  02260000
*                                       IN THE SMB FOR THE SMB CHAIN    02280000
*                                       TTR                             02300000
         ST    R2,QMPCL                 STORE AS THE ADDR.OF THE QMGR.  02320000
*                                       EXTERNAL PARAMETER LIST         02340000
         MVI   QMTPY,3                  SET TYPE FLD TO SYSOUT          02360000
         MVI   QMPCL,X'10'              TELL QMGR.TO ASSIGN ONE TTR     02380000
         OI    QMPRI,X'20'             INDICATE INITIATOR QMPA     994  02400000
         LR    R2,R1                    LOAD ADDR.OF PARA.AREA INTO A   02420000
*                                       REG.THAT WILL BE SAVED BY QMGR. 02440000
         L     R15,QASGN               ASSIGN FUNCTION                  02460000
         BALR  R14,R15                  LINK TO Q-MGR ROUTINE           02480000
         LTR   R15,R15                  TEST FOR ERROR RETURN FROM QMGR 02500000
         BC    8,NOERR3                 BRANCH IF THERE IS NO ERROR     02520000
         BC    15,CUEIO1                 YES, WTO AND RETURN      17371 02540017
NOERR3   LR    R1,R2                    RESTORE ADDR.OF PARA.AREA       02560000
         MVI   QMPOP,X'03'              MOVE THE OPERATION CODE FOR A   02580000
*                                       WRITE TO THE QMGR.PARA.AREA     02600000
         ST    R3,QMPCL                 STORE ADDR.OF EXTERNAL PARA.    02620000
*                                       THIS VALUE WAS LOADED AT THE    02640000
*                                       BEGINNING OF THIS ROUTINE       02660000
         MVI   QMPCL,X'01'              TELL THE QMGR.TO WRITE ONE      02680000
*                                       RECORD                          02700000
         L     R9,SMBDSKAD              LOAD TTR FOR CURRENT SMB        02720000
         IC    R9,SMBLGTH               USE HIGH ORDER ZERO OF CONSTANT 02740000
*                                       TO ZERO RECORD CODE IN LOW      02760000
*                                       ORDER BYTE OF WORD CONTAINING   02780000
*                                       TTR                             02800000
         STM   R8,R9,0(R3)              STORE CORE ADDR.AND DISK ADDR.  02820000
*                                       IN QMGR.EXTERNAL PARA.LIST      02840000
         L     R15,QMRAW               WRITE FUNCTION                   02860000
         BALR  R14,R15                  LINK TO QMGR. ROUTINE           02880000
         LR    R7,R15                   GET ERROR RETURN            706 02900000
         LR    R1,R3                         R1 = ADDR OF EXT PARM LIST 02920000
         FREEMAIN   R,LV=8,A=(1)                                        02940000
         LTR   R7,R7                    TEST FOR ERROR RETURN      706  02960000
         BC    8,NOERR4                 BRANCH IF THERE IS NO ERROR     02980000
         BC    15,CUEIO2                 YES, WTO AND RETURN      17371 03000017
NOERR4   S     R13,RSALGTH              RESTORE ADDR.TO USERS REG SAVE  03020000
*                                       AREA                            03040000
         MVC   SMBDSKAD(3),SMBNEXT      MOVE NEW TTR TO CURRENT TTR     03060000
         MVI   3(R8),5                  SET SMB RECORD ID               03080000
         L     R7,LCTSCTAD              LOAD ADDR.OF THE SCT            03100000
         MVC   SCTADSMB(3),SMBNEXT      UPDATE THE POINTER TO THE SMB   03120000
*                                       IN THE SCT                      03140000
         XC    SMBNEXT(172),SMBNEXT     ZERO THE CORE FOR THE NEW SMB   03160000
         SR    R6,R6                    RELATIVE POINTER TO THE NEXT    03180000
*                                       AVAILABLE BYTE IN THE SMB IS    03200000
*                                       NOW ZERO                        03220000
         LA    R4,1(R5)                 TOTAL LENGTH OF THE MESSAGES IN 03240000
*                                       THE SMB IS NOW THE LENGTH OF    03260000
*                                       THE NEW MESSAGE PLUS THE LENGTH 03280000
*                                       (ONE BYTE) OF THE LENGTH FIELD  03300000
*********************************************************************** 03320000
**             THE USERS MESSAGE IS NOW MOVE INTO THE SMB            ** 03340000
*********************************************************************** 03360000
MSGADDA  LA    R6,SMBMSGLN(R6)          OBTAIN THE ACTUAL CORE ADDR.OF  03380000
*                                       THE FIRST AVAILABLE BYTE IN     03400000
*                                       THE SMB                         03420000
         STC   R5,0(R6)                 STORE LENGTH OF MESSAGE AS      03440000
*                                       FIRST BYTE OF MSG.IN THE SMB    03460000
         L     R1,16(0)                 COMPARE ADDR. OF          15764 03462016
         LA    R1,164(R1)               MESSAGE WITH UPPER        15764 03464016
         L     R1,0(R1)                 BOUNDRY OF CORE MINUS     15764 03466016
         SR    R1,R5                    LENGTH OF MESSAGE         15764 03468016
         CL    R1,LCTPARM1              IF MESSAGE IS             15764 03470016
         BC    4,ACCTERR                OUT OF CORE, WTO & RETURN.15764 03472016
         L     R1,LCTPARM1              LOAD ADDR.OF THE MESSAGE TO     03480000
*                                       BE PUT INTO THE SMB (INPUT      03500000
*                                       PARAMETER)                      03520000
         S     R5,EXFACT                SUBTRACT ONE FROM THE MESSAGE   03540000
*                                       LENGTH (AN EXECUTE INSTRUCTION  03560000
*                                       REQUIRES A LENGTH ONE LESS      03580000
*                                       THAN THE ACTUAL LENGTH          03600000
         EX    R5,MSGMOVE               MOVE MSG.TO THE SMB             03620000
         STH   R4,SMBNABPT              STORE THE UPDATED POINTER TO    03640000
*                                       THE FIRST AVAILABLE BYTE IN     03660000
*                                       THE SMB                         03680000
RETURN   LM    R0,R15,0(R13)            RESTORE USERS REGISTERS   15764 03690016
         RETURN                                                         03720000
*********************************************************************** 03722016
*                 **  WTO FOR SYSTEM OR  I/O ERROR  **                * 03724016
*********************************************************************** 03726016
ACCTERR  L     R7,LCTJCTAD                                        17371 03726817
         USING JCTD,R7                   GET JOBNAME FOR WTO      17371 03727617
         MVC   ACCTWTO+16(8),JCTJNAME                             17371 03728417
* JOB STATUS DESCRIPTOR CODE TO MASTER CONSOLE - INFO                   03728718
ACCTWTO  WTO   'IEF289I          ACCT/SYSTEM ERROR',ROUTCDE=(2),       X03729018
               DESC=(6)                                                 03729318
* NO SMB IN CORE - RETURNS TO CALLER                                    03729618
         BC    15,RETURN                DO NOT CONTINUE - RETURN  15764 03730016
CUEIO1   LR    R1,R3                     REG1= ADDR OF EXT REGS   17371 03731017
         FREEMAIN  R,LV=8,A=(1)          FREE PARM LIST AREA      17371 03732017
CUEIO2   S     R13,RSALGTH       GET ADDR TO USERS REG SAVE AREA  17371 03733017
         BC    15,RETURN                DO NOT CONTINUE - RETURN  15764 03734016
*********************************************************************** 03740000
*                  ** EQUATES FOR THE GENERAL REGISTERSS **           * 03760000
*********************************************************************** 03780000
R0       EQU   0                                                        03800000
R1       EQU   1                                                        03820000
R2       EQU   2                                                        03840000
R3       EQU   3                                                        03860000
R4       EQU   4                                                        03880000
R5       EQU   5                                                        03900000
R6       EQU   6                                                        03920000
R7       EQU   7                                                        03940000
R8       EQU   8                                                        03960000
R9       EQU   9                                                        03980000
R10      EQU   10                                                       04000000
R11      EQU   11                                                       04020000
R12      EQU   12                                                       04040000
R13      EQU   13                                                       04060000
R14      EQU   14                                                       04080000
R15      EQU   15                                                       04100000
*********************************************************************** 04120000
*                          ** ADDRESS CONSTANTS **                    * 04140000
*********************************************************************** 04160000
QASGN  DC  V(IEFQASGN)                                                  04180000
QMRAW  DC  V(IEFQMRAW)                                                  04200000
*********************************************************************** 04220000
*                          ** EXECUTED INSTRUCTIONS **                * 04240000
*********************************************************************** 04260000
MSGMOVE  MVC   1(1,R6),0(R1)            THE INSTRUCTION USED TO MOVE    04280000
*                                       THE USERS MSG TO THE SMB        04300000
*********************************************************************** 04320000
*                         ** CONSTANTS NEEDED FOR PROG. **            * 04340000
*********************************************************************** 04360000
SMBLGTH  DC    F'162'                   THE LENGTH OF THE MESSAGE       04380000
*                                       AREA IN THE SMB                 04400000
RSALGTH  DC    F'64'                    THE LENGTH OF A REG.SAVE AREA   04420000
EXFACT   DC    F'1'                     CONSTANT FOR THE EX.INSTR.      04440000
*********************************************************************** 04460000
*                  ** DSECTS OF AREAS REFERENCED IN PROG. **          * 04480000
*********************************************************************** 04500000
LCT      DSECT                                                          04520000
         IEFALLCT                                                       04540000
JCTD     DSECT                                                    17371 04540417
******************************************************************17371 04540817
**                                                                17371 04541217
**                       JOB CONTROL TABLE                        17371 04541617
**                                                                17371 04542017
******************************************************************17371 04542417
         DS    0D                                                 17371 04542817
INJMJCT  EQU   *                                                  17371 04543217
JCTDSKAD DS    CL3      DISK ADDRESS OF THIS JCT                  17371 04543617
JCTIDENT DS    CL1      JCT ID = 64                               17371 04544017
JCTID    EQU   0                                                  17371 04544417
JCTJSRNO DS    CL1      INTERNAL JOB SERIAL NUMBER                17371 04544817
JCTJBLBS DS    0C       JOBLIB SWITHC BITS 0-3                    17371 04545217
JCTJSTAT DS    1C       INTERNAL JOB TYPE                         17371 04545617
JCTJSTPC EQU   32       BIT-2/JOB STEP CANCELLED BY COND CODES    17371 04546017
INCMSTS  EQU   4        BIT-5 JOB FAILED BIT                      17371 04546417
*                            BIT 5 = 1 JOB FAILED                 17371 04546817
*                            BIT 6 = 0 GO JOB                     17371 04547217
INDMCTLG EQU   2        BIT 6 = 1 CATALOG JOB                     17371 04547617
INCMCAT  EQU   2        BIT 6 CATALOG BIT                         17371 04548017
INCMNSET EQU   1        BIT 7  NONSETUP                           17371 04548417
*                            BIT 7 = 0 SETUP JOB                  17371 04548817
*                            BIT 7 = 1 NONSETUP JOB               17371 04549217
JCTJMGPO DS    CL1      MESSAGE CLASS                             17371 04549617
JCTJMGLV DS    0C       4 BITS FOR MESSAGE LEVEL                  17371 04550017
INCMMGL1 EQU   16       MESSAGE LEVEL BIT                         17371 04550417
JCTJPRTY DS    1C       4 BITS FOR JOB PRIORITY                   17371 04550817
JCTJNAME DS    CL8      JOBNAME                                   17371 04551217
JCTJTPTN DS    CL8      T/P TERMINAL NAME                         17371 04551617
JCTPDQDA DS    CL4      DISK ADDRESS OF PDQ                       17371 04552017
JCTBCTDA DS    CL4      DISK ADDRESS OF BIAS CT TABLE             17371 04552417
JCTSDKAD DS    CL4      DISK ADDRESS OF FIRST SCT                 17371 04552817
JCTSMBAD DS    CL4      DISK ADDRESS OF FIRST SMB                 17371 04553217
JCTACTAD DS    CL4      DISK ADDRESS OF FIRST ACT                 17371 04553617
JCTDSSBA DS    CL4      DISK ADDRESS OF 1ST DATA S SO B           17371 04554017
JCTDSBAD DS    CL4      DISK ADDRESS OF LAST DATA SET B           17371 04554417
JCTSMBID DS    CL2      KEY (OF TRACK ID) FOR SMBS                17371 04554817
JCTJDPCD DS    CL2      DEPENDENCY CODE                           17371 04555217
JCTJDPOP DS    CL2      DEPENDENCY OPERATOR                       17371 04555617
         DS    CL28     ROOM FOR 7 MORE DEPS                      17371 04556017
JCTLNGTH EQU   86       LENGTH OF JCT                             17371 04556417
SCT      DSECT                                                          04560000
         IEFASCTB                                                       04580000
SMB      DSECT                                                          04600000
SMBDSKAD DS    CL3                      DISK OF THIS SMB                04620000
SMBIDENT DS    1C                       TABLE ID SMB                    04640000
SMBID    EQU   5                                                        04660000
SMBNEXT  DS    CL4                      DISK ADDR.OF THE NEXT SMB       04680000
         DS    CL4                                                      04700000
SMBNABPT DS    CL2                      RELATIVE PTR.TO NEXT AVAIL.BYTE 04720000
SMBMSGLN DS    1C                       LENGTH OF MESSAGE               04740000
SMBMESAG DS    CL165                                                    04760000
         IEFQMNGR                                                 M0691 04780021
         END                                                            04800000
