IEC3211B START X'00'                                                    00050000
*A277600-277920,119600,185100,185200,277940,277960             @SA69284 00052021
*C278000                                                       @SA69284 00054021
*A062100,158100,183100                                         @SA69507 00060021
*1171233000,234000,236000,237000,247000,595000                   A42862 00100000
*0000377000-380000                                               M5877  00150000
**                                                               A49456 00200000
*A180000-180420,C180500,C278000                                  A51574 00210000
         SPACE 2                                                        00250000
*                      3211 ERROR RECOVERY PROCEDURE                    00300000
*STATUS CHANGE LEVEL 002 OS/21.8                                        00350021
*      FUNCTION     ANALYZE STATUS AND SENSE DATA AND ATTEMPT ERROR     00400000
*                   RECOVERY. IF THE ERROR IS CORRECTED,PROCEED IN A    00450000
*                   NORMAL MANNER. IF A PERMANENT ERROR IS DETECTED     00500000
*                   INDICATE IT TO THE USER BY A COMPLETION CODE IN THE 00550000
*                   ECB AND A MESSAGE ON THE SYSTEM CONSOLE.            00600000
*                                                                       00650000
*                   MULTI-CONSOLE SUPPORT                               00700000
*                                                                       00750000
*                   IF MULTI-CONSOLE SUPPORT IS IN SYSTEM THE           00800000
*                   ERROR RECOVERY PROCEDURE SETS UP FOR A              00850000
*                   BROADCAST WTO, WHICH WILL OUTPUT 'INTERVENTION      00900000
*                   REQUIRED' TO ALL DEVICES THAT MAKE A MESSAGE        00950000
*                   AVAILABLE TO THE SYSTEM OPERATOR. ALL OTHER         01000000
*                   ERRORS WILL BE RETRIED FIVE TIMES. IF RECOVERY,     01050000
*                   THE SYSTEM WILL CONTINUE-IF NO RECOVERY, ENSURES    01100000
*                   PERMANENT ERROR WILL BE INDICATED.                  01150000
*         ENTRY:    ER3211B   FROM IGE0000F                             01200000
*         INPUT     REQUEST ELEMENT POINTER IN REGISTER 1               01250000
*        OUTPUT     NONE                                                01300000
*       EXT REF     NONE                                                01350000
*         EXITS     1. ERREXCP EXIT TO I/O SUPERVISOR TO RE-EXECUTE     01400000
*                      THE CHANNEL PROGRAM IN ERROR.                    01450000
*                   2. SVC 3 EXIT TO RETURN CONTROL TO THE SUPERVISOR   01500000
*                      AND RELINQUISH CONTROL OVER THE TRANSIENT AREA   01550000
*                   3. XCTL EXIT TO OUTBOARD RECORDING, STATISTICS UP-  01600000
*                      DATE OR WRITE TO OPERATOR. RETURN WILL BE MADE   01650000
*                      FROM THESE ROUTINES TO THE SUPERVISOR VIA SVC 3. 01700000
*       ERR MSGS    CONSOLE MESSAGES TO INDICATE ERROR CONDITIONS ARE   01750000
*                        1. I/O ERR                                     01800000
*                        2. INT REQ                                     01850000
*         NOTES     IOB EXCEPTION AND IOB ERROR FLAGS ARE INTERPRETED   01900000
*                   AS FOLLOWS                                          01950000
*                        IOBEX ON AND IOBERR ON, ERR RTNE IN CONTROL.   02000000
*                        IOBEX ON AND IOBERR OFF, PERMANENT ERROR.      02050000
*                        IOBEX OFF AND IOBERR OFF, NO ERR OR CORRECTED  02100000
*        TABLES     STATISTICS TABLE AND IOB                            02150000
*     OPERATION     THIS ROUTINE HANDLES RECOVERY FROM CHANNEL          02200000
*                   ERRORS AND THE RECORDING OF CONTROL UNIT BUFFERS. * 02250000
*                                                                       02300000
*  CHANNEL ERRORS                                                       02350000
*              THE ERPIB INTERROGATOR DETERMINES THE VALIDITY OF        02400000
*              THE CAW,CSW,CHAN ADR, DEV ADR, BY INSPECTING THE         02450000
*              ERPIB. IF ANY ARE INVALID, LOGOUT AND WTO ARE INIT-      02500000
*              IATED. IF GOOD AND DEVICE STATUS IS IN THE CSW           02550000
*              RETRIES ARE MADE UNDER CERTAIN CONDITIONS. UNIT ERRS     02600000
*              HAVE PRIORITY THUS ARE RETURNED TO NORMAL FLOW.          02650000
*                                                                       02700000
*  LOGOUT OF PARITY ERRORS                                            * 02750000
*        THE FOLLOWING INFORMATION WILL BE RECORDED ON SYS1.LOGREC FOR* 02800000
*        EACH OF THREE BUFFER PARITY ERRORS:                          * 02850000
*        PLB (EQUIPMENT CHECK WITH COMMAND RETRY)--RECORD CONTENTS OF * 02900000
*        PRINT LINE BUFFER AND DIAGNOSTIC CHECK READ DATA             * 02950000
*        UCS (BUFFER PARITY CHECK WITH COMMAND RETRY)--RECORD CONTENTS* 03000000
*        UCS BUFFER AND UCBUSCID FROM UCB                             * 03050000
*        FCB (BUFFER PARITY CHECK WITH LINE POSITION)--RECORD CONTENTS* 03100000
*        OF CARRIAGE CONTROL ADDRESS REGISTER (CCAR) AND UCBFCBID FROM* 03150000
*        UCB                                                          * 03200000
*                                                                     * 03250000
*        THE ABOVE INFORMATION AS WELL AS THE DEVICE ADDRESS WILL BE  * 03300000
*        PASSED TO MODULE IGE0625F FOR RECORDING                      * 03350000
*********************************************************************** 03400000
         EJECT                                                          03450000
         SPACE 2                                                        03500000
*        TITLE  ' INPUT OUTPUT CONTROL BLOCK (IOB) '                    03550000
*                                                                       03600000
*                                                                       03650000
*               *****************************************               03700000
*               *    *    *         *    *              *               03750000
*             0 *FLG1*FLG2*  SENSE  *ECB *   ECB PTR    *               03800000
*               *    *    *         *CODE*              *               03850000
*               *****************************************               03900000
*               *                                       *               03950000
*             8 *        CHANNEL  STATUS  WORD          *               04000000
*               *                                       *               04050000
*               *****************************************               04100000
*               *    *              *         *         *               04150000
*            16 * CC *    START     *WGHT*   DCB PTR    *               04200000
*               *    *              *    *              *               04250000
*               *****************************************               04300000
*               *    *              *    *              *               04350000
*            24 *MODF*   RESTART    * INCR (2)* ERR CNTS*               04400000
*               *    *              *    *TP 1*         *               04450000
*               *****************************************               04500000
*               *                                       *               04550000
*            32 *  M *  B *  B *  C *  C *  H *  H *  R *               04600000
*               *                                       *               04650000
*               *****************************************               04700000
*                                                                       04750000
*                                                                       04800000
*              IOB DEFINITION                                           04850000
IOBFL1   EQU   0                        FLAGS 1                         04900000
IOBFL2   EQU   1                        FLAGS 2                         04950000
IOBSNS   EQU   2                        SENSE DATA                      05000000
IOBCOD   EQU   4                        ECB CODE                        05050000
IOBFL3   EQU   8                        IOB FLAG NO 3                   05100000
IOBCSW   EQU   8                        CSW STORAGE                     05150000
IOBCC    EQU   16                       CONDITION CODE                  05200000
IOBDCB   EQU   21                       DCB POINTER                     05250000
IOBMDB   EQU   24                       MODIFIER BYTE                   05300000
IOBRST   EQU   25                       RESTART POINTER                 05350000
IOBECT   EQU   30                       ERROR COUNTS                    05400000
IOBCC1   EQU   X'10'                    CONDITION CODE OF SIO           05450000
IOSTUS   EQU   X'10'                    STATUS BIT                      05500000
IOCLBT   EQU   X'00'                    CLEAR BYTE                      05550000
         SPACE 2                                                        05600000
*   THESE FLAGS ARE IN IOB-FLAG 1                                       05650000
IOBCP1   EQU   X'80'                    TYPE OF CHANNEL PROGRAM         05700000
IOBCP2   EQU   X'40'                    TYPE OF CHANNEL PROGRAM         05750000
IOBERR   EQU   X'20'                    IOB ERROR FLAG                  05800000
IOBMD1   EQU   X'10'                    MOD1 FLAG-POSITIONING           05850000
IOBMD2   EQU   X'08'                    MOD2 FLAG- CRC                  05900000
IOBSRS   EQU   X'01'                    START/RESTART FLAG              05950000
IOBEX    EQU   X'04'                    EXCEPT FLAG                     06000000
IOBEXE   EQU   IOBEX+IOBERR             IOB EX + IOB ERROR FLAG         06050000
         SPACE 1                                                        06100000
*   THESE FLAGS ARE IN IOB-FLAG 2                                       06150000
IOBHLT   EQU   X'80'                    HALT I/O ISSUED FLAG            06200000
IOBRHA   EQU   X'10'                    BYPASS USER KEY IN CAW          06210021
         SPACE 1                                                        06250000
*   THESE FLAGS ARE IN IOB-FLAG 3                                       06300000
IOBMCS   EQU   X'80'                    MCS FLAG                        06350000
IOBENT   EQU   X'40'                    IOB ENTRY BIT                   06400000
IOBLCK   EQU   X'20'                    LOAD CHECK COUNT                06450000
IOBBOE   EQU   X'10'                    BUS OUT ERROR CNT               06500000
IOBBUF   EQU   X'08'                    BUFFER FLAG                     06550000
IOBMSG   EQU   X'04'                    MESSAGE TYPE                    06600000
IOBTPR   EQU   X'02'                    TPERR FLAG                      06650000
IOBLOG   EQU   X'01'                    LOGOUT FLAG                     06700000
         SPACE 2                                                        06750000
*              THESE FLAGS ON IN IOBECT FIELD                           06800000
IOBFCB   EQU   X'08'                    FORMS CONTROL BUFFER COUNT      06850000
IOBUCS   EQU   X'04'                    UNIVERSAL CHARACTER SET COUNT   06900000
IOBCCH   EQU   X'02'                    CHANNEL ERROR COUNT             06950000
IOBPLB   EQU   X'01'                    PRINT LINE BUFFER COUNT  M1785  07000000
         SPACE 2                                                        07050000
*   REGISTER DEFINITION                                                 07100000
ERREG3   EQU   0                        WORK REG                        07150000
TSTREG   EQU   1                        TWELVE STAR REG.                07200000
ERREG2   EQU   2                        WORK REG                        07250000
DCBREG   EQU   3                       DCB ADDRESS REG                  07300000
CCWREG   EQU   4                        CCW ADDRESS REG                 07350000
ERREG5   EQU   5                        WORK REG                        07400000
ERPIBRG  EQU   6                        ERPIB PTR REG                   07450000
UCBREG   EQU   7                        UCB ADDRESS REG                 07500000
COMREG   EQU   8                        COMMUNICATION TABLE REG         07550000
SAVREG   EQU   9                        SAVE REG.                       07600000
IOBRG    EQU   10                       IOB ADDRESS REG                 07650000
ERREG4   EQU   11                       WORK REG                        07700000
ERRLNK   EQU   12                       LINK REG                        07750000
ERREG1   EQU   13                       WORK REG 1                      07800000
ERRETR   EQU   14                       RETURN REG                      07850000
BASREG   EQU   15                       BASE REG.                       07900000
         SPACE 2                                                        07950000
*              ECB DEFINITIONS                                          08000000
ECBFL    EQU   0                        FLAGS                           08050000
         SPACE 2                                                        08100000
*              DCB DEFINITION                                           08150000
DCBFL    EQU   44                       FLAGS                           08200000
DCBPER   EQU   X'C0'                    PERMANENT ERROR FLAGS           08250000
DCBEX    EQU   X'40'                    EXCEPTION CONDITION             08300000
DCB09    EQU   X'20'                    CHANNEL 9                       08350000
DCB12    EQU   X'10'                    CHANNEL 12                      08400000
         SPACE 2                                                        08450000
*              TWELVE STAR DEFINITION                                   08500000
TSTLNK   EQU   0                        FORWARD 12* LINK                08550000
TSTUCB   EQU   2                        UCB POINTER                     08600000
TSTIOB   EQU   5                        IOB POINTER                     08650000
TSTPR    EQU   8                        PRIORITY OF ENTRY               08700000
TSTDEB   EQU   9                        DEB POINTER                     08750000
         SPACE 2                                                        08800000
*              STATUS INDICATORS                                        08850000
CSWSMD   EQU   X'40'                    STATUS MODIFIER                 08900000
CSWCHE   EQU   X'08'                    CHANNEL END                     08950000
CSWUCK   EQU   X'02'                    UNIT CHECK                      09000000
CSWUEX   EQU   X'01'                    UNIT EXCEPTION                  09050000
CSWIL    EQU   X'40'                    WRONG LENGTH IND.               09100000
CSWPC    EQU   X'20'                    PROGRAM CHECK                   09150000
CSWPCK   EQU   X'10'                    PRTECTION CHECK                 09200000
CSWCCK   EQU   X'01'                    CHAINING CHECK                  09250000
CSWCDCK  EQU   X'08'                    CHANNEL DATA CHECK              09300000
CSWCCCK  EQU   X'04'                    CHANNEL CNTRL CHECK             09350000
CSWICCK  EQU   X'02'                    INTRFCE CNTRL CHECK             09400000
         SPACE 2                                                        09450000
*              SENSE INDICATORS                                         09500000
CMNDREJ  EQU   X'80'                    CMNDREJ ON CHAN9                09550000
INTREQ   EQU   X'40'                    INTERVENTION REQUIRED SENSE     09600000
EQCK     EQU   X'10'                    EQUIPMENT CHECK                 09650000
BUFPAR   EQU   X'04'                    BUFFER PARITY                   09700000
CHAN9    EQU   X'01'                    CHAN 9 SENSE BIT                09750000
CMDRTY   EQU   X'80'                    COMMAND RETRY                   09800000
LNEPOS   EQU   X'10'                    LINE POSITION                   09850000
CMDSUP   EQU   X'04'                    COMMAND SUPRESS                 09900000
BUFONY   EQU   LNEPOS+CMDRTY            BUFFER PARITY ONLY              09950000
LDCHK    EQU   X'02'                    LOAD CHECK                      10000000
         SPACE 2                                                        10050000
*   UCB DEFINITION                                                      10100000
UCBUA    EQU   4                        UNIT ADDRESS                    10150000
UCBFL1   EQU   6                        UCB FLAGS                       10200000
UCBSTI   EQU   9                        STATISTICS POINTER              10250000
UCBLTS   EQU   14                       LAST RQE FIELD                  10300000
UCBSNSPT EQU   24                       U UCB SENSE ADDRESS             10350000
UCBXTADR EQU   28                       UCB EXTENSION ADDRESS           10400000
UCBBSY   EQU   X'80'                    BUSY FLAG                       10450000
UCBNRY   EQU   X'40'                    UCB NOT READY                   10500000
LTSZER   EQU   X'00'                    ZERO RQE FIELD                  10550000
         SPACE 2                                                        10600000
*              UCB EXTENSION                                            10650000
UCBUCSID EQU   0                        UCS ID                          10700000
UCBUCSOP EQU   4                        UCS FLAGS                       10750000
UCBERCNT EQU   7                        RECORD COUNT                    10800000
UCBFCBID EQU   8                        FCB ID                          10850000
UCBERADR EQU   12                       LOGOUT AREA                     10900000
UCBUCSPE EQU   X'01'                    PARITY ERROR                    10950000
         SPACE 2                                                        11000000
*              CVT DEFINITIONS                                          11050000
LOC016   EQU   16                       COMMUNICATION TABLE             11100000
VECTXL   EQU   44                       VECTOR TO XCTL RNT.             11150000
VECT68   EQU   68                       INTERPRETER ROUTINE             11200000
VECT72   EQU   72                       WRITE TO OPERATOR ROUTINE       11250000
UCMADR   EQU   100                      UCM OFFSET IN CVT               11300000
STATAB   EQU   112                      INDEX TO STATISTICS TABLE       11350000
IBPTR    EQU   116                      PTR TO PTR TO PTR TO ERPIB CCHA 11400000
CVTDCB   EQU   X'74'                    CVT OFFSET IN DCB               11450000
         SPACE 2                                                        11500000
*        THE FOLLOWING EQU'S REFER TO THE RECORD BUILT FOR BUFFER       11550000
*              PARITY ERRORS                                            11600000
         SPACE 1                                                        11650000
UCSRSZE  EQU   544                      UCS RECORD SIZE                 11700000
FCBRSZE  EQU   208                      FCB RECORD SIZE          M1785  11750000
PLBRSZE  EQU   188                      PLB RECORD SIZE                 11800000
ERRCNT   EQU   10                       PLB ERROR COUNTER               11850000
CHRCNT   EQU   150                      PLB CHAR COUNTER                11900000
SAVECSW  EQU   560                      SAVE AREA FOR CSW        A42862 11950000
SAVERST  EQU   540                      SAVE- RESTART ADDR     @SA69284 11960021
CCW1     EQU   544                      FIRST CCW                A42862 12000000
DATA1    EQU   28                       DATA AREA                       12050000
SAVESNS  EQU   552                      SAVE AREA FOR SENSE      A49456 12100000
TYPFLG   EQU   568                      TYPE FLAG                A42862 12150000
UCSTYP   EQU   X'80'                    UCS TYPE                        12200000
FCBTYP   EQU   X'40'                    FCB TYPE                        12250000
PLBTYP   EQU   X'20'                    PLB TYPE                 M1785  12300000
CHKTYP   EQU   X'10'                    CHECK DATA               A49456 12350000
CLRTYP   EQU   X'00'                    CLEAR FLAG               A49456 12400000
RCDID    EQU   X'04'                    RECORD ID                       12450000
RCDSIZE  EQU   0                        RECORD SIZE AREA                12500000
TPRTNID  EQU   3                        RETURN ID                       12550000
TPRCDID  EQU   5                        RECORD ID                       12600000
UNITADR  EQU   24                       UNIT ADDRESS                    12650000
RCDCNT   EQU   26                       RECORD COUNTER                  12700000
RCDFLG   EQU   27                       RECORD FLAG                     12750000
UCSID    EQU   540                      UCSID AREA               A42862 12800000
FCBID    EQU   29                       FCBID AREA                      12850000
UCSFLG   EQU   X'01'                    UCS RECORD                      12900000
FCBFLG   EQU   X'02'                    FCB RECORD                      12950000
PLBFLG   EQU   X'03'                    PLB RECORD                      13000000
         SPACE 2                                                        13050000
*              ERPIB DEFINITION                                         13100000
COMADVAL EQU   X'04'                    COMMAND ADDRESS VALID           13150000
NORETRY  EQU   X'01'                    UNCONDITIONAL NO RETRY          13200000
PGMFLGS  EQU   X'04'                    PROGRAM FLGS DISP IN ERPIB      13250000
VALIDIND EQU   X'06'                    VALIDITY INDICATORS ERPIB       13300000
RETRYCD  EQU   X'07'                    RETRY CODE OFFSET IN ERPIB      13350000
TERMCODE EQU   X'07'                    TERMINATION BITS IN ERPIB       13400000
RTRYCOD1 EQU   X'01'                    RETRY CODE TEST CONSTANT        13450000
RTRYCOD2 EQU   X'02'                    RETRY CODE TEST CONSTANT        13500000
RTRYCOD3 EQU   X'03'                    RETRY CODE TEST CONSTANT        13550000
RTRYCOD4 EQU   X'04'                    RETRY CODE TEST CONSTANT        13600000
TRMCOD80 EQU   X'80'                    TERMINATION CODE 1              13650000
TRMCOD40 EQU   X'40'                    TERMINATION CODE2               13700000
ENDTBL   EQU   X'FF'                    END OF ERPIB TABLE              13750000
         SPACE 2                                                        13800000
*              MISCELLANEOUS DEFINITIONS                                13850000
CMNDCD   EQU   0                        CCW COMMAND CODE DISP           13900000
INCR     EQU   1                        CONSTATN OF ONE                 13950000
FVRTRY   EQU   5                         FIVE RETRIES                   14000000
WRITE    EQU   X'01'                    WRITE OP CODE                   14050000
PLBCMD   EQU   X'02'                    READ PLB CMD             A49456 14100000
CONTRL   EQU   X'03'                    CONTROL OP CODE                 14150000
NOP      EQU   X'03'                    NOP COMMAND CODE                14200000
CHKCMD   EQU   X'06'                    CHECK READ CMD           A49456 14250000
TIC      EQU   X'07'                    TEST FOR TIC                    14300000
SIOCC1   EQU   X'80'                    WAS CSW STORED ON SIO           14350000
EXCPER   EQU   15                       ERROR EXCP                      14400000
WTORTN   EQU   253                      LOAD NAME TO WTO RTN.           14450000
STATUP   EQU   254                      LOAD NAME STAT UPDATE           14500000
         EJECT                                                          14550000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   14600000
*                                                                   *   14650000
*       THIS IS ENTRY TO THE 3211 ERROR ROUTINE                         14700000
*                                                                   *   14750000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   14800000
*                                                                   *   14850000
*    WHEN ENTERED THE IOBEX AND THE IOBERR FLAGS WILL BE SET TO 1 BY  * 14900000
*      THE ERROR ROUTINE.                                             * 14950000
*                                                                     * 15000000
*    ON RETURN THESE TWO FLAGS SHOULD BE INTERPRETED AS FOLLOWS.      * 15050000
*      IOBEX ON  AND IOBERR ON  - IOB IN CONTROL BY THE ERROR ROUTINE.* 15100000
*      IOBEX ON  AND IOBERR OFF - PERMANENT ERROR                     * 15150000
*      IOBEX OFF AND IOBERR OFF - ERROR CORRECTED                     * 15200000
*                                                                     * 15250000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 15300000
         SPACE 1                                                        15350000
         USING ER3211B,15                                               15400000
ER3211B  L     IOBRG,TSTIOB-1(TSTREG)   IOB ADDRESS                     15450000
         LH    UCBREG,TSTUCB(TSTREG)    UCB ADDRESS                     15500000
         L     COMREG,LOC016            CVT ADDRESS                     15550000
         L     CCWREG,IOBCSW(IOBRG)     GET ADDRESS OF CCW              15600000
         LA    CCWREG,0(CCWREG)         ZERO HIGH ORDER BYTE            15650000
         SH    CCWREG,ERRCN1            BACK UP BY 8                    15700000
         L     ERREG5,UCBXTADR(UCBREG)  GET ADDR UCB EXTENSION          15750000
         L     ERREG1,UCBERADR(ERREG5)  GET ADDR BUFFER AREA            15800000
         NI    IOBFL2(IOBRG),X'FF'-IOBRHA   CLR KEY-0 FLAG     @SA69507 15810021
         TM    IOBCSW+5(IOBRG),CSWCCCK+CSWICCK CH/INTERFACE CK          15850000
         BC    7,ERPIBFND               YES-FIND ERPIB                  15900000
         TM    IOBFL3(IOBRG),IOBBUF     TEST FOR BUFFER INFO.           15950000
         BC    1,BUFLOG                 YES--LOGOUT                     16000000
         LA    ERREG1,0(ERREG1)         ZERO HIGH ORDER BYTE            16050000
         LTR   ERREG1,ERREG1            TEST FOR ZERO ADDRESS           16100000
         BC    8,ERR070A                YES-PERM ERROR                  16150000
         MVI   TYPFLG(ERREG1),CLRTYP    CLEAR TYPE FLAG         A49456  16200000
         SPACE 1                                                        16250000
*                        TEST FOR PLB READ                              16300000
         SPACE 1                                                        16350000
         TM    IOBECT(IOBRG),IOBPLB     TEST FOR PLB READ         M1785 16400000
         BC    8,ERR020                 NO,CHECK UCSB             M1785 16450000
         SPACE 1                                                        16500000
ERR020D  LA    ERREG2,CHKCCW            GET CCW ADDR             A49456 16550000
         BAL   ERRLNK,READBUF           GO SET FLAGS-SET UP CCW         16600000
         MVI   RCDFLG(ERREG1),PLBFLG    INITIALIZE RECORD FLAG          16650000
         LA    ERREG2,PLBRSZE           SET ERREG2 TO RECORD SIZE       16700000
         NI    IOBECT(IOBRG),X'FF'-IOBPLB  CLR READ FLAG          M1785 16750000
         BC    15,ERR020C               READ SELECTED BUFFER      M1785 16800000
ERR020   TM    IOBECT(IOBRG),IOBUCS     TEST FOR UCSB READ        M1785 16850000
         BC    8,ERR020A                NO,READ FCB               M1785 16900000
         LA    ERREG2,UCSCCW            GET ADDR CCW                    16950000
         BAL   ERRLNK,READBUF           GO SET FLAGS-SET UP CCW         17000000
         MVI   RCDFLG(ERREG1),UCSFLG    INITIALIZE RECORD FLAG          17050000
         LA    ERREG2,UCSRSZE           GET RECORD SIZE                 17100000
         MVC   UCSID(4,ERREG1),UCBUCSID(ERREG5)  MOVE UCSID TO RECORD   17150000
         NI    IOBECT(IOBRG),X'FF'-IOBUCS  CLEAR READ FLAG        M1785 17200000
         BC    15,ERR020C               GO SET RESTART                  17250000
         SPACE 1                                                        17300000
ERR020A  EQU   *                                                        17350000
         TM    IOBECT(IOBRG),IOBFCB     TEST FOR FCB READ        A49456 17400000
         BC    8,ERR070A                NO,PERM ERROR            A49456 17450000
         LA    ERREG2,FCBCCW            GET CCW ADDR                    17500000
         BAL   ERRLNK,READBUF           GO SET FLAGS-SET UP CCW         17550000
         MVI   RCDFLG(ERREG1),FCBFLG    INITIALIZE RECORD FLAG          17600000
         LA    ERREG2,FCBRSZE           GET RECORD SIZE                 17650000
         XC    UCBFCBID(4,ERREG5),UCBFCBID(ERREG5)  ZERO FCBID          17700000
*                     THIS WILL INDICATE TO DATA MANAGEMENT TO RELOAD   17750000
*                     THE FCB AT NEXT OPEN                              17800000
         NI    IOBECT(IOBRG),X'FF'-IOBFCB  CLEAR READ FLAG        M1785 17850000
ERR020C  ST    ERREG4,IOBMDB(IOBRG)     SET RESTART ON NEW CCW          17900000
         MVI   IOBCOD(IOBRG),X'7F'      SET ECB CODE TO NORMAL    M1785 17950000
         STH   ERREG2,RCDSIZE(ERREG1)   STORE RECORD SIZE               18000000
ERR020E  EQU   *                                                        18010000
         TM    IOBSNS(IOBRG),INTREQ     INT REQUIRED                    18020000
         BC    8,ERR020F                NO, LEAVE MSG BIT ON            18030000
         NI    IOBFL3(IOBRG),X'FF'-IOBMSG  ISSUE INT REQ MSG            18040000
         BC    15,ERR072                CALL WTO                        18042000
ERR020F  SVC   EXCPER                                                   18050000
         SVC   3                                                        18100000
         SPACE 1                                                        18150000
*        INITIALIZE FLAGS,SET UP CCW AND SAVE CSW FOR RECORDING         18200000
         SPACE 1                                                        18250000
READBUF  EQU   *                                                        18300000
         OI    IOBFL2(IOBRG),IOBRHA     EX ERP PGM IN KEY-0    @SA69507 18310021
         OI    IOBFL1(IOBRG),IOBSRS     SET RESTART FLAG                18350000
         XC    TPRTNID(2,ERREG1),TPRTNID(ERREG1)  ZERO RETURN IND.      18400000
         MVC   UNITADR(2,ERREG1),UCBUA(UCBREG) GET UNIT ADDR            18450000
         MVC   SAVECSW(7,ERREG1),IOBCSW+1(IOBRG)  SAVE CSW              18500000
         MVC   SAVERST(1,ERREG1),IOBFL1(IOBRG)  SAVE RST FLAG  @SA69284 18510021
         MVC   SAVERST+1(3,ERREG1),IOBRST(IOBRG)  SAVE ADDR    @SA69284 18520021
         L     ERREG4,UCBSNSPT(UCBREG)  GET ADDR SENSE AREA      A49456 18550000
         MVC   SAVESNS(6,ERREG1),0(ERREG4)  SAVE SENSE           A49456 18600000
         MVC   RCDCNT(1,ERREG1),UCBERCNT(ERREG5)  MOVE IN RECORD CNT    18650000
         MVI   TPRCDID(ERREG1),RCDID    INSERT RECORD ID                18700000
ERR056A  MVC   CCW1(8,ERREG1),0(ERREG2)  MOVE CCW'S TO USER AREA A49456 18750000
         LA    ERREG4,DATA1(ERREG1)     GET DATA ADDR            M1785  18800000
         CLI   CCW1(ERREG1),X'02'       TEST FOR PLB CMD         A49456 18850000
         BC    7,ERR056B                NO,BYPASS CCW2           A49456 18900000
         LA    ERREG4,CHRCNT(ERREG4)    GET ADDR FOR PL DATA     M1785  18950000
ERR056B  EQU   *                                                        19000000
         O     ERREG4,CCW1(ERREG1)      GET OP CODE              A49456 19050000
         ST    ERREG4,CCW1(ERREG1)      STORE COMPLETED CCW      A49456 19100000
         OI    IOBFL3(IOBRG),IOBBUF     SET BUFFER FLAG          M1785  19150000
         LA    ERREG4,CCW1(ERREG1)      GET CCW ADDR                    19200000
         BCR   15,ERRLNK                RETURN TO FINISH RECORD         19250000
         SPACE 1                                                        19300000
*   SET MESSAGE AND LOGOUT FLAGS AS NECESSARY AND XCTL TO NEXT MODULE   19350000
ERR070   BAL   ERRLNK,TESTMCS                                           19400000
ERR070A  OI    IOBFL3(IOBRG),IOBLOG     INDICATE LOGOUT                 19450000
ERR071   OI    IOBFL3(IOBRG),IOBMSG     INDICATE PERM ERR MSG           19500000
ERR072   LA    ERREG1,WTORTN            GET LOAD NAME WTO RTN           19550000
         BC    15,ERR090A               XCTL WTO                        19600000
         SPACE 1                                                        19650000
*                  PERMANENT ERROR--NO MESSAGE                          19700000
         SPACE 1                                                        19750000
ERR073   NI    IOBFL1(IOBRG),X'FF'-IOBERR  INDICATE PERM ERROR          19800000
         OI    IOBFL3(IOBRG),IOBLOG     INDICATE LOGOUT                 19850000
         LA    ERREG1,STATUP             GET LOAD NAME STAT UPDATE      19900000
         XC    IOBECT(2,IOBRG),IOBECT(IOBRG) CLEAR ERR COUNTS           19950000
         BC    15,ERR090A               GO TO XCTL                      20000000
         SPACE 1                                                        20050000
*    SET UP FOR 5 RETRIES IF MCS IN SYSTEM AND THIS IS A CONSOLE        20100000
         SPACE 1                                                        20150000
ERR075   LA    ERRLNK,ERR070A           SET RETN FROM MCS TEST          20200000
         XC    0(8,ERPIBRG),0(ERPIBRG)  ZERO ERPIB                      20250000
TESTMCS  TM    IOBFL3(IOBRG),IOBMCS      TEST FOR MCS                   20300000
         BCR   8,ERRLNK                  NO-TO NORMAL FLOW              20350000
         TM    IOBECT+1(IOBRG),FVRTRY   RETRIED FIVE TIMES              20400000
         BC    1,ERR073                 YES-RETURN                      20450000
         IC    ERREG4,IOBECT+1(0,IOBRG) LOAD ERR CNT                    20500000
         LA    ERREG4,INCR(ERREG4)       INCREMENT ERR CTR              20550000
         STC   ERREG4,IOBECT+1(0,IOBRG)  STORE NEW ERR CNT              20600000
         BC    15,ERR080A               TEST IF CCW ADDR VALID          20650000
         SPACE 1                                                        20700000
*                SET UP RETRY OF CHANNEL ERRORS                         20750000
         SPACE 1                                                        20800000
ERR080   TM    IOBECT(IOBRG),IOBCCH     SECOND OCCURENCE                20850000
         BC    1,ERR070A                YES-PROVIDE OPERATOR MSG        20900000
         OI    IOBECT(IOBRG),IOBCCH     SET ERROR COUNT                 20950000
ERR080A  LTR   CCWREG,CCWREG            CCW PTR ZERO OR NEGATIVE        21000000
         BC    2,ERR081                  NO-RETRY COMMAND               21050000
         NI    IOBFL1(IOBRG),X'FF'-IOBSRS  YES-START AT TOP             21100000
ERR081   OI    IOBFL3(IOBRG),IOBENT     SET ENTRY FLAG                  21150000
         SVC   EXCPER                                                   21200000
         SVC   3                                                        21250000
         SPACE 1                                                        21300000
*                     SEARCH FOR CORRECT ERPIB                          21350000
         SPACE 1                                                        21400000
ERPIBFND L     ERPIBRG,IBPTR(COMREG)    PTR TO PTR TO PTR TO ERPIB      21450000
         L     ERPIBRG,0(ERPIBRG)       PTR TO PTR TO ERPIB             21500000
         L     ERPIBRG,0(ERPIBRG)       PTR TO ERPIB                    21550000
ERCMPR   CH    UCBREG,2(ERPIBRG)        IS THIS ERPIB FOR PRNTR         21600000
         BC    8,ERPIBTST               YES, GO CHECK ERPIB             21650000
         LA    ERPIBRG,8(ERPIBRG)       ADDR OF NEXT ERPIB              21700000
         TM    0(ERPIBRG),ENDTBL        END OF ERPIB TABLE              21750000
         BC    8+4,ERCMPR               NO-TEST NEXT ERPIB              21800000
         BC    1,ERR070                 YES-LOG OUT                     21850000
         SPACE 1                                                        21900000
*     TEST IF RETRY POSSIBLE ON ICC OR CCC BY EXAMINING RETRY AND       21950000
*     TERMINATION CODES IN ERPIB.  THE ACTIONS FOR THESE CODES ARE      22000000
*     STANDARD FOR THE 2211                                             22050000
         SPACE 1                                                        22100000
ERPIBTST LA    ERRLNK,ERR075            SET RETN FOR MCS TEST           22150000
         CLI   IOBCOD(IOBRG),X'7E'      IS THIS INTERCEPT CON           22200000
         BCR   8,ERRLNK                 YES-PERMANENT ERROR             22250000
         TM    PGMFLGS(ERPIBRG),NORETRY UNCONDITIONAL NO RETRY SET      22300000
         BCR   1,ERRLNK                 YES-PERMANENT ERROR             22350000
         TM    PGMFLGS(ERPIBRG),SIOCC1  WAS CSW STORED ON SIO           22400000
         BC    1,CHERR                  YES-RETRY                       22450000
         TM    VALIDIND(ERPIBRG),COMADVAL  COMMAND ADDR VALID           22500000
         BCR   8,ERRLNK                 NO-ZERO ERPIB/TEST IF MCS       22550000
         CLI   0(CCWREG),NOP            NOP COMMAND                     22600000
         BC    8,CHERR                  YES-RETRY                       22650000
         TM    RETRYCD(ERPIBRG),RTRYCOD4 RETRY CODE>=4                  22700000
         BC    8,ERR086                 NO-TEST FOR CODE<4              22750000
         TM    RETRYCD(ERPIBRG),RTRYCOD3  RETRY CODE=7                  22800000
         BC    1,ERR087                 YES-BRANCH TEST FURTHER         22850000
         BC    8,CHERR                  BRANCH IF CODE=4                22900000
         TM    RETRYCD(ERPIBRG),RTRYCOD2 RETRY CODE=2                   22950000
         BCR   1,ERRLNK                 YES-PERM ERROR                  23000000
         SPACE 1                                                        23050000
*              RETRY CODE = 011 OR 101                                  23100000
ERR085   LR    ERREG1,ERRLNK            SET RETN FROM OP CODE TEST      23150000
         LR    ERREG2,ERRLNK            SET RETN FROM TERM CODE TEST    23200000
         BC    15,ERR088                                                23250000
         SPACE 1                                                        23300000
ERR086   TM    RETRYCD(ERPIBRG),RTRYCOD3 RETRY CODE =3                  23350000
         BC    1,ERR085                 YES-BRANCH                      23400000
         BCR   8,ERRLNK                 BRANCH CODE=0-PERM ERROR        23450000
         TM    RETRYCD(ERPIBRG),RTRYCOD1 RETRY CODE=1                   23500000
         BC    1,CHERR                  YES-BRANCH FOR RETRY            23550000
         SPACE 1                                                        23600000
*              RETRY CODE = 010                                         23650000
         CLI   CMNDCD(CCWREG),WRITE     TEST FOR WRITE COMMAND          23700000
         BC    8,CHERR                  YES-GO RETRY                    23750000
ERR086A  LA    ERREG2,ERR089            SET RETN FROM TERM CODE TEST    23800000
         LA    ERREG1,ERR088A           SET RETN FROM OP CODE TEST      23850000
         BC    15,ERR088                                                23900000
         SPACE 1                                                        23950000
*              SET UP TO RETRY IF NOT SECOND OCCURRENCE                 24000000
         SPACE 1                                                        24050000
CHERR    XC    0(8,ERPIBRG),0(ERPIBRG)  ZERO ERPIB                      24100000
         LA    ERRLNK,ERR080            SET ERRLNK FOR RETRY            24150000
         TM    0(CCWREG),TIC            IS FIRST CCW A TIC              24200000
         BC    5,TESTMCS                NO-RETRY                        24250000
         MVC   IOBRST(3,IOBRG),1(CCWREG)  INITIALIZE RESTART ADDRESS    24300000
         BC    15,TESTMCS               GO RETRY THE REQUEST            24350000
         SPACE 1                                                        24400000
*              RETRY CODE = 111                                         24450000
ERR087   TM    CMNDCD(CCWREG),X'03'     TEST FOR CONTROL COMMAND        24500000
         BC    1,ERR086A                YES-BRANCH TO SET RETN CODES    24550000
         LR    ERREG2,ERRLNK            SET RETN FROM TERM CODE TEST    24600000
         LA    ERREG1,ERR088A           SET RETN FROM OP CODE TEST      24650000
ERR088   TM    CMNDCD(CCWREG),CONTRL    TEST OP CODE                    24700000
         BCR   1,ERREG1                 BRANCH IF CONTROL COMMAND       24750000
         TM    CMNDCD(CCWREG),WRITE     TEST OP CODE                    24800000
         BC    8,CHERR                  BRANCH IF READ                  24850000
         SPACE 1                                                        24900000
*        TEST TERMINATION CODE TO DETERMINE RETRY                       24950000
         SPACE 1                                                        25000000
ERR088A  TM    TERMCODE(ERPIBRG),TRMCOD40 TEST FOR TERMCODE=01          25050000
         BC    8,CHERR                  NO-RETRY                        25100000
         TM    TERMCODE(ERPIBRG),TRMCOD80  TEST FOR TERMCODE=10         25150000
         BC    1,CHERR                  YES-RETRY                       25200000
         BCR   15,ERREG2                                                25250000
         SPACE 1                                                        25300000
*     SET UP FOR INTERVENTION REQUIRED MESSAGE                          25350000
         SPACE 1                                                        25400000
ERR089   CLI   UCBLTS(UCBREG),LTSZER    FIRST BYTE OF UCBLTS ZERO       25450000
         BC    7,ERR089B                ZERO THE ERPIB                  25500000
         SPACE 1                                                        25550000
ERR089A  STH   TSTREG,UCBLTS(UCBREG)    RESTORE LAST RQE POINTER        25600000
ERR089B  TM    IOBECT(IOBRG),IOBCCH     ERROR COUNT OF ONE              25650000
         BC    1,ERR075                 YES-PERM ERROR                  25700000
         XC    0(8,ERPIBRG),0(ERPIBRG)  ZERO ERPIB                      25750000
         OI    IOBECT(IOBRG),IOBCCH     SET ERR COUNT                   25800000
         BC    15,ERR072                ISSUE INT REQ MESSAGE           25850000
         SPACE 1                                                        25900000
         SPACE 1                                                        25950000
*        BUILD MORE CCW'S IF NECESSARY AND THEN GO TO TPERR FOR         26000000
*        RECORDING                                                      26050000
         SPACE 1                                                        26100000
BUFLOG   EQU   *                                                        26150000
         NI    IOBFL3(IOBRG),X'FF'-IOBBUF   CLR BUFFER FLAG      M1785  26200000
         CLI   0(CCWREG),CHKCMD         CHECK DATA               A49456 26250000
         BC    8,ERR090B                YES,READ PLB             A49456 26300000
         CLI   0(CCWREG),PLBCMD         PLB TYPE                 A49456 26350000
         BC    7,ERR09E                 NO,CHECK OTHER TYPES     A49456 26400000
         SR    ERREG2,ERREG2            SET ERROR COUNT                 26450000
         LA    ERREG3,CHRCNT-1          SET CHAR COUNT                  26500000
         LA    ERREG4,DATA1(ERREG1)     POINT TO DIAG RD DATD           26550000
ERR09D   CLI   0(ERREG4),X'04'          TEST FOR PRINT ERROR     M1785  26600000
         BC    4,ERR09B                 YES-MOVE CHAR TO BUFFER         26650000
         MVI   CHRCNT(ERREG4),X'40'     NO-BLANK CHAR                   26700000
ERR09C   LA    ERREG4,1(ERREG4)         ADV CHAR POINTER                26750000
         BCT   ERREG3,ERR09D            LAST CHAR                       26800000
         BC    15,ERR09E                YES,CHECK OTHER TYPES     M1785 26850000
ERR09B   LA    ERREG2,1(ERREG2)         ADV ERR POINTER                 26900000
         STC   ERREG2,STCNT             SAVE ERROR COUNT          M1785 26950000
         LA    ERREG2,DATA1+CHRCNT-1(ERREG2,ERREG1) ERR CHR       M1785 27000000
         MVC   0(1,ERREG2),CHRCNT(ERREG4) PLB CHAR TO BUFFER            27050000
         SR    ERREG2,ERREG2            CLR CHAR ADDR             M1785 27100000
         IC    ERREG2,STCNT             RESTORE ERR COUNT         M1785 27150000
         CLI   STCNT,ERRCNT             TEN ERRORS?               M1785 27200000
         BC    4,ERR09C                 NO-CHECK NEXT CHAR              27250000
ERR09E   TM    IOBECT(IOBRG),IOBUCS     TEST FOR UCSB FLAG       M1785  27300000
         BC    1,ERR092                 YES,SET UP FOR UCSB      M1785  27350000
         MVC   IOBCSW+1(7,IOBRG),SAVECSW(ERREG1)  RESTORE CSW    M1785  27400000
         L     ERREG4,UCBSNSPT(UCBREG)  GET ADDR SENSE           A49456 27450000
         MVC   0(6,ERREG4),SAVESNS(ERREG1)  RESTORE UCB SNS      A49456 27500000
         MVC   IOBSNS(2,IOBRG),SAVESNS(ERREG1)  RESTORE IOB SNS  A49456 27550000
         TM    TYPFLG(ERREG1),UCSTYP    UCSB TYPE                M1785  27600000
         BC    1,ERR094                 YES,BUILD RECORD         M1785  27650000
ERR09A   EQU   *                                                        27700000
         MVC   TPRTNID(2,ERREG1),WTO    MOVE IN RETURN ID               27750000
         TM    IOBSNS(IOBRG),X'10'      TEST FOR EQC           @SA69284 27760021
         BC    8,ERR090                 NO-SKIP ADDTNL CHECKS  @SA69284 27770021
         TM    IOBSNS+1(IOBRG),X'70'    TEST FOR INT-REQ ERRS  @SA69284 27780021
         BC    7,ERR010                 YES-CLEAR MSG BIT      @SA69284 27790021
ERR090   OI    IOBFL3(IOBRG),IOBMSG     NO-SET MSG FLAG        @SA69284 27792021
         BC    15,ERR091                SKIP ADDR RESTORE      @SA69284 27794021
ERR010   MVC   IOBFL1(1,IOBRG),SAVERST(ERREG1)  RESTORE FLAG   @SA69284 27796021
         MVC   IOBRST(3,IOBRG),SAVERST+1(ERREG1) RESTORE ADDR  @SA69284 27798021
ERR091   OI    IOBFL3(IOBRG),IOBLOG     SET LOGOUT FLAG        @SA69284 27800021
         MVI   TPRCDID(ERREG1),RCDID    INSERT RECORD ID                27850000
         LH    ERREG1,TPERR             GET LOAD NAME TPERR             27900000
ERR090A  L     ERRETR,VECTXL(COMREG)    GET ADDR XCTL ROUTINE           27950000
         BCR   15,ERRETR                XCTL TPERR                      28000000
         SPACE 1                                                        28050000
*              SET UP FOR PLB ERROR                                     28100000
         SPACE 1                                                        28150000
ERR090B  LA    ERREG2,PLBCCW            GET CCW ADDR             A49456 28200000
         BAL   ERRLNK,ERR056A           GO SET UP CCW            A49456 28250000
         ST    ERREG4,IOBMDB(IOBRG)     SET RESTART ON NEW CCW   A49456 28300000
         BC    15,ERR020E               READ PLB                 A49456 28350000
         SPACE 1                                                        28400000
*              SET UP FOR UCS ERROR                                     28450000
         SPACE 1                                                        28500000
ERR092   LA    ERREG2,UCSCCW            GET CCW ADDR                    28550000
         BAL   ERRLNK,ERR056A           GO SET UP CCW                   28600000
         NI    IOBECT(IOBRG),X'FF'-IOBUCS  TURN OFF IOBUCS              28650000
         MVI   TYPFLG(ERREG1),UCSTYP    SET UCS TYPE             A49456 28700000
ERR092A  ST    ERREG4,IOBMDB(IOBRG)     SET RESTART ON NEW CCW          28750000
         BC    15,ERR090                GO TO TPERR              M1785  28800000
         SPACE                                                          28850000
*              FORMAT UCSB RECORD                                       28900000
         SPACE 1                                                        28950000
ERR094   NI    TYPFLG(ERREG1),X'FF'-UCSTYP  TURN OFF UCS TYPE           29000000
         MVI   RCDFLG(ERREG1),UCSFLG    INITIALIZE RECORD FLAG          29050000
         LA    ERREG2,UCSRSZE           GET RECORD SIZE                 29100000
ERR095   STH   ERREG2,RCDSIZE(ERREG1)   STORE RECORD SIZE               29150000
         MVC   UCSID(4,ERREG1),UCBUCSID(ERREG5)  MOVE UCSID TO RECORD   29200000
         BC    15,ERR09A                SET RTNID FOR WTO               29250000
         SPACE 1                                                        29300000
         SPACE 1                                                        29350000
WTO      DC    H'0253'                  LOAD NAME WTO RTN               29400000
TPERR    DC    H'6256'                  LOAD NAME FOR TPERR             29450000
ERRCN1   DC    AL2(8)                                                   29500000
UCSCCW   DC    X'0A00000020000200'      READ UCS                 A42862 29550000
FCBCCW   DC    X'12000000200000B4'      READ FCB                 M1785  29600000
CHKCCW   DC    X'0600000020000096'      CHECK READ               A49456 29650000
PLBCCW   DC    X'0200000020000096'      READ PLB                 A49456 29700000
STCNT    DS    H                        ERROR COUNT SAVE AREA           29750000
         DC    C'IGE0100F 218 4/8/74'                                   29760021
         END                                                            29800000
