IEWSYOVR CSECT                                                          00020000
*0802067800                                                        AAAA 00040018
         TITLE 'IEWSYOVR BASIC SYNCHRONOUS OVERLAY SUPERVISOR-MIN SYS.' 00060000
*                                                                       00080000
*STATUS: CHANGE LEVEL O.                                                00100000
*                                                                       00120000
*FUNCTION/OPERATION:  RECEIVES CONTROL FROM RESIDENT OVERLAY SUPERVISOR 00140000
*   MODULE. EXAMINES STATUS OF REQUESTED SEGMENT. IF NOT IN MAIN        00160000
*   STORAGE, REQUESTED SEGMENT AND SEGMENTS HIGHER IN ITS PATH ARE      00180000
*   LOADED INTO MAIN STORAGE. TABLES ARE MODIFIED TO REFLECT THE STATUS 00200000
*   OF SEGMENTS IN MAIN STORAGE AND SEGMENTS OVERWRITTEN.               00220000
*                                                                       00240000
*ENTRY POINT:  IEWSYOVR.                                                00260000
*                                                                       00280000
*INPUT: REGISTERS ARE INITIALIZED AS FOLLOWS:                           00300000
*                                                                       00320000
*        REG 1 - ADDRESS OF AN ENTAB ENTRY.                             00340000
*        REG 2 - POSITIVE VALUE INDICATES SEGWT.                        00360000
*              - NEGATIVE VALUE INDICATES CALL OR BRANCH.               00380000
*        REG 6 - ADDRESS OF REGISTER SAVE AREA (EXTENDED SAVE AREA).    00400000
*        REG 8 - BASE OF COMMUNICATION VECTOR.                          00420000
*        REG 9 - NO. OF REQUESTED SEGMENT,RIGHT JUSTIFIED.              00440000
*        REG 10- ZERO                                                   00460000
*        REG 12- ADDRESS OF SEGTAB                                      00480000
*                                                                       00500000
*OUTPUT: N/A                                                            00520000
*                                                                       00540000
*EXTERNAL ROUTINES:- IEWFTMIN  - PROGRAM FETCH.                         00560000
*                  - IEAVLDCK  - VALIDITY CHECK RTN.                    00580000
*                  - IEGTTRNO  - TEST TRANSLATOR INTERPRETER FOR OVER-  00600000
*                                LAY.                                   00620000
*                                                                       00640000
*EXITS:- NORMAL  UPON EXIT, REGISTER 15 IS SET TO A RETURN CODE. RETURN 00660000
*                IS TO THE RESIDENT MODULE WHICH INTERPRETS THE RETURN  00680000
*                CODE. REGISTER 15 IS USED TO CONTAIN THE RETURN CODE   00700000
*                ON NORMAL RETURNS, THE CODE IS ZERO.                   00720000
*      - ERRORS  THE ERROR RETURN CODES ARE PLACED IN THE LOW ORDER     00740000
*                BYTES OF REGISTER 15.                                  00760000
*                    CODES   - X'12D'   SEGMENT TABLE HAS BEEN CONTAMI- 00780000
*                                       NATED.                          00800000
*                            - X'22D'   VALIDITY TEST INDICATES AN AD-  00820000
*                                       DRESS IN ENTAB OR SEGTAB HAS    00840000
*                                       BEEN DESTROYED AND NOW ADDRESS- 00860000
*                                       ES A LOCATION OUTSIDE OF THE    00880000
*                                       PROBLEM PROGRAM.                00900000
*                           - X'X2D'   AN ERROR HAS BEEN DETECTED BY    00920000
*                                      PROGRAM FETCH. 'X' IS THE CODE   00940000
*                                      RETURNED BY PROGRAM FETCH.       00960000
*                            X = F     I/O ERROR.                       00980000
*                            X = E     INVALID ADDRESS.                 01000000
*                            X = D     INVALID RECORD TYPE.             01020000
*                                                                       01040000
         EJECT                                                          01060000
*TABLES/WORK AREAS:                                                     01080000
*                                                                       01100000
*  SEGTAB                                                               01120000
*                                                                       01140000
*    '***************'***************'***************'***************'  01160000
*    '0 BIT 1-0 NOT  '1              '2              '3              '  01180000
*    '          IN   '                                               '  01200000
*    '          TEST '        DCB  ADDRESS                           '  01220000
*    '       -1 IN   '                                               '  01240000
*    '          TEST '                                               '  01260000
*    '***************'***************'***************'***************'  01280000
*    '4              '5              '6              '7              '  01300000
*    '               '        NOTE LIST ADDRESS                      '  01320000
*    '               '                                               '  01340000
*    '***************'***************'***************'***************'  01360000
*    '8 HIGHEST SEG  '9  HIGHEST SEG '10 HIGHEST SEG '11 HIGHEST SEG '  01380000
*    'IN REGION 1    'OF REGION 1 IN 'IN REGION 2    'OF REGION 2 IN '  01400000
*    '               'MAIN STORAGE   '               'MAIN STORAGE   '  01420000
*    '***************'***************'***************'***************'  01440000
*    '12 HIGHEST SEG '13 HIGHEST SEG '14HIGHEST SEG  '15 HIGHEST SEG '  01460000
*    'IN REGION 3    'OF REGION 3 IN 'IN REGION 4    'OF REGION 4 IN '  01480000
*    '               'MAIN STORAGE   '               'MAIN STORAGE   '  01500000
*    '***************'***************'***************'***************'  01520000
*    '16             '17             '18             '19             '  01540000
*    '                  NOT USED BY THIS MODULE                      '  01560000
*    '                                                                  01580000
*    '***************'***************'***************'***************'  01600000
*    '20             '21             '22             '23             '  01620000
*    '                  NOT USED BY THIS MODULE                      '  01640000
*    '                                                               '  01660000
*    '***************'***************'***************'***************'  01680000
*ROOT'24             '25             '26             '27             '  01700000
* 1ST' PREVIOUS SEG- '        CALLER FIELD                           '  01720000
* SEG' MENT FIELD.   '                                               '  01740000
*    '               '                                               '  01760000
*    '***************'***************'***************'***************'  01780000
*    '28             '29             '30             '31             '  01800000
* 2ND' PREVIOUS SEG- '        CALLER FIELD                           '  01820000
* SEG' MENT FIELD    '                                               '  01840000
*    '               '                                               '  01860000
*    '***************'***************'***************'***************'  01880000
*                                                                       01900000
* ETC.                                                                  01920000
*  NOTES ON SEGTAB                                                      01940000
*    1. THE TEST BIT IS SET BY PROGRAM FETCH IF THE PROGRAM ATTRIBUTES  01960000
*       INDICATE THAT THE PROGRAM IS IN TEST                            01980000
*    2. THE DCB ADDRESS POINTS TO THE DCB USED TO LOAD THE ROOT. IT IS  02000000
*       USED EACH TIME A SEGMENT IS LOADED. THE ADDRESS IS INITIALIZED  02020000
*       BY PROGRAM FETCH.                                               02040000
*    3. THE NOTE LIST IS READ BY PROGRAM FETCH AND THE ADDRESS IN       02060000
*       SEGTAB IS INITIALIZED BY PROGRAM FETCH.                         02080000
*    4. THE PREVIOUS SEGMENT FIELD CONTAINS THE NUMBER OF THE SEGMENT   02100000
*       IMMEDIATELY ABOVE THIS SEGMENT IN THE OVERLAY TREE.             02120000
*    5. THE CALLER FIELD IS USED TO RECORD THE CURRENT STATUS OF A      02140000
*       SEGMENT. THE LOW ORDER 2 BITS ARE USED.                         02160000
*                                                                       02180000
*                     00 - IN MAIN STORAGE                              02200000
*                     10 - IN MAIN STORAGE                              02220000
*                     01 - NOT IN MAIN STORAGE,BUT MUST BE LOADED       02240000
*                     11 - NOT IN MAIN STORAGE,NOT TO BE LOADED         02260000
*       THE 00 INDICATES THAT THE REMAINDER OF THE FIELD CONTAINS THE   02280000
*       ADDRESS OF AN ENTAB ENTRY WHICH WAS MODIFIED WHEN THIS SEGMENT  02300000
*       WAS BROUGHT INTO MAIN STORAGE.                                  02320000
*                                                                       02340000
*                                                                       02360000
*ENTAB                                                                  02380000
*                                                                       02400000
*                                                                       02420000
*  ALL ENTRIES BUT THE LAST                                             02440000
*                                                                       02460000
*  '********************'********************'********************'     02480000
*  '                    '                    ' SEG X              '     02500000
*  ' BC  15,DIS(15,0)   ' ADDRESS CONSTANT   ' NO  X PREVIOUS     '     02520000
*  '                    '                    ' OF  X CALLER       '     02540000
*  '                    ' LOCATION OF ENTRY  ' REQ.X FIELD        '     02560000
*  '                    ' POINT IN REQUESTED ' SEG X              '     02580000
*  '                    ' SEGMENT            '     X              '     02600000
*  '********************'********************'********************'     02620000
*  '     4 BYTES        '     4 BYTES        ' 1   '   3 BYTES    '     02640000
*                                             BYTE                      02660000
*                                                                       02680000
*                                                                       02700000
*   DIS  IS THE DISPLACEMENT BETWEEN THE BEGINNING OF THIS LINE AND THE 02720000
*   LAST LINE IN THE TABLE.                                             02740000
*                                                                       02760000
*                                                                       02780000
*  LAST ENTRY                                                           02800000
*                                                                       02820000
*  '********************'********************'*******************'      02840000
*  '         *          '         *          'SEG  *             '      02860000
*  '  SVC 45 *  L 15,4(0,15)      *BCR 15,15 'NO OF* ADDRESS OF  '      02880000
*  '         *                    *          'THIS *   SEGTAB    '      02900000
*  '         *                    *          'ENTAB*             '      02920000
*  '********************'********************'*******************'      02940000
*  '  2 BYTES'      4 BYTES       '  2 BYTES ' 1   '   3 BYTES   '      02960000
*                                             BYTE                      02980000
*ATTRIBUTES:   READ ONLY,REENTRANT,PRIVILEGED,ENABLED.                  03000000
         EJECT                                                          03020000
SAVEAREA EQU   96                                                       03040000
OVRR0    EQU   0                                                        03060000
OVRR1    EQU   1                                                        03080000
OVRR2    EQU   2                                                        03100000
OVRR3    EQU   3                                                        03120000
OVRR4    EQU   4                                                        03140000
OVRR5    EQU   5                                                        03160000
OVRR6    EQU   6                                                        03180000
OVRR7    EQU   7                                                        03200000
OVRR8    EQU   8                                                        03220000
OVRR9    EQU   9                                                        03240000
OVRR10   EQU   10                                                       03260000
OVRBRG   EQU   11                                                       03280000
OVRR12   EQU   12                                                       03300000
OVRR13   EQU   13                                                       03320000
OVRR14   EQU   14                                                       03340000
OVRR15   EQU   15                                                       03360000
OVRFWA   EQU   440    SIZE OF FETCH WORK AREA IN ANY SYSTEM             03380018
CVT      DSECT                                                          03400000
         CVT   SYS=MIN                                                  03420000
         EJECT                                                          03440000
IEWSYOVR CSECT                                                          03460000
*                                                                       03480000
         BALR  OVRBRG,0      SET UP BASE REGISTER.                      03500000
         USING *,OVRBRG                                                 03520000
         STC   OVRR9,SAVEAREA+4(OVRR6)  SAVE NSEG.                      03540000
*                                                                       03560000
* DETERMINE THE REGION CONTAINING NSEG AND SAVE IT.                     03580000
*                                                                       03600000
         BAL   OVRR15,OVRL88  GET REGION OF NSEG.                       03620000
         ST    OVRR5,SAVEAREA(OVRR6)   SAVE REGION PTR.                 03640000
         LR    OVRR4,OVRR5                                              03660000
*                                                                       03680000
* DETERMINE ADDRESS OF SEGTAB LINE FOR NSEG                             03700000
*                                                                       03720000
         LR    OVRR13,OVRR9        MOVE SEGNO FOR ADDRESS COMPUTE  RTN. 03740000
         BAL   OVRR15,OVRL80  COMPUTE ADDRESS AND VALIDITY CHECK IT.    03760000
*                                                                       03780000
         LR    OVRR0,OVRR5   SAVE SEGTAB ENTRY ADDRESS FOR NSEG.        03800000
         TM    3(OVRR5),X'03' IS SEGMENT IN MAIN STORAGE.               03820000
         BC    14,OVRL60      BRANCH IF YES.                            03840000
*                                                                       03860000
*                                                                       03880000
OVRL25   IC    OVRR10,1(OVRR4)     GET OSEG FOR THIS REGION.            03900000
         STC   OVRR9,1(OVRR4) STORE NEW OSEG.                           03920000
*                                                                       03940000
*  DETERMINE SEGMENTS TO BE LOADED AND MARK THEM. DETERMINE SEGMENTS    03960000
*    BEING OVERWRITTEN AND RESET TABLES.                                03980000
*                                                                       04000000
OVRL30   CLR   OVRR9,OVRR10   COMPARE NSEG TO OSEG.                     04020000
         BC    4,OVRL40       OSEG GT NSEG.                             04040000
         BC    8,OVRL50  OSEG EQ NSEG.                                  04060000
*                                                                       04080000
*   THIS SECTION MARKS SEGMENTS TO BE LOADED.                           04100000
*                                                                       04120000
         LR    OVRR13,OVRR9   SET UP ENTRY FOR ADDRESS CHECK RTN.       04140000
         BAL   OVRR15,OVRL80  COMPUTE ADDRESS AND CHECK IT.             04160000
         MVI   3(OVRR5),X'01'           SET ON LOAD INDICATOR           04180000
         IC    OVRR9,0(OVRR5) SET NSEG EQ TO PSEG(NSEG).                04200000
         BC    15,OVRL30                                                04220000
*                                                                       04240000
*   THIS SECTION RESETS TABLES FOR SEGMENTS BEING OVERWRITTEN.          04260000
*                                                                       04280000
OVRL40   LR    OVRR13,OVRR10  SET OSEG IN OVRR13 FOR ADDRESS COMPUTE.   04300000
         BAL   OVRR15,OVRL80  COMPUTE ADDRESS AND CHECK IT.             04320000
         EJECT                                                          04340000
*                                                                       04360000
*                                                                       04380000
** DONT PUT INSTRUCTIONS IN THIS BOX BELOW TM WHICH CHANGE THE CC ***** 04400000
*                                                                       04420000
         TM    3(OVRR5),X'03' DOES CALLER FIELD CONTAIN AN ADDRESS.   * 04440000
*                                                                     * 04460000
         L     OVRR7,0(OVRR5)     SAVE CALLER FIELD.                  * 04480000
         LR    OVRR3,OVRR5  SAVE PTR TO CURRENT SEGTAB ENTRY.           04500000
*                                                                     * 04520000
         MVI   3(OVRR5),X'03' SET NOT LOADED INDICATOR.               * 04540000
         BC    8,OVRL43       BRANCH IF CALLER FIELD CONTAINE AN ADDR.* 04560000
*                                                                       04580000
*********************************************************************** 04600000
*                                                                       04620000
*                                                                       04640000
OVRL41   IC    OVRR10,0(OVRR3)  SET OSEG EQ TO PSEG OF OSEG.            04660000
         BC    15,OVRL30   GO BACK FOR NEXT NSEG-OSEG COMPARISON.       04680000
*                                                                       04700000
*   RESET ENTAB ENTRIES USING CHAIN WHICH STARTS IN CALLER FIELD.       04720000
*                                                                       04740000
OVRL43   LA    OVRR7,0(OVRR7)    CLEAR OUT HIGH ORDER BYTE.             04760000
OVRL44   BAL   OVRR15,OVRL83  VALIDITY TEST THIS ADDRESS.               04780000
         XI    3(OVRR5),X'02'          RESET THIS ENTAB ENTRY.          04800000
         L     OVRR4,8(OVRR5)  GET PCALLER FIELD OF THIS ENTRY ENTAB    04820000
OVRL45   LA    OVRR4,0(OVRR4)   REMOVE THE SEGMENT NUMBER.              04840000
         LTR   OVRR4,OVRR4      TEST FOR ZERO.                          04860000
         BC    8,OVRL41         BRANCH IF PCALLER FIELD WAS ZERO.       04880000
         XC    9(3,OVRR5),9(OVRR5) SET PCALLER FIELD TO ZERO.           04900000
         LR    OVRR7,OVRR4                                              04920000
         BC    15,OVRL44      GO BACK WITH NEXT ADDRESS IN CHAIN.       04940000
*                                                                       04960000
*   THIS SECTION RESCANS SEGTAB AND LOADS SEGMENTS MARKED TO BE LOADED. 04980000
*                                                                       05000000
OVRL50   LR    OVRR13,OVRR8  MOVE BASE ADDRESS OF COMM. VECTOR.         05020000
         LR    OVRR8,OVRR0        SAVE REGS 0,1 IN 8,10.                05040000
         LR    OVRR10,OVRR1                                             05060000
         L     OVRR0,OVRLMNST      MAIN STORAGE FOR FETCH.              05080000
         GETMAIN R,LV=(0)                                               05100000
         LR    OVRR3,OVRR1       SHIFT TO FETCH'S REG.                  05120000
         IC    OVRR9,8(OVRR10)    PICK UP NSEG.                         05140000
OVRL52   SLL   OVRR9,2            MULTIPLY BY 4.                        05160000
         LA    OVRR1,20(OVRR12,OVRR9)                                   05180000
         TM    3(OVRR1),X'01'  MUST SEG BE LOADED.                      05200000
         BC    14,OVRL57           BRANCH ON NO.                        05220000
         STM   OVRR8,OVRR2,SAVEAREA+4(OVRR6)   SAVE REGS.               05240000
*                                                                       05260000
*  ENTER PROGRAM FETCH TO LOAD A SEGMENT. REGISTER SETTINGS:            05280000
*                   REG 3 - ADDRESS OF WORK AREA.                       05300000
*                   REG 7 - ADDRESS OF DCB.                             05320000
*                   REG 8 - ADDRESS OF NOTE LIST.                       05340000
*                   REG 9 - SEGMENT NO. MULTIPLIED BY 4.                05360000
*  ALL REGISTERS ARE VOLATILE IN PROGRAM FETCH EXCEPT REGS 3 AND 6.     05380000
*  FETCH PASSES A RETURN CODE IN REG 15. IF NON-ZERO, AN ERROR  HAS     05400000
*  OCCURRED.                                                            05420000
*                                                                       05440000
         LM    OVRR7,OVRR8,0(OVRR12)   PUT DCB AND NOTE LIST IN PAR REG 05460000
         USING CVT,OVRR13                                               05480000
         L     OVRR15,CVTFBOSV     GET ADDRESS OF PROGRAM FETCH.        05500000
         DROP  OVRR13                                                   05520000
         BALR  OVRR14,OVRR15           GO TO FETCH.                     05540000
         EJECT                                                          05560000
*                                                                       05580000
*** DONT PUT INSTRUCTIONS IN THIS BOX WHICH CHANGE THE CC ************* 05600000
*                                                                       05620000
         LTR   OVRR7,OVRR15       TEST COMPLETION INDICATOR.            05640000
         LM    OVRR8,OVRR2,SAVEAREA+4(OVRR6)                            05660000
         BC    7,OVRL70            BRANCH IF ERROR IN LOADING.        * 05680000
*********************************************************************** 05700000
*                                                                       05720000
         MVI   3(OVRR1),X'02'      SET ON LOADED INDICATOR.             05740000
         SR    OVRR9,OVRR9             CLEAR REG 9                 8140 05760000
         IC    OVRR9,0(OVRR1)     GET NEXT SEG IN PATH.                 05780000
         BC    15,OVRL52                                                05800000
OVRL57   LR    OVRR1,OVRR3    SET UP FOR FREEMAIN.                      05820000
         FREEMAIN R,LV=(0),A=(1)                                        05840000
         LR    OVRR0,OVRR8       RESET REGS 0,1                         05860000
         LR    OVRR1,OVRR10                                             05880000
*                                                                       05900000
* IF PROGRAM IS IN TEST, LINK TO TEST TRANSLATOR INTERPRETER. PARAMETER 05920000
*    PASSED IS ADDRESS OF SEGTAB IN REGISTER 12. ALL REGISTERS (0-13)   05940000
*    ARE TRANSPARENT.                                                   05960000
*                                                                       05980000
OVRL58   TM    0(OVRR12),X'40'       IS PROGRAM IN TEST.                06000000
         BC    14,OVRL60   BRANCH IF NO.                                06020000
         LR    OVRR9,OVRR14                                             06040000
         LA    OVRR15,OVRLTEST    LINK PARAM. LIST.                     06060000
         LINK  MF=(E,(1)),SF=(E,(15))                                   06080000
         LR    OVRR14,OVRR9                                             06100000
*                                                                       06120000
*  IF REQUEST WAS A CALL OR BRANCH AND                                  06140000
*  IF THE 'FROM' AND 'TO' SEGMENT ARE IN THE SAME REGION OR IF THE      06160000
*     REQUEST IS THRU THE ENTAB IN THE ROOT SEGMENT                     06180000
*  THE ENTAB ENTRY IS MODIFIED SO THAT SUBSEQUENT BRANCHES TO THAT      06200000
*     ENTRY WILL BYPASS THE SVC 45 AND CONTROL WILL PASS DIRECTLY TO    06220000
*     THE CALLED SEGMENT.                                               06240000
*                                                                       06260000
OVRL60   LTR   OVRR2,OVRR2    IS THE REQUEST A SEGWT.                   06280000
         BC    2,OVRL68         BRANCH IF YES                           06300000
         ST    OVRR12,SAVEAREA+4(OVRR6) PUT SEGNO OF ENTAB IN SAVEAREA. 06320000
         CLI   SAVEAREA+4(OVRR6),X'01'   IS REQUEST FRON ROOT ENTAB.    06340000
         BC    8,OVRL63                                                 06360000
         BAL   OVRR15,OVRL88   GET REGION OF ENTAB.                     06380000
         CL    OVRR5,SAVEAREA(OVRR6)    COMPARE REGION PTRS.            06400000
         BC    7,OVRL68  BRANCH IF UNEQUAL.                             06420000
*                                                                       06440000
*   THIS SECTION RESETS ENTAB ENTRY FOR REQUESTED SEGMENT AND UPDATES   06460000
*    SEGTAB.                                                            06480000
*                                                                       06500000
OVRL63   LR    OVRR5,OVRR0    GET ADDRESS OF SEGTAB ENTRY.              06520000
         TM    3(OVRR5),X'03' DOES IT CONTAIN AN ADDRESS.               06540000
         BC    7,OVRL65       BRANCH IF NO.                             06560000
         MVC   9(3,OVRR1),1(OVRR5) MOVE ADDRESS TO PCALLER FIELD.       06580000
OVRL65   IC    OVRR4,0(OVRR5)      SAVE PSEG FIELD.                     06600000
         ST    OVRR1,0(OVRR5) STORE ADDRESS OF ENTAB IN CALLER FIELD.   06620000
         STC   OVRR4,0(OVRR5) RESTORE PSEG FIELD.                       06640000
         XI    3(OVRR1),X'02'      INCREMENT ENTAB BRANCH.              06660000
*                                                                       06680000
*                                                                       06700000
*        RETURN                                                         06720000
OVRL68   SR    OVRR15,OVRR15   SET ERROR CODE TO NORMAL RETURN.         06740000
         BCR   15,OVRR14      RETURN...........                         06760000
OVRL70   LA    15,15                                               AAAA 06766018
         CR    OVRR7,15      CHECK FOR RETURN CODE OF F            AAAA 06772018
         BC    7,OVRL71                                            AAAA 06778018
         LA    OVRR7,3       CHANGE CODE OF F TO 3                 AAAA 06784018
OVRL71   SLL   OVRR7,8                                             AAAA 06790018
         LA    OVRR15,45(OVRR7)        MERGE ERROR CODES.               06800000
         BCR   15,OVRR14      RETURN WITH ERROR CODE.                   06820000
*                                                                       06840000
         EJECT                                                          06860000
*  AT ENTRY TO OVERL80, REG 13 CONTAINS A SEGMENT NUMBER. IT IS MULTI-  06880000
*  PLIED BY 4 AND ADDED TO THE SEGTAB ADDRESS PLUS PREFIX BYTES (24-4)  06900000
*  TO GET THE ADDRESS OF THE SEGTAB LINE FOR THE GIVEN SEGMENT. UPON    06920000
*  RETURN FROM THIS ROUTINE, THE RESULTING ADDRESS IS IN REG 5.         06940000
*  AT ENTRY TO OVRL83, THE ADDRESS TO BE CHECKED IS ASSUMED TO BE IN    06960000
*  REG 7                                                                06980000
*                                                                       07000000
OVRL80   SLL   OVRR13,2       MULTIPLY BY 4.                            07020000
         LA    OVRR7,20(OVRR12,OVRR13)                                  07040000
OVRL83   LR    OVRR5,OVRR7                                              07060000
*   REGISTER USAGE IS AS FOLLOWS                                        07080000
*        REG 7 CONTAINS ADDRESS TO BE CHECKED.IT IS DESTROYED IN THE    07100000
*              PROCESS.                                                 07120000
*        REG 8 CONTAINS THE ENTRY POINT TO THE ROUTINE.                 07140000
*        REG 9 SET TO ZERO. INDICATES USE OF CURRENT TCB.               07160000
*        REG 10 RETURN ADDRESS.                                         07180000
*  IF THE ADDRESS IS CONSIDERED VALID, A CONDITION CODE OF 8 IS         07200000
*  RETURNED BY THE VALIDITY TEST ROUTINE.                               07220000
*                                                                       07240000
         STM   OVRR7,OVRR10,SAVEAREA+8(OVRR6)                           07260000
         SR    OVRR9,OVRR9    SET TCB ADDRESS REG TO ZERO.              07280000
         USING CVT,OVRR8                                                07300000
         L     OVRR8,CVT0VL00      ADDRESS OF VAL CHECK ROUTINE.        07320000
         DROP  OVRR8                                                    07340000
         BALR  OVRR10,OVRR8                                             07360000
         LM    OVRR7,OVRR10,SAVEAREA+8(OVRR6)                           07380000
         BCR   8,OVRR15                                                 07400000
         LA    OVRR15,557          ERROR CODE X'22D'                    07420000
         BCR   15,OVRR14      RETURN WITH ERROR CODE.                   07440000
*                                                                       07460000
*  THIS ROUTINE DETERMINES THE REGION FOR A GIVEN SEG.  IT MAKES A      07480000
*  LEFT TO RIGHT COMPARISON BETWEEN THE GIVEN SEGMENT AND BYTES 8,10,12 07500000
*  AND 14 OF SEGTAB WHICH CONTAIN THE NO. OF THE HIGHEST NO. SEGMENT    07520000
*  WHICH CAN BE LOADED IN A REGION (MAXSEG). WHEN THE GIVEN SEGMENT     07540000
*  NO. IS LESS THAN OR EQUAL TO A MAXSEG, THE GIVEN SEGMENT IS IN THAT  07560000
*  REGION. THE REGION POINTER IS OUTPUT IN REG 5.                       07580000
*  THE POINTER TO THE MAXSEG IS CONSIDERED TO GIVE THE REGION.          07600000
*                                                                       07620000
OVRL88   LA    OVRR3,4                 LOOP COUNT.                      07640000
         LA    OVRR5,6(OVRR12) ADDRESS OF FIRST MAXSEG - 2              07660000
OVRL89   LA    OVRR5,2(OVRR5)                                           07680000
         CLC   SAVEAREA+4(1,OVRR6),0(OVRR5) COMPARE NSEG TO MAXSEG.     07700000
         BCR   12,OVRR15  IF NSEG LESS OR EQ TO MAXSEG.                 07720000
         BCT   OVRR3,OVRL89                                             07740000
         LA    OVRR15,301          ERROR CODE X'12D'                    07760000
         BCR   15,OVRR14      RETURN WITH ERROR CODE.                   07780000
OVRLTEST DC    A(TESTINTR)                                              07800000
         DC    A(0)                                                     07820000
TESTINTR DC    C'IEGTTRNO'  TEST TRANS. INTR. FOR OVERLAY.              07840000
OVRLMNST DC    X'FD'                                                    07860000
         DC    AL3(OVRFWA)                                              07880000
*                                                                       07900000
         END                                                            07920000
