         TITLE 'IGE0225E - DAVV - LOAD 2'                               00210021
IGE0225E START 0                                                   DAVV 00220021
         EJECT                                                     DAVV 00400018
*              VOLUME LABEL VERIFICATION ROUTINE                   DAVV 00600018
         SPACE 3                                                   DAVV 00800018
*   FUNCTION   INSURE THAT DIRECT ACCESS DEVICES WHICH GO FROM A   DAVV 01000018
*              NOT READY TO A READY STATE HAVE THE SAME VOLUME     DAVV 01200018
*              SERIAL AS IS CONTAINED IN THE UCB.                  DAVV 01400018
*   ENTRY      IGE0225E VIA XCTL FROM IGE0125E WHEN AN ERROR       DAVV 01600018
*              CONDITION EXISTS.                                   DAVV 01800018
*   INPUT      ENTRY POINT IN REG 15, RQE POINTER IN REG 1.        DAVV 02000018
*   OUTPUT     CONSOLE MESSAGES VIA WTO MACRO.                     DAVV 02200018
*   EXT REF.   NONE                                                DAVV 02400018
*   EXITS      1.  SVC 15 TO IOS.                                  DAVV 02600018
*              2.  SVC 3 TO RETURN CONTROL TO SUPERVISOR.          DAVV 02800018
*              3.  XCTL TO WTO ERROR ROUTINE.                      DAVV 03000018
*   MESSAGES   THREE TYPES OF CONSOLE MESSAGES ARE                 DAVV 03200018
*              1.  DISMOUNT MESSAGE                                DAVV 03400018
*              2.  MOUNT MESSAGE                                   DAVV 03600018
*              3.  VOLUME LABEL ERROR MESSAGE.                     DAVV 03800018
*   TABLES     UCB,IOB.                                            DAVV 04000018
*   OPERATION  A TEST IS MADE TO DETERMINE IS AN ERROR CONDITION   DAVV 04200018
*              EXISTS.  IF NOT, THIS MODULE GAINED CONTROL DUE TO  DAVV 04400018
*              A MOUNTED VOLUME WITH AN INCORRECT VOLUME SERIAL,   DAVV 04600018
*              AND A DISMOUNT MESSAGE AND A MOUNT MESSAGE ARE      DAVV 04800018
*              WRITTEN TO THE OPERATOR.  IF AN ERROR CONDITION     DAVV 05000018
*              EXISTS, THE CHANNEL PROGRAM IS RETRIED UNTIL        DAVV 05200018
*              CORRECTED OR A MAXIMUM OF TEN TIMES.  IF THE        DAVV 05400018
*              ERROR PERSISTS, A BAD VOLUME LABEL MESSAGE AND      DAVV 05600018
*              A MOUNT MESSAGE ARE WRITTEN TO THE OPERATOR.        DAVV 05800018
         EJECT                                                     DAVV 06000018
*              REGISTER DEFINITION                                 DAVV 06200018
TSTREG   EQU   1                        RQE POINTER                DAVV 06400018
UCBREG   EQU   2                        UCB POINTER                DAVV 06600018
IOBREG   EQU   3                        IOB POINTER                DAVV 06800018
INCREG   EQU   4                        INCREMENT VALUE FOR BUF   19022 07000019
WKREG2   EQU   13                       WORK REGISTER 2            DAVV 07200018
WKREG3   EQU   5                        WORK REGISTER 3            DAVV 07400018
BASEREG  EQU   12                       BASE REGISTER              DAVV 07600018
CCWREG   EQU   10                       REG USED FOR BLDING CH PGM DAVV 07800018
CVTREG   EQU   6                        CVT POINTER                DAVV 08000018
DATAREG  EQU   7                        REG USED FOR BLDING CH PGM DAVV 08200018
PARMREG  EQU   7                        PARM REG FOR WTO RTN      19022 08300019
UCBWKREG EQU   11                       PTR TO UCB WKAREA          DAVV 08400018
VOL1RG   EQU   9                        PTR TO VOLSER              DAVV 08600018
BUFREG   EQU   8                        BUFFER PTR FOR WTO RTN     DAVV 08800018
XCTLREG  EQU   14                       POINTER TO XCTL RTN        DAVV 09000018
SUCBREG  EQU   14                       SUB UCB POINTER FOR 2321  19022 09100019
LNKREG   EQU   15                       BRANCH AND LINK REG        DAVV 09200018
         SPACE 2                                                   DAVV 09400018
*              RQE DEFINITION                                      DAVV 09600018
TSTUCB   EQU   2                        UCB POINTER                DAVV 09800018
TSTIOB   EQU   4                        IOB POINTER                DAVV 10000018
TSTTCBID EQU   4                        TCB ID FOR MFT             DAVV 10200018
TSTDEB   EQU   9                        DEB POINTER                DAVV 10400018
TSTTCB   EQU   12                       TCB POINTER FOR MVT        DAVV 10600018
         SPACE 2                                                   DAVV 10800018
*              IOB FLAGS                                           DAVV 11000018
IOBEX    EQU   X'04'                    IOB EXCEPTION FLAG         DAVV 11200018
IOBERR   EQU   X'20'                    ERROR RTN IN CTL FLAG      DAVV 11400018
IOBSRS   EQU   X'01'                    RESTART FLAG               DAVV 11600018
IOBNET   EQU   X'08'                    NO EXTENT TEST FLAG        DAVV 11800018
IOBMSG   EQU   X'04'                    I/O ERR MSG FLAG           DAVV 12000018
IOBLOG   EQU   X'01'                    LOG OUT FLAG FOR I/O ERRS  DAVV 12200018
IOBHAR0  EQU   X'10'                    SUPVR PROTECT KEY FLAG     DAVV 12400018
         SPACE 2                                                   DAVV 12600018
*              DEVICE TYPES                                       19022 12650019
DEV2321  EQU   X'05'                    2321 DEVICE TYPE          19022 12700019
         SPACE 3                                                  19022 12750019
*              UCB FLAGS                                           DAVV 12800018
UCBVVRTN EQU   X'40'                    VOL VER RTN IN CONTROL     DAVV 13000018
FTFLAG   EQU   X'20'                    FLAG ON AFTER FIRST ENTRY  DAVV 13200018
TCCFLAG  EQU   X'10'                    FLAG FOR ALT TRK CHN PGM   DAVV 13400018
UCBVER   EQU   X'08'                    VOLUME VERIFIED FLAG       DAVV 13600018
UCBMNT   EQU   X'80'                    MOUNT MSG ISSUED FLAG      DAVV 13800018
UCBNRY   EQU   X'40'                    NOT READY FLAG IN UCBFL1   DAVV 14000018
         SPACE 2                                                   DAVV 14200018
*              UCB OFFSETS                                         DAVV 14400018
UCBVS    EQU   28                       OFFSET IN WKAREA FOR VOLSERDAVV 14600018
UCBALTHA EQU   16                       OFFSET TO HA AFTER TCC     DAVV 14800018
UCBALTR0 EQU   21                       OFFSET TO REC 0 AFTER TCC  DAVV 15000018
UCBID    EQU   34                       OFFSET TO SRCH ID ARGUMNT  DAVV 15200018
UCBWKPFX EQU   104                      OFFSET TO NORMAL WKAREA    DAVV 15400018
UCBSAV   EQU   0                        SAVE AREA FOR MSG ID       DAVV 15600018
UCBBIN   EQU   0                        OFFSET OF BIN INTO SUBUCB 19022 15700019
         SPACE 2                                                   DAVV 15800018
*              DEFINITIONS FOR BUILDING CHANNEL PROGRAM            DAVV 16000018
RDHACM   EQU   X'1A'                    READ HOME ADDRESS CM       DAVV 16200018
RDR0CM   EQU   X'16'                    READ RECORD 0 COMMAND      DAVV 16400018
CMCHNSLI EQU   X'60'                    COMMAND CHAIN,SUPP INC LEN DAVV 16600018
FIVECNT  EQU   5                        COUNT FOR RDHA,RDR0,SIDEQ  DAVV 16800018
REC03    EQU   3                        VOLUME LABEL IS RECORD 3   DAVV 17000018
IDR      EQU   4                        OFFSET TO R IN CCHHR       DAVV 17200018
SIDCM    EQU   X'31'                    SEARCH ID EQUAL COMMAND    DAVV 17400018
RDHACCW  EQU   0                        OFFSET TO READ HA CMD      DAVV 17600018
RDR0CCW  EQU   8                        OFFSET TO READ R0 COMMAND  DAVV 17800018
SIDCCW   EQU   0                        OFFSET TO S ID EQ CM       DAVV 18000018
TICCCW   EQU   8                        OFFSET TO TIC COMMAND      DAVV 18200018
TICCM    EQU   X'08'                    TRANSFER IN CHANNEL COMMANDDAVV 18400018
RDCCW    EQU   16                       OFFSET TO READ COMMAND     DAVV 18600018
RDDATACM EQU   X'06'                    READ DATA COMMAND          DAVV 18800018
SLI      EQU   X'20'                    SUPPRESS INCORRECT LENGTH  DAVV 19000018
         SPACE 2                                                   DAVV 19200018
*              STATUS AND SENSE INDICATORS                         DAVV 19400018
UNITCK   EQU   X'02'                    UNIT CHECK STATUS          DAVV 19600018
INTREQ   EQU   X'40'                    INTERVENTION REQUIRED SNS  DAVV 19800018
TRKCNDCK EQU   X'02'                    TRACK COND CHECK SENSE     DAVV 20000018
UEX      EQU   X'01'                    UNIT EXCEPTION STATUS      DAVV 20200018
SKCHK    EQU   X'01'                    SEEK CHECK SENSE          19022 20260019
MISSAM   EQU   X'02'                    MISSING ADDR MARKER SNS   19022 20320019
         SPACE 2                                                   DAVV 20400018
*              WTO AND BUFFER DEFINITIONS                          DAVV 20600018
DISMLEN  EQU   24                       LENGTH OF DISMOUNT MSG     DAVV 20800018
BLANK    EQU   X'40'                    EBCDIC BLANK               DAVV 21000018
COMMA    EQU   X'EF'                    UNTRANSLATED COMMA         DAVV 21200018
TCOMMA   EQU   C','                     TRANSLATED COMMA           DAVV 21400018
MNTMSGLN EQU   26                       LENGTH OF MOUNT MSG        DAVV 21600018
JOBNMLN  EQU   8                        LENGTH OF JOB NAME         DAVV 21800018
CHANMSK  EQU   X'0F'                    MASK FOR VALID CHANNELS    DAVV 22000018
DISMOUNT EQU   C'D'                     DISMOUNT COMMAND           DAVV 22200018
MOUNT    EQU   C'M'                     MOUNT COMMAND              DAVV 22400018
CODE4    EQU   C'4'                     MESSAGE CODE               DAVV 22600018
CODE5    EQU   C'5'                     MESSAGE CODE               DAVV 22800018
BUF00    EQU   0                        BUFFER OFFSET OF 0        19022 22810019
BUF01    EQU   1                        BUFFER OFFSET OF 1        19022 22820019
BUF02    EQU   2                        BUFFER OFFSET OF 2        19022 22830019
BUF06    EQU   6                        BUFFER OFFSET OF 6        19022 22840019
BUF07    EQU   7                        BUFFER OFFSET OF 7        19022 22850019
BUF08    EQU   8                        BUFFER OFFSET OF 8        19022 22860019
BUF09    EQU   9                        BUFFER OFFSET OF 9        19022 22870019
BUF17    EQU   17                       BUFFER OFFSET OF 17       19022 22880019
BUF18    EQU   18                       BUFFER OFFSET OF 18       19022 22890019
BUF20    EQU   20                       BUFFER OFFSET OF 20       19022 22900019
BUF21    EQU   21                       BUFFER OFFSET OF 21       19022 22910019
BUF25    EQU   25                       BUFFER OFFSET OF 25       19022 22920019
BUF26    EQU   26                       BUFFER OFFSET OF 26       19022 22930019
BUF30    EQU   30                       BUFFER OFFSET OF 30       19022 22940019
BUF36    EQU   36                       BUFFER OFFSET OF 36       19022 22950019
OFF0     EQU   0                        OFFSET OF 0               19022 22960019
         SPACE 2                                                   DAVV 23000018
*              MISCELLANEOUS DEFINITIONS                           DAVV 23200018
CVTPTR   EQU   16                       CORE LOC OF CVT POINTER    DAVV 23400018
CVTXCTL  EQU   X'2C'                    POINTER TO XCTL RTN        DAVV 23600018
CVTIXAVL EQU   X'7C'                    OFFSET TO NEXT AVAIL. PTR  DAVV 23800018
CVTMACSZ EQU   164                      MACHINE SIZE IN CVT        DAVV 24000018
CVTCONFG EQU   X'74'                    OFFSET TO CONFIG. FLAG     DAVV 24200018
MVT      EQU   X'10'                    MVT INDICATOR IN CVT       DAVV 24400018
MFT      EQU   X'20'                    MFT INDICATOR IN CVT       DAVV 24600018
PCP      EQU   X'40'                    PCP INDICATOR IN CVT       DAVV 24800018
TCBTIOT  EQU   12                       TIOT POINTER               DAVV 25000018
TCBK     EQU   4                        OFFSET TO TCBLKUP TBL      DAVV 25200018
DEBTCB   EQU   0                        TCB POINTER                DAVV 25400018
TIOTJOBN EQU   0                        JOB NAME POINTER           DAVV 25600018
WTORA    EQU   253                      LOAD NAME OF WTO ERR RTN   DAVV 25800018
MAXERR   EQU   10                       MAXIMUM NUMBER OF RETRIES  DAVV 26000018
NORMC    EQU   X'7F'                    NORMAL COMPLETION FLAG     DAVV 26200018
ERREXCP  EQU   15                       SVC 15                     DAVV 26400018
EXIT     EQU   3                        SVC 3                      DAVV 26600018
ZERO     EQU   0                        ZERO COMPARAND             DAVV 26800018
NONWORD  EQU   3                        NON-FULL-WORD BOUNDARY     DAVV 27000018
LASTIND  EQU   X'80'                    LAST ENTRY IN LIST         DAVV 27200018
BININCR  EQU   2                        BUFFER INCREMENT FOR BIN  19022 27250019
NUMZONE  EQU   X'F0'                    ZONE FIELD FOR NUM. CHAR. 19022 27300019
SLASH    EQU   C'/'                     EBCDIC CHAR 'SLASH'       19022 27350019
         EJECT                                                     DAVV 27400018
*****                                                        ***** DAVV 27600018
*                       I/O ERROR HANDLER                        * DAVV 27800018
*****                                                        ***** DAVV 28000018
*                                                                * DAVV 28200018
*   THIS ROUTINE IS ENTERED WHENEVER A CHANNEL PROGRAM INITIATED   DAVV 28400018
*   IN IGE0125E RECEIVES AN ERROR CONDITION.  THE CHANNEL PROGRAM* DAVV 28600018
*   IS RETRIED UNTIL CORRECTED UP TO TEN TIMES, AT WHICH TIME AN * DAVV 28800018
*   ERROR MESSAGE AND A MOUNT MESSAGE ARE ISSUED.                * DAVV 29000018
*   RECOVERY IS ATTEMPTED FROM TRACK CONDITION CHECKS BY RETRYING* DAVV 29200018
*   THE CHANNEL PROGRAM ON THE ALTERNATE TRACK.                  * DAVV 29400018
*****                                                        ***** DAVV 29600018
         SPACE 1                                                   DAVV 29800018
         USING *,BASEREG                                           DAVV 30000018
INITENT  LR    BASEREG,15               ESTAB ADDRESSABILITY       DAVV 30200018
         LH    UCBREG,TSTUCB(0,TSTREG)  GET UCB ADDRESS            DAVV 30400018
         L     IOBREG,TSTIOB(0,TSTREG)  GET IOB ADDRESS            DAVV 30600018
         USING UCBDSECT,UCBREG          ESTAB ADDR'TY FOR UCB      DAVV 30800018
         USING IOBDSECT,IOBREG          ESTAB ADDR'TY FOR IOB      DAVV 31000018
         L     CVTREG,CVTPTR            GET PTR TO CVT            19022 31040019
         LA    VOL1RG,UCBVOL1           UCB VOLSER - NON2321      19022 31080019
         SR    INCREG,INCREG            INCR VAL OF 0 FOR NON2321 19022 31120019
         LA    LNKREG,UPDERCNT          INIT LNKREG FOR NON2321   19022 31160019
         L     UCBWKREG,UCBWORK         GET UCB WORK AREA PTR      DAVV 31200018
         CLI   UCBTYP+3,DEV2321         TEST FOR 2321             19022 31270019
         BC    7,INIT001                NO, BRANCH                19022 31340019
         LA    INCREG,BININCR           SET INCR FOR 2321         19022 31410019
         LA    LNKREG,DCELTEST          INIT FOR 2321             19022 31480019
         SR    WKREG2,WKREG2            CLEAR WORK REG            19022 31550019
         IC    WKREG2,IOBDCCNT          GET SUBUCB OFFSET         19022 31620019
         LA    VOL1RG,UCBDCVOL(WKREG2)  POINT TO 2321 VOLSER      19022 31690019
         LA    SUCBREG,UCBBINNO(WKREG2) POINT TO SUB UCB          19022 31760019
         L     UCBWKREG,UCBWKB          GET 2321 WKAREA PTR       19022 31830019
INIT001  LA    UCBWKREG,UCBWKPFX(0,UCBWKREG) ADJUST PAST PREFIX   19022 31900019
         TM    IOBFL2,IOBNET            WAS LAST I/O A           A43739 31910021
*                                       RECALIBRATE              A43739 31920021
         BZ    RECRSET                  YES, RETRY VOL LABEL     A43739 31930021
*                                       READ                     A43739 31940021
         LH    WKREG2,IOBCSW+3          GET CSW STATUS            19022 31970019
         N     WKREG2,ERRMSK            CHECK FOR ERROR COND      19022 32040019
         BC    8,WTORTN                 NO,MUST BE DISM MSG        DAVV 32200018
         SPACE 1                                                  19022 32260019
*   AN ERROR CONDITION EXISTS.                                    19022 32320019
ERRPROC  TM    IOBCSW+3,UNITCK          TEST FOR UNIT CHECK STATUS DAVV 32400018
         BC    8,UPDERCNT               NO,GO TO UPDATE ERR COUNTR DAVV 32600018
         TM    IOBSNS,INTREQ            TEST FOR INTERVENTION REQ  DAVV 32800018
         BC    1,XCTLWTO                YES,GO TO XCTL TO WTO RTN  DAVV 33000018
         TM    IOBSNS,TRKCNDCK          TEST FOR TRACK COND. CHECK DAVV 33200018
         BC    1,ALTTRKCP               YES,GO TO ALT TRK PROCEDUREDAVV 33400018
         BCR   15,LNKREG                IF 2321, GO TEST BALLAST  19022 33460019
         SPACE 1                                                  19022 33520019
*   THIS CODE MAINTAINS THE ERROR COUNTER AND EITHER BRANCHES TO   DAVV 33600018
*     THE RETRY PROCEDURE OR ISSUES AN ERROR MESSAGE.              DAVV 33800018
RECRSET  OI    IOBFL2,IOBNET            RESET BYPASS OF SEEK     A43739 33860021
         ST    UCBWKREG,IOBRESTR-1      RESET RESTART FIELD      A43739 33920021
         XC    UCBID(4,UCBWKREG),UCBID(UCBWKREG)  CLEAR CCHH    SA60761 33970021
         MVI   UCBID+IDR(UCBWKREG),REC03  SET SID TO RECORD 3   SA60761 33980021
UPDERCNT IC    WKREG2,IOBECT+1          GET CURRENT ERROR COUNT   19022 34000019
         LA    WKREG2,1(0,WKREG2)       UPDATE BY 1                DAVV 34200018
         STC   WKREG2,IOBECT+1          STORE NEW ERROR COUNT     19022 34400019
         CLI   IOBECT+1,MAXERR          TEST IF TEN RETRIES DONE   DAVV 34600018
         BC    2,ERWTORTN               YES,GO ISSUE ERROR MSG.    DAVV 34800018
         SVC   ERREXCP                  RETURN TO IOS              DAVV 35000018
         SVC   EXIT                     RETURN TO SUPERVISOR       DAVV 35200018
         EJECT                                                     DAVV 35400018
*   THIS ROUTINE TESTS FOR A BALLAST CELL FOR 2321 ERRORS.  IF    19022 35420019
*     NOT, NORMAL PROCESSING IS FOLLOWED.  IF BALLAST, NO RETRIES 19022 35440019
*     ARE DONE, AND AN ERROR MESSAGE IS ISSUED.                   19022 35460019
DCELTEST TM    IOBSNS,SKCHK             TEST FOR SEEK CHECK       19022 35480019
         BC    8,UPDERCNT               NO, NOT BALLAST           19022 35500019
         TM    IOBSNS+1,MISSAM          TEST FOR MISSING ADDR MKR 19022 35520019
         BC    8,UPDERCNT               NO, NOT BALLAST           19022 35540019
         BC    15,ERWTORTN              BALLAST, ISSUE ERR MSG    19022 35560019
         SPACE 1                                                  19022 35580019
*   THIS CODE TRANSFERS CONTROL TO THE WRITE-TO-OPERATOR ERROR     DAVV 35600018
*     ROUTINE TO ISSUE THE INTERVENTION REQUIRED MESSAGE           DAVV 35800018
XCTLWTO  LA    WKREG2,WTORA             GET LOAD NAME OF WTO       DAVV 36000018
         NI    IOBFL3,X'FF'-IOBLOG-IOBMSG  INSURE INT REQ MSG      DAVV 36200018
         L     XCTLREG,CVTXCTL(0,CVTREG)   GET PTR TO XCTL RTN     DAVV 36400018
         BCR   15,XCTLREG               GO TO ROUTINE              DAVV 36600018
         SPACE 1                                                   DAVV 36800018
*   THIS ROUTINE SETS UP A CHANNEL PROGRAM TO READ THE HOME        DAVV 37000018
*     ADDRESS AND RECORD ZERO ON THE DEFECTIVE TRACK.              DAVV 37200018
ALTTRKCP LR    CCWREG,UCBWKREG          GET PTR TO WKAREA          DAVV 37400018
         LA    DATAREG,UCBALTHA(CCWREG)  GET HA BUFFER ADR         DAVV 37600018
         ST    DATAREG,RDHACCW(0,CCWREG)  STR BUF ADR INTO RDHA CM DAVV 37800018
         MVI   RDHACCW(CCWREG),RDHACM   MOVE READ H.A. COMMAND     DAVV 38000018
         MVI   RDHACCW+4(CCWREG),CMCHNSLI  SET CMD CHAIN AND SLI   DAVV 38200018
         MVI   RDHACCW+7(CCWREG),FIVECNT  SET HA LENGTH TO FIVE    DAVV 38400018
         LA    DATAREG,FIVECNT(0,DATAREG)  UPDATE BEYOND HA TO R0  DAVV 38600018
         ST    DATAREG,RDR0CCW(0,CCWREG)  STR BUF ADR INTO RDR0 CM DAVV 38800018
         MVI   RDR0CCW(CCWREG),RDR0CM   MOVE READ R0 COMMAND       DAVV 39000018
         MVI   RDR0CCW+4(CCWREG),SLI    SET SUPPRESS INCORRECT LEN DAVV 39200018
         MVI   RDR0CCW+7(CCWREG),FIVECNT  SET R0 LENGTH TO FIVE    DAVV 39400018
         OI    UCBFL4,TCCFLAG           INDICATE ALT TRK PROCEDURE DAVV 39600018
         SVC   ERREXCP                  RETURN TO IOS              DAVV 39800018
         SVC   EXIT                     RETURN TO SUPERVISOR       DAVV 40000018
         SPACE 2                                                   DAVV 40200018
*   THIS SUBROUTINE IS ENTERED WHEN THE PACK MOUNTED DISAGREES IN  DAVV 40400018
*     VOLUME SERIAL WITH THE UCB INFORMATION.                      DAVV 40600018
WTORTN   MVC   DMBUFCUA(3),UCBUTN       MOVE UNIT NAME TO BUF     19022 40700019
         CLI   UCBTYP+3,DEV2321         TEST FOR 2321             19022 40800019
         BC    7,WTO001                 NO, NO BIN NUMBER         19022 40900019
         MVI   DMBUFCUA+3,SLASH         MOVE SLASH TO BUF         19022 41000019
         MVC   DMBUFCUA+4(1),UCBBIN+1(SUCBREG) MOVE BIN NO.       19022 41100019
         OI    DMBUFCUA+4,NUMZONE       MAKE BIN NO. PRINTABLE    19022 41200019
WTO001   LA    BUFREG,DMBUFVOL-1(INCREG) INIT BUF PTR PAST CUA    19022 41300019
         MVI   BUF00(BUFREG),TCOMMA     COMMA AFTER CUA           19022 41400019
         MVC   BUF01(6,BUFREG),UCBVS(UCBWKREG) VOLSER OF MNTD VOL 19022 41500019
         MVC   BUF07(4,BUFREG),DMDESC   DESCR + RTING CODES       19022 41600019
         MVI   DMBUFACT,DISMOUNT        MOVE DISMOUNT INDICATOR    DAVV 42400018
         MVI   DMBUFCOD+5,CODE4         INSURE PROPER MSG CODE     DAVV 42600018
         LA    WKREG2,DISMLEN(0,INCREG) GET MSG LENGTH            19022 42700019
         STH   WKREG2,DMBUFLN           STORE IN BUF LEN FLD      19022 42800019
         LR    WKREG2,TSTREG            SAVE RQE POINTER OVER SVC  DAVV 43000018
         LA    1,DMBUF                  INIT REG FOR WTO MACRO     DAVV 43200018
         WTO   MF=(E,(1))                                          DAVV 43400018
         ST    1,UCBSAV(0,UCBWKREG)     SAVE MSG ID IN WKAREA      DAVV 43600018
         LA    BUFREG,BUF09(0,BUFREG)   POINT TO JOBNAME FIELD    19022 44600019
         LR    TSTREG,WKREG2            SAVE RQE PTR OVER JOBN RTN19022 45600019
         BAL   LNKREG,ERJOBNAM          GO TO GET JOB NAME        19022 46600019
         LR    WKREG2,TSTREG            SAVE TSTREG OVER WTO      19022 47600019
         SPACE 1                                                  19022 48600019
WTOMNT   MVC   BUF00(4,BUFREG),DMDESC   MOVE DESCR + RTING CODES  19022 49600019
         LA    1,DMBUF                  INIT PTR FOR WTO MACRO    19022 50600019
         SR    BUFREG,1                 FORM MSG LENGTH           19022 51600019
         STH   BUFREG,DMBUFLN           STORE IN BUFFER           19022 52600019
         OI    UCBFL1,UCBNRY            INDICATE NOT READY        19022 53600019
         LA    WKREG3,DMBUFVOL(INCREG)  GET PTR TO VOLSER FIELD   19022 54600019
         MVC   BUF00(6,WKREG3),OFF0(VOL1RG) MOVE UCB VOLSER       19022 55600019
         MVI   BUF06(WKREG3),TCOMMA     MOVE COMMA TO BUFFER      19022 56600019
         MVI   BUF07(WKREG3),TCOMMA     MOVE COMMA TO BUFFER      19022 57600019
         MVI   DMBUFACT,MOUNT           SET ACTION TO MOUNT        DAVV 59800018
         MVI   DMBUFCOD+5,CODE5         SET WTO CODE               DAVV 60000018
         WTO   MF=(E,(1))                                          DAVV 60400018
         ST    1,UCBSAV+4(0,UCBWKREG)   SAVE MSG ID IN WKAREA      DAVV 60600018
         OI    UCBSAV+4(UCBWKREG),LASTIND  INDICATE LAST ENTRY     DAVV 60800018
         OI    UCBFL4,UCBMNT            INDICATE MOUNT MSG ISSUED  DAVV 61000018
         LR    TSTREG,WKREG2            RESTORE RQE POINTER        DAVV 61200018
         MVI   UCBRQESV,ZERO            FORCE RE-DAVV           SA68917 61250021
         NI    UCBFL4,X'FF'-FTFLAG      RESET FIRST TIME FLAG   SA68917 61300021
         SVC   ERREXCP                  RET TO IOS TO POST IN ERR  DAVV 61400018
         SVC   EXIT                     RET TO SUPERVISOR          DAVV 61600018
         SPACE 1                                                  19022 61603019
*     THIS ROUTINE FORMATS AND PRINTS AN I/O ERROR MESSAGE.       19022 61606019
ERWTORTN MVC   ERBUFWK(2),UCBCUA        MOVE UNIT ADDR TO WKAREA  19022 61609019
         UNPK  ERBUFCUA-1(5),ERBUFWK(3) UNPACK INTO CUA FIELD     19022 61612019
         MVI   ERBUFCUA-1,BLANK         RESET BLANK               19022 61615019
         TR    ERBUFCUA(3),ERRTBL-X'EE' TRANSLATE CUA             19022 61618019
         MVC   DMBUFCUA(3),UCBUTN       INIT CUA FOR MNT MSG      19022 61621019
         MVI   DMBUFCUA+3,TCOMMA        INSURE COMMA              19022 61624019
         CLI   UCBTYP+3,DEV2321         TEST FOR 2321             19022 61627019
         BC    7,ERWTO002               NO, BRANCH                19022 61630019
         MVI   ERBUFCUA+3,SLASH         FORMAT BUF FOR 2321       19022 61633019
         MVC   ERBUFCUA+4(1),UCBBIN+1(SUCBREG) MOVE BIN NO.       19022 61636019
         OI    ERBUFCUA+4,NUMZONE       MAKE BIN NO. PRINTABLE    19022 61639019
         MVC   DMBUFCUA+3(2),ERBUFCUA+3 MOVE TO MNT MSG BUFFER    19022 61642019
         MVI   DMBUFCUA+5,TCOMMA        RESET COMMA               19022 61645019
ERWTO002 LA    BUFREG,ERBUFTXT-1(INCREG) POINT BUFREG AFTER CUA   19022 61648019
         MVI   BUF00(BUFREG),TCOMMA     MOVE COMMA AFTER CUA      19022 61651019
         MVC   BUF01(16,BUFREG),LBLMSG  MOVE MSG TEXT TO BUF      19022 61654019
         MVI   BUF17(BUFREG),TCOMMA     MOVE COMMA AFTER TEXT     19022 61657019
         MVC   BUF18(3,BUFREG),DUMMYCM  INIT TO DUMMY COMMAND     19022 61660019
         L     CCWREG,IOBCSW-1          LOAD CCW ADDR FROM CSW    19022 61663019
         LA    CCWREG,OFF0(0,CCWREG)    INSURE HI ORDER BYTE ZERO 19022 61666019
         LTR   CCWREG,CCWREG            TEST CCW ADDR FOR ZERO   A39733 61667020
*                                       A3973                    A39733 61668020
         BC    8,ERWTOST                YES, USE DUMMY CM        A39733 61669020
*                                       A3973                    A39733 61670020
         SH    CCWREG,CCWLN             POINT TO FAILING CMD     A39733 61671020
*                                       A3973                    A39733 61672020
         UNPK  BUF18(3,BUFREG),OFF0(2,CCWREG) UNPK COMMAND TO BUF 19022 61675019
         MVI   BUF20(BUFREG),COMMA      MOVE COMMA AFTER COMMAND  19022 61678019
ERWTOST  UNPK  BUF21(5,BUFREG),IOBCSW+3(3) UNPACK STATUS INTO BUF 19022 61681019
         MVI   BUF25(BUFREG),COMMA      MOVE COMMA AFTER STATUS   19022 61684019
         CLC   UCBSNS(2),IOBSNS         TEST IF UCB SENSE VALID   19022 61687019
         BC    7,ERWTOSNS               NO, GO TO USE IOB SNS     19022 61690019
         UNPK  BUF26(11,BUFREG),UCBSNS(6) UNPACK SENSE INTO BUF   19022 61693019
         TR    BUF18(18,BUFREG),ERRTBL-X'EE' TRANS CM,STAT,SENSE  19022 61696019
         LA    BUFREG,BUF36(0,BUFREG)   UPDATE REG TO NXT AVAIL   19022 61699019
         BC    15,ERWTO001              BRANCH                    19022 61702019
         SPACE 1                                                  19022 61705019
ERWTOSNS UNPK  BUF26(5,BUFREG),IOBSNS(3) UNPACK SENSE FROM IOB    19022 61708019
         TR    BUF18(12,BUFREG),ERRTBL-X'EE' TRANS CM,STAT,SENSE  19022 61711019
         LA    BUFREG,BUF30(0,BUFREG)   UPDATE TO NEXT AVAIL POS. 19022 61714019
ERWTO001 MVI   BUF00(BUFREG),TCOMMA     MOVE COMMA AFTER SENSE    19022 61717019
         MVI   BUF01(BUFREG),TCOMMA     MOVE POSITIONAL COMMA     19022 61720019
         MVC   BUF02(6,BUFREG),OFF0(VOL1RG) USE VOLSER IN UCB     19022 61723019
         MVI   BUF08(BUFREG),TCOMMA     MOVE COMMA AFTER VOLSER   19022 61726019
         LA    BUFREG,BUF09(0,BUFREG)   UPDATE TO NEXT AVAIL POS. 19022 61729019
         BAL   LNKREG,ERJOBNAM          GO TO GET JOB NAME        19022 61732019
         MVC   BUF00(4,BUFREG),ERDESC   MOVE DESCR + RTING CODES  19022 61735019
         LR    WKREG2,TSTREG            SAVE TSTREG OVER WTO      19022 61738019
         LA    1,ERBUF                  INIT WTO INPUT REG        19022 61741019
         SR    BUFREG,1                 FORM MSG LENGTH           19022 61744019
         STH   BUFREG,ERBUFLN           STORE LENGTH IN BUFFER    19022 61747019
         WTO   MF=(E,(1))                                         19022 61750019
         ST    1,UCBSAV(0,UCBWKREG)     SAVE MSG ID FOR DOM       19022 61753019
         LA    BUFREG,DMBUFJOB(PARMREG) PT REG TO END OF MNT BUF  19022 61756019
         BC    15,WTOMNT                GO TO ISSUE MOUNT MSG     19022 61759019
         SPACE 1                                                  19022 61762019
*   THE FOLLOWING MOVES THE JOBNAME TO THE BUFFER IF THE TCB CAN  19022 61765019
*     BE DETERMINED.                                              19022 61768019
ERJOBNAM LR    PARMREG,INCREG           INIT EOBUF REG FOR WTOMNT 19022 61771019
         TM    CVTCONFG(CVTREG),MVT     CHK SYSTEM TYPE FOR 16 STARDAVV 61778019
         L     WKREG2,TSTTCB(0,TSTREG)  GET TCB PTR                DAVV 61785019
         BC    1,GETTIOT                YES,BRANCH                 DAVV 61792019
         SR    WKREG3,WKREG3            CLEAR REG                  DAVV 61799019
         IC    WKREG3,TSTTCBID(0,TSTREG)  GET TCB ID-OFFSET TCBLK  DAVV 61806019
         SLL   WKREG3,2                 FORM PROPER OFFSET        19054 61809019
         L     WKREG2,CVTIXAVL(0,CVTREG)  GET NEXT AVAIL. PTR      DAVV 61813019
         L     WKREG2,TCBK(0,WKREG2)    NEXAVL + 4 = PTR TO TCBLK  DAVV 61820019
         L     WKREG2,0(WKREG3,WKREG2)  GET TCB PTR                DAVV 61827019
GETTIOT  L     WKREG3,TSTDEB-1(0,TSTREG)  GET DEB PTR FROM 12 STAR DAVV 61834019
         L     WKREG3,DEBTCB(0,WKREG3)  GET TCB POINTER            DAVV 61841019
         LA    WKREG2,0(0,WKREG2)       INSURE ZERO IN HI ORDER    DAVV 61848019
         LA    WKREG3,0(0,WKREG3)       INSURE ZERO IN HI ORDER    DAVV 61855019
         CR    WKREG2,WKREG3            COMPARE TCB PTRS FOR VLDTY DAVV 61862019
         BCR   7,LNKREG                 NOT EQUAL, OMIT JOBNAME   19022 61869019
         TM    TCBTIOT+3(WKREG2),NONWORD INSURE WORD BOUNDARY     19022 61876019
         BCR   4+1,LNKREG               NO, OMIT JOBNAME          19022 61883019
         L     WKREG2,TCBTIOT(0,WKREG2) GET TIOT PTR              19022 61890019
         L     WKREG3,CVTMACSZ(0,CVTREG) GET MAX CORE ADDR        19022 61897019
         SH    WKREG3,CCWLN             ALLOW FOR JOBNAME LENGTH  19022 61904019
         CLR   WKREG2,WKREG3            TEST IF TIOT PTR TOO HIGH 19022 61911019
         BCR   2,LNKREG                 YES, OMIT JOBNAME         19022 61918019
         MVC   BUF00(8,BUFREG),TIOTJOBN(WKREG2) MOVE JOBN TO BUF  19022 61925019
         LA    BUFREG,BUF08(0,BUFREG)   UPDATE TO END OF BUFFER   19022 61932019
         LA    PARMREG,BUF08(0,PARMREG) UPDATE FOR MNT BUFFER     19022 61939019
         LA    WKREG3,DMBUFJOB(INCREG)  POINT TO JOBNAME FIELD    19022 61946019
         MVC   BUF00(8,WKREG3),TIOTJOBN(WKREG2) MOVE JOBN TO BUF  19022 61953019
         BCR   15,LNKREG                RETURN TO CALLER          19022 61960019
         EJECT                                                    19022 61967019
*****                                                        ***** DAVV 62000018
*                                                                * DAVV 62200018
*             CONSTANTS, MESSAGES, AND WORK AREAS                * DAVV 62400018
*                                                                * DAVV 62600018
*****                                                        ***** DAVV 62800018
         DS    0F                                                  DAVV 63000018
ERRMSK   DC    X'0000037F'              MASK FOR CSW STATUS ERRORS DAVV 63200018
CCWLN    DC    H'8'                     COUNT OF 8                 DAVV 63400018
         SPACE 1                                                   DAVV 63600018
*   DISMOUNT/MOUNT MESSAGE BUFFER                                  DAVV 63800018
DMBUF    DC    H'0'                     LENGTH FIELD              M4158 63900018
         DC    X'8000'                  MCS FLAG                  M4158 64000018
         DC    CL36'IEA600A M CUA,VOLSER,,JOB'                   A31376 64100020
*                                       A3137                    A31376 64200020
DMDESC   DC    XL2'4000'                DESCRIPTOR CODE- IAR       DAVV 64400018
DMRTC    DC    XL2'1000'                ROUTING CODE-DIRECT ACCESS DAVV 64600018
DMBUFLN  EQU   DMBUF+0                  LENGTH FIELD               DAVV 64800018
DMBUFCOD EQU   DMBUF+4                  MESSAGE CODE FIELD         DAVV 65000018
DMBUFACT EQU   DMBUF+12                 ACTION FIELD               DAVV 65200018
DMBUFCUA EQU   DMBUF+14                 CHN AND UNIT ADDR FIELD    DAVV 65400018
DMBUFVOL EQU   DMBUF+18                 VOLUME SERIAL FIELD        DAVV 65600018
DMBUFJOB EQU   DMBUF+26                 JOB NAME FIELD             DAVV 65800018
         SPACE 1                                                   DAVV 66200018
*   I/O ERROR MESSAGE BUFFER                                     BBBBBB 66300019
ERBUF    DC    H'0'                     LENGTH FIELD              M4158 66500018
         DC    X'8000'                  MCS FLAG                  M4158 66600018
         DC    CL70'IEA606I CUA'                                 A31376 66700020
*                                       A3137                    A31376 66800020
ERDESC   DC    XL2'1000'                DESCRIPTOR CODE-SYST STAT  DAVV 67000018
ERRTC    DC    XL2'1040'                RT CODE - D/A POOL AND ER  DAVV 67200018
ERBUFLN  EQU   ERBUF+0                  LENGTH FIELD               DAVV 67400018
ERBUFCUA EQU   ERBUF+12                 CUA FIELD                  DAVV 67600018
ERBUFTXT EQU   ERBUF+16                 MESSAGE TEXT FIELD         DAVV 67800018
ERBUFCM  EQU   ERBUF+33                 COMMAND FIELD              DAVV 68000018
ERBUFST  EQU   ERBUF+36                 STATUS FIELD               DAVV 68200018
ERBUFSNS EQU   ERBUF+41                 SENSE FIELD                DAVV 68400018
ERBUFWK  EQU   ERBUF+36                 WORK AREA WITHIN BUFFER    DAVV 68600018
         SPACE 1                                                   DAVV 68800018
ERRTBL   DC    C'*,0123456789ABCDEF'    TRANSLATE TABLE            DAVV 69000018
DUMMYCM  DC    X'EEEEEF'                UNTRANSLATED **,           DAVV 69200018
LBLMSG   DC    C'BAD VOLUME LABEL'      TEXT FOR ERROR MSG        19022 69300019
PATCH    EQU   *                        START OF PATCH AREA             69350021
         DC    (1024-(PATCH-INITENT))X'00'                              69360021
         EJECT                                                     DAVV 69400018
*   DUMMY CONTROL SECTION FOR A UCB                                DAVV 69600018
UCBDSECT DSECT                                                     DAVV 69800018
         DS    AL3                      JOB NO.,ALLOC CHN MSK,ID   DAVV 70000018
UCBSTAT  DS    XL1                      STATUS A FLAGS             DAVV 70200018
UCBCUA   DS    H                        CHANNEL AND UNIT ADDRESS   DAVV 70400018
UCBFL1   DS    XL1                      FLAGS 1 - IOS FLAGS        DAVV 70600018
         DS    XL2                      INDECES                    DAVV 70800018
UCBSTI   DS    XL1                      INDEX TO STAT TABLE        DAVV 71000018
         DS    XL3                      INDECES                    DAVV 71200018
UCBUTN   DS    XL3                      UNIT NAME IN EBCDIC        DAVV 71400018
UCBTYP   DS    F                        DEVICE DESCRIPTOR WORD     DAVV 71600018
UCBLTS   DS    H                        LAST RQE                   DAVV 71800018
UCBSNS   DS    XL6                      SENSE INFORMATION          DAVV 72000018
UCBVOL1  DS    XL6                      VOLUME SERIAL              DAVV 72200018
         DS    XL8                      VOLUME INFO, RESERVE/RELSE DAVV 72400018
UCBRQESV DS    H                        RQE SAVE FOR VOL. VER. RTN DAVV 72600018
UCBCNTR  DS    XL1                      BITS 0-3 2321 BIN COUNTER  DAVV 72800018
UCBFL4   EQU   UCBCNTR                  BITS 4-7 FLAGS FOR VVR     DAVV 73000018
         DS    XL3                      UNUSED                     DAVV 73200018
UCBSKA   DS    2F                       LAST SEEK ADDRESS          DAVV 73400018
         DS    F                        NO. USERS,ECB              DAVV 73600018
UCBWORK  DS    F                        WORK AREA POINTER          DAVV 73800018
         SPACE 1                                                  19022 73810019
*     UCB EXTENSION FOR DATA CELL                                 19022 73820019
         ORG   UCBVOL1                                            19022 73830019
UCBWKA   DS    XL12                     DATA CELL WORK AREA A     19022 73840019
         DS    4F                       RES/REL,VOL VER,SEEK ADR  19022 73850019
*     DESCRIPTION OF CELL ZERO                                    19022 73860019
UCBBINNO DS    H                        BIN NUMBER                19022 73870019
         DS    H                        VOLUME AND CELL STATUS    19022 73880019
UCBDCVOL DS    XL6                      CELL VOLUME SERIAL        19022 73890019
         DS    XL6                      CELL INFORMATION          19022 73900019
         DS    36F                      NINE MORE SUB-UCBS        19022 73910019
UCBWKB   DS    F                        WORK AREA POINTER         19022 73920019
         EJECT                                                     DAVV 74000018
*   DUMMY CONTROL SECTION FOR AN IOB                               DAVV 74200018
IOBDSECT DSECT                                                     DAVV 74400018
IOBFL1   DS    XL1                      I/O FLAGS 1                DAVV 74600018
IOBFL2   DS    XL1                      I/O FLAGS 2                DAVV 74800018
IOBSNS   DS    H                        SENSE INFORMATION          DAVV 75000018
IOBECB   DS    F                        ECB POINTER                DAVV 75200018
IOBFL3   DS    XL1                      I/O FLAGS 3                DAVV 75400018
IOBCSW   DS    XL7                      LAST CSW                   DAVV 75600018
         DS    2F                       START OF CHN PGM,DCB ADDR  DAVV 75800018
         DS    XL1                      OP CODE                    DAVV 76000018
IOBRESTR DS    XL3                      RESTART ADDR FOR IOS       DAVV 76200018
         DS    H                        ACCESS METHOD FIELD        DAVV 76400018
IOBECT   DS    H                        ERROR COUNT FOR RETRIES    DAVV 76600018
IOBDCCNT EQU   IOBECT                   BIN COUNTER FOR 2321      19022 76700019
IOBSEEK  DS    2F                       SEEK ADDRESS               DAVV 76800018
         END                                                            77000018
