IEC1052A START X'00'                                                    00020000
*C0611601                                                      @SA69208 00020121
*A056684-056688                                                  A63659 00020421
*C048930,049100                                                  A61178 00022021
*2724035000-035400                                               A41637 00025021
*082035000,35200,59000,59200,59400                                 7884 00030017
*2309029000                                                      M0466  00035020
*2724032620-032650,048920,056650,061140,061405                   S21002 00037021
         SPACE 2                                                        00040000
*                   1052/2150 ERROR RECOVERY PROCEDURE                  00060000
         SPACE 2                                                        00080000
*      FUNCTION     ANALYSE STATUS AND SENSE DATA AND ATTEMPT ERROR     00100000
*                   RECOVERY. IF THE ERROR IS CORRECTED,PROCEED IN A    00120000
*                   NORMAL MANNER. IF A PERMANENT ERROR IS DETECTED     00140000
*                   INDICATE IT TO THE USER BY A COMPLETION CODE IN THE 00160000
*                   ECB AND A MESSAGE ON THE SYSTEM CONSOLE.            00180000
*                                                                  MCS  00181018
*                   MULTI-CONSOLE SUPPORT                          MCS  00182018
*                                                                  MCS  00183018
*                   IF MULTI-CONSOLE SUPPORT IS IN SYSTEM.THE      MCS  00184018
*                   ERROR RECOVERY PROCEDURE SETS UP FOR A         MCS  00185018
*                   BROADCAST WTO, WHICH WILL OUTPUT'INTERVENTION  MCS  00186018
*                   REQUIRED'TO ALL DEVICES THATH MAKE  A  MESSAGE MCS  00187018
*                   AVAILABLE TO THE SYSTEM OPERATOR. ALL OTHER    MCS  00188018
*                   ERRORS WILL BE RETRIED FIVE TIMES.IF RECOVERY, MCS  00189018
*                   THE SYSTEM WIL CONTINUE-IF NO RECOVERY,ENSUES  MCS  00190018
*                   PERMANENT ERROR WILL BE INDICATED.             MCS  00191018
*         ENTRY:    ER1052    FROM INTERRUPT SUPERVISOR                 00200000
*         INPUT     REQUEST ELEMENT POINTER IN REGISTER 1               00220000
*        OUTPUT     NONE                                                00240000
*       EXT REF     NONE                                                00260000
*         EXITS     1. ERRECXP EXIT TO I/O SUPERVISOR TO RE-EXECUTE     00280000
*                      THE CHANNEL PROGRAM IN ERROR.                    00300000
*                   2. SVC 3 EXIT TO RETURN CONTROL TO THE SUPERVISOR   00320000
*                      AND RELINQUISH CONTROL OVER THE TRANSIENT AREA   00340000
*                   3. XCTL EXIT TO OUTBOARD RECORDING, STATISTICS UP-  00360000
*                      DATE OR WRITE TO OPERATOR. RETURN WILL BE MADE   00380000
*                      FROM THESE ROUTINES TO THE SUPERVISOR VIA SVC 3. 00400000
*       ERR MSGS    CONSOLE MESSAGES TO INDICATE ERROR CONDITIONS ARE   00420000
*                        1. I/O ERR                                     00440000
*                        2. INT REQ                                     00460000
*         NOTES     IOB EXCEPTION AND IOB ERROR FLAGS ARE INTERPRETED   00480000
*                   AS FOLLOWS                                          00500000
*                        IOBEX ON AND IOBERR ON, ERR RTNE IN CONTROL.   00520000
*                        IOBEX ON AND IOBERR OFF, PERMANENT ERROR.      00540000
*                        IOBEX OFF AND IOBERR OFF, NO ERR OR CORRECTED  00560000
*        TABLES     STATISTICS TABLE AND IOB                            00580000
*     OPERATION     THIS ROUTINE CHECKS THE STATUS AND SENSE BYTES      00600000
*                   STORED IN THE UCB AND IOB AND TAKES ACTION AS       00620000
*                   SPECIFIED IN THE DEVICE STANDARDS. STATISTICS ARE   00640000
*                   KEPT AS TO THE KIND AND FREQUENCY OF ERRORS. THESE  00660000
*                   STATISTICS ARE USED BY THE CE TO ISOLATED AND       00680000
*                   RECOGNIZE ERRORS.                                   00700000
*                   A COMMON INTERPRETER ROUTINE IS USED TO CHECK BOTH  00720000
*                   STATUS AND SENSE. ON RETURN FROM THE INTERPRETER    00740000
*                   THE PROPER ACTION OF RETRY, RETURN OR WRITE A       00760000
*                   MESSAGE TO THE OPERATOR IS TAKEN.                   00780000
*                                                                       00781018
*                   MULTI-CONSOLE SUPPORT                          MCS  00782018
*                                                                  MCS  00783018
*                   UPON ENTERING THIS ERROR RECOVERY PROCEDURE    MCS  00784018
*                   INTERROGATION IS MADE FOR MULTI-CONSOLE IN     MCS  00785018
*                   SYSTEM. A FLAG (IOBMCS) IN THE IOB IS SET.     MCS  00786018
*                   ANALYSES OF THE ERROR IS CARRIED OUT AS        MCS  00787018
*                   DESCRIBED ABOVE. ALL ERRORS ARE RETRIED FIVE   MCS  00788018
*                   TIMES. EXCEPT: INTERVENTION REQUIRED           MCS  00789018
*                   WHICH CAUSES A BROADCAST WTO; UNIT EXCEPTION   MCS  00790018
*                   WHICH CAUSES THE CONSOLE BUFFER TO BE CLEARED  MCS  00791018
*                   AND RETRIED.                                   MCS  00792018
         SPACE 1                                                        00792818
*              THE ERPIB INTERROGATOR DETERMINES THE VALIDITY OF   CCHB 00793618
*              THE CAW,CSW,CHAN ADR, DEV ADR, BY INSPECTING THE    CCHB 00794418
*              ERPIB. IF ANY ARE INVALID AS INDICATED IN THE ERPIB CCHB 00795218
*              PERM ERROR WELL BE THE RESULT OF THE ERP. IF VALID  CCHB 00796018
*              AND A UNIT ERROR EXISTS CONTROL IS RETURNED TO THE  CCHB 00796818
*              NORMAL FLOW FOR UNIT ERRORS. 2F NO UNIT ERRORSARE   CCHB 00797618
*              PRESENT WITH THE CHANNEL ERRORS ERROR RECOVERY IS   CCHB 00798418
*              RETRIED FIVE TIMES FOR ALL CHANNEL ERRORS.          CCHB 00799218
         EJECT                                                          00800000
*              IOB DEFINITION                                           00820000
IOBFL1   EQU   0                        FLAGS 1                         00840000
IOBSNS   EQU   2                        SENSE DATA                      00880000
IOBCOD   EQU   4                        ECB CODE                        00900000
IOBCSW   EQU   8                        CSW STORAGE                     00940000
IOBFL3   EQU   8                        FLAGS 3                         00960000
IOBST    EQU   17                       START ADDRESS                   01000000
IOBDCB   EQU   21                       DCB POINTER                     01040000
IOBMDB   EQU   24                       MODIFIER BYTE                   01060000
IOBECT   EQU   30                       ERROR COUNTS                    01140000
         SPACE 1                                                        01200000
*   THESE FLAGS ARE IN IOB-FLAG 1                                       01220000
IOBCP2   EQU   X'40'                    TYPE OF CHANNEL PROGRAM         01240000
IOBERR   EQU   X'20'                    IOB ERROR FLAG                  01260000
IOBMD1   EQU   X'10'                    MODE 1 FLAG                     01280000
IOBEX    EQU   X'04'                    EXCEPT FLAG                     01300000
IOBSRS   EQU   X'01'                    START/RESTART FLAG              01320000
IOBEXE   EQU   IOBEX+IOBERR             EX + ERR FLAGS                  01340000
IOBCXE   EQU   X'FF'-IOBEXE             CLEAR EX + ERR FLAGS            01360000
         SPACE 1                                                        01380000
*   THESE FLAGS ARE IN IOB-FLAG 3                                       01400000
ERWTCT   EQU   X'20'                    WRITE COUNT                     01420000
IOBBOE   EQU   X'10'                    BUS OUT ERROR CNT               01440000
IOCBM1   EQU   X'08'                    CONTROL BIT M 1                 01460000
IOBMSG   EQU   X'04'                    MESSAGE TYPE                    01480000
IOBMCS   EQU   X'80'                    MCS OFFSET IN IOB          MCS  01490018
IOCBM0   EQU   X'02'                    CONTROL BIT M 0                 01500000
IOBLOG   EQU   X'01'                    LOGOUT FLAG                     01520000
         SPACE 2                                                        01540000
*              REGISTER DEFINITION                                      01560000
TSTREG   EQU   1                        TWELVE STAR REG                 01600000
ERREG2   EQU   2                        WORK REG                        01620000
UCBWKREG EQU   3                        REGISTER FOR WORK AREA   A41637 01630021
*                                       A4163                    A41637 01640021
CCWREG   EQU   4                        CCW ADDRESS REG                 01660000
UCMREG   EQU   5                        UNIT CONTROL REG           MCS  01665018
ERPIBRG  EQU   6                        ERPIB PTR REG              CCHA 01670016
UCBREG   EQU   7                        UCB ADDRESS REG                 01680000
COMREG   EQU   8                        COMMUNICATION TABLE REG         01700000
SAVREG   EQU   9                        SAVE REG.                       01720000
IOBRG    EQU   10                       IOB ADDRESS REG                 01740000
ERREG4   EQU   11                       WORK REG                        01760000
ERRLNK   EQU   12                       LINK REG                        01780000
ERREG1   EQU   13                       WORK REG                        01800000
ERRETR   EQU   14                       RETURN REG                      01820000
BASREG   EQU   15                       BASE REGISTER                   01840000
         SPACE 2                                                        01860000
*              TWELVE STAR DEFINITION                                   01880000
TSTUCB   EQU   2                        UCB POINTER                     01920000
TSTIOB   EQU   5                        IOB POINTER                     01940000
         SPACE 2                                                        02000000
         SPACE 2                                                        02240000
*              UCB DEFINITION                                           02260000
UCBFL1   EQU   6                        UCB FLAGS                       02280000
UCBSTI   EQU   9                        STATISTICS POINTER              02300000
UCBEXTAD EQU   24                       UCB WORK AREA PTR        A41637 02306021
*                                       A4163                    A41637 02312021
UCBNRY   EQU   X'40'                    UCB NOT READY                   02320000
         SPACE 2                                                        02340000
*              STATUS INDICATORS                                        02360000
CSWCHE   EQU   X'08'                    CHANNEL END                     02420000
CSWUCK   EQU   X'02'                    UNIT CHECK                      02440000
CSWCCK   EQU   X'01'                    CHAINING CHECK                  02460000
CSWCCCK  EQU   X'04'                    CHANNEL CNTRL CHECK        CCHA 02490016
CSWICCK  EQU   X'02'                    INTRFCE CNTRL CHECK      CCHA   02495016
        EJECT                                                           02500000
*              MISC. DEFINITIONS                                        02520000
CNTLAL   EQU   X'0B'                    CONTROL ALARM                   02620000
EWRTCM   EQU   X'01'                                                    02640000
IOCLBT   EQU   X'00'                    CLEAR BYTE                      02660000
NORCOD   EQU   X'7F'                    IOB NORMAL                      02680000
         SPACE 1                                                        02700000
EXCPER   EQU   15                       EXCP ERROR ROUTINE              02720000
LOC016   EQU   16                       COMMUNICATION TABLE             02740000
VECTXL   EQU   44                       VECTOR TO XCTL RNT.             02760000
VECT68   EQU   68                       INDEX TO INTERPRETER ROUTINE    02780000
STATAB   EQU   112                      INDEX TO STATISTICS TABLE       02820000
WTORTN   EQU   253                      LOAD NAME TO WTO RTN.           02840000
STATUP   EQU   254                      LOAD NAME TO STAT. UPDATE RNT.  02860000
IBPTR    EQU   116                      PTR TO PTR TO PTR TO ERPIB CCHA 02866016
ENDTBL   EQU   X'FF'                    END OF ERPIB TABLE         CCHA 02872016
NXT      EQU   2                        NEXT CONTROL ENTRY         256D 02881018
TFTYSX   EQU   256                      INCREMENT STAT INDEX       256D 02882018
BRDCST   EQU   X'FF'                    BROADCAST INDICATOR        MCS  02883018
BUFBGN   EQU   0                        BEGINNING OF BUFFER        MCS  02884018
CCWBC    EQU   6                        BYTE COUNT IN CCW          MCS  02885018
CCWCC    EQU   0                        SECOND WORD OF CCW         MCS  02887018
CVTDCB   EQU   X'74'                    CVT OFFSET IN DCB          MCS  02888018
FVRTRY   EQU   5                        CONSTANT OF FIVE           MCS  02889018
INCR     EQU   1                        CONSTANT OF ONE            MCS  02890018
MCSID    EQU   X'02'                    MCS ID MASK                MCS  02891018
SRTSTAT  EQU   3                                                   MCS  02892018
PRMALT   EQU   X'03'                    PRIMARY ALTERNATE MASK     MCS  02893018
SYSPCP   EQU   X'40'                    PCP SYSTEM MASK            MCS  02894018
UCMADR   EQU   100                      UCM OFFSET IN CVT          MCS  02895018
UCMMCS   EQU   68                                                M04666 02898020
*                                        M046                    M0466  02901020
VALIDIND EQU   X'06'                    VALID INDIC IN ERPIB       CCHB 02905018
CCWADROK EQU   X'04'                    VALID CCW ADDRESS BIT      CCHB 02915018
INTRCPT  EQU   X'7E'                    IOB INTERCEPT CODE              02916018
UNCNORTY EQU   X'01'                    UNCONDITIONAL NO RETRY FLAGCCHB 02917018
PROGFLGS EQU   4                        PROG FLAGS BYTE IN ERPIB   CCHB 02918018
CSWSSIO  EQU   X'80'                    CSW STORED ON SIO INDICATIOCCHB 02919018
NOP      EQU   X'03'                    RETRY CODE OF THREE        CCHB 02920018
ONE      EQU   X'01'                    ERROR COUNT OF ONE         CCHB 02921018
RETRCD   EQU   7                        RETRY CODE IN ERPIB        CCHB 02922018
FOUR     EQU   X'04'                    RETRY CODE OF FOUR         CCHB 02923018
THREE    EQU   X'03'                    RETRY CODE OF THREE        CCHB 02924018
UCBLTS   EQU   20                       UCB LAST RQE FIELD         CCHB 02925018
LTSZER   EQU   X'00'                    COMPARE FIELD-RQE FIELD ZERCCHB 02926018
UCBBSY   EQU   X'80'                    DEVICE BUSY FLAG           CCHB 02927018
         EJECT                                                          02930018
*********************************************************************** 02935018
*    THIS IS THE - 1 0 5 2 - ERROR ROUTINE                           *  02940000
**********************************************************************  02960000
*        WHEN ENTERED, THE IOBEX BIT IN FLAG 1 IS SET TO 1           *  02980000
*        THE ERROR ROUTINE WILL SET THE IOB ERROR FLAG INDICATING    *  03000000
*        THAT THIS IOB IS IN ERROR.                                  *  03020000
*                                                                    *  03040000
*        INTERPRETATION OF THESE TWO BITS IS AS FOLLOWS.             *  03060000
*        IOBEX ON   IOBERR ON    ERROR ROUTINE HAS CONTROL           *  03080000
*        IOBEX ON   IOBERR OFF   PERMANENT ERROR                     *  03100000
*        IOBEX OFF  IOBERR OFF   ERROR CORRECTED                     *  03120000
         SPACE 1                                                        03140000
         USING *,15                                                     03160000
ER1052   L     IOBRG,TSTIOB-1(TSTREG)   GET ADDRESS OF IOB              03180000
         LH    UCBREG,TSTUCB(TSTREG)    GET UCB ADDRESS                 03200000
         L     COMREG,LOC016            ADDRESS OF COMMUNICATION TABLE  03220000
         L     UCBWKREG,UCBEXTAD(UCBREG) GET WORK AREA ADDRESS   A41637 03221021
*                                       A4163                    A41637 03222021
         LA    ERRLNK,ERR499            MCS TEST RETURN ADDRESS    MCS  03223018
         SPACE 1                                                        03226018
***            MULTIPLE CONSOLE SUPPORT INTERROGATOR                    03229018
*** SET IOB MCS FLAG ON IF THE DEVICE IS A PRIMARY OR ALTERNATE CONSOLE 03232018
*** RUNNING IN A NON-PCP ENVIRONMENT WHICH CONTAINS UCM AND             03235018
*** MULTI CONSOLE SUPPORT                                               03238018
         TM    SRTSTAT(UCBREG),PRMALT   PRIM OR ALTERNATE CONSOLE  MCS  03241018
         BCR   8,ERRLNK                 NO RETURN TO NORMAL FLOW   MCS  03244018
         TM    CVTDCB(COMREG),SYSPCP    PCP SYSTEM                 MCS  03247018
         BCR   1,ERRLNK                 YES TO NORMAL FLOW         MCS  03250018
         L     UCMREG,UCMADR(0,COMREG)  LOAD ADDR OF UNIT CONT MOD MCS  03253018
         LTR   UCMREG,UCMREG            UCM IN SYSTEM              MCS  03256018
         BCR   8,ERRLNK                 TO NORMAL FLOW             MCS  03259018
         TM    UCMMCS(UCMREG),MCSID     MCS IN SYSTEM            X01458 03263021
         BCR   8,ERRLNK                 TO NORMAL FLOW           X01458 03265021
         OI    IOBFL3(IOBRG),IOBMCS     SET IOBMCS FLAG            MCS  03268018
         SPACE 1                                                        03271018
ERR499   NI    IOBFL1(IOBRG),X'FF'-IOBMD1 CLEAR MODE 1 FLAG             03274018
         OI    IOBFL1(IOBRG),IOBEXE     SET IOB EX + ERR FLAGS          03280000
         TM    IOBFL3(IOBRG),IOCBM1     TEST CONTROL BIT M1             03300000
         BC    8,ERR500                 NO, TEST M0 BIT                 03320000
         NI    IOBFL3(IOBRG),X'FF'-IOCBM1 RESET CONTROL BIT M1          03340000
         NI    IOBFL1(IOBRG),X'FF'-IOBSRS RESET RESTART FLAG            03360000
         OI    UCBFL1(UCBREG),UCBNRY    SET UCB NOT READY FLAG          03380000
         SVC   EXCPER                   ERROR EXCP                      03400000
         SVC   3                        RETURN                          03420000
         SPACE 1                                                        03440000
ERR500   TM    IOBFL3(IOBRG),IOCBM0     TEST CONTROL BIT M0             03460000
         BC    8,ERR500B                NO, CONTINUE             A41637 03470021
*                                       A4163                    A41637 03480021
         MVC   IOBCSW+1(7,IOBRG),1(UCBWKREG) RESTORE ORIG. CSW   A41637 03490021
*                                       A4163                    A41637 03500021
         BC    15,ERR505                PERM ERROR EXIT          A41637 03510021
*                                       A4163                    A41637 03520021
ERR500B  L     CCWREG,IOBCSW(IOBRG)     GET CCW ADDRESS          A41637 03530021
         LA    CCWREG,0(CCWREG)         ZERO HIGH BYTE                  03560000
         SH    CCWREG,ERRCN1            BACK UP ONE CCW                 03580000
         BC    12,ERR500A               BR IF RESULT 0 OR LESS   A61533 03590021
         SPACE 1                                                        03600000
         TM    IOBFL1(IOBRG),IOBCP2     TEST IF COMMAND CHAINED    CCHB 03602018
         BC    8,ERR500A                NO-TEST CH/INTF CNTL CK    CCHB 03604018
         ST    CCWREG,IOBMDB(IOBRG)     PUT CCW ADDRESS IN RESTART CCHB 03606018
         OI    IOBFL1(IOBRG),IOBSRS     SET RESTART FLAG           CCHB 03608018
ERR500A  TM    IOBCSW+5(IOBRG),CSWCCCK+CSWICCK CH/INFCE CNTL CK    CCHB 03610018
         BC    4+1,ERR530               YES-FIND ERPIB             CCHS 03616018
         SPACE 1                                                        03624016
ERR501   TM    IOBCSW+5(IOBRG),CSWCCK   TEST FOR CHAIN CK          CCHB 03633018
         BC    1,ERR524A                TEST FOR MCS               MCS  03642018
         TM    IOBCSW+4(IOBRG),CSWUCK   TEST FOR UNIT CHECK             03660000
         BC    8,ERR516                 NO, CHECK STATUS                03680000
         SPACE 1                                                        03700000
*        INFORMATION FOR STATISTICS IS OBTAINED FROM SENSE BYTE 0       03720000
*        AND IS STORED IN THE WORK AREA OF THE STATISTIC TABLE          03740000
         SPACE 1                                                        03760000
         LA    ERRLNK,ERR501A           GET EXIT ADDR FOR STAT RTN CCHS 03769018
ERRSTAT  L     ERREG2,STATAB(COMREG)    GET STAT TAB ADDR          CCHB 03778018
         SR    ERREG4,ERREG4                                            03788018
         IC    ERREG4,UCBSTI(UCBREG)    GET STAT. TAB INDEX        256D 03796018
         LR    ERREG1,ERREG2            GET STAT. TAB START ADR    256D 03804018
ERRLOOP1 CH    UCBREG,0(0,ERREG1)       DEV SUPPORTED BY THIS SECT 256D 03812018
         BC    4,ERRLOOP2           YES,INCR ADJUSTED CORRECTLY    256D 03820018
         LA    ERREG1,NXT(0,ERREG1)     INCR TO NXT CTL SECTION    256D 03828018
         LA    ERREG4,TFTYSX(0,ERREG4)  INCR STAT INDEX TO NXT SECT256D 03836018
         BC    15,ERRLOOP1              LOOP TO CHECK THIS SECT    256D 03844018
         SPACE 1                                                        03852018
ERRLOOP2 MH    ERREG4,ERRCN2            MULTIPLY BY 10             256D 03860018
         AR    ERREG2,ERREG4            ADD TO TABLE ADDRESS       256D 03868018
         BCR   15,ERRLNK                GO TO PROPER EXIT          CCHS 03874018
ERR501A  OC    8(1,ERREG2),IOBSNS(IOBRG) OR SENSE BYTE INTO TABLE       03884018
         NI    8(ERREG2),X'70'          MASK OUT UNWANTED BITS          03900000
         SPACE 1                                                        03920000
*        LINK TO THE INTERPRETER ROUTINE - THE BYTES FOLLOWING THE BALR 03940000
*        INDICATE IN WHAT ORDER THE BITS ARE TO BE TESTED (BIT 3 ON OF  03960000
*        THE CODE BYTE INDICATES STATUS) FOLLOWED BY AN INDEX VALUE THE 03980000
*        INTERPRETER USES TO RETURN TO THIS ROUTINE                     04000000
         SPACE 1                                                        04020000
ERRSTEXT LR    SAVREG,BASREG            SAVE BASE REG              CCHB 04040018
         L     BASREG,VECT68(COMREG)    GET INTERP. RTN. ADDRESS        04060000
ERR502   BALR  ERRLNK,BASREG            LINK TO INTERPRETER ROUTINE     04080000
         SPACE 1                                                        04100000
         DC    X'07'                    SHOULD NOT OCCUR                04120000
         DC    AL1(ERR504-ERR502-2)                                     04140000
         DC    X'06'                    SHOULD NOT OCCUR                04160000
         DC    AL1(ERR504-ERR502-4)                                     04180000
         DC    X'05'                    SHOULD NOT OCCUR                04200000
         DC    AL1(ERR504-ERR502-6)                                     04220000
         DC    X'04'                    SHOULD NOT OCCUR                04240000
         DC    AL1(ERR504-ERR502-8)                                     04260000
         DC    X'03'                    EQUIPMENT CHECK                 04280000
         DC    AL1(ERR506-ERR502-10)                                    04300000
         DC    X'01'                    INTERVENTION REQUIRED           04320000
         DC    AL1(ERR509-ERR502-12)                                    04340000
         DC    X'02'                    BUSOUT CHECK                    04360000
         DC    AL1(ERR510-ERR502-14)                                    04380000
         DC    X'00'                    COMMAND REJECT                  04400000
         DC    AL1(ERR518A-ERR502-16)                              MCS  04420018
         DC    X'2F'                    END OF TEST                     04440000
         DC    AL1(ERR504-ERR502-18)                                    04460000
         SPACE 1                                                        04480000
ERR504   BAL   ERRLNK,TESTMCS           TEST FOR MCS               MCS  04490018
ERR505   OI    IOBFL3(IOBRG),IOBLOG     SET LOGOUT FLAG           M0810 04500018
         NI    IOBFL1(IOBRG),X'FF'-IOBERR INDICATE PERM. ERROR          04520000
         BC    15,ERR522                BR- TO UPDATE STATISTICS        04540000
         SPACE 1                                                        04560000
         SPACE 1                                                        04574016
         SPACE 1                                                        04576016
*        EQUIPMENT CHECK                                                04580000
ERR506   BAL   ERRLNK,TESTMCS           TEST FOR MCS               MCS  04590018
ERR506A  LTR   CCWREG,CCWREG            CCW ADDRESS ZERO OR NEG    MCS  04600018
         BC    12,ERR518A               YES, PERM. ERROR                04620018
        TM    0(CCWREG),EWRTCM         IS THIS A WRITE COMMAND          04640000
         BC    8,ERR524                 NO, SEND MSG & LOGOUT           04660000
         TM    IOBFL3(IOBRG),ERWTCT     TEST WRITE COUNT EQUAL 1        04680000
         BC    1,ERR511                 YES, SET CNTL BIT M0            04700000
         OI    IOBFL3(IOBRG),ERWTCT     SET WRITE COUNT BIT             04720000
ERR508   SVC   EXCPER                   ERR EXCP                        04820000
         SVC   3                        RETURN                          04840000
         SPACE 1                                                        04860000
*     INTERVENTION REQUIRED                                             04880000
ERR509   TM    IOBFL3(IOBRG),IOBMCS     TEST FOR CONSOLE         A61178 04893021
         BC    1,ERRMCS                 YES-TO INT REQ FOR MCS     MCS  04900018
         OI    IOBFL3(IOBRG),IOCBM1     SET CONTROL BIT M1 TO 1  A61178 04910021
         BC    15,ERR512                BR- SET UP MODIFY BYTE          04920000
         SPACE 1                                                        04940000
*     BUS OUT CHECK                                                     04960000
ERR510   BAL   ERRLNK,TESTMCS           TEST FOR MCS               MCS  04970018
         TM    IOBFL3(IOBRG),IOBBOE     BUS OUT FLAG ON            MCS  04980018
         BC    8,ERR514                 NO, SET BUSOUT                  05000000
ERR511   OI    IOBFL3(IOBRG),IOCBM0     SET CNTL BIT M0                 05020000
         MVC   1(7,UCBWKREG),IOBCSW+1(IOBRG) SAVE CSW ACROSS CMD A41637 05026021
*                                       A4163                    A41637 05032021
ERR512   MVI   IOBMDB(IOBRG),CNTLAL     SET CNTL ALARM IN MODIFY BYTE   05040000
         OI    IOBFL1(IOBRG),IOBMD1     SET MODE 1 FLAG                 05060000
         SVC   EXCPER                   ERR EXCP                        05080000
         SVC   3                        RETURN                          05100000
         SPACE 1                                                        05120000
ERR514   OI    IOBFL3(IOBRG),IOBBOE     SET BUSOUT COUNT                05140000
         TM    IOBCSW+4(IOBRG),CSWCHE   TEST CHANNEL END                05160000
         BC    1,ERR515                 YES-RETRY                  CCHB 05170018
         NI    IOBFL1(IOBRG),X'FF'-IOBSRS RESTART AT TOP OF CP     CCHB 05180018
ERR515   SVC   EXCPER                   ERR EXCP                   CCHB 05190018
         SVC   3                        RETURN                          05220000
         SPACE 1                                                        05240000
*        LINK TO THE INTERPRETER ROUTINE - THE BYTES FOLLOWING THE BALR 05260000
*        INDICATE IN WHAT ORDER THE BITS ARE TO BE TESTED (BIT 3 ON OF  05280000
*        THE CODE BYTE INDICATES STATUS) FOLLOWED BY AN INDEX VALUE THE 05300000
*        INTERPRETER USES TO RETURN TO THIS ROUTINE                     05320000
         SPACE 1                                                        05340000
ERR516   LR    SAVREG,BASREG            SAVE BASE ADDRESS               05360000
         L     BASREG,VECT68(COMREG)    GET ADDRESS OF INTERP. RTN.     05380000
ERR517   BALR  ERRLNK,BASREG            LINK TO INTERPRETER ROUTINE     05400000
         SPACE 1                                                        05420000
         DC    X'1C'                    CHANNEL DATA CHECK         CCHA 05430016
         DC    AL1(ERR525-ERR517-2)                                CCHA 05440016
         DC    X'1A'                    PROGRAM CHECK              CCHA 05450016
         DC    AL1(ERR518A-ERR517-4)                               MCS  05460018
         DC    X'1B'                    PROTECTION CHECK           CCHA 05470016
         DC    AL1(ERR518A-ERR517-6)                               MCS  05480018
         DC    X'17'                    UNIT EXCEPTION             CCHA 05490016
         DC    AL1(ERR518B-ERR517-8)                                    05500018
         DC    X'19'                    INCORRECT LENGTH           CCHA 05510016
         DC    AL1(ERR518A-ERR517-10)                              MCS  05520018
         DC    X'2F'                    END OF TEST                CCHA 05530016
         DC    AL1(ERR520-ERR517-12)                               CCHA 05540016
         SPACE 1                                                        05640000
*        PERMANENT ERROR                                                05660000
ERR518C  XC    0(8,ERPIBRG),0(ERPIBRG)  ZERO ERPIB                 CCHB 05661018
         BC    15,ERR524                INDICATE PERM ERROR        CCHB 05662018
         SPACE 1                                                        05667018
ERR518B  L     SAVREG,IOBST-1(0,IOBRG)  START FIELD OF CHAN PROG   MCS  05668021
         CLI   0(SAVREG),X'0A'         READ INQUIRY CMD?         A63659 05668421
         BC    7,ERR508                NO, SKIP BLANKING BUFFER  A63659 05668821
         L     ERPIBRG,CCWCC(0,SAVREG)  LOAD ADDR OF DATA BUFFER   MCS  05669018
         LH    SAVREG,CCWBC(0,SAVREG)   LOAD BUFFER LENGTH         MCS  05670018
         MVI   BUFBGN(ERPIBRG),X'40'    INITIALIZE BLANK           MCS  05670418
         BCTR  SAVREG,0                 DECREMENT COUNT            MCS  05670818
         BCTR  SAVREG,0                 DECREMENT COUNT            MCS  05671218
         EX    SAVREG,BLNKBUF           BLANK INPUT                MCS  05671618
         BC    15,ERR508                ERROR EXCP INTERFACE       MCS  05672018
         SPACE 1                                                        05674018
BLNKBUF  MVC   BUFBGN+1(0,ERPIBRG),BUFBGN(ERPIBRG)   BLANK BUFFER  MCS  05676018
         SPACE 1                                                        05680018
ERR518   BAL   ERRLNK,TESTMCS           TEST FOR MCS               MCS  05685018
ERR518A  NI    IOBFL1(IOBRG),X'FF'-IOBERR INDICATE PERM ERROR      MCS  05690018
         SVC   EXCPER                   ERR EXCP                        05700000
         SVC   3                        RETURN                          05720000
         SPACE 1                                                        05740000
*        ERROR CORRECTED                                                05760000
ERR520   TM    IOBCOD(IOBRG),NORCOD     TEST FOR NORMAL CODE            05780000
         BC    1,ERR521                 YES, CLEAR EXCEPTION            05800000
         MVI   IOBCOD(IOBRG),NORCOD     SET CODE TO NORMAL              05820000
         TM    IOBECT(IOBRG),X'FF'      TEST FOR STAT UPDATE       MCS  05826018
         BC    7,ERR521                 YES-UPDATE STAT            MCS  05832018
         SVC   EXCPER                   ERR EXCP                        05840000
         SVC   3                        RETURN                          05860000
         SPACE 1                                                        05880000
ERR521   NI    IOBFL1(IOBRG),IOBCXE-IOBSRS RESET IOB EX,ERR,REST   7884 05920017
         MVI   IOBFL3(IOBRG),IOCLBT     CLEAR ERROR COUNTS              05960000
         NI    IOBCSW+4(IOBRG),X'FF'-CSWUCK RESET CSW UNIT CHECK        05980000
ERR522   LA    ERREG1,STATUP            GET STAT. UPDATE                05983018
         XC    IOBECT(2,IOBRG),IOBECT(IOBRG)   CLR ERR CNT         MCS  05986018
         L     ERRETR,VECTXL(COMREG)    GET XCTL ROUTINE                05989018
         BCR   15,ERRETR                XCTL TO STAT. UPDATE            05992018
         SPACE 1                                                        05995018
ERR524A  BAL   ERRLNK,TESTMCS           TEST FOR MCS               MCS  05998018
ERR524   OI    IOBFL3(IOBRG),IOBMSG+IOBLOG SET MSG & LOGOUT FLAGS       06001018
ERR524B  LA    ERREG1,WTORTN            GET WTO ROUTINE                 06004018
         L     ERRETR,VECTXL(COMREG)    GET XCTL ROUTINE                06007018
         BCR   15,ERRETR                XCTL TO WTO ROUTINE             06010018
         SPACE 1                                                        06010118
ERR525   LA    ERRLNK,ERR506A           SET LINK REG               CCHS 06010218
         SPACE 1                                                        06010418
         CLI   IOBECT(IOBRG),X'01'      CH DATA CK IN STAT TAB     CCHS 06010818
         BC    11,TESTMCS               YES-TEST IF MCS            CCHS 06011218
         BAL   ERRLNK,ERRSTAT           GET STAT TAB ADDR          CCHB 06011618
         OI    9(ERREG2),X'01'          CH DTA CK IN STAT TAB      CCHB 06012018
         OI    IOBECT(IOBRG),X'01'      SET ERR COUNT              CCHB 06012118
         LA    ERRLNK,ERR506A           SET LINK REG               CCHS 06012218
         BC    15,TESTMCS               TEST IF MCS                CCHS 06012318
         SPACE 1                                                        06012418
ERR530   L     ERPIBRG,IBPTR(COMREG)   PTR TO PTR TO PTR TO ERPIB  CCHS 06012518
         SPACE 1                                                        06013018
         SPACE 1                                                        06019018
         L     ERPIBRG,0(ERPIBRG)       PTR TO PTR TO ERPIB        CCHA 06025018
         SPACE 1                                                        06034018
         L     ERPIBRG,0(ERPIBRG)       PTR TO ERPIB               CCHA 06037018
ERCMPR   CH    UCBREG,2(ERPIBRG)        IS THIS ERPIB FOR 1052     CCHA 06040018
         BC    8,ERPIBINT               GOTO ERPIB INTERROGATOR    CCHB 06043018
         SPACE 1                                                        06046018
         LA    ERPIBRG,8(ERPIBRG)       ADDR OF NEXT ERPIB         CCHA 06049018
         TM    0(ERPIBRG),ENDTBL        END OF ERPIB TABLE              06052018
         BC    8+4,ERCMPR               NO-TEST NEXT ERBIB              06055018
         BC    1,ERR506                 YES-HANDLE LIKE EQUIP CHECKCCHA 06058018
         SPACE 1                                                        06106018
ERRMCS   MVI   IOBDCB-1(IOBRG),BRDCST   INDICATE BRDST TO WTO      MCS  06108018
         BC    15,ERR524B               TO WTO INTERFACE           MCS  06110018
         SPACE 1                                                        06112018
TESTMCS  TM    IOBFL3(IOBRG),IOBMCS     TEST FOR CONSOLE         S21002 06114021
         BCR   1,ERRLNK                 YES-TO NORMAL FLOW     @SA69208 06116021
CCHRETRY TM    IOBECT(IOBRG),FVRTRY     HAS ERR BEEN RETRIED 5     CCHB 06118018
         BC    1,ERR505                 YES,RETN FOR PERM ERR     M0810 06120018
         SR    ERREG4,ERREG4            ZERO IC REG                CCHS 06122018
         IC    ERREG4,IOBECT(IOBRG)     LOAD ERROR COUNT           MCS  06124018
         LA    ERREG4,INCR(ERREG4)      INCREMENT ERR CTR          MCS  06126018
         STC   ERREG4,IOBECT(IOBRG)     STORE NEW ERROR CNT        MCS  06128018
ERR538   LTR   CCWREG,CCWREG            CCWADDR ZERO OR NEG        CCHB 06130018
         BC    2,ERR539                 NO-RETRY                   CCHB 06132018
         NI    IOBFL1(IOBRG),X'FF'-IOBSRS INSURE RETR FROM TOP     MCS  06134018
ERR539   SVC   EXCPER                   ERR EXCP                   CCHB 06136018
         SVC   3                                                        06138018
         SPACE 1                                                        06140018
ERPIBINT TM    IOBFL3(IOBRG),IOBMCS     TEST FOR CONSOLE         S21002 06140521
         BC    8,ERR540                 NO-TEST FOR INTERCEPTED IOBCCHB 06141018
         XC    0(8,ERPIBRG),0(ERPIBRG)  ZERO ERPIB                 CCHB 06141518
         BC    15,CCHRETRY              BR TO RETRY                CCHB 06142018
         SPACE 1                                                        06142518
ERR540   CLI   IOBCOD(IOBRG),INTRCPT    IOB INTERCEPTED            CCHB 06143018
         BC    8,ERR518C                YES-PERM ERROR             CCHB 06143518
         TM    PROGFLGS(ERPIBRG),UNCNORTY NO RETRY FLAG SET        CCHB 06144018
         BC    1,ERR518C                YES-PERM ERROR                  06144518
         TM    PROGFLGS(ERPIBRG),CSWSSIO CSW STORED ON SIO         CCHB 06145018
         BC    1,ERR550                 YES-RETRY IF FIRST OCCUR   CCHB 06145518
         TM    VALIDIND(ERPIBRG),CCWADROK COMMAND ADDRESS VALID    CCHB 06146018
         BC    8,ERR518C                NO-PERM ERROR              CCHB 06146518
         CLI   0(CCWREG),NOP            NOP COMMAND                CCHB 06147018
         BC    8,ERR550                 YES-RETRY IF FIRST OCCUR   CCHB 06147518
         TM    RETRCD(ERPIBRG),FOUR     RETRY CODE OF FOUR         CCHB 06148018
         BC    8,ERR555                 NO-TEST RETRY CODE OF 3    CCHB 06148518
         TM    RETRCD(ERPIBRG),THREE    TEST RETRY CODE            CCHB 06149018
         BC    1,ERR545                 SEVEN-ISSUE INT REQ        CCHB 06149518
         BC    8,ERR550                 FOUR ALONE-RETRY           CCHB 06150018
         TM    RETRCD(ERPIBRG),ONE      RETRY CODE OF FIVE         CCHB 06150518
         BC    8,ERR518C                NO-SET PERM ERR            CCHB 06151018
ERR545   CLI   UCBLTS(UCBREG),LTSZER    FIRST BYTE OF UCBLTS ZERO  CCHB 06151218
         BC    8,ERR546                 YES-RESTORE UCBLTS         CCHB 06151418
         OI    UCBFL1(UCBREG),UCBBSY    SET BUSY FLAG IN UCB       CCHB 06151618
         BC    15,ERR547                ZERO THE ERPIB             CCHB 06151818
         SPACE 1                                                        06152018
ERR546   STH   TSTREG,UCBLTS(UCBREG)    RESTORE LAST RQE POINTER   CCHB 06152218
ERR547   XC    0(8,ERPIBRG),0(ERPIBRG)  ZERO THE ERPIB             CCHB 06152418
         TM    IOBECT+1(IOBRG),ONE      ERROR COUNT OF ONE         CCHB 06152618
         BC    1,ERR518C                YES-PERMANENT ERROR        CCHB 06152818
         OI    IOBECT+1(IOBRG),ONE      SET ERROR COUNT            CCHB 06153018
         BC    15,ERR524B               ISSUE INT REQ MESSAGE      CCHB 06153218
         SPACE 1                                                        06154018
ERR550   XC    0(8,ERPIBRG),0(ERPIBRG) ZERO ERPIB                  CCHB 06154518
         TM    IOBECT+1(IOBRG),ONE      ERR CNT OF ONE             CCHB 06155018
         BC    1,ERR518C                YES-PERM ERR               CCHB 06155518
         OI    IOBECT+1(IOBRG),ONE      SET ERR CNT                CCHB 06156018
         BC    15,ERR538                CHECK CCW ADDR             CCHB 06156518
         SPACE 1                                                        06157018
ERR555   TM    RETRCD(ERPIBRG),THREE    TEST RETRY CODE            CCHB 06157518
         BC    8,ERR518C                ZERO-SET PERM ERR          CCHB 06158018
         BC    1,ERR545                 THREE-SET INT REQ          CCHB 06158518
         BC    15,ERR550                ONE OR TWO RETRY           CCHB 06159018
         SPACE 1                                                        06159518
         SPACE 1                                                        06160000
ERRCN1   DC    AL2(8)                   DECIMAL 8                       06180000
ERRCN2   DC    AL2(10)                  MULTIPLIER CONSTANT             06200000
         DC    C'IGE0000D 218 5/8/74'   RELEASE ID             @SA69208 06210021
         DC    CL50'PATCH AREA'         MAINTENANCE AREA                06212021
         END                                                            06220000
