         TITLE '1419 OS ERROR RECOVERY PROCEDURE'                       00200000
         START                                                          00400000
*              1419 ERROR RECOVERY PROCEDURE                            00600000
*                                                                       00800000
*     STATUS   CHANGE LVL 000, VERSION LVL 000, MODIFICATION LVL 000    01000000
*                                                                       01200000
*   FUNCTION   ANALYZE STATUS AND SENSE DATA FROM BOTH  THE PCU AND     01400000
*              SCU.MAINTAIN CURRENT ERROR STATISTIC AND SET A FLAG FOR  01600000
*              RECORDING OF ERRORS THAT OCCUR IN THE 1419 AND IN THE    01800000
*              CONTROL UNITS.ALSO SET A FLAG FOR THE PROPER MESSAGE     02000000
*              TO THE OPERATOR.                                         02200000
*                                                                       02400000
* ATTRIBUTES   SERIALLY REUSEABLE                                       02600000
*                                                                       02800000
*      ENTRY   ER1419 FROM SCHEDULER                                    03000000
*                                                                       03200000
*      INPUT   REQUEST ELEMENT POINTER IN REGISTER 1                    03400000
*                                                                       03600000
*     OUTPUT   ERROR LOGOUTS AND MESSAGES TO THE OPERATOR               03800000
*                                                                       04000000
*    EXT REF   NONE                                                     04200000
*                                                                       04400000
*NORMAL EXIT   XCTL EXIT TO OUTBOARD RECORDING,STATISTIC UPDATE OR      04600000
*              WRITE TO OPERATOR.RETURN WILL BE MADE FROM THESE         04800000
*              ROUTINES TO SUPERVISOR VIA SVC 3.                        05000000
*                                                                       05200000
* ERROR EXIT   NOT APPLICABLE                                           05400000
*                                                                       05600000
*   ERR MSGS   CONSOLE MESSAGES TO INDICATE ERROR CONDITIONS ARE        05800000
*              1. I/O PERMANENT ERROR                                   06000000
*              2. INTERVENTION REQUIRED                                 06200000
*                                                                       06400000
*      NOTES   IOB EXCEPTION AND IOB ERROR FLAGS ARE INTERPRETED        06600000
*              AS FOLLOWS                                               06800000
*                IOBEX ON AND IOBERR ON, ERROR ROUTINE IN CONTROL       07000000
*                IOBEX ON AND IOBERR OFF, PERMANENT ERROR               07200000
*     TABLES   STATISTIC TABLE AND IOB                                  07400000
*                                                                       07600000
*  OPERATION   THIS ROUTINE CHECKS THE STATUS AND SENSE BYTES STORED    07800000
*              IN THE IOB AND TAKES NECESSARY ACTION.STATISTICS ARE     08000000
*              KEPT AS TO THE KIND AND FREQUENCY OF ERRORS.THESE        08200000
*              STATISTICS ARE USED BY THE CE TO RECOGNIZE,ANALYZE AND   08400000
*              ISOLATE ERRORS.                                          08600000
*              A COMMON INTERPRETER ROUTINE IS USED TO CHECK BOTH       08800000
*              STATUS AND SENSE.ON RETURN FROM THE INTERPRETER,THE      09000000
*              PROPER FLAGS ARE SET AND A WRITE A MESSAGE TO THE        09200000
*              OPERATOR IS TAKEN.                                       09400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 09600000
*              IOB DEFINITION                                           09800000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 10000000
IOBFL1   EQU   0                        FLAGS1                          10200000
IOBFL2   EQU   1                        FLAGS2                          10400000
IOBSNS   EQU   2                        SENSE DATA                      10600000
IOBCOD   EQU   4                        ECB CODE                        10800000
IOBFL3   EQU   8                        IOB FLAG NO 3                   11000000
IOBCSW   EQU   8                        CSW STORAGE                     11200000
IOBCC    EQU   16                       CONDITION CODE                  11400000
IOBDCB   EQU   21                       DCB POINTER                     11600000
IOBMDB   EQU   24                       MODIFIER BYTE                   11800000
IOBRST   EQU   25                       RESTART ROUTINE                 12000000
IOBECT   EQU   30                       ERROR COUNTS                    12200000
IOBINC   EQU   32                       SPECIAL UNIT TYPE CODE          12400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 12600000
*      THIS FLAG IS IN THE IOB IOBECBCC                                 12800000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 13000000
IOBECB   EQU   X'41'                    COMPLETION CODE PERMANENT ERROR 13200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 13400000
*        THESE FLAGS ARE IN IOB-FLAG 1                                  13600000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 13800000
IOBCP1   EQU   X'80'                    TYPE OF CHANNEL PROGRAM         14000000
IOBCP2   EQU   X'40'                    TYPE OF CHANNEL PROGRAM         14200000
IOBERR   EQU   X'20'                    IOB ERROR FLAG                  14400000
IOBMD1   EQU   X'10'                    MOD1 FLAG-POSITIONING           14600000
IOBMD2   EQU   X'08'                    MOD2 FLAG-CRC                   14800000
IOBSRS   EQU   X'01'                    START/RESTART FLAG              15000000
IOBEX    EQU   X'04'                    EXCEPTION FLAG                  15200000
IOBEXE   EQU   IOBEX+IOBERR             IOB ERROR AND EXCEPTION FLAG    15400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 15600000
*        THESE FLAGS ARE IN IOB-FLAG3                                   15800000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 16000000
IOBENT   EQU   X'40'                    IOB ENTRY BIT                   16200000
IOBMSG   EQU   X'04'                    MESSAGE TYPE                    16400000
IOBLOG   EQU   X'01'                    LOGOUT FLAG                     16600000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 16800000
*     REGISTER DEFINITION                                               17000000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 17200000
ERREG0   EQU   0                        WORK REG                        17400000
TSTREG   EQU   1                        REQUEST ELEMENT                 17600000
ERREG2   EQU   2                        WORK REG                        17800000
ERREG3   EQU   3                        WORK REG                        18000000
CCWREG   EQU   4                        CCW ADDRESS REG                 18200000
UCBREG   EQU   7                        UCB ADDRESS REG                 18400000
COMREG   EQU   8                        COMMUNICATION TABLE REG         18600000
SAVREG   EQU   9                        SAVE REG                        18800000
IOBREG   EQU   10                       IOB ADDRESS REG                 19000000
ERREG4   EQU   11                       WORK REG                        19200000
ERRLNK   EQU   12                       LINK REG                        19400000
ERREG1   EQU   13                       WORK REG 1                      19600000
ERRETR   EQU   14                       RETURN REG                      19800000
BASREG   EQU   15                       BASE REG                        20000000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 20200000
*              DCB DEFINITION                                           20400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 20600000
DCBFL    EQU   44                       FLAGS                           20800000
DCBPER   EQU   X'C0'                    PERMANENT ERROR FLAGS           21000000
DCBEX    EQU   X'40'                    EXCEPTION CONDITION             21200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 21400000
*      REQUEST ELEMENT DEFINITION                                       21600000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 21800000
TSTLNK   EQU   0                        FORWARD 12 STAR LINK            22000000
TSTUCB   EQU   2                        UCB POINTER                     22200000
TSTIOB   EQU   5                        IOB POINTER                     22400000
TSTPR    EQU   8                        PRIORITY OF ENTRY               22600000
TSTDER   EQU   9                        DEB POINTER                     22800000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 23000000
*      STATUS INDICATORS                                                23200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 23400000
CSWSMD   EQU   X'40'                    STATUS MODIFIER                 23600000
CSWCHE   EQU   X'08'                    CHANNEL END                     23800000
CSWUCK   EQU   X'02'                    UNIT CHECK                      24000000
CSWUEX   EQU   X'01'                    UNIT EXCEPTION                  24200000
CHAINCK  EQU   X'01'                    CHAINING CHECK                  24400000
PROGCK   EQU   X'20'                    PROGRAM CHECK                   24600000
CSWIL    EQU   X'40'                    WRONG LENGTH IND.               24800000
CSWPCK   EQU   X'10'                    PROTECTION CHECK                25000000
CSWCCC   EQU   X'04'                    CHANNEL CONTROL CHECK           25200000
CSWICC   EQU   X'02'                    INTERFACE CONTROL CHECK         25400000
CSWCDC   EQU   X'08'                    CHANNEL DATA CHECK              25600000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 25800000
*     UCB DEFINITION                                                    26000000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 26200000
UCBFL1   EQU   6                        UCB FLAGS                       26400000
UCBSTI   EQU   9                        STATISTIC TABLE POINTER         26600000
*      MISC.  DEFINITIONS                                               26800000
ONE      EQU   1                                                        27000000
TWO      EQU   2                                                        27200000
ERPIBI   EQU   8                        ERPIB INDEX                     27400000
EIGHT    EQU   8                                                        27600000
STATWK   EQU   8                        STATISTIC TABLE WORK AREA INDEX 27800000
LOC016   EQU   16                       COMMUNICATION VECTOR TABLE      28000000
VECTXL   EQU   44                       VECTOR TO XCTL ROUTINE          28200000
VECT68   EQU   68                       INTERPRETER ROUTINE POINTER     28400000
VECT72   EQU   72                       WRITE TO OPERATOR ROUTINE       28600000
STATAB   EQU   112                      INDEX TO STATISTIC TABLE        28800000
CVTDCB   EQU   116                      CVT DCB POINTER                 29000000
WTORTN   EQU   253                      NAME OF WTO ROUTINE             29200000
STATUP   EQU   254                      LOAD NAME TO STAT.UPDATE RNT.   29400000
STATI    EQU   256                      STATISTIC TABLE INDEX           29600000
IOBPCU   EQU   X'00'                    PCU TEST BYTE                   29800000
IOBSCU   EQU   X'01'                    SCU TEST BYTE                   30000000
WKBIT1   EQU   X'01'                                                    30200000
ERREST   EQU   X'DF'                    IOB ERROR RESET FLAG            30400000
BATNUM   EQU   X'07'                    BATCH NUMBER TEST BYTE          30600000
PCUMSK   EQU   X'2E'  MASK FOR UNWANTED  PCU SNS BITS           SA44107 30800021
SCUMSK   EQU   X'A6'  MASK FOR UNWANTED  SCU SNS BITS           SA44107 31000021
SWITCH   EQU   X'FF'                                                    31200000
         USING ER1419,15                                                31400000
ER1419   L     IOBREG,TSTIOB-ONE(TSTREG) LOAD ADD OF IOB IN REG 10      31600000
         LH    UCBREG,TSTUCB(TSTREG)   LOAD UCB ADDRESS IN-REG 7        31800000
         L     COMREG,LOC016           LOAD ADD OF COMMUNICATION TABLE  32000000
         OI    IOBFL1(IOBREG),IOBEXE    SET IOB EX AND ERROR FLAG       32200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 32400000
*        LINK TO THE COMMON INTERPRETER ROUTINE. THE BYTES FOLLOWING    32600000
*        THE BALR INDICATE IN WHAT ORDER THE BITS ARE TO BE TEST (BIT 3 32800000
*        ON OF CODE BYTE INDICATES STATUS) FOLLOWED BY AN INDEX VALUE   33000000
*        THE INTERPRETER USES TO RETURN TO THIS ROUTINE                 33200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 33400000
ERR010   LR    SAVREG,BASREG            SAVE BASE REGISTER              33600000
         L     BASREG,VECT68(COMREG)    GET ADDR.TO INTERP.ROUTINE      33800000
ERR020   BALR  ERRLNK,BASREG            LINK TO INTERPRETER ROUTINE     34000000
         DC    X'1D'                    CHANNEL CONTROL CHECK           34200000
         DC    AL1(ERR025-ERR020-2)     BRANCH TO CHECK ERPIB TABLE     34400000
         DC    X'1E'                    INTERFACE CONTROL CHECK         34600000
         DC    AL1(ERR025-ERR020-4)     BRANCH TO CHECK ERPIB TABLE     34800000
         DC    X'1C'                    CHANNEL DATA CHECK              35000000
         DC    AL1(ERR028-ERR020-6)     BRANCH TO SET CDC SWITCH        35200000
         DC    X'10'                    SHOULD NOT OCCUR-INVALID STATUS 35400000
         DC    AL1(ERR070-ERR020-8)     BRANCH TO SET LOGOUT FLAG       35600000
         DC    X'11'                    SHOULD NOT OCCUR INVALID STATUS 35800000
         DC    AL1(ERR070-ERR020-10)    BRANCH TO SET LOGOUT FLAG       36000000
         DC    X'12'                    SHOULD NOT OCCUR INVALID STATUS 36200000
         DC    AL1(ERR070-ERR020-12)    BRANCH TO SET LOGOUT FLAG       36400000
         DC    X'16'                    UNIT CHECK                      36600000
         DC    AL1(ERR029-ERR020-14)    BRANCH TO STAT TABLE UPDATE     36800000
         DC    X'2F'                    END OF LIST                     37000000
         DC    AL1(ERR068-ERR020-16)    CHECK ADDITIONAL STATUS BITS    37200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 37400000
*              FRONT END SUPPORT FOR CHANNEL CONTROL CHECK              37600000
*              AND FOR INTERFACE CONTROL CHECK                          37800000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 38000000
ERR025   L     ERREG3,CVTDCB(COMREG)    CVT TO PTR TO PTR TO ERPIB      38200000
         L     ERREG3,0(ERREG3)         PTR TO PTR TO ERPIB             38400000
         L     ERREG3,0(ERREG3)         PTR TO ERPIB                    38600000
ERR026   CH    UCBREG,TWO(ERREG3)       IS CORRECT ERPIB                38800000
         BE    ERR027                   YES BRANCH TO CLEAR ERPIB ENTRY 39000000
         LA    ERREG3,ERPIBI(ERREG3)    ADDRESS OF NEXT ERPIB           39200000
         TM    0(ERREG3),SWITCH         END OF ERPIB TABLE              39400000
         BNO   ERR026                   BRANCH IF NOT END OF TABLE      39600000
         BO    ERR070                   YES BRANCH TO SET LOGOUT FLAG   39800000
ERR027   XC    0(ERPIBI,ERREG3),0(ERREG3)  CLEAR ENTRY IN ERPIB TABLE   40000000
         B     ERR070                   BRANCH TO SET LOGOUT FLAG       40200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 40400000
*        CHANNEL DATA CHECK                                             40600000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 40800000
ERR028   MVI   ERRCN1,SWITCH            SET CDC SWITCH                  41000000
         B     ERR029                   BRANCH TO STATISTIC TABLE UPDAT 41200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 41400000
*        STATISTIC TABLE UPDATE ROUTINE TO LOAD SENSE DATA INTO         41600000
*        TABLE WORKAREA                                                 41800000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 42000000
ERR029   L     ERREG2,STATAB(COMREG)    GET ADD.OF STATISTIC TABLE      42200000
         SR    ERREG1,ERREG1            CLEAR REGISTER                  42400000
         IC    ERREG1,UCBSTI(UCBREG)    GET STATAB PTR FROM UCB         42600000
         LR    ERREG3,ERREG2            GET STATISTIC TABLE ADDRESS     42800000
ER029A   CH    UCBREG,0(0,ERREG3)       IS DEV. SUPPORTED BY THIS SECT. 43000000
         BNH   ER029B                   YES, INCREMENT ADJUSTED CORR.   43200000
         LA    ERREG3,TWO(0,ERREG3)     INCREMENT TO NEXT CTRL ENTRY    43400000
         LA    ERREG1,STATI(0,ERREG1)   INCREMENT STAT.INDEX TO NEXT    43600000
*      *                                SECTION                         43800000
         B     ER029A                   LOOP TO CHECK NEXT SECTION      44000000
ER029B   MH    ERREG1,ERRCN2            MULTIPLY BY 10                  44200000
         AR    ERREG2,ERREG1            ADD.TO STATISTIC TABLE          44400000
         TM    ERRCN1,SWITCH            TEST FOR CHANNEL DATA CHECK     44600000
         BO    ER029C                   YES-OR BIT REP CTR NO 16        44800000
         OC    EIGHT(ONE,ERREG2),IOBSNS(IOBREG)  LD SNS BYTE 0 IN TABLE 45000000
         CLI   IOBINC(IOBREG),IOBPCU    TEST FOR PCU                    45200000
         BE    ER029D                   YES, BRANCH                     45400000
         TM    IOBINC(IOBREG),IOBSCU    TEST FOR SCU                    45600000
         BO    ER029E                   YES,CLEAR UNWANTED SCU BITS     45800000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 46000000
*             CHANNEL DATA  CHECK                                       46200000
ER029C   XC    ERRCN1,ERRCN1            CLEAR CDC SWITCH                46400000
         OI    STATWK+ONE(ERREG2),WKBIT1  LD BIT FOR CTR NO 16 IN       46600000
*                                         STATISTIC TABLE WORK AREA     46800000
         B     ERR070                   BRANCH TO SET LOGOUT FLAG       47000000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 47200000
*                MASK UNWANTED BITS FOR PCU                             47400000
ER029D   NI    STATWK(ERREG2),PCUMSK    MASK BITS EXCEPT DATA CK,CDC   C47600000
                                        BUS OUT,AUTO SEL AND           C47800000
                                        DATA OVERRUN                    48000000
         B     ERR050                   BRANCH TO CK PCU SENSE          48200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 48400000
*                 MASK UNWANTED BITS FOR SCU                            48600000
ER029E   NI    STATWK(ERREG2),SCUMSK    MASK BITS EXCEPT AUTO SELECT   C48800000
                               BUS OUT,LSS,CR & CDC             SA44107 49000021
         B     ERR060                   BRANCH TO CK SCU SENSE          49200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 49400000
*        LINK TO THE COMMON INTERPRETER ROUTINE. THE BYTES FOLLOWING    49600000
*        THE BALR INDICATE IN WHAT ORDER THE BITS ARE TO BE TEST (BIT 3 49800000
*        ON OF CODE BYTE INDICATES STATUS) FOLLOWED BY AN INDEX VALUE   50000000
*        THE INTERPRETER USES TO RETURN TO THIS ROUTINE                 50200000
*             CHECK PCU SENSE BITS                                      50400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 50600000
ERR050   LR    SAVREG,BASREG            SAVE BASE REGISTER              50800000
         L     BASREG,VECT68(COMREG)    GET ADDR.TO INTERPRETER ROUTINE 51000000
ERR051   BALR  ERRLNK,BASREG            LINK TO INTERPRETER ROUTINE     51200000
         DC    X'02'                    BUS OUT CHECK                   51400000
         DC    AL1(ERR070-ERR051-2)     BRANCH TO SET LOGOUT FLAG       51600000
         DC    X'03'                    SHOULD NOT OCCUR                51800000
         DC    AL1(ERR070-ERR051-4)     BRANCH TO SET LOGOUT FLAG       52000000
         DC    X'07'                    SHOULD NOT OCCUR                52200000
         DC    AL1(ERR070-ERR051-6)     BRANCH TO SET LOGOUT FLAG       52400000
         DC    X'01'                    INTERVENTION REQUIRED           52600000
         DC    AL1(ERR077-ERR051-8)     BRANCH TO SET MESSAGE FLAG      52800000
         DC    X'00'                    COMMAND REJECT                  53000000
         DC    AL1(ERR075-ERR051-10)    BRANCH TO SET PERM ERR FLAG     53200000
         DC    X'04'                    DATA CHECK                      53400000
         DC    AL1(ERR070-ERR051-12)    BRANCH TO SET LOGOUT FLAG       53600000
         DC    X'05'                    DATA OVERRUN                    53800000
         DC    AL1(ERR070-ERR051-14)    BRANCH TO SET LOGOUT FLAG       54000000
         DC    X'06'                    AUTO SELECT                     54200000
         DC    AL1(ERR070-ERR051-16)    BRANCH TO SET LOGOUT FLAG       54400000
         DC    X'2F'                    END OF LIST                     54600000
         DC    AL1(ERR068-ERR051-18)    BRANCH TO CK REMAINING STATUS   54800000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 55000000
*        LINK TO THE COMMON INTERPRETER ROUTINE. THE BYTES FOLLOWING    55200000
*        THE BALR INDICATE IN WHAT ORDER THE BITS ARE TO BE TEST (BIT 3 55400000
*        ON OF CODE BYTE INDICATES STATUS) FOLLOWED BY AN INDEX VALUE   55600000
*        THE INTERPRETER USES TO RETURN TO THIS ROUTINE                 55800000
*                CHECK SENSE BITS FOR SCU                               56000000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 56200000
ERR060   LR    SAVREG,BASREG            SAVE BASE REGISTER              56400000
         L     BASREG,VECT68(COMREG)    GET ADDR. OF INTERPRETER ROUT.  56600000
ERR061   BALR  ERRLNK,BASREG            LINK TO INTERPRETER ROUTINE     56800000
         DC    X'02'                    BUS OUT CHECK                   57000000
         DC    AL1(ERR070-ERR061-2)     BRANCH TO SET LOGOUT FLAG       57200000
         DC    X'04'                    SHOULD NOT OCCUR                57400000
         DC    AL1(ERR070-ERR061-4)     BRANCH TO SET LOGOUT FLAG       57600000
         DC    X'03'                    SHOULD NOT OCCUR                57800000
         DC    AL1(ERR070-ERR061-6)     BRANCH TO SET LOGOUT FLAG       58000000
         DC    X'01'                    INTERVENTION REQUIRED           58200000
         DC    AL1(ERR077-ERR061-8)     BRANCH TO SET MESSAGE FLAG      58400000
         DC    X'07'                    OPERATOR ATTENTION              58600000
         DC    AL1(ERR077-ERR061-10)    BRANCH TO SET MESSAGE FLAG      58800000
         DC    X'00'                    COMMAND REJECT SCU              59000000
         DC    AL1(ERR070-ERR061-12)   BRANCH TO SET LOGOUT FLAGSA44107 59200021
         DC    X'05'                    LATE STACKER SELECT             59400000
         DC    AL1(ERR070-ERR061-14)    BRANCH TO SET LOGOUT FLAG       59600000
         DC    X'06'                    AUTO SELECT                     59800000
         DC    AL1(ERR070-ERR061-16)    BRANCH TO SET LOGOUT FLAG       60000000
         DC    X'2F'                    END OF LIST                     60200000
         DC    AL1(ERR068-ERR061-18)    BRANCH TO CK REMAINING STATUS   60400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 62200000
*        LINK TO THE COMMON INTERPRETER ROUTINE. THE BYTES FOLLOWING    62400000
*        THE BALR INDICATE IN WHAT ORDER THE BITS ARE TO BE TEST (BIT 3 62600000
*        ON OF CODE BYTE INDICATES STATUS) FOLLOWED BY AN INDEX VALUE   62800000
*        THE INTERPRETER USES TO RETURN TO THIS ROUTINE                 63000000
*               CHECK REMAINING STATUS BITS                             63200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 63400000
ERR068   LR    SAVREG,BASREG            SAVE BASE REGISTER              63600000
         L     BASREG,VECT68(COMREG)    GET ADDR. OF INTERPRETER ROUT.  63800000
ERR069   BALR  ERRLNK,BASREG            LINK TO INTERPRETER ROUTINE     64000000
         DC    X'1F'                    CHAINING CHECK                  64200000
         DC    AL1(ERR070-ERR069-2)     BRANCH TO SET LOGOUT FLAG       64400000
         DC    X'1A'                    PROGRAM CHECK                   64600000
         DC    AL1(ER070A-ERR069-4)     BRANCH TO ECB CODE ROUTINE      64800000
         DC    X'1B'                    PROTECTION CHECK                65000000
         DC    AL1(ER070A-ERR069-6)     BRANCH TO ECB CODE ROUTINE      65200000
         DC    X'19'                    INCORRECT LENGTH                65400000
         DC    AL1(ER070A-ERR069-8)     BRANCH TO ECB CODE ROUTINE      65600000
         DC    X'2F'                    END OF LIST                     65800000
         DC    AL1(ERR075-ERR069-10)    BRANCH TO SET MESSAGE FLAG P ER 66000000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 66200000
*      SET LOGOUT OUT FLAG BIT 7 OF IOBFLG3                             66400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 66600000
ERR070   OI    IOBFL3(IOBREG),IOBLOG    SET LOGOUT FLAG                 66800000
*                                                                       67000000
ER070A   OI    IOBCOD(IOBREG),IOBECB    SET PERMANENT ERROR FLAG        67200000
*                                                                       67400000
ERR075   OI    IOBFL3(IOBREG),IOBMSG    SET PERMANENT ERROR MESSAGE FLG 67600000
         B     ERR078                   BRANCH TO RESET IOB ERROR FLAG  67800000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 68000000
*      SET MESSAGE FLAG FOR OPERATOR ATTN. OR INTERVENTION REQUIRED     68200000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 68400000
ERR077   OI    IOBFL3(IOBREG),IOBMSG-IOBMSG  SET FLAG FOR INTERVENTION  68600000
*                                            REQUIRED OR OP. ATTN       68800000
ERR078   NI    0(IOBREG),ERREST         RESET IOB ERROR FLAG            69000000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 69200000
*                   WTO ROUTINE                                       * 69400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 69600000
         L     ERRETR,LOC016            GET ADDRESS OF CVT              69800000
         L     ERRETR,VECTXL(ERRETR)    GET ADDRESS OF XCTL             70000000
         LA    ERREG1,WTORTN            LOAD NAME OF WTO                70200000
         BR    ERRETR                  GO TO XCTL                       70400000
ERRCN1   DC    CL1'0'                   SWITCH                          70600000
         DS    0D                                                       70800000
ERRCN2   DC    H'10'                    MULTIPLER CONSTANT OF TEN       71000000
         DS    CL50                     MAINTENANCE AREA                71200000
         END                                                            71400000
