TT16     TITLE 'IGX00015-IS PURGE REQUIRED AT TASK TERMINATION'         00400021
IGX00015 CSECT                                                          00800021
         SPACE 1                                                        01200021
*                                                                     * 01600021
*                                                                     * 02000021
*          RELEASE 217 DELETIONS/CHANGES                                02400021
*          RELEASE 218 DELETIONS/CHANGES                                02450021
*                                                                     * 02800021
*                                                                     * 03200021
*STATUS CHANGE LEVEL 001                                              * 03600021
*                                                                     * 04000021
*TITLE 'IGX00015' - IS PURGE REQ'D AT TASK TERMINATION                  04400021
*                                                                     * 04800021
*FUNCTION/OPERATION                                                   * 05200021
*   IGX00015 IS AN ESR ROUTINE (SVC 109), WHICH IS USED BY TASK       * 05600021
*   TERMINATION TO ENSURE THAT A TASK CANNOT LEAVE OUTSTANDING I/O.   * 06000021
*   IF AN RQE IS ASSIGNED, ITS TCB ADDRESS IS CHECKED.  IF THE TCB    * 06800021
*   ADDRESS IN THE RQE MATCHES THE TERMINATING TASKS TCB, IGX00015    * 06850021
*   DETERMINES IF THE UCB REPRESENTS A TP DEVICE.  IF YES, THE TASK   * 07200021
*   IS ABENDED WITH A 3FE ABEND CODE.  IF THERE ARE NO ASSIGNED       * 07210021
*   RQE'S FOR THE TERMINATING TASK, SVC 3 IS ISSUED.  IF THE          * 07600021
*   ASSIGNED RQE'S REPRESENT NON/TP-ASSOCIATED I/O, AND THE           * 08000021
*   TERMINATING TASK IS NOT THE OWNER, (SUCH AS A SUBTASK             * 08010021
*   TERMINATING, LEAVING OUTSTANDING I/O REQUESTS WHICH ARE OWNED     * 08020021
*   BY THE MOTHER TASK) AN ATTEMPT IS MADE TO REASSIGN THE REQUEST    * 08050021
*   TO ITS OWNER.  IF I/O CAN NOT BE REASSIGNED, IGX00015 SETS UP     * 08100021
*   FOR, AND ISSUES THE PURGE SVC (SVC 16) WITH THE QUIESCE OPTION.   * 08200021
*   IF AN IOB CHAIN FOR RESTORE RESULTS, THE TASK IS ABENDED WITH     * 08400021
*   ABEND CODE 4FE.  IF NO IOB CHAIN RESULTS, SVC 3 IS ISSUED.        * 08800021
*                                                                     * 09200021
*ENTRY POINT                                                          * 09600021
*   IGX00015 IS ENTERED WITH ENVIRONMENTAL REGS SET                   * 10000021
*                                                                     * 10400021
*INPUT                                                                * 10800021
*   REGS-ENVIRONMENTAL REGS                                           * 11200021
*                                                                     * 11600021
*OUTPUT                                                               * 12000021
*   REGS-ENVIRONMENTAL REGS INTACT                                    * 12400021
*   IOB CHAIN BUILT,IF REQUIRED,AT TCBIOBRC                           * 12800021
*                                                                     * 13200021
*EXTERNAL ROUTINES                                                    * 13600021
*   GETMAIN,FREEMAIN                                                  * 14000021
*                                                                     * 14400021
*EXITS                                                                * 14800021
*   'NORMAL'-SVC 3                                                    * 15200021
*   'ERROR'-ABEND                                                     * 15600021
*                                                                     * 16000021
*TABLES/PARAMETER LISTS                                               * 16400021
*   EXTERNAL-RQE TABLE                                                * 16800021
*   INTERNAL-PURGE PARAMETER LIST(PPL)                                * 17200021
*                                                                     * 17600021
*ATTRIBUTES                                                           * 18000021
*   REENTRANT,REFRESHABLE                                             * 18400021
*                                                                     * 18800021
*********************************************************************** 19200021
         EJECT                                                          19600021
*********************************************************************** 20000021
*                                                                     * 20400021
*                               EQUATES                               * 20800021
*                                                                     * 21200021
*********************************************************************** 21600021
*          REGISTER DEFINITIONS                                       * 21650021
*********************************************************************** 21700021
R0       EQU   0                        PARAMETER REG                   21750021
PARMREG  EQU   1                        PARAMETER                       21800021
ACTREG   EQU   2                        ACTIVE RQE COUNT                21850021
CVTREG   EQU   3                        CVT                             21900021
TCBREG   EQU   4                        TCB                             21950021
RBREG    EQU   5                        RB                              21960021
BASREG   EQU   6                        BASE REG                        21970021
RQEREG   EQU   7                        RQE                             21980021
DEBTCBRG EQU   8                        TCB FROM DEB                    21990021
UCBREG   EQU   8                        UCB                             21992021
RQTREG   EQU   9                        TCB FROM RQE                    21994021
WKREGA   EQU   10                       TCB REST. CHAIN,                21996021
WKREGB   EQU   11                       RQE SIZE                        21998021
WKREGC   EQU   12                       *                               21998421
R13      EQU   13                       *                               21998821
RETREG   EQU   14                       RETURN                          21999221
EPREG    EQU   15                       EP                              21999621
*                                                                     * 21999721
*********************************************************************** 22400021
*          DISPLACEMENTS                                              * 22800021
*********************************************************************** 23200021
CVTIOQET EQU   X'78'                    DISP--BEGIN RQE'S               23600021
CVTDCBD  EQU   116                      DISPL TO MFT/MVT IND.           24000021
CVTMFTI  EQU   X'20'                    MFT INDICATOR                   24400021
CVTHEAD  EQU   160                      DISP TO FIRST TCB PTR           24450021
PPLCDSP  EQU   8                        DISP INTO PPL FOR RST CHN       24800021
PPLODSP  EQU   0                        DISP FOR PPL OPTION BYTE        25200021
PPLTDSP  EQU   4                        DISP INTO PPL FOR TCB           25600021
RQEIDT   EQU   4                        DISPL TO 'ASSIGNED' FLAG        26000021
*                                       AND ID OF TCB                   26400021
RQDDSP   EQU   8                        DISP INTO RQE FOR DEB           26450021
RQTDSP   EQU   12                       DISP INTO RQE FOR TCB           26800021
RQUDSP   EQU   2                        DISP INTO RQE FOR UCB           27200021
TCBFL1   EQU   29                       DISP TO FIRST TCB FLAG BYTE     27250021
TCBRSCH  EQU   X'BC'                    DISPL TO RESTORE CHN            27600021
TCBIDF   EQU   112                      TCB ID                          28000021
TCBTCB   EQU   116                      DISP TO NEXT TCB PTR            28050021
UCBETI   EQU   8                        DISPL TO ERP INDICATOR          28400021
UCBTYPD  EQU   18                       DISP TO DEVICE TYPE             28800021
*                                                                     * 29200021
*********************************************************************** 29600021
*          LENGTHS AND INCREMENTS                                     * 30000021
*********************************************************************** 30400021
RQELNGF  EQU   12                       RQE LENGTH--MFT                 30800021
RQELNGV  EQU   16                       RQE LENGTH--MVT                 31200021
ONE      EQU   1                        ONE                             31600021
SIX      EQU   6                        INCR 6                          32000021
THREE    EQU   3                        INCR 3                          32400021
ZIP      EQU   0                        ZERO                            32800021
*                                                                     * 33200021
*********************************************************************** 33600021
*          MISCELLANEOUS                                              * 34000021
*********************************************************************** 34400021
SVC3     EQU   3                        EXIT                            34800021
SVC16    EQU   16                       PURGE                           35200021
*                                                                     * 35600021
A3FE     EQU   X'803FE000'              ABEND CODE-TP                   36000021
A4FE     EQU   X'804FE000'              ABEND CODE-REST. CHN.           36400021
TP       EQU   X'40'                    TP DEVICE BYTE FOR UCBTYP       37200021
TTOPT    EQU   X'42'                    OPTION BYTE IN PPL FOR TT       37600021
NERESTX  EQU   TCBRSCH+THREE            SPOT IN TCBIOBRC 4 NULL         38400021
ENDRQE   EQU   X'01'                    END OF RQE TABLE CHECK          38800021
FF       EQU   X'FF'                    RQE ACTIVE CHECK                39200021
*                                       AND MASK                        39210021
ZERO     EQU   0                        RQE ACTIVE CHECK                39250021
*                                                                     * 39600021
*********************************************************************** 40000021
         EJECT                                                          49600021
         BALR  BASREG,ZIP               EST BASE                        50400021
         USING *,BASREG                 ESTABLISH ADDRESSABILITY        50800021
         SR    ACTREG,ACTREG            INIT. ACTIVE RQE COUNT          51600021
         LA    TCBREG,ZIP(TCBREG)       ASSURE CLEAR HI-BYTE            52000021
         CLI   CVTDCBD(CVTREG),CVTMFTI  MFT SYSTEM                      52400021
         BE    MFTRS                    GO GET MFT RQE SIZE             52800021
         LA    WKREGB,RQELNGV           LOAD RQE SIZE FOR MVT           53200021
         SPACE 1                                                        53600021
* THIS SECTION SEARCHES RQE TABLE AND INTERPRETS SEARCH RESULTS       * 54000021
BGNRT    EQU   *                        BEGIN RQE'S                     54400021
         L     RQEREG,CVTIOQET(CVTREG)  BEGIN OF RQE TABLE              54800021
ACTRQE   CLI   RQEIDT(RQEREG),FF        RQE ACTIVE                      55200021
         BE    NXTRQE                   NO, GET NEXT RQE        SA65989 55600021
         CLI   CVTDCBD(CVTREG),CVTMFTI  MFT SYSTEM              SA65989 55650021
         BE    CKTCB                    YES, CHECK IF THIS TCB  SA65989 55700021
         CLI   RQEIDT(RQEREG),ZERO      RQE ACTIVE              SA65989 55750021
         BE    CKTCB                    YES, CHECK IF THIS TCB  SA65989 55800021
NXTRQE   LA    RQEREG,ZIP(WKREGB,RQEREG) INC TO NEXT RQE                56000021
         CLI   ONE(RQEREG),ENDRQE       END OF RQE TABLE                56400021
         BNE   ACTRQE                   NO,CHECK FOR ACTIVE RQE         56800021
         LTR   ACTREG,ACTREG            ANY ACTIVE RQE'S                57200021
         BNZ   NEED16                   GO DO PURGE                     57600021
         SVC   SVC3                     NO,RETURN TO EOT                58000021
         SPACE 1                                                        58400021
MFTRS    LA    WKREGB,RQELNGF           LOAD RQE SIZE FOR MFT           58800021
         B     BGNRT                    GET BEGINNING RQE               59200021
         SPACE 1                                                        60000021
CKTCB    EQU   *                                                        60400021
         CLI   CVTDCBD(CVTREG),CVTMFTI  MFT SYSTEM                      60800021
         BE    CKMFTCB                  GO CHECK ID'S                   61200021
         L     RQTREG,RQTDSP(RQEREG)    GET TCB IN RQE                  61600021
         LA    RQTREG,ZIP(RQTREG)       CLEAR HI-BYTE                   62000021
         CR    TCBREG,RQTREG            RQE FOR TERM'G TASK             62400021
         BNE   NXTRQE                   NO,GET NEXT RQE                 62800021
         SPACE 1                                                        63200021
* THIS SECTION CHECKS THE UCB                                         * 63600021
CKUCB    EQU   *                        EXAMINE UCB                     64000021
         LH    UCBREG,RQUDSP(RQEREG)    GET UCB FROM RQE                64400021
         N     UCBREG,MASK1             CLEAR LO-BIT IF ON - AEQ        64800021
         TM    UCBETI(UCBREG),FF        IGE0025E SCHEDULED              65200021
         BNO   UCBOK                    NO,UCB ADDR OK                  65600021
         LA    UCBREG,SIX(UCBREG)       RE-ADJUST TO UCB ADDR           66000021
UCBOK    EQU   *                        UCB ADDR OK                     66400021
         CLI   UCBTYPD(UCBREG),TP       ACTIVE RQE FOR TP               66800021
         BNE   CTACNTP                  NO,COUNT ACTIVE,NON-TP          67200021
         ABEND A3FE,DUMP                LEFTOVER TP I/O---TERM. SA65836 67600021
         SPACE 1                                                        68000021
*    THIS SECTION ATTEMPTS TO ASSIGN OUTSTANDING I/O REQUESTS TO        68050021
*    THE OWNER OF THE I/O, IF THE OWNER IS NOT THE TERMINATING TASK     68400021
CTACNTP  EQU   *                                                        68800021
         L     DEBTCBRG,RQDDSP(RQEREG)  GET DEB FROM RQE                68810021
         L     DEBTCBRG,0(DEBTCBRG)     GET TCB ADDR FROM DEB           68820021
         LA    DEBTCBRG,0(DEBTCBRG)     CLEAR HIGH ORDER BYTE           68830021
         LTR   DEBTCBRG,DEBTCBRG        ANY ADDRESS                     68840021
         BC    8,INCRCNT                NO, INCREMENT PRG CNT           68842021
         CR    DEBTCBRG,TCBREG          TASK OWN DEB                    68844021
         BC    8,INCRCNT                YES, INCREMENT PRG CNT          68846021
         L     WKREGA,CVTHEAD(CVTREG)   GET HIGHEST PRIOR TCB AD        68848021
TCBLOOP  CR    DEBTCBRG,WKREGA          DEB TCB ON TCB CHAIN            68848421
         BC    8,CHGTCBAD               YES, CHANGE RQE TCB ADDR        68848821
         L     WKREGA,TCBTCB(WKREGA)    GET NEXT TCB ON CHAIN           68849221
         LTR   WKREGA,WKREGA            END OF CHAIN                    68849621
         BC    8,INCRCNT                YES, INCREMENT PRG CNT          68849721
         B     TCBLOOP                  CHECK TCB                       68849821
         SPACE 1                                                        68849921
CHGTCBAD EQU   *                                                        68899921
         TM    TCBFL1(WKREGA),FF        IS I/O OWNER TERMINATING        68909921
         BC    4+1,INCRCNT              YES, INCREMENT PRG CNT          68919921
         CLI   CVTDCBD(CVTREG),CVTMFTI  MFT SYSTEM                      68929921
         BC    8,CHGMFT                 YES, CHANGE TCB ID              68939921
         IC    R0,RQTDSP(RQEREG)        SAVE RQE PRIORITY               68941921
         ST    DEBTCBRG,RQTDSP(RQEREG)  CHANGE RQE TCB ADDR             68943921
         STC   R0,RQTDSP(RQEREG)        RESTORE RQE PRIORITY            68945921
         BC    15,NXTRQE                GET NEXT RQE                    68947921
         SPACE 1                                                        68948321
CHGMFT   EQU   *                                                        68948721
         MVC   RQEIDT(ONE,RQEREG),TCBIDF(WKREGA) RQE FOR TERM'G TASK    68949121
         BC    15,NXTRQE                GET NEXT RQE                    68949521
         SPACE 1                                                        68949621
*    THIS SECTION MAINTAINS A COUNT OF THE NUMBER OF                    68949721
*    OUTSTANDING I/O REQUESTS                                           68999721
         SPACE 1                                                        69049721
INCRCNT  LA    ACTREG,ONE(ACTREG)       COUNT ACTIVE NON-TP I/O         69099721
         B     NXTRQE                   GET NEXT RQE                    69200021
         SPACE 1                                                        69600021
CKMFTCB  EQU   *                       ID CHECK                         70000021
         CLC   RQEIDT(ONE,RQEREG),TCBIDF(TCBREG) RQE FOR TERM'G TASK    70400021
         BE    CKUCB                   YES,GO CHECK UCB                 70800021
         B     NXTRQE                  GET NEXT RQE                     71200021
         TITLE 'PURGE IS NEEDED'                                        71600021
* THIS SECTION BUILDS PPL AND ISSUES SVC 16(PURGE)                    * 72000021
NEED16   EQU   *                        SVC 16 REQUIRED                 72400021
         L     R0,SPNLNGH               GET SP AND LNGH                 72800021
         GETMAIN R,LV=(0)               GET CORE FOR PPL                73200021
         ST    TCBREG,PPLTDSP(PARMREG)  TCB ADDR TO PPL                 73600021
         LA    WKREGA,TCBRSCH(TCBREG)   GET ADDR OF BEGIN/RST CHN       74000021
         ST    WKREGA,PPLCDSP(PARMREG)  PTR TO RST CHN BEGIN            74400021
         MVI   PPLODSP(PARMREG),TTOPT   OPTION BYTE                     74800021
         LR    WKREGA,PARMREG           SAVE PPL CORE LOC               75200021
*  REG 1 HAS ADDR OF PPL                                                75600021
         SVC   SVC16                    PURGE                           76000021
         SPACE 1                                                        76400021
         LR    PARMREG,WKREGA           RESTORE PPL CORE LOC            76800021
         L     R0,SPNLNGH               GET SP AND LNGH                 77200021
         FREEMAIN R,LV=(0),A=(1)        FREE PPL CORE                   77600021
         SPACE 1                                                        78000021
* THIS SECTION INTERPRETS RESULT OF SVC 16                            * 78400021
         SPACE 1                                                        78800021
         CLI   NERESTX(TCBREG),FF       IOB'S ON CHAIN---RESTORE        79200021
         BE    RTNORES                                                  79600021
         ABEND A4FE,DUMP                LEFTOVER NON-TP I/O     SA65836 80000021
*                                          RESTORE CHAIN BUILT          80400021
         SPACE 2                                                        81200021
RTNORES  SVC   SVC3                     RETURN TO EOT/NO REST. CH       82000021
         EJECT                                                          83200021
*********************************************************************** 83600021
*CONSTANTS WHICH REQUIRE FULL-WORD BOUNDARY                             84000021
*                                                                       84400021
SPNLNGH  DS    0F                                                       84800021
         DC    AL1(253)                 SUBPOOL 253             SA64058 85200021
         DC    AL3(16)                  CORE REQ'D FOR PPL              85600021
MASK1    DC    X'FFFFFFFE'              CLEAR LO-BIT K                  86000021
*                                                                       86400021
*********************************************************************** 86800021
         END                                                            87200021
