IEWSXOVR CSECT                                                          00020000
*0801078400                                                        AAAA 00040018
         TITLE 'IEWSXOVR SYNCH.OVERLAY SUPERVISOR WITH CHECK. MIN SYS.' 00060000
*                                                                       00080000
*STATUS: CHANGE LEVEL O.                                                00100000
*                                                                       00120000
*FUNCTION/OPERATION:  RECEIVES CONTROL FROM RESIDENT OVERLAY SUPERVISOR 00140000
*   MODULE. EXAMINES STATUS OF REQUESTED SEGMENT. IF NOT IN MAIN        00160000
*   STORAGE, REQUESTED SEGMENT AND SEGMENTS HIGHER IN ITS PATH ARE      00180000
*   LOADED INTO MAIN STORAGE. TABLES ARE MODIFIED TO REFLECT THE STATUS 00200000
*   OF SEGMENTS IN MAIN STORAGE AND SEGMENTS OVERWRITTEN.               00220000
*                                                                       00240000
*ENTRY POINT:  IEWSXOVR                                                 00260000
*              IT IS 'LINKED TO' UNDER THE NAME IEWSZOVR.               00280000
*                                                                       00300000
*INPUT: REGISTERS ARE INITIALIZED AS FOLLOWS:                           00320000
*                                                                       00340000
*        REG 1 - ADDRESS OF AN ENTAB ENTRY.                             00360000
*        REG 2 - POSITIVE VALUE INDICATES SEGWT.                        00380000
*              - NEGATIVE VALUE INDICATES CALL OR BRANCH.               00400000
*        REG 6 - ADDRESS OF REGISTER SAVE AREA (EXTENDED SAVE AREA).    00420000
*        REG 8 - BASE OF COMMUNICATION VECTOR.                          00440000
*        REG 9 - NO. OF REQUESTED SEGMENT,RIGHT JUSTIFIED.              00460000
*        REG 10- ZERO                                                   00480000
*        REG 12- ADDRESS OF SEGTAB                                      00500000
*                                                                       00520000
*OUTPUT: N/A                                                            00540000
*                                                                       00560000
*EXTERNAL ROUTINES:- IEWFTMIN  - PROGRAM FETCH.                         00580000
*                  - IEAVLDCK  - VALIDITY CHECK RTN.                    00600000
*                  - IEGTTRNO  - TEST TRANSLATOR INTERPRETER FOR OVER-  00620000
*                                LAY.                                   00640000
*                                                                       00660000
*EXITS:- NORMAL  UPON EXIT, REGISTER 15 IS SET TO A RETURN CODE. RETURN 00680000
*                IS TO THE RESIDENT MODULE WHICH INTERPRETS THE RETURN  00700000
*                CODE. REGISTER 15 IS USED TO CONTAIN THE RETURN CODE   00720000
*                ON NORMAL RETURNS, THE CODE IS ZERO.                   00740000
*      - ERRORS  THE ERROR RETURN CODES ARE PLACED IN THE LOW ORDER     00760000
*                BYTES OF REGISTER 15.                                  00780000
*                    CODES   - X'12D'   SEGMENT TABLE HAS BEEN CONTAMI- 00800000
*                                       NATED.                          00820000
*                            - X'22D'   VALIDITY TEST INDICATES AN AD-  00840000
*                                       DRESS IN ENTAB OR SEGTAB HAS    00860000
*                                       BEEN DESTROYED AND NOW ADDRESS- 00880000
*                                       ES A LOCATION OUTSIDE OF THE    00900000
*                                       PROBLEM PROGRAM.                00920000
*                           - X'X2D'   AN ERROR HAS BEEN DETECTED BY    00940000
*                                      PROGRAM FETCH. 'X' IS THE CODE   00960000
*                                      RETURNED BY PROGRAM FETCH.       00980000
*                            X = F     I/O ERROR.                       01000000
*                            X = E     INVALID ADDRESS.                 01020000
*                            X = D     INVALID RECORD TYPE.             01040000
*                            - X'425'   AN INVALID SEGWT REQUEST MADE   01060000
*                                       BY PROBLEM PROGRAM. INVALID     01080000
*                                       REQUESTS OF THIS TYPE ARE THOSE 01100000
*                                       IN WHICH THE VCON IS RESOLVED   01120000
*                                       TO AN ENTAB AND THE REQUESTED   01140000
*                                       SEGMENT IS EXCLUSIVE.           01160000
*                                                                       01180000
*                                                 *                     01200000
*                                                 *                     01220000
*                                                 *                     01240000
*                                               1 * V(JOE)              01260000
*                                                 *                     01280000
*                                                 *                     01300000
*                                         ******************            01320000
*                                         *                * JOE        01340000
*                                         *                *            01360000
*                                      2  * SEGWT JOE    3 *            01380000
*                                         *                *            01400000
*                                         *                *            01420000
*                                         *                *            01440000
*                                                                       01460000
*                                       IF V(JOE) HAD NOT APPEARED IN   01480000
*                                       THE COMMON SEGMENT, THE VCON    01500000
*                                       FOR JOE IN SEG 2 (GENERATED BY  01520000
*                                       THE SEGWT MACRO) WOULD BE RESO- 01540000
*                                       LVED DIRECTLY TO JOE, ITS HIGH  01560000
*                                       ORDER BYTE WOULD BE ZERO AND    01580000
*                                       IS TREATED AS A NOP. IT APPEARS 01600000
*                                       THE SAME AS A SEGWT TO A HIGHER 01620000
*                                       SEGMENT. THE REQUEST IS INVALID 01640000
*                                       BECAUSE IT ATTEMPTS TO OVERLAY  01660000
*                                       THE CALLING SEGMENT OR ONE      01680000
*                                       HIGHER IN ITS PATH.             01700000
*                                                                       01720000
         EJECT                                                          01740000
*TABLES/WORK AREAS:                                                     01760000
*                                                                       01780000
*  SEGTAB                                                               01800000
*                                                                       01820000
*    '***************'***************'***************'***************'  01840000
*    '0 BIT 1-0 NOT  '1              '2              '3              '  01860000
*    '          IN   '                                               '  01880000
*    '          TEST '        DCB  ADDRESS                           '  01900000
*    '       -1 IN   '                                               '  01920000
*    '          TEST '                                               '  01940000
*    '***************'***************'***************'***************'  01960000
*    '4              '5              '6              '7              '  01980000
*    '               '        NOTE LIST ADDRESS                      '  02000000
*    '               '                                               '  02020000
*    '***************'***************'***************'***************'  02040000
*    '8 HIGHEST SEG  '9  HIGHEST SEG '10 HIGHEST SEG '11 HIGHEST SEG '  02060000
*    'IN REGION 1    'OF REGION 1 IN 'IN REGION 2    'OF REGION 2 IN '  02080000
*    '               'MAIN STORAGE   '               'MAIN STORAGE   '  02100000
*    '***************'***************'***************'***************'  02120000
*    '12 HIGHEST SEG '13 HIGHEST SEG '14HIGHEST SEG  '15 HIGHEST SEG '  02140000
*    'IN REGION 3    'OF REGION 3 IN 'IN REGION 4    'OF REGION 4 IN '  02160000
*    '               'MAIN STORAGE   '               'MAIN STORAGE   '  02180000
*    '***************'***************'***************'***************'  02200000
*    '16             '17             '18             '19             '  02220000
*    '                  NOT USED BY THIS MODULE                      '  02240000
*    '                                                                  02260000
*    '***************'***************'***************'***************'  02280000
*    '20             '21             '22             '23             '  02300000
*    '                  NOT USED BY THIS MODULE                      '  02320000
*    '                                                               '  02340000
*    '***************'***************'***************'***************'  02360000
*ROOT'24             '25             '26             '27             '  02380000
* 1ST' PREVIOUS SEG- '        CALLER FIELD                           '  02400000
* SEG' MENT FIELD.   '                                               '  02420000
*    '               '                                               '  02440000
*    '***************'***************'***************'***************'  02460000
*    '28             '29             '30             '31             '  02480000
* 2ND' PREVIOUS SEG- '        CALLER FIELD                           '  02500000
* SEG' MENT FIELD    '                                               '  02520000
*    '               '                                               '  02540000
*    '***************'***************'***************'***************'  02560000
*                                                                       02580000
* ETC.                                                                  02600000
*  NOTES ON SEGTAB                                                      02620000
*    1. THE TEST BIT IS SET BY PROGRAM FETCH IF THE PROGRAM ATTRIBUTES  02640000
*       INDICATE THAT THE PROGRAM IS IN TEST                            02660000
*    2. THE DCB ADDRESS POINTS TO THE DCB USED TO LOAD THE ROOT. IT IS  02680000
*       USED EACH TIME A SEGMENT IS LOADED. THE ADDRESS IS INITIALIZED  02700000
*       BY PROGRAM FETCH.                                               02720000
*    3. THE NOTE LIST IS READ BY PROGRAM FETCH AND THE ADDRESS IN       02740000
*       SEGTAB IS INITIALIZED BY PROGRAM FETCH.                         02760000
*    4. THE PREVIOUS SEGMENT FIELD CONTAINS THE NUMBER OF THE SEGMENT   02780000
*       IMMEDIATELY ABOVE THIS SEGMENT IN THE OVERLAY TREE.             02800000
*    5. THE CALLER FIELD IS USED TO RECORD THE CURRENT STATUS OF A      02820000
*       SEGMENT. THE LOW ORDER 2 BITS ARE USED.                         02840000
*                                                                       02860000
*                     00 - IN MAIN STORAGE                              02880000
*                     10 - IN MAIN STORAGE                              02900000
*                     01 - NOT IN MAIN STORAGE,BUT MUST BE LOADED       02920000
*                     11 - NOT IN MAIN STORAGE,NOT TO BE LOADED         02940000
*       THE 00 INDICATES THAT THE REMAINDER OF THE FIELD CONTAINS THE   02960000
*       ADDRESS OF AN ENTAB ENTRY WHICH WAS MODIFIED WHEN THIS SEGMENT  02980000
*       WAS BROUGHT INTO MAIN STORAGE.                                  03000000
*                                                                       03020000
*                                                                       03040000
*ENTAB                                                                  03060000
*                                                                       03080000
*                                                                       03100000
*  ALL ENTRIES BUT THE LAST                                             03120000
*                                                                       03140000
*  '********************'********************'********************'     03160000
*  '                    '                    ' SEG X              '     03180000
*  ' BC  15,DIS(15,0)   ' ADDRESS CONSTANT   ' NO  X PREVIOUS     '     03200000
*  '                    '                    ' OF  X CALLER       '     03220000
*  '                    ' LOCATION OF ENTRY  ' REQ.X FIELD        '     03240000
*  '                    ' POINT IN REQUESTED ' SEG X              '     03260000
*  '                    ' SEGMENT            '     X              '     03280000
*  '********************'********************'********************'     03300000
*  '     4 BYTES        '     4 BYTES        ' 1   '   3 BYTES    '     03320000
*                                             BYTE                      03340000
*                                                                       03360000
*                                                                       03380000
*   DIS  IS THE DISPLACEMENT BETWEEN THE BEGINNING OF THIS LINE AND THE 03400000
*   LAST LINE IN THE TABLE.                                             03420000
*                                                                       03440000
*                                                                       03460000
*  LAST ENTRY                                                           03480000
*                                                                       03500000
*  '********************'********************'*******************'      03520000
*  '         *          '         *          'SEG  *             '      03540000
*  '  SVC 45 *  L 15,4(0,15)      *BCR 15,15 'NO OF* ADDRESS OF  '      03560000
*  '         *                    *          'THIS *   SEGTAB    '      03580000
*  '         *                    *          'ENTAB*             '      03600000
*  '********************'********************'*******************'      03620000
*  '  2 BYTES'      4 BYTES       '  2 BYTES ' 1   '   3 BYTES   '      03640000
*                                             BYTE                      03660000
*ATTRIBUTES:   READ ONLY,REENTRANT,PRIVILEGED,ENABLED.                  03680000
         EJECT                                                          03700000
SAVEAREA EQU   96                                                       03720000
OVRR0    EQU   0                                                        03740000
OVRR1    EQU   1                                                        03760000
OVRR2    EQU   2                                                        03780000
OVRR3    EQU   3                                                        03800000
OVRR4    EQU   4                                                        03820000
OVRR5    EQU   5                                                        03840000
OVRR6    EQU   6                                                        03860000
OVRR7    EQU   7                                                        03880000
OVRR8    EQU   8                                                        03900000
OVRR9    EQU   9                                                        03920000
OVRR10   EQU   10                                                       03940000
OVRBRG   EQU   11                                                       03960000
OVRR12   EQU   12                                                       03980000
OVRR13   EQU   13                                                       04000000
OVRR14   EQU   14                                                       04020000
OVRR15   EQU   15                                                       04040000
OVRFWA   EQU   440    SIZE OF FETCH WORK AREA IN ANY SYSTEM             04060018
CVT      DSECT                                                          04080000
         CVT   SYS=MIN                                                  04100000
         EJECT                                                          04120000
IEWSXOVR CSECT                                                          04140000
*                                                                       04160000
         BALR  OVRBRG,0      SET UP BASE REGISTER.                      04180000
         USING *,OVRBRG                                                 04200000
         STC   OVRR9,SAVEAREA+4(OVRR6)  SAVE NSEG.                      04220000
*                                                                       04240000
* DETERMINE THE REGION CONTAINING NSEG AND SAVE IT.                     04260000
*                                                                       04280000
         BAL   OVRR15,OVRL88  GET REGION OF NSEG.                       04300000
         ST    OVRR5,SAVEAREA(OVRR6)   SAVE REGION PTR.                 04320000
         LR    OVRR4,OVRR5                                              04340000
*                                                                       04360000
* DETERMINE ADDRESS OF SEGTAB LINE FOR NSEG                             04380000
*                                                                       04400000
         LR    OVRR13,OVRR9        MOVE SEGNO FOR ADDRESS COMPUTE  RTN. 04420000
         BAL   OVRR15,OVRL80  COMPUTE ADDRESS AND VALIDITY CHECK IT.    04440000
*                                                                       04460000
         LR    OVRR0,OVRR5   SAVE SEGTAB ENTRY ADDRESS FOR NSEG.        04480000
         TM    3(OVRR5),X'03' IS SEGMENT IN MAIN STORAGE.               04500000
         BC    14,OVRL60      BRANCH IF YES.                            04520000
         LTR   OVRR2,OVRR2         IS REQUEST A SEGWT.                  04540000
         BC    13,OVRL25           BRANCH ON NO.                        04560000
         ST    OVRR1,SAVEAREA+4(OVRR6)  PUT RESEGNO IN SAVE AREA.       04580000
         LR    OVRR3,OVRR9      USE NSEG AS LOOP LIMIT.                 04600000
OVRL18   NC    0(1,OVRR5),0(OVRR5)     IS PSEG ZERO.                    04620000
         BC    8,OVRL20            BRANCH IF  YES.                      04640000
         CLC   0(1,OVRR5),SAVEAREA+4(OVRR6)  IS RSEG HIGHER IN PATH OF  04660000
         BC    8,OVRL25                        NSEG. BRANCH IF YES.     04680000
         SR    OVRR13,OVRR13                                            04700000
         IC    OVRR13,0(OVRR5)      GET PSEG.                           04720000
         BAL   OVRR15,OVRL80  GET SEGTAB LINE ADDRESS.                  04740000
         BCT   OVRR3,OVRL18        TRY AGAIN                            04760000
         BC    15,OVRL90         ERROR.                                 04780000
OVRL20   BAL   OVRR15,OVRL88       GET REGION OF RSEG.                  04800000
         CL    OVRR5,SAVEAREA(OVRR6)    ARE REGIONS THE SAME.           04820000
         BC    7,OVRL25      BRANCH IF NO.                              04840000
         LA    OVRR15,X'425'     ERR CODE X'425'                        04860000
         BCR   15,OVRR14           RETURN WITH ERROR CODE.              04880000
*                                                                       04900000
*   DETERMINE THE REGION CONTAINING NSEG AND GET OSEG FOR THAT REGION.  04920000
*                                                                       04940000
OVRL25  IC    OVRR10,1(OVRR4)   GET OSEG FOR THIS REGION.               04960000
         STC   OVRR9,1(OVRR4) STORE NEW OSEG.                           04980000
*                                                                       05000000
*  DETERMINE SEGMENTS TO BE LOADED AND MARK THEM. DETERMINE SEGMENTS    05020000
*    BEING OVERWRITTEN AND RESET TABLES.                                05040000
*                                                                       05060000
OVRL30   CLR   OVRR9,OVRR10   COMPARE NSEG TO OSEG.                     05080000
         BC    4,OVRL40       OSEG GT NSEG.                             05100000
         BC    8,OVRL50  OSEG EQ NSEG.                                  05120000
*                                                                       05140000
*   THIS SECTION MARKS SEGMENTS TO BE LOADED.                           05160000
*                                                                       05180000
         LR    OVRR13,OVRR9   SET UP ENTRY FOR ADDRESS CHECK RTN.       05200000
         BAL   OVRR15,OVRL80  COMPUTE ADDRESS AND CHECK IT.             05220000
         MVI   3(OVRR5),X'01'           SET ON LOAD INDICATOR           05240000
         IC    OVRR9,0(OVRR5) SET NSEG EQ TO PSEG(NSEG).                05260000
         BC    15,OVRL30                                                05280000
*                                                                       05300000
*   THIS SECTION RESETS TABLES FOR SEGMENTS BEING OVERWRITTEN.          05320000
*                                                                       05340000
OVRL40   LR    OVRR13,OVRR10  SET OSEG IN OVRR13 FOR ADDRESS COMPUTE.   05360000
         BAL   OVRR15,OVRL80  COMPUTE ADDRESS AND CHECK IT.             05380000
         EJECT                                                          05400000
*                                                                       05420000
*                                                                       05440000
** DONT PUT INSTRUCTIONS IN THIS BOX BELOW TM WHICH CHANGE THE CC ***** 05460000
*                                                                       05480000
         TM    3(OVRR5),X'03' DOES CALLER FIELD CONTAIN AN ADDRESS.   * 05500000
*                                                                     * 05520000
         L     OVRR7,0(OVRR5)     SAVE CALLER FIELD.                  * 05540000
         LR    OVRR3,OVRR5  SAVE PTR TO CURRENT SEGTAB ENTRY.           05560000
*                                                                     * 05580000
         MVI   3(OVRR5),X'03' SET NOT LOADED INDICATOR.               * 05600000
         BC    8,OVRL43       BRANCH IF CALLER FIELD CONTAINE AN ADDR.* 05620000
*                                                                       05640000
*********************************************************************** 05660000
*                                                                       05680000
*                                                                       05700000
OVRL41   IC    OVRR10,0(OVRR3)  SET OSEG EQ TO PSEG OF OSEG.            05720000
         BC    15,OVRL30   GO BACK FOR NEXT NSEG-OSEG COMPARISON.       05740000
*                                                                       05760000
*   RESET ENTAB ENTRIES USING CHAIN WHICH STARTS IN CALLER FIELD.       05780000
*                                                                       05800000
OVRL43  LA    OVRR7,0(OVRR7)  CLEAR OUT HIGH ORDER BYTE.                05820000
OVRL44   BAL   OVRR15,OVRL83  VALIDITY TEST THIS ADDRESS.               05840000
         XI    3(OVRR5),X'02'          RESET THIS ENTAB ENTRY.          05860000
         L     OVRR4,8(OVRR5)  GET PCALLER FIELD OF THIS ENTRY ENTAB    05880000
OVRL45   LA    OVRR4,0(OVRR4)   REMOVE THE SEGMENT NUMBER.              05900000
         LTR   OVRR4,OVRR4      TEST FOR ZERO.                          05920000
         BC    8,OVRL41         BRANCH IF PCALLER FIELD WAS ZERO.       05940000
         XC    9(3,OVRR5),9(OVRR5) SET PCALLER FIELD TO ZERO.           05960000
         LR    OVRR7,OVRR4                                              05980000
         BC    15,OVRL44      GO BACK WITH NEXT ADDRESS IN CHAIN.       06000000
*                                                                       06020000
*   THIS SECTION RESCANS SEGTAB AND LOADS SEGMENTS MARKED TO BE LOADED. 06040000
*                                                                       06060000
OVRL50  LR    OVRR13,OVRR8  MOVE BASE ADDRESS OF COMM. VECTOR.          06080000
         LR    OVRR8,OVRR0        SAVE REGS 0,1 IN 8,10.                06100000
         LR    OVRR10,OVRR1                                             06120000
         L     OVRR0,OVRLMNST      MAIN STORAGE FOR FETCH.              06140000
         GETMAIN R,LV=(0)                                               06160000
         LR    OVRR3,OVRR1       SHIFT TO FETCH'S REG.                  06180000
         IC    OVRR9,8(OVRR10)    PICK UP NSEG.                         06200000
OVRL52   SLL   OVRR9,2            MULTIPLY BY 4.                        06220000
         LA    OVRR1,20(OVRR12,OVRR9)                                   06240000
         TM    3(OVRR1),X'01'  MUST SEG BE LOADED.                      06260000
         BC    14,OVRL57           BRANCH ON NO.                        06280000
         STM   OVRR8,OVRR2,SAVEAREA+4(OVRR6)   SAVE REGS.               06300000
*                                                                       06320000
*  ENTER PROGRAM FETCH TO LOAD A SEGMENT. REGISTER SETTINGS:            06340000
*                   REG 3 - ADDRESS OF WORK AREA.                       06360000
*                   REG 7 - ADDRESS OF DCB.                             06380000
*                   REG 8 - ADDRESS OF NOTE LIST.                       06400000
*                   REG 9 - SEGMENT NO. MULTIPLIED BY 4.                06420000
*  ALL REGISTERS ARE VOLATILE IN PROGRAM FETCH EXCEPT REGS 3 AND 6.     06440000
*  FETCH PASSES A RETURN CODE IN REG 15. IF NON-ZERO, AN ERROR  HAS     06460000
*  OCCURRED.                                                            06480000
*                                                                       06500000
         LM    OVRR7,OVRR8,0(OVRR12)   PUT DCB AND NOTE LIST IN PAR REG 06520000
         USING CVT,OVRR13                                               06540000
         L     OVRR15,CVTFBOSV     GET ADDRESS OF PROGRAM FETCH.        06560000
         DROP  OVRR13                                                   06580000
         BALR  OVRR14,OVRR15           GO TO FETCH.                     06600000
         EJECT                                                          06620000
*                                                                       06640000
*** DONT PUT INSTRUCTIONS IN THIS BOX WHICH CHANGE THE CC ************* 06660000
*                                                                       06680000
         LTR   OVRR7,OVRR15       TEST COMPLETION INDICATOR.            06700000
         LM    OVRR8,OVRR2,SAVEAREA+4(OVRR6)                            06720000
         BC    7,OVRL70            BRANCH IF ERROR IN LOADING.        * 06740000
*********************************************************************** 06760000
*                                                                       06780000
         MVI   3(OVRR1),X'02'      SET ON LOADED INDICATOR.             06800000
         SR    OVRR9,OVRR9             CLEAR REG 9                 8140 06820000
         IC    OVRR9,0(OVRR1)     GET NEXT SEG IN PATH.                 06840000
         BC    15,OVRL52                                                06860000
OVRL57   LR    OVRR1,OVRR3    SET UP FOR FREEMAIN.                      06880000
         FREEMAIN R,LV=(0),A=(1)                                        06900000
         LR    OVRR0,OVRR8       RESET REGS 0,1                         06920000
         LR    OVRR1,OVRR10                                             06940000
*                                                                       06960000
* IF PROGRAM IS IN TEST, LINK TO TEST TRANSLATOR INTERPRETER. PARAMETER 06980000
*    PASSED IS ADDRESS OF SEGTAB IN REGISTER 12. ALL REGISTERS (0-13)   07000000
*    ARE TRANSPARENT.                                                   07020000
*                                                                       07040000
OVRL58   TM    0(OVRR12),X'40'       IS PROGRAM IN TEST.                07060000
         BC    14,OVRL60       BRANCH IF NO.                            07080000
         LR    OVRR9,OVRR14                                             07100000
        LA    OVRR15,OVRLTEST    LINK PARAM. LIST.                      07120000
         LINK  MF=(E,(1)),SF=(E,(15))                                   07140000
         LR    OVRR14,OVRR9                                             07160000
*                                                                       07180000
*  IF REQUEST WAS A CALL OR BRANCH AND                                  07200000
*  IF THE 'FROM' AND 'TO' SEGMENT ARE IN THE SAME REGION OR IF THE      07220000
*     REQUEST IS THRU THE ENTAB IN THE ROOT SEGMENT                     07240000
*  THE ENTAB ENTRY IS MODIFIED SO THAT SUBSEQUENT BRANCHES TO THAT      07260000
*     ENTRY WILL BYPASS THE SVC 45 AND CONTROL WILL PASS DIRECTLY TO    07280000
*     THE CALLED SEGMENT.                                               07300000
*                                                                       07320000
OVRL60   LTR   OVRR2,OVRR2    IS THE REQUEST A SEGWT.                   07340000
         BC    2,OVRL68         BRANCH IF YES                           07360000
         ST    OVRR12,SAVEAREA+4(OVRR6) PUT SEGNO OF ENTAB IN SAVEAREA. 07380000
         CLI   SAVEAREA+4(OVRR6),X'01'   IS REQUEST FRON ROOT ENTAB.    07400000
         BC    8,OVRL63                                                 07420000
         BAL   OVRR15,OVRL88   GET REGION OF ENTAB.                     07440000
         CL    OVRR5,SAVEAREA(OVRR6)    COMPARE REGION PTRS.            07460000
         BC    7,OVRL68  BRANCH IF UNEQUAL.                             07480000
*                                                                       07500000
*   THIS SECTION RESETS ENTAB ENTRY FOR REQUESTED SEGMENT AND UPDATES   07520000
*    SEGTAB.                                                            07540000
*                                                                       07560000
OVRL63   LR    OVRR5,OVRR0    GET ADDRESS OF SEGTAB ENTRY.              07580000
         TM    3(OVRR5),X'03' DOES IT CONTAIN AN ADDRESS.               07600000
         BC    7,OVRL65       BRANCH IF NO.                             07620000
         MVC   9(3,OVRR1),1(OVRR5) MOVE ADDRESS TO PCALLER FIELD.       07640000
OVRL65   IC    OVRR4,0(OVRR5)      SAVE PSEG FIELD.                     07660000
         ST    OVRR1,0(OVRR5) STORE ADDRESS OF ENTAB IN CALLER FIELD.   07680000
         STC   OVRR4,0(OVRR5) RESTORE PSEG FIELD.                       07700000
         XI    3(OVRR1),X'02'      INCREMENT ENTAB BRANCH.              07720000
*                                                                       07740000
*                                                                       07760000
*        RETURN                                                         07780000
OVRL68   SR    OVRR15,OVRR15     SET CODE TO NORMAL RETURN.             07800000
         BCR   15,OVRR14                                                07820000
OVRL70   LA    15,15                                               AAAA 07826018
         CR    OVRR7,15      CHECK FOR RETURN CODE OF F            AAAA 07832018
         BC    7,OVRL71                                            AAAA 07838018
         LA    OVRR7,3       CHANGE CODE OF F TO 3                 AAAA 07844018
OVRL71   SLL   OVRR7,8                                             AAAA 07850018
         LA    OVRR15,45(OVRR7)        MERGE ERROR CODES.               07860000
         BCR   15,OVRR14                                                07880000
         EJECT                                                          07900000
*  AT ENTRY TO OVERL80, REG 13 CONTAINS A SEGMENT NUMBER. IT IS MULTI-  07920000
*  PLIED BY 4 AND ADDED TO THE SEGTAB ADDRESS PLUS PREFIX BYTES (24-4)  07940000
*  TO GET THE ADDRESS OF THE SEGTAB LINE FOR THE GIVEN SEGMENT. UPON    07960000
*  RETURN FROM THIS ROUTINE, THE RESULTING ADDRESS IS IN REG 5.         07980000
*  AT ENTRY TO OVRL83, THE ADDRESS TO BE CHECKED IS ASSUMED TO BE IN    08000000
*  REG 7                                                                08020000
*                                                                       08040000
OVRL80   SLL   OVRR13,2       MULTIPLY BY 4.                            08060000
         LA    OVRR7,20(OVRR12,OVRR13)                                  08080000
OVRL83   LR    OVRR5,OVRR7                                              08100000
*   REGISTER USAGE IS AS FOLLOWS                                        08120000
*        REG 7 CONTAINS ADDRESS TO BE CHECKED.IT IS DESTROYED IN THE    08140000
*              PROCESS.                                                 08160000
*        REG 8 CONTAINS THE ENTRY POINT TO THE ROUTINE.                 08180000
*        REG 9 SET TO ZERO. INDICATES USE OF CURRENT TCB.               08200000
*        REG 10 RETURN ADDRESS.                                         08220000
*  IF THE ADDRESS IS CONSIDERED VALID, A CONDITION CODE OF 8 IS         08240000
*  RETURNED BY THE VALIDITY TEST ROUTINE.                               08260000
*                                                                       08280000
         STM   OVRR7,OVRR10,SAVEAREA+8(OVRR6)                           08300000
         SR    OVRR9,OVRR9    SET TCB ADDRESS REG TO ZERO.              08320000
         USING CVT,OVRR8                                                08340000
         L     OVRR8,CVT0VL00      ADDRESS OF VAL CHECK ROUTINE.        08360000
         DROP  OVRR8                                                    08380000
         BALR  OVRR10,OVRR8                                             08400000
         LM    OVRR7,OVRR10,SAVEAREA+8(OVRR6)                           08420000
         BCR   8,OVRR15                                                 08440000
         LA    OVRR15,557          ERROR CODE X'22D'                    08460000
         BCR   15,OVRR14        RETURN WITH ERROR CODE.                 08480000
*                                                                       08500000
*  THIS ROUTINE DETERMINES THE REGION FOR A GIVEN SEG.  IT MAKES A      08520000
*  LEFT TO RIGHT COMPARISON BETWEEN THE GIVEN SEGMENT AND BYTES 8,10,12 08540000
*  AND 14 OF SEGTAB WHICH CONTAIN THE NO. OF THE HIGHEST NO. SEGMENT    08560000
*  WHICH CAN BE LOADED IN A REGION (MAXSEG). WHEN THE GIVEN SEGMENT     08580000
*  NO. IS LESS THAN OR EQUAL TO A MAXSEG, THE GIVEN SEGMENT IS IN THAT  08600000
*  REGION. THE REGION POINTER IS OUTPUT IN REG 5.                       08620000
*  THE POINTER TO THE MAXSEG IS CONSIDERED TO GIVE THE REGION.          08640000
*                                                                       08660000
OVRL88   LA    OVRR3,4                 LOOP COUNT.                      08680000
         LA    OVRR5,6(OVRR12) ADDRESS OF FIRST MAXSEG - 2              08700000
OVRL89   LA    OVRR5,2(OVRR5)                                           08720000
         CLC   SAVEAREA+4(1,OVRR6),0(OVRR5) COMPARE NSEG TO MAXSEG.     08740000
         BCR   12,OVRR15  IF NSEG LESS OR EQ TO MAXSEG.                 08760000
         BCT   OVRR3,OVRL89                                             08780000
OVRL90   LA    OVRR15,301        ERROR CODE X'12D'.                     08800000
         BCR   15,OVRR14      RETURN WITH ERROR CODE.                   08820000
OVRLTEST DC    A(TESTINTR)                                              08840000
         DC    A(0)                                                     08860000
TESTINTR DC    C'IEGTTRNO'  TEST TRANS. INTR. FOR OVERLAY.              08880000
OVRLMNST DC    X'FD'                                                    08900000
         DC    AL3(OVRFWA)                                              08920000
*                                                                       08940000
         END                                                            08960000
