         TITLE 'IGE0011D - 1288 OPTICAL CHARACTER READER ERP'           00100019
IGE0011D CSECT                    ENTRY POINT FOR 1288 ERP     @SA65621 00150021
*********************************************************************** 00200019
*MODULE-NAME                                                   @SA65621 00210021
* IGE0011D                                                     @SA65621 00220021
*                                                              @SA65621 00222021
*DESCRIPTIVE-NAME                                              @SA65621 00224021
* OCR ERP FOR 1288 DEVICE                                      @SA65621 00226021
*                                                              @SA65621 00228021
*COPYRIGHT                                                     @SA65621 00228421
* NONE                                                         @SA65621 00228821
*                                                              @SA65621 00229221
*CHANGE-ACTIVITY                                               @SA65621 00229621
* RELEASE 20 ADDITIONS/CHANGES/DELETIONS                                00230020
*C503000                                                         A33926 00260020
*D360000                                                         A33936 00270001
*C482000,533000                                                  A33936 00280001
*                                                                       00285021
* RELEASE 21 ADDITIONS/CHANGES/DELETIONS                                00290021
*C17600,180000                                                    21797 00295021
*C379000-382000                                                  A39680 00297021
*                                                                       00297621
*D006000                                                                00298221
* RELEASE 21.7 ADDITIONS / CHANGES /DELETIONS                           00298821
*C379000-382000                                                  A39692 00299421
*                                                                     * 00300019
*TITLE 'IGE0011D' - 1288 ERROR RECOVERY PROCEDURES                    * 00400019
*                                                                     * 00500019
*STATUS RELEASE 21.7 CHANGE LEVEL 000                                 * 00600021
*                                                                     * 00700019
*FUNCTION/OPERATION   IGE0011D IS SCHEDULED FOR EXECUTION WHENEVER THE* 00800019
*   I/O SUPERVISOR DETECTS AN ERROR ASSOCIATED WITH THE 1288 OPTICAL  * 00900019
*   CHARACTER READER THAT REQUIRES ERROR RECOVERY PROCEDURES.         * 01000019
*                                                                     * 01100019
*                                                                     * 01200019
*   THE ERROR ROUTINE USES THE STANDARD ERROR INTERPRETER ROUTINE FOR * 01300019
*   TESTING OF SENSE BITS AND CSW STATUS BITS. THE FOLLOWING ACTIONS  * 01400019
*   ARE TAKEN DEPENDING UPON THE NATURE OF THE ERROR                  * 01500019
*                                                                     * 01600019
*   1)  NORMAL CONDITION OR SUCCESSFUL RETRY OF RECOVERABLE ERROR     * 01700019
*       CONDITION                                                     * 01800019
*                                                                     * 01900019
*       IOB EXCEPTION AND ERROR FLAGS ARE CLEARED AND CONTROL IS      * 02000019
*       TRANSFERRED TO THE STATISTICS UPDATE ROUTINE.                 * 02100019
*   2)  RECOVERABLE ERROR                                             * 02200019
*                                                                     * 02300019
*       IOB ERROR FLAG IS SET.                                        * 02400019
*       IOB EXCEPTION FLAG IS CLEARED.                                * 02500019
*       ERROR COUNTS ARE UPDATED.                                     * 02600019
*       CONTROL IS PASSED TO THE I/O SUPERVISOR VIA SVC 15 AND SVC 3  * 02700019
*       TO RETRY THE CHANNEL PROGRAM.                                 * 02800019
*                                                                     * 02900019
*   3)  PERMANENT ERROR                                               * 03000019
*       IOB ERROR AND EXCEPTION FLAGS ARE SET.                        * 03100019
*       IOB MESSAGE AND LOGOUT FLAGS MAY BE SET.                      * 03200019
*       CONTROL IS RETURNED TO THE I/O SUPERVISOR EITHER DIRECTLY     * 03300019
*       THROUGH ISSUANCE OF AN SVC 15 AND AN SVC 3 OR INDIRECTLY BY   * 03400019
*       FIRST PASSING CONTROL TO THE WTO ROUTINE WHICH IN TURN PASSES * 03500019
*       CONTROL TO THE STATISTICS UPDATE ROUTINE AND THE I/O OUTBOARD * 03600019
*       RECORDING ROUTINE, IF REQUIRED, AND EVENTUALLY TO THE I/O     * 03700019
*       SUPERVISOR.                                                   * 03800019
*                                                                     * 03900019
*ENTRY POINTS                                                         * 04000019
*       IGE0011D - ERROR RECOVERY PROCEDURE ENTRY POINT               * 04100019
*                                                                     * 04200019
*       DATA PASSED TO THE ROUTINE CONSISTS OF STANDARD SYSTEM CONTROL* 04300019
*       BLOCKS.                                                       * 04400019
*                                                                     * 04500019
*INPUT  RQE POINTER IN REGISTER 1.                                    * 04600019
*                                                                     * 04700019
*OUTPUT I/O ERROR AND INTERVENTION REQUIRED MESSAGES IN SOME INSTANCES* 04800019
*                                                                     * 04900019
*EXTERNAL ROUTINES  ERROR INTERPRETER ROUTINE                         * 05000019
*                                                                     * 05100019
*EXITS-NORMAL  XCTL TO STATISTICS UPDATE ROUTINE FOLLOWING SUCCESSFUL * 05200019
*       RECOVERY OF A RETRYABLE ERROR OR UPON DETECTION OF A NORMAL   * 05300019
*       CONDITION.                                                    * 05400019
*                                                                     * 05500019
*     -ERROR                                                          * 05600019
*                                                                     * 05700019
*   1)  SVC 15 AND SVC 3 EXIT TO I/O SUPERVISOR FOR RE-EXECUTION OF   * 05800019
*       THE CHANNEL PROGRAM UPON DETECTION OF A RETRYABLE ERROR.      * 05900019
*                                                                     * 06000019
*   2)  XCTL TO WTO ROUTINE FOR ISSUANCE OF A PERMANENT I/O ERROR     * 06100019
*       MESSAGE AND UPDATING OF STATISTICS AND SYS1.LOGREC IN THE CASE* 06200019
*       OF SOME PERMANENT ERRORS.                                     * 06300019
*                                                                     * 06400019
*   3)  SVC 15 AND SVC 3 EXIT TO I/O SUPERVISOR IN THE CASE OF SOME   * 06500019
*       PERMANENT I/O ERRORS.                                         * 06600019
*                                                                     * 06700019
*TABLES/WORK AREAS                                                    * 06800019
*   1)  INPUT/OUTPUT BLOCK (IOB)                                      * 06900019
*                                                                     * 07000019
*   2)  UNIT CONTROL BLOCK (UCB)                                      * 07100019
*                                                                     * 07200019
*   3)  UCB EXTENSION                                                 * 07300019
*                                                                     * 07400019
*   4)  STATISTICS UPDATE TABLE                                       * 07500019
*                                                                     * 07600019
*ATTRIBUTES                                                           * 07700019
*                                                                     * 07800019
*       RE-USABLE, SUPERVISOR MODE                                    * 07900019
*                                                                     * 08000019
*NOTES                                                                * 08100019
*                                                                     * 08200019
*       N/A                                                           * 08300019
*                                                                     * 08400019
*                                                                     * 08500019
*********************************************************************** 08600019
*********************************************************************** 08700019
*                                                                     * 08800019
*        IOB DEFINITION                                               * 08900019
*                                                                     * 09000019
*********************************************************************** 09100019
IOBFL1   EQU   0                  FLAGS 1                               09200019
IOBSNS   EQU   2                  SENSE DATA                            09300019
IOBCOD   EQU   4                  ECB CODE                              09400019
IOBFL3   EQU   8                  FLAGS 3                               09500019
IOBCSW   EQU   8                  CSW STORAGE                           09600019
STATUS1  EQU   4                  FIRST BYTE OF CSW STATUS              09700019
STATUS2  EQU   5                  SECOND BYTE OF CSW STATUS             09800019
SIOCC    EQU   16                 DISPLACEMENT TO SIO CONDITION CODE    09900019
IOBST    EQU   17                 START ADDRESS                         10000019
IOBRST   EQU   25                 RESTART POINTER                       10100019
IOBBCI   EQU   28                 BLOCK COUNT INCR.                     10200019
IOBECT   EQU   30                 ERROR COUNTS                          10300019
*********************************************************************** 10400019
*                                                                     * 10500019
*        IOB FLAG 1 DEFINITION                                        * 10600019
*                                                                     * 10700019
*********************************************************************** 10800019
IOBCP2   EQU   X'40'              TYPE OF CHANNEL PROGRAM               10900019
IOBERR   EQU   X'20'              IOB ERROR FLAG                        11000019
IOBCER   EQU   X'DF'              CLEAR IOBERR FLAG                     11100019
IOBEX    EQU   X'04'              EXCEPT FLAG                           11200019
IOBSRS   EQU   X'01'              START/RESTART FLAG                    11300019
IOBCEX   EQU   X'FF'-IOBEX        CLEAR IOB EXCEPTION                   11400019
IOBEXE   EQU   IOBEX+IOBERR       FX + ERR FLAGS                        11500019
*********************************************************************** 11600019
*                                                                     * 11700019
*        IOB FLAG 3 DEFINITION                                        * 11800019
*                                                                     * 11900019
*********************************************************************** 12000019
IOBPRT   EQU   X'08'              PUNCH RETRY BIT                       12100019
IOBMSG   EQU   X'04'              MESSAGE TYPE                          12200019
IOBPR2   EQU   X'02'              QSAM PUNCH RETRY BIT                  12300019
IOBLOG   EQU   X'01'              LOGOUT FLAG                           12400019
*********************************************************************** 12500019
*                                                                     * 12600019
*        UCB DEFINITION                                               * 12700019
*                                                                     * 12800019
*********************************************************************** 12900019
UCBSTI   EQU   9                  STATISTICS POINTER                    13000019
UCBERRCT EQU   24                 DISPLACEMENT TO UCB ERROR COUNTER ADR 13100019
*********************************************************************** 13200019
*                                                                     * 13300019
*        TWELVE STAR DEFINITION                                       * 13400019
*                                                                     * 13500019
*********************************************************************** 13600019
RQEUCB   EQU   2                  DISPLACEMENT TO UCB ADDRESS           13700019
RQEIOB   EQU   5                  DISPLACEMENT TO IOB ADDRESS           13800019
*********************************************************************** 13900019
*                                                                     * 14000019
*        STATUS INDICATORS                                            * 14100019
*                                                                     * 14200019
*********************************************************************** 14300019
CSWUCK   EQU   X'02'              UNIT CHECK                            14400019
*********************************************************************** 14500019
*                                                                     * 14600019
*        REGISTER DEFINITION                                          * 14700019
*                                                                     * 14800019
*********************************************************************** 14900019
RQEREG   EQU   1                  RQE POINTER                           15000019
CCWREG   EQU   2                  CCW ADDRESS REGISTER                  15100019
ERREG    EQU   4                  WORK REGISTER                         15200019
WKREG3   EQU   4                  WORK REGISTER                         15300019
WKRG1    EQU   5                  WORK REGISTER                         15400019
WKREG1   EQU   5                  WORK REGISTER                         15500019
WKREG2   EQU   6                  WORK REGISTER                         15600019
WKRG2    EQU   6                  WORK REGISTER                         15700019
UCBREG   EQU   7                  UCB ADDRESS REG                       15800019
COMREG   EQU   8                  COMMUNICATION TABLE REG               15900019
SVREG    EQU   9                  WORK REGISTER                         16000019
WKREG4   EQU   9                  WORK REGISTER                         16100019
IOBREG   EQU   10                 IOB ADDRESS REGISTER                  16200019
LINKR    EQU   12                 WORK REGISTER                         16300019
ERRLNK   EQU   12                 LINK REG                              16400019
ERRE1    EQU   13                 WORK REGISTER                         16500019
ERRETR   EQU   14                 RETURN REG                            16600019
BASREG   EQU   15                 BASE REGISTER                         16700019
*********************************************************************** 16800019
*                                                                     * 16900019
*        RETRY COUNTS                                                 * 17000019
*                                                                     * 17100019
*********************************************************************** 17200019
BOCOUNT  EQU   X'08'              TEST FOR BUS OUT CHECK RETRIED        17300019
CDCCNT   EQU   X'80'              TEST FOR CHANNEL DATA CHECK RETRIED   17400019
CCCNT    EQU   5                  TEST FOR CHAINING CHECK RETRISE       17500019
EQCNT    EQU   X'03'              TEST FOR EQUIPMENT CHECK RETRY  21797 17600021
DCCOUNT1 EQU   X'03'              DOCUMENT DATA CHECK RETRY COUNT       17700019
INCCOUNT EQU   16                 INCREMENT FOR OVERRUN RETRY COUNT     17800019
ORCOUNT  EQU   X'50'              OVERRUN RETRY COUNT (FIVE)            17900019
ILCOUNT  EQU   X'03'              INCORRECT LENGTH RETRY COUNT    21797 18000021
*********************************************************************** 18100019
*                                                                     * 18200019
*        MISCELLANEOUS DEFINITIONS                                    * 18300019
*                                                                     * 18400019
*********************************************************************** 18500019
VEXCTL   EQU   44                 ADDR OF XCTL ROUTINE                  18600019
STAUPRTN EQU   254                STATISTICS UPDATE ROUTINE             18700019
CVTADDR  EQU   16                 POINTER TO CVT ADDRESS                18800019
BYTECNT  EQU   6                  DISPLACMENT TO BYTE COUNT IN CCW      18900019
INTERCPT EQU   X'7E'              TEST FOR INTERCEPT CONDITION          19000019
STABINC  EQU   256                INCREMENT TO NEXT STATAB SECTION      19100019
ENTDISP  EQU   2                  CONTROL ENTRY DISPLACEMENT            19200019
CLRCNT   EQU   X'03'              BYTE COUNT FOR CLEARING COUNTERS      19300019
CHINTCHK EQU   X'06'              TEST FOR CHANNEL OR INTERFACE CHECK   19400019
MIXCHAIN EQU   X'C0'              TEST FOR MIXED CHAINING               19500019
SNSDISP  EQU   8                  STATAB SENSE DISPLACEMENT             19600019
SNSLEN   EQU   2                  LENGTH OF SENSE BYTES TO PUT IN STATA 19700019
EOPDISP  EQU   9                  DISPLACEMENT TO END OF PAGE BIT       19800019
EOP      EQU   X'40'              TEST FOR END OF PAGE                  19900019
NODOC    EQU   X'20'              TEST FOR NO DOCUMENT FOUND            20000019
INVSNS   EQU   X'97'              TEST FOR INVALID SENSE BITS           20100019
INVSNS1  EQU   X'01'              TEST FOR INVALID SENSE BIT            20200019
CLEARCNT EQU   X'02'              COUNT OF ERROR COUNTER BYTES TO CLEAR 20300019
ERRORSVC EQU   15                 ERROR EXCP                            20400019
RETSVC   EQU   3                  RETURN TO IOS SVC                     20500019
CCLENGTH EQU   1                  LENGTH OF CCW COMMAND CODE            20600019
CLEARHI  EQU   X'0F'              CLEAR FOUR BITS OF A BYTE             20700019
RBTEST   EQU   X'0C'              TEST FOR READ BACKWARD COMMAND        20800019
BITS56   EQU   X'03'              CLEAR BITS 5 AND 6 OF A BYTE          20900019
RFTEST   EQU   X'02'              TSET FOR READ FORWARD COMMAND         21000019
VEX116   EQU   116                ERPIB LOCATION                        21100019
EPDT     EQU   2                  DISPLACEMENT TO ERPIB DEVICE TYPE     21200019
ERPIBLEN EQU   8                  ERPIB LENGTH                          21300019
DC       EQU   0                  DISPLACEMENT TO DATA CHECK COUNTS     21400019
ILC      EQU   1                  DISPLACEMENT TO INCORRECT LENGTH CNTS 21500019
EC       EQU   2                  DISPLACEMENT TO EQUIPMENT CHECK CNTS  21600019
EOT      EQU   X'FF'              TEST FOR END OF ERPIB TABLE           21700019
ZEROCNT  EQU   X'0F'              TEST FOR FIRST RETRY, INC LENGTH      21800019
IOSTUS   EQU   X'10'              STATUS BIT                            21900019
VFCT68   EQU   68                 INDEX TO INTERPRETER ROUTINE          22000019
STATAB   EQU   112                INDEX TO STATISTICS TABLE             22100019
WTORTN   EQU   253                LOAD NAME TO WTO RTN.                 22200019
PERMERR  EQU   X'41'              ECB CODE FOR PERM ERROR      @SA65613 22250021
ADDRLN   EQU   3                  LENGTH OF CCW ADDRESS        @SA65613 22300021
         USING *,BASREG                                                 25500019
ERR0011  L     IOBREG,RQEIOB-1(RQEREG) GET IOB ADDRESS                  25600019
         LH    UCBREG,RQEUCB(RQEREG) GET UCB ADDRESS                    25700019
         L     COMREG,CVTADDR     GET CVT ADDRESS                       25800019
         TM    IOBFL1(IOBREG),IOBERR ERP IN CONTROL                     25900019
         BO    ERR000             YES CONTINUE                          26000019
* CLEAR IOB ERROR COUNTERS                                              26050019
         XC    IOBBCI(CLRCNT,IOBREG),IOBBCI(IOBREG) CLEAR COUNTERS      26100019
ERR000   CLI   IOBCOD(IOBREG),INTERCPT IS IT AN INTERCEPT CONDITION     26200019
         BE    ERR0012            YES SEE IF CHANNEL ERROR              26300019
         CLI   IOBCOD(IOBREG),PERMERR CHECK FOR X'41' IN ECB   @SA65613 26350021
         BNE   ERR001A            NO, CONTINUE                 @SA65613 26360021
         CLC   IOBCSW+1(ADDRLN,IOBREG),WKAREA IS CCW ADDR OK?  @SA65613 26370021
         BE    ERR007             NO, PERMANENT ERROR          @SA65613 26380021
ERR001A  TM    IOBFL1(IOBREG),MIXCHAIN IS IT MIXED CHAINING    @SA65613 26400021
         BO    ERR0012            YES SEE IF CHANNEL ERROR              26500019
         TM    SIOCC(IOBREG),IOSTUS CODE EQUAL 10                       26600019
         BZ    ERR002             NO CONTINUE                           26700019
         L     CCWREG,IOBRST-1(IOBREG) GET RESTART ADDRESS              26800019
         TM    IOBFL1(IOBREG),IOBSRS RESTART FLAG ON                    26900019
         BO    ERR003             YES RESTART ADDRESS IS USED           27000019
         L     CCWREG,IOBST-1(IOBREG) GET START ADDRESS                 27100019
         B     ERR003             CONTINUE                              27200019
ERR0012  TM    IOBCSW+STATUS2(IOBREG),CHINTCHK CHANNEL OR INTERFACE CHK 27300019
         BZ    ERR007             NO EXIT TO WTO ROUTINE                27400019
         B     ERR010             YES TO CHANNEL+INTERFACE CHK RTN      27500019
ERR002   L     CCWREG,IOBCSW(IOBREG) GET CCW ADDRESS                    27600019
         LA    CCWREG,0(CCWREG)   CLEAR HIGH ORDER BYTE                 27700019
         SH    CCWREG,ERRON1      BACK UP ONE CCW                       27800019
         TM    IOBFL1(IOBREG),IOBCP2 IS COMMAND CHAINING USED           27900019
         BZ    ERR003             NO SET UP FOR WTO                     28000019
         TM    IOBFL1(IOBREG),IOBERR ENTERED AFTER RETRY                28100019
         BZ    ERR002A            NO CONTINUE                           28200019
         LR    ERREG,CCWREG       GET CCW ADDR IN WORK REGISTER         28300019
         S     ERREG,IOBRST-1(IOBREG)  SUBTRACT RESATART ADDRESS        28400019
         BE    ERR003             IF EQUAL ERROR                        28500019
         LA    WKREG1,IOBBCI(IOBREG) POINT TO IOB ERROR COUNTERS        28600019
         L     WKREG2,UCBERRCT(UCBREG) POINT TO UCB ERROR COUNTERS      28700019
         MVI   CLEAR1+1,CLEARCNT  SET COUNT TO CLEAR                    28800019
         BAL   LINKR,ERR018       LINK TO COUNTER UPDATE ROUTINE        28900019
ERR002A  OI    IOBFL1(IOBREG),IOBSRS SET RESTART FLAG ON                29000019
         ST    CCWREG,IOBRST-1(IOBREG) SAVE CCW RESTART ADDRESS         29100019
ERR003   TM    IOBCSW+STATUS1(IOBREG),CSWUCK IS UNIT CHECK POSTED       29200019
         BZ    ERR004             NO DETERMINE ERROR TYPE               29300019
         L     ERREG,STATAB(COMREG) GET STATISTICS TABLE ADDRESS        29400019
         SR    WKREG1,WKREG1      CLEAR WORK REGISTER                   29500019
         IC    WKRG1,UCBSTI(UCBREG) GET STATAB POINTER FROM UCB         29600019
         LR    WKRG2,ERREG        GET STATISTICS TABLE START ADDRESS    29700019
ERR003A  CH    UCBREG,0(0,WKRG2)  DEVICE SUPPORTED BY THIS SECTION      29800019
         BC    4,ERR003B          YES PROCESS THIS SECTIOB              29900019
         LA    WKRG2,ENTDISP(WKRG2) BUMP TO NEXT CONTROL ENTRY          30000019
         LA    WKRG1,STABINC(0,WKRG1) POINT AT NEXT STATAB ENTRY        30100019
         B     ERR003A            LOOP TO TEST NEXT SECTION             30200019
ERR003B  MH    WKRG1,TEN          MULTIPLY STATAB POINTET BY TEN        30300019
         AR    ERREG,WKRG1        ADD TO STATAB START ADDRESS           30400019
         OC    SNSDISP(SNSLEN,ERREG),IOBSNS(IOBREG) OR SENSE BYTES IN T 30500019
         NC    SNSDISP(SNSLEN,ERREG),MASKOUT GET RID OF UNWANTED BITS   30600019
         NI    EOPDISP(ERREG),EOP CLEAR POSSIBLE END OF PAGE            30700019
ERR004   LR    SVREG,BASREG       SAVE BASE REGISTER                    30800019
         L     BASREG,VFCT68(COMREG) GET INTERPRETER ROUTINE ADDRESS    30900019
ERR0041  BALR  ERRLNK,BASREG      LINK TO INTERPRETER                   31000019
         DC    X'1D'              TEST FOR CHANNEL CONTROL CHECK        31100019
         DC    AL1(ERR010L-ERR0041-2) BRANCH TO CCC ACTION              31200019
         DC    X'1E'              TEST FOR INTERFACE CONTROL CHECK      31300019
         DC    AL1(ERR010L-ERR0041-4) BRANCH TO ICC ACTION              31400019
         DC    X'1C'              TEST FOR CHANNEL DATA CHECK           31500019
         DC    AL1(ERR200L-ERR0041-6) BRANCH TO CDC ACTION              31600019
         DC    X'10'              TEST FOR ATTENTION                    31700019
         DC    AL1(ERR007-ERR0041-8) BRANCH TO ATTENTION ACTION         31800019
         DC    X'12'              TEST FOR CONTROL UNIT END             31900019
         DC    AL1(ERR007-ERR0041-10) BRANCH TO CUE ACTION              32000019
         DC    X'16'              TEST FOR UNIT CHECK                   32100019
         DC    AL1(ERR006-ERR0041-12) BRANCH TO UNIT CHECK ACTION       32200019
         DC    X'2F'              END OF LIST                           32300019
         DC    AL1(ERR004B-ERR0041-14)  PASS CONTROL TO ERR004B         32400019
* FOLLOWING BRANCHES GO TO ROUTINES MORE THAN 128 BYTES AWAY            32450019
ERR010L  B     ERR010             GO TO ERR010                          32500019
ERR200L  B     ERR200             GO TO CDC ROUTINE                     32600019
ERR004B  LR    SVREG,BASREG       SAVE BASE REGISTER                    32800019
         L     BASREG,VFCT68(COMREG) GET INTERPRETER ROUTINE ADDRESS    32900019
ERR004B1 BALR  ERRLNK,BASREG      LINK TO INTERPRETER                   33000019
         DC    X'1F'              TEST FOR CHAINING CHECK               33100019
         DC    AL1(ERR011L-ERR004B1-2) BRANCH TO CC ACTION              33200019
         DC    X'1A'              TEST FOR PROGRAM CHECK                33300019
         DC    AL1(ERR007A-ERR004B1-4) BRANCH TO PC ACTION              33400019
         DC    X'1B'              TEST FOR PROTECTION CHECK             33500019
         DC    AL1(ERR007A-ERR004B1-6) BRANCH TO PC ACTION              33600019
         DC    X'19'              TEST FOR INCORRECT LENGTH             33700019
         DC    AL1(ERR017L-ERR004B1-8) BRANCH TO IL ACTION              33800019
         DC    X'17'              CHECK FOR UNIT EXCEPTION              33900019
         DC    AL1(ERR013L-ERR004B1-10) BRANCH TO UE ACTION             34000019
         DC    X'2F'              END OF LIST                           34100019
         DC    AL1(ERR004B2-ERR004B1-12) PASS CONTROL TO ERR004B2       34200019
* THESE BRANCHS GO TO ROUTINES MORE THAN 128 BYTES AWAY                 34250019
ERR011L  B     ERR011             GO TO CC ACTION                       34300019
ERR017L  B     ERR017             GO TO IL ACTION                       34400019
ERR013L  B     ERR013             GO TO UE-ACTION                       34500019
ERR004B2 TM    IOBCSW+STATUS1(IOBREG),CSWUCK IS UNIT CHECK POSTED       34700019
         BZ    ERR005             NO TO STATISTICS UPDATE ROUTINE       34900019
ERR004C  TM    IOBSNS+1(IOBREG),EOP IS IR END OF PAGE                   35000019
         BO    ERR008             YES EXIT TO IOS                       35200019
ERR004D  TM    IOBSNS+1(IOBREG),NODOC IS NO DOCUMENT FOUND POSTED       35600019
         BO    ERR005B            YES CLEAN UP                          35700019
ERR005   NI    IOBFL1(IOBREG),IOBCEX CLEAR IOB EXCEPTION, ERROR CORRECT 35800019
         B     ERR005B            CONTINUE CLEAN UP                     35900019
ERR005B  NI    IOBFL1(IOBREG),IOBCER CLEAR IOBERR                       36100019
         LA    ERRE1,STAUPRTN     LOAD NAME OF STATISTICS UPDATE RTN    36200019
ERR005C  L     WKREG1,UCBERRCT(UCBREG) POINT TO UCB ERROR COUNTERS      36300019
         LA    WKREG2,IOBBCI(IOBREG) POINT TO IOB ERROR COUNTERS        36400019
         MVI   CLEAR1+1,CLEARCNT  SET COUNT TO CLEAR                    36500019
         BAL   LINKR,ERR018       LINK TO COUNTER UPDATE ROUTINE        36600019
         L     ERRETR,VEXCTL(COMREG) GET ADDRESS OF XCTL ROUTINE        36700019
         BR    ERRETR             EXIT VIA XCTL                         36800019
ERR006   TM    IOBSNS+1(IOBREG),INVSNS ANY INVALID SENSE BITS ON        36900019
         BC    5,ERR007           YES ALL DONE-CLEAN UP                 37000019
ERR006A  TM    IOBSNS(IOBREG),INVSNS1 INVALID SENSE BIT ON              37200019
         BO    ERR007             YES GO CLEAN UP                       37300019
ERR006B  LR    SVREG,BASREG       SAVE BASE ADDRESS                     37400019
         L     BASREG,VFCT68(COMREG) GET INTERPRETER ROUTINE ADDRESS    37500019
ERR006C  BALR  ERRLNK,BASREG      LINK TO INTERPRETER ROUTINE           37600019
         DC    X'03'              TEST FOR EQUIPMENT CHECK              37700019
         DC    AL1(ERR012L-ERR006C-2) BRANCH TO EC ROUTINE              37800021
         DC    X'06'                   TEST FOR NONRECOVERY      A39692 37900021
         DC    AL1(ERR007-ERR006C-4)   BRANCH TO NONREC ROUTINE  A39692 38000021
         DC    X'01'              TEST FOR INTERVENTION REQUIRED A39692 38100021
         DC    AL1(ERR006D-ERR006C-6)  BRANCH TO IR ROUTINE      A39692 38200021
         DC    X'02'              TEST FOR BUS OUT CHECK                38300019
         DC    AL1(ERR015L-ERR006C-8) BRANCH TO BUS OUT CHECK ROUTINE   38400019
         DC    X'04'              TEST FOR DATA CHECK                   38500019
         DC    AL1(ERR014L-ERR006C-10) BRANCH TO DATA CHECK ROUTINE     38600019
         DC    X'05'              TEST FOR OVERRUN                      38700019
         DC    AL1(ERR016L-ERR006C-12) BRANCH TO OVERRUN ROUTINE        38800019
         DC    X'00'              TEST FOR COMMAND REJECT               38900019
         DC    AL1(ERR007A-ERR006C-14) BRANCH TO COMMAND REJECT ROUTINE 39000019
         DC    X'0C'              TEST FOR INVALID OPERATION            39100019
         DC    AL1(ERR007-ERR006C-16)  BRANCH TO INVALID OPERATION RTN  39200019
         DC    X'2F'              END OF LIST                           39300019
         DC    AL1(ERR004BL-ERR006C-18) CONTINUE CHECKING FOR ERRORS    39400019
ERR012L  B     ERR012             GO TO EC ACTION                       39500019
ERR015L  B     ERR015             GO TO BUS OUT ACTION                  39600019
ERR014L  B     ERR014             GO TO DATA CHECK ACTION               39700019
ERR016L  B     ERR016             GO TO OVERRUN ACTION                  39800019
ERR004BL B     ERR004B            CONTINUE ERROR CHECKING               39900019
ERR006D  OI    IOBFL1(IOBREG),IOBERR SET IOBERR ON                      40000019
         B     ERR007B            GO WRITE TO OPERATOR                  40100019
* EXIT TO WTO ROUTINE                                                   40200019
ERR007   OI    IOBFL3(IOBREG),IOBLOG SET LOGOUT FLAG                    40300019
ERR007A  OI    IOBFL3(IOBREG),IOBMSG SET MESSAGE FLAG                   40400019
         NI    IOBFL1(IOBREG),IOBCER CLEAR IOBERR FLAG                  40500019
ERR007B  LA    ERRE1,WTORTN       LOAD NAME OF WTO ROUTINE              40600019
         B     ERR005C            GET OUT VIA XCTL                      40700019
ERR008   NI    IOBFL1(IOBREG),IOBCER CLEAR IOBERR FLAG                  40800019
         L     WKREG1,UCBERRCT(UCBREG) POINT TO UCB ERROR COUNTERS      40900019
         LA    WKREG2,IOBBCI(IOBREG) POINT TO IOB ERROR COUNTERS        41000019
         MVI   CLEAR1+1,CLEARCNT  SET COUNT TO CLEAR                    41100019
         BAL   LINKR,ERR018       LINK TO COUNTER UPDATE ROUTINE        41200019
         SVC   ERRORSVC           ISSUE ERROR EXCP                      41300019
         SVC   RETSVC             RETURN TO IOS VIA SVC 3               41400019
* UPDATE UCB ERROR COUNTERS ROUTINE                                     41500019
ERR018   SR    WKREG3,WKREG3      ZERO OUT                              41600019
         SR    WKREG4,WKREG4      WORK REGISTERS                        41700019
         IC    WKREG3,DC(WKREG1)  GET DATA                              41800019
         IC    WKREG4,DC(WKREG2)  CHECK COUNTS                          41900019
         AR    WKREG3,WKREG4      ADD COUNTS                            42000019
         STC   WKREG3,DC(WKREG2)  UPDATE DATA CHECK COUNT               42100019
         IC    WKREG3,ILC(WKREG1) GET INCORRECT                         42200019
         IC    WKREG4,ILC(WKREG2) LENGTH COUNTS                         42300019
         AR    WKREG3,WKREG4      ADD COUNTS                            42400019
         STC   WKREG3,ILC(WKREG2) UPDATE INCORRECT LENGTH COUNT         42500019
         IC    WKREG3,EC(WKREG1)  GET EQUIPMENT CHECK                   42600019
         IC    WKREG4,EC(WKREG2)  CHECK COUNTS                          42700019
         AR    WKREG3,WKREG4      ADD COUNTS                            42800019
         STC   WKREG3,EC(WKREG2)  UPDATE EQUIPMENT CHECK COUNT          42900019
CLEAR1   XC    0(0,WKREG1),0(WKREG1) CLEAR ERROR COUNTERS               43000019
         BR    LINKR              RETURN TO CALLER                      43100019
* CHANNLE DATA CHECK ROUTINE                                            43200019
ERR200   TM    IOBFL3(IOBREG),CDCCNT CHANNEL DAYA CHECK ALREADY RETRIED 43300019
         BO    ERR007             YES EXIT TO WTO ROUTINE               43400019
         OI    IOBFL3(IOBREG),CDCCNT SET TO INDICATE RETRIED            43500019
* RETRY ROUTINE                                                         43600019
ERR009   MVC   WKAREA(CCLENGTH),0(CCWREG) GET CCW COMMAND CODE          43700019
         NI    WKAREA,CLEARHI     CLEAR HIGH ORDER FOUR BITS            43800019
         CLI   WKAREA,RBTEST      IS COMMAND READ BACKWARD              43900019
         BE    ERR009B            YES CLEAR INPUT AREA & RETRY          44000019
         NI    WKAREA,BITS56      CLEAR BITS 5 & 6                      44100019
         CLI   WKAREA,RFTEST      IS COMMAND READ FORWARD               44200019
         BE    ERR009B            YES CLEAR INPUT AREA & RETRY          44300019
ERR009A  OI    IOBFL1(IOBREG),IOBERR SET IOBERR ON                      44400019
         XC    IOBSNS(SNSLEN,IOBREG),IOBSNS(IOBREG)               M0381 44450021
         SVC   ERRORSVC           RETRY CCW                             44500019
         SVC   RETSVC             RETURN TO IOS VIA SVC 3               44600019
* CLEAR INPUT AREA                                                      44700019
ERR009B  L     WKREG2,0(CCWREG)   GET INPUT AREA ADDRESS FROM CCW       44800019
         LA    WKREG2,0(WKREG2)   CLEAR OUT COMMAND CODE                44900019
         LH    WKREG3,BYTECNT(CCWREG) GET BYTE COUNT                    45000019
         BCTR  WKREG3,0           DECREMENT COUNT BY ONE                45100019
         CLI   WKAREA,RFTEST      IS COMMAND READ FORWARD               45200019
         BE    ERR009C            YES ADDRESS NOW CORRECT               45300019
         SR    WKREG2,WKREG3      ADJUST ADDRESS TO PROPER VALUE        45400019
ERR009C  STC   WKREG3,ERR009D+1   STORE COUNT TO CLEAR                  45500019
ERR009D  XC    0(0,WKREG2),0(WKREG2) CLEAR INPUT AREA                   45600019
         B     ERR009A            RETRY BAD CCW                         45700019
* CHANNEL CHECK ROUTINE                                                 45800019
ERR010   L     WKREG1,VEX116(COMREG) GET PTR TO PTR TO PTR TO ERPIB     45900019
         L     WKREG1,0(WKREG1)   GET PTR TO PTR TO ERPIB               46000019
         L     WKREG1,0(WKREG1)   GET PTR TO ERPIB                      46100019
ERR010A  CH    UCBREG,EPDT(WKREG1) IS THIS CORRECT ERPIB                46200019
         BE    ERR010B            YES PROCESS IT                        46300019
         LA    WKREG1,ERPIBLEN(WKREG1) BUMP TO NEXT ERPIB               46400019
         TM    0(WKREG1),EOT      IS IT END OF ERPIB TABLE              46500019
         BC    14,ERR010A         NO TEST NEXT ERPIB                    46600019
         BC    1,ERR007           YES TO LOGOUT ROUTINE                 46700019
ERR010B  XC    0(ERPIBLEN,WKREG1),0(WKREG1) CLEAR ERPIB                 46800019
         B     ERR007             GO TO LOGOUT ROUTINE                  46900019
* CHAINING CHECK ROUTINE                                                47000019
ERR011   IC    WKREG1,IOBECT+1(IOBREG) GET CHAINING CHECK COUNT         47100019
         LA    WKREG1,1(WKREG1)   INCREMENT COUNT                       47200019
         STC   WKREG1,IOBECT+1(IOBREG) UPDATE COUNT                     47300019
         TM    IOBECT+1(IOBREG),CCCNT IS COUNT NOW FIVE                 47400019
         BO    ERR007             YES TO LOGOUT                         47500019
         B     ERR009             NO RETRY                              47600019
* EQUIPMENT CHECK                                                       47700019
ERR012   IC    WKREG1,IOBECT(IOBREG) GET EQUIPMENT CHECK COUNT          47800019
         LA    WKREG1,1(WKREG1)   INCREMENT COUNT                       47900019
         STC   WKREG1,IOBECT(IOBREG) UPDATE COUNTER                     48000019
         CLI   IOBECT(IOBREG),EQCNT IS COUNT NOW TEN                    48100019
         BE    ERR008             YES TO IOS                     A33936 48200001
         B     ERR009             NO RETRY                              48300019
* UNIT EXCEPTION                                                        48400019
ERR013   TM    IOBFL1(IOBREG),IOBERR IOBERR ON (ENTERED AFTER RETRY)    48500019
         BZ    ERR005B            NO EXIT TO STATISTICS UPDATE          48600019
ERR013A  NI    IOBFL1(IOBREG),IOBCEX SET IOBEX OFF                      48700019
         B     ERR005B            TO STATISTICS UPDATE ROUTINE          48800019
* DATA CHECK ROUTINE                                                    49600019
ERR014   IC    WKREG1,IOBBCI(IOBREG) GET DATA CHECK ERROR COUNT         49700019
         LA    WKREG1,1(WKREG1)   INCREMENT COUNT                       49800019
         STC   WKREG1,IOBBCI(IOBREG) UPDATE DATA CHECK ERROR COUNT      49900019
         TM    IOBBCI(IOBREG),DCCOUNT1 IS COUNT NOW THREE               50200019
         BO    ERR008             YES TO IOS                     A33926 50300020
         B     ERR009             NO RETRY                              50400019
* BUSOUT CHECK                                                          50500019
ERR015   TM    IOBECT+1(IOBREG),BOCOUNT BUS OUT CHECK COUNT EQUAL ONE   50600019
         BO    ERR007             YES TO WTO ROUTINE                    50700019
         OI    IOBECT+1(IOBREG),BOCOUNT SET COUNT TO ONE                50800019
         B     ERR009             RETRY                                 50900019
* OVERRUN                                                               51000019
ERR016   IC    WKREG1,IOBECT+1(IOBREG) GET OVERRUN ERROR COUNT          51100019
         LA    WKREG1,INCCOUNT(WKREG1) INCREMENT COUNT                  51200019
         STC   WKREG1,IOBECT+1(IOBREG) UPDATE ERROR COUNT               51300019
         TM    IOBECT+1(IOBREG),ORCOUNT DOES COUNT EQUAL FOVE           51400019
         BO    ERR007             YES EXIT TO WTO ROUTINE               51500019
         B     ERR009             NO RETRY                              51600019
* INCORRECT LENGTH                                                      51700019
ERR017   TM    IOBFL1(IOBREG),IOBERR ENTERED AFTER RETRY                51800019
         BZ    ERR017A            NO                                    51900019
         TM    IOBBCI+1(IOBREG),ZEROCNT FIRST TIME HERE                 52000019
         BC    5,ERR017A          NO CONTINUE                           52100019
         NI    IOBFL1(IOBREG),IOBCEX CLEAR IOBEX                        52200019
         B     ERR008             EXIT TO IOS                           52300019
ERR017A  IC    WKREG1,IOBBCI+1(IOBREG) GET INCORRECT LENGTH ERROR COUNT 52400019
         LA    WKREG1,1(WKREG1)   INCREMENT ERROR COUNT                 52500019
         STC   WKREG1,IOBBCI+1(IOBREG) UPDATE COUNTER                   52600019
         CLI   IOBBCI+1(IOBREG),ILCOUNT IS COUNT NOW FIVE               52700019
         BE    ERR008             YES EXIT TO IOS                       52800019
         B     ERR009             NO RETRY                              52900019
         DS    0H                 FORCE HALF WORD ALIGNMENT             53000019
ERRON1   DC    AL2(8)             CONSTANT OF 8                         53100019
TEN      DC    X'000A'            CONSTANT OF 10                        53200019
MASKOUT  DC    X'267F'    MASK FOR CLEARING UNWANTED SENSE DATA  A33936 53300001
WKAREA   DC    XL1'00'            WORK AREA                             53400019
ZERO     DC    XL2'0000'          USED TO CHECK SENSE          @SA65613 53450021
         END   IGE0011D                                                 53500019
