 TITLE 'IGC0006C (IHJACP00) CHECKPOINT HOUSEKEEPING ROUTINE- 1ST LOAD'  00002017
*0333                                                            M1848  00003020
*0333                                                            A38481 00003520
*STATUS CHANGE LEVEL 003                                                00004020
*FUNCTION/OPERATION:                                                    00006017
*   1.) IF CHKPT IS TO BE SUPPRESSED(I.E.,IF RD=NC OR RD=RNC WAS SPEC-  00008017
*       IFIED ON JOB OR EXEC CARD), THIS ROUTINE WILL PLACE A RETURN    00010017
*       CODE OF X'00' IN REGISTER 15 AND RETURN CONTROL TO USER.        00012017
*   2.) IF 'CANCEL' REQUEST WAS SPECIFIED BY CHKPT MACRO                00014017
*       A.) A GETMAIN IS ISSUED FOR A WORK AREA IN SUBPOOL 0 OF THE     00016017
*           PROBLEM PROGRAM REGION. THE WORK AREA IS INITIALIZED, THE   00018017
*           ADDRESS OF THE WORK AREA IS PLACED IN REGISTER 1 AND XCTL   00020017
*           TO IGC0206C.                                                00022017
*       B.) IF GETMAIN WAS UNSUCCESSFUL A RETURN CODE OF X'08' IS       00024017
*           PLACED IN THE SVRB EXTENDED SAVE AREA AND CONTROL IS TRANS- 00026017
*           FERED TO CHKPT EXIT ROUTINE, IGC0Q06C.                      00028017
*   3.) FOR NORMAL PROCESSING OF CHKPT THIS ROUTINE PERFORMS THE        00030017
*       FOLLOWING:                                                      00032017
*        *  DETERMINES WHETHER THE CHKPT PARAMETER LIST IS VALID. IF    00033017
*           IT IS INVALID, THIS ROUTINE PUTS A RETURN CODE OF X'08'     00034017
*           IN THE SVRB EXTENDED SAVE AREA AND XCTLS TO IGC0Q06C.       00035017
*                                                                       00036017
*        *  DETERMINES WHETHER THE CHKPT DATA SET IS OPEN. IF IT IS     00037017
*           NOT OPEN, THIS ROUTINE WILL OPEN THE DATA SET. IF OPEN WAS  00038017
*           UNSUCCESSFUL, EITHER AN I/O OR CHKPT DD ERROR OCCURRED AND  00039017
*           A RETURN CODE OF X'0C' IS PLACED IN THE SVRB EXTENDED SAVE  00040017
*           AREA AND THIS ROUTINE XCTLS TO IGC0Q06C.                    00041017
*                                                                       00042017
*        *  COMPUTES THE SIZE OF THE CHKPT WORK AREA.                   00043017
*                                                                       00044017
*        *  GETS CORE FOR THE WORK AREA FROM SUBPOOL ZERO IF POSSIBLE.  00045017
*           IF THERE IS NOT ENOUGH SPACE, A RETURN CODE OF X'08' IS     00046017
*           PLACED IN THE SVRB EXTENDED SAVE AREA AND THIS ROUTINE      00047017
*           XCTLS TO IGC0Q06C.                                          00048017
*                                                                       00048717
*        *  MAKES SURE THAT THE BOUNDARIES OF THE WORK AREA ARE         00049417
*           MORE THAN 17 BYTES (MINIMUM OUTPUT RECORD SIZE) AWAY        00050117
*           FROM THE BOUNDARIES OF PP CORE.                             00050817
*                                                                       00051517
*        *  FILLS IN THE FIRST PART OF THE WORK AREA WITH               00052217
*           INFORMATION NEEDED BY OTHER CHKPT MODULES.                  00052917
*                                                                       00054017
*ENTRY POINTS: IGC0006C                                                 00055017
*INPUT:  ADDRESS OF PARAMETER LIST(SHOWN BELOW) IN REGISTER 1.          00064017
*   AL2(FLAG)    FLAG EQUALS X'80' IF NO CHECKID WAS SPECIFIED BY THE   00066017
*                USER AND THE GENERATED CHECKID ADDRESS IS NOT TO BE    00068017
*                RETURNED TO THE USER. FLAG EQUALS X'00' IF CHECKID WAS 00070017
*                SPECIFIED.                                             00073017
*   AL3(DCBORCN) ADDRESS OF CHKPT DCB.                                  00076017
*   AL1(LENGTH)  LENGTH OF USER SPECIFIED CHECKID. IF THIS BYTE EQUALS  00077017
*                X'FF', THIS INDICATES THAT THE USER WANTS THE SYSTEM   00078017
*                TO GENERATE A CHECKID AND RETURN IT AT THE LOCATION    00079017
*                SPECIFIED BY IDADDR.                                   00080017
*   AL3(IDADDR)   IF USER SUPPLIES THE CHECKID, THIS FIELD WILL POINT   00081017
*                TO THAT CHECKID. IF THE SYSTEM IS TO SUPPLY THE        00082017
*                CHECKID, THIS FIELD POINTS TO AN 8 BYTE AREA WHERE     00083017
*                THE GENERATED CHECKID WILL BE RETURNED.                00084017
*   IF 'CANCEL' WAS SPECIFIED IN THE CHKPT MACRO, REGISTER 1 WILL CON-  00086017
*   TAIN ALL ZEROS.                                                     00088017
*OUTPUT:  A RETURN CODE AND MESSAGE CODE WILL BE PLACED IN THE SVRB     00090017
*   EXTENDED SAVE AREA IF AN ERROR EXISTS.                              00092017
*   1.) IF THE USER REQUESTS THAT CHKPTS BE SUPPRESSED, A RETURN CODE   00094017
*       OF X'00' IS GIVEN.                                              00096017
*   2.) IF THIS ROUTINE WAS UNSUCCESSFUL IN OPENING CHKPT DATA SET      00098017
*       THEN A RETURN CODE OF X'0C' WILL BE GIVEN.                      00100017
*   3.) IF A WORK AREA OF THE PROPER SIZE AND LOCATION COULD NOT BE     00102017
*       GETMAIN'D OR IF THE PARAMETER LIST CONTAINS AN INVALID ADDRESS  00104017
*       THEN A RETURN CODE OF X'08' IS GIVEN.                           00106017
*   4.) IF NORMAL CHKPT PROCESSING IS TO CONTINUE, THE ADDRESS OF THE   00108017
*       CHKPT WORK AREA WILL BE PLACED IN REGISTER 1.                   00110017
*   ONE OF THE FOLLOWING MESSAGE CODES IS PLACED IN THE SVRB EXTENDED   00112017
*   SAVE AREA TO BE PRINTED IN THE CONSOLE MESSAGE BY THE CHKPT EXIT    00114017
*   ROUTINE IF AN ERROR OCCURS:                                         00116017
*        DEC VALUE  MNEMONIC                 MEANING                    00118017
*            1      CKERPG1        PARAMETER LIST ERROR                 00120017
*            2      CKERPG2        OPEN UNSUCCESSFUL                    00122017
*            3      CKERPG3        GETMAIN UNSUCCESSFUL                 00124017
*            4      CKERPG4        CHKPT WORK AREA EXTENDS TOO LOW      00126017
*           20      CKERPG20       JOB INVOKING ROLLOUT          A26719 00127019
*   IF ANY ERROR OCCURS, THIS ROUTINE XCTL'S TO IGC0Q06C WITH THE       00128017
*   FOLLOWING INPUT:                                                    00130017
*   REGISTER 1 - CONTAINS ALL ZEROS.                                    00132017
*   REGISTER 5 - ADDRESS SVRB                                           00140017
*   ONE BYTE OF FLAGS IN SVRB EXTENDED SAVE AREA TO DETERMINE WHAT      00142017
*   ACTION IS TO BE TAKEN BY CER AND WHAT MESSAGE IS TO BE WRITTEN.     00144017
*  ACTION IS TO BE TAKEN BY CER, RETURN CODE AND MESSAGE CODE IN        00144517
*  BYTES 0-3, TIOT ADDRESS IN BYTES 33-35 AND DCB ADDRESS IN BYTES      00145017
*  37-39 (IF A BAD PARAMETER LIST IS PASSED BYTES 37-39 WILL BE ZERO).  00145517
*EXTERNAL ROUTINES:  IEAOVLOO - ADDRESS OF VALIDITY CHECK ROUTINE       00146017
*SVCS USED  GETMAIN, FREEMAIN, OPEN, XCTL, SVC3                         00148017
*EXITS-NORMAL:                                                          00150017
*   1.) XCTL TO IGC0106C IF NORMAL PROCESSING OF CHKPT CAN CONTINUE.    00152017
*   2.) XCTL TO IGC0206C IF 'CANCEL' WAS SPECIFIED.                     00154017
*   3.) RETURN TO USER IF CHKPT'S ARE TO BE SUPPRESSED.                 00156017
*EXITS-ERROR:                                                           00158017
*   1.) XCTL TO IGC0Q06C IF THIS ROUTINE WAS UNABLE TO:                 00160017
*       A.) GETMAIN FOR THE WORK AREA                                   00162017
*       B.) OPEN THE CHKPT DATA SET.                                    00164017
*       C.) VALIDATE THE ADDRESSES OF THE PARAMETER LIST.               00166017
*TABLES/WORKAREAS CREATED:  CHKWA IS THE FIRST PART OF THE CHKPT WORK   00168017
*   AREA. THIS ROUTINE FILLS IN THE WORK AREA WITH INFORMATION THAT IS  00170017
*   NEEDED BY OTHER CHKPT ROUTINES.                                     00172017
*TABLES/WORKAREAS REFERENCED  CVT, TCB, TIOT, SVRB, DCB, DEB, PQE,      00174017
*   AND THE PCP/MFT BOUNDARY BOX                                        00176017
*ATTRIBUTES:  REENTRANT, SUPERVISOR STATE, TYPE 4 SVC ROUTINE.          00178017
*RESTRICTIONS ON USE OF ROUTINE:  MAY NOT BE USED IN OS/MFT.            00180017
*NOTES:  NONE                                                           00190017
IGC0006C CSECT                                                          00290017
*228000,253000                                                     I283 00295019
* 041000,041400,045000                                           A26719 00300019
         USING CVTSECT,R3          ADDRESS CVT.                         00400017
         USING TCBSECT,R4          ADDRESS TCB.                         00600017
         USING TIOTSECT,R2         ADDRESS TIOT.                        00800017
         USING HKPSECT,R5          ADDRESS CHKPT SVRB                   01000017
         BALR  RB,0      BASE ADDR                                      01200018
         USING *,RB                ADDRESS MODULE.                      01400017
         SSM   CHKMASK             SET MASK TO ALLOW INTERRUPTS.        01600017
         C     R0,PNAME  XXXXXXXXXX                                     01800017
         BE    RESTXX    XXXXXXXXXX                                     02000017
         L     R2,TCBTIO           GET ADDR OF TIOT.                    02200017
*********************************************************************** 02210018
*                                                                     * 02220018
*                                                                     * 02240017
*        IF CHECKPOINTS ARE TO BE SUPPRESSED, RETURN TO USER.         * 02280017
*                                                                     * 02320017
*********************************************************************** 02340018
*                                                                     * 02360017
         TM    TCBTRN,SUPPRESS     ARE CHKPTS TO BE SUPPRESSED          02460018
         BO    CHKSUP              YES-GO TO RETURN TO USER.            02600017
         XC    HKPGML2(LNXSA),HKPGML2                                   02700018
         ST    R2,HKPTIO                                                02800018
         TM    CVTDCB,KCVTMVT      IS THIS AN MVT SYSTEM                03000017
         BZ    CHKSM               NO-DO NOT SET MVT INDICATOR          03200017
         OI    HKPFLAG,CKMVT       SET MVT INDICATOR.                   03400017
*                                                                     * 03410018
*********************************************************************** 03420018
*                                                                     * 03440017
*        IF CANCEL WAS REQUESTED, BRANCH TO CANCEL ROUTINE TO GETMAIN * 03480017
*        A WORK AREA.                                                 * 03520017
*                                                                     * 03560017
*********************************************************************** 03570018
*                                                                     * 03580018
CHKSM    EQU   *                                                        03600017
         LTR   R1,R1               WAS CANCEL REQUESTED                 03800017
         BZ    CHKCANC1            YES-GO TO CANCEL ROUTINE.            04000017
*                                                                     * 04000318
*********************************************************************** 04000618
*                                                                     * 04001017
*        CHECK PARAMETER LIST ADDRESSES FOR BEING WITHIN P/P CORE AND * 04002017
*        DCB ADDRESS FOR BEING ON FULL WORD BOUNDARY.                 * 04003017
*                                                                     * 04004017
*********************************************************************** 04004518
*                                                                     * 04005017
CHKPARM  EQU   *                                                        04010017
         XR    RE,RE    CLEAR REGISTER                                  04020017
         LA    RE,1     SET SWITCH TO CHECK ONLY 2 ADDRS.               04030017
         USING PARMLST,R1          ADDR PARAMETER LIST                  04036018
         L     R7,DCBADDR          SET PARM FOR VAL CHK RTN - ADDR DCB  04042018
CHKVALR  EQU   *                                                        04050017
         LA    R7,0(R7)            CLEAR HIGH-ORDER BYTE OF REGISTER    04055017
         LR    R9,R4              ADDR TCB                              04060017
         L     R8,CVT0VL00        GET ADDR OF VALIDITY CHK RTN          04070017
         BALR  RA,R8                    BRANCH TO VALIDITY CHK RTN      04071017
         LA    RA,CKERPG1               SET RETURN CODE IF ERROR OCCURS 04072017
         BNZ   CHKERX              VALID ADDR-NO-GO TO ERROR EXIT RTN   04082018
         BCT   RE,CHKROLL         CHECK 2 ADDR-YES-TAKE BRANCH   A26719 04100019
         TM    LOWBYTE(R1),WDBNDTST LOW-ORDER BYTE DCB ADDR ON WD BOUND 04110018
         BNZ   CHKERX              NO-GO TO ERROR EXIT RTN              04120018
         CLI   FLAG,NOCHKID        CHECKID SPECIFIED-                   04130018
         BE    CHKROLL            NO-SKIP CODE TO CHECK 2ND WORD A26719 04140019
         L     R7,IDADDR           GET ADDR OF CHECKID                  04150018
         B     CHKVALR            VALIDATE CHECKID ADDR                 04160017
CHKROLL  TM    CVTDCB,KCVTMVT      IS THIS AN MVT SYSTEM?        A26719 04160119
         MVC   HKPWD1,DCBADDR      SAVE CHKPT DCB ADDRESS        A26719 04160219
         BZ    CHKOPEN             NO, DO NOT CHECK FOR ROLLOUT  A26719 04160319
         LA    RA,CKERPG20         YES, LOAD RETURN CODE IF ERRORA26719 04160719
         TM    TCBFLG2,ROLLOUT     IS JOB INVOKING ROLLOUT?      A26719 04160819
         BO    CHKERX              YES, GO TO ERROR EXIT RTN     A26719 04160919
*********************************************************************** 04161018
*                                                                     * 04162017
*        OPEN CHECKPOINT DATA SET IF USER DID NOT OPEN DATA SET       * 04164017
*                                                                     * 04166017
*********************************************************************** 04167018
*                                                                     * 04168018
CHKOPEN  EQU   *                                                        04170017
         LR    RD,R1                                                    04270017
         L     RC,DCBADDR          GET CHKPT DCB ADDR                   04340018
         DROP  R1                                                     * 04410018
         XR    R6,R6                                                    04600017
         LA    R9,TIOENTRY         GET ADDR OF FIRST DD ENTRY IN TIOT.  04800017
         USING IHADCB,RC           ADDRESS CHKPT DCB.                   05000017
         TM    DCBOFLGS,CKDCBOP    IS CHKPT DATA SET OPEN               05200017
         BO    CHKAFOP             YES-BYPASS OPENING OF DATA SET.      05400017
         ST    RC,HKPGLIST         PUT DCB ADDR IN OPEN'S PARM LIST.    05600017
         MVI   HKPGLIST,OPENOPT    MOVE OPTION BYTE TO PARM LIST.       05800017
         OPEN  MF=(E,HKPGLIST)     OPEN CHKPT DATA SET.                 06000017
         LA    RA,CKERPG2           SET RETURN CODE IF ERROR OCCURS.    06100017
         TM    DCBOFLGS,CKDCBOP    WAS OPEN SUCCESSFUL                  06200017
         BZ    CHKIOERR            NO-GO TO ERROR ROUTINE               06400017
         OI    HKPFLAG,CKOPEN      SET CHKPT OPEN BIT.                  06600017
*                                                                     * 06630017
*********************************************************************** 06640018
*                                                                     * 06660017
*        COMPUTE SIZE OF WORK AREA NEEDED BY RESTART                  * 06690017
*                                                                     * 06720017
*********************************************************************** 06730018
*                                                                     * 06750017
CHKAFOP  EQU   *                                                        06800017
         LA    R7,TIOLEN           INITIALIZE TIOT-LENGTH-ACCUMULATOR.  07000017
         USING TIOENTRY,R9         ADDRESS DD ENTRY IN TIOT             07200017
CHKETI   EQU   *                                                        07400017
         NC    TIOELNGH(TIOEDDNM-TIOENTRY),TIOELNGH    IS THIS THE      07500018
*                                  END OF THE TIOT                      07600018
         BNZ   CHKTIL              NO-GO TO GET ADDR OF NEXT DD ENTRY.  07800017
         STH   R7,HKPTIOTL         SAVE LENGTH OF TIOT.                 08000017
*                                                                     * 08006018
*********************************************************************** 08012018
*                                                                     * 08020017
*        LENGTH OF TIOT + LENGTH OF FIXED PART OF RESTART WORK AREA + * 08040017
*        LENGTH OF BASIC PART OF REPDCB'S WORK AREA                   * 08060017
*                                                                     * 08080017
*********************************************************************** 08180018
*                                                                     * 08280018
         LA    R7,WAK(R7)          ADD LENGTH OF FIXED W.A. TO TIOT     08380017
*                                                                     * 08480018
*********************************************************************** 08580018
*                                                                     * 08840017
*        INCREASE WORK AREA SIZE FOR REPDCB ACCORDING TO THE NUMBER   * 08880017
*        OF OPEN DATA SETS.                                           * 08920017
*                                                                     * 08960017
*********************************************************************** 08970018
*                                                                     * 08980018
CHKDEBN  EQU   *                                                        09000017
         USING DEBSECT,R8                                               09200017
         XR    R6,R6                                                    09400017
         LA    RA,CKERR11          SET UP DAUGHTER TASK ERROR    M1848  09440020
*                                       CODE                     M1848  09480020
         OC    TCBDEB,TCBDEB       CHECK FOR NO DEB CHAIN        M1848  09520020
         BZ    CHKERX              GO TO ERROR IF NO DEB CHAIN   M1848  09560020
         L     R8,TCBDEB           GET ADDR OF FIRST DEB.               09600017
CHKLSDB  EQU   *                                                        09800017
         NC    DEBLINK+1(3),DEBLINK+1 IS THIS THE LAST DEB              10000017
         BNZ   CHKNXDB             NO-GET ADDR OF NEXT DEB.             10200017
         LTR   R6,R6               Q. WAS THERE ONLY ONE DEB            10250017
         BZ    CHKCOMP             YES-SKIP CODE TO INCREASE W. A. SIZE 10300017
         BCTR  R6,0                GET NUMBER OF DEBS MINUS TWO         10350017
         MH    R6,REPDCB1          COMPUTE W.A THAT IS                  10400017
         AR    R7,R6               NEEDED BY REPDCB.                    10600017
         DROP  R8                                                       10800017
*                                                                     * 11180017
*********************************************************************** 11280018
*                                                                     * 11380017
*        PUT ADDRESS OF WORK AREA ON DOUBLE-WORD BOUNDARY AND ISSUE   * 11580017
*        CONDITIONAL GETMAIN FOR WORK AREA OF SIZE COMPUTED.          * 11780017
*                                                                     * 11980017
*********************************************************************** 12080018
*                                                                     * 12180017
CHKCOMP  EQU   *                                                        12400017
         LR    R1,R7                                                    13400017
         BAL   RF,CHKRDUP          GO TO ROUNDUP ROUTINE                13600017
         LR    R7,R1                                                    13800017
         BAL   R9,CHKCOMG          GO TO ISSUE CONDITIONAL GETMAIN      14000017
         B     *+4(RF)             IF RETURN CODE IS 0,                 14200017
         B     CHKCONT             CONTINUE NORMAL PROCESSING           14400017
         B     CHKERC               OTHERWISE-GO TO ERROR EXIT ROUTINE  14600017
*                                                                     * 14620017
*********************************************************************** 14630018
*                                                                     * 14640017
*        DETERMINE IF THE WORK AREA IS LOCATED WITHIN THE BOUNDARIES  * 14660017
*        FOR INVOKING ROLLIN/ROLLOUT.                                 * 14680017
*                                                                     * 14700017
*********************************************************************** 14710018
*                                                                     * 14720017
CHKCONT  EQU   *                                                        14800017
         TM    HKPFLAG,CKMVT       IS THIS AN MVT SYSTEM                15000017
         BZ    CHKPCP1              NO-GO TO GET PP CORE BOUNDARIES     15200017
         L     R9,TCBPQE           GET ADDR OF DUMMY PQE.               15400017
         USING PQE,R9              ADDR PQE MAPPING                     15500018
         L     R9,NPQE             GET ADDR OF FIRST PQE                15600018
         TM    PQEHRID,HIERONE     IS THIS PQE FOR HIERARCHY ONE   I283 15610019
         BZ    CHKCONT1            BRANCH IF NO                    I283 15620019
         L     RF,NPQE             GET ADDR OF NEXT PQE            I283 15630019
         LTR   RF,RF               DOES HIERARCHY ZERO PQE EXIST   I283 15640019
         BZ    CHKCONT1            BRANCH IF NO                    I283 15650019
         LR    R9,RF               USE HIERARCHY ZERO PQE SINCE    I283 15660019
*                                  WORK AREA MUST BE IN HIERARCHY  I283 15670019
*                                  ZERO IF IT EXISTS.              I283 15680019
CHKCONT1 EQU   *                                                   I283 15690019
         L     R3,LNREG            GET LENGTH OF REGION                 15700018
         L     R8,ADREG            GET ADDR OF REGION                   15800018
         AR    R3,R8               COMPUTE HIGH BOUNDARY OF REGION.     16200017
CHKULC   EQU   *                                                        16400017
         AH    R8,NOISE            COMPUTE HIGHEST AND LOWEST PART      16600017
         SH    R3,NOISE            OF CORE THAT W.A. CAN EXTEND INTO.   16800017
         LR    R2,R6               COMPUTE HIGH ORDER                   17000017
         AR    R2,R7               ADDRESS OF W.A.                      17200017
*                                                                     * 17210018
*********************************************************************** 17220018
*                                                                     * 17240017
*        IF WORK AREA IS LOCATED TOO HIGH IN CORE BRANCH TO ADJUST    * 17280017
*        ADDRESS AND ISSUE A CONDITIONAL GETMAIN FOR ANOTHER WORK AREA* 17320017
*                                                                     * 17360017
*********************************************************************** 17370018
*                                                                     * 17380018
         CR    R2,R3               DOES W.A. EXTEND TOO HIGH            17400017
         BH    CHKGMA2             YES-TRY TO GET ANOTHER W.A.          17600017
*                                                                     * 17601018
*********************************************************************** 17602018
*                                                                     * 17603017
*        IF WORK AREA EXTENDS TOO LOW IN CORE, NO FREE AREA OF SIZE   * 17606017
*        AND LOCATION ARE AVAILABLE - BRANCH TO ERROR ROUTINE         * 17609017
*                                                                     * 17612017
*********************************************************************** 17613018
*                                                                     * 17614018
         LA    RA,CKERPG4           LOAD MESSAGE CODE IF ERROR OCCURS.  17615017
         CR    R6,R8                DOES W.A. EXTEND TOO LOW            17618017
         BL    CHKERG               YES-GO TO ERROR EXIT ROUTINE        17621017
*                                                                     * 17624017
*********************************************************************** 17625018
*                                                                     * 17627017
*        INITIALIZE WORK AREA WITH INFORMATION THAT WILL BE USED BY   * 17630017
*        CHECKPOINT MODULES                                           * 17633017
*                                                                     * 17636017
*********************************************************************** 17637018
*                                                                     * 17639017
         USING CHKWA,R6             ADDRESS W.A.                        17650017
         XC    CHKWA(ZLN),CHKWA     ZERO OUT W.A.                       17700017
         MVC   CKSYNAD(WDLNG),DCBSYNAD  SAVE DCBSYNAD FIELD IN WA       17900018
         MVC   CKTIOTLN(LNG),HKPTIOTL   MOVE INFO FROM SVRB SA TO WA    18100018
         USING PARMLST,RD          ADDR PARAMETER LIST                  18300018
         MVC   CKDCB(ADDRLNG),DCBORCN   PUT ADDR OF CHKPT DCB INTO      18500018
         MVC   CKDCB2(ADDRLNG),DCBORCN  DECBS INWA                      18700018
         LR    R8,R7               SAVE W.A. LENGTH.                    19300017
         SH    R7,SURLN                                                 19400017
         ST    R7,CKBFOFST                                              20300017
CHKCOCNC EQU   *                                                        21200017
         ST    R4,CKTCBAD          INITIALIZE CHKWA                     21400017
         ST    R8,CKWACL                                                21600017
         LA    RF,CHKWAL           GET OFFSET TO CHKDCB W.A.            21800017
         ST    RF,CKWAOFST                                              22000017
         MVC   CKFLAG1(ONE),HKPFLAG                                     22200018
         TM    CKFLAG1,CKMVT       IS THIS AN MVT SYSTEM                22400017
         BZ    CHKPCP2              NO-GO TO CHECK FOR LCS CORE         22600017
         DROP  R9                                                  I283 22700019
         L     RF,TCBPQE           GET ADDR OF DUMMY PQE           I283 22800019
         USING PQE,RF                                              I283 22900019
CHKPQELP EQU   *                                                   I283 23000019
         L     RF,NPQE             GET NEXT PQE                    I283 23100019
         LTR   RF,RF               DOES NEXT ONE EXIST             I283 23200019
         BZ    CHKGO2              BRANCH IF NO                    I283 23300019
         L     R9,ADREG            LOAD BEGINNING ADDR OF REGION   I283 23400019
         LR    RA,R9               PUT ADDR IN RA TOO              I283 23500019
         A     RA,LNREG            CALCULATE END ADDR              I283 23600019
         BCTR  RA,0                          OF REGION             I283 23700019
         TM    PQEHRID,HIERONE     IS THIS HIERARCHY ONE           I283 23800019
         BO    CHKH1BND            BRANCH IF YES                   I283 23900019
         STM   R9,RA,CKPPM         STORE LOW AND HIGH ADDRS OF     I283 24000019
*                                  HIERARCHY ZERO IN THE WORK AREA I283 24100019
         B     CHKPQELP            BRANCH TO CHECK FOR NEXT PQE    I283 24200019
CHKH1BND EQU   *                                                   I283 24300019
         STM   R9,RA,CKPPML        STORE LOW AND HIGH ADDRS OF     I283 24400019
*                                  HIERARCHY ONE IN WORK AREA      I283 24500019
         B     CHKPQELP            GO CHECK FOR NEXT PQE           I283 24600019
         DROP  RF                                                  I283 24700019
CHKGO    EQU   *                                                        25600017
         USING HKPSECT,R5                                               25700017
         LTR   R8,R8               ANY H0 CORE                    MFTCR 25730018
         BZ    CHKGO1              BRANCH IF NO                   MFTCR 25760018
         BCTR  R8,0                PP CORE.                             25800017
CHKGO1   EQU   *                                                  MFTCR 25900018
         ST    R8,CKPPE                                                 26000017
CHKGO2   EQU   *                                                   I283 26100019
         ST    RD,CKPARMAD                                              26200017
         LR    R1,R6                                                    26400017
         MVC   HKPGLIST(LNXCTLST),CHKXLIST                              26406018
*                                                                     * 26412017
*********************************************************************** 26412618
*                                                                     * 26413218
*        IF CANCEL IS REQUESTED, XCTL TO IGC0206C; OTHERWISE, TRANSFER* 26414017
*        CONTROL TO NEXT LOAD, IGC0106C.                              * 26416017
*                                                                     * 26418017
*********************************************************************** 26419018
         TM    CKFLAG1,CKCANCEL         IS THIS A CANCEL REQUEST        26420017
         BO    CHKCANC2                 YES-                            26440017
CHKRET   EQU   *                                                        26480017
         LA    RF,HKPGLIST                                              26500017
         ST    RF,HKPNTLST                                              26520018
         LA    RF,HKPNTLST                                              26540018
         XCTL  SF=(E,(15))                                              26560017
RESTXX   EQU   *              XXXXX                                     28400017
         MVC   HKPGLIST(LNXCTLST),IGC52X                                28460018
         B     CHKRET              BRANCH TO XCTL TO SVC52.             28660018
*                                                                     * 28860018
*********************************************************************** 29060018
*                                                                     * 29570017
*        RETURN TO USER WHEN CHECKPOINTS ARE TO BE SUPPRESSED         * 29580017
*                                                                     * 29590017
*********************************************************************** 29593018
*                                                                     * 29596018
CHKSUP   EQU   *                                                        29600017
         LA    RF,CKNORM           LOAD RETURN CODE.                    29800017
         SVC   3                   ISSUE EXIT SVC.                      30000017
*                                                                     * 30020017
*********************************************************************** 30030018
*                                                                     * 30040017
*        ERROR EXIT ROUTINES - SETS MESSAGE AND RETURN CODE IN SVRB   * 30060017
*        EXTENDED WORK AREA, FREEMAINS INVALID CHKPT W.A. IF NECESSARY* 30080017
*        AND XCTL'S TO EXIT ROUTINE, IGC0Q06C.                        * 30100017
*                                                                     * 30120017
*********************************************************************** 30130018
*                                                                     * 30140017
CHKERX   EQU   *                                                        30200017
         OI    HKPFLAG,HKPEXIT     INDICATES ACTION TO BE TAKEN IN CER  30400017
CHKERCOD EQU   *                                                        30600017
         MVI   HKPRETCD,CKPGMERR   PUT RETURN CODE IN PARM. AREA        30800018
CHKERMSG EQU   *                                                        31000017
         STH   RA,HKPMSGCD         PUT MESSAGE CODE IN PARM AREA        31200018
         XR    R1,R1              SET UP PARM REG - NO CHKPT WA         31400017
CHKCER   EQU   *                                                        32260017
         OI    HKPFLAG,CKMSG1      INDICATES MSG-ENVIRONMENT ERROR      32261017
         MVC   HKPGLIST(8),CHKXLIST  SET XCTL PARLIST TO GO TO CER.     32262017
         MVI   HKPWD2,Q06C                                              32263018
*                                                                     * 32264018
*********************************************************************** 32265018
         B     CHKRET              GO TO XCTL TO IGC0Q06C.              32295018
CHKERG   EQU   *                                                        32336017
         LR    R0,R7               LOAD FREEMAIN PARAMETER REGISTERS    32406017
         LR    R1,R6                                                    32476017
         FREEMAIN R,LV=(0),A=(1)                                        32546017
CHKERC   EQU   *                                                        32616017
         TM HKPFLAG,CKOPEN        DID CHKPT OPEN DS                     32686017
         BZ    CHKERX              NO-GO TO INDICATE ACTION IN CER      32756017
         OI    HKPFLAG,HKPCLOSE    INDICATES ACTION TO BE TAKEN IN CER  32826017
         LR    R2,RC               LOAD PARM REG WITH ADDR DCB          32896017
         B     CHKERCOD            GO TO STORE ERROR CODES IN CHKWA     32966018
CHKIOERR EQU   *                                                        33036017
         MVI   HKPRETCD,CKIOERR    PUT RETURN CODE IN PARM. AREA        33106018
         OI    HKPFLAG,HKPEXIT     INDICATES ACTION TO BE TAKEN IN CER  33176017
         B     CHKERMSG            GO TO STORE MSG CODE IN CHKWA        33246018
*                                                                     * 33326017
*        TALLY LENGTH OF TIOT AND POINT TO NEXT DD ENTRY IN TIOT      * 33406017
*                                                                     * 33486017
*********************************************************************** 33516018
*                                                                     * 33546018
CHKTIL   EQU   *                                                        33600017
         USING TIOENTRY,R9        ADDRESS DD ENTRY IN TIOT              33700017
         IC    R6,TIOELNGH                                              33800017
         AR    R7,R6               UPDATE TIOT-LENGTH ACCUMULATOR       34000017
         AR    R9,R6               UPDATE DD ENTRY POINTER.             34200017
         B     CHKETI              RETURN TO TIOT-LENGTH-LOOP           34400018
         USING DEBSECT,R8          ADDRESS DEBS.                        34600017
*                                                                     * 34610018
*********************************************************************** 34620018
*                                                                     * 34650017
*        INCREMENT NUMBER OF DEB'S AND POINT TO NEXT DEB              * 34700017
*                                                                     * 34750017
*********************************************************************** 34760018
*                                                                     * 34770018
CHKNXDB  EQU   *                                                        34800017
         LA    R6,1(0,R6)          INCREMENT DEB COUNTER.               35000017
         L     R8,DEBLINK          GET ADDR OF NEXT DEB.                35200017
         B     CHKLSDB             GO TO CHECK FOR END OF DEB CHAIN.    35400017
         DROP  R8                                                       35600017
*                                                                     * 36000017
*********************************************************************** 36200018
*                                                                     * 36400017
*        ROUNDUP ROUTINE - CHECK FOR CHKPT WORK AREA ADDRESS ON DOUBLE* 36800017
*        WORD BOUNDARY. IF NOT, INCREASE ADDRESS TO NEXT HIGHER       * 37200017
*        DOUBLE WORD BOUNDARY.                                        * 37600017
*                                                                     * 38000017
*********************************************************************** 38200018
*                                                                     * 38400017
CHKRDUP  EQU   *                                                        38800017
         STC   R1,HKPSP            SAVE LOW ORDER BYTE OF ADDR.         39000017
         TM    HKPSP,DBLWDBND      IS ADDR ALREADY ON DBL WD BOUNDARY   39200018
         BCR   ZERO,RF             YES-RETURN TO CALLER                 39400018
         LA    R1,8(0,R1)          INCREASE ADDR BY EIGHT.              39600017
         SRA   R1,TRUNC3           TRUNCATE 3 LOW                       39800018
         SLA   R1,TRUNC3           ORDER BINARY DIGITS                  40000018
         BR    RF                  RETURN TO CALLER                     40200017
*                                                                     * 40220017
*********************************************************************** 40230018
*                                                                     * 40240017
*        SET UP PARAMETER LIST AND ISSUE CONDITIONAL GETMAIN FOR      * 40260017
*        WORK AREA                                                    * 40280017
*                                                                     * 40300017
*********************************************************************** 40310018
*                                                                     * 40320017
CHKCOMG  EQU   *                                                        40400017
         LA    RE,HKPGLIST          SET UP GETMAIN PARM LIST            40600017
         ST    R7,HKPGLIST                                              41000017
         LA    R0,HKPGML                                                41400017
         LA    RA,CKERPG3          LOAD MESSAGE CODE IF ERROR OCCURS.   41500017
         LA    R8,HKPGMLAD                                              41600017
         GETMAIN EC,A=(R8),SP=250,MF=(E,(RE))                           41800017
         L     R6,HKPGMLAD         GET ADDR OF W.A.                     42000017
         LA    R6,0(R6)            CLEAR HIGH ORDER BYTE.               42100017
         XC    HKPGML2(HKPGML-HKPGML2),HKPGML2                          42120018
*                                  CLEAR AREA TO STORE ERROR CODES      42140018
         LR    R8,R7               SAVE LENGTH OF W.A. FOR CANCEL RTN   42170017
         BR    R9                  RETURN TO CALLER                     42200017
*                                                                     * 42300018
*********************************************************************** 42400018
*                                                                       42700017
*        FOR PCP, GET POINTERS TO HIGH AND LOW BOUNDARIES OF P/P CORE.* 43200017
*                                                                     * 43700017
*********************************************************************** 43800018
*                                                                     * 43900018
CHKPCP1  EQU   *                                                        44200017
         L     R9,TCBMSS           GET ADDR OF BOUNDARY BOX.            44400017
         USING BOUNDBOX,R9         BOUNDARY BOX MAPPING                 44500018
         L     R3,BBHI             GET HIGH BOUNDARY ADDR               44600018
         L     R8,BBLO             GET LOW BOUNDARY ADDR                44700018
         LA    R8,0(R8)                                           MFTCR 44710018
         LTR   R8,R8               IS THERE ANY H0                MFTCR 44720018
         BNZ   CHKULC              BRANCH IF YES                  MFTCR 44730018
         L     R3,LCSHI            GET HIGH LCS ADDRESS           MFTCR 44740018
         L     R8,LCSLO            GET LOW LCS ADDRESS            MFTCR 44750018
         DROP  R9                                                       44800018
         B     CHKULC              GO TO DETERMINE IF WA WITHIN LIMITS  44900018
*                                                                     * 45020017
*********************************************************************** 45030018
*                                                                     * 45040017
*        WHEN WORK AREA HAS BEEN GETMAIN'D TOO HIGH IN CORE, THE VALID* 45060017
*        PORTION OF W.A. IS FREEMAIN'D AND A CONDITIONAL GETMAIN IS   * 45080017
*        ISSUED FOR A PIECE OF CORE BELOW INVALID PORTION OF W.A.     * 45100017
*        A FREEMAIN IS THEN ISSUED FOR INVALID PORTION OF W.A.        * 45120017
*                                                                     * 45140017
*********************************************************************** 45150018
*                                                                     * 45160017
CHKGMA2  EQU   *                                                        45200017
         BCTR  R3,0                ADJUST ADDR OF AREA TO BE KEPT.      45400017
         STC   R3,HKPSP            SAVE LOW ORD. BYTE OF ADDR TO BE KPT 45600017
         TM    HKPSP,DBLWDBND      WAS ADDR ALREADY ON DBL WD BOUNDARY  45800018
         BZ    CHKLV               YES-DO NOT ADJUST ADDR.              46000017
         LR    R1,R3                                                    46200017
         BAL   RF,CHKRDUP          GO TO ROUNDUP ROUTINE.               46400017
         SH    R1,CHK8             GET ADDR OF NEXT LOWER DOUBLE WORD.  46600017
         LR    R3,R1                                                    46800017
CHKLV    EQU   *                                                        47000017
         SR    R1,R6               COMPUTE LENGTH TO BE FREED.          47200017
         LR    R2,R7               LOAD LENGTH OF W.A.                  47400017
         SR    R2,R1               COMPUTE LENGTH TO BE KEPT.           47600017
         LR    R0,R1               LOAD LENGTH TO BE FREED.             47800017
         LR    R1,R6               LOAD ADDR OF AREA TO BE FREED.       48000017
         O     R0,SP250            INDICATE SP 250.                     48100017
         FREEMAIN R,LV=(0),A=(1)   FREEMAIN FOR ELIGIBLE PART OF W.A.   48200017
         BAL   R9,CHKCOMG          GO TO ISSUE CONDITIONAL GETMAIN      48400017
         LR    R9,RF               SAVE GETMAIN RETURN CODE.            48600017
         LR    R0,R2               LOAD FREEMAIN PARAMETER REGISTERS.   48800017
         LR    R1,R3                                                    49000017
         O     R0,SP250            INDICATE SP 250.                     49100017
         FREEMAIN R,LV=(0),A=(1)   FREEMAIN FOR INVALID W.A.            49200017
         B     *+4(R9)             IF GETMAIN RETURN CODE WAS 0,        49400017
         B     CHKCONT             CONTINUE NORMAL PROCESSING.          49600017
         B     CHKERC              OTHERWISE-GO TO ERROR EXIT ROUTINE   49800017
*                                                                     * 49860018
*********************************************************************** 49920018
*                                                                     * 50000017
*        FOR PCP, CHECK FOR LCS CORE IN SYSTEM AND SAVE BOUNDARY      * 50200017
*        ADDRESSES                                                    * 50400017
*                                                                     * 50600017
*********************************************************************** 50700018
*                                                                     * 50800018
CHKPCP2  EQU   *                                                        51000017
         L     R3,CVTPTR                                          MFTCR 51020018
         USING CVTSECT,R3                                         MFTCR 51040018
         TM    CVTDCB,X'20'        IS THIS MFT SYSTEM             MFTCR 51060018
         BZ    CHKLCS             LBRANCH IF NO                   MFTCR 51080018
         OI    CKFLAG1,CKMFT       SET MFT FLAG                   MFTCR 51100018
CHKLCS   EQU   *                                                  MFTCR 51120018
         L     R9,TCBMSS           GET ADDR OF BOUNDARY BOX.            51200017
         USING BOUNDBOX,R9         BOUNDARY BOX MAPPING                 51300018
         TM    BBFLAG,LCS          IS LCS IN SYSTEM                     51400018
         BZ    CHKNOLCS            NO-SKIP CODE TO PROCESS LCS.         51600017
         L     RF,LCSFQE           GET ADDR OF FIRST FQE IN LCS         51700018
         L     R3,LCSHI            GET HI BND OF LCS CORE               51800018
         S     R3,LCSLO                                                 51900018
         MVC   CKPPML(CKPPEL-CKPPML),LCSLO   MOVE LOW BND OF LCS TO WA  52800018
         L     R8,LCSHI            DECREMENT HIGH BND OF LCS BY ONE     53000018
         BCTR  R8,0                AND STORE IN WA.                     53200018
         ST    R8,CKPPEL                                                53400017
CHKNOLCS EQU   *                                                        53600017
         MVC   CKPPM(CKPPE-CKPPM),BBLO  MOVE LOW BND P/P CORE TO WA     53680018
         L     R8,BBHI             GET HIGH BND P/P CORE                53760018
         B     CHKGO               GO TO DECREMENT AND STORE IN WA AND  53840018
*                                  TRANSFER CONTROL TO NEXT MODULE      53920018
         DROP  R9                                                       54000018
*                                                                     * 54080018
*********************************************************************** 54160018
*                                                                     * 54240017
*        FOR CANCEL REQUEST, ISSUE CONDITIONAL GETMAIN FOR WORK AREA  * 54280017
*        NEEDED AND BRANCH TO INITIALIZE WORK AREA                    * 54320017
*                                                                     * 54360017
*********************************************************************** 54370018
*                                                                     * 54380018
CHKCANC1 EQU   *                                                        54400017
         OI    HKPFLAG,CKCANCEL    SET CANCEL INDICATOR                 54500017
         LA    R7,LENCANCL         GET LENGTH OF W.A.                   54600017
         BAL   R9,CHKCOMG          GO TO GETMAIN FOR W.A.               54800017
         B     *+4(RF)             WAS GETMAIN SUCCESSFUL               54900017
         B     CHKCCN              YES-CONTINUE PROCESSING CANCEL REQ.  55000017
         B     CHKERC              NO-GO TO ERROR EXIT ROUTINE          55100017
         USING CHKWA,R6            ADDRESS W.A.                         55800017
CHKCCN   EQU   *                                                        56000017
         XC    CHKWA(ZLN),CHKWA    ZERO OUT W.A.                        56200017
         B     CHKCOCNC            GO TO INITIALIZE CANCEL WA           56260018
*                                                                     * 56320018
*********************************************************************** 56380018
*                                                                     * 56440017
*        ALTER XCTL PARAMETER LIST FOR CANCEL REQUEST TO TRANSFER     * 56480017
*        CONTROL TO IGC0206C.                                         * 56520017
*                                                                     * 56560017
*********************************************************************** 56570018
*                                                                     * 56580018
CHKCANC2 EQU   *                                                        56600017
         MVI   HKPWD2,C206C        ALTER XCTL PARM LIST SO THAT         56800018
*                                  IGG0206C WILL GET CONTROL NEXT.      57000017
         B     CHKRET              GO TO XCTL                           57200018
         DS    0F                                                       57400017
SP250    DC    X'FA000000'    INDICATES SUBPOOL 250 FOR GETMAIN PARMLST 57500018
PNAME    DC    CL4'IEFD'           ***                                  57600018
CHKXLIST DC    C'IGC0106C'         MODULE NAME FOR XCTL PARMLST         57680018
NOISE    DC    H'18'     MAXIMUM LENGTH OF NOISE RECORD.                57760018
SURLN    DC    H'200'   LENGTH OF SUR BUFFER.                           57920017
CHK8     DC    H'8'                CONSTANT USED TO GET NEXT DBLWD ADDR 58020018
REPDCB1  DC    H'48'     AMOUNT OF EXTRA CORE NEEDED BY                 58200017
*                        REPDCB FOR EACH OPEN DATA SET.                 58400017
CHKMINBK DC    H'600'    MINIMUM BLOCKSIZE FOR CHKPT DATA SET.          58500017
IGC52X   DC    C'IGC0005B'         ***                                  58600018
CHKMASK  DC    X'FF'               MASK TO ENABLE INTERRUPTS            58800017
HKPSECT  DSECT                                                          58900017
HKPSVRB  DS    24F       INITIAL SECTION OF SVRB                        58940018
HKPGML2  DS    0F        SAVE AREA FOR ERROR RETURN AND MESSAGE CODES   58980018
         DS    C         RETURN CODE                                    59020018
HKPRETCD DS    C                                                        59060018
HKPMSGCD DS    H         MESSAGE CODE                                   59100018
HKPGML   DS    F         GETMAIN PARAMETER LIST:                        59140018
HKPGMLAD DS    2F          LNG AND ADDR OF GETMAIN'D AREA RETURNED HERE 59180018
HKPGLIST DS    1F        PARAMETER LIST FOR OPEN, GETMAIN AND XCTL      59220018
HKPWD2   DS    F                                                        59260018
HKPNTLST DS    F                                                        59300018
HKPTIOTL DS    H         LENGTH OF TIOT                                 59340018
HKPBUFL  DS    H         UNUSED                                         59380018
HKPTIO   DS    0F                                                       59420018
HKPFLAG  DS    1C        FLAG BYTE                                      59460018
HKPCLOSE EQU   16        INDICATES CER MUST CLOSE CHKPT D.S.            59500018
HKPEXIT  EQU   1                                                        59540018
HKPTIOAD DS    3C        ADDRESS OF TIOT                                59580018
HKPWD1   DS    0F                                                       59620018
HKPSP    DS    1C        USED TO CHECK BOUNDARY ALIGNMENT OF ADDRESS    59660018
HKPDCBAD DS    3C        ADDRESS CHKPT DCB                              59700018
HKPSAVRN DS    F         UNUSED                                         59740018
*        MAPPING OF MAIN STORAGE BOUNDARY BOX IN PCP AND MFT            59780018
BOUNDBOX DSECT                                                          59820018
FQEPNT   DS    0F   ADDR OF FIRST FQE                                   59860018
BBFLAG   DS    C    FLAG BYTE - INDICATES IF LCS IN SYSTEM              59900018
         DS    3C                                                       59940018
BBLO     DS    F    LOW ORDER ADDR OF P/P CORE                          59980018
BBHI     DS    F    HIGH ORDER ADDR OF P/P CORE                         60020018
LCSFQE   DS    F    ADDR OF FIRST FQE IN LCS                            60060018
LCSLO    DS    F    LOW ORDER ADDR OF LCS CORE                          60100018
LCSHI    DS    F    HIGH ORDER ADDR OF LCS CORE                         60140018
*        MAPPING OF FREE QUEUE ELEMENT (FQE)                            60180018
FQESECT  DSECT                                                          60220018
NEXTFQE  DS    F    POINTER TO NEXT FQE ON CHAIN                        60260018
LNFREE   DS    F    LENGTH OF FREE AREA DESCRIBED BY THIS FQE           60300018
*        CHKPT PARAMETER LIST                                           60340018
PARMLST  DSECT                                                          60380018
DCBADDR  DS    0CL4                                                     60420018
FLAG     DS    CL1       FLAG BYTE                                      60460018
NOCHKID  EQU   X'80'     SYSTEM-GENERATED CHECKID NOT RETURNED TO USER  60500018
UCHKID   EQU   X'00'     USER-SPECIFIED CHECKID                         60540018
DCBORCN  DS    CL3       ADDRESS OF CHKPT DCB                           60580018
IDADDR   DS    0CL4                                                     60620018
LNGID    DS    CL1       LENGTH OF USER SPECIFIED CHECKID               60660018
RTNCKID  EQU   X'FF'     SYSTEM-GENERATED CHECKID RETURNED TO USER      60700018
         DS    CL3       ADDR OF CHECKID                                60740018
ADDRLNG  EQU   3         LENGTH OF ADDRESS                              60780018
*        MAPPING OF PQE                                                 60820018
PQE      DSECT                                                          60860018
         DS    CL8       DUMMY PQE                                      60900018
NPQE     DS    CL4       FIRST PQE                                      60940018
         DS    CL8                                                      60980018
LNREG    DS    CL4       LENGTH OF REGION                               61020018
ADREG    DS    CL4       ADDR OF REGION                                 61060018
PQEFLGS  DS    CL1                 FLAGS                           I283 61080019
PQEHRID  DS    CL1                 HIERARCHY ID                    I283 61100019
HIERONE  EQU   X'01'               INDICATES HIERARCHY ONE         I283 61120019
         DS    H                   RESERVED                        I283 61140019
         IEEVCHWA                                                       61200017
CHRDEC   DS    D                                                        61840017
CHRCON   DS    5H                                                       61880017
CHRAD    DS    F                                                        61920017
CHRXL    DS    CL8  NAME OF MODULE TO TRANSFER CONTROL TO.              61960017
 IEEVRSWA                                                               62000017
TIOTSECT DSECT                                                          62200017
         IEFTIOT1                                                       62400017
         DCBD  DSORG=(BS,PO),DEVD=(DA,TA)                               62600017
         IHBABCTL                                                       62800017
BLKL     EQU   2    LENGTH OF DCBBLKSI FIELD.                           63200017
OPENOPT  EQU   143  OPTION BYTE FOR OPEN'S PARM LIST                    63400017
CLOSEOPT EQU   128  OPTION BYTE FOR CLOSE'S PARM LIST.                  63600017
LENCANCL EQU   CHRXL+8-CHKWA  LENGTH OF W.A. NEED                       63800017
LCS      EQU   X'01'     INDICATES LCS.                                 64600017
SVRBL    EQU   200  LENGTH OF REPMAIN'S OWN W.A.                        64800017
CHKWAL   EQU   DXCCW3+8-CHKWA      LENGTH OF CHKWA.                     65000017
WAK      EQU   1108      CONSTANT USED IN CALCULATING W.A.              65200017
TAPEDML  EQU   48   LENGTH OF IOB/CP FOR TAPE TO BE USED AT RESTART.    65400017
DADML    EQU   88   LENGTH OF IOB/CP FOR D.A. TO BE USED AT RESTART.    65600017
DADEB    EQU   344  MAXIMUM LENGTH FOR D.A. DEB.                        65800017
TAPEDEB  EQU   92   MAXIMUM LENGTH FOR TAPE DEB.                        66000017
RSWAL    EQU   RSTIOT-RSTWA   LENGTH OF FIXED PART OF RESTART W.A.      66200017
TIOLEN   EQU   28      LENGTH OF TIOT THAT IS NOT PART OF A DD ENTRY    66800017
ZLN      EQU   256     LENGTH OF W.A. TO BE ZEROED OUT.                 67400017
DADCK    EQU   32      DCBDEVT FIELD- INDICATES DIRECT ACCESS DEVICE    67600017
CKDCBOP  EQU   16                                                       67800017
CKSUPRS  EQU   64   TIOESTTA FIELD-INDICATES CHKPT SUPPRESS REQUEST     68000017
KCVTMVT  EQU   X'10'     CVTDCB FIELD-INDICATES MVT SYSTEM.             68200017
DD2L     EQU   44   NO. OF BYTES TIOT IS ALLOWED TO INCREASE AT RESTART 68400017
PCPDA    EQU   DADEB+DADML                                              68600017
PCPTAPE  EQU   TAPEDEB+TAPEDML                                          68800017
SUPPRESS EQU   X'40'     BIT IN TCB INDICATING CHKPTS TO BE SUPPRESSED. 68800518
LOWBYTE  EQU   3         ADDRESSING LOW-ORDER BYTE OF A WORD            68801018
LNXSA    EQU   48        LENGTH OF EXTENDED SAVE AREA FOR SVRB          68801518
Q06C     EQU   C'Q'      CHARACTER TO ALTER NAME OF XCTL MODULE         68802018
DBLWDBND EQU   X'07'     TEST FOR ADDRESS ON DOUBLE WORD BOUNDARY       68802518
C206C    EQU   C'2'      CHARACTER TO ALTER NAME OF XCTL MODULE         68803018
LNXCTLST EQU   8         LENGTH OF XCTL PARM LIST                       68803518
ZERO     EQU   8         CONDITION CODE SETTING FOR TM INSTRUCTION      68804018
WDBNDTST EQU   X'03'     TEST FOR ADDRESS ON WORD BOUNDARY              68804518
LNG      EQU   2         LENGTH OF HALFWORD                             68805018
WDLNG    EQU   4         LENGTH OF WORD                                 68805518
ONE      EQU   1         LENGTH OF FLAG BYTE                            68806018
TRUNC3   EQU   3         USED TO MAKE ADDR MULTIPLE OF 8                68806518
CKTIOTLN EQU   CKTIOLN+2                                                68807018
CKDCB    EQU   CKDCBAD+1                                                68807518
CKDCB2   EQU   CKDCBAD2+1                                               68808018
CKMSG1   EQU   32    WTO MESSAGE = NOT TAKEN                            68810017
CKERR11  EQU   X'0B'               DAUGHTER TASK ERROR CODE      M1848  68815020
CKERPG1  EQU   X'01'    PARAMETER LIST ERROR                            68820017
CKERPG2  EQU   X'02'    OPEN UNSUCCESSFUL                               68830017
CKERPG3  EQU   X'03'    GETMAIN UNSUCCSSSFUL                            68840017
CKERPG4  EQU   X'04'    CHKPT WORKAREA EXTENDS TOO LOW                  68870017
CKERPG20 EQU   X'14'    ROLLOUT                                  A26719 68880019
TCBFLG2  EQU   TCBFLGS+2  ADDRESS BYTE WITHIN DSECT              A26719 68890019
ROLLOUT  EQU   X'40'   INDICATES JOB HAS ROLLED OUT ANOTHER TASK A26719 68900019
 END                                                                    69000017
