IGC037   START 0                                                        00020000
         TITLE 'IEWSUOVR....OVERLAY SUPERVISOR,RESIDENT MOD. FOR VMS'   00040000
*                                                                       00060000
*STATUS  CHANGE LEVEL 0.                                                00080000
*                                                                       00100000
*FUNCTION/OPERATION - TO HANDLE OVERLAY REQUESTS FROM PROBLEM PROGRAMS. 00120000
*   THIS MODULE RESIDES IN THE RESIDENT NUCLEUS. IT IS GIVEN CONTROL    00140000
*   BY THE SVC INTERRUPT HANDLER FOR SVC 37 AND SVC 45. IT INITIALIZES  00160000
*   INDICATORS AND POINTERS AND PASSES CONTROL TO THE MAIN PROCESSING   00180000
*   MODULE OF OVERLAY SUPERVISOR. UPON RETURN TO THIS MODULE, A RETURN  00200000
*   CODE IS EXAMINED AND IF AN ERROR HAS BEEN DETECTED, AN ABEND IS     00220000
*   ISSUED.                                                             00240000
*                                                                       00260000
*ENTRY POINTS                                                           00280000
*        IGC037 - SEGLD OR SEGWT REQUEST.                               00300000
*              IF REGISTER 0 CONTAINS 0 REQUEST IS SEGLD.               00320000
*              IF REGISTER 0 CONTAINS 1 REQUEST IS SEGWT.               00340000
*              REGISTER ONE POINTS TO AN ENTAB ENTRY CONTAINING THE     00360000
*               NUMBER OF THE REQUESTED SEGMENT.                        00380000
*        IGC045 - CALL OR BRANCH.                                       00400000
*              REGISTER 15 POINTS TO AN ENTAB ENTRY CONTAINING THE      00420000
*               NUMBER OF THE REQUESTED SEGMENT AND THE RELOCATED VALUE 00440000
*               OF THE SYMBOL TO WHICH THE CALL (OR BRANCH) IS BEING    00460000
*               MADE.                                                   00480000
*                                                                       00500000
*INPUT  (SEE ENTRY PTS)                                                 00520000
*                                                                       00540000
*OUTPUT   N/A                                                           00560000
*                                                                       00580000
*EXTERNAL ROUTINES - IEWSWOVR - NON-RESIDENT OVERLAY SUPERVISOR         00600000
*                                                                       00620000
*EXITS-NORMAL   ALL PROBLEM PROGRAM REGISTERS ARE TRANSPARENT. REGISTER 00640000
*   0,1,15 ARE RESTORED TO PROBLEM PROGRAM CONTENTS BEFORE EXIT.        00660000
*   THIS MODULE EXITS BY ISSUING  SVC EXIT  FOR NORMAL RETURNS.         00680000
*                                                                       00700000
*     -ERRORS  ALL ERRORS ARE FOUND IN THE NON-RESIDENT  MODULE WHICH   00720000
*   PASSES  A RETURN CODE IN REGISTER 15 TO THIS MODULE.                00740000
*                 RETURN CODE OF ZERO INDICATES NO ERROR FOUND.         00760000
*                 RETURN CODE OF NON ZERO INDICATES ERROR.              00780000
*   IF AN ERROR HAS BEEN DETECTED THE RETURN CODE IS USED TO FORM THE   00800000
*     ABEND ERROR CODE.                                                 00820000
*                 CODES - X'8012D000'  SEGMENT TABLE AS BEEN CONTAMIN-  00840000
*                                      ATED.                            00860000
*                       - X'8022D000'  VALIDITY TEST INDICATES AN ADDR- 00880000
*                                      ESS IN ENTAB OR SEGTAB HAS BEEN  00900000
*                                      DESTROYED AND NOW ADDRESSES A    00920000
*                                      LOCATION OUTSIDE OF THE PROBLEM  00940000
*                                      PROGRAM.                         00960000
*                      - X'80X2D000'   AN ERROR HAS BEEN DETECTED BY    00980000
*                                      PROGRAM FETCH. 'X' IS THE CODE   01000000
*                                      RETURNED BY PROGRAM FETCH.       01020000
*                            X = F     I/O ERROR.                       01040000
*                            X = E     INVALID ADDRESS.                 01060000
*                            X = D     INVALID RECORD TYPE.             01080000
*                       - X'80425000'  AN INVALID SEGWT REQUEST MADE BY 01100000
*                                     PROBLEM PROGRAM. INVALID REQU-    01120000
*                                     ESTS ARE REQUESTS TO OVERLAY THE  01140000
*                                     REQUESTING SEGMENT OR ONE HIGHER  01160000
*                                     IN ITS PATH. THIS ERROR IS NOT    01180000
*                                     DETECTED BY MODULE IEWSYOVR.      01200000
*                                                                       01220000
*TABLES/WORK AREAS  (SEE DESCRIPTION PRECEDING NON-RESIDENT MODULE.)    01240000
*                                                                       01260000
*ATTRIBUTES   READ ONLY, REENTRANT, PRIVILEGED, ENTERED DISABLED BUT    01280000
*             ENABLES UPON ENTRY.                                       01300000
*             RESIDENT TYPE 2 SVC ROUTINE.                              01320000
*                                                                       01340000
*NOTES                                                                  01360000
*   THIS MODULE OPERATES WITH SYNCHRONOUS OVERLAY SUPERVISOR MODULES.   01380000
*   SEGLD IS TREATED AS A NOP IN THIS CASE.                             01400000
*   THIS ROUTINE REQUIRES SIX DOUBLE WORDS OF EXTENDED SAVE AREA STOR-  01420000
*   AGE ATTACHED TO ITS SVRB.                                           01440000
         EJECT                                                          01460000
IEWSRGSV EQU   32        OFFSET OF REGISTER SAVE AREA IN SVRB           01480000
* THIS IS THE SAVE AREA IN WHICH THE PROBLEM PROGRAM REGISTERS ARE      01500000
* SAVED WHEN AN SVC IS EXECUTED.                                        01520000
IEWSRBS1 EQU   7                                                        01540000
IEWSRBS2 EQU   11                                                       01560000
IEWSRR0  EQU   0                                                        01580000
IEWSRR1  EQU   1                                                        01600000
IEWSRR2  EQU   2                                                        01620000
IEWSRR3  EQU   3                                                        01640000
IEWSRR4  EQU   4                                                        01660000
IEWSRR5  EQU   5                                                        01680000
IEWSRR6  EQU   6                                                        01700000
IEWSRR8  EQU   8                                                        01720000
IEWSRR9  EQU   9                                                        01740000
IEWSRR10 EQU   10                                                       01760000
IEWSRR12 EQU   12                                                       01780000
IEWSRR14 EQU   14                                                       01800000
IEWSRR15 EQU   15                                                       01820000
IEWSSAVE EQU   96           BEGINNING OF THE EXTENDED SAVE AREA.        01840000
* THE EXTENDED SAVE AREA IS APPENDED TO THE SVRB WHICH IS CREATED FOR   01860000
* SVC ROUTINES. OVERLAY SUPERVISOR REQUIRES 12 WORDS OF EXTENDED SAVE   01880000
* AREA. THE LENGTH IS SPECIFIED IN THE SVC TABLE CONTROL SECTION IN THE 01900000
* RESIDENT NUCLEUS. THE SAVE AREA IS USED PRIMARILY BY THE NON-RESIDENT 01920000
* MODULE. THIS MODULE SAVES ITS BASE REGISTER IN THE 12TH WORD.         01940000
EXIT     EQU   3                                                        01960000
CVT      DSECT                                                          01980000
         CVT   SYS=MIN                                                  02000000
         EJECT                                                          02020000
IGC037   CSECT           ENTRY FOR SEGLD AND SEGWT.                     02040000
         ENTRY IGC045    ENTRY FOR CALL(OR BRANCH).                     02060000
         DS    0D                                                       02080000
         BALR  IEWSRBS2,0                                               02100000
         USING *,IEWSRBS2                                               02120000
*                                                                       02140000
*   CHECK REGISTER 0 AND MOVE IT TO REG 2. IF CONTENTS IS ZERO          02160000
*   REQUEST IS A SEGLD. IF NON-ZERO REQUEST IS A SEGWT.                 02180000
*   EXAMINE HIGH ORDER BYTE OF REG 1. IF ZERO VCON DOES NOT             02200000
*   POINT TO AN ENTAB, EXIT TO PROBLEM PROGRAM.                         02220000
*                                                                       02240000
         LR    IEWSRR2,IEWSRR0          MOVE FUNCTION CODE.             02260000
         CL    IEWSRR1,IEWSLCN1    TEST HIGH ORDER BYTE OF VCON FOR 0.  02280000
         BC    11,IEWSL10                                               02300000
         SVC   EXIT                                                     02320000
         DS    0F                                                       02340000
IEWSLCN1 DC    X'00FFFFFF' CONSTANT TO CHECK HIGH ORDER BYTE OF VCON.   02360000
         DS    0D                                                       02380000
IGC045   EQU   *                                                        02400000
*                                                                       02420000
*   MOVE PTR TO ENTAB FROM REG15 TO REG 1. SET REG 2 NEGATIVE TO INDI-  02440000
*   CATE CALL (OR BRANCH).                                              02460000
*                                                                       02480000
         LR    IEWSRR1,IEWSRR15    MOVE ENTAB PTR TO REG 1              02500000
         LNR   IEWSRR2,IEWSRR15    SET FUNCTION CODE BRANCH(CALL)       02520000
IEWSL10  BALR  IEWSRBS1,0                                               02540000
         USING *,IEWSRBS1                                               02560000
*  THE FOLLOWING GENERATES THE SSM INSTRUCTION.  THE MASK IS IN THE     02580000
*  SECOND BYTE OF THE INSTRUCTION. WHEN EXECUTED IT ENABLES THE CPU FOR 02600000
*  ALL INTERRUPTS.                                                      02620000
*                                                                       02640000
*                                                                       02660000
         DC    X'80FF'                                                  02680000
         DC    S(*-1)                                                   02700000
*                                                                       02720000
*                                                                       02740000
*   PUT BASE ADDRESS OF COMMUNICATION VECTOR IN REG 8. GET ADDRESS OF   02760000
*  SVRB INTO REG 6. THE SAVE AREA IS REFERENCED THROUGH OFFSET.         02780000
*                                                                       02800000
         LR    IEWSRR8,IEWSRR3    ADDRESS OF COMMUNICATION VECTOR.      02820000
         LR    IEWSRR6,IEWSRR5    ADDRESS OF SVRB FOR SAVE AREA.        02840000
*                                                                       02860000
*   PUT ADDRESS OF SEGTAB INTO REG 12.                                  02880000
*                                                                       02900000
         LH    IEWSRR12,2(IEWSRR1) GET DISPLCMT FIELD FROM ENTAB.       02920000
         SRL   IEWSRR12,2                                               02940000
         SLL   IEWSRR12,2                                               02960000
         LA    IEWSRR12,8(IEWSRR12,IEWSRR1)  LOCN OF ADDRESS OF SEGTAB. 02980000
         L     IEWSRR12,0(IEWSRR12)    GET ADDRESS OF SEGTAB.           03000000
*                                                                       03020000
* PICK UP NUMBER OF REQUESTED SEGMENT (NSEG) FROM ENTAB.                03040000
*                                                                       03060000
         SR    IEWSRR9,IEWSRR9                                          03080000
         IC    IEWSRR9,8(IEWSRR1)  GET NUMBER OF REQUESTED SEGMENT.     03100000
         SR    IEWSRR10,IEWSRR10   PRESET 10 TO ZERO.                   03120000
*                                                                       03140000
*   LINK TO NON-RESIDENT MODULE OF OVERLAY TO PROCESS REQUEST.          03160000
*                                                                       03180000
*    DCB=LINKLIB ADDED TO FORCE THE SEARCH FOR THE NON-RESIDENT OVERLAY 03190021
*     SUPERVISOR(IEWSZOVR) TO LINKLIB.                                  03192021
         SPACE                                                          03194021
         USING CVT,IEWSRR4                                              03196021
         L     IEWSRR4,CVTPTR(0)       R4=CVT POINTER           SA64417 03198021
         L     IEWSRR4,CVTLINK         R4=LINKLIB DCB ADDRESS   SA64417 03198421
         DROP  IEWSRR4                                                  03198821
         SPACE                                                          03199221
         LA    IEWSRR15,IEWSLKPR                                        03200000
         LINK  MF=(E,(1)),SF=(E,(15)),DCB=(IEWSRR4)             SA64417 03220021
         BALR  IEWSRBS1,0              SET BASE ON RETURN FROM LINK     03240000
         USING *,IEWSRBS1                                               03260000
         LR    IEWSRR3,IEWSRR1                                          03280000
*                                                                       03300000
*   TEST REGISTER 15 FOR RETURN CODE.                                   03320000
*                                                                       03340000
         LTR   IEWSRR1,IEWSRR15    CHECK ERROR CODE.                    03360000
         BC    7,IEWSERR                                                03380000
*                                                                       03400000
*   RESTORE REGISTERS 0,1,15 FROM SVRB.                                 03420000
*                                                                       03440000
         LM    IEWSRR0,IEWSRR1,IEWSRGSV(IEWSRR6)  RESTORE REGS 0,1.     03460000
         L     IEWSRR15,IEWSRGSV+60(IEWSRR6)      RESTORE REG 15.       03480000
IEWSEXIT SVC   EXIT                                                     03500000
*  GENERATE ABEND CODE WITH DUMP BIT ON AND ISSUE ABEND. REGISTER 3     03520000
*  CONTAINS ADDRESS OF ENTAB ENTRY SPECIFIED IN THE REQUEST.            03540000
IEWSERR  SLL   IEWSRR1,12                                               03560000
         A     IEWSRR1,IEWSLCN2   SET ON DUMP BIT.                      03580000
         ABEND (1)                                                      03600000
IEWSLKPR DC    A(IEWSNAME)    ADDRESS OF NAME                           03620000
         DC    F'0'     DCB ADDRESS.                                    03640000
IEWSLCN2 DC    X'80000000'                                              03660000
IEWSNAME DC    C'IEWSZOVR'                                              03680000
         END                                                            03700000
