         EJECT                                                          00500019
*********************************************************************** 01000019
*                                                                     * 01500019
* TITLE- IGC00088,SVC 88                                              * 02000019
*                                                                     * 02500019
* STATUS- CHANGE LEVEL 001                                            * 03000019
*                                                                     * 03500019
* FUNCTION/OPERATION- THE MAIN FUNCTIONS OF THIS ROUTINE ARE TO CHANGE* 04000019
*        THE PARITY OR DENSITY BITS,AS REQUIRED,IN THE DEBDVMOD FIELD * 04500019
*        OF THE DEB.ALSO,AT OPEN TIME,THIS ROUTINE WILL BE USED TO    * 05000019
*        TURN ON DEB BIT 8.5 WHICH DENOTES EMULATOR MODE,7 TRACK      * 05500019
*        OPERATION.AT CLOSE TIME THIS ROUTINE WILL BE USED TO TURN    * 06000019
*        DEB 8.5 OFF.                                                 * 06500019
*        DEB BIT 8.3(NOISE BIT) IS USED BY 7 OR 9 TRACK NATIVE        * 07000019
*        MODE TAPES.IF A NOISE RECORD IS DETECTED AND 8.3 IS ON       * 07500019
*        2400 TAPE ERP FLAGS THE RECORD AS A PERMANENT I/O ERROR.     * 08000019
*                                                                     * 08500019
* ENTRY POINT- IGC00088                                               * 09000019
*                                                                     * 09500019
* INPUT- 1) JOB CODE IN REGISTER 0.ISSUED BY   MOD88  MACRO ACCORDING * 10000019
*        TO PARAMETER SUPPLIED TO THE   MOD88  MACRO BY THE USER.     * 10500019
*                                                                     * 11000019
*        2) DCB ADDRESS IN REGISTER 1.                                * 11500019
*                                                                     * 12000019
* OUTPUT- N/A                                                         * 12500019
*                                                                     * 13000019
* EXTERNAL ROUTINES- N/A                                              * 13500019
*                                                                     * 14000019
* EXITS-NORMAL- 1) RETURN CODE OF ZERO IN REGISTER 15.                * 14500019
*                                                                     * 15000019
*               2) SVC 3.                                             * 15500019
*                                                                     * 16000019
*      -ERROR - 1) RETURN CODE OF FOUR IN REGISTER 15.SVC USAGE ERROR.* 16500019
*                                                                     * 17000019
*               2) BR 14 TO USER.                                     * 17500019
*                                                                     * 18000019
* TABLES/WORK AREAS- 1) MAINTAIN- SVC MAINTENANCE AREA                * 18500019
*                                                                     * 19000019
* ATTRIBUTES- REENTRANT                                               * 19500019
*                                                                     * 20000019
* NOTES- N/A                                                          * 20500019
*                                                                     * 21000019
*********************************************************************** 21500019
         EJECT                                                          22000019
IGC00088 CSECT                                                          22500019
         BALR  RBASEREG,ZERO            ESTABLISH                       23000019
         USING *,RBASEREG                         ADDRESSABILITY        23500019
*********************************************************************** 24000019
*        DCB ADDRESS CHECK,PASSED CODE NUMBER CHECK,AND 2400 TAPE     * 24500019
*                                CHECK                                * 25000019
*********************************************************************** 25500019
         LR    RDCBADDR,RDCB@REG        GET PASSED DCB ADDRESS          26000019
         L     RDEBADDR,DEBPOINT(RDCBADDR) GET DEB ADDRESS.FOUND IN DCB 26500019
         LA    RDEBADDR,ZERO(RDEBADDR)  CLEAR HIGH ORDER BYTE OF REG 7  27000019
         L     RDEBDCB@,DCBPOINT(RDEBADDR) GET DCB ADDRESS.FOUND IN DEB 27500019
         LA    RDEBDCB@,ZERO(RDEBDCB@)  CLEAR HIGH ORDER BYTE OF REG 8  28000019
*********************************************************************** 28500019
*                                       THE FOLLOWING INSTRUCTION TESTS 29000019
*                                       THE DCB ADDRESS AS PASSED BY    29500019
*                                       THE USER,WITH THE DCB ADDRESS   30000019
*                                       FOUND IN THE DEB.THIS INSURES   30500019
*                                       THAT THE CORRECT DEB WILL BE    31000019
*                                       TESTED AND MODIFIED BY THE      31500019
*                                       EMULATOR SVC,SVC 88.            32000019
*********************************************************************** 32500019
         CR    RDCBADDR,RDEBDCB@   Q.IF DCB ADDRESSES ARE               32510019
         BNE    ERROR       NOT  ALIKE,GO TO BRANCH TABLE               32520019
***************                                                         32530019
*        THE DEB CHAIN IS SEARCHED TO SEE IF THE ADDRESS                32540019
*        REPORTEDLY IN THE DCB IS ACTUALLY CHAINED TO                   32550019
*        THE USERS TCB                                                  32560019
         L     RTCBDEB,TCBDEB(RSVCTCB)   GET DEB CHAIN ORIGIN           32570019
         LA    RTCBDEB,ZERO(RTCBDEB)     CLEAR HIGH ORDER BYTE          32590019
         LTR   RTCBDEB,RTCBDEB     Q. ANY DEBS                          32610019
         BZ    ERROR               NO, GO GO ERROR                      32620019
LOOP     CR    RDEBADDR,RTCBDEB    Q. ARE DEB ADDRESSES EQUAL           32630019
         BE    BRTABLE             YES,GO TO BRANCH TABLE               32640019
         L     RTCBDEB,DEBDEB(RTCBDEB)  GET ADDR OF NEXT ANYWAY         32650019
         LA    RTCBDEB,ZERO(RTCBDEB)   CLEAR HIGH ORDER BYTE            32670019
         LTR   RTCBDEB,RTCBDEB     Q. IS IT END OF CHAIN                32690019
         BZ    ERROR               YES,GO TO ERROR EXIT                 32700019
         B     LOOP                NO,SEARCH MORE                       32710019
ERROR    LA    RERORREG,SVCERROR        ERROR IN THE SVC ROUTINE        34000019
         BR    RBRTOREG                 RETURN VIA REGISTER 14          34500019
BRTABLE  CL    RCODEREG,CODECHCK        Q. IS THE INPUT CODE > 32 ?.    35000019
         BH    ERROR                    YES,GO TO ERROR EXIT            35500019
         L     RUCBADDR,UCBPOINT(RDEBADDR)  GET UCB ADDRESS             36000019
         LA    RUCBADDR,ZERO(RUCBADDR)  CLEAR HIGH ORDER BYTE           36500019
         TM    DEVCLASS(RUCBADDR),TAPE  IS THE UNIT TYPE 2400 TAPE      37000019
         BZ    ERROR                    NOT 2400 TAPE,RC=4              37500019
         LR    RCODEPAS,RCODEREG                                        38000019
         B     TABLE(RCODEPAS)          CODE DEPENDENT BRANCH           38500019
*********************************************************************** 39000019
*                     BRANCH TABLE                                    * 39500019
*********************************************************************** 40000019
TABLE    B     EMMUON                   DEB 8.5 ON     CODE 00          40500019
         B     EMMUOFF                  DEB 8.5 OFF    CODE 04          41000019
         B     EVENPAR                  EVEN PARITY    CODE 08          41500019
         B     ODDPAR                   ODD PARITY     CODE 12          42000019
         B     TWOBPI                   200 BPI DENSITY CODE 16         42500019
         B     FIVBPI                   556 BPI DENSITY CODE 20         43000019
         B     EIGTHBPI                 800 BPI DENSITY CODE 24         43500019
         B     XEMMUON                  DEB 8.3 ON     CODE 28          44000019
         B     XEMMUOFF                 DEB 8.3 OFF    CODE 32          44500019
*********************************************************************** 45000019
*                            DEB 8.5 ON OR OFF                        * 45500019
*********************************************************************** 46000019
EMMUON   BAL   RRETOREG,TEST7TRK        TEST FOR 7 TRACK                46500019
         OI    DEBEMUBT(RDEBADDR),EMULON  TURN DEB 8.5 ON               47000019
         B     EXIT         RETURN                                      47500019
EMMUOFF  BAL   RRETOREG,TEST7TRK        TEST FOR 7 TRACK                48000019
         NI    DEBEMUBT(RDEBADDR),EMULOFF  TURN DEB 8.5 OFF             48500019
         B     EXIT                                                     49000019
*********************************************************************** 49500019
*                       EVEN OR ODD PARITY SET                        * 50000019
*********************************************************************** 50500019
EVENPAR  BAL   RRETOREG,DEB85ON         TEST DEB 8.5                    51000019
         NI    DEBDVMOD(RDEBADDR),PAROFF TURN OFF PARITY BITS           51500019
         OI    DEBDVMOD(RDEBADDR),PAREVEN SET DEBDVMOD TO EVEN PARITY   52000019
         B     EXIT              RETURN                                 52500019
ODDPAR   BAL   RRETOREG,DEB85ON                                         53000019
         NI    DEBDVMOD(RDEBADDR),PAROFF                                53500019
         OI    DEBDVMOD(RDEBADDR),PARODD  SET DEBDVMOD TO ODD PARITY    54000019
         B     EXIT              RETURN                                 54500019
*********************************************************************** 55000019
*                            200,556,800 BPI SET                      * 55500019
*********************************************************************** 56000019
TWOBPI   BAL   RRETOREG,DEB85ON       TEST DEB 8.5                      56500019
         NI    DEBDVMOD(RDEBADDR),LOWDEN TURN DEBDVMOD DEN BITS OFF(00) 57000019
         B     EXIT              RETURN                                 57500019
FIVBPI   BAL   RRETOREG,DEB85ON                                         58000019
         NI    DEBDVMOD(RDEBADDR),LOWDEN TURN OFF EXISTING DEN BITS     58500019
         OI    DEBDVMOD(RDEBADDR),MIDDEN TURN ON 556 BPI BITS(01)       59000019
         B     EXIT                                                     59500019
EIGTHBPI BAL   RRETOREG,DEB85ON                                         60000019
         NI    DEBDVMOD(RDEBADDR),LOWDEN TURN OFF EXISTING DEN BITS     60500019
         OI    DEBDVMOD(RDEBADDR),HIGHDEN TURN ON 800 BPI BITS(10)      61000019
         B     EXIT                                                     61500019
*********************************************************************** 62000019
*                            DEB 8.3 ON OR OFF SET                    * 62500019
*********************************************************************** 63000019
XEMMUON  OI    DEBEMUBT(RDEBADDR),XEMULON   TURN DEB 8.3 ON RELEASE 19  63500019
         B     EXIT                     RC=0                            64000019
XEMMUOFF NI    DEBEMUBT(RDEBADDR),XEMULOFF  TURN DEB 8.3 OFF RELEASE 19 64500019
         B     EXIT                     RC=0                            65000019
*********************************************************************** 65500019
*        DEB 8.5 OR 8.3 CHECK,AND 7 TRACK TEST                        * 66000019
*********************************************************************** 66500019
DEB85ON  TM    DEBEMUBT(RDEBADDR),EMULBITS  IS DEB 8.5,AND OR 8.3 ON    67000019
         BZ    ERROR                    NO,ERROR IN THE SVC ROUTINE     67500019
TEST7TRK TM    OPTNFEAT(RUCBADDR),SEVTRACK  IS IT A 7 TRACK TAPE        68000019
         BZ    ERROR                        NOT 7 TRACK,RC=4            68500019
         BR    RRETOREG                     RETURN TO NS:               69000019
EXIT     XR    RERORREG,RERORREG        RETURN CODE 0. NO ERRORS        69500019
          BR    RBRTOREG             RETURN                             70000019
*                                                                       70500019
*        GENERAL REGISTER EQUATES                                       71000019
*                                                                       71500019
RCODEREG EQU   00                       CONTAINS THE SVC 88 ROUTINE CDE 72000019
RDCB@REG EQU   01                       CONTAINS THE DCB ADDRESS        72500019
RCODEPAS EQU   02                       COPY OF MACRO PASSED SVC CODE   73000019
RSVCTCB  EQU   04                  TCB ADDRESS                          73210019
RUCBADDR EQU   05                       CONTAINS THE UCB ADDRESS        73500019
RDCBADDR EQU   06                       DCB ADDRESS AS PASSED BY USER   74000019
RDEBADDR EQU   07                       DEB ADDRESS AS FOUND IN DCB     74500019
RDEBDCB@ EQU   08                       DCB ADDRESS AS FOUND IN DEB     75000019
RTCBDEB  EQU   09                  DEB ADDRESS                          75010019
RRETOREG EQU   10                       CONTAINS NSI ADDRESS            75500019
RBASEREG EQU   12                       SVC BASE REGISTER               76000019
RBRTOREG EQU   14                       EXIT ADDRESS.USER ENTRY POINT   76500019
RERORREG EQU   15                       CONTAINS EXIT CODE              77000019
*                                                                       77500019
*        WORKAREAS                                                      78000019
*                                                                       78500019
CODECHCK DC    F'32'                    MAXIMUM CODE VALUE CONSTANT     79000019
MAINTAIN DC    5CL10'MAINTENANC'        MAINTENANCE AREA                79500019
*                                                                       80000019
*        GENERAL EQUATES                                                80500019
*                                                                       81000019
ZERO     EQU   00                       A DISPLACEMENT VALUE            81500019
THREE    EQU   03                       SVC # VALUE                     82000019
DEBDEB   EQU   04                  NEXT DEB IN DEB CHAIN                82210019
TCBDEB   EQU   08                  DEB CHAIN ORIGIN IN TCB              82220019
SVCERROR EQU   04                       VALUE THAT DENOTES AN SVC ERROR 82500019
DEBEMUBT EQU   08                       DISP VALUE FOR 8 TH BYTE IN DEB 83000019
OPTNFEAT EQU   17                       DISP IN UCB OF OPT.FEAT. BYTE   83500019
DEVCLASS EQU   18                       DISP IN UCB OF DEV.CLASS  BYTE  84000019
DCBPOINT EQU   24                       DEB DISPLACEMENT(ADDR OF DCB)   84500019
UCBPOINT EQU   32                       UCB DISP VALUE                  85000019
DEBPOINT EQU   44                       DCB DISPLACEMENT(ADDR OF DEB)   85500019
XEMULON  EQU   X'10'                    DEB 8.3 ON MASK                 86000019
EMULON   EQU   X'04'                    DEB 8.5                         86500019
EMULBITS EQU   X'14'                    DEB 8.3,8.5 ON MASK             87000019
DEBDVMOD EQU   X'20'                    DEB DEBDVMOD FIELD DISPLACEMENT 87500019
PAREVEN  EQU   X'28'                    EVEN PARITY MASK                88000019
PARODD   EQU   X'38'                    ODD PATITY MASK                 88500019
LOWDEN   EQU   X'3F'                    200 BPI MASK BITS               89000019
MIDDEN   EQU   X'40'                    556 BPI MASK BITS               89500019
SEVTRACK EQU   X'80'                    7 TRACK MASK BIT                90000019
TAPE     EQU   X'80'                    2400 TAPE MASK                  90500019
HIGHDEN  EQU   X'80'                    800 BPI MASK BITS               91000019
PAROFF   EQU   X'C7'                    PARITY OFF MASK                 91500019
XEMULOFF EQU   X'EF'                    DEB 8.3 OFF MASK                92000019
EMULOFF  EQU   X'FB'                    DEB 8.5 OFF MASK                92500019
         END                                                            93000019
