         TITLE 'IGE0125E - DAVV - LOAD 1'                               00350021
IGE0125E START 0                                                   DAVV 00360021
*2547648000                                                      A43739 00400021
         EJECT                                                     DAVV 00600018
*              VOLUME LABEL VERIFICATION ROUTINE                   DAVV 00900018
         SPACE 3                                                   DAVV 01200018
*   FUNCTION   INSURE THAT DIRECT ACCESS DEVICES WHICH GO FROM A   DAVV 01500018
*              NOT READY TO A READY STATE HAVE THE SAME VOLUME     DAVV 01800018
*              SERIAL AS IS CONTAINED IN THE UCB.                       02100018
*   ENTRY      IGE0125E VIA XCTL FROM IGE0025E WHEN THE VOLUME     DAVV 02400018
*              VERIFICATION FLAG IS ON IN THE UCB.                 DAVV 02700018
*   INPUT      ENTRY POINT IN REG 15, RQE POINTER IN REG 1.        DAVV 03000018
*   OUTPUT     NONE.                                               DAVV 03300018
*   EXT REF.   NONE                                                DAVV 03600018
*   EXITS      1.  SVC 15 TO IOS TO EXECUTE THIS ROUTINE'S CHANNEL DAVV 03900018
*                  PROGRAM.                                        DAVV 04200018
*              2.  SVC 15 TO IOS TO EXECUTE USER'S CHANNEL PROGRAM.DAVV 04500018
*              3.  XCTL TO IGE0225E.                               DAVV 04800018
*              4.  SVC 3 TO RETURN CONTROL TO SUPERVISOR.          DAVV 05100018
*   TABLES     UCB,IOB.                                            DAVV 05400018
*   OPERATION  THE INITIAL ENTRY ROUTINE SETS UP THE CHANNEL       DAVV 05700018
*              PROGRAM TO READ THE VOLUME LABEL, AND ISSUES SVC 15 DAVV 06000018
*              TO HAVE IT EXECUTED.                                DAVV 06300018
*              THE VOLUME LABEL VERIFICATION ROUTINE EXAMINES      DAVV 06600018
*              CHANNEL PROGRAM RESULTS, AND IF THE VOLUME SERIAL   DAVV 06900018
*              IS CORRECT, ISSUES SVC 15 TO EXECUTE THE USER'S     DAVV 07200018
*              CHANNEL PROGRAM.  VOLUME SERIAL CONFLICTS AND       DAVV 07500018
*              I/O ERRORS CAUSE CONTROL TO BO TRANSFERRED TO       DAVV 07800018
*              IGE0225E.                                           DAVV 08100018
         EJECT                                                     DAVV 08400018
*              REGISTER DEFINITION                                 DAVV 08700018
TSTREG   EQU   1                        RQE POINTER                DAVV 09000018
UCBREG   EQU   2                        UCB POINTER                DAVV 09300018
IOBREG   EQU   3                        IOB POINTER                DAVV 09600018
WKREG1   EQU   4                        WORK REGISTER 1            DAVV 09900018
WKREG2   EQU   13                       WORK REGISTER 2            DAVV 10200018
WKREG3   EQU   5                        WORK REGISTER 3            DAVV 10500018
BASEREG  EQU   12                       BASE REGISTER              DAVV 10800018
CCWREG   EQU   10                       REG USED FOR BLDING CH PGM DAVV 11100018
CVTREG   EQU   6                        CVT POINTER                DAVV 11400018
SUCBREG  EQU   6                        SUB-UCB PTR FOR 2321      19022 11500019
DATAREG  EQU   7                        REG USED FOR BLDING CH PGM DAVV 11700018
SRCHREG  EQU   11                       REG USED FOR BLDING CH PGM DAVV 12000018
VOL1RG   EQU   9                        PTR TO VOLSER              DAVV 12300018
BUFREG   EQU   8                        BUFFER PTR FOR WTO RTN     DAVV 12600018
XCTLREG  EQU   14                       POINTER TO XCTL RTN        DAVV 12900018
UCBWKREG EQU   14                       WORK AREA POINTER         19022 13000019
LNKREG   EQU   15                       BRANCH AND LINK REG        DAVV 13200018
         SPACE 2                                                   DAVV 13500018
*              RQE DEFINITION                                      DAVV 13800018
TSTUCB   EQU   2                        UCB POINTER                DAVV 14100018
TSTIOB   EQU   4                        IOB POINTER                DAVV 14400018
TSTTCBID EQU   4                        TCB ID FOR MFT             DAVV 14700018
TSTDEB   EQU   9                        DEB POINTER                DAVV 15000018
TSTTCB   EQU   12                       TCB POINTER FOR MVT        DAVV 15300018
         SPACE 2                                                   DAVV 15600018
*              IOB FLAGS                                           DAVV 15900018
IOBEX    EQU   X'04'                    IOB EXCEPTION FLAG         DAVV 16200018
IOBERR   EQU   X'20'                    ERROR RTN IN CTL FLAG      DAVV 16500018
IOBSRS   EQU   X'01'                    RESTART FLAG               DAVV 16800018
IOBNET   EQU   X'08'                    NO EXTENT TEST FLAG        DAVV 17100018
IOBMSG   EQU   X'04'                    I/O ERR MSG FLAG           DAVV 17400018
IOBLOG   EQU   X'01'                    LOG OUT FLAG FOR I/O ERRS  DAVV 17700018
IOBHAR0  EQU   X'10'                    SUPVR PROTECT KEY FLAG     DAVV 18000018
         SPACE 3                                                  19022 18070019
*              DEVICE TYPES                                       19022 18140019
DEV2321  EQU   X'05'                    2321 DEVICE TYPE          19022 18210019
         SPACE 2                                                   DAVV 18300018
*              UCB FLAGS                                           DAVV 18600018
UCBVVRTN EQU   X'40'                    VOL VER RTN IN CONTROL     DAVV 18900018
FTFLAG   EQU   X'20'                    FLAG ON AFTER FIRST ENTRY  DAVV 19200018
TCCFLAG  EQU   X'10'                    FLAG FOR ALT TRK CHN PGM   DAVV 19500018
UCBVER   EQU   X'08'                    VOLUME VERIFIED FLAG       DAVV 19800018
UCBMNT   EQU   X'80'                    MOUNT REQUEST BY IGE0225E  DAVV 20100018
*                                       OR BY DATA MGT. OR SCHED A28578 20200019
*                                       IN SRTEDMCT FIELD        A28578 20300019
UCBNRY   EQU   X'40'                    NOT READY FLAG IN UCBFL1   DAVV 20400018
         SPACE 2                                                   DAVV 20700018
*              UCB OFFSETS                                         DAVV 21000018
UCBVS    EQU   28                       OFFSET IN WKAREA FOR VOLSERDAVV 21300018
UCBALTHA EQU   16                       OFFSET TO HA AFTER TCC     DAVV 21600018
UCBALTR0 EQU   21                       OFFSET TO REC 0 AFTER TCC  DAVV 21900018
UCBID    EQU   34                       OFFSET TO SRCH ID ARGUMNT  DAVV 22200018
UCBWKPFX EQU   104                      OFFSET TO NORMAL WKAREA    DAVV 22500018
DCELBIN  EQU   0                        OFFSET IN SUBUCB TO BIN   19022 22600019
DCELVOL1 EQU   4                        OFFSET IN SUBUCB TO VOLSR 19022 22700019
         SPACE 2                                                   DAVV 22800018
*              DEFINITIONS FOR BUILDING CHANNEL PROGRAM            DAVV 23100018
RDHACM   EQU   X'1A'                    READ HOME ADDRESS CM       DAVV 23400018
RDR0CM   EQU   X'16'                    READ RECORD 0 COMMAND      DAVV 23700018
CMCHNSLI EQU   X'60'                    COMMAND CHAIN,SUPP INC LEN DAVV 24000018
FIVECNT  EQU   5                        COUNT FOR RDHA,RDR0,SIDEQ  DAVV 24300018
REC03    EQU   3                        VOLUME LABEL IS RECORD 3   DAVV 24600018
IDR      EQU   4                        OFFSET TO R IN CCHHR       DAVV 24900018
SIDCM    EQU   X'31'                    SEARCH ID EQUAL COMMAND    DAVV 25200018
RDHACCW  EQU   0                        OFFSET TO READ HA CMD      DAVV 25500018
RDR0CCW  EQU   8                        OFFSET TO READ R0 COMMAND  DAVV 25800018
SIDCCW   EQU   0                        OFFSET TO S ID EQ CM       DAVV 26100018
TICCCW   EQU   8                        OFFSET TO TIC COMMAND      DAVV 26400018
TICCM    EQU   X'08'                    TRANSFER IN CHANNEL COMMANDDAVV 26700018
RDCCW    EQU   16                       OFFSET TO READ COMMAND     DAVV 27000018
RDDATACM EQU   X'06'                    READ DATA COMMAND          DAVV 27300018
SLI      EQU   X'20'                    SUPPRESS INCORRECT LENGTH  DAVV 27600018
RKB      EQU   X'13'                    RECALIBRATE COMMAND      A43739 27700021
NOP      EQU   X'03'                    NO OPERATION COMMAND     A43739 27800021
         SPACE 2                                                   DAVV 27900018
*              STATUS AND SENSE INDICATORS                         DAVV 28200018
UNITCK   EQU   X'02'                    UNIT CHECK STATUS          DAVV 28500018
INTREQ   EQU   X'40'                    INTERVENTION REQUIRED SNS  DAVV 28800018
TRKCNDCK EQU   X'02'                    TRACK COND CHECK SENSE     DAVV 29100018
UEX      EQU   X'01'                    UNIT EXCEPTION STATUS      DAVV 29400018
SEEKCK   EQU   X'01'                    SEEK CHECK SENSE         A43739 29500021
         SPACE 2                                                   DAVV 29700018
*              WTO AND BUFFER DEFINITIONS                          DAVV 30000018
DISMLEN  EQU   24                       LENGTH OF DISMOUNT MSG     DAVV 30300018
BLANK    EQU   X'40'                    EBCDIC BLANK               DAVV 30600018
COMMA    EQU   X'EF'                    UNTRANSLATED COMMA         DAVV 30900018
TCOMMA   EQU   C','                     TRANSLATED COMMA           DAVV 31200018
MNTMSGLN EQU   26                       LENGTH OF MOUNT MSG        DAVV 31500018
JOBNMLN  EQU   8                        LENGTH OF JOB NAME         DAVV 31800018
CHANMSK  EQU   X'0F'                    MASK FOR VALID CHANNELS    DAVV 32100018
DISMOUNT EQU   C'D'                     DISMOUNT COMMAND           DAVV 32400018
MOUNT    EQU   C'M'                     MOUNT COMMAND              DAVV 32700018
CODE4    EQU   C'4'                     MESSAGE CODE               DAVV 33000018
CODE5    EQU   C'5'                     MESSAGE CODE               DAVV 33300018
         SPACE 2                                                   DAVV 33600018
*              MISCELLANEOUS DEFINITIONS                           DAVV 33900018
CVTPTR   EQU   16                       CORE LOC OF CVT POINTER    DAVV 34200018
CVTXCTL  EQU   X'2C'                    POINTER TO XCTL RTN        DAVV 34500018
CVTHEAD  EQU   X'A0'                    HI PRIORITY TCB FOR MFT    DAVV 34800018
CVTMACSZ EQU   164                      MACHINE SIZE IN CVT        DAVV 35100018
CVTCONFG EQU   X'74'                    OFFSET TO CONFIG. FLAG     DAVV 35400018
DCBFL    EQU   X'2C'                    OFFSET IN DCB OF IOS FLAGS DAVV 35700018
DCBPER   EQU   X'C0'                    IOS ERROR FLAGS IN DCBFL   DAVV 36000018
MVT      EQU   X'10'                    MVT INDICATOR IN CVT       DAVV 36300018
MFT      EQU   X'20'                    MFT INDICATOR IN CVT       DAVV 36600018
PCP      EQU   X'40'                    PCP INDICATOR IN CVT       DAVV 36900018
CVTK     EQU   X'2C'                    CONSTANT FOR LOOP INIT     DAVV 37200018
TCBTIOT  EQU   12                       TIOT POINTER               DAVV 37500018
TCBNEXT  EQU   X'74'                    TCB CHAIN                  DAVV 37800018
DEBTCB   EQU   0                        TCB POINTER                DAVV 38100018
TIOTJOBN EQU   0                        JOB NAME POINTER           DAVV 38400018
WTORA    EQU   253                      LOAD NAME OF WTO ERR RTN   DAVV 38700018
MAXERR   EQU   10                       MAXIMUM NUMBER OF RETRIES  DAVV 39000018
NORMC    EQU   X'7F'                    NORMAL COMPLETION FLAG     DAVV 39300018
VVRLD2   EQU   2255                     LOAD NAME OF IGE0225E      DAVV 39600018
ERREXCP  EQU   15                       SVC 15                     DAVV 39900018
EXIT     EQU   3                        SVC 3                      DAVV 40200018
ZERO     EQU   0                        ZERO COMPARAND             DAVV 40500018
NONWORD  EQU   3                        NON-FULL-WORD BOUNDARY     DAVV 40800018
SUCBLN   EQU   16                       LENGTH OF SUB-UCB         19022 40900019
SUCBMAX  EQU   160                      FIRST BYTE AFTER SUB-UCBS 19022 41000019
         EJECT                                                     DAVV 41100018
*****                                                        ***** DAVV 41400018
*                    INITIAL ENTRY ROUTINE                       * DAVV 41700018
*****                                                        ***** DAVV 42000018
*                                                                * DAVV 42300018
*   THIS ROUTINE IS EXECUTED THE FIRST TIME IGE0125E IS ENTERED  * DAVV 42600018
*   DURING THE PROCESSING OF AN ASYNCHRONOUS DEVICE END          * DAVV 42900018
*   INTERRUPT ON A DIRECT ACCESS DEVICE.  ITS FUNCTIONS INCLUDE  * DAVV 43200018
*   INITIALIZATION OF UCB AND IOB FIELDS, AND SETTING UP THE     * DAVV 43500018
*   BASIC CHANNEL PROGRAM.                                       * DAVV 43800018
*****                                                        ***** DAVV 44100018
         SPACE 1                                                   DAVV 44400018
         USING *,BASEREG                                           DAVV 44700018
INITENT  LR    BASEREG,15               ESTAB ADDRESSABILITY       DAVV 45000018
         LH    UCBREG,TSTUCB(0,TSTREG)  GET UCB ADDRESS            DAVV 45300018
         L     IOBREG,TSTIOB(0,TSTREG)  GET IOB ADDRESS            DAVV 45600018
         USING UCBDSECT,UCBREG          ESTAB ADDR'TY FOR UCB      DAVV 45900018
         USING IOBDSECT,IOBREG          ESTAB ADDR'TY FOR IOB      DAVV 46200018
         L     UCBWKREG,UCBWORK         GET WORK AREA POINTER     19022 46300019
         CLI   UCBTYP+3,DEV2321         TEST FOR 2321             19022 46400019
         BC    7,INIT001                NO, BRANCH                19022 46500019
         L     UCBWKREG,UCBWKB          GET 2321 WKAREA POINTER   19022 46600021
INIT001  LA    UCBWKREG,UCBWKPFX(0,UCBWKREG) UPDATE PAST PREFIX SA68917 46610021
         TM    UCBFL4,UCBMNT            TEST IF MOUNT MSG ISSUE SA57136 46650021
         BC    14,NODOM                 NO,SKIP                 SA57136 46660021
    SPACE 1                                                     SA57136 46680021
*   THIS SUBROUTINE DELETES THE OPERATOR MESSAGES GRAPHICS      SA57136 46690021
*     CONSOLES UNDER MCS.                                       SA57136 46692021
DOMRTN   NI    UCBFL4,X'FF'-UCBMNT      TURN OFF MOUNT FLAG     SA57136 46694021
         LR    WKREG2,TSTREG            SAVE REG OVER SVC       SA57136 46696021
         LR    1,UCBWKREG               INIT INPUT REG FOR DOM  SA57136 46698021
*        DOM   MSGLIST=(1)              DOM MACRO               SA57136 46698421
         LNR   0,1                                              SA57136 46698821
         SVC   87                                               SA57136 46699221
         LR    TSTREG,WKREG2            RESTORE REG             SA57136 46699621
         OI    UCBFL4,FTFLAG            TURN ON FIRST TIME FLAG SA68917 46749621
         B     REBLD                    GO REBUILD DAVV'S CP    SA68917 46799621
NODOM    TM    UCBFL4,FTFLAG            TEST FOR FIRST TIME THRU   DAVV 46800021
         BC    1,VOLVER                 NO, GO TO CHECK RESULTS    DAVV 47100018
PRGENT   L     WKREG1,IOBDCB            GET DCB POINTER          A28578 47400019
         NI    DCBFL(WKREG1),X'FF'-DCBPER  RESET ERROR FLAGS       DAVV 47700018
         STH   TSTREG,UCBRQESV          SAVE RQE ADDR FOR IOS    A28578 47740019
         NC    IOBFL1(4),IOBFLMSK       CLEAR FLAGS AND SENSE    A28578 47780019
         OI    IOBFL1,IOBERR+IOBSRS     TURN ON IOB FLAGS        A28578 47820019
         CLI   UCBTYP+3,DEV2321         TEST FOR 2321             19022 47860019
         BC    8,PRG001                 YES, SKIP TEST            19022 47900019
         CLI   UCBVOL1,ZERO             TST MNT REQST SINCE INTPT 19022 48000019
         BC    8,NORMRET                YES,NO VERIFICATION NEEDED DAVV 48300018
         TM    UCBDMCT,UCBMNT           TEST MOUNT BIT           A28578 48400019
         BC    1,NORMRET                ON-NO VERIFICATION NEC   A28578 48500019
PRG001   NI    UCBFL4,UCBVVRTN          CLEAR FLAGS               19022 48600019
         OI    UCBFL4,FTFLAG            TURN ON FIRST TIME FLAG    DAVV 48900018
         XC    IOBFL3(9),IOBFL3         CLEAR FLAGS, CSW FIELDS    DAVV 49800018
         XC    IOBECT(2),IOBECT         ZERO ERROR COUNT IN IOB    DAVV 50100018
         MVI   IOBECB,NORMC             SET NORMAL COMPLETION FLAG DAVV 50400018
         OI    IOBFL2,IOBNET+IOBHAR0    SET IOB FLAGS              DAVV 51000018
         MVC   UCBSKA(1),IOBSEEK        INIT M FROM IOB          A29995 51100019
         XC    UCBSKA+1(6),UCBSKA+1     INIT BBCCHH                DAVV 51300018
         MVI   UCBSKA+7,REC03           SET TO RECORD 3            DAVV 51600018
ERRETRY  CLI   UCBTYP+3,DEV2321         TEST FOR 2321             19022 51800019
         BC    8,DCELRTN                YES, GO TO HANDLE         19022 52000019
CCWBLD   LR    CCWREG,UCBWKREG          INIT CCW REG              19022 52200019
         ST    CCWREG,IOBRESTR-1        STORE RESTART ADR FOR IOS 19022 52400019
         LA    SRCHREG,UCBID(0,CCWREG)  POINT TO SRCH ID ARGUMENT  DAVV 52800018
         XC    0(4,SRCHREG),0(SRCHREG)  CCHH = 0                   DAVV 53100018
         MVI   IDR(SRCHREG),REC03       INIT TO RECORD 3           DAVV 53400018
         LA    DATAREG,UCBVS-4(0,CCWREG)  POINT TO VOL LBL BUFFER  DAVV 53700018
         SPACE 1                                                   DAVV 54000018
*   BUILD CHANNEL PROGRAM TO READ THE VOLUME LABEL.                DAVV 54300018
REBLD    ST    SRCHREG,SIDCCW(0,CCWREG)  STORE SRCH ARG PTR     SA68917 54600021
         MVI   SIDCCW(CCWREG),SIDCM     MOVE SEARCH ID EQUAL CMD   DAVV 54900018
         MVI   SIDCCW+4(CCWREG),CMCHNSLI  SET CMD CHAIN AND SILI   DAVV 55200018
         LA    WKREG2,FIVECNT           GET ID COUNT OF 5          DAVV 55500018
         STH   WKREG2,SIDCCW+6(0,CCWREG)  STORE COUNT INTO CCW     DAVV 55800018
         ST    CCWREG,TICCCW(0,CCWREG)  STORE TIC ADDRESS          DAVV 56100018
         MVI   TICCCW(CCWREG),TICCM     MOVE TIC COMMAND           DAVV 56400018
         ST    DATAREG,RDCCW(0,CCWREG)  STORE BUF ADR FOR VOL LBL  DAVV 56700018
         MVI   RDCCW(CCWREG),RDDATACM   MOVE READ DATA COMMAND     DAVV 57000018
         MVI   RDCCW+4(CCWREG),SLI      SET SUPPRESS INCORRECT LEN DAVV 57300018
         ALR   WKREG2,WKREG2            GET COUNT OF 10 FOR VOLLBL DAVV 57600018
         STH   WKREG2,RDCCW+6(0,CCWREG)  STORE RD DATA COUNT OF 10 DAVV 57900018
         SVC   ERREXCP                  RETURN TO IOS              DAVV 58200018
         SVC   EXIT                     RETURN TO SUPERVISOR       DAVV 58500018
         SPACE 3                                                  19022 58510019
*   THIS ROUTINE LOOPS THROUGH THE SUB-UCBS LOOKING FOR A BIN     19022 58520019
*     WHICH REQUIRES VOLUME SERIAL VERIFICATION.  IT THEN         19022 58530019
*     INITIALIZES THE BB IN THE SEEK ADDRESS.  IF BIN 9 IS        19022 58540019
*     ACCESSED AND DOES NOT REQUIRE PROCESSING, THE VOLUME        19022 58550019
*     VERIFIED EXIT IS TAKEN.                                     19022 58560019
DCELRTN  SR    WKREG1,WKREG1            CLEAR WORK REG            19022 58570019
         IC    WKREG1,IOBDCCNT          GET CURRENT SUB-UCB OFFST 19022 58580019
DCEL001  LA    SUCBREG,UCBBINNO(WKREG1) POINT TO SUB-UCB          19022 58590019
         CLI   DCELVOL1(SUCBREG),ZERO   TEST IF VER REQUIRED      19022 58600019
         BC    8,UPDATCEL               NO, GO TO GET NEXT        19022 58610019
         MVC   UCBSKA+1(2),DCELBIN(SUCBREG) INIT BB IN SK ADDR    19022 58620019
         BC    15,CCWBLD                GO TO BUILD CHN PGM       19022 58630019
         SPACE 1                                                  19022 58640019
UPDATCEL LA    WKREG1,SUCBLN(0,WKREG1)  UPDATE TO NEXT SUB-UCB    19022 58650019
         STC   WKREG1,IOBDCCNT          STORE BACK IN BIN CNTR    19022 58660019
         CLI   IOBDCCNT,SUCBMAX         CHECK IF LAST BIN PROC'D  19022 58670019
         BC    4,DCEL001                NO, GO TO PROCESS         19022 58680019
         BC    15,NORMRET               YES, GO TO EXIT RTN       19022 58690019
         EJECT                                                     DAVV 58800018
*****                                                        ***** DAVV 59100018
*    VOLUME LABEL VERIFICATION AND DENSITY CHECKING ROUTINE      * DAVV 59400018
*****                                                        ***** DAVV 59700018
*                                                                * DAVV 60000018
*   THIS ROUTINE IS ENTERED AFTER THE INITIAL ENTRY ROUTINE'S    * DAVV 60300018
*   CHANNEL PROGRAM IS EXECUTED.  ITS FUNCTION IS TO INSURE THAT * DAVV 60600018
*   THE PACK WITH THE PROPER VOLUME SERIAL IS MOUNTED AND IF SO, * DAVV 60900018
*   TO ISSUE AN SVC 15 TO RETURN TO IOS TO EXECUTE THE USER'S    * DAVV 61200018
*   CHANNEL PROGRAM.  IF NOT, A DISMOUNT MESSAGE AND A MOUNT     * DAVV 61500018
*   MESSAGE WILL BE ISSUED TO THE OPERATOR AFTER CONTROL IS      * DAVV 61800018
*   TRANSFERRED TO IGE0225E.                                     * DAVV 62100018
*****                                                        ***** DAVV 62400018
         SPACE 1                                                   DAVV 62700018
VOLVER   CH    TSTREG,UCBRQESV          CHECK IF RQE WAS PURGED SA57136 63600021
         BC    7,PRGENT                 YES, RETURN TO I.E.R.      DAVV 63900018
         LH    WKREG1,IOBCSW+3          GET STATUS IN REG          DAVV 64200018
         N     WKREG1,ERRMSK            CHECK FOR ERROR STATUS     DAVV 64500018
         BC    4,LKFORUCK               YES,GO CHECK FOR SEEK    A43739 64700021
*                                       CHK                      A43739 64900021
         TM    UCBFL4,TCCFLAG           TEST FOR ALT TRK PROC      DAVV 65100018
         BC    1,TCCRCVRY               YES, GO TO INIT FOR RETRY  DAVV 65400018
         TM    IOBCSW+3,UEX             TEST FOR UNIT EXCEPTION    DAVV 65700018
         BC    1,XCTL225E               YES, GO TO HANDLE          DAVV 66000018
         LA    VOL1RG,UCBVOL1           GET VOLSER PTR             DAVV 66300018
         CLI   UCBTYP+3,DEV2321         TEST FOR 2321             19022 66400019
         BC    7,VV001                  NO, BRANCH                19022 66500019
         TM    IOBFL2,IOBNET            WAS LAST OP A            A43739 66520021
*                                       RECALIBRATE              A43739 66540021
         BZ    XCTL225E                 GO HANDLE                A43739 66560021
         SR    WKREG1,WKREG1            CLEAR REG                 19022 66600019
         IC    WKREG1,IOBDCCNT          BET SUB-UCB OFFSET        19022 66700019
         LA    VOL1RG,UCBDCVOL(WKREG1)  POINT TO VOLSER IN SUBUCB 19022 66800019
VV001    LA    DATAREG,UCBVS(0,UCBWKREG) POINT TO VOLSER READ     19022 66900019
         CLC   0(6,VOL1RG),0(DATAREG)   VOLSER SAME AS PACK M'NTED DAVV 67200018
         BC    7,XCTL225E               NO, GO TO ISSUE MSG        DAVV 67500018
         CLI   UCBTYP+3,DEV2321         TEST FOR 2321             19022 67600019
         BC    8,UPDATCEL               YES, GO TO HANDLE         19022 67700019
         SPACE 1                                                   DAVV 67800018
*   THIS IS THE RETURN POINT FOR CLEARING ALL IGE0125E FIELDS      DAVV 68100018
*     IN THE UCB AND IOB, AND RE-INITIALIZING THEM TO EXECUTE      DAVV 68400018
*     THE USER'S CHANNEL PROGRAM.                                  DAVV 68700018
NORMRET  NC    IOBFL1(4),IOBFLMSK       CLEAR FLAGS AND SENSE      DAVV 69000018
         XC    IOBFL3(9),IOBFL3         CLEAR IOB FLAGS,CSW,SIOCC  DAVV 69300018
         XC    IOBECT(2),IOBECT         CLEAR ERROR COUNT          DAVV 69600018
         MVI   IOBECB,NORMC             SET NORMAL COMPLETION FLAG DAVV 69900018
         OI    UCBFL4,UCBVER            INDICATE VOLUME VERIFIED   DAVV 70500018
         SVC   ERREXCP                  RET TO IOS TO TRY USER CP  DAVV 70800018
         SVC   EXIT                     RET TO SUPERVISOR          DAVV 71100018
LKFORUCK TM    IOBCSW+3,UNITCK          WAS ERROR A UNIT CHECK   A43739 71110021
         BNO   XCTL225E                 NO, GO TO HANDLE         A43739 71120021
         TM    IOBSNS,SEEKCK            WAS ERROR A SEEK CHECK   A43739 71130021
         BNO   XCTL225E                 NO, GO TO HANDLE         A43739 71140021
         SPACE                                                          71150021
*  IN THE CASE OF A SEEK CHECK, BUILD A RECALIBRATE CCW BEFORE          71160021
*  TRYING TO RESTART THE VOLUME LABLE CHANNEL PROGRAM                   71170021
         NI    IOBFL2,X'FF'-IOBNET      INDICATE DAVV-TYPE NO    A43739 71180021
*                                       SEEK                     A43739 71190021
         LA    CCWREG,UCBVS-4(UCBWKREG) POINT TO SPARE WORK AREA A43739 71200021
         ST    CCWREG,IOBRESTR-1        STORE RESTART ADR FOR    A43739 71210021
*                                       IOS                      A43739 71220021
         MVC   0(16,CCWREG),RECAL       SET UP CCWS FOR          A43739 71230021
*                                       RECALIBRATE              A43739 71240021
         SVC   ERREXCP                  RETURN TO IOS            A43739 71250021
         SVC   EXIT                     RETURN TO SUPERVISOR     A43739 71260021
         EJECT                                                     DAVV 71400018
*   THIS SUBROUTINE TAKES THE CCHH READ IN RECORD 0 BY THE         DAVV 71700018
*     ALTERNATE TRACK PROCEDURE, AND UPDATES THE SEEK ADDRESS IN   DAVV 72000018
*     THE INITIAL ENTRY ROUTINE'S CHANNEL PROGRAM WITH IT.         DAVV 72300018
TCCRCVRY NI    UCBFL4,X'FF'-TCCFLAG     TURN OFF ALT TRK PROC FLAG DAVV 72600018
         MVC   UCBSKA+3(4),UCBALTR0(UCBWKREG) MOVE CCHH           19022 73000019
         MVI   IOBECT+1,ZERO            SET ERROR COUNT TO 0       DAVV 73500018
         BC    15,ERRETRY               GO TO RETRY ORIG CHN PGM   DAVV 73550021
         SPACE 1                                                   DAVV 77100018
*   THIS ROUTINE TRANSFERS CONTROL TO IGE0225E TO PROCESS          DAVV 77400018
*     OPERATOR MESSAGES AND ERROR CONDITIONS.                      DAVV 77700018
XCTL225E LA    WKREG2,VVRLD2            GET LOAD NAME OF IGE0225E  DAVV 78000018
         L     CVTREG,CVTPTR            GET ADDR OF CVT           19022 78100019
         L     XCTLREG,CVTXCTL(0,CVTREG)  GET PTR TO XCTL RTN      DAVV 78300018
         BCR   15,XCTLREG               GO TO XCTL                 DAVV 78600018
         EJECT                                                     DAVV 78900018
*****                                                        ***** DAVV 79200018
*                                                                * DAVV 79500018
*             CONSTANTS, MESSAGES, AND WORK AREAS                * DAVV 79800018
*                                                                * DAVV 80100018
*****                                                        ***** DAVV 80400018
         DS    0F                                                  DAVV 80700018
ERRMSK   DC    X'0000027F'              MASK FOR CSW STATUS ERRORS DAVV 81000018
IOBFLMSK DC    X'E2010000'              IOBCDS,IOBERR,IOBURL,QSAM  DAVV 81300018
RECAL    CCW   RKB,1,CMCHNSLI,1         RECALIBRATE CCW          A43739 81400021
         CCW   NOP,1,0,1                NO OPERATION CCW         A43739 81500021
PATCH    EQU   *                        START OF PATCH AREA             81550021
         DC    (1024-(PATCH-INITENT))X'00'                              81560021
         EJECT                                                     DAVV 81600018
*   DUMMY CONTROL SECTION FOR A UCB                                DAVV 81900018
UCBDSECT DSECT                                                     DAVV 82200018
         DS    AL3                      JOB NO.,ALLOC CHN MSK,ID   DAVV 82500018
UCBSTAT  DS    XL1                      STATUS A FLAGS             DAVV 82800018
UCBCUA   DS    H                        CHANNEL AND UNIT ADDRESS   DAVV 83100018
UCBFL1   DS    XL1                      FLAGS 1 - IOS FLAGS        DAVV 83400018
         DS    XL2                      INDECES                    DAVV 83700018
UCBSTI   DS    XL1                      INDEX TO STAT TABLE        DAVV 84000018
         DS    XL3                      INDECES                    DAVV 84300018
UCBUTN   DS    XL3                      UNIT NAME IN EBCDIC        DAVV 84600018
UCBTYP   DS    F                        DEVICE DESCRIPTOR WORD     DAVV 84900018
UCBLTS   DS    H                        LAST RQE                   DAVV 85200018
UCBSNS   DS    XL6                      SENSE INFORMATION          DAVV 85500018
UCBVOL1  DS    XL6                      VOLUME SERIAL              DAVV 85800018
         DS    XL1                      STATUS BYTE              A28578 85900019
UCBDMCT  DS    XL1                      DATA MGT. COUNT FIELD    A28578 86000019
         DS    XL6                      VOL INFO, RES/RELSE      A28578 86100019
UCBRQESV DS    H                        RQE SAVE FOR VOL. VER. RTN DAVV 86400018
UCBCNTR  DS    XL1                      BITS 0-3 2321 BIN COUNTER  DAVV 86700018
UCBFL4   EQU   UCBCNTR                  BITS 4-7 FLAGS FOR VVR     DAVV 87000018
         DS    XL3                      UNUSED                     DAVV 87300018
UCBSKA   DS    2F                       LAST SEEK ADDRESS          DAVV 87600018
         DS    F                        NO. USERS,ECB              DAVV 87900018
UCBWORK  DS    F                        WORK AREA POINTER          DAVV 88200018
         SPACE 1                                                  19022 88220019
*     UCB EXTENSION FOR DATA CELL                                 19022 88240019
         ORG   UCBVOL1                                            19022 88260019
UCBWKA   DS    XL12                     DATA CELL WORK AREA A     19022 88280019
         DS    4F                       RES/REL,VOL VER,SEEK ADR  19022 88300019
*     DESCRIPTION OF CELL ZERO                                    19022 88320019
UCBBINNO DS    H                        BIN NUMBER                19022 88340019
         DS    H                        VOLUME AND CELL STATUS    19022 88360019
UCBDCVOL DS    XL6                      CELL VOLUME SERIAL        19022 88380019
         DS    XL6                      CELL INFORMATION          19022 88400019
         DS    36F                      NINE MORE SUB-UCBS        19022 88420019
UCBWKB   DS    F                        WORK AREA POINTER         19022 88440019
         EJECT                                                     DAVV 88500018
*   DUMMY CONTROL SECTION FOR AN IOB                               DAVV 88800018
IOBDSECT DSECT                                                     DAVV 89100018
IOBFL1   DS    XL1                      I/O FLAGS 1                DAVV 89400018
IOBFL2   DS    XL1                      I/O FLAGS 2                DAVV 89700018
IOBSNS   DS    H                        SENSE INFORMATION          DAVV 90000018
IOBECB   DS    F                        ECB POINTER                DAVV 90300018
IOBFL3   DS    XL1                      I/O FLAGS 3                DAVV 90600018
IOBCSW   DS    XL7                      LAST CSW                   DAVV 90900018
IOBSTART DS    F                        CHANNEL PROGRAM POINTER    DAVV 91200018
IOBDCB   DS    F                        POINTER TO DCB             DAVV 91500018
         DS    XL1                      OP CODE                    DAVV 91800018
IOBRESTR DS    XL3                      RESTART ADDR FOR IOS       DAVV 92100018
         DS    H                        ACCESS METHOD FIELD        DAVV 92400018
IOBECT   DS    H                        ERROR COUNT FOR RETRIES    DAVV 92700018
IOBDCCNT EQU   IOBECT                   BIN COUNTER FOR 2321      19022 92800019
IOBSEEK  DS    2F                       SEEK ADDRESS               DAVV 93000018
*0320000200-026800                                                 DAVV 93300018
         END                                                            93600018
