         TITLE 'IGE0325C - WTO - LOAD 4'                         S20201 00100021
IECWTORD START 0                                                 BBBBBB 00200019
*1261430100-431500,482000,486000-514000,914000,956000            S20201 00300020
*STATUS CHANGE LEVEL 002                                                00400020
*                   WRITE TO OPERATOR ROUTINE - LOAD 4           BBBBBB 00600019
         SPACE 2                                                 BBBBBB 00800019
*      FUNCTION     HANDLE CONDITION CODE 3 ERRORS               BBBBBB 01000019
*         ENTRY     IECXWTO FROM IGE0025C AND FROM IGE0025E      BBBBBB 01200019
*         INPUT     REQUEST ELEMENT IN REGISTER 1, ENTRY         BBBBBB 01400019
*                   ADDRESS IN REGISTER 15, AND PATH INDICATOR   BBBBBB 01600019
*                   IN THE IOBCC FIELD.                          BBBBBB 01800019
*        OUTPUT     MESSAGE ON CONSOLE VIA WTO MACRO.            BBBBBB 02000019
*       EXT REF     NONE.                                        BBBBBB 02200019
*         EXITS     RETURN TO SUPERVISOR VIA SVC 3.              BBBBBB 02400019
*         NOTES     NONE.                                        BBBBBB 02600019
*        TABLES     TEST CHANNEL TABLE IN IOS, MP CHANNEL        BBBBBB 02800019
*                   TABLES, AND APR CEB TABLE.                   BBBBBB 03000019
*     OPERATION     THIS MODULE DETERMINES IF THE LAST PATH TO   BBBBBB 03200019
*                   A DEVICE HAS JUST RECEIVED A NOT OPERATIONAL BBBBBB 03400019
*                   CONDITION CODE.  IF THERE ARE ANY PATHS      BBBBBB 03600019
*                   REMAINING, A WTO IS ISSUED INFORMING THE     BBBBBB 03800019
*                   OPERATOR ABOUT THE INOPERATIVE PATH.  IF     BBBBBB 04000019
*                   THERE ARE NO PATHS REMAINING, AN ACTION      BBBBBB 04200019
*                   MESSAGE IS WRITTEN TO THE OPERATOR,          BBBBBB 04400019
*                   REQUIRING HIM TO EITHER VARY A PATH ONLINE,  BBBBBB 04600019
*                   OR TO RESET A SWITCH.  IF APR IS PROCESSING  BBBBBB 04800019
*                   PATHS TO A DEVICE WHEN THE LAST PATH GOT THE BBBBBB 05000019
*                   CONDITION CODE 3, APR WILL BE CANCELLED,     BBBBBB 05200019
*                   THE PATHS IT WAS PROCESSING WILL BE MADE     BBBBBB 05400019
*                   AVAILABLE, AND THE INOPERATIVE PATH MESSAGE  BBBBBB 05600019
*                   WILL BE ISSUED.  IF IN A MULTI-PROCESSING    BBBBBB 05800019
*                   ENVIRONMENT, THE CHANNEL TABLES IN MP CORE   BBBBBB 06000019
*                   WILL BE USED TO DETERMINE THE TOTAL NUMBER   BBBBBB 06200019
*                   OF PATHS OFFLINE.                            BBBBBB 06400019
*                   IF AN EXCP USER WHO IS NOT USING IBM ERROR   BBBBBB 06600019
*                   ROUTINES GETS A CC 3, THIS MODULE IS ENTERED BBBBBB 06800019
*                   AS A LOGICAL EXTENSION OF IOS VIA IGE0025E.  BBBBBB 07000019
*                   IF THIS IS THE CASE, ALL PROCESSING IS THE   BBBBBB 07200019
*                   SAME EXCEPT FOR THE LAST PATH SITUATION.     BBBBBB 07400019
*                   IN THIS CASE, NO MESSAGE WILL BE ISSUED,     BBBBBB 07600019
*                   AND IOS WILL POST THE USER WITH A PERMANENT  BBBBBB 07800019
*                   ERROR INDICATION.                            BBBBBB 08000019
*                                                                BBBBBB 08200019
*                   MESSAGE FORMATS                              BBBBBB 08400019
*                                                                BBBBBB 08600019
*        IEA001I UNIT XXX, PATH YY INOPERATIVE FOR CPU Z         BBBBBB 08800019
*        IEA000A XXX,INT REQ,,CC=3/NO PATHS AVAILABLE,,,SER,JOBN BBBBBB 09000019
         EJECT                                                   BBBBBB 09200019
*              IOB DEFINITION                                    BBBBBB 09400019
IOBFL1   EQU   0                        FLAGS 1                  BBBBBB 09600019
IOBFL2   EQU   1                        IOB FLAGS 2              BBBBBB 09800019
IOBSNS   EQU   2                        SENSE DATA               BBBBBB 10000019
IOBCOD   EQU   4                        ECB CODE                 BBBBBB 10200019
IOBFL3   EQU   8                        FLAG 3                   BBBBBB 10400019
IOBCSW   EQU   8                        CSW STORAGE              BBBBBB 10600019
IOBCC    EQU   16                       SIO COND CODE + PATH IND BBBBBB 10800019
IOBDCB   EQU   21                       DCB POINTER              BBBBBB 11000019
IOBMDB   EQU   24                       MODIFIER BYTE            BBBBBB 11200019
IOBRST   EQU   25                       RESTART POINTER          BBBBBB 11400019
IOBECT   EQU   30                       ERROR COUNTER            BBBBBB 11600019
IOBSK    EQU   33                       IOB SEEK ADDRESS         BBBBBB 11800019
*              IOB FLAGS                                         BBBBBB 12000019
IOBERR   EQU   X'20'                    ERROR CORECTION INDICATORBBBBBB 12200019
IOBEX    EQU   X'04'                    EXCEPT FLAG              BBBBBB 12400019
IOBMSG   EQU   X'04'                    MESSAGE CODE             BBBBBB 12600019
IOBSRS   EQU   X'01'                    START/RESTART FLAG       BBBBBB 12800019
IOBEXE   EQU   IOBEX+IOBERR             IOB EX AND ERROR FLAG    BBBBBB 13000019
IOBRHA   EQU   X'10'                    READ HA FLAG             BBBBBB 13200019
         SPACE 2                                                 BBBBBB 13400019
*              DCB DEFINITION                                    BBBBBB 13600019
DCBBLK   EQU   12                       POINTER TO BLOCK COUNT   BBBBBB 13800019
DCBFL    EQU   44                       FLAGS                    BBBBBB 14000019
DCBDEB   EQU   44                                                BBBBBB 14200019
*              DCB FLAGS                                         BBBBBB 14400019
DCBPER   EQU   X'C0'                    PERMANENT ERROR FLAGS    BBBBBB 14600019
DCBEX    EQU   X'40'                    EXCEPTION CONDITION      BBBBBB 14800019
DCBIEK   EQU   X'0C'                    IBM ERP FLAG             BBBBBB 15000019
         SPACE 2                                                 BBBBBB 15200019
*              DEB DEFINITION                                    BBBBBB 15400019
DEBTCB   EQU   0                        TCB POINTER              BBBBBB 15600019
DEBDCB   EQU   25                       DEB DCB POINTER          BBBBBB 15800019
DEBUCB   EQU   33                                                BBBBBB 16000019
         SPACE 2                                                 BBBBBB 16200019
*              UCB DEFINITION                                    BBBBBB 16400019
UCBMPBYT EQU   0                        MULT PROC IND AT UCB - 4 BBBBBB 16600019
UCBALLC  EQU   1                        ALLOCATION CHAN. MASK    BBBBBB 16800019
UCBSTATA EQU   3                        STATUS 'A' BYTE          BBBBBB 17000019
UCBCUA   EQU   4                        CHAN. AND UNIT ADDRESS   BBBBBB 17200019
UCBFL1   EQU   6                        UCB FLAGS                BBBBBB 17400019
UCBLCI   EQU   10                       OFFSET TO LCH INDEX      BBBBBB 17600019
UCBCHM   EQU   12                       CHANNEL MASK (BITS 4-7)  BBBBBB 17800019
UCBUTN   EQU   13                       UNIT NAME                BBBBBB 18000019
UCBTYP   EQU   16                       UCB TYPE FIELD           BBBBBB 18200019
UCBLTS   EQU   20                       ADR OF LAST RQE STARTED  BBBBBB 18400019
UCBSNS   EQU   22                       SENSE BYTES              BBBBBB 18600019
UCBVSER  EQU   28                       VOLUME SERIAL            BBBBBB 18800019
DCELBBNR EQU   56                       DISPL TO BIN 0 IN UCB    BBBBBB 19000019
UCBEXT   EQU   60                       PTR TO UCB EXTENSION     S20201 19040020
UCBBASE  EQU   92                       OFFSET FOR PTR TO BASE   S20201 19120020
UCBDCVOL EQU   4                        DISPL IN SUBUCB OF VOLSERBBBBBB 19200019
*              UCB FLAGS                                         BBBBBB 19400019
UCBTP    EQU   X'40'                    TP DEVICE TYPE           BBBBBB 19600019
UCBUR    EQU   X'08'                    UNIT RECORD DEVICE TYPE  BBBBBB 19800019
UCBTAPE  EQU   X'80'                    TAPE DEVICE TYPE         BBBBBB 20000019
UCBDA    EQU   X'20'                    DIRECT ACCESS DEVICE TYPEBBBBBB 20200019
D2321    EQU   X'05'                    2321 CLASS               S20201 20220020
ZEUSA    EQU   X'06'                    ATHENS ZEUS DRUM TYPE    S20201 20260020
ZEUSC    EQU   X'07'                    CORINTH ZEUS DRUM TYPE   S20201 20300020
UCBNRY   EQU   X'40'                    UCB NOT READY            BBBBBB 20400019
UCBSYSRS EQU   X'02'                    SYS RES INDICATOR        BBBBBB 20600019
MULTPATH EQU   X'01'                    MULTI PATH INDIC IN ALLC BBBBBB 20800019
UCBCPUA  EQU   X'08'                    CPU 'A' IND FOR MULT PROCBBBBBB 21000019
         SPACE 2                                                 BBBBBB 21200019
*              TWELVE STAR DEFINITION                            BBBBBB 21400019
TSTLNK   EQU   0                        FORWARD 12* LINK         BBBBBB 21600019
TSTUCB   EQU   2                        UCB POINTER              BBBBBB 21800019
TSTTCBID EQU   4                        TCB ID FOR MFT           BBBBBB 22000019
TSTIOB   EQU   5                        IOB POINTER              BBBBBB 22200019
TSTPR    EQU   8                        PRIORITY OF ENTRY        BBBBBB 22400019
TSTDEB   EQU   9                        DEB POINTER              BBBBBB 22600019
TSTTCB   EQU   12                       TST TCB PTR FOR MVT      BBBBBB 22800019
         SPACE 2                                                 BBBBBB 23000019
*              TCB DEFINITION                                    BBBBBB 23200019
TCBTIOT  EQU   12                       POINTER TO TIOT          BBBBBB 23400019
TCBNEXT  EQU   116                      TCB LINK FIELD           BBBBBB 23600019
         SPACE 2                                                 BBBBBB 23800019
*              TIOT DEFINITION                                   BBBBBB 24000019
TIOTJOBN EQU   0                        POINTER TO JOB NAME      BBBBBB 24200019
         SPACE 2                                                 BBBBBB 24400019
*              REGISTER DEFINITION                               BBBBBB 24600019
TSTREG   EQU   1                        RQE POINTER              BBBBBB 24800019
PARMREG  EQU   1                        PARAMETER REG FOR WTO    BBBBBB 25000019
IOBREG   EQU   2                        IOB POINTER              BBBBBB 25200019
UCBREG   EQU   3                        UCB POINTER              BBBBBB 25400019
CVTREG   EQU   4                        CVT POINTER              BBBBBB 25600019
BASREG   EQU   12                       BASE REGISTER            BBBBBB 25800019
ERRLNK   EQU   14                       LINK REGISTER            BBBBBB 26000019
ERREG2   EQU   5                        WORK REGISTER            BBBBBB 26200019
ERREG3   EQU   6                        WORK REGISTER            BBBBBB 26400019
ERREG4   EQU   7                        WORK REGISTER            BBBBBB 26600019
ERREG5   EQU   8                        WORK REGISTER            BBBBBB 26800019
ERREG6   EQU   9                        WORK REGISTER            BBBBBB 27000019
ERREG7   EQU   10                       WORK REGISTER            BBBBBB 27200019
ERREG8   EQU   11                       WORK REGISTER            BBBBBB 27400019
ERREG9   EQU   13                       WORK REGISTER            BBBBBB 27600019
ERREGA   EQU   15                       WORK REGISTER            BBBBBB 27800019
BUFREG   EQU   15                       BUFFER POINTER           BBBBBB 28000019
ERREG0   EQU   0                        WORK REGISTER            BBBBBB 28200019
         SPACE 2                                                 BBBBBB 28400019
*              CEB DEFINITION                                    BBBBBB 28600019
CEBCTR   EQU   24                       DISPL FR NXAVL TO CEB CTRBBBBBB 28800019
CEBTBL   EQU   25                       DISP FR NXAVL TO CEB PTR BBBBBB 29000019
CEBFLG   EQU   0                        DISP IN CEB TO FLAGS     BBBBBB 29200019
CEBCHM   EQU   1                        DISPL IN CEB OF CHM FLD  BBBBBB 29400019
CEBRQE   EQU   2                        DISP TO CEB RQE FIELD    BBBBBB 29600019
CEBNXT   EQU   4                        CEB LENGTH               BBBBBB 29800019
*              CEB FLAGS                                         BBBBBB 30000019
CEBFREE  EQU   X'FE'                    CONST TO TEST IF CEB FREEBBBBBB 30200019
CEBACTV  EQU   X'01'                    ACTIVE CEB INDICATOR     BBBBBB 30400019
         SPACE 2                                                 BBBBBB 30600019
*              CVT DEFINITION                                    BBBBBB 30800019
LOC016   EQU   16                       ADDR. TO VECTOR TABLE    BBBBBB 31000019
CVTLINK  EQU   8                        PTR TO LINKLIB DCB       BBBBBB 31200019
CVTXCTL  EQU   44                       VECTOR TO XCTL RNT.      BBBBBB 31400019
CVTDCB   EQU   116                      LOGREC DCB POINTER       BBBBBB 31600019
CVTIXAVL EQU   124                      NEXT AVAILABLE RQE PTR   BBBBBB 31800019
CVTNUCB  EQU   128                      DISP IN CVT OF APR FLG   BBBBBB 32000019
CVTILCH  EQU   140                      LOGICAL CHN TABLE PTR    BBBBBB 32200019
CVTHEAD  EQU   160                      PTR TO FIRST TCB         BBBBBB 32400019
CVTMACSZ EQU   164                      MAXIMUM CORE SIZE        BBBBBB 32600019
CVTOTTA  EQU   182                      DISP TO NIP INDICATOR    BBBBBB 32800019
*              CVT FLAGS                                         BBBBBB 33000019
CVTNIP   EQU   X'10'                    NIP IN CONTROL FLAG      BBBBBB 33200019
APRVARP  EQU   X'40'                    APR FLAG IN CVT + 128    BBBBBB 33400019
MULTPROC EQU   X'14'                    MULTI PROCESSING FLAG    BBBBBB 33600019
MVT      EQU   X'10'                    MVT FLAG IN CVT + X'74'  BBBBBB 33800019
MFT      EQU   X'20'                    MFT FLAG IN CVT + X'74'  BBBBBB 34000019
PCP      EQU   X'40'                    PCP FLAG IN CVT + X'74'  BBBBBB 34200019
         SPACE 2                                                 BBBBBB 34400019
*              MULTI PROCESSING DEFINITION                       BBBBBB 34600019
AMPCHAN0 EQU   X'2A0'                   LOC OF CHAN TBL IN MP PFXBBBBBB 34800019
APREFIX2 EQU   X'2B0'                   PTR TO OTHER CPU'S PREFIXBBBBBB 35000019
MPPATHA  EQU   X'08'                    MULT PROC PATH FOR CPU A BBBBBB 35200019
MPPATHB  EQU   X'03'                    MULT PROC PTHS FOR CPU B BBBBBB 35400019
MP1PTH   EQU   X'0A'                    PATH TOT FOR MP SING PTH BBBBBB 35600019
MPMLTPTH EQU   X'0F'                    PATH TOT FOR 4 PATH DEV  BBBBBB 35800019
CPUA     EQU   C'A'                     ID FOR CPU A             BBBBBB 36000019
CPUB     EQU   C'B'                     ID FOR CPU B             BBBBBB 36200019
CPUID    EQU   24                       OFFSET TO CPU ID FROM TBLBBBBBB 36400019
CHNFLG   EQU   0                        FLAG FIELD IN MP CHAN TBLBBBBBB 36600019
CHNDOWN  EQU   X'70'                    CHANNEL DOWN INDICATOR   BBBBBB 36800019
         SPACE 2                                                 BBBBBB 37000019
*              MCS DEFINITIONS                                   BBBBBB 37020019
DARTCOD  EQU   X'10'                    D/A ROUTING CODE         BBBBBB 37040019
TAPRTCOD EQU   X'20'                    TAPE ROUTINE CODE        BBBBBB 37060019
URRTCOD  EQU   X'02'                    UNIT RECORD ROUTINE CODE BBBBBB 37080019
TPRTCOD  EQU   X'01'                    TP ROUTINE CODE          BBBBBB 37100019
         SPACE 2                                                 BBBBBB 37120019
*              MISCELLANEOUS DEFINITIONS                         BBBBBB 37200019
EXCPER   EQU   15                       ERROR EXCP               BBBBBB 37400019
EXIT     EQU   3                        SVC EXIT                 BBBBBB 37600019
TCBLKUP  EQU   4                        DISPL FROM NXT AVL-TCBTBLBBBBBB 37800019
ACHMSK   EQU   20                       DISPL FR NXTAVL - CHMSK  BBBBBB 38000019
LCHTCH   EQU   6                        OFFSET IN LCH TO TCH CODEBBBBBB 38200019
TBLLEN   EQU   4                        LENGTH OF TCH TBL FOR MP BBBBBB 38400019
VSERLN   EQU   6                        LENGTH OF VOLUME SERIAL  BBBBBB 38600019
INOPCNT1 EQU   41                       LEN OF INOP PTH MSG-NO MPBBBBBB 38800019
INOPCNT2 EQU   51                       INOP PATH MSG LEN FOR MP BBBBBB 39000019
TBLORG   EQU   240                      ORIGIN OF TRANSLATE TBL  BBBBBB 39200019
VALIDPTH EQU   X'0F'                    MASK FOR VALID PATHS     BBBBBB 39400019
CUMSK    EQU   X'F0'                    CONTROL UNIT MASK        BBBBBB 39600019
NOEXCEP  EQU   X'FB'                    SAVE ALL BITS BUT EXCEP  A57256 39650021
NOTOPER  EQU   X'30'                    CONDITION CODE 3 ON SIO  BBBBBB 39800019
COMMA    EQU   C','                     EBCDIC COMMA             BBBBBB 40000019
BLANK    EQU   X'40'                    BLANK CHARACTER          BBBBBB 40200019
ZERO     EQU   0                        ZERO COMPARAND           BBBBBB 40400019
D0       EQU   0                        DISPLACEMENT OF 0        BBBBBB 40600019
D1       EQU   1                        DISPLACEMENT OF 1        BBBBBB 40800019
D2       EQU   2                        DISPLACEMENT OF 2        BBBBBB 41000019
D8       EQU   8                        DISPLACEMENT OF 8        BBBBBB 41200019
D32      EQU   32                       DISPLACEMENT OF 32       S20201 41220020
D3       EQU   3                        DISPLACEMENT OF 3        S20201 41260020
D6       EQU   6                        DISPLACEMENT OF 6        S20201 41300020
DEVCLAS  EQU   X'02'                    DEVICE CLASS             S20201 41340020
         EJECT                                                   BBBBBB 41400019
*    THIS ROUTINE DETERMINES WHETHER AN INOP PATH MSG OR AN      BBBBBB 41600019
*    INT REQ MSG SHOULD BE ISSUED.                               BBBBBB 41800019
         USING *,BASREG                                          BBBBBB 42000019
IECXWTO  DS    0H                                                BBBBBB 42200019
         LR    BASREG,15                INITBASREG FROM ENTRYREG BBBBBB 42400019
         L     IOBREG,TSTIOB-1(0,TSTREG) INIT IOB POINTER        BBBBBB 42600019
         LH    UCBREG,TSTUCB(0,TSTREG)  INIT UCB PTR             BBBBBB 42800019
         L     CVTREG,LOC016            GET CVT POINTER          BBBBBB 43000019
         SPACE 1                                                 S20201 43010020
*   DETERMINE ROUTING CODE FOR THIS DEVICE TYPE                   20201 43020020
         MVC   RCTABEND-D2(D1),UCBTYP+DEVCLAS(UCBREG) SET TABL   S20201 43030020
         LA    ERREG5,RCTAB-D2          INITIALIZE POINTER       S20201 43050020
ERCOD    LA    ERREG5,D2(ERREG5)        STEP TO NEXT ENTRY       S20201 43070020
         CLC   UCBTYP+DEVCLAS(D1,UCBREG),ZERO(ERREG5) THIS ENTRY S20201 43090020
         BC    7,ERCOD                  NO, GET NEXT ENTRY       S20201 43110020
         MVC   BUFRTCOD(D1),D1(ERREG5)  INSERT ROUTING CODE      S20201 43130020
         MVC   INOPRTCD(D1),BUFRTCOD    PUT IN OTHER BUFFER      S20201 43150020
         SPACE 1                                                 S20201 43170020
         TM    IOBCC(IOBREG),VALIDPTH   TEST IF SINGLE PATH DEV  BBBBBB 43200019
         BC    9,ERRINT                 YES, TO INT REQ RTN     SA61720 43400021
         MVN   WORKCHM(1),IOBCC(IOBREG) MOVE PATH IND TO WKAREA  BBBBBB 43600019
         OC    UCBCHM(1,UCBREG),WORKCHM SET PATH DOWN IND IN UCB BBBBBB 43800019
         BC    15,ERRLAST               GO TO DETERM IF LAST PTH BBBBBB 44000019
         SPACE 1                                                 BBBBBB 44200019
*    THE ERRLAST ROUTINE RETURNS WITH THE CONDITION CODE SET     BBBBBB 44400019
*    TO 0 IF A LAST PATH SITUATION EXISTS.                       BBBBBB 44600019
ERR802   BC    7,ERRINOP                NO, ISSUE INOP PATH MSG  BBBBBB 44800019
         TM    CVTNUCB(CVTREG),APRVARP  TEST IF APR IN SYSTEM    BBBBBB 45000019
         BC    1,ERRAPR                 YES, GO TO TEST CEB      BBBBBB 45200019
         SPACE 1                                                 BBBBBB 45400019
*    THE ERRAPR ROUTINE RETURNS HERE IF NO CEBS WERE BEING       BBBBBB 45600019
*    PROCESSED FOR THIS RQE.  I.E., NO PATHS AVAILABLE.          BBBBBB 45800019
ERR800   XC    UCBCHM(1,UCBREG),WORKCHM RESET UCBCHM-LEAVE 1 PTH BBBBBB 46000019
         SPACE 3                                                 BBBBBB 46200019
*    THE FOLLOWING ROUTINE TESTS IF THE USER IS USING IBM ERROR  BBBBBB 46400019
*    ROUTINES.  IF NOT, CONTROL IS RETURNED TO IOS WHERE HE      BBBBBB 46600019
*    WILL BE POSTED IN ERROR.  OTHERWISE, THE INT REQ MESSAGE    BBBBBB 46800019
*    IS FORMATTED AND ISSUED.                                    BBBBBB 47000019
ERRINT   L     ERREG2,IOBDCB-1(0,IOBREG) GET DCB POINTER         BBBBBB 47200019
         TM    DCBFL(ERREG2),DCBIEK     TEST IOS ERROR KEY       BBBBBB 47400019
         BC    4+1,ERR802B              NO-RET TO IOS-POST ERR    M4775 47600019
         OI    UCBFL1(UCBREG),UCBNRY    SET DEV NOT READY        BBBBBB 47800019
         MVC   INTRQCUA(3),UCBUTN(UCBREG) MOVE UNIT NAME TO BUF  BBBBBB 48000019
         LA    BUFREG,INTRQVOL          INIT BUFREG TO VOLSER    BBBBBB 48400019
         CLI   UCBTYP+D2(UCBREG),UCBTAPE IS THIS TAPE            S20201 48470020
         BC    8,ERVS2                  YES, GO CHECK FOR VOL SERS20201 48610021
         CLI   UCBTYP+D2(UCBREG),UCBDA  IS THIS DA               S20201 48750020
         BC    7,ERRJOBN                NO, GO GET JOB NAME      S20201 48890020
         CLI   UCBTYP+D3(UCBREG),D2321  IS THIS 2321             S20201 49030020
         BC    7,ERVOL1                 NO, SKIP 2321 CODE       S20201 49170020
         SR    ERREG6,ERREG6            CLEAR REG                S20201 49310020
         IC    ERREG6,IOBSK+D1(IOBREG)  GET BIN NUMBER           S20201 49450020
         SLL   ERREG6,4                 MULTIPLY BY 16           S20201 49590020
         LA    UCBREG,D32(UCBREG,ERREG6) ALMOST POINT TO SUB UCB S20201 49730020
         SPACE 1                                                 S20201 49870020
*   GET BASE ADDRESS UCB IF THIS IS A ZEUS DRUM                   20201 49940020
ERVOL1   CLI   UCBTYP+D3(UCBREG),ZEUSA  IS THIS A ZEUS DRUM      S20201 50010020
         BC    8,ERSV1                  YES, GO GET BASE UCB     S20201 50150020
         CLI   UCBTYP+D3(UCBREG),ZEUSC  IS THIS A ZEUS DRUM      S20201 50290020
         BC    7,ERVS2                  NO, GO CHECK FOR A VALID S20201 50430020
ERSV1    L     UCBREG,UCBEXT(UCBREG)    GET POINTER TO UCB EXTEN S20201 50570021
         L     UCBREG,UCBBASE(UCBREG)   GET POINTER TO BASE UCB  S20201 50710020
*   UCBREG HAS INVALID UCB FROM HERE ON ----                      20201 50850020
         SPACE 1                                                 S20201 50920020
ERVS2    CLI   UCBVSER(UCBREG),ZERO     CHECK FOR VALID VOLSER   S20201 50990020
         BC    8,ERRJOBN                NO, GO FIND JOB NAME     S20201 51130020
         MVC   D0(D6,BUFREG),UCBVSER(UCBREG) MOVE VOL SER TO MSG S20201 51270020
ERR801   LA    BUFREG,VSERLN(0,BUFREG)  UPDATE BUFREG TO JOBN    BBBBBB 51600019
         SPACE 1                                                 BBBBBB 51800019
*    THE FOLLOWING MOVES THE JOBNAME TO THE BUFFER IF THE TCB    BBBBBB 52000019
*    CAN BE DETERMINED.                                          BBBBBB 52200019
ERRJOBN  MVI   D0(BUFREG),COMMA         MOVE COMMA AFTER VOLSER  BBBBBB 52400019
         LA    BUFREG,D1(0,BUFREG)      UPDATE BUFREG            BBBBBB 52600019
         L     ERREG5,TSTTCB(0,TSTREG)  GET TCB PTR IF MVT       BBBBBB 52800019
         TM    CVTDCB(CVTREG),MVT       CHECK SYSTEM TYPE FOR MVTBBBBBB 53000019
         BC    1,GETTIOT                NO, BRANCH               BBBBBB 53200019
         SR    ERREG6,ERREG6            CLEAR WORK REG           BBBBBB 53400019
         IC    ERREG6,TSTTCBID(0,TSTREG) GET TCB ID              BBBBBB 53600019
         SLL   ERREG6,2                 FORM OFFSET INTO TCB TBL  19054 53800019
         L     ERREG5,CVTIXAVL(0,CVTREG) GET PTR TO NEXT AVAIL.  BBBBBB 54000019
         L     ERREG5,TCBLKUP(0,ERREG5) GET PTR TO TCB TBL       BBBBBB 54200019
         L     ERREG5,D0(ERREG6,ERREG5) GET TCB PTR              BBBBBB 54400019
GETTIOT  L     ERREG6,TSTDEB-1(0,TSTREG) GET DEB PTR FROM RQE    BBBBBB 54600019
         L     ERREG6,DEBTCB(0,ERREG6)  GET TCB POINTER          BBBBBB 54800019
         LA    ERREG5,D0(0,ERREG5)      INSURE ZERO IN HI ORDER  BBBBBB 55000019
         LA    ERREG6,D0(0,ERREG6)      INSURE ZERO IN HI ORDER  BBBBBB 55200019
         CR    ERREG5,ERREG6            COMP TCB PTRS FOR VLDTY  BBBBBB 55400019
         BC    7,ERR814                 NOT EQUAL, OMIT JOBNAME  BBBBBB 55600019
         L     ERREG5,TCBTIOT(0,ERREG5) GET TIOT PTR             BBBBBB 55800019
         L     ERREG6,CVTMACSZ(0,CVTREG) GET HIGHEST CORE ADDR   BBBBBB 56000019
         SH    ERREG6,EIGHT             INSURE NO PGM CHK IN MVC BBBBBB 56200019
         CLR   ERREG5,ERREG6            TEST IF TIOT PTR TOO HIGHBBBBBB 56400019
         BC    2,ERR814                 YES, OMIT JOB NAME       BBBBBB 56600019
         LTR   ERREG5,ERREG5            TEST IF VALID TIOT PTR    M4046 56660019
         BC    8+4,ERR814               NO-OMIT JOB NAME          M4046 56720019
         MVC   D0(8,BUFREG),TIOTJOBN(ERREG5) MOVE JOBN TO BUFFER BBBBBB 56800019
         LA    BUFREG,D8(0,BUFREG)      POINTER TO END OF BUFFER BBBBBB 57000019
ERR814   LR    ERREG5,TSTREG            SAVE TSTREG OVER WTO     BBBBBB 57200019
         LA    PARMREG,INTRQMSG         INIT BUFFER PTR FOR WTO  BBBBBB 57400019
         MVC   D0(4,BUFREG),INTDESC      MOVE DES + RT COD TO BUFBBBBBB 57600019
         SR    BUFREG,PARMREG           COMPUTE BUFFER LENGTH    BBBBBB 57800019
         STH   BUFREG,INTRQMSG          STORE MSG LENGTH         BBBBBB 58000019
         BC    15,ERR809                GO TO ISSUE MSG          BBBBBB 58200019
         SPACE 3                                                 BBBBBB 58400019
*    THE FOLLOWING ROUTINE FORMATS AND ISSUES THE INOP PATH MSG  BBBBBB 58600019
ERRINOP  MVC   INOPCUA(3),UCBUTN(UCBREG) MOVE UNIT NAME TO BUF   BBBBBB 58800019
         MVI   INOPMSG+1,INOPCNT1       INIT LENGTH FOR NO MP    BBBBBB 59000019
         MVC   INOPDSRT(4),INOPDESC     MOVE RT + DESC CODES     BBBBBB 59200019
         TM    UCBALLC(UCBREG),MULTPATH TEST IF MULTI PATH DEV   BBBBBB 59400019
         BC    8,ERRI002                NO, NO TCH CHAN TBL      BBBBBB 59600019
*    ERREG2 POINTS TO TCH CHANNEL TABLE SUMMARY                  BBBBBB 59800019
         IC    ERREG5,D0(0,ERREG2)      GET TOT NUM OF PATHS     BBBBBB 60000019
         AR    ERREG5,ERREG5            DOUBLE FOR TBL LENGTH    BBBBBB 60200019
         SR    ERREG2,ERREG5            POINT TO START OF TBL    BBBBBB 60400019
         IC    ERREG5,WORKCHM           GET PATH INDICATOR       BBBBBB 60600019
         TM    CVTDCB(CVTREG),MULTPROC  TEST IF MP SYSTEM        BBBBBB 60800019
         BC    8+4,ERRI001              NO, GO TO FIND ENTRY     BBBBBB 61000019
ERRI002  MVI   INOPCPU,CPUA             INIT BUF TO CPU A        BBBBBB 61200019
         MVI   INOPMSG+1,INOPCNT2       REINIT MSG LENGTH        BBBBBB 61400019
         MVC   INOPDSRT(4),INOPTXT      REINIT BUFFER            BBBBBB 61600019
         TM    WORKCHM,MPPATHB          TEST IF CC 3 ON CPU B    BBBBBB 61800019
         BC    8,ERRI001                NO, GO TO FIND PATH      BBBBBB 62000019
         MVI   INOPCPU,CPUB             INIT BUF TO CPU B        BBBBBB 62200019
         SLL   ERREG5,2                 SHIFT PATH TO CPU A FORM BBBBBB 62400019
ERRI001  TM    UCBALLC(UCBREG),MULTPATH TEST IF MULTI PATH DEV   BBBBBB 62600019
         LH    ERREG4,UCBCUA(0,UCBREG)  INIT FOR NO TCH TBL      BBBBBB 62800019
         BC    8,ERRI003                NO, GO STORE PATH IN BUF BBBBBB 63000019
ERRI004  IC    ERREG4,D1(0,ERREG2)      GET PATH FROM TABLE      BBBBBB 63200019
         N     ERREG4,CHINDMSK          MASK OUT INVALID PATHS   BBBBBB 63400019
         CR    ERREG5,ERREG4            TEST IF THIS IS THE PATH BBBBBB 63600019
         BC    7,ERRI005                NO, GO TO UPDATE TBL PTR BBBBBB 63800019
         LH    ERREG4,D0(0,ERREG2)      GET CHANNEL ADDR         BBBBBB 64000019
         TM    D1(ERREG2),CUMSK         TEST IF SUBCHN IN PATH   BBBBBB 64200019
         BC    4+1,ERRI003              YES, GO STORE PATH IN BUFBBBBBB 64400019
         IC    ERREG4,UCBCUA+1(0,UCBREG) GET CTL UNIT FROM UCB   BBBBBB 64600019
ERRI003  SRL   ERREG4,4                 GET CHN + CTL UNIT IN BYTBBBBBB 64800019
         STC   ERREG4,INOPPATH          STORE CHN, CU IN BUF     BBBBBB 65000019
         UNPK  INOPPATH(3),INOPPATH(2)  UNPACK CHN + CU          BBBBBB 65200019
         TR    INOPPATH(2),ERRTBL-TBLORG TRANSLATE CHN + CU      BBBBBB 65400019
         MVI   INOPPATH+2,BLANK         REINIT BLANK             BBBBBB 65600019
         LR    ERREG5,TSTREG            SAVE TSTREG OVER WTO     BBBBBB 65800019
         LA    PARMREG,INOPMSG          INIT PARM REG TO WTO     BBBBBB 66000019
ERR809   OI    IOBFL1(IOBREG),IOBERR    INSURE RQE RETURN TO QUE BBBBBB 66100019
         TM    CVTOTTA(CVTREG),CVTNIP   TEST IF NIP IN CONTROL   BBBBBB 66200019
         BC    1,ERR802A                YES, NO MESSAGE          BBBBBB 66400019
         WTO   MF=(E,(1))                                        BBBBBB 66600019
ERR802A  LR    TSTREG,ERREG5            REINIT TST REG           BBBBBB 66800019
         NI    IOBFL1(IOBREG),NOEXCEP   TURN OFF EXCEP CONDITION A57256 66850021
ERR802B  SVC   EXCPER                   ISSUE SVC 15              M4775 67000019
         SVC   EXIT                     ISSUE SVC 3              BBBBBB 67200019
         SPACE 2                                                 BBBBBB 67400019
ERRI005  LA    ERREG2,D2(0,ERREG2)      UPDATE TBL PTR           BBBBBB 67600019
         BC    15,ERRI004               GO TO PROC NXT ENTRY     BBBBBB 67800019
         SPACE 3                                                 BBBBBB 68000019
*    THE FOLLOWING ROUTINE DETERMINES IF THERE ARE ANY ACTIVE    BBBBBB 68200019
*    CEBS FOR THE RQE THAT GOT THE CC 3.  IF NOT, THE INT REQ    BBBBBB 68400019
*    MESSAGE IS ISSUED.  IF SO, THE PATHS BEING PROCESSED BY APR BBBBBB 68600019
*    ARE RESET (IN UCBCHM), MAKING THEM AVAILABLE TO IOS, AND    BBBBBB 68800019
*    THE INOP PATH MESSAGE IS ISSUED.                            BBBBBB 69000019
ERRAPR   L     ERREG5,CVTIXAVL(0,CVTREG) GET PTR TO NEXT AVAIL.  BBBBBB 69200019
         SR    ERREG3,ERREG3            CLEAR REG                BBBBBB 69400019
         IC    ERREG3,CEBCTR(0,ERREG5)  GET CEB COUNT            BBBBBB 69600019
         L     ERREG4,CEBTBL-1(0,ERREG5)  GET PTR TO CEB TABLE   BBBBBB 69800019
         TM    CEBFLG(ERREG4),CEBACTV   TEST IF ANY ACTIVE CEBS  BBBBBB 70000019
         BC    8,ERR800                 NO, INT REQ MSG          BBBBBB 70200019
ERRAPR01 TM    CEBFLG(ERREG4),CEBFREE   TEST IF THIS CEB IN USE  BBBBBB 70400019
         BC    1,ERRAPR02               NO, GO UPDATE TO NEXT    BBBBBB 70600019
         CLC   UCBLTS(2,UCBREG),CEBRQE(ERREG4) TEST RETRY FOR RQEBBBBBB 70800019
         BC    7,ERRAPR02               NO, GO TO UPDATE         BBBBBB 71000019
         NC    UCBCHM(1,UCBREG),CEBCHM(ERREG4) RESET PATHS ONLINEBBBBBB 71200019
         OI    CEBFLG(ERREG4),CEBFREE   DEACTIVATE CEB           BBBBBB 71400019
         IC    ERREG3,UCBCUA(0,UCBREG)  GET CHANNEL ADDRESS      BBBBBB 71600019
         N     ERREG3,CHINDMSK          INSURE 4 BIT CHANNEL     BBBBBB 71800019
         L     ERREG4,ZRCHNMSK          GET CHAN 0 MASK          BBBBBB 72000019
         SRL   ERREG4,0(ERREG3)         FORM PROPER CHAN MASK    BBBBBB 72200019
         O     ERREG4,ACHMSK(0,ERREG5)  OR MASK WITH IOS CHMSK   BBBBBB 72400019
         ST    ERREG4,ACHMSK(0,ERREG5)  STORE NEW CHMSK          BBBBBB 72600019
         BC    15,ERRINOP               GO ISSUE INOP PATH MSG   BBBBBB 72800019
         SPACE 1                                                 BBBBBB 73000019
ERRAPR02 LA    ERREG4,CEBNXT(0,ERREG4)  UPDATE TO NEXT CEB       BBBBBB 73200019
         BCT   ERREG3,ERRAPR01          BRANCH TO HANDLE         BBBBBB 73400019
         BC    15,ERR800                APR NOT ACTIVE FOR THIS  BBBBBB 73600019
*                                       RQE - GO ISSUE INT REQ   BBBBBB 73800019
         SPACE 3                                                 BBBBBB 74000019
*    THE FOLLOWING ROUTINE DETERMINES IF THE LAST PATH TO A      BBBBBB 74200019
*    DEVICE GOT A CC 3.  THE UCBCHM FIELD IS COMPARED TO THE     BBBBBB 74400019
*    COMPOSITE OF ALL PATHS IN THE TCH TABLE.  IF EQUAL, A       BBBBBB 74600019
*    LAST PATH CONDITION EXISTS.  IF THE SYSTEM IS MP, THE       BBBBBB 74800019
*    UCBCHM MUST BE COMBINED WITH THE PATHS (CHANNELS) DOWN      BBBBBB 75000019
*    IN THE MP CHANNEL TABLES.  ALSO, THE COMPOSITE MUST BE      BBBBBB 75200019
*    UPDATED TO REFLECT THE CPU B PATHS.                         BBBBBB 75400019
ERRLAST  TM    UCBALLC(UCBREG),MULTPATH TEST MULTI PATH BIT TO   BBBBBB 75600019
*                                       DETERM IF TCH TBL EXISTS BBBBBB 75800019
         LA    ERREG8,UCBCUA(0,UCBREG)  INIT PTR FOR NO TABLE    BBBBBB 76000019
         LA    ERREG2,UCBCUA+2(0,UCBREG) INIT EOTBL PTR FOR NOTBLBBBBBB 76200019
         LA    ERREG4,MP1PTH            INIT TOTAL PATH REG FOR  BBBBBB 76400019
*                                       MULT PROC SINGLE PATH DEVBBBBBB 76600019
         BC    8,ERRL002                NO TBL- GO TEST MP CHNTBLBBBBBB 76800019
         L     ERREG2,CVTILCH(0,CVTREG) GET LCH TBL PTR          BBBBBB 77000019
         SR    ERREG4,ERREG4            CLEAR WORK REG           BBBBBB 77200019
         IC    ERREG4,UCBLCI(0,UCBREG)  GET LCH TBL INDEX        BBBBBB 77400019
         SLL   ERREG4,3                 MULT BY 8                BBBBBB 77600019
         LH    ERREG2,LCHTCH(ERREG4,ERREG2) GET TCH CODE PTR     BBBBBB 77800019
         N     ERREG2,HWDMSK            INSURE HALF WORD ADDR    BBBBBB 78000019
         BCTR  ERREG2,0                 BACK UP BY 2 TO POINT    BBBBBB 78200019
         BCTR  ERREG2,0                 TO TBL SUMMARY           BBBBBB 78400019
         IC    ERREG4,D1(0,ERREG2)      GET TOTAL OF PATH INDCTRSBBBBBB 78600019
         N     ERREG4,CHINDMSK          MASK OUT INVALID PATHS   BBBBBB 78800019
         TM    CVTDCB(CVTREG),MULTPROC  TEST FOR MULT PROC SYSTEMBBBBBB 79000019
         BC    1,ERRLMP                 YES, GO TO MP ROUTINE    BBBBBB 79200019
         IC    ERREG5,UCBCHM(0,UCBREG)  GET TOTAL PATH DOWN INDS BBBBBB 79400019
         N     ERREG5,CHINDMSK          MASK OUT INVALID PATHS   BBBBBB 79600019
ERRL001  CR    ERREG4,ERREG5            TEST IF ALL PATHS DOWN   BBBBBB 79800019
         BC    15,ERR802                RETURN WITH CC SET       BBBBBB 80000019
         SPACE 1                                                 BBBBBB 80200019
*    THIS CODE IS ENTERED FOR MP ONLY.                           BBBBBB 80400019
ERRLMP   LA    ERREG4,MPMLTPTH          INIT TOTAL TO 4 PATHS    BBBBBB 80600019
         LA    ERREG5,TBLLEN            GET TABLE LENGTH OF 4 -  BBBBBB 80800019
*                                       TWO 2-BYTE ENTRIES       BBBBBB 81000019
         LR    ERREG8,ERREG2            POINT TO END OF TBL      BBBBBB 81200019
         SR    ERREG8,ERREG5            POINT TO START OF TABLE  BBBBBB 81400019
ERRL002  LA    ERREG6,AMPCHAN0          GET PTR TO MP CHAN TBL   BBBBBB 81600019
         L     ERREG7,APREFIX2          POINT TO OTHER CPU PREFIXBBBBBB 81800019
         AR    ERREG7,ERREG6            PTR TO OTHER CPU CHN TBL BBBBBB 82000019
         SR    ERREG0,ERREG0            CLEAR PATH ACCUMULATOR   BBBBBB 82200019
ERRL003  IC    ERREG5,D0(0,ERREG8)      GET CHANNEL FROM TCH TBL BBBBBB 82400019
         N     ERREG5,CHINDMSK          MASK OUT INVALID CHAN -  BBBBBB 82600019
*                                       NEEDED FOR MP SING PATH  BBBBBB 82800019
         AR    ERREG5,ERREG5            DOUBLE TO GET OFFSET INTOBBBBBB 83000019
*                                       MP CHANNEL TABLE         BBBBBB 83200019
         LA    ERREG9,D0(ERREG5,ERREG6) POINT TO ENTRY IN MP TBL BBBBBB 83400019
         LR    ERREGA,ERREG6            BACK-UP TABLE PTR        BBBBBB 83600019
         BAL   ERRLNK,ERRL004           GO TO TEST ENTRY         BBBBBB 83800019
         LA    ERREG9,D0(ERREG5,ERREG7) POINT TO ENT IN OTHR TBL BBBBBB 84000019
         LR    ERREGA,ERREG7            BACK-UP TBL PTR          BBBBBB 84200019
         BAL   ERRLNK,ERRL004           GO TO TEST ENTRY         BBBBBB 84400019
         LA    ERREG8,D2(0,ERREG8)      UPDATE TCH TBL TO NXT CHNBBBBBB 84600019
         CR    ERREG8,ERREG2            TEST FOR END OF TCH TBL  BBBBBB 84800019
         BC    4,ERRL003                NO, GO GET NEXT CHANNEL  BBBBBB 85000019
         IC    ERREG5,UCBCHM(0,UCBREG)  GET PATH DOWN TOT IN UCB BBBBBB 85200019
         N     ERREG5,CHINDMSK          MASK OUT INVALID PAHTS   BBBBBB 85400019
         OR    ERREG5,ERREG0            OR IN TOT FROM MP CHN TBLBBBBBB 85600019
         BC    15,ERRL001               GO TO COMPARE PATH TOTALSBBBBBB 85800019
         SPACE 1                                                 BBBBBB 86000019
ERRL004  TM    CHNFLG(ERREG9),CHNDOWN   TEST IF THIS CHAN DOWN   BBBBBB 86200019
         BCR   8,ERRLNK                 NO, RETURN               BBBBBB 86400019
         TM    UCBALLC(UCBREG),MULTPATH TEST FOR MULTI PATH DEV  BBBBBB 86600019
         LA    ERREG3,MPPATHA           INIT FOR SINGLE PATH     BBBBBB 86800019
         BC    8,ERRL005                SINGLE PATH, GO TEST CPU BBBBBB 87000019
         IC    ERREG3,D1(0,ERREG8)      GET PATH FROM TCH TBL    BBBBBB 87200019
         N     ERREG3,CHINDMSK          MASK OUT INVALID PATHS   BBBBBB 87400019
ERRL005  CLI   CPUID(ERREGA),CPUA       TEST IF CPU A            BBBBBB 87600019
         BC    8,ERRL006                YES,PATH IN PROPER FORMATBBBBBB 87800019
         SRL   ERREG3,2                 SHIFT TO CPU B FORMAT    BBBBBB 88000019
ERRL006  OR    ERREG0,ERREG3            OR PATH IND INTO ACCUMLTRBBBBBB 88200019
         BCR   15,ERRLNK                RETURN                   BBBBBB 88400019
         EJECT                                                   BBBBBB 88600019
*              CONSTANTS AND WORK AREAS                          BBBBBB 88800019
         DS    0F                                                BBBBBB 89000019
CHINDMSK DC    X'0000000F'              MASK FOR VALID CHN PATHS BBBBBB 89200019
ZRCHNMSK DC    X'80000000'              MASK FOR CHANNEL 0       BBBBBB 89400019
HWDMSK   DC    X'0000FFFF'              HALF WORD MASK           BBBBBB 89600019
EIGHT    DC    H'8'                     HALF WORD CONSTANT 8     BBBBBB 89800019
         SPACE 2                                                 BBBBBB 90000019
*    INTERVENTION REQUIRED MESSAGE BUFFER                        BBBBBB 90200019
INTRQMSG DC    XL2'0'                   WTO MSG LENGTH           BBBBBB 90400019
         DC    XL2'8000'                MCS FLAG                 BBBBBB 90600019
INTRQBUF DC    CL40'IEA000A CUA,INT REQ,,CC=3/NO PATHS AVAIL'    BBBBBB 90800019
         DC    CL22'ABLE,,,VOLSER,JOBN'                          BBBBBB 91000019
INTDESC  DC    X'4000'                  IMMED ACT REQ DESCR CODE BBBBBB 91200019
BUFRTCOD DC    X'0000'                  ROUTING CODE             S20201 91300020
         SPACE 1                                                 BBBBBB 91600019
*    BUFFER DEFINITION                                           BBBBBB 91800019
INTRQCUA EQU   INTRQBUF+8                                        BBBBBB 92000019
INTRQVOL EQU   INTRQBUF+47                                       BBBBBB 92200019
         SPACE 2                                                 BBBBBB 92400019
*     INOPERATIVE PATH MESSAGE BUFFER                            BBBBBB 92600019
INOPMSG  DC    XL2'0'                   WTO MSG LENGTH           BBBBBB 92800019
         DC    XL2'8000'                MCS FLAG                 BBBBBB 93000019
INOPBUF  DC    CL37'IEA001I UNIT XXX, PATH YY INOPERATIVE'       BBBBBB 93200019
         DC    CL10' FOR CPU X'                                  BBBBBB 93400019
INOPDESC DC    X'1000'                  SYSTEM STAT DESCR CODE   BBBBBB 93600019
INOPRTCD DC    X'0040'                  ERROR ROUTING CODE       BBBBBB 93800019
         SPACE 1                                                 BBBBBB 94000019
*    BUFFER DEFINITION                                           BBBBBB 94200019
INOPCUA  EQU   INOPBUF+13                                        BBBBBB 94400019
INOPPATH EQU   INOPBUF+23                                        BBBBBB 94600019
INOPDSRT EQU   INOPBUF+37               RTING + DESCR CODES-NO MPBBBBBB 94800019
INOPCPU  EQU   INOPBUF+46                                        BBBBBB 95000019
         SPACE 2                                                 BBBBBB 95200019
ERRTBL   DC    C'0123456789ABCDEF'      TRANSLATE TABLE          BBBBBB 95400019
WORKCHM  DC    X'00'                    SVAREA FOR CURR PATH DOWNBBBBBB 95800019
INOPTXT  DC    C' FOR'                  TEXT FOR REINIT'G BUFFER BBBBBB 96000019
RCTAB    DC    X'0802'                  UR CLASS AND ROUTE CODE  S20201 96010020
         DC    X'2010'                  DA CLASS AND ROUTE CODE  S20201 96030020
         DC    X'4001'                  TP CLASS AND ROUTE CODE  S20201 96050020
         DC    X'8020'                  TAPE CLASS AND ROUTE     S20201 96070020
         DC    X'0040'                  DUMMY ENTRY             SA69928 96090021
RCTABEND DS 0H                                                   S20201 96110020
PATCH    EQU   *                        START OF PATCH AREA             96160021
         DC    (1024-(PATCH-IECXWTO))X'00'                              96170021
         END                                                            96200019
