         TITLE 'IGG019C5 - CH. END APP. FOR SYSOUT WRITER EXCP MODE'    00050021
*          RELEASE 21.8 DELETIONS/CHANGES                               00060021
* 420000,553000,574000                                           A66896 00180021
*          RELEASE 21.7 DELETIONS/CHANGES                               00190021
* 420000,574000                                                  SM5256 00200021
*                                                                       00210021
IGG019C5 CSECT                                                          00700019
*                                                                     * 01400019
*STATUS - CHANGE LEVEL 000                                            * 02100019
*                                                                     * 02800019
*FUNCTION/OPERATION - THIS MODULE IS THE NORMAL CHANNEL END APPENDAGE * 03500019
*              FOR THE SYSOUT WRITER. IT IS ENTERED FROM IOS UNDER    * 04200019
*              TWO CONDITIONS.                                        * 04900019
*                   1) WHEN A 12-HOLE IS SENSED IN A PRINTER CARRIAGE * 05600019
*                        CONTROL TAPE WITH A UNIT EXCEPTION.          * 06300019
*                        THIS INDICATES END OF FORM PAGE.             * 07000019
*                        IF NOT USER SPECIFIED,THE                    * 07700019
*                        SYSOUT WRITER THEN ACCESSES THE NEXT CCW VIA * 08400019
*                        THE IOBCSW, CHANGES THE CONTROL CHARACTER TO * 09100019
*                        SKIP TO CHANNEL ONE AND RETURNS CONTROL TO   * 09800019
*                        IOS TO COMPLETE EXECUTION OF THE CCW CHAIN.  * 10500019
*                                                                     * 11200019
*                   2) WHEN A CHAIN OF CCW'S HAS COMPLETED EXECUTION  * 11900019
*                        WITH A CHANNEL END.  THE SYSOUT WRITER TAKES * 12600019
*                        NO ACTION OTHER THAN RETURNING CONTROL TO    * 13300019
*                        IOS.                                         * 14000019
*********************************************************************** 14700019
*                                                                     * 15400019
*     ** NOTE **  THIS APPENDAGE IS USED ONLY WHEN THE SYSOUT WRITER  * 16100019
*                   IS USING EXCP AND COMMAND CHAINING UNDER          * 16800019
*                   CONDITIONS SPECIFIED IN IEFSD081.                 * 17500019
*                                                                     * 18200019
*********************************************************************** 18900019
*ENTRY POINT - THIS APPENDAGE IS ENTERED ONLY AT IGG019C5.            * 19600019
*                                                                     * 20300019
*INPUT REGISTERS - REGISTER  2 POINTS TO THE IOB                      * 21000019
*                  REGISTER 11 WORK REGISTER                          * 21700019
*                  REGISTER 14 CONTAINS THE RETURN ADDRESS TO IOS     * 22400019
*                  REGISTER 15 CONTAINS THE APPENDAGE ENTRY POINT     * 23100019
*                                                                     * 23800019
*EXITS - NORMAL - RETURN TO IOS ON REGISTER 14.                       * 24500019
*                                                                     * 25200019
*EXITS - ERROR - NONE                                                 * 25900019
*                                                                     * 26600019
*EXTERNAL ROUTINES - THIS APPENDAGE IS ALWAYS ENTERED FROM IOS AND    * 27300019
*                        EXITS TO IOS.                                * 28000019
*                                                                     * 28700019
*TABLES/WORKAREAS - NONE                                              * 29400019
*                                                                     * 30100019
*ATTRIBUTES - REENTRANT,NON-PRIVILEGED.                               * 30800019
*                                                                     * 31500019
*********************************************************************** 32200019
*                                                                     * 32900019
*  THE FOLLOWING ARE REGISTER ASSIGNMENTS.                            * 33600019
*                                                                     * 34300019
IOBREG   EQU   2                        IOB POINTER                     35000019
WORKREG  EQU   11                       WORK REGISTER                   35700019
RETREG   EQU   14                       IOS RETURN                      36400019
BASEREG  EQU   15                       APPENDAGE BASE AND ENTRY        37100019
FLAGF    EQU   X'FF'                    ONE BYTE FLAG                   37800019
NOP      EQU   X'03'                    NOP CCW OP CODE                 38500019
SKIPOPRT EQU   X'89'                    SKIP ONE PRINT OP CODE          39200019
SKIPNO   EQU   X'8B'                    SKIP NO PRINT OP CODE           39900019
ZERO     EQU   0                        DISPLACEMENT INDICATOR          40600019
STATUS   EQU   3                        CSW STATUS BYTE PTR             41300019
EOCFLAG  EQU   6                        END OF CHAIN IND LOC     A66896 42000021
EOCBITS  EQU   X'07'                    EOC INDICATOR            A66896 42050021
CHCCIND  EQU   7                        USER SPEC. CNTRL C FLAG         42700019
CCWLGN   EQU   8                        LENGTH OF 1 CCW                 43400019
*                                                                     * 44100019
UE       EQU   X'01'                    UNIT EXCEPTION                  44800019
         EJECT                                                          45500019
*********************************************************************** 46200019
         USING IOB,IOBREG               ESTABLISH ADDRESSIBILITY        46900019
         USING IGG019C5,BASEREG           TO IOB AND APPENDAGE          47600019
         SPACE                                                          48300019
ENTRY    EQU   *                                                        49000019
         SPACE                                                          49700019
         TM    IOBCSW+STATUS,UE         12 PUNCH SENSED                 50400019
         BNO   RETURN                   NO, RETURN TO IOS               51100019
         SPACE                                                          51800019
         L     WORKREG,IOBFLAG3         CCW ADDR FROM CSW               52500019
         LA    WORKREG,ZERO(WORKREG)    CLEAR HI-BYTE                   53200019
         SPACE                                                          53900019
CHAINEND EQU   *                                                        54600019
         TM    EOCFLAG(WORKREG),EOCBITS END OF CHAIN FLAGGED     A66896 55300021
         BNO   ADVANCE                  CHECK REST OF CHAIN             56000019
         TM    CHCCIND(WORKREG),FLAGF   USER SPECIFIED CNTRL CHAR       56700019
         BZ    RECOVER                  NO, PROVIDE C.C.         A66896 57400021
         SPACE                                                          58100019
RETURN   EQU   *                                                        58800019
         BR    RETREG                   RETURN TO IOS                   59500019
         SPACE                                                          60200019
ADVANCE  EQU   *                                                        60900019
         LA    WORKREG,CCWLGN(WORKREG)  ADVANCE TO NEXT CCW             61600019
         B     CHAINEND                 LOOK FOR CHAIN END              62300019
         SPACE                                                          63000019
RECOVER  EQU   *                                                        63700019
         L     WORKREG,IOBFLAG3         CCW ADDR FROM CSW               64400019
         LA    WORKREG,ZERO(WORKREG)    CLEAR HI-BYTE                   65100019
         TM    ZERO(WORKREG),NOP        IS CCW A NOP                    65800019
         BNO   NORMCCW                  NO, SKIP TO 1 W/PRINT           66500019
         MVI   ZERO(WORKREG),SKIPNO     YES, SKIP TO 1 NO PRINT         67200019
         B     RETURN                   RETURN TO IOS                   67900019
         SPACE                                                          68600019
NORMCCW  EQU   *                                                        69300019
         MVI   ZERO(WORKREG),SKIPOPRT   OP CODE SKIP TO ONE             70000019
         B     RETURN                   RETURN TO IOS                   70700019
*********************************************************************** 71400019
*                                                                       72100019
IOB      DSECT                                                          72800019
*                                                                       73500019
IOBFLAG1 DS    CL1                                                      74200019
IOBFLAG2 DS    CL1                                                      74900019
IOBSENS0 DS    CL1                                                      75600019
IOBSENS1 DS    CL1                                                      76300019
IOBECBCC DS    CL1                                                      77000019
IOBECBPT DS    CL3                                                      77700019
IOBFLAG3 DS    CL1                                                      78400019
IOBCSW   DS    CL7                                                      79100019
IOBSIOCC DS    CL1                                                      79800019
IOBSTART DS    CL3                                                      80500019
         DS    CL1                                                      81200019
IOBDCBPT DS    CL3                                                      81900019
         DS    CL1                                                      82600019
IOBRESTR DS    CL3                                                      83300019
IOBINCAM DS    CL2                                                      84000019
IOBERRCT DS    CL2                                                      84700019
*              THE CHANNEL COMMAND WORDS FOLLOW                       * 85400019
IOCCW    DS    CL8                                                      86100019
*              THESE ARE FOLLOWED BY THE BUFFERS                      * 86800019
         END                                                            87500019
