          TITLE 'IGE0011A - 2495 ERROR RECOVERY PROCEDURES'             00100019
*                                                                     * 00200019
*TITLE 'IGE0011A' - 2495 ERROR RECOVERY PROCEDURES                    * 00300019
*                                                                     * 00400019
*STATUS:  CHANGE LEVEL 000                                            * 00500019
*                                                                     * 00600019
*FUNCTION/OPERATION:  IGE0011A IS SCHEDULED FOR EXECUTION WHENEVER THE* 00700019
*   I/O SUPERVISOR DETECTS AN ERROR ASSOCIATED WITH THE 2495 TAPE     * 00800019
*   CARTRIDGE READER THAT REQUIRES ERROR RECOVERY PROCEDURES.  THE    * 00900019
*   ROUTINES ARE NORMALLY SCHEDULED FOR THE FOLLOWING ERRORS:         * 01000019
*                                                                     * 01100019
*                 PROGRAM CHECK                                       * 01200019
*                 PROTECTION CHECK                                    * 01300019
*                 UNIT CHECK                                          * 01400019
*                 CHANNEL DATA CHECK                                  * 01500019
*                 UNIT EXCEPTION                                      * 01600019
*                 INCORRECT LENGTH                                    * 01700019
*                                                                     * 01800019
*   IF THE CHANNEL CHECK HANDLER (CCH) IS IN THE SYSTEM, THE ERROR    * 01900019
*   RECOVERY PROCEDURE IS ALSO ENTERED FOR CHANNEL CONTROL CHECKS AND * 02000019
*   INTERFACE CONTROL CHECKS.                                         * 02100019
*                                                                     * 02200019
*   THE ROUTINES MAY ALSO BE ENTERED WITH THE FOLLOWING CONDITIONS    * 02300019
*   FOLLOWING SUCCESSFUL RE-TRY OF A RECOVERABLE ERROR.  THESE        * 02400019
*   CONDITIONS ARE CONSIDERED NORMAL AND ARE TREATED ACCORDINGLY.     * 02500019
*                                                                     * 02600019
*                 BUSY                                                * 02700019
*                 CHANNEL END                                         * 02800019
*                 DEVICE END                                          * 02900019
*                                                                     * 03000019
*   THE ERROR ROUTINES USE THE STANDARD ERROR INTERPRETER ROUTINE     * 03100019
*   FOR TESTING OF SENSE BITS AND CSW STATUS BITS.  THE FOLLOWING     * 03200019
*   ACTIONS ARE TAKEN DEPENDING UPON THE NATURE OF THE ERROR:         * 03300019
*                                                                     * 03400019
*   1)  NORMAL CONDITION OR SUCCESSFUL RE-TRY OF RECOVERABLE ERROR    * 03500019
*       CONDITION                                                     * 03600019
*                                                                     * 03700019
*       IOB EXCEPTION AND ERROR FLAGS ARE CLEARED AND CONTROL IS      * 03800019
*       TRANSFERRED TO THE STATISTICS UPDATE ROUTINE.                 * 03900019
*                                                                     * 04000019
*   2)  RECOVERABLE ERROR                                             * 04100019
*                                                                     * 04200019
*       IOB ERROR FLAG IS SET.                                        * 04300019
*       IOB EXCEPTION FLAG IS CLEARED.                                * 04400019
*       ERROR COUNTS ARE UPDATED.                                     * 04500019
*       REPOSITION AND RESIDUAL READ CCW'S MAY BE CONSTRUCTED IN THE  * 04600019
*       UCB EXTENSION.                                                * 04700019
*       CONTROL IS PASSED TO THE I/O SUPERVISOR VIA SVC 15 AND SVC 3  * 04800019
*       TO RE-TRY THE CHANNEL PROGRAM.                                * 04900019
*                                                                     * 05000019
*   3)  PERMANENT ERROR                                               * 05100019
*                                                                     * 05200019
*   IOB ERROR AND EXCEPTION FLAGS ARE SET.                            * 05300019
*   IOB MESSAGE AND LOGOUT FLAGS MAY BE SET.                          * 05400019
*   CONTROL IS RETURNED TO THE I/O SUPERVISOR EITHER DIRECTLY         * 05500019
*   THROUGH ISSUANCE OF AN SVC 15 AND AN SVC 3 OR INDIRECTLY BY       * 05600019
*   FIRST PASSING CONTROL TO THE WTO ROUTINE WHICH IN TURN PASSES     * 05700019
*   CONTROL TO THE STATISTICS UPDATE ROUTINE AND THE I/O OUTBOARD     * 05800019
*   RECORDING ROUTINE, IF REQUIRED, AND EVENTUALLY TO THE I/O         * 05900019
*   SUPERVISOR.                                                       * 06000019
*                                                                     * 06100019
*   IF THE CHANNEL CHECK HANDLER (CCH) IS IN THE SYSTEM AND THE       * 06200019
*   ERROR RECOVERY PROCEDURE IS ENTERED FOR A CHANNEL CONTROL         * 06300019
*   CHECK OR AN INTERFACE CONTROL CHECK, THE ROUTINES ZERO OUT        * 06400019
*   THE ERROR RECOVERY PROCEDURE INTERFACE BYTES (ERPIB) CREATED      * 06500019
*   BY THE CCH AND HANDLE THE ERROR AS A PERMANENT ERROR.             * 06600019
*                                                                     * 06700019
*   STATISTICS ARE KEPT FOR THE FOLLOWING ERROR CONDITIONS:           * 06800019
*                                                                     * 06900019
*            INTERVENTION REQUIRED                                    * 07000019
*            EQUIPMENT CHECK                                          * 07100019
*            DATA CHECK                                               * 07200019
*            POSITION CHECK                                           * 07300019
*            CHANNEL DATA CHECK                                       * 07400019
*                                                                     * 07500019
*ENTRY POINTS:                                                        * 07600019
*                                                                     * 07700019
*        IGE0011A - ERROR RECOVERY PROCEDURE ENTRY POINT              * 07800019
*                                                                     * 07900019
*   THE ROUTINES ARE ENTERED INTO THE I/O SUPERVISOR TRANSIENT        * 08000019
*   AREA AND SCHEDULED FOR EXECUTION BY THE I/O INTERRUPTION          * 08100019
*   SUPERVISOR.                                                       * 08200019
*                                                                     * 08300019
*   DATA PASSED TO THE ROUTINES CONSISTS OF STANDARD SYSTEM CONTROL   * 08400019
*   BLOCKS.                                                           * 08500019
*                                                                     * 08600019
*INPUT:  RQE POINTER IN REGISTER 1.                                   * 08700019
*                                                                     * 08800019
*OUTPUT:  I/O ERROR AND INTERVENTION REQUIRED MESSAGES IN SOME        * 08900019
*   INSTANCES                                                         * 09000019
*                                                                     * 09100019
*EXTERNAL ROUTINES:  NONE                                             * 09200019
*                                                                     * 09300019
*EXITS-NORMAL:  XCTL TO STATISTICS UPDATE ROUTINE FOLLOWING           * 09400019
*   SUCCESSFUL RECOVERY OF A RE-TRYABLE ERROR OR UPON DETECTION OF    * 09500019
*   A NORMAL CONDITION                                                * 09600019
*                                                                     * 09700019
*     -ERROR:                                                         * 09800019
*                                                                     * 09900019
*   1)  SVC 15 AND SVC 3 EXIT TO I/O SUPERVISOR FOR RE-EXECUTION      * 10000019
*   OF THE CHANNEL PROGRAM UPON DETECTION OF A RE-TRYABLE ERROR       * 10100019
*                                                                     * 10200019
*   2)  XCTL TO WTO ROUTINE FOR ISSUANCE OF AN INTERVENTION           * 10300019
*   REQUIRED MESSAGE AND QUEUEING OF THE I/O REQUEST IN THE CASE OF   * 10400019
*   INTERVENTION REQUIRED                                             * 10500019
*                                                                     * 10600019
*   3)  XCTL TO WTO ROUTINE FOR ISSUANCE OF A PERMANENT I/O ERROR     * 10700019
*   MESSAGE AND UPDATING OF STATISTICS AND LOGREC IN THE CASE OF      * 10800019
*   SOME PERMANENT ERRORS.                                            * 10900019
*                                                                     * 11000019
*   4)  SVC 15 AND SVC 3 EXIT TO I/O SUPERVISOR IN THE CASE OF SOME   * 11100019
*   PERMANENT I/O ERRORS.                                             * 11200019
*                                                                     * 11300019
*TABLES/WORK AREAS:                                                   * 11400019
*                                                                     * 11500019
*   1) INPUT/OUTPUT BLOCK (IOB)                                       * 11600019
*                                                                     * 11700019
*                                                                     * 11800019
*   ****************************************************************  * 11900019
*   *IOB-  * CHANNEL     *IOB   *      *      *IOB   *UNREL *START/*  * 12000019
*   *FLG1  * PROGRAM      ERROR *      *      *EXCEP *FLAG  *RESTRT*  * 12100019
*   *      * DESCRIPTION *FLAG  *      *      *FLAG  *      *FLAG  *  * 12200019
*   ****************************************************************  * 12300019
*   *IOB-  *      *SENSE *PURGE *      *      *      *      *      *  * 12400019
*   *FLG2  *      *BIT   *FLAG  *      *      *      *      *      *  * 12500019
*   *      *      *      *      *      *      *      *      *      *  * 12600019
*   ****************************************************************  * 12700019
*   *IOB-  *      *ENTRY *CHAN  *BUS-  *      *MSG   *      *LOG-  *  * 12800019
*   *FLG3  *      *BIT   *DATA  *OUT   *      *TYPE  *      *OUT   *  * 12900019
*   *      *      *      *CHK   *COUNT *      *      *      *FLAG  *  * 13000019
*   *      *      *      *COUNT *      *      *      *      *      *  * 13100019
*   ****************************************************************  * 13200019
*   *IOB   *     READ POSITION         *       READ DATA           *  * 13300019
*   *ERROR *     CHECK COUNT           *       CHECK COUNT         *  * 13400019
*   *CNTS  *                           *                           *  * 13500019
*   ****************************************************************  * 13600019
*                                                                     * 13700019
*                                                                     * 13800019
*                                                                     * 13900019
*   2)  UNIT CONTROL BLOCK (UCB)                                      * 14000019
*                                                                     * 14100019
*                                                                     * 14200019
*       *****************************************************         * 14300019
*    +0 *            *            *            *            *         * 14400019
*       *****************************************************         * 14500019
*    +4 *            *            *            *            *         * 14600019
*       *****************************************************         * 14700019
*    +8 *            *STATAB INDEX*            *            *         * 14800019
*       *****************************************************         * 14900019
*   +12 *            *                                      *         * 15000019
*       *****************************************************         * 15100019
*   +16 *      *                                            *         * 15200019
*       *****************************************************         * 15300019
*   +20 *                         *                         *         * 15400019
*       *****************************************************         * 15500019
*   +24 *               UCB EXTENSION POINTER               *         * 15600019
*       *****************************************************         * 15700019
*                                                                     * 15800019
         EJECT                                                          15900019
*                                                                     * 16000019
*   3)  UCB EXTENSION                                                 * 16100019
*                                                                     * 16200019
*                                                                     * 16300019
*       *****************************************************         * 16400019
*    +0 *          BACKSPACE OR REPOSITION CCW              *         * 16500019
*       *****************************************************         * 16600019
*    +8 *          RESIDUAL READ CCW OR TIC CCW             *         * 16700019
*       *****************************************************         * 16800019
*   +16 *                   TIC CCW                         *         * 16900019
*       *****************************************************         * 17000019
*   +24 *               IOB CSW STORE                       *         * 17100019
*       *****************************************************         * 17200019
*                                                                     * 17300019
*                                                                     * 17400019
*   4)  STATISTICS UPDATE TABLE                                       * 17500019
*                                                                     * 17600019
*ATTRIBUTES:  RE-ENTRANT                                              * 17700019
*                                                                     * 17800019
*NOTES:  A 32-BYTE UCB EXTENSION IS UTILIZED FOR CONSTRUCTION OF      * 17900019
*   A BACKSPACE OR REPOSITION CCW, A RESIDUAL READ CCW, A TIC         * 18000019
*   COMMAND, AND A CSW STORAGE AREA FOR RE-TRYING OF POSITION CHECK,  * 18100019
*   DATA CHECK, AND CHANNEL DATA CHECK ERRORS.                        * 18200019
*                                                                     * 18300019
         EJECT                                                          18400019
IGE0011A START 0                                                        18500019
         SPACE 3                                                        18600019
*        REGISTER DEFINITIONS                                           18700019
         SPACE 2                                                        18800019
TSTREG   EQU   1                       TWELVE STAR REG - RQE            18900019
UCBEXT   EQU   2                       UCB EXTENSION                    19000019
CRBREG   EQU   3                       CURRENT RB REG                   19100019
CCWREG   EQU   4                       CCW ADDRESS REGISTER             19200019
LOGRCREG EQU   5                       LOGREC DCB ADDRESS               19300019
WKREG1   EQU   5                       WORK REGISTER                    19400019
WKREG2   EQU   6                       WORK REGISTER                    19500019
UCBREG   EQU   7                       UCB REG                          19600019
CVTREG   EQU   8                       CVT REG                          19700019
SAVEREG  EQU   9                       SAVE REG                         19800019
IOBREG   EQU   10                      IOB REG                          19900019
LNKREG   EQU   12                      LINK REG                         20000019
WKREG3   EQU   13                      WORK REGISTER                    20100019
RETREG   EQU   14                      RETURN REG                       20200019
BASEREG  EQU   15                      BASE REG                         20300019
         SPACE 2                                                        20400019
*        IOB DEFINITION                                                 20500019
         SPACE 1                                                        20600019
IOBFLAG1 EQU   0                       FLAGS 1                          20700019
IOBFLAG2 EQU   1                       FLAGS 2                          20800019
IOBSENS0 EQU   2                       SENSE BYTE 1                     20900019
IOBECBCC EQU   4                       COMPLETION CODE                  21000019
IOBECBPT EQU   4                       ECB ADDRESS                      21100019
IOBFLAG3 EQU   8                       FLAGS 3                          21200019
IOBCSW   EQU   8                       CSW STORAGE                      21300019
IOBSIOCC EQU   16                      SIO CONDITION CODE               21400019
IOBSTART EQU   17                      CHANNEL PROGRAM ADDRESS          21500019
IOBDCBPT EQU   21                      DCB POINTER                      21600019
IOBRESTR EQU   24                      RESTART POINTER                  21700019
IOBERRCT EQU   30                      ERROR COUNTS                     21800019
*                                        BITS  0-3  READ POSITION CHECK 21900019
*                                              4-7  READ DATA CHECK     22000019
         SPACE 1                                                        22100019
*        IOBFLAG1 INDICATORS                                            22200019
         SPACE 1                                                        22300019
IOBCP1   EQU   X'80'                   DATA CHAINING                    22400019
IOBCP2   EQU   X'40'                   COMMAND CHAINING                 22500019
IOBERR   EQU   X'20'                   IOB ERROR FLAG                   22600019
IOBEX    EQU   X'04'                   IOB EXCEPTION FLAG               22700019
IOBSRS   EQU   X'01'                   START/RESTART FLAG               22800019
         EJECT                                                          22900019
*        IOBFLAG3 INDICATORS                                            23000019
         SPACE 2                                                        23100019
IOBENT   EQU   X'40'                   IOB ENTRY BIT                    23200019
IOBCDCK  EQU   X'20'                   CHANNEL DATA CHECK COUNT         23300019
IOBBUS   EQU   X'10'                   BUS-OUT ERROR COUNT              23400019
IOBMSG   EQU   X'04'                   MESSAGE TYPE                     23500019
IOBLOG   EQU   X'01'                   LOGOUT FLAG                      23600019
         SPACE 2                                                        23700019
*        TWELVE STAR DEFINITION                                         23800019
         SPACE 1                                                        23900019
TSTLNK   EQU   0                       FORWARD 12* LINK                 24000019
TSTUCB   EQU   2                       UCB POINTER                      24100019
TSTIOB   EQU   5                       IOB POINTER                      24200019
TSTDEB   EQU   9                       DEB POINTER                      24300019
         SPACE 2                                                        24400019
*        UCB DEFINITION                                                 24500019
         SPACE 1                                                        24600019
UCBSTI   EQU   9                       STATISTICS POINTER               24700019
UCBEXTAD EQU   24                      UCB EXTENSION ADDRESS            24800019
         SPACE 2                                                        24900019
*        UCB EXTENSION DEFINITION                                       25000019
         SPACE 1                                                        25100019
UCBCCW1  EQU   0                       REPO OR BACKSPACE CCW            25200019
UCBCCW2  EQU   8                       RESIDUAL READ OR TIC             25300019
UCBCCW3  EQU   16                      TIC                              25400019
EXTWORK  EQU   24                      WORK AREA                        25500019
CSWADD   EQU   25                      OLD CSW ADDRESS                  25600019
CSWCNT   EQU   30                      OLD CSW COUNT                    25700019
         SPACE 2                                                        25800019
*        CSW INDICATORS                                                 25900019
         SPACE 1                                                        26000019
CSWUCK   EQU   X'02'                   UNIT CHECK                       26100019
CSWCHE   EQU   X'08'                   CHANNEL END                      26200019
CSWDVE   EQU   X'04'                   DEVICE END                       26300019
CSWCEDE  EQU   X'0C'                   CHANNEL OR DEVICE END            26400019
CSWCDK   EQU   X'08'                   CHANNEL DATA CHECK               26500019
         SPACE 2                                                        26600019
*        CCW FLAGS AND COMMANDS                                         26700019
         SPACE 1                                                        26800019
CCFLAG   EQU   X'40'                   COMMAND CHAINING CCW FLAG        26900019
CCWFLAGS EQU   X'30'                   CCW SLI AND SKIP MASK            27000019
CTRLCMD  EQU   X'03'                   CONTROL COMMAND                  27100019
REPOCMD  EQU   X'27'                   CONTROL BACKSPACE                27200019
READCMD  EQU   X'02'                   READ                             27300019
TICCMD   EQU   X'08'                   TIC                              27400019
         EJECT                                                          27500019
*        MISCELLANEOUS DEFINITIONS                                      27600019
         SPACE 1                                                        27700019
FOUR     EQU   4                       FOUR                             27800019
TEN      EQU   10                      TEN                              27900019
HEXTEN   EQU   X'0A'                   HEXADECIMAL TEN                  28000019
POSCLR   EQU   X'0F'                   POSITION CHECK COUNT CLEAR       28100019
DCKCLR   EQU   X'F0'                   DATA CHECK COUNT CLEAR           28200019
EXCPER   EQU   15                      ERROR EXCP                       28300019
RETURN   EQU   3                       SVC RETURN                       28400019
IOBCC1   EQU   X'10'                   CONDITION CODE OF SIO            28500019
LOC016   EQU   16                      COMMUNICATION TABLE              28600019
VECTXL   EQU   44                      VECTOR TO XCTL ROUTINE           28700019
VECINT   EQU   68                      VECTOR TO INTERPRETER ROUTINE    28800019
VECWTO   EQU   72                      VECTOR TO WTO ROUTINE            28900019
STATAB   EQU   112                     INDEX TO STATISTICS TABLE        29000019
WTORTN   EQU   253                     LOAD NAME TO WTO RTN             29100019
STATUP   EQU   254                     LOAD NAME TO STAT. UPDATE RTN    29200019
IOBEXER  EQU   IOBEX+IOBERR            IOB EX + IOB ERR FLAG            29300019
IOBINCPT EQU   X'7E'                   INTERCEPT CONDITION              29400019
ZERO     EQU   X'00'                   ZERO                             29500019
STABIT   EQU   X'7A'                   SENSE BITS REQUIRING STATISTICS  29600019
INTREQ   EQU   X'40'                   INT. REQ. BIT IN SENSE BYTE      29700019
ERRORECB EQU   X'7F'                   IOB ECB ERROR COMPLETION CODE    29800019
SNSDCK   EQU   X'08'                   DATACHECK                        29900019
CVTDCB   EQU   116                     LOGREC DCB POINTER               30000019
LASTERIB EQU   X'FF'                   LAST ERIB TABLE ENTRY            30100019
TICTEST1 EQU   X'07'                   TIC COMMAND TEST 1               30200019
TICTEST2 EQU   X'08'                   TIC COMMAND TEST 2               30300019
CHADCK   EQU   X'01'                   STAT TABLE CHAN DATA CHK ENTRY   30400019
LEFTTEN  EQU   X'A0'                   HEXIDECIMAL TEN                  30500019
CCCICC   EQU   X'06'                   CHANNEL CTRL CHK OR INT CTRL CHK 30600019
         EJECT                                                          30700019
*        2495 ERROR RECOVERY PROCEDURES                                 30800019
         SPACE 1                                                        30900019
*        THE FOLLOWING IS A LIST OF ERRORS HANDLED BY THIS ERROR        31000019
*        RECOVERY PROCEDURE AND THE MAIN PROCESSING ROUTINE ENTRY       31100019
*        POINT ASSOCIATED WITH EACH.                                    31200019
*                                                                       31300019
*                 CHANNEL CONTROL CHECK - ERR130                        31400019
*               INTERFACE CONTROL CHECK - ERR130                        31500019
*                         PROGRAM CHECK - ERR040                        31600019
*                      PROTECTION CHECK - ERR040                        31700019
*                            UNIT CHECK - ERR045                        31800019
*                    CHANNEL DATA CHECK - ERR070                        31900019
*                        UNIT EXCEPTION - ERR120                        32000019
*                      INCORRECT LENGTH - ERR120                        32100019
*                       EQUIPMENT CHECK - ERR055                        32200019
*                         BUS-OUT CHECK - ERR050                        32300019
*                 INTERVENTION REQUIRED - ERR065                        32400019
*                        POSITION CHECK - ERR080                        32500019
*                            DATA CHECK - ERR100                        32600019
*                        COMMAND REJECT - ERR060                        32700019
         SPACE 2                                                        32800019
*        THIS SECTION SETS UP CONTROL BLOCK POINTERS AND TESTS FOR      32900019
*        DATA CHAINING AND MIXED CHAINING.                              33000019
         SPACE 2                                                        33100019
         USING ER2495,BASEREG          INDICATE BASE REGISTER           33200019
ER2495   L     IOBREG,TSTIOB-1(TSTREG)  LOAD IOB ADDRESS                33300019
         L     CVTREG,LOC016           LOAD CVT ADDRESS                 33400019
         LH    UCBREG,TSTUCB(TSTREG)   LOAD UCB ADDRESS                 33500019
         L     UCBEXT,UCBEXTAD(UCBREG) LOAD ADDRESS OF EXTENSION        33600019
         OI    IOBFLAG1(IOBREG),IOBEXER  SET IOB EX AND ERROR FLAGS     33700019
         TM    IOBFLAG1(IOBREG),IOBCP1 DATA CHAINING OR MIXED CHAINING  33800019
         BO    ERR130                  BR YES                           33900019
         SPACE 2                                                        34000019
*        THIS SECTION DEVELOPS THE FAILING CCW ADDRESS, TESTS           34100019
*        WHETHER OR IT IS ZERO OR NEGATIVE, AND TESTS FOR THE SAME      34200019
*        ERROR IF THIS IS NOT THE FIRST ENTRY TO THE ERP.  IF IT        34300019
*        IS NOT THE SAME ERROR, THIS SECTION ZEROES ALL RECOVERABLE     34400019
*        ERROR COUNTS AND STORES THE NEW CSW                            34500019
         SPACE 2                                                        34600019
ERR015   L     CCWREG,IOBCSW(IOBREG)   LOAD CCW ADDRESS                 34700019
         LA    CCWREG,0(CCWREG)        ZERO HIGH-ORDER BYTE             34800019
         SH    CCWREG,CCWLNG           BACK UP ONE CCW                  34900019
         LTR   CCWREG,CCWREG           CCW ADDRESS ZERO OR NEGATIVE     35000019
         BNP   ERR150                  BR YES, INTERCEPT CONDITION      35100019
         TM    IOBFLAG3(IOBREG),IOBENT ENTRY BIT ON                     35200019
         BZ    ERR020                  BR NO                            35300019
         TM    IOBFLAG1(IOBREG),IOBCP2  COMMAND CHAINING SPECIFIED      35400019
         BZ    ERR025                  BR NO                            35500019
         LA    WKREG1,UCBCCW1(UCBEXT)  TEST CURRENT CCW WITHIN          35600019
         CLR   WKREG1,CCWREG             EXTENSION                      35700019
         BE    ERR025                  BR YES                           35800019
         LA    WKREG1,UCBCCW2(UCBEXT)  2ND CCW                          35900019
         CLR   WKREG1,CCWREG                                            36000019
         BE    ERR025                  BR YES                           36100019
         CLC   CSWADD(3,UCBEXT),IOBCSW+1(IOBREG)  SAME CCW WITHIN       36200019
*                                        CHAIN                          36300019
         BE    ERR025                  BR YES                           36400019
         MVI   IOBFLAG3(IOBREG),ZERO   CLEAR COUNTERS                   36500019
         MVI   IOBERRCT(IOBREG),ZERO   CLEAR COUNTERS                   36600019
ERR020   MVC   CSWADD(7,UCBEXT),IOBCSW+1(IOBREG)  STORE NEW CSW         36700019
         SPACE 2                                                        36800019
*        IF UNIT CHECK IS ON, THIS SECTION OR'S THE SENSE BYTE INTO     36900019
*        THE FIRST BYTE OF THE STATISTICS TABLE WORK AREA.  IF          37000019
*        CHANNEL DATA CHECK IS ON, IT SETS BIT 7 OF BYTE TWO OF THE     37100019
*        STATISTICS TABLE WORK AREA TO ONE.                             37200019
         SPACE 2                                                        37300019
ERR025   TM    IOBCSW+5(IOBREG),CSWCDK CHANNEL DATA CHECK               37400019
         BO    ERR026                  BRANCH IF YES                    37500019
         TM    IOBCSW+4(IOBREG),CSWUCK TEST IF UNIT CHECK               37600019
         BZ    ERR030                  BR IF NO                         37700019
ERR026   L     WKREG2,STATAB(CVTREG)   LOAD STATISTICS TABLE ADDRESS    37800019
         XR    WKREG1,WKREG1           CLEAR WORK REGISTER              37900019
         IC    WKREG1,UCBSTI(UCBREG)   LOAD UCB STATAB PTR              38000019
ERR027   CH    UCBREG,0(0,WKREG2)      DEVICE SUPPORTED BY THIS SECTION 38100019
         BL    ERR028                  BR YES                           38200019
         LA    WKREG2,2(WKREG2)        INCREMENT TO NEXT CONTROL ENTRY  38300019
         LA    WKREG1,256(WKREG1)      INCREMENT STATAB POINTER         38400019
         B     ERR027                  LOOP TO CHECK THIS SECTION       38500019
ERR028   MH    WKREG1,STALNG           MULTIPLY BY ENTRY LENGTH         38600019
         AR    WKREG2,WKREG1           ADD TO STATISTICS TABLE ADDRESS  38700019
         OC    8(1,WKREG2),IOBSENS0(IOBREG) OR SENSE BYTE INTO TABLE    38800019
         NI    8(WKREG2),STABIT        MASK OUT UNWANTED BITS           38900019
         TM    IOBCSW+5(IOBREG),CSWCDK CHANNEL DATA CHECK               39000019
         BZ    ERR030                  BRANCH IF NO                     39100019
         OI    9(WKREG2),CHADCK        SET BIT 7 OF STATISTICS TABLE    39200019
*                                        WORK AREA BYTE 2 TO ONE        39300019
         EJECT                                                          39400019
*        THIS SECTION USES THE COMMON INTERPRETER ROUTINE TO ANALYZE    39500019
*        CSW STATUS BITS.                                               39600019
         SPACE 2                                                        39700019
ERR030   LR    SAVEREG,BASEREG         SAVE BASE ADDRESS                39800019
         L     BASEREG,VECINT(CVTREG)  LOAD ADDR INTERPRETER RTN        39900019
ERR033   BALR  LNKREG,BASEREG          LINK TO INTERPRETER RTN          40000019
         SPACE 1                                                        40100019
         DC    X'1D'                   CHANNEL CONTROL CHECK ID         40200019
         DC    AL1(ERR034-ERR033-2)    CHANNEL CONTROL CHECK DISP       40300019
         DC    X'1E'                   INTERFACE CONTROL CHECK ID       40400019
         DC    AL1(ERR034-ERR033-4)    INTERFACE CONTROL CHECK DISP     40500019
         DC    X'1A'                   PROGRAM CHECK ID                 40600019
         DC    AL1(ERR040-ERR033-6)    PROGRAM CHECK DISPLACEMENT       40700019
         DC    X'1B'                   PROTECTION CHECK IDENT           40800019
         DC    AL1(ERR040-ERR033-8)    PROTECTION CHECK DISPLACEMENT    40900019
         DC    X'16'                   UNIT CHECK ID                    41000019
         DC    AL1(ERR045-ERR033-10)   UNIT CHECK DISPLACEMENT          41100019
         DC    X'1C'                   CHANNEL DATA CHECK ID            41200019
         DC    AL1(ERR035-ERR033-12)   CHANNEL DATA CHECK DISP          41300019
         DC    X'17'                   UNIT EXCEPTION ID                41400019
         DC    AL1(ERR036-ERR033-14)   UNIT EXCEPTION DISPLACEMENT      41500019
         DC    X'19'                   INCORRECT LENGTH ID              41600019
         DC    AL1(ERR036-ERR033-16)   INCORRECT LENGTH DISPL           41700019
         DC    X'2F'                   END OF TEST ID                   41800019
         DC    AL1(ERR037-ERR033-18)   END OF TEST DISPLACEMENT         41900019
         SPACE 1                                                        42000019
ERR034   B     ERR130                  CCC AND ICC PROCESSING           42100019
ERR035   B     ERR070                  CHANNEL DATA CHECK PROCESSING    42200019
ERR036   B     ERR120                  U.E. AND I.L. PROCESSING         42300019
ERR037   B     ERR125                  CORRECTED ERROR PROCESSING       42400019
         SPACE 2                                                        42500019
*        PERMANENT ERROR EXIT - NO LOGOUT OR MESSAGE OUTPUT             42600019
         SPACE 1                                                        42700019
ERR040   NI    IOBFLAG1(IOBREG),X'FF'-IOBERR  CLEAR ERROR FLAG          42800019
         SVC   EXCPER                  ERROR EXCP                       42900019
         SVC   RETURN                  RETURN                           43000019
         EJECT                                                          43100019
*        THIS SECTION USES THE COMMON INTERPRETER ROUTINE TO ANALYZE    43200019
*        CSW STATUS BITS AND SENSE BITS ON A UNIT CHECK CONDITION.      43300019
         SPACE 1                                                        43400019
ERR045   LR    SAVEREG,BASEREG         SAVE BASE ADDRESS                43500019
         L     BASEREG,VECINT(CVTREG)  LOAD ADDR INTERPRETER RTN        43600019
ERR046   BALR  LNKREG,BASEREG          LINK TO INTERPRETER RTN          43700019
         SPACE 1                                                        43800019
         DC    X'05'                   SENSE BIT 5 (NOT USED)           43900019
         DC    AL1(ERR060-ERR046-2)    SENSE BIT 5 DISPLACEMENT         44000019
         DC    X'07'                   SENSE BIT 7 (NOT USED)           44100019
         DC    AL1(ERR060-ERR046-4)    SENSE BIT 7 DISPLACEMENT         44200019
         DC    X'03'                   EQUIPMENT CHECK ID               44300019
         DC    AL1(ERR055-ERR046-6)    EQUIPMENT CHECK DISP             44400019
         DC    X'1C'                   CHANNEL DATA CHECK ID            44500019
         DC    AL1(ERR070-ERR046-8)    CHANNEL DATA CHECK DISP          44600019
         DC    X'02'                   BUS-OUT CHECK ID                 44700019
         DC    AL1(ERR050-ERR046-10)   BUS-OUT CHECK DISP               44800019
         DC    X'01'                   INTERVENTION REQUIRED ID         44900019
         DC    AL1(ERR065-ERR046-12)   INTERVENTION REQ'D DISP          45000019
         DC    X'06'                   POSITION CHECK ID                45100019
         DC    AL1(ERR047-ERR046-14)   POSITION CHECK DISP              45200019
         DC    X'04'                   DATA CHECK ID                    45300019
         DC    AL1(ERR048-ERR046-16)   DATA CHECK DISP                  45400019
         DC    X'00'                   COMMAND REJECT ID                45500019
         DC    AL1(ERR060-ERR046-18)   COMMAND REJECT DISP              45600019
         DC    X'2F'                   END OF TEST ID                   45700019
         DC    AL1(ERR060-ERR046-20)   PERMANENT ERROR PROCESSING       45800019
         SPACE 1                                                        45900019
ERR047   B     ERR080                  POSITION CHECK PROCESSING        46000019
ERR048   B     ERR100                  DATA CHECK PROCESSING            46100019
         SPACE 2                                                        46200019
*        BUS-OUT CHECK PROCESSING                                       46300019
         SPACE 1                                                        46400019
*        IF THE BUS-OUT ERROR OCCURS AT INITIAL SELECTION, THE          46500019
*        THE FAILING CCW IS RE-EXECUTED ONE TIME.                       46600019
         SPACE 2                                                        46700019
ERR050   TM    IOBCSW+4(IOBREG),CSWCEDE CHANNEL OR DEVICE END           46800019
         BNZ   ERR055                  BR-YES  (NOT INITIAL SELECTION)  46900019
         TM    IOBFLAG3(IOBREG),IOBBUS ERROR COUNT EQUAL TO ONE         47000019
         BO    ERR055                  BR-YES                           47100019
         OI    IOBFLAG3(IOBREG),IOBBUS SET ERROR COUNT TO ONE           47200019
ERR053   OI    IOBFLAG3(IOBREG),IOBENT SET IOB ENTRY BIT ON             47300019
         SVC   EXCPER                  ERROR EXCP                       47400019
         SVC   RETURN                  RETURN                           47500019
         EJECT                                                          47600019
*        PERMANENT ERROR EXIT - WITH WTO MESSAGE AND LOGOUT             47700019
         SPACE 1                                                        47800019
*        IF THE FAILING CCW IS THE READ CCW WITHIN THE EXTENSION,       47900019
*        THE IOB CSW ADDRESS IS REPLACED BY THE ORIGINAL FAILING CCW    48000019
*        ADDRESS WHICH HAS BEEN STORED IN THE UCB EXTENSION.            48100019
         SPACE 2                                                        48200019
ERR055   OI    IOBFLAG3(IOBREG),IOBLOG SET LOG OUT BIT                  48300019
ERR060   OI    IOBFLAG3(IOBREG),IOBMSG SET MESSAGE BIT                  48400019
         NI    IOBFLAG1(IOBREG),X'FF'-IOBERR  CLEAR ERROR FLAG          48500019
         LA    WKREG1,UCBCCW2(UCBEXT)  SET POINTER TO READ CCW WITHIN   48600019
*                                        EXTENSION                      48700019
         CLR   CCWREG,WKREG1           IS IT READ CCW                   48800019
         BNE   ERR062                  BR NO                            48900019
         MVC   IOBCSW+1(3,IOBREG),CSWADD(UCBEXT) RESTORE ORIGINAL CSW   49000019
ERR062   LA    WKREG3,WTORTN           GET LOAD NAME TO WTO RTN         49100019
ERR064   L     RETREG,VECTXL(CVTREG)   GET ADDRESS XCTL ROUTINE         49200019
         BR    RETREG                  XCTL TO WTO RTN                  49300019
         EJECT                                                          49400019
*        INTERVENTION REQUIRED                                          49500019
         SPACE 2                                                        49600019
*        ONE OF FOUR  SITUATIONS IS POSSIBLE:                           49700019
*                                                                       49800019
*        1)  THE INTERVENTION REQUIRED OCCURRED AT INITIAL SELECTION    49900019
*            (NO CHANNEL OR DEVICE END)                                 50000019
*                                                                       50100019
*        2)  THE INTERVENTION REQUIRED OCCURRED DURING TRANSFER         50200019
*            OF DATA.  (INDICATED BY CHANNEL END ALONE OR BY CHANNEL    50300019
*            END AND DEVICE END IF COMMAND CHAINING WAS USED)           50400019
*                                                                       50500019
*        3)  INTERVENTION REQUIRED OCCURRED FOLLOWING A TRANSFER        50600019
*            OF DATA DURING WHICH A UNIT CHECK CONDITION OCCURRED       50700019
*            BUT PRIOR TO ISSUANCE OF THE SENSE COMMAND (INDICATED      50800019
*            BY CHANNEL END, UNIT CHECK, AND SOME OTHER ERROR)          50900019
*                                                                       51000019
*        4)  INTERVENTION REQUIRED OCCURRED AT DEVICE END.  IN THIS     51100019
*            CASE, THE STATUS IS STORED IN THE UCB UNTIL THE NEXT       51200019
*            SIO IS ISSUED.  AT THAT TIME THE CSW IS TRANSFERRED TO     51300019
*            THE IOB AND AN INTERCEPT CONDITION IS INDICATED. (THE      51400019
*            IOB ECB CONDITION CODE IS SET TO '7E'.)                    51500019
           SPACE 2                                                      51600019
ERR065   TM    IOBCSW+4(IOBREG),CSWCEDE CHANNEL OR DEVICE END           51700019
         BNZ   ERR067                  BR YES                           51800019
         SPACE 1                                                        51900019
*        ON INITIAL SELECTION XCTL TO THE WTO ROUTINE TO ISSUE THE      52000019
*        INTERVENTION REQUIRED MESSAGE AND RETRY THE COMMAND            52100019
         SPACE 1                                                        52200019
ERR066   NI    IOBFLAG3(IOBREG),X'FF'-IOBMSG SET IOB MSG BIT TO ZERO    52300019
         OI    IOBFLAG3(IOBREG),IOBENT SET IOB ENTRY BIT                52400019
         B     ERR062                  BRANCH TO XCTL TO WTO ROUTINE    52500019
         SPACE 1                                                        52600019
*        ON A COMPLETED READ (CHANNEL END OR DEVICE END PRESENT)        52700019
*        IGNORE THE INTERVENTION REQUIRED AND CONTINUE CHECKING AS      52800019
*        INDICATED IN THE STANDARDS CHART                               52900019
         SPACE 1                                                        53000019
ERR067   LR    SAVEREG,BASEREG         SAVE BASE ADDRESS                53100019
         L     BASEREG,VECINT(CVTREG)  LOAD ADDR INTERPRETER RTN        53200019
ERR068   BALR  LNKREG,BASEREG          LINK TO INTERPRETER RTN          53300019
         SPACE 1                                                        53400019
         DC    X'06'                   POSITION CHECK ID                53500019
         DC    AL1(ERR080-ERR068-2)    POSITION CHECK DISP              53600019
         DC    X'04'                   DATA CHECK ID                    53700019
         DC    AL1(ERR0683-ERR068-4)   DATA CHECK DISP                  53800019
         DC    X'00'                   COMMAND REJECT ID                53900019
         DC    AL1(ERR0684-ERR068-6)   COMMAND REJECT DISP              54000019
         DC    X'2F'                   END OF TEST                      54100019
         DC    AL1(ERR0685-ERR068-8)   CORRECTED ERROR PROCESSING       54200019
         SPACE 1                                                        54300019
ERR0683  B     ERR100                  DATA CHECK                       54400019
ERR0684  B     ERR060                  PERMANENT ERROR                  54500019
ERR0685  B     ERR125                  CORRECTED ERROR                  54600019
         SPACE 1                                                        54700019
         EJECT                                                          54800019
*        CHANNEL DATA CHECK PROCESSING                                  54900019
         SPACE 1                                                        55000019
*        IF THE CHANNEL DATA CHECK OCCURRED ON A READ COMMAND,          55100019
*        A REPOSITION CCW AND A TIC TO THE FAILING CCW ARE CONSTRUCTED  55200019
*        IN THE UCB EXTENSION.  SVC 15 AND SVC 3 ARE ISSUED TO RETRY    55300019
*        THE OPERATION ONE TIME.                                        55400019
         SPACE 2                                                        55500019
ERR070   TM    0(CCWREG),CTRLCMD       CONTROL COMMAND                  55600019
         BO    ERR075                  BR-YES                           55700019
         TM    IOBFLAG3(IOBREG),IOBCDCK ERROR COUNT EQUAL TO ONE        55800019
         BO    ERR055                  BR-YES                           55900019
         OI    IOBFLAG3(IOBREG),IOBCDCK SET COUNT EQUAL TO ONE          56000019
         SPACE 1                                                        56100019
*        IF THE CURRENT ERROR OCCURRED ON A RETRY OPERATION AND THE     56200019
*        PREVIOUS ERROR WAS DIFFERENT, CLEAR ALL OTHER COUNTS.          56300019
         SPACE 1                                                        56400019
         CLC   CSWCNT(2,UCBEXT),IOBCSW+6(IOBREG)  COMPARE RESIDUAL CNT  56500019
         BE    ERR071                  BR EQUAL                         56600019
         NI    IOBFLAG3(IOBREG),X'FF'-IOBBUS-IOBCDCK  CLEAR BUS-OUT     56700019
*                                      AND CHANNEL DATA CHECK COUNTS    56800019
         MVI   IOBERRCT(IOBREG),ZERO   CLEAR POSITION AND DATA CHECK    56900019
*                                        COUNTS                         57000019
         MVC   CSWCNT(2,UCBEXT),IOBCSW+6(IOBREG) STORE NEW COUNT        57100019
ERR071   LH    WKREG2,6(CCWREG)        LOAD ORIGINAL COUNT              57200019
         SH    WKREG2,IOBCSW+6(IOBREG) SUBTRACT RESIDUAL COUNT          57300019
         STH   WKREG2,UCBCCW1+6(UCBEXT) STORE REPOSITION COUNT          57400019
         LA    WKREG1,8(UCBEXT)        SET POINTER TO 2ND CCW WITHIN    57500019
*                                        EXTENSION                      57600019
         CLR   CCWREG,WKREG1           CURRENT CCW WITHIN EXTENSION     57700019
         BE    ERR073                  BR YES                           57800019
         MVI   UCBCCW1(UCBEXT),REPOCMD SET UP REPOSITION COMMAND        57900019
         MVC   UCBCCW1+1(3,UCBEXT),1(CCWREG)  SET DUMMY ADDRESS         58000019
         MVI   UCBCCW1+4(UCBEXT),CCWFLAGS    SET SLI AND SKIP MASK      58100019
         NC    UCBCCW1+4(1,UCBEXT),4(CCWREG) SET FLAGS IF REQUIRED      58200019
         OI    UCBCCW1+4(UCBEXT),CCFLAG     SET COMMAND CHAINING FLAG   58300019
         ST    CCWREG,UCBCCW2(UCBEXT)  STORE CCW ADDRESS IN TIC         58400019
         MVI   UCBCCW2(UCBEXT),TICCMD  SET UP TIC COMMAND               58500019
ERR072   LA    WKREG1,UCBCCW1(UCBEXT)  LOAD ADDRESS REPO CCW            58600019
         ST    WKREG1,IOBRESTR(IOBREG) STORE ADDR IN RESTART            58700019
         OI    IOBFLAG1(IOBREG),IOBSRS SET RESTART FLAG                 58800019
         OI    IOBFLAG3(IOBREG),IOBENT SET IOB ENTRY BIT ON             58900019
ERR073   SVC   EXCPER                  ERROR EXCP                       59000019
         SVC   RETURN                  RETURN                           59100019
         EJECT                                                          59200019
*        CHANNEL DATA CHECK - CONTROL COMMAND                           59300019
         SPACE 1                                                        59400019
*        IF THE CHANNEL DATA CHECK OCCURRED ON A CONTROL COMMAND,       59500019
*        CONTINUE TESTING THE REMAINING SENSE BITS.  IF NO OTHER        59600019
*        ERROR IS FOUND, IGNORE THE CHANNEL DATA CHECK AND              59700019
*        CONTINUE.                                                      59800019
         SPACE 2                                                        59900019
ERR075   TM    IOBCSW+4(IOBREG),CSWUCK TEST IF UNIT CHECK               60000019
         BZ    ERR125                  BR NO                            60100019
         LR    SAVEREG,BASEREG         SAVE BASE ADDRESS                60200019
         L     BASEREG,VECINT(CVTREG)  LOAD ADDR INTERPRETER RTN        60300019
ERR077   BALR  LNKREG,BASEREG          LINK TO INTERPRETER RTN          60400019
         SPACE 1                                                        60500019
         DC    X'02'                   BUS OUT IDENT                    60600019
         DC    AL1(ERR078-ERR077-2)    BUS-OUT DISPLACEMENT             60700019
         DC    X'01'                   INTERVENTION REQUIRED ID         60800019
         DC    AL1(ERR0783-ERR077-4)   INTERVENTION REQ'D DISP          60900019
         DC    X'06'                   POSITION CHECK ID                61000019
         DC    AL1(ERR080-ERR077-6)    POSITION CHECK DISP              61100019
         DC    X'04'                   DATA CHECK ID                    61200019
         DC    AL1(ERR100-ERR077-8)    DATA CHECK DISPLACEMENT          61300019
         DC    X'00'                   COMMAND REJECT ID                61400019
         DC    AL1(ERR0785-ERR077-10)  COMMAND REJECT DISPLACEMENT      61500019
         DC    X'2F'                   END OF TEST                      61600019
         DC    AL1(ERR125-ERR077-12)   CORRECTED ERROR PROCESSING       61700019
         SPACE 1                                                        61800019
ERR078   B     ERR050                  BUS-OUT                          61900019
ERR0783  B     ERR065                  INTERVENTION REQ'D PROCESSING    62000019
ERR0785  B     ERR060                  COMMAND REJECT PROCESSING        62100019
         EJECT                                                          62200019
*        POSITION CHECK PROCESSING                                      62300019
         SPACE 1                                                        62400019
*        IF THE POSITION CHECK OCCURRED ON A READ COMMAND,              62500019
*        BACKSPACE CCW AND A RESIDUAL READ CCW ARE CONSTRUCTED          62600019
*        IN THE UCB EXTENSION AND SVC 15 AND SVC 3 ARE ISSUED TO        62700019
*        RE-TRY THE OPERATION.  IF COMMAND CHAINING WAS SPECIFIED,      62800019
*        A TIC COMMAND WHICH BRANCHES TO THE NEXT COMMAND IN THE        62900019
*        CHAIN IS ALSO CONSTRUCTED.                                     63000019
         SPACE 2                                                        63100019
ERR080   TM    0(CCWREG),CTRLCMD       CONTROL COMMAND                  63200019
         BO    ERR055                  BR-YES                           63300019
         SPACE 1                                                        63400019
*        IF THE CURRENT ERROR OCCURRED ON A RETRY OPERATION AND IS      63500019
*        DIFFERENT FROM THE ORIGINAL ERROR, CLEAR ALL OTHER COUNTS.     63600019
         SPACE 1                                                        63700019
         CLC   CSWCNT(2,UCBEXT),IOBCSW+6(IOBREG)  COMPARE RESIDUAL CNT  63800019
         BE    ERR082                  BR EQUAL                         63900019
         NI    IOBFLAG3(IOBREG),X'FF'-IOBCDCK-IOBBUS  CLEAR BUS-OUT     64000019
*                                        AND CHANNEL DATA CHECK COUNTS  64100019
         MVI   IOBERRCT(IOBREG),ZERO   CLEAR DATA CHECK AND POSITION    64200019
*                                        CHECK COUNTS                   64300019
         MVC   CSWCNT(2,UCBEXT),IOBCSW+6(IOBREG) STORE NEW COUNT        64400019
ERR082   TM    IOBERRCT(IOBREG),LEFTTEN  COUNT EQUAL TO TEN             64500019
         BO    ERR055                  BR YES                           64600019
         XR    WKREG1,WKREG1           CLEAR REGISTER                   64700019
         IC    WKREG1,IOBERRCT(IOBREG) INSERT ERROR COUNT               64800019
         LA    WKREG1,16(WKREG1)       INCREMENT POSITION CHECK COUNT   64900019
         STC   WKREG1,IOBERRCT(IOBREG)  REPLACE OLD COUNT               65000019
         SPACE 1                                                        65100019
*        CONSTRUCT BACKSPACE CCW                                        65200019
         SPACE 1                                                        65300019
ERR085   MVI   UCBCCW1(UCBEXT),REPOCMD SET UP BACKSPACE COMMAND         65400019
         MVC   UCBCCW1+1(3,UCBEXT),1(CCWREG) SET UP DUMMY ADDRESS       65500019
         MVI   UCBCCW1+4(UCBEXT),CCWFLAGS SET SLI AND SKIP MASK         65600019
         NC    UCBCCW1+4(1,UCBEXT),4(CCWREG) SET FLAGS IF REQUIRED      65700019
         OI    UCBCCW1+4(UCBEXT),CCFLAG  SET COMMAND CHAINING FLAG      65800019
         MVC   UCBCCW1+6(2,UCBEXT),BACKCNT SET COUNT EQUAL TO ONE       65900019
         SPACE 1                                                        66000019
*        CONSTRUCT RESIDUAL READ CCW                                    66100019
         SPACE 1                                                        66200019
         LH    WKREG2,IOBCSW+6(IOBREG) LOAD RESIDUAL COUNT              66300019
         LA    WKREG2,1(WKREG2)        INCREMENT BY ONE                 66400019
         LH    WKREG1,6(CCWREG)        LOAD ORIGINAL COUNT              66500019
         STH   WKREG2,UCBCCW2+6(UCBEXT) STORE RESIDUAL READ COUNT       66600019
         SR    WKREG1,WKREG2           SUBTRACT RESIDUAL COUNT FROM     66700019
*                                        ORIGINAL COUNT                 66800019
         L     WKREG2,0(CCWREG)        LOAD ORIGINAL DATA ADDRESS       66900019
         LA    WKREG2,0(WKREG2)        CLEAR LEFT BYTES                 67000019
         AR    WKREG2,WKREG1           INCREMENT TO LAST BYTE FILLED    67100019
         ST    WKREG2,UCBCCW2(UCBEXT)  STORE NEW DATA ADDRESS           67200019
         MVI   UCBCCW2(UCBEXT),READCMD SET UP READ COMMAND              67300019
         LA    WKREG1,UCBCCW2(UCBEXT)  SET POINTER TO READ CCW WITHIN   67400019
*                                        EXTENSION                      67500019
         CLR   CCWREG,WKREG1           CURRENT CCW WITHIN EXTENSION     67600019
         BE    ERR073                  BR YES                           67700019
         SPACE 1                                                        67800019
*        SET UP CCW FLAGS                                               67900019
         SPACE 1                                                        68000019
         MVI   UCBCCW2+4(UCBEXT),CCWFLAGS   SET SLI MASK                68100019
         NC    UCBCCW2+4(1,UCBEXT),4(CCWREG) SET SLI FLAG IF REQUIRED   68200019
         SPACE 1                                                        68300019
*        ON COMMAND CHAINING CONSTRUCT TIC TO NEXT CCW                  68400019
         SPACE 1                                                        68500019
         TM    IOBFLAG1(IOBREG),IOBCP2  COMMAND CHAINING SPECIFIED      68600019
         BZ    ERR072                  BR NO                            68700019
         TM    4(CCWREG),IOBCP2        COMMAND CHAINING THIS CCW        68800019
         BZ    ERR072                  BR-NO                            68900019
         OI    UCBCCW2+4(UCBEXT),CCFLAG  SET COMMAND CHAINING FLAG      69000019
         SPACE 1                                                        69100019
*        IF NEXT INSTRUCTION IS TIC, REMOVE ADDRESS AND INSERT IN       69200019
*        TRANSFERRING TIC                                               69300019
         SPACE 1                                                        69400019
         TM    8(CCWREG),TICTEST1      COMMAND CODE BITS 5,6,7 ALL ZERO 69500019
         BNZ   ERR090                  BRANCH NO                        69600019
         TM    8(CCWREG),TICTEST2      COMMAND CODE BIT 4 SET           69700019
         BZ    ERR090                  BRANCH NO                        69800019
         L     WKREG1,8(CCWREG)        LOAD CCW ADDRESS                 69900019
         LA    WKREG1,0(WKREG1)        CLEAR COMMAND CODE               70000019
         B     ERR092                                                   70100019
ERR090   LA    WKREG1,8(CCWREG)        LOAD FAILING CCW ADDRESS+8       70200019
ERR092   ST    WKREG1,UCBCCW3(UCBEXT)  STORE NEXT CCW ADDR IN TIC       70300019
         MVI   UCBCCW3(UCBEXT),TICCMD  SET UP TIC COMMAND               70400019
         B     ERR072                  BR TO CONTINUE PROCESSING        70500019
         EJECT                                                          70600019
*        DATA CHECK PROCESSING                                          70700019
         SPACE 1                                                        70800019
*        IF THE DATA CHECK OCCURRED ON A READ COMMAND, CONSTRUCT        70900019
*        A BACKSPACE CCW AND A RESIDUAL READ CCW IN THE UCB EXTENSION   71000019
*        AND RETRY THE OPERATION.                                       71100019
         SPACE 2                                                        71200019
ERR100   TM    0(CCWREG),CTRLCMD        CONTROL COMMAND                 71300019
         BO    ERR055                     BR - YES                      71400019
         SPACE 1                                                        71500019
*        IF THIS ERROR OCCURRED ON A RETRY OPERATION AND IS DIFFERENT   71600019
*        FROM THE ORIGINAL ERROR, CLEAR ALL OTHER COUNTS.               71700019
         SPACE 1                                                        71800019
         CLC   CSWCNT(2,UCBEXT),IOBCSW+6(IOBREG)  COMPARE RESIDUAL CNT  71900019
         BE    ERR110                  BR EQUAL                         72000019
         NI    IOBFLAG3(IOBREG),X'FF'-IOBCDCK-IOBBUS  CLEAR BUS-OUT     72100019
*                                      AND CHANNEL DATA CHECK COUNTS    72200019
         MVI   IOBERRCT(IOBREG),ZERO   CLEAR POSITION CHECK AND DATA    72300019
*                                      CHECK COUNTS                     72400019
         MVC   CSWCNT(2,UCBEXT),IOBCSW+6(IOBREG) STORE NEW COUNT        72500019
ERR110   TM    IOBERRCT(IOBREG),HEXTEN COUNT EQUAL TO TEN               72600019
         BO    ERR055                  BR YES                           72700019
         XR    WKREG1,WKREG1                                            72800019
         IC    WKREG1,IOBERRCT(IOBREG)  INSERT ERROR COUNT              72900019
         LA    WKREG1,1(WKREG1)        INCREMENT DATA CHECK COUNT       73000019
         STC   WKREG1,IOBERRCT(IOBREG)  REPLACE OLD COUNT               73100019
         B     ERR085                  BR TO SET UP BACKSPACE           73200019
*                                      AND RESIDUAL READ CCW'S          73300019
         SPACE 3                                                        73400019
*        UNIT EXCEPTION OR INCORRECT LENGTH                             73500019
         SPACE 1                                                        73600019
*        IF UNIT EXCEPTION OR INCORRECT LENGTH OCCURS ON THE FIRST      73700019
*        ENTRY TO THE ERP, IT SET AS A PERMANENT ERROR.  IF IT OCCURS   73800019
*        FOLLOWING THE RETRY OF ANOTHER ERROR, IT IS SET AS A           73900019
*        CORRECTED ERROR TO FORCE THE I/O SUPERVISOR TO SCHEDULE        74000019
*        NORMAL UNIT EXCEPTION AND INCORRECT LENGTH PROCESSING (SUCH    74100019
*        AS ENTERING APPENDAGES).   WHEN THE ERP IS RE-SCHEDULED, THE   74200019
*        ERROR IS THEN INDICATED AS A PERMANENT ERROR.                  74300019
         SPACE 2                                                        74400019
ERR120   TM    IOBFLAG3(IOBREG),IOBENT ENTRY BIT ON                     74500019
         BZ    ERR040                  BR NO                            74600019
         EJECT                                                          74700019
*        SUCCESSFUL RECOVERY - RESET ALL ERROR INDICATORS AND COUNTS    74800019
         SPACE 1                                                        74900019
ERR125   NI    IOBFLAG1(IOBREG),X'FF'-IOBEXER CLEAR IOB EXCEPTION AND   75000019
*                                      ERROR FLAGS                      75100019
         NI    IOBFLAG1(IOBREG),X'FF'-IOBSRS CLEAR IOB RESTART FLAG     75200019
         MVI   IOBERRCT(IOBREG),ZERO   CLEAR ADDITIONAL ERROR COUNTS    75300019
         SPACE 1                                                        75400019
*        IF THE ERROR OCCURRED ON THE READ CCW WITHIN THE UCB EXTEN-    75500019
*        SION, REPLACE THE CURRENT IOB CSW ADDRESS WITH THE ORIGINAL    75600019
*        CSW ADDRESS WHICH WAS STORED IN THE UCB EXTENSION.             75700019
         SPACE 1                                                        75800019
         LA    WKREG1,UCBCCW2(UCBEXT)  SET POINTER TO READ CCW WITHIN   75900019
*                                      EXTENSION                        76000019
         CLR   CCWREG,WKREG1           CURRENT CCW READ CCW             76100019
         BNE   ERR127                  BR NO                            76200019
         MVC   IOBCSW+1(3,IOBREG),CSWADD(UCBEXT) RESTORE ORIGINAL CSW   76300019
*                                      ADDRESS                          76400019
ERR127   NC    IOBCSW+4(2,IOBREG),CSWMASK  CLEAR ABNORMAL CSW BITS      76500019
ERR128   MVI   IOBFLAG3(IOBREG),ZERO   CLEAR IOB ENTRY, LOGOUT, AND     76600019
*                                      MSG BITS AND ERROR COUNTS        76700019
         LA    WKREG3,STATUP           GET LOAD NAME TO STATISTICS      76800019
*                                      UPDATE                           76900019
         L     RETREG,VECTXL(CVTREG)   GET ADDRESS XCTL ROUTINE         77000019
         BR    RETREG                  XCTL TO STATISTICS UPDATE RTN    77100019
         EJECT                                                          77200019
*        CLEAR ERPIB ON CHANNEL CONTROL CHECK, INTERFACE CONTROL        77300019
*        CHECK, DATA CHAINING, MIXED CHAINING, OR UNRECOVERABLE         77400019
*        INTERCEPT CONDITION                                            77500019
         SPACE 2                                                        77600019
ERR130   TM    IOBCSW+5(IOBREG),CCCICC  CHANNEL CONTROL CHECK OR        77700019
*                                      INTERFACE CONTROL CHECK          77800019
         BZ    ERR055                  BR NO                            77900019
         L     LOGRCREG,CVTDCB(CVTREG) LOAD ADDR LOGREC DCB             78000019
         L     WKREG1,0(LOGRCREG)      LOAD PARAMETER TABLE ADDRESS     78100019
         L     WKREG2,0(WKREG1)        LOAD ERPIB TABLE ADDRESS         78200019
*                                                                       78300019
ERR132   TM    0(WKREG2),LASTERIB      LAST TABLE ENTRY                 78400019
         BO    ERR055                  BR - YES                         78500019
         CL    UCBREG,0(WKREG2)        SAME UCB ADDRESS                 78600019
         BE    ERR135                  BR - YES                         78700019
         LA    WKREG2,8(WKREG2)        INCREMENT TO NEXT ERPIB          78800019
         B     ERR132                  BR TO LOOP                       78900019
ERR135   XC    0(8,WKREG2),0(WKREG2)   CLEAR ERPIB                      79000019
ERR140   B     ERR060                  BR TO PERMANENT ERROR PROC       79100019
         SPACE 4                                                        79200019
*        INTERCEPT CONDITION --- IF INTERVENTION REQUIRED IS ON,        79300019
*        HANDLE IT NORMALLY.  OTHERWISE, UNRECOVERABLE INTERCEPT        79400019
         SPACE 2                                                        79500019
ERR150   TM    IOBCSW+4(IOBREG),CSWUCK     UNIT CHECK ?                 79600019
         BZ    ERR130                      BRANCH IF NO                 79700019
         CLI   IOBSENS0(IOBREG),INTREQ     INT. REQ. ?                  79800019
         BNE   ERR130                      BRANCH IF NO                 79900019
         MVI   IOBECBCC(IOBREG),ERRORECB   RESET ECB CODE TO '7F'       80000019
         NI    IOBFLAG1(IOBREG),X'FF'-IOBSRS   RESET RESTART FLAG       80100019
         B     ERR066                      BRANCH TO NORMAL INT REQ RTN 80200019
         EJECT                                                          80300019
*        CONSTANTS                                                      80400019
         SPACE 1                                                        80500019
CCWLNG   DC    H'8'                    CCW LENGTH                       80600019
STALNG   DC    H'10'                   STATISTICS TABLE ENTRY LENGTH    80700019
BACKCNT  DC    H'1'                    BACKSPACE COUNT                  80800019
CSWMASK  DC    X'FDC0'                 CSW ABNORMAL INDICATOR           80900019
*                                        RESET MASK                     81000019
         END                                                            81100019
