IGC037   START 0                                                        00020021
         TITLE 'IEWSVOVR,OVERLAY SUPERVISOR,RESIDENT MOD.,MIN. SYSTEMS' 00040000
*                                                                       00060000
*STATUS  CHANGE LEVEL 0.                                                00080000
*                                                                       00100000
*FUNCTION/OPERATION - TO HANDLE OVERLAY REQUESTS FROM PROBLEM PROGRAMS. 00120000
*   THIS MODULE RESIDES IN THE RESIDENT NUCLEUS. IT IS GIVEN CONTROL    00140000
*   BY THE SVC INTERRUPT HANDLER FOR SVC 37 AND SVC 45. IT INITIALIZES  00160000
*   INDICATORS AND POINTERS AND PASSES CONTROL TO THE MAIN PROCESSING   00180000
*   MODULE OF OVERLAY SUPERVISOR. UPON RETURN TO THIS MODULE, A RETURN  00200000
*   CODE IS EXAMINED AND IF AN ERROR HAS BEEN DETECTED, AN ABEND IS     00220000
*   ISSUED.                                                             00240000
*                                                                       00260000
*ENTRY POINTS                                                           00280000
*        IGC037 - SEGLD OR SEGWT REQUEST.                               00300000
*              IF REGISTER 0 CONTAINS 0 REQUEST IS SEGLD.               00320000
*              IF REGISTER 0 CONTAINS 1 REQUEST IS SEGWT.               00340000
*              REGISTER ONE POINTS TO AN ENTAB ENTRY CONTAINING THE     00360000
*               NUMBER OF THE REQUESTED SEGMENT.                        00380000
*        IGC045 - CALL OR BRANCH.                                       00400000
*              REGISTER 15 POINTS TO AN ENTAB ENTRY CONTAINING THE      00420000
*               NUMBER OF THE REQUESTED SEGMENT AND THE RELOCATED VALUE 00440000
*               OF THE SYMBOL TO WHICH THE CALL (OR BRANCH) IS BEING    00460000
*               MADE.                                                   00480000
*                                                                       00500000
*INPUT  (SEE ENTRY PTS)                                                 00520000
*                                                                       00540000
*OUTPUT   N/A                                                           00560000
*                                                                       00580000
*EXTERNAL ROUTINES:-IEWSYOVR -BASIC SYNCHRONOUS OVERLAY SUPERVISOR      00600000
*                   OR                                                  00620000
*                  -IEWSXOVR -SYNCHRONOUS OVERLAY SUPERVISOR WITH       00640000
*                             CHECKING.                                 00660000
*                   ONE OF THE ABOVE ROUTINES IS CHOSEN AT SYSGEN TIME. 00680000
*                                                                       00700000
*EXITS-NORMAL   ALL PROBLEM PROGRAM REGISTERS ARE TRANSPARENT. REGISTER 00720000
*   0,1,15 ARE RESTORED TO PROBLEM PROGRAM CONTENTS BEFORE EXIT.        00740000
*   THIS MODULE EXITS BY ISSUING  SVC EXIT  FOR NORMAL RETURNS.         00760000
*                                                                       00780000
*     -ERRORS  ALL ERRORS ARE FOUND IN THE NON-RESIDENT  MODULE WHICH   00800000
*   PASSES  A RETURN CODE IN REGISTER 15 TO THIS MODULE.                00820000
*                 RETURN CODE OF ZERO INDICATES NO ERROR FOUND.         00840000
*                 RETURN CODE OF NON ZERO INDICATES ERROR.              00860000
*   IF AN ERROR HAS BEEN DETECTED THE RETURN CODE IS USED TO FORM THE   00880000
*     ABEND ERROR CODE.                                                 00900000
*                 CODES - X'8012D000'  SEGMENT TABLE AS BEEN CONTAMIN-  00920000
*                                      ATED.                            00940000
*                       - X'8022D000'  VALIDITY TEST INDICATES AN ADDR- 00960000
*                                      ESS IN ENTAB OR SEGTAB HAS BEEN  00980000
*                                      DESTROYED AND NOW ADDRESSES A    01000000
*                                      LOCATION OUTSIDE OF THE PROBLEM  01020000
*                                      PROGRAM.                         01040000
*                      - X'80X2D000'   AN ERROR HAS BEEN DETECTED BY    01060000
*                                      PROGRAM FETCH. 'X' IS THE CODE   01080000
*                                      RETURNED BY PROGRAM FETCH.       01100000
*                            X = F     I/O ERROR.                       01120000
*                            X = E     INVALID ADDRESS.                 01140000
*                            X = D     INVALID RECORD TYPE.             01160000
*                       - X'80425000'  AN INVALID SEGWT REQUEST MADE BY 01180000
*                                     PROBLEM PROGRAM. INVALID REQU-    01200000
*                                     ESTS ARE REQUESTS TO OVERLAY THE  01220000
*                                     REQUESTING SEGMENT OR ONE HIGHER  01240000
*                                     IN ITS PATH. THIS ERROR IS NOT    01260000
*                                     DETECTED BY MODULE IEWSYOVR.      01280000
*                                                                       01300000
*TABLES/WORK AREAS  (SEE DESCRIPTION PRECEDING NON-RESIDENT MODULE.)    01320000
*                                                                       01340000
*ATTRIBUTES   READ ONLY, REENTRANT, PRIVILEGED, ENTERED DISABLED BUT    01360000
*             ENABLES UPON ENTRY.                                       01380000
*             RESIDENT TYPE 2 SVC ROUTINE.                              01400000
*                                                                       01420000
*NOTES                                                                  01440000
*   THIS MODULE OPERATES WITH SYNCHRONOUS OVERLAY SUPERVISOR MODULES.   01460000
*   SEGLD IS TREATED AS A NOP IN THIS CASE.                             01480000
*   THIS ROUTINE REQUIRES SIX DOUBLE WORDS OF EXTENDED SAVE AREA STOR-  01500000
*   AGE ATTACHED TO ITS SVRB.                                           01520000
         EJECT                                                          01540000
IEWSRGSV EQU   32        OFFSET OF REGISTER SAVE AREA IN SVRB           01560000
* THIS IS THE SAVE AREA IN WHICH THE PROBLEM PROGRAM REGISTERS ARE      01580000
* SAVED WHEN AN SVC IS EXECUTED.                                        01600000
IEWSRBS1 EQU   7                                                        01620000
IEWSRBS2 EQU   11                                                       01640000
IEWSRR0  EQU   0                                                        01660000
IEWSRR1  EQU   1                                                        01680000
IEWSRR2  EQU   2                                                        01700000
IEWSRR3  EQU   3                                                        01720000
IEWSRR4  EQU   4                                                        01740000
IEWSRR5  EQU   5                                                        01760000
IEWSRR6  EQU   6                                                        01780000
IEWSRR8  EQU   8                                                        01800000
IEWSRR9  EQU   9                                                        01820000
IEWSRR10 EQU   10                                                       01840000
IEWSRR12 EQU   12                                                       01860000
IEWSRR14 EQU   14                                                       01880000
IEWSRR15 EQU   15                                                       01900000
IEWSSAVE EQU   96           BEGINNING OF THE EXTENDED SAVE AREA.        01920000
* THE EXTENDED SAVE AREA IS APPENDED TO THE SVRB WHICH IS CREATED FOR   01940000
* SVC ROUTINES. OVERLAY SUPERVISOR REQUIRES 12 WORDS OF EXTENDED SAVE   01960000
* AREA. THE LENGTH IS SPECIFIED IN THE SVC TABLE CONTROL SECTION IN THE 01980000
* RESIDENT NUCLEUS. THE SAVE AREA IS USED PRIMARILY BY THE NON-RESIDENT 02000000
* MODULE. THIS MODULE SAVES ITS BASE REGISTER IN THE 12TH WORD.         02020000
EXIT     EQU   3                                                        02040000
CVT      DSECT                                                          02060000
         CVT   SYS=MIN                                                  02080000
         EJECT                                                          02100000
IGC037   CSECT           ENTRY FOR SEGLD AND SEGWT.                     02120000
         ENTRY IGC045    ENTRY FOR CALL(OR BRANCH).                     02140000
         DS    0D                                                       02160000
         BALR  IEWSRBS2,0                                               02180000
         USING *,IEWSRBS2                                               02200000
*                                                                       02220000
*   CHECK REGISTER 0 AND MOVE IT TO REG 2. IF CONTENTS ARE ZERO, REQ-   02240000
*   UEST IS A SEGLD AND IS TREATED AS A NOP. IF NON-ZERO, REQUEST IS A  02260000
*   SEGWT. EXAMINE HIGH ORDER BYTE OF REG 1. IF ZERO, VCON DOES NOT     02280000
*   POINT TO AN ENTAB, EXIT TO PROBLEM PROGRAM.                         02300000
*                                                                       02320000
         LTR   IEWSRR2,IEWSRR0        MOVE AND TEST FUNCTION CODE.      02340000
         BCR   8,IEWSRR14                                               02360000
         CL    IEWSRR1,IEWSLCN1    TEST HIGH ORDER BYTE OF VCON FOR 0.  02380000
         BC    11,IEWSL10                                               02400000
         SVC   EXIT                                                     02420000
         DS    0F                                                       02440000
IEWSLCN1 DC    X'00FFFFFF' CONSTANT TO CHECK HIGH ORDER BYTE OF VCON.   02460000
         DS    0D                                                       02480000
IGC045   EQU   *                                                        02500000
*                                                                       02520000
*   MOVE PTR TO ENTAB FROM REG15 TO REG 1. SET REG 2 NEGATIVE TO INDI-  02540000
*   CATE CALL (OR BRANCH).                                              02560000
*                                                                       02580000
         LR    IEWSRR1,IEWSRR15    MOVE ENTAB PTR TO REG 1              02600000
         LNR   IEWSRR2,IEWSRR15    SET FUNCTION CODE BRANCH(CALL)       02620000
IEWSL10  BALR  IEWSRBS1,0                                               02640000
         USING *,IEWSRBS1                                               02660000
*  THE FOLLOWING GENERATES THE SSM INSTRUCTION.  THE MASK IS IN THE     02680000
*  SECOND BYTE OF THE INSTRUCTION. WHEN EXECUTED IT ENABLES THE CPU FOR 02700000
*  ALL INTERRUPTS.                                                      02720000
*                                                                       02740000
*                                                                       02760000
         DC    X'80FF'                                                  02780000
         DC    S(*-1)                                                   02800000
*                                                                       02820000
*                                                                       02840000
*   PUT BASE ADDRESS OF COMMUNICATION VECTOR IN REG 8. GET ADDRESS OF   02860000
*  SVRB INTO REG 6. THE SAVE AREA IS REFERENCED THROUGH OFFSET.         02880000
*                                                                       02900000
         LR    IEWSRR8,IEWSRR3    ADDRESS OF COMMUNICATION VECTOR.      02920000
         LR    IEWSRR6,IEWSRR5    ADDRESS OF SVRB FOR SAVE AREA.        02940000
*                                                                       02960000
*   PUT ADDRESS OF SEGTAB INTO REG 12.                                  02980000
*                                                                       03000000
         LH    IEWSRR12,2(IEWSRR1) GET DISPLCMT FIELD FROM ENTAB.       03020000
         SRL   IEWSRR12,2                                               03040000
         SLL   IEWSRR12,2                                               03060000
         LA    IEWSRR12,8(IEWSRR12,IEWSRR1)  LOCN OF ADDRESS OF SEGTAB. 03080000
         L     IEWSRR12,0(IEWSRR12)    GET ADDRESS OF SEGTAB.           03100000
*                                                                       03120000
* PICK UP NUMBER OF REQUESTED SEGMENT (NSEG) FROM ENTAB.                03140000
*                                                                       03160000
         SR    IEWSRR9,IEWSRR9                                          03180000
         IC    IEWSRR9,8(IEWSRR1)  GET NUMBER OF REQUESTED SEGMENT.     03200000
         SR    IEWSRR10,IEWSRR10   PRESET 10 TO ZERO.                   03220000
*                                                                       03240000
*   LINK TO NON-RESIDENT MODULE OF OVERLAY TO PROCESS REQUEST.          03260000
*                                                                       03280000
*    DCB=LINKLIB ADDED TO FORCE THE SEARCH FOR THE NON-RESIDENT         03290021
*     OVERLAY SUPERVISOR(IEWSZOVR) TO LINKLIB.                          03292021
         SPACE                                                          03294021
         USING CVT,IEWSRR4                                              03296021
         L     IEWSRR4,CVTPTR(0)       R4=CVT POINTER           SA64417 03298021
         L     IEWSRR4,CVTLINK         R4=LINKLIB DCB ADDRESS   SA64417 03298421
         DROP  IEWSRR4                                                  03298821
         SPACE                                                          03299221
         LA    IEWSRR15,IEWSLKPR                                        03300000
         LINK  MF=(E,(1)),SF=(E,(15)),DCB=(IEWSRR4)             SA64417 03320021
         BALR  IEWSRBS1,0                                               03340000
         USING *,IEWSRBS1                                               03360000
         LR    IEWSRR3,IEWSRR1                                          03380000
*                                                                       03400000
*   TEST REGISTER 15 FOR RETURN CODE.                                   03420000
*                                                                       03440000
         LTR   IEWSRR1,IEWSRR15    CHECK ERROR CODE.                    03460000
         BC    7,IEWSERR                                                03480000
*                                                                       03500000
*   RESTORE REGISTERS 0,1,15 FROM SVRB.                                 03520000
*                                                                       03540000
         LM    IEWSRR0,IEWSRR1,IEWSRGSV(IEWSRR6)  RESTORE REGS 0,1.     03560000
         L     IEWSRR15,IEWSRGSV+60(IEWSRR6)      RESTORE REG 15.       03580000
IEWSEXIT SVC   EXIT                                                     03600000
*  GENERATE ABEND CODE WITH DUMP BIT ON AND ISSUE ABEND. REGISTER 3     03620000
*  CONTAINS ADDRESS OF ENTAB ENTRY SPECIFIED IN THE REQUEST.            03640000
IEWSERR  SLL   IEWSRR1,12                                               03660000
         A     IEWSRR1,IEWSLCN2   SET ON DUMP BIT.                      03680000
         ABEND (1)                                                      03700000
IEWSLKPR DC    A(IEWSNAME)    ADDRESS OF NAME                           03720000
         DC    F'0'     DCB ADDRESS.                                    03740000
IEWSLCN2 DC    X'80000000'                                              03760000
IEWSNAME DC    C'IEWSZOVR'                                              03780000
         END                                                            03800000
