IGC00089 START                                                          00600019
*********************************************************************** 01200019
*                                                                       01800019
*         TITLE:    IGC0008I (EMULATOR SERVICE SVC ROUTINE)             02400019
*                                                                       03000019
*        STATUS:    CHANGE LEVEL = 00 (RELEASE 19)                      03600019
*                                                                       04200019
*         ENTRY:    SVC 89, OR USE -EMSRV- MACRO                        04800019
*                                                                       05400019
*      FUNCTION:    SVC 89 WILL VARIOUSLY:                              06000019
*                        ENTER EMULATION MODE                           07200019
*                        LEAVE EMULATION MODE                           07800019
*                                                                       08400019
*         INPUT:    REG 1 IS THE PARAMETER REGISTER, IT CONTAINS A      09000019
*                   POINTER TO A ONE-WORD PARAMETER LIST (P-LIST).      09600019
*                   THE HI-ORDER BYTE OF THE P-LIST IS A CODED BYTE     10200019
*                   THAT INDICATES WHICH PROCESSING FUNCTIONS ARE       10800019
*                   TO TAKE PLACE (SEE OPERATION BELOW).                11400019
*                                                                       13200019
*     OPERATION:    SVC 89 SEQUENTIALLY CHECKS EACH BIT IN THE CODED    13800019
*                   HI-ORDER BYTE OF THE PARAMETER LIST AND PROCESSES   14400019
*                   EACH OPERATION AS INDICATED:                        15000019
*                   BIT       OPERATION                                 15600019
*                     C0      ENTER EMULATION MODE                      16800019
*                     A0      LEAVE EMULATION MODE                      17400019
*                                                                       18000019
*                   EMULATION MODE IS ENTERED, OR LEFT, BY:             18600019
*                   1)   REFERENCING THE MACHINE STATUS BLOCK (MSB) AND 19200019
*                        MOVING BYTES 0-4 OF THE RESIDENT MAINTENANCE   19800019
*                        CONTROL WORD (MCW) INTO BYTES 0-4 OF THE       20400019
*                        EMULATOR MCW (LOCATED AT HEX-20 IN THE MSB)    21000019
*                   2)   PUT HEX-9FF000 INTO BYTES 5-7 OF THE           21600019
*                        EMULATOR MCW FIELD                             22200019
*                   3)   FOR ENTERING EMULATION MODE, BIT 20.3 IN THE   22800019
*                        TCB IS TURNED -ON-(=1) TO IDENTIFY THE PROBLEM 23400019
*                        PROGRAM AS AN EMULATOR                         24000019
*                        FOR LEAVING EMULATION MODE, BIT 20.3 IN THE    24600019
*                        TCB IS TURNED -OFF-(=0)                        25200019
*                   4)   ISSUE THE DIAGNOSE INSTRUCTION (83) WITH AN    25800019
*                        IMMEDIATE FIELD OF -O2- TO ENTER EMULATION     26400019
*                        MODE, OR WITH -OO- TO LEAVE EMULATION MODE     27000019
*                                                                       27600019
*        OUTPUT:    A RETURN CODE IS PUT INTO REGISTER 15               28200019
*                   CODE      INDICATION                                28800019
*                     0       SVC EXECUTED SUCCESSFULLY                 29400019
*                     4       SVC DID NOT EXECUTE (NOT A MODEL 85)      30000019
*                                                                       30600019
* EXTERNAL RTNS:    NONE                                                31200019
*                                                                       31800019
* EXITS(NORMAL):    RETURN CODE OF -0- IN REG 15, RETURN VIA REG 14     32400019
*                                                                       33000019
*  EXITS(ERROR):    RETURN CODE OF -4- IN REG 15, RETURN VIA REG 14     33600019
*                                                                       34200019
* TABLES/      :    THE TCB (BIT 20.3) AND THE MSB (MACHINE STATUS      34800019
*    WORK AREAS     BLOCK) ARE REFERENCED                               35400019
*                                                                       36000019
*    ATTRIBUTES:    TYPE 3 SVC (TRANSIENT, <1024 BYTES), RE-ENTRANT,    36600019
*                   AND DISABLED EXCEPT FOR MACHINE CHECKS              37200019
*                                                                       37800019
*         NOTES:    TCB BIT 20.3 (HI-ORDER BYTE IN TESTRAN FIELD) IS    38400019
*                   USED TO IDENTIFY A PROBLEM PROGRAM AS AN EMULATOR.  39000019
*                   IF BIT IS -ON-(=1), THE PROGRAM IS AN EMULATOR      39600019
*                                                                       40200019
*********************************************************************** 40800019
  SPACE 2                                                               41400019
IGC00089 CSECT                                                          42000019
         TITLE 'IGC0008I ENTER/LEAVE EMULATOR MODE  MODEL 85'           42010019
  SPACE                                                                 42600019
***   QUANTITY OR VALUE EQUATES    ****                                 43200019
         SPACE 1                                                        43800019
Q0       EQU   0              VALUE OF 0                                44400019
Q2       EQU   2              VALUE OF 2                                44410019
Q3       EQU   3              VALUE OF 3                                45000019
Q4       EQU   4              VALUE OF 4                                45600019
Q5       EQU   5              VALUE OF 5                                46200019
Q7       EQU   7                                                        46800019
Q8       EQU   8                                                        47400019
Q10      EQU   10                                                       48000019
Q16      EQU   16                                                       48600019
Q28      EQU   28                                                       49200019
  SPACE 2                                                               49800019
***   REGISTER EQUATES             ****                                 50400019
         SPACE 1                                                        51000019
R0SAVE   EQU   0                                                        51600019
R1PARM   EQU   1              PARAMETER REG 1                           52200019
M85CHK   EQU   2              VERIFICATION OF MODEL TYPE                52210019
CVTREG   EQU   3              ADDRESS OF CVT SUPPLIED                   52220019
R4TCB    EQU   4              TCB REG 4                                 52800019
RMSB     EQU   6              MACHINE STATUS BLOCK REG                  53400019
R7       EQU   7              WORK REG 7                                54000019
RBASE    EQU   12             BASE REG                                  54600019
RETREG   EQU   14             RETURN REGISTER                           54610019
RCODE    EQU   15             CODE REG                                  55200019
  SPACE 2                                                               55800019
***   MASK EQUATES                 ****                                 56400019
         SPACE 1                                                        57000019
MSKENT   EQU   X'40'          TEST MASK FOR ENTER.EMUL.MODE OPERATION   58200019
MSKLV    EQU   X'20'          TEST MASK FOR LEAVE.EMUL.MODE OPERATION   58800019
EMBITON  EQU   X'10'          MASK TO SET EMUL.TCB.BIT -ON-             59400019
EMBITOFF EQU   X'EF'          MASK TO SET EMUL.TCB.BIT -OFF-            60000019
  SPACE 2                                                               60600019
***   FIELD DISPLACEMENT EQUATES    ****                                61200019
         SPACE 1                                                        61800019
CVTPTR   EQU   16                  PTR TO CVT                           62400019
CVTRMS   EQU   224                 PTR TO MSB IN CVT                    63000019
EMMCW    EQU   56                  EMULATOR MCW FIELD DISPL IN MSB      63600019
TCBTRN   EQU   20             TESTRAN FIELD DISPL IN TCB                66000019
         EJECT                                                          66010019
  SPACE 2                                                               66600019
         BALR  RBASE,0                  ESTAB                           67200019
         USING *,RBASE                  ADDR                            67800019
  SPACE                                                                 68400019
         LA    RCODE,Q4                 SET CODE FOR -ERROR-            68410019
         L     RMSB,CVTRMS(CVTREG)   FETCH POINTER TO MSB               69600019
         LR    M85CHK,CVTREG       REPLICATE REGISTER CONTENTS          69610019
         A     M85CHK,NEGA6        DECREMENT TO MODEL FIELD BELOW CVT   69620019
         LA    M85CHK,Q0(M85CHK) CLEAR HIGH ORDER BYTE                  69630019
         CLC   M85ID(Q2),Q0(M85CHK)   Q.IS IT MODEL 85 VIA NIP          69640019
         BNE   OUT                 NO,DO NOT PROCESS SVC CALL           69660019
NOERR    LA    RCODE,Q0            SET CODE FOR - NO ERROR -            79200019
  SPACE                                                                 79800019
TSTENT   TM    Q0(R1PARM),MSKENT        TST-EMUL MODE TO BE ENTERED     80400019
         BNO   TSTLV                    NO, GO TEST LV                  81000019
ENT      MVC   EMMCW(Q5,RMSB),Q0(RMSB)  YES,XFER MCW FOR EMUL           81600019
         MVC   EMMCW+Q5(Q3,RMSB),EMMASK SET EM.MCW CSAR AND COUNT FIELD 82200019
** ISSUE DIAGNOSE INSTR (83) TO ENTER.EMULATOR.MODE (I-FIELD = 02)      83400019
** WITH A POINTER TO THE EMULATOR MAINTENANCE.CONTROL.WORD (MCW)        84000019
** IN RECOVERY MANAGEMENT SERVICES' (RMS) MACHINE.STATUS.BLOCK(MSB)     84600019
         DC    X'8302'                  ISSUE DIAGNOSE INSTR            85200019
         DC    S(EMMCW(RMSB))           TO ENTER EMUL.MODE              85800019
         OI    TCBTRN(R4TCB),EMBITON    TURN ON EMUL.TCB.BIT            85810019
  SPACE                                                                 86400019
TSTLV    TM    Q0(R1PARM),MSKLV         TST-EMUL MODE TO BE LEFT        87000019
         BNO   OUT                      NO, EXIT NOW                    87600019
LV       MVC   EMMCW(Q5,RMSB),Q0(RMSB)  YES, XFER MCW FOR EMUL          88200019
         MVC   EMMCW+Q5(Q3,RMSB),EMMASK SET EM.MCW CSAR AND COUNT FIELD 88800019
         NI    TCBTRN(R4TCB),EMBITOFF   TURN OFF EMUL.TCB.BIT           89400019
** ISSUE DIAGNOSE INSTR (83) TO LEAVE.EMULATOR.MODE (I-FIELD = 00)      90000019
** WITH A POINTER TO THE EMULATOR MAINTENANCE.CONTROL.WORD (MCW)        90600019
** IN RECOVERY MANAGEMENT SERVICES' (RMS) MACHINE.STATUS.BLOCK(MSB)     91200019
         DC    X'8300'                  ISSUE DIAGNOSE INSTR            91800019
         DC    S(EMMCW(RMSB))           TO LEAVE EMUL.MODE              92400019
  SPACE                                                                 93000019
OUT      BR    RETREG                       EXIT SVC                    93600019
  SPACE 2                                                               94200019
***   STORAGE DEFINITIONS          ****                                 94800019
NEGA6    DC     F'-6'                   MINUS SIX DISPLACEMENT IN CVT   94810019
M85ID    DC     X'0085'                 MODEL 85 ID SET BY NIP IN CVT-6 94820019
EMMASK   DC    X'9FF000'           EMUL CSAR AND COUNT FIELDS FOR MCW   95400019
         SPACE 1                                                        96000019
 END                                                                    96600019
