IEC1402A START X'00'                                                    00020000
*A061500                                                       @SA67574 00022800
*C061200,062200                                                @SA67574 00024800
*A060500-060560                                                @SA63702 00026400
*C050460-050484                                                @SA63702 00029200
*D058760-058780                                                @SA63702 00032000
*A062900,063700                                                 SA65501 00034800
*A050220-050360,050500-050520                                    A56356 00037600
*D051200-051400,053400-053600,052600                             A56356 00040400
*C051600,052400                                                  A56356 00043200
*A050304                                                         A63702 00046000
*D050400                                                         A63702 00048800
*084049600,49800                                                   7884 00051617
*0731056500                                                      A35195 00054421
         SPACE 2                                                        00057200
*                   2540 ERROR RECOVERY PROCEDURE                       00060000
         SPACE 2                                                        00080000
*      FUNCTION     ANALYSE STATUS AND SENSE DATA AND ATTEMPT ERROR     00100000
*                   RECOVERY. IF THE ERROR IS CORRECTED,PROCEED IN A    00120000
*                   NORMAL MANNER. IF A PERMANENT ERROR IS DETECTED     00140000
*                   INDICATE IT TO THE USER BY A COMPLETION CODE IN THE 00160000
*                   ECB AND A MESSAGE ON THE SYSTEM CONSOLE.            00180000
*         ENTRY:    ER2540    FROM INTERRUPT SUPERVISOR                 00200000
*         INPUT     REQUEST ELEMENT POINTER IN REGISTER 1               00220000
*        OUTPUT     NONE                                                00240000
*       EXT REF     NONE                                                00260000
*         EXITS     1. ERRECXP EXIT TO I/O SUPERVISOR TO RE-EXECUTE     00280000
*                      THE CHANNEL PROGRAM IN ERROR.                    00300000
*                   2. SVC 3 EXIT TO RETURN CONTROL TO THE SUPERVISOR   00320000
*                      AND RELINQUISH CONTROL OVER THE TRANSIENT AREA   00340000
*                   3. XCTL EXIT TO OUTBOARD RECORDING, STATISTICS UP-  00360000
*                      DATE OR WRITE TO OPERATOR. RETURN WILL BE MADE   00380000
*                      FROM THESE ROUTINES TO THE SUPERVISOR VIA SVC 3. 00400000
*       ERR MSGS    CONSOLE MESSAGES TO INDICATE ERROR CONDITIONS ARE   00420000
*                        1. I/O ERR                                     00440000
*                        2. INT REQ                                     00460000
*         NOTES     IOB EXCEPTION AND IOB ERROR FLAGS ARE INTERPRETED   00480000
*                   AS FOLLOWS                                          00500000
*                        IOBEX ON AND IOBERR ON, ERR RTNE IN CONTROL.   00520000
*                        IOBEX ON AND IOBERR OFF, PERMANENT ERROR.      00540000
*                        IOBEX OFF AND IOBERR OFF, NO ERR OR CORRECTED  00560000
*        TABLES     STATISTICS TABLE AND IOB                            00580000
*     OPERATION     THIS ROUTINE CHECKS THE STATUS AND SENSE BYTES      00600000
*                   STORED IN THE UCB AND IOB AND TAKES ACTION AS       00620000
*                   SPECIFIED IN THE DEVICE STANDARDS. STATISTICS ARE   00640000
*                   KEPT AS TO THE KIND AND FREQUENCY OF ERRORS. THESE  00660000
*                   STATISTICS ARE USED BY THE CE TO ISOLATED AND       00680000
*                   RECOGNIZE ERRORS.                                   00700000
*                   A COMMON INTERPRETER ROUTINE IS USED TO CHECK BOTH  00720000
*                   STATUS AND SENSE. ON RETURN FROM THE INTERPRETER    00740000
*                   THE PROPER ACTION OF RETRY, RETURN OR WRITE A       00760000
*                   MESSAGE TO THE OPERATOR IS TAKEN.                   00780000
         EJECT                                                          00800000
         SPACE 2                                                        00820000
         SPACE 1                                                        00840000
*              IOB DEFINITION                                           00860000
IOBFL1   EQU   0                        FLAGS 1                         00880000
IOBFL2   EQU   1                        FLAGS 2                         00900000
IOBSNS   EQU   2                        SENSE DATA                      00920000
IOBCOD   EQU   4                        ECB CODE                        00940000
IOBCSW   EQU   8                        CSW STORAGE                     00960000
IOBFL3   EQU   8                        FLAGS 3                         00980000
IOBCC    EQU   16                       CONDITION CODE                  01000000
IOBST    EQU   17                       START ADDRESS                   01020000
IOBDCB   EQU   21                       DCB POINTER                     01040000
IOBMDB   EQU   24                       MODIFIER BYTE                   01060000
IOBRST   EQU   25                       RESTART POINTER                 01080000
IOBBCI   EQU   28                       BLOCK COUNT INCR.               01100000
IOBTPM   EQU   29                       T.P. EXTENT (M) BYTE            01120000
IOBECT   EQU   30                       ERROR COUNTS                    01140000
IOBSK    EQU   33                       SEEK ADDRESS                    01160000
IOBDAM   EQU   32                       DIRECT ACCESS EXTENT (M) BYTE   01180000
         SPACE 2                                                        01200000
*   THESE FLAGS ARE IN IOB-FLAG 1                                       01220000
IOBCP1   EQU   X'80'                    TYPE OF CHANNEL PROGRAM         01240000
IOBCP2   EQU   X'40'                    TYPE OF CHANNEL PROGRAM         01260000
IOBERR   EQU   X'20'                    IOB ERROR FLAG                  01280000
IOBEX    EQU   X'04'                    EXCEPT FLAG                     01300000
IOBSRS   EQU   X'01'                    START/RESTART FLAG              01320000
IOBCEX   EQU   X'FF'-IOBEX              CLEAR IOB EXCEPTION             01340000
IOBEXE   EQU   IOBEX+IOBERR             EX + ERR FLAGS                  01360000
IOBCXE   EQU   X'FF'-IOBEXE             CLEAR EX + ERR FLAGS            01380000
*    FLAGS IN IOB FLG. 2                                                01400000
IOBQSM   EQU   X'01'                    Q-SAM ACCCES METHOD             01420000
         SPACE 2                                                        01440000
*   THESE FLAGS ARE IN IOB-FLAG 3                                       01460000
IOBIN1   EQU   X'80'                    INDICATOR  1                    01480000
IOBENT   EQU   X'40'                    IOB ENTRY BIT                   01500000
IOBRDE   EQU   X'20'                    READ ERROR CNT.                 01520000
IOBBOE   EQU   X'10'                    BUS OUT ERROR CNT               01540000
IOBPRT   EQU   X'08'                    PUNCH RETRY BIT                 01560000
IOBMSG   EQU   X'04'                    MESSAGE TYPE                    01580000
IOBPR2   EQU   X'02'                    QSAM ERR. CNT.                  01600000
IOBLOG   EQU   X'01'                    LOGOUT FLAG                     01620000
         SPACE 2                                                        01640000
*              UCB DEFINITION                                           01660000
UCBFL1   EQU   6                        UCB FLAGS                       01680000
UCBSTI   EQU   9                        STATISTICS POINTER              01700000
UCBNRY   EQU   X'40'                    UCB NOT READY                   01720000
         SPACE 2                                                        01740000
*              ECB DEFINITIONS                                          01760000
ECBFL    EQU   0                        FLAGS                           01780000
         SPACE 2                                                        01800000
*              DCB DEFINITION                                           01820000
DCBFL    EQU   44                       FLAGS                           01840000
DCBBUF   EQU   20                       PTR TO NUMBER OF BUFFERS        01860000
DCBORG   EQU   26                       DCBDSORG                        01880000
DCBMCF   EQU   42                       DCBMACRF                        01900000
DCBSPA   EQU   X'80'                    SPECIAL ACCESS                  01920000
DCBPER   EQU   X'C0'                    PERMANENT ERROR FLAGS           01940000
DCBEX    EQU   X'40'                    EXCEPTION CONDITION             01960000
DCBQSM   EQU   X'40'                    DCB QSAM BIT                    01980000
PHYSEQ   EQU   X'40'                    DCB PHYSICAL SEQ                02000000
DCBCEX   EQU   X'FF'-DCBPER             CLEAR DCB EXCEPTION             02020000
         SPACE 2                                                        02040000
*              TWELVE STAR DEFINITION                                   02060000
TSTLNK   EQU   0                        FORWARD 12* LINK                02080000
TSTUCB   EQU   2                        UCB POINTER                     02100000
TSTTCB   EQU   4                        TCB ID BYTE                     02120000
TSTIOB   EQU   5                        IOB POINTER                     02140000
TSTPR    EQU   8                        PRIORITY OF ENTRY               02160000
TSTDEB   EQU   9                        DEB POINTER                     02180000
         SPACE 2                                                        02200000
*              STATUS INDICATORS                                        02220000
CSWPCI   EQU   X'80'                    PCI                             02240000
CSWSMD   EQU   X'40'                    STATUS MODIFIER                 02260000
CSWIL    EQU   X'40'                    WRONG LENGTH IND.               02280000
CSWCUE   EQU   X'20'                    CONTROL UNIT END                02300000
CSWPC    EQU   X'20'                    PROGRAM CHECK                   02320000
CSWBSY   EQU   X'10'                    BUSY                            02340000
CSWPCK   EQU   X'10'                    PRTECTION CHECK                 02360000
CSWCHE   EQU   X'08'                    CHANNEL END                     02380000
CSWDVE   EQU   X'04'                    DEVICE END                      02400000
CSWUCK   EQU   X'02'                    UNIT CHECK                      02420000
CSWUEX   EQU   X'01'                    UNIT EXCEPTION                  02440000
CSWCCK   EQU   X'01'                    CHAINING CHECK                  02460000
CSWCDCK  EQU   X'08'                    CHANNEL DATA CHECK         CCHA 02465016
CSWCCCK  EQU   X'04'                    CHANNEL CNTRL CHECK        CCHA 02470016
CSWICCK  EQU   X'02'                    INTRFCE CNTRL CHECK      CCHA   02475016
         SPACE 2                                                        02480000
*              REGISTER DEFINITION                                      02500000
ERREG3   EQU   0                        WORK REG                        02520000
TSTREG   EQU   1                        TWELVE STAR REG                 02540000
ERREG2   EQU   2                        WORK REG                        02560000
CRBREG   EQU   3                        CURRENT RB REG.                 02580000
CCWREG   EQU   4                        CCW ADDRESS REG                 02600000
ERPIBRG  EQU   6                        ERPIB PTR REG              CCHA 02610016
UCBREG   EQU   7                        UCB ADDRESS REG                 02620000
COMREG   EQU   8                        COMMUNICATION TABLE REG         02640000
SAVREG   EQU   9                        SAVE REG.                       02660000
IOBRG    EQU   10                       IOB ADDRESS REG                 02680000
ERREG4   EQU   11                       WORK REG                        02700000
ERRLNK   EQU   12                       LINK REG                        02720000
ERREG1   EQU   13                       WORK REG                        02740000
ERRETR   EQU   14                       RETURN REG                      02760000
BASREG   EQU   15                       BASE REGISTER                   02780000
         SPACE 2                                                        02800000
*              MISC. DEFINITIONS                                        02820000
ERRBLK   EQU   X'40'                    BLANK                           02840000
INTREQ   EQU   X'40'                    INTERVENTION REQUIRED           02860000
CMDMD2   EQU   X'20'                    COMMAND DATA MODE 2             02880000
ERRDCT   EQU   X'20'                    READ ERROR CNT.                 02900000
IOBCC1   EQU   X'10'                    CONDITION CODE OF SIO           02920000
IOSTUS   EQU   X'10'                    STATUS BIT                      02940000
RDCNTL   EQU   X'06'                    READ SENSE OR CONTROL           02960000
IOCLBT   EQU   X'00'                    CLEAR BYTE                      02980000
ANYPCH   EQU   IOBPRT+IOBPR2            BOTH PUNCH RETRY FLAGS          03000000
UCBLTS   EQU   20                       UCB LAST RQE FIELD         CCHB 03005018
LTSZER   EQU   X'00'                    COMPARE FIELD-RQE FIELD ZERCCHB 03010018
UCBBSY   EQU   X'80'                    DEVICE BUSY FLAG           CCHB 03015018
         SPACE 1                                                        03020000
RETURN   EQU   3                        RETURN VALUE                    03040000
EXCPER   EQU   15                                                       03060000
LOC016   EQU   16                       COMMUNICATION TABLE             03080000
VECTXL   EQU   44                       VECTOR TO XCTL RNT.             03100000
VECT68   EQU   68                       INDEX TO INTERPRETER ROUTINE    03120000
VECT72   EQU   72                       INDEX TO WRITE TO OPERATOR      03140000
STATAB   EQU   112                      INDEX TO STATISTICS TABLE       03160000
WTORTN   EQU   253                      LOAD NAME TO WTO RTN.           03180000
LOAD2    EQU   1013                     LOAD NAME TO SECT. 2            03200000
IBPTR    EQU   116                      PTR TO PTR TO PTR TO ERPIB CCHA 03206016
ENDTBL   EQU   X'FF'                    END OF ERPIB TABLE         CCHA 03212016
NXT      EQU   2                        NEXT CONTROL ENTRY         256D 03212418
TFTYSX   EQU   256                      INCREMENT STAT INDEX       256D 03212818
CHDACK   EQU   X'01'                    CHAN DATA CK BIT FOR STATABCCHS 03213218
VALBITS  EQU   6                        VALID IND BITS IN ERPIB    CCHS 03213618
COMADVAL EQU   X'04'                    COMMAND ADDRESS VALID      CCHS 03214818
RDNCNTRL EQU   X'C0'                    READ(WITHOUT CTRL) COMMAND CCHS 03215618
RETRCD   EQU   7                        RETRY CODE IN ERPIB        CCHS 03216818
FOUR     EQU   X'04'                    RETRY CODE OF FOUR         CCHS 03217218
ONE      EQU   X'01'                    ERROR COUNT OF ONE         CCHS 03217618
READFEED EQU   X'10'                    READ/FEED CMD              CCHS 03218018
EQUIPCK  EQU   X'10'                    EQUIPMENT CHECK SENSE      CCHS 03218418
INTRCPT  EQU   X'7E'                    INTERCEPT CONDITION        CCHB 03218618
UNCNORTY EQU   X'01'                    UNCONTITIONAL NO-RETRY FLG CCHB 03218818
PROGFLGS EQU   4                        PROG FLAGS BYTE IN ERPIB   CCHB 03219018
CSWSSIO  EQU   X'80'                    CSW STORED ON SIO INDICAT  CCHB 03219218
NOP      EQU   X'03'                    NOP COMMAND                CCHB 03219418
THREE    EQU   X'03'                    RETRY CODE OF THREE        CCHB 03219618
ACPTUCS  EQU   X'80'                   ACCEPT UNUS CMD SEQ IND     CCHB 03219818
         EJECT                                                          03220000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 03240000
*   THIS IS ENTRY TO THE  - 1 4 0 2 - ERROR ROUTINE                     03260000
*********************************************************************   03280000
*                                                                    *  03300000
*    WHEN ENTERED THE IOBEX AND THE IOBERR FLAGS WILL BE SET TO 1 BY  * 03320000
*      THE ERROR ROUTINE.                                             * 03340000
*    ON RETURN THESE TWO FLAGS SHOULD BE INTERPRETED AS FOLLOWS.      * 03360000
*      IOBEX ON  AND IOBERR ON  - IOB IN CONTROL BY THE ERROR ROUTINE.* 03380000
*      IOBEX ON  AND IOBERR OFF - PERMANENT ERROR                     * 03400000
*      IOBEX OFF AND IOBERR OFF - ERROR CORRECTED                     * 03420000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 03440000
*        RESTART PROCEDURES                                             03460000
*        PUNCH ERRORS                                                   03480000
*                                                                       03500000
*              WHEN A CARD JAM OCCURS ON THE 1402/2540 PUNCH ANY ONE OR 03520000
*        MORE OF FOUR CARDS MAY BE JAMMED.                              03540000
*              1.  THE CARD PASSING THE PUNCH CHECK STATION             03560000
*              2.  THE CARD PASSING THE PUNCH STATION                   03580000
*              3.  THE CARD PASSING THE PUNCH FEED READ STATION         03600000
*              4.  THE CARD ENTERING THE THROAT                         03620000
*                                                                       03640000
*              IN C A                                                   03660000
*              IN CASE 1 ABOVE, THE JAM WILL CAUSE A HOLE COUNT CHECK,  03680000
*        AND ON RUN IN FOLLOWING THE CLEARING OF THE JAM THERE WILL BE  03700000
*        NO AUTOMATIC REPUNCHING.  ONLY IF THE QSAM ACCESS METHOD IS    03720000
*        USED WILL THE ERROR ROUTINE ATTEMPT RECOVERY ON A PUNCH EQ CK. 03740000
*                                                                       03760000
*              IN CASES 2,3 AND 4 THE CARD BEING CHECKED WILL NORMALLY  03780000
*        CHECK AS CORRECT (NO EQUIPMENT CHECK).  THE SENSE INFORMATION  03800000
*        WILL INDICATE INTERVENTION REQUIRED.  AFTER THE JAM IS CLEARED 03820000
*        3 CARDS SHOULD BE DISCARDED (2 BLANKS PLUS THE LAST CARD       03840000
*        PUNCHED). RUN-IN FOLLOWING A CARD JAM WHICH IS NOT ACCOMPANIED 03860000
*        BY AN EQUIPMENT CHECK WILL REPUNCH THE CARD WHICH WAS BEING    03880000
*        PUNCHED WHEN THE JAM OCCURED UNLESS IT IS A PUNCH FEED READ OP 03900000
*                                                                       03920000
*              IF THE EQUIPMENT CHECK IS NOT ACCOMPANIED BY AN INTER-   03940000
*        VENTION REQUIRED THE CARD IN ERROR WILL AUTOMATICALLY BE STACK 03960000
*        ED IN P1 POCKET.  THE OPERATOR SHOULD RUN OUT THE CARDS BY     03980000
*        DEPRESSING THE NPRO BUTTON.  THE LAST 4 CARDS IN &             04000000
*        DEPRESSING THE NPRO BUTTON.  THE LAST 4 CARDS IN P1 POCKET     04020000
*        SHOULD BE DISCARDED.  THEN READY THE UNIT BY DEPRESSING THE    04040000
*        START KEY, FEEDING THE FIRST CARD TO THE PREPUNCH STATION.     04060000
*                                                                       04080000
*              IF THE EQUIPMENT CHECK IS ACCOMPANIED BY AN INTERVENTION 04100000
*        REQUIRED, THE CARD IN ERROR IS JAMMED AT THE PUNCH CHECK       04120000
*        STATION AND THE JAM HAS TO BE CLEARED BEFORE RUNNING OUT THE   04140000
*        REMAINING CARDS.  THE LAST 4 CARDS SHOULD BE DISCARDED.  THE   04160000
*        RESTART PROCEDURE WILLBE AS FOR EQUIPMENT CHECK ALONE.  IF THE 04180000
*        ERROR SHOULD OCCUR AGAIN, THE ERROR IS CONSIDERED TO BE        04200000
*        UNRECOVERABLE.                                                 04220000
*                                                                       04240000
*        READ ERRORS                                                    04260000
*                                                                       04280000
*        DATA OR EQUIPMENT CHECK                                        04300000
*        A. READ AND FEED AND STACKER SELECT                            04320000
*              1. REMOVE THE CARDS FROM THE HOPPER                      04340000
*              2. REMOVE THE LAST CARD FROM THE STACKER (DATA CHECK,    04360000
*                 EXAMINE AND CORRECT THIS CARD).                       04380000
*              3. RUN THE CARDS OUT USING NON PROCESS RUN OUT           04400000
*              4. PLACE THE FOUR CARDS AT THE BEGINNING OF THE DECK     04420000
*              5. LOAD THE HOPPER AND READY THE UNIT                    04440000
*                                                                       04460000
*        B. READ NO FEED NO STACKER SELECT                              04480000
*              1. REMOVE THE CARDS FROM THE HOPPER                      04500000
*              2. RUN THE CARDS OUT USING NON PROCESS RUN OUT           04520000
*              3. EXAMINE AND CORRECT THE FIRST CARD RUN OUT (DATA CK.) 04540000
*              4. PLACE THE THREE CARDS AT THE BEGINNING OF THE DECK    04560000
*              5. LOAD THE HOPPER AND READY THE UNIT                    04580000
*                                                                       04600000
*        C. READ JAM                                                    04620000
*              1. INTERVENTION REQUIRED WITHOUT EQUIPMENT OR DATA CHECK 04640000
*                 THE CARDS IN THE STACKERS OR PAST THE PRESTACKER      04660000
*                 STATION HAVE BEEN PROCESSED PROPERLY                  04680000
*              2. JAM ACCOMPANIED BY EQUIPMENT OR DATA CHECK, CLEAR     04700000
*                 THE JAM AND FOLLOW PROCEDURE A ABOVE                  04720000
         EJECT                                                          04740000
         SPACE 1                                                        04760000
         USING ERR1402,15                                               04780000
ERR1402  L     IOBRG,TSTIOB-1(TSTREG)   GET ADDRESS OF IOB              04800000
         LH    UCBREG,TSTUCB(TSTREG)    GET UCB ADDRESS                 04820000
         L     COMREG,LOC016            ADDRESS OF COMMUNICATION TABLE  04840000
         OI    IOBFL1(IOBRG),IOBEXE     SET IOB EX AND ERROR FLAG ON    04860000
         SPACE 1                                                        04880000
         TM    IOBFL1(IOBRG),IOBCP1+IOBCP2 TEST FOR MIXED CHANNEL PROGR 04900000
         BC    1,ERR548                 YES, SET MSG TYPE               04920000
         SPACE 1                                                        04940000
         L     CCWREG,IOBCSW(IOBRG)     GET CCW ADDRESS                 05000000
         LA    CCWREG,0(CCWREG)         ZERO HIGH ORDER BYTE            05020000
         L     ERREG2,IOBMDB(IOBRG)     GET OLD RESTART ADDR     A56356 05022000
         LTR   CCWREG,CCWREG            TEST FOR INVALID ADDR    A56356 05034000
         BC    12,ERR521                NO, CONTINUE TESTS       A56356 05036000
         SH    CCWREG,ERRCN1            BACK UP ONE CCW        @SA63702 05046000
         TM    IOBFL1(IOBRG),IOBCP2     TEST FOR CMD CHAINING  @SA63702 05048000
         BC    8,ERR524                 NO, TEST FOR ICC/CCC   @SA63702 05048400
         OI    IOBFL1(IOBRG),IOBSRS     SET RESTART FLAG         A56356 05050000
         ST    CCWREG,IOBMDB(IOBRG)     SET RESTART ADDR         A56356 05052000
         TM    IOBFL3(IOBRG),IOBPRT     IS PUNCH RETRY FLAG ON          05060000
         BC    1,ERR524                 YES-TST CH/INTFCE CNTRL CK CCHA 05070016
         SPACE 1                                                        05080016
         SPACE 1                                                        05100000
ERR521   TM    IOBFL3(IOBRG),IOBENT     IS ENTRY BIT ON          A56356 05160000
         BC    8,ERR522                 BR-IF NOT ON                    05180000
         NI    IOBMDB(IOBRG),IOCLBT     ZERO MODIFIER BYTE              05200000
*   TEST IF ERROR OCCURED ON THE RESTARTED CCW                          05220000
         CR    ERREG2,CCWREG            CMPR CCW ADDR TO RESTART A56356 05240000
         BC    8,ERR524                 BR-CCW ADDR. IS EQUAL TO REST.  05280000
         NI    IOBFL3(IOBRG),X'FF'-IOBRDE-IOBBOE-IOBPRT  CLEAR CNTRS    05300000
ERR522   OI    IOBFL3(IOBRG),IOBENT     SET ENTRY BIT                   05320000
ERR524   TM    IOBCSW+5(IOBRG),CSWCCCK+CSWICCK CHAN/INTFCE CNT CK  CCHA 05368016
         BC    4+1,ERR551               YES-FIND ERPIB                  05376018
         SPACE 1                                                        05384016
         TM    IOBCSW+5(IOBRG),CSWCCK   TEST IF CHAINING CHECK ON  CCHA 05392016
         BC    1,ERR546                 BR-TO INDICATE LOG OUT          05400000
         SPACE 2                                                        05420000
         TM    IOBCSW+5(IOBRG),CSWCDCK  CHANNEL DAT CHECK          CCHS 05430018
         BC    8,ERR525                 NO-TEST IF UNIT CHECK      CCHS 05440018
         BAL   ERRLNK,ERR526            GET STATAB ADDRESS         CCHS 05450018
         OI    9(ERREG2),CHDACK         SET BIT IN STATISTICS TABLECCHS 05460018
ERR525   TM    IOBCSW+4(IOBRG),CSWUCK   TEST FOR UNIT CHECK        CCHS 05470018
         BC    8,ERR5CH                 NO-TEST FOR CHAN DAT CK    CCHS 05480018
ERR525A  LA    ERRLNK,ERR527            SET RTNREG FR STATAB FIND  CCHS 05490018
ERR526   L     ERREG2,STATAB(COMREG)    GET STATISTICS TABLE ADDR  256D 05500018
         SR    ERREG4,ERREG4            ZERO WORK REG              256D 05510018
         IC    ERREG4,UCBSTI(UCBREG)    GET STATAB INDEX           256D 05520018
         LR    ERREG1,ERREG2            GET STATAB START ADDR      256D 05530018
ERRLOOP1 CH    UCBREG,0(0,ERREG1)       DEV SUPPORTED BY THIS SECT 256D 05540018
         BC    4,ERRLOOP2               YES-INCR ADJUSTED CORRCTLY 256D 05550018
         LA    ERREG1,NXT(0,ERREG1)     INCR TO NXT CTL SECTION    256D 05560018
         LA    ERREG4,TFTYSX(0,ERREG4)  INCR STAT INDEX TO NXT SECT256D 05570018
         BC    15,ERRLOOP1              LOOP TO CHECK THIS SECT    256D 05580018
         SPACE 1                                                        05590018
ERRLOOP2 MH    ERREG4,ERRCN2            MULTIPLY BY 10             256D 05600018
         AR    ERREG2,ERREG4            ADD TO TABLE ADDRESS       256D 05610018
         BCR   15,ERRLNK                RETURN OR FALL THROUGH     256D 05620018
         SPACE 1                                                        05630018
ERR527   OC    8(1,ERREG2),IOBSNS(IOBRG) OR SENSE BYTE INTO TABLE  256D 05640018
         NI    8(ERREG2),X'78'          MASK OUT UNWANTED BITS   A35195 05670021
         SPACE 1                                                        05700000
         TM    IOBSNS(IOBRG),X'05'      TEST SHOULD NOT OCCUR SENSE     05720000
         BC    5,ERR546                 BR-TO INDICATE LOG OUT          05740000
         SPACE 1                                                        05760000
         TM    IOBSNS(IOBRG),X'10'      TEST FOR EQUIPMENT CHECK        05780000
         BC    1,ERR528                                                 05800000
ERR540   LA    ERREG1,LOAD2             GET LOAD NAME TO SECT. 2        05820000
         L     ERRETR,VECTXL(COMREG)                                    05840000
         BCR   15,ERRETR                                                05860000
         SPACE 1                                                        05865016
ERR5CH   TM    IOBCSW+5(IOBRG),CSWCDCK   CHANNEL DATA CHECK        CCHA 05870016
         BC    8,ERR540                 NO-GET SECOND LOAD         CCHA 05875016
         SPACE 1                                                        05900000
*       EQUIPMENT CHECK OR CHANNEL DATA CHECK ON READ CMD          CCHA 05920016
ERR528   CLI   IOBCOD(IOBRG),X'7E'      TEST IF IOB IS INTERCEPTED      05940000
         BC    8,ERR529                 YES, BYPASS COMMAND TEST        05960000
         LTR   CCWREG,CCWREG            TEST IF CCW ADDR. IS 0 OR NEG.  05980000
         BC    12,ERR546                BR ON YES TO PERM. ERROR        06000000
         TM    0(CCWREG),RDCNTL         TEST IF READ CMD.               06020000
         BC    5,ERR531                 BR- TO CHECK COUNT              06040000
         TM    IOBCSW+4(IOBRG),CSWUCK   TEST FOR UNIT CHECK    @SA63702 06050000
         BC    8,ERR529                 NO-EQUIP CHECK         @SA63702 06052000
         XC    IOBCSW+4(2,IOBRG),IOBCSW(IOBRG) CLEAR STATUS    @SA63702 06054000
         BC    15,ERR540                GO TO SECOND LOAD      @SA63702 06056000
ERR529   MVI   IOBCOD(IOBRG),X'7F'      SET CODE TO NORMAL              06060000
         TM    IOBFL2(IOBRG),IOBQSM     IS THIS QSAM                    06080000
         BC    12,ERR532                BR-ON NO TEST INTERV. REQ.      06100000
         TM    IOBFL3(IOBRG),IOBPR2+IOBPRT IS ERR. CNT. 1      @SA67574 06120000
         BC    1,ERR546                BR ON YES TO LOG OUT        9656 06140015
         BC    4,ERR550                 MIX = ERR DURING ERP   @SA67574 06150000
         SPACE 1                                                        06160000
*        THE FOLLOWING IS TO HANDLE QSAM WITH 3 OR MORE IOBS            06180000
         SPACE 1                                                        06200000
         OI    IOBFL3(IOBRG),IOBPR2+IOBPRT SET QSAM ERR COUNT  @SA67574 06220000
         NI    IOBFL1(IOBRG),X'FF'-IOBSRS RESET RESTART FLAG       9656 06230015
         L     IOBRG,IOBCOD(IOBRG)      GET ECB PTR TO QSAM EXTENSION   06240000
         LA    IOBRG,4(IOBRG)           ADJUST ADDR TO IOB IN ERROR     06260000
         OI    IOBFL3(IOBRG),IOBPRT     SET PUNCH RETRY                 06280000
         MVI   IOBCOD(IOBRG),X'7F'      SET CODE TO NORMAL      SA65501 06290000
         LR    ERREG2,IOBRG             PUT ERROR IOB IN WORKREG        06300000
         SH    ERREG2,ERRCN1            GET QSAM LINK FIELD             06320000
         L     ERREG2,0(ERREG2)         GET NEXT IOB EXT ADDR           06340000
         OI    IOBFL3+8(ERREG2),IOBPRT  SET PUNCH RETRY IN NEXT IOB     06360000
         MVI   IOBCOD+8(ERREG2),X'7F'   SET CODE TO NORMAL      SA65501 06370000
         OI    IOBFL1(IOBRG),IOBEXE     SET IOB EX AND ERR FLAGS        06380000
         IC    ERREG4,TSTTCB(TSTREG)    SAVE TCB ID                     06400000
         ST    IOBRG,TSTTCB(TSTREG)     STORE IOB ADDRESS IN 12 *       06420000
         STC   ERREG4,TSTTCB(TSTREG)    RESTORE TCB ID                  06440000
         BC    15,ERR550                GET WTO RTN.                    06460000
         SPACE 1                                                        06480000
ERR531   TM    IOBECT+1(IOBRG),X'05'    IS RETRY COUNT 5?               06500000
         BC    1,ERR53A                 YES-PERM. ERROR                 06520000
         LH    ERREG1,IOBECT(IOBRG)     GET CURRENT ERROR COUNT         06540000
         LA    ERREG1,1(ERREG1)         INCREMENT COUNT                 06560000
         STH   ERREG1,IOBECT(IOBRG)                                     06580000
         BC    15,ERR550                BR- TO GET WTO                  06600000
         SPACE 1                                                        06620000
ERR53A   MVI   IOBECT+1(IOBRG),X'00'    CLEAR IOB ERROR COUNT           06640000
         BC    15,ERR546                TO WTO RTN                      06660000
         SPACE 1                                                        06661016
ERR551   L     ERPIBRG,IBPTR(COMREG)    PTR TO PTR TO PTR TO ERPIB      06662018
         L     ERPIBRG,0(ERPIBRG)       PTR TO PTR TO ERPIB        CCHA 06663016
         L     ERPIBRG,0(ERPIBRG)       PTR TO ERPIB               CCHA 06666016
ERCMPR   CH    UCBREG,2(ERPIBRG)        IS THIS ERPIB FOR CARD 2540CCHA 06667016
         BC    8,ERR552                 YES-CHECK FOR POSSIBLE RETRCCHS 06668018
         SPACE 1                                                        06669016
         LA    ERPIBRG,8(ERPIBRG)       ADDR OF NEXT ERPIB         CCHA 06670016
         TM    0(ERPIBRG),ENDTBL        END OF ERPIB TABLE         CCHA 06671018
         BC    8+4,ERCMPR               NO-TEST NEXT ERPIB         CCHS 06672018
         SPACE 1                                                        06673016
         BC    1,ERR546                 YES-LOG OUT                CCHA 06674016
         SPACE 1                                                        06675016
ERZERO   XC    0(8,ERPIBRG),0(ERPIBRG)  ZERO ERPIB                 CCHA 06676016
         BC    15,ERR546                INDICATE LOG OUT           CCHA 06677016
         SPACE 1                                                        06680000
ERR532   TM    IOBSNS(IOBRG),INTREQ     TEST FOR INTERV. REQ.           06700000
         BC    1,ERR550                 BR-ON YES                       06720000
ERR546   OI    IOBFL3(IOBRG),IOBLOG     SET LOGOUT FLAG                 06740000
ERR548   OI    IOBFL3(IOBRG),IOBMSG     SET MESSAGE TYPE TO 1           06760000
ERR550   LA    ERREG1,WTORTN            GET LOAD NAME TO WTO RTN.       06780000
         L     ERRETR,VECTXL(COMREG)    GET ADDR. TO XCTL RTN.          06800000
         BCR   15,ERRETR                XCTL TO WTO RTN.                06820000
         SPACE 1                                                        06820518
*        CHANNEL OR INTERFACE CONTROL CHECK                             06821018
         SPACE 1                                                        06821518
ERR552   CLI   IOBCOD(IOBRG),INTRCPT    IS IOB INTERCEPTED         CCHB 06821818
         BC    8,ERZERO                 YES-PERM ERROR             CCHB 06822118
         TM    PROGFLGS(ERPIBRG),UNCNORTY NO RETRY FLAG SET        CCHB 06822418
         BC    1,ERZERO                 YES-PERM ERROR             CCHB 06822718
         TM    0(CCWREG),RDNCNTRL       READ WITHOUT CNTRL CMD     CCHB 06823018
         BC    8+4,ERR553               NO-TEST IF CSW STORED ON SIOCHB 06823318
         TM    0(CCWREG),READFEED       READ FEED COMMAND          CCHB 06823618
         BC    1,ERR553                YES-TEST IF CSW STORED      CCHB 06823918
         TM    IOBECT+1(IOBRG),ONE     SECOND OCCURRENCE           CCHB 06824218
         BC    1,ERZERO                YES-PERM ERROR              CCHB 06824518
         SPACE 1                                                        06824818
*        UNUSUAL CMD SEQ SENSE WILL RESULT FROM RETRYING A READ    CCHB 06825118
*        WITH NO CNTRL.  THE NEXT INSTRUCTION SETS A FLAG IN       CCHB 06825418
*        IOBECT TO TELL THE SECOND LOAD TO ACCEPT UNUSUAL CMD SEQ  CCHB 06825718
*        AFTER CHANNEL ERROR.                                      CCHB 06826018
         SPACE 1                                                        06826318
         OI    IOBECT+1(IOBRG),ACPTUCS  SET UP TO ACCEPT UCS       CCHB 06826618
         BC    15,ERR557               BR TO SET ERR COUNT              06826918
         SPACE 1                                                        06827218
ERR553   TM    PROGFLGS(ERPIBRG),CSWSSIO CSW STORED ON SIO         CCHB 06827518
         BC    1,ERR556                 YES-TEST ERROR COUNT       CCHB 06827818
         TM    VALBITS(ERPIBRG),COMADVAL COMMAND ADDRESS VALID     CCHB 06828118
         BC    8,ERZERO                 NO-ZERO ERPIB/PERM ERR     CCHB 06828418
         CLI   0(CCWREG),NOP            NOP COMMAND                CCHB 06828718
         BC    8,ERR556                 YES-TEST ERROR COUNT       CCHB 06829018
         TM    RETRCD(ERPIBRG),FOUR     RETRY CODE OF FOUR         CCHB 06829318
         BC    8,ERR560                 NO-TEST RETRY CODE OF THREECCHB 06829618
         TM    RETRCD(ERPIBRG),THREE    RETRY CODE OF FOUR ALONE   CCHB 06829918
         BC    4+1,ERZERO               NO-PERMANENT ERROR         CCHB 06830218
ERR556   TM    IOBECT+1(IOBRG),ONE      HAS THIS BEEN RETRIED      CCHB 06830518
         BC    1,ERZERO                 YES-ZERO ERPIB/GO TO WTO   CCHB 06830818
ERR557   OI    IOBECT+1(IOBRG),ONE     SET ERROR FLAG              CCHB 06831118
         XC    0(8,ERPIBRG),0(ERPIBRG)  ZERO ERPIB                 CCHB 06831418
         SVC   EXCPER                   ERREXCP                    CCHB 06831718
         SVC   RETURN                   RETURN                     CCHB 06832018
         SPACE 1                                                        06832318
ERR560   TM    RETRCD(ERPIBRG),THREE    RETRY CODE TEST            CCHB 06832618
         BC    8,ERZERO                 ZERO-ZERO ERPIB/PERM ERR   CCHB 06832918
         BC    1,ERR563                 THREE-TEST UCBLTS FIELD    CCHB 06833218
         TM    RETRCD(ERPIBRG),ONE      RETRY CODE OF ONE          CCHB 06833518
         BC    1,ERR556                 YES-RETRY                  CCHB 06833818
         BC    15,ERZERO                NO-PERMANENT ERROR         CCHB 06833918
         SPACE 1                                                        06834018
ERR563   CLI   UCBLTS(UCBREG),LTSZER    FIRST BYTE UCBLTS ZERO     CCHB 06834118
         BC    8,ERR564                 YES-RESTORE UCBLTS         CCHB 06834218
         OI    UCBFL1(UCBREG),UCBBSY    SET BUSY FLAG IN UCB       CCHB 06834318
         BC    15,ERR565                ZERO ERPIB                 CCHB 06834418
         SPACE 1                                                        06834518
ERR564   STH   TSTREG,UCBLTS(UCBREG)    RESTORE LAST RQE POINTER   CCHB 06834618
ERR565   XC    0(8,ERPIBRG),0(ERPIBRG)  ZERO THE ERPIB             CCHB 06834718
         TM    IOBECT+1(IOBRG),ONE      ERROR COUNT EQUAL TO ONE   CCHB 06834818
         BC    1,ERR546                 YES-PELRMANENT ERROR       CCHB 06834918
         OI    IOBECT+1(IOBRG),ONE      SET ERROR COUNT TO ONE     CCHB 06835018
         BC    15,ERR550                ISSUE INT REQ MESSAGE      CCHB 06835118
         SPACE 1                                                        06835218
         SPACE 1                                                        06836218
         SPACE 1                                                        06838518
         SPACE 1                                                        06840000
         DS    0H                                                       06860000
ERRCN1   DC    AL2(8)                   DECIMAL 8                       06880000
ERRCN2   DC    AL2(10)                  MULTIPLIER CONSTANT             06900000
         ORG   IEC1402A+1024-16                                         06902000
LABEL    DC    C'IGE0001C OS/21.8'      MODULE ID                       06910000
         END                                                            06920000
